git-svn.perl

   1 #!/usr/bin/perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use 5.008;
   5 use warnings;
   6 use strict;
   7 use vars qw/    $AUTHOR $VERSION
   8                 $sha1 $sha1_short $_revision $_repository
   9                 $_q $_authors $_authors_prog %users/;
  10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11 $VERSION = '@@GIT_VERSION@@';
  12
  13 use Carp qw/croak/;
  14 use Digest::MD5;
  15 use IO::File qw//;
  16 use File::Basename qw/dirname basename/;
  17 use File::Path qw/mkpath/;
  18 use File::Spec;
  19 use File::Find;
  20 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  21 use IPC::Open3;
  22 use Memoize;
  23
  24 use Git::SVN;
  25 use Git::SVN::Editor;
  26 use Git::SVN::Fetcher;
  27 use Git::SVN::Ra;
  28 use Git::SVN::Prompt;
  29 use Git::SVN::Log;
  30 use Git::SVN::Migration;
  31
  32 use Git::SVN::Utils qw(
  33         fatal
  34         can_compress
  35         canonicalize_path
  36         canonicalize_url
  37         join_paths
  38         add_path_to_url
  39         join_paths
  40 );
  41
  42 use Git qw(
  43         git_cmd_try
  44         command
  45         command_oneline
  46         command_noisy
  47         command_output_pipe
  48         command_close_pipe
  49         command_bidi_pipe
  50         command_close_bidi_pipe
  51 );
  52
  53 BEGIN {
  54         Memoize::memoize 'Git::config';
  55         Memoize::memoize 'Git::config_bool';
  56 }
  57
  58
  59 # From which subdir have we been invoked?
  60 my $cmd_dir_prefix = eval {
  61         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  62 } || '';
  63
  64 $Git::SVN::Ra::_log_window_size = 100;
  65
  66 if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
  67         $ENV{SVN_SSH} = $ENV{GIT_SSH};
  68 }
  69
  70 if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
  71         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  72         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  73 }
  74
  75 $Git::SVN::Log::TZ = $ENV{TZ};
  76 $ENV{TZ} = 'UTC';
  77 $| = 1; # unbuffer STDOUT
  78
  79 # All SVN commands do it.  Otherwise we may die on SIGPIPE when the remote
  80 # repository decides to close the connection which we expect to be kept alive.
  81 $SIG{PIPE} = 'IGNORE';
  82
  83 # Given a dot separated version number, "subtract" it from
  84 # the SVN::Core::VERSION; non-negaitive return means the SVN::Core
  85 # is at least at the version the caller asked for.
  86 sub compare_svn_version {
  87         my (@ours) = split(/\./, $SVN::Core::VERSION);
  88         my (@theirs) = split(/\./, $_[0]);
  89         my ($i, $diff);
  90
  91         for ($i = 0; $i < @ours && $i < @theirs; $i++) {
  92                 $diff = $ours[$i] - $theirs[$i];
  93                 return $diff if ($diff);
  94         }
  95         return 1 if ($i < @ours);
  96         return -1 if ($i < @theirs);
  97         return 0;
  98 }
  99
 100 sub _req_svn {
 101         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
 102         require SVN::Ra;
 103         require SVN::Delta;
 104         if (::compare_svn_version('1.1.0') < 0) {
 105                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
 106         }
 107 }
 108
 109 $sha1 = qr/[a-f\d]{40}/;
 110 $sha1_short = qr/[a-f\d]{4,40}/;
 111 my ($_stdin, $_help, $_edit,
 112         $_message, $_file, $_branch_dest,
 113         $_template, $_shared,
 114         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
 115         $_before, $_after,
 116         $_merge, $_strategy, $_preserve_merges, $_dry_run, $_local,
 117         $_prefix, $_no_checkout, $_url, $_verbose,
 118         $_commit_url, $_tag, $_merge_info, $_interactive);
 119
 120 # This is a refactoring artifact so Git::SVN can get at this git-svn switch.
 121 sub opt_prefix { return $_prefix || '' }
 122
 123 $Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
 124 $_q ||= 0;
 125 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
 126                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
 127                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
 128                     'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
 129                     'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
 130 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
 131                 'authors-file|A=s' => \$_authors,
 132                 'authors-prog=s' => \$_authors_prog,
 133                 'repack:i' => \$Git::SVN::_repack,
 134                 'noMetadata' => \$Git::SVN::_no_metadata,
 135                 'useSvmProps' => \$Git::SVN::_use_svm_props,
 136                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 137                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 138                 'no-checkout' => \$_no_checkout,
 139                 'quiet|q+' => \$_q,
 140                 'repack-flags|repack-args|repack-opts=s' =>
 141                    \$Git::SVN::_repack_flags,
 142                 'use-log-author' => \$Git::SVN::_use_log_author,
 143                 'add-author-from' => \$Git::SVN::_add_author_from,
 144                 'localtime' => \$Git::SVN::_localtime,
 145                 %remote_opts );
 146
 147 my ($_trunk, @_tags, @_branches, $_stdlayout);
 148 my %icv;
 149 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 150                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 151                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 152                   'stdlayout|s' => \$_stdlayout,
 153                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 154                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 155                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 156                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 157                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 158                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 159                   %remote_opts );
 160 my %cmt_opts = ( 'edit|e' => \$_edit,
 161                 'rmdir' => \$Git::SVN::Editor::_rmdir,
 162                 'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
 163                 'l=i' => \$Git::SVN::Editor::_rename_limit,
 164                 'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
 165 );
 166
 167 my %cmd = (
 168         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 169                         { 'revision|r=s' => \$_revision,
 170                           'fetch-all|all' => \$_fetch_all,
 171                           'parent|p' => \$_fetch_parent,
 172                            %fc_opts } ],
 173         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 174                         { 'revision|r=s' => \$_revision,
 175                           'preserve-empty-dirs' =>
 176                                 \$Git::SVN::Fetcher::_preserve_empty_dirs,
 177                           'placeholder-filename=s' =>
 178                                 \$Git::SVN::Fetcher::_placeholder_filename,
 179                            %fc_opts, %init_opts } ],
 180         init => [ \&cmd_init, "Initialize a repo for tracking" .
 181                           " (requires URL argument)",
 182                           \%init_opts ],
 183         'multi-init' => [ \&cmd_multi_init,
 184                           "Deprecated alias for ".
 185                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 186                           \%init_opts ],
 187         dcommit => [ \&cmd_dcommit,
 188                      'Commit several diffs to merge with upstream',
 189                         { 'merge|m|M' => \$_merge,
 190                           'strategy|s=s' => \$_strategy,
 191                           'verbose|v' => \$_verbose,
 192                           'dry-run|n' => \$_dry_run,
 193                           'fetch-all|all' => \$_fetch_all,
 194                           'commit-url=s' => \$_commit_url,
 195                           'revision|r=i' => \$_revision,
 196                           'no-rebase' => \$_no_rebase,
 197                           'mergeinfo=s' => \$_merge_info,
 198                           'interactive|i' => \$_interactive,
 199                         %cmt_opts, %fc_opts } ],
 200         branch => [ \&cmd_branch,
 201                     'Create a branch in the SVN repository',
 202                     { 'message|m=s' => \$_message,
 203                       'destination|d=s' => \$_branch_dest,
 204                       'dry-run|n' => \$_dry_run,
 205                       'tag|t' => \$_tag,
 206                       'username=s' => \$Git::SVN::Prompt::_username,
 207                       'commit-url=s' => \$_commit_url } ],
 208         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 209                  'Create a tag in the SVN repository',
 210                  { 'message|m=s' => \$_message,
 211                    'destination|d=s' => \$_branch_dest,
 212                    'dry-run|n' => \$_dry_run,
 213                    'username=s' => \$Git::SVN::Prompt::_username,
 214                    'commit-url=s' => \$_commit_url } ],
 215         'set-tree' => [ \&cmd_set_tree,
 216                         "Set an SVN repository to a git tree-ish",
 217                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 218         'create-ignore' => [ \&cmd_create_ignore,
 219                              'Create a .gitignore per svn:ignore',
 220                              { 'revision|r=i' => \$_revision
 221                              } ],
 222         'mkdirs' => [ \&cmd_mkdirs ,
 223                       "recreate empty directories after a checkout",
 224                       { 'revision|r=i' => \$_revision } ],
 225         'propget' => [ \&cmd_propget,
 226                        'Print the value of a property on a file or directory',
 227                        { 'revision|r=i' => \$_revision } ],
 228         'proplist' => [ \&cmd_proplist,
 229                        'List all properties of a file or directory',
 230                        { 'revision|r=i' => \$_revision } ],
 231         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 232                         { 'revision|r=i' => \$_revision
 233                         } ],
 234         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 235                         { 'revision|r=i' => \$_revision
 236                         } ],
 237         'multi-fetch' => [ \&cmd_multi_fetch,
 238                            "Deprecated alias for $0 fetch --all",
 239                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 240         'migrate' => [ sub { },
 241                        # no-op, we automatically run this anyways,
 242                        'Migrate configuration/metadata/layout from
 243                         previous versions of git-svn',
 244                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 245                          %remote_opts } ],
 246         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 247                         { 'limit=i' => \$Git::SVN::Log::limit,
 248                           'revision|r=s' => \$_revision,
 249                           'verbose|v' => \$Git::SVN::Log::verbose,
 250                           'incremental' => \$Git::SVN::Log::incremental,
 251                           'oneline' => \$Git::SVN::Log::oneline,
 252                           'show-commit' => \$Git::SVN::Log::show_commit,
 253                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 254                           'authors-file|A=s' => \$_authors,
 255                           'color' => \$Git::SVN::Log::color,
 256                           'pager=s' => \$Git::SVN::Log::pager
 257                         } ],
 258         'find-rev' => [ \&cmd_find_rev,
 259                         "Translate between SVN revision numbers and tree-ish",
 260                         { 'before' => \$_before,
 261                           'after' => \$_after } ],
 262         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 263                         { 'merge|m|M' => \$_merge,
 264                           'verbose|v' => \$_verbose,
 265                           'strategy|s=s' => \$_strategy,
 266                           'local|l' => \$_local,
 267                           'fetch-all|all' => \$_fetch_all,
 268                           'dry-run|n' => \$_dry_run,
 269                           'preserve-merges|p' => \$_preserve_merges,
 270                           %fc_opts } ],
 271         'commit-diff' => [ \&cmd_commit_diff,
 272                            'Commit a diff between two trees',
 273                         { 'message|m=s' => \$_message,
 274                           'file|F=s' => \$_file,
 275                           'revision|r=s' => \$_revision,
 276                         %cmt_opts } ],
 277         'info' => [ \&cmd_info,
 278                     "Show info about the latest SVN revision
 279                      on the current branch",
 280                     { 'url' => \$_url, } ],
 281         'blame' => [ \&Git::SVN::Log::cmd_blame,
 282                     "Show what revision and author last modified each line of a file",
 283                     { 'git-format' => \$Git::SVN::Log::_git_format } ],
 284         'reset' => [ \&cmd_reset,
 285                      "Undo fetches back to the specified SVN revision",
 286                      { 'revision|r=s' => \$_revision,
 287                        'parent|p' => \$_fetch_parent } ],
 288         'gc' => [ \&cmd_gc,
 289                   "Compress unhandled.log files in .git/svn and remove " .
 290                   "index files in .git/svn",
 291                 {} ],
 292 );
 293
 294 use Term::ReadLine;
 295 package FakeTerm;
 296 sub new {
 297         my ($class, $reason) = @_;
 298         return bless \$reason, shift;
 299 }
 300 sub readline {
 301         my $self = shift;
 302         die "Cannot use readline on FakeTerm: $$self";
 303 }
 304 package main;
 305
 306 my $term = eval {
 307         $ENV{"GIT_SVN_NOTTY"}
 308                 ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
 309                 : new Term::ReadLine 'git-svn';
 310 };
 311 if ($@) {
 312         $term = new FakeTerm "$@: going non-interactive";
 313 }
 314
 315 my $cmd;
 316 for (my $i = 0; $i < @ARGV; $i++) {
 317         if (defined $cmd{$ARGV[$i]}) {
 318                 $cmd = $ARGV[$i];
 319                 splice @ARGV, $i, 1;
 320                 last;
 321         } elsif ($ARGV[$i] eq 'help') {
 322                 $cmd = $ARGV[$i+1];
 323                 usage(0);
 324         }
 325 };
 326
 327 # make sure we're always running at the top-level working directory
 328 if ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 329         $ENV{GIT_DIR} ||= ".git";
 330 } else {
 331         my ($git_dir, $cdup);
 332         git_cmd_try {
 333                 $git_dir = command_oneline([qw/rev-parse --git-dir/]);
 334         } "Unable to find .git directory\n";
 335         git_cmd_try {
 336                 $cdup = command_oneline(qw/rev-parse --show-cdup/);
 337                 chomp $cdup if ($cdup);
 338                 $cdup = "." unless ($cdup && length $cdup);
 339         } "Already at toplevel, but $git_dir not found\n";
 340         $ENV{GIT_DIR} = $git_dir;
 341         chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 342         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 343 }
 344
 345 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 346
 347 read_git_config(\%opts);
 348 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 349         Getopt::Long::Configure('pass_through');
 350 }
 351 my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
 352                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 353                     'id|i=s' => \$Git::SVN::default_ref_id,
 354                     'svn-remote|remote|R=s' => sub {
 355                        $Git::SVN::no_reuse_existing = 1;
 356                        $Git::SVN::default_repo_id = $_[1] });
 357 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 358
 359 usage(0) if $_help;
 360 version() if $_version;
 361 usage(1) unless defined $cmd;
 362 load_authors() if $_authors;
 363 if (defined $_authors_prog) {
 364         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 365 }
 366
 367 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 368         Git::SVN::Migration::migration_check();
 369 }
 370 Git::SVN::init_vars();
 371 eval {
 372         Git::SVN::verify_remotes_sanity();
 373         $cmd{$cmd}->[0]->(@ARGV);
 374         post_fetch_checkout();
 375 };
 376 fatal $@ if $@;
 377 exit 0;
 378
 379 ####################### primary functions ######################
 380 sub usage {
 381         my $exit = shift || 0;
 382         my $fd = $exit ? \*STDERR : \*STDOUT;
 383         print $fd <<"";
 384 git-svn - bidirectional operations between a single Subversion tree and git
 385 usage: git svn <command> [options] [arguments]\n
 386
 387         print $fd "Available commands:\n" unless $cmd;
 388
 389         foreach (sort keys %cmd) {
 390                 next if $cmd && $cmd ne $_;
 391                 next if /^multi-/; # don't show deprecated commands
 392                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 393                 foreach (sort keys %{$cmd{$_}->[2]}) {
 394                         # mixed-case options are for .git/config only
 395                         next if /[A-Z]/ && /^[a-z]+$/i;
 396                         # prints out arguments as they should be passed:
 397                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 398                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 399                                                         "--$_" : "-$_" }
 400                                                 split /\|/,$_)," $x\n";
 401                 }
 402         }
 403         print $fd <<"";
 404 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 405 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 406 one git repository and want to keep them separate.  See git-svn(1) for more
 407 information.
 408
 409         exit $exit;
 410 }
 411
 412 sub version {
 413         ::_req_svn();
 414         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 415         exit 0;
 416 }
 417
 418 sub ask {
 419         my ($prompt, %arg) = @_;
 420         my $valid_re = $arg{valid_re};
 421         my $default = $arg{default};
 422         my $resp;
 423         my $i = 0;
 424
 425         if ( !( defined($term->IN)
 426             && defined( fileno($term->IN) )
 427             && defined( $term->OUT )
 428             && defined( fileno($term->OUT) ) ) ){
 429                 return defined($default) ? $default : undef;
 430         }
 431
 432         while ($i++ < 10) {
 433                 $resp = $term->readline($prompt);
 434                 if (!defined $resp) { # EOF
 435                         print "\n";
 436                         return defined $default ? $default : undef;
 437                 }
 438                 if ($resp eq '' and defined $default) {
 439                         return $default;
 440                 }
 441                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 442                         return $resp;
 443                 }
 444         }
 445         return undef;
 446 }
 447
 448 sub do_git_init_db {
 449         unless (-d $ENV{GIT_DIR}) {
 450                 my @init_db = ('init');
 451                 push @init_db, "--template=$_template" if defined $_template;
 452                 if (defined $_shared) {
 453                         if ($_shared =~ /[a-z]/) {
 454                                 push @init_db, "--shared=$_shared";
 455                         } else {
 456                                 push @init_db, "--shared";
 457                         }
 458                 }
 459                 command_noisy(@init_db);
 460                 $_repository = Git->repository(Repository => ".git");
 461         }
 462         my $set;
 463         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 464         foreach my $i (keys %icv) {
 465                 die "'$set' and '$i' cannot both be set\n" if $set;
 466                 next unless defined $icv{$i};
 467                 command_noisy('config', "$pfx.$i", $icv{$i});
 468                 $set = $i;
 469         }
 470         my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
 471         command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
 472                 if defined $$ignore_paths_regex;
 473         my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
 474         command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
 475                 if defined $$ignore_refs_regex;
 476
 477         if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
 478                 my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
 479                 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
 480                 command_noisy('config', "$pfx.placeholder-filename", $$fname);
 481         }
 482 }
 483
 484 sub init_subdir {
 485         my $repo_path = shift or return;
 486         mkpath([$repo_path]) unless -d $repo_path;
 487         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 488         $ENV{GIT_DIR} = '.git';
 489         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 490 }
 491
 492 sub cmd_clone {
 493         my ($url, $path) = @_;
 494         if (!defined $path &&
 495             (defined $_trunk || @_branches || @_tags ||
 496              defined $_stdlayout) &&
 497             $url !~ m#^[a-z\+]+://#) {
 498                 $path = $url;
 499         }
 500         $path = basename($url) if !defined $path || !length $path;
 501         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 502         cmd_init($url, $path);
 503         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 504             if $_authors;
 505         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 506 }
 507
 508 sub cmd_init {
 509         if (defined $_stdlayout) {
 510                 $_trunk = 'trunk' if (!defined $_trunk);
 511                 @_tags = 'tags' if (! @_tags);
 512                 @_branches = 'branches' if (! @_branches);
 513         }
 514         if (defined $_trunk || @_branches || @_tags) {
 515                 return cmd_multi_init(@_);
 516         }
 517         my $url = shift or die "SVN repository location required ",
 518                                "as a command-line argument\n";
 519         $url = canonicalize_url($url);
 520         init_subdir(@_);
 521         do_git_init_db();
 522
 523         if ($Git::SVN::_minimize_url eq 'unset') {
 524                 $Git::SVN::_minimize_url = 0;
 525         }
 526
 527         Git::SVN->init($url);
 528 }
 529
 530 sub cmd_fetch {
 531         if (grep /^\d+=./, @_) {
 532                 die "'<rev>=<commit>' fetch arguments are ",
 533                     "no longer supported.\n";
 534         }
 535         my ($remote) = @_;
 536         if (@_ > 1) {
 537                 die "usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 538         }
 539         $Git::SVN::no_reuse_existing = undef;
 540         if ($_fetch_parent) {
 541                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 542                 unless ($gs) {
 543                         die "Unable to determine upstream SVN information from ",
 544                             "working tree history\n";
 545                 }
 546                 # just fetch, don't checkout.
 547                 $_no_checkout = 'true';
 548                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 549         } elsif ($_fetch_all) {
 550                 cmd_multi_fetch();
 551         } else {
 552                 $remote ||= $Git::SVN::default_repo_id;
 553                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 554         }
 555 }
 556
 557 sub cmd_set_tree {
 558         my (@commits) = @_;
 559         if ($_stdin || !@commits) {
 560                 print "Reading from stdin...\n";
 561                 @commits = ();
 562                 while (<STDIN>) {
 563                         if (/\b($sha1_short)\b/o) {
 564                                 unshift @commits, $1;
 565                         }
 566                 }
 567         }
 568         my @revs;
 569         foreach my $c (@commits) {
 570                 my @tmp = command('rev-parse',$c);
 571                 if (scalar @tmp == 1) {
 572                         push @revs, $tmp[0];
 573                 } elsif (scalar @tmp > 1) {
 574                         push @revs, reverse(command('rev-list',@tmp));
 575                 } else {
 576                         fatal "Failed to rev-parse $c";
 577                 }
 578         }
 579         my $gs = Git::SVN->new;
 580         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 581         $gs->fetch;
 582         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 583                 fatal "There are new revisions that were fetched ",
 584                       "and need to be merged (or acknowledged) ",
 585                       "before committing.\nlast rev: $r_last\n",
 586                       " current: $gs->{last_rev}";
 587         }
 588         $gs->set_tree($_) foreach @revs;
 589         print "Done committing ",scalar @revs," revisions to SVN\n";
 590         unlink $gs->{index};
 591 }
 592
 593 sub split_merge_info_range {
 594         my ($range) = @_;
 595         if ($range =~ /(\d+)-(\d+)/) {
 596                 return (int($1), int($2));
 597         } else {
 598                 return (int($range), int($range));
 599         }
 600 }
 601
 602 sub combine_ranges {
 603         my ($in) = @_;
 604
 605         my @fnums = ();
 606         my @arr = split(/,/, $in);
 607         for my $element (@arr) {
 608                 my ($start, $end) = split_merge_info_range($element);
 609                 push @fnums, $start;
 610         }
 611
 612         my @sorted = @arr [ sort {
 613                 $fnums[$a] <=> $fnums[$b]
 614         } 0..$#arr ];
 615
 616         my @return = ();
 617         my $last = -1;
 618         my $first = -1;
 619         for my $element (@sorted) {
 620                 my ($start, $end) = split_merge_info_range($element);
 621
 622                 if ($last == -1) {
 623                         $first = $start;
 624                         $last = $end;
 625                         next;
 626                 }
 627                 if ($start <= $last+1) {
 628                         if ($end > $last) {
 629                                 $last = $end;
 630                         }
 631                         next;
 632                 }
 633                 if ($first == $last) {
 634                         push @return, "$first";
 635                 } else {
 636                         push @return, "$first-$last";
 637                 }
 638                 $first = $start;
 639                 $last = $end;
 640         }
 641
 642         if ($first != -1) {
 643                 if ($first == $last) {
 644                         push @return, "$first";
 645                 } else {
 646                         push @return, "$first-$last";
 647                 }
 648         }
 649
 650         return join(',', @return);
 651 }
 652
 653 sub merge_revs_into_hash {
 654         my ($hash, $minfo) = @_;
 655         my @lines = split(' ', $minfo);
 656
 657         for my $line (@lines) {
 658                 my ($branchpath, $revs) = split(/:/, $line);
 659
 660                 if (exists($hash->{$branchpath})) {
 661                         # Merge the two revision sets
 662                         my $combined = "$hash->{$branchpath},$revs";
 663                         $hash->{$branchpath} = combine_ranges($combined);
 664                 } else {
 665                         # Just do range combining for consolidation
 666                         $hash->{$branchpath} = combine_ranges($revs);
 667                 }
 668         }
 669 }
 670
 671 sub merge_merge_info {
 672         my ($mergeinfo_one, $mergeinfo_two, $ignore_branch) = @_;
 673         my %result_hash = ();
 674
 675         merge_revs_into_hash(\%result_hash, $mergeinfo_one);
 676         merge_revs_into_hash(\%result_hash, $mergeinfo_two);
 677
 678         delete $result_hash{$ignore_branch} if $ignore_branch;
 679
 680         my $result = '';
 681         # Sort below is for consistency's sake
 682         for my $branchname (sort keys(%result_hash)) {
 683                 my $revlist = $result_hash{$branchname};
 684                 $result .= "$branchname:$revlist\n"
 685         }
 686         return $result;
 687 }
 688
 689 sub populate_merge_info {
 690         my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
 691
 692         my %parentshash;
 693         read_commit_parents(\%parentshash, $d);
 694         my @parents = @{$parentshash{$d}};
 695         if ($#parents > 0) {
 696                 # Merge commit
 697                 my $all_parents_ok = 1;
 698                 my $aggregate_mergeinfo = '';
 699                 my $rooturl = $gs->repos_root;
 700                 my ($target_branch) = $gs->full_pushurl =~ /^\Q$rooturl\E(.*)/;
 701
 702                 if (defined($rewritten_parent)) {
 703                         # Replace first parent with newly-rewritten version
 704                         shift @parents;
 705                         unshift @parents, $rewritten_parent;
 706                 }
 707
 708                 foreach my $parent (@parents) {
 709                         my ($branchurl, $svnrev, $paruuid) =
 710                                 cmt_metadata($parent);
 711
 712                         unless (defined($svnrev)) {
 713                                 # Should have been caught be preflight check
 714                                 fatal "merge commit $d has ancestor $parent, but that change "
 715                      ."does not have git-svn metadata!";
 716                         }
 717                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 718                                 fatal "commit $parent git-svn metadata changed mid-run!";
 719                         }
 720                         my $branchpath = $1;
 721
 722                         my $ra = Git::SVN::Ra->new($branchurl);
 723                         my (undef, undef, $props) =
 724                                 $ra->get_dir(canonicalize_path("."), $svnrev);
 725                         my $par_mergeinfo = $props->{'svn:mergeinfo'};
 726                         unless (defined $par_mergeinfo) {
 727                                 $par_mergeinfo = '';
 728                         }
 729                         # Merge previous mergeinfo values
 730                         $aggregate_mergeinfo =
 731                                 merge_merge_info($aggregate_mergeinfo,
 732                                                                 $par_mergeinfo,
 733                                                                 $target_branch);
 734
 735                         next if $parent eq $parents[0]; # Skip first parent
 736                         # Add new changes being placed in tree by merge
 737                         my @cmd = (qw/rev-list --reverse/,
 738                                            $parent, qw/--not/);
 739                         foreach my $par (@parents) {
 740                                 unless ($par eq $parent) {
 741                                         push @cmd, $par;
 742                                 }
 743                         }
 744                         my @revsin = ();
 745                         my ($revlist, $ctx) = command_output_pipe(@cmd);
 746                         while (<$revlist>) {
 747                                 my $irev = $_;
 748                                 chomp $irev;
 749                                 my (undef, $csvnrev, undef) =
 750                                         cmt_metadata($irev);
 751                                 unless (defined $csvnrev) {
 752                                         # A child is missing SVN annotations...
 753                                         # this might be OK, or might not be.
 754                                         warn "W:child $irev is merged into revision "
 755                                                  ."$d but does not have git-svn metadata. "
 756                                                  ."This means git-svn cannot determine the "
 757                                                  ."svn revision numbers to place into the "
 758                                                  ."svn:mergeinfo property. You must ensure "
 759                                                  ."a branch is entirely committed to "
 760                                                  ."SVN before merging it in order for "
 761                                                  ."svn:mergeinfo population to function "
 762                                                  ."properly";
 763                                 }
 764                                 push @revsin, $csvnrev;
 765                         }
 766                         command_close_pipe($revlist, $ctx);
 767
 768                         last unless $all_parents_ok;
 769
 770                         # We now have a list of all SVN revnos which are
 771                         # merged by this particular parent. Integrate them.
 772                         next if $#revsin == -1;
 773                         my $newmergeinfo = "$branchpath:" . join(',', @revsin);
 774                         $aggregate_mergeinfo =
 775                                 merge_merge_info($aggregate_mergeinfo,
 776                                                                 $newmergeinfo,
 777                                                                 $target_branch);
 778                 }
 779                 if ($all_parents_ok and $aggregate_mergeinfo) {
 780                         return $aggregate_mergeinfo;
 781                 }
 782         }
 783
 784         return undef;
 785 }
 786
 787 sub dcommit_rebase {
 788         my ($is_last, $current, $fetched_ref, $svn_error) = @_;
 789         my @diff;
 790
 791         if ($svn_error) {
 792                 print STDERR "\nERROR from SVN:\n",
 793                                 $svn_error->expanded_message, "\n";
 794         }
 795         unless ($_no_rebase) {
 796                 # we always want to rebase against the current HEAD,
 797                 # not any head that was passed to us
 798                 @diff = command('diff-tree', $current,
 799                            $fetched_ref, '--');
 800                 my @finish;
 801                 if (@diff) {
 802                         @finish = rebase_cmd();
 803                         print STDERR "W: $current and ", $fetched_ref,
 804                                      " differ, using @finish:\n",
 805                                      join("\n", @diff), "\n";
 806                 } elsif ($is_last) {
 807                         print "No changes between ", $current, " and ",
 808                               $fetched_ref,
 809                               "\nResetting to the latest ",
 810                               $fetched_ref, "\n";
 811                         @finish = qw/reset --mixed/;
 812                 }
 813                 command_noisy(@finish, $fetched_ref) if @finish;
 814         }
 815         if ($svn_error) {
 816                 die "ERROR: Not all changes have been committed into SVN"
 817                         .($_no_rebase ? ".\n" : ", however the committed\n"
 818                         ."ones (if any) seem to be successfully integrated "
 819                         ."into the working tree.\n")
 820                         ."Please see the above messages for details.\n";
 821         }
 822         return @diff;
 823 }
 824
 825 sub cmd_dcommit {
 826         my $head = shift;
 827         command_noisy(qw/update-index --refresh/);
 828         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 829                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 830                 . "or stash them with `git stash'.\n";
 831         $head ||= 'HEAD';
 832
 833         my $old_head;
 834         if ($head ne 'HEAD') {
 835                 $old_head = eval {
 836                         command_oneline([qw/symbolic-ref -q HEAD/])
 837                 };
 838                 if ($old_head) {
 839                         $old_head =~ s{^refs/heads/}{};
 840                 } else {
 841                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 842                 }
 843                 command(['checkout', $head], STDERR => 0);
 844         }
 845
 846         my @refs;
 847         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 848         unless ($gs) {
 849                 die "Unable to determine upstream SVN information from ",
 850                     "$head history.\nPerhaps the repository is empty.";
 851         }
 852
 853         if (defined $_commit_url) {
 854                 $url = $_commit_url;
 855         } else {
 856                 $url = eval { command_oneline('config', '--get',
 857                               "svn-remote.$gs->{repo_id}.commiturl") };
 858                 if (!$url) {
 859                         $url = $gs->full_pushurl
 860                 }
 861         }
 862
 863         my $last_rev = $_revision if defined $_revision;
 864         if ($url) {
 865                 print "Committing to $url ...\n";
 866         }
 867         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 868         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 869                 warn "Attempting to commit more than one change while ",
 870                      "--no-rebase is enabled.\n",
 871                      "If these changes depend on each other, re-running ",
 872                      "without --no-rebase may be required."
 873         }
 874
 875         if (defined $_interactive){
 876                 my $ask_default = "y";
 877                 foreach my $d (@$linear_refs){
 878                         my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
 879                         while (<$fh>){
 880                                 print $_;
 881                         }
 882                         command_close_pipe($fh, $ctx);
 883                         $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
 884                                  valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 885                                  default => $ask_default);
 886                         die "Commit this patch reply required" unless defined $_;
 887                         if (/^[nq]/i) {
 888                                 exit(0);
 889                         } elsif (/^a/i) {
 890                                 last;
 891                         }
 892                 }
 893         }
 894
 895         my $expect_url = $url;
 896
 897         my $push_merge_info = eval {
 898                 command_oneline(qw/config --get svn.pushmergeinfo/)
 899                 };
 900         if (not defined($push_merge_info)
 901                         or $push_merge_info eq "false"
 902                         or $push_merge_info eq "no"
 903                         or $push_merge_info eq "never") {
 904                 $push_merge_info = 0;
 905         }
 906
 907         unless (defined($_merge_info) || ! $push_merge_info) {
 908                 # Preflight check of changes to ensure no issues with mergeinfo
 909                 # This includes check for uncommitted-to-SVN parents
 910                 # (other than the first parent, which we will handle),
 911                 # information from different SVN repos, and paths
 912                 # which are not underneath this repository root.
 913                 my $rooturl = $gs->repos_root;
 914                 foreach my $d (@$linear_refs) {
 915                         my %parentshash;
 916                         read_commit_parents(\%parentshash, $d);
 917                         my @realparents = @{$parentshash{$d}};
 918                         if ($#realparents > 0) {
 919                                 # Merge commit
 920                                 shift @realparents; # Remove/ignore first parent
 921                                 foreach my $parent (@realparents) {
 922                                         my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
 923                                         unless (defined $paruuid) {
 924                                                 # A parent is missing SVN annotations...
 925                                                 # abort the whole operation.
 926                                                 fatal "$parent is merged into revision $d, "
 927                                                          ."but does not have git-svn metadata. "
 928                                                          ."Either dcommit the branch or use a "
 929                                                          ."local cherry-pick, FF merge, or rebase "
 930                                                          ."instead of an explicit merge commit.";
 931                                         }
 932
 933                                         unless ($paruuid eq $uuid) {
 934                                                 # Parent has SVN metadata from different repository
 935                                                 fatal "merge parent $parent for change $d has "
 936                                                          ."git-svn uuid $paruuid, while current change "
 937                                                          ."has uuid $uuid!";
 938                                         }
 939
 940                                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 941                                                 # This branch is very strange indeed.
 942                                                 fatal "merge parent $parent for $d is on branch "
 943                                                          ."$branchurl, which is not under the "
 944                                                          ."git-svn root $rooturl!";
 945                                         }
 946                                 }
 947                         }
 948                 }
 949         }
 950
 951         my $rewritten_parent;
 952         my $current_head = command_oneline(qw/rev-parse HEAD/);
 953         Git::SVN::remove_username($expect_url);
 954         if (defined($_merge_info)) {
 955                 $_merge_info =~ tr{ }{\n};
 956         }
 957         while (1) {
 958                 my $d = shift @$linear_refs or last;
 959                 unless (defined $last_rev) {
 960                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 961                         unless (defined $last_rev) {
 962                                 fatal "Unable to extract revision information ",
 963                                       "from commit $d~1";
 964                         }
 965                 }
 966                 if ($_dry_run) {
 967                         print "diff-tree $d~1 $d\n";
 968                 } else {
 969                         my $cmt_rev;
 970
 971                         unless (defined($_merge_info) || ! $push_merge_info) {
 972                                 $_merge_info = populate_merge_info($d, $gs,
 973                                                              $uuid,
 974                                                              $linear_refs,
 975                                                              $rewritten_parent);
 976                         }
 977
 978                         my %ed_opts = ( r => $last_rev,
 979                                         log => get_commit_entry($d)->{log},
 980                                         ra => Git::SVN::Ra->new($url),
 981                                         config => SVN::Core::config_get_config(
 982                                                 $Git::SVN::Ra::config_dir
 983                                         ),
 984                                         tree_a => "$d~1",
 985                                         tree_b => $d,
 986                                         editor_cb => sub {
 987                                                print "Committed r$_[0]\n";
 988                                                $cmt_rev = $_[0];
 989                                         },
 990                                         mergeinfo => $_merge_info,
 991                                         svn_path => '');
 992
 993                         my $err_handler = $SVN::Error::handler;
 994                         $SVN::Error::handler = sub {
 995                                 my $err = shift;
 996                                 dcommit_rebase(1, $current_head, $gs->refname,
 997                                         $err);
 998                         };
 999
1000                         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1001                                 print "No changes\n$d~1 == $d\n";
1002                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
1003                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
1004                                                                $parents->{$d};
1005                         }
1006                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
1007                         $SVN::Error::handler = $err_handler;
1008                         $last_rev = $cmt_rev;
1009                         next if $_no_rebase;
1010
1011                         my @diff = dcommit_rebase(@$linear_refs == 0, $d,
1012                                                 $gs->refname, undef);
1013
1014                         $rewritten_parent = command_oneline(qw/rev-parse/,
1015                                                         $gs->refname);
1016
1017                         if (@diff) {
1018                                 $current_head = command_oneline(qw/rev-parse
1019                                                                 HEAD/);
1020                                 @refs = ();
1021                                 my ($url_, $rev_, $uuid_, $gs_) =
1022                                               working_head_info('HEAD', \@refs);
1023                                 my ($linear_refs_, $parents_) =
1024                                               linearize_history($gs_, \@refs);
1025                                 if (scalar(@$linear_refs) !=
1026                                     scalar(@$linear_refs_)) {
1027                                         fatal "# of revisions changed ",
1028                                           "\nbefore:\n",
1029                                           join("\n", @$linear_refs),
1030                                           "\n\nafter:\n",
1031                                           join("\n", @$linear_refs_), "\n",
1032                                           'If you are attempting to commit ',
1033                                           "merges, try running:\n\t",
1034                                           'git rebase --interactive',
1035                                           '--preserve-merges ',
1036                                           $gs->refname,
1037                                           "\nBefore dcommitting";
1038                                 }
1039                                 if ($url_ ne $expect_url) {
1040                                         if ($url_ eq $gs->metadata_url) {
1041                                                 print
1042                                                   "Accepting rewritten URL:",
1043                                                   " $url_\n";
1044                                         } else {
1045                                                 fatal
1046                                                   "URL mismatch after rebase:",
1047                                                   " $url_ != $expect_url";
1048                                         }
1049                                 }
1050                                 if ($uuid_ ne $uuid) {
1051                                         fatal "uuid mismatch after rebase: ",
1052                                               "$uuid_ != $uuid";
1053                                 }
1054                                 # remap parents
1055                                 my (%p, @l, $i);
1056                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
1057                                         my $new = $linear_refs_->[$i] or next;
1058                                         $p{$new} =
1059                                                 $parents->{$linear_refs->[$i]};
1060                                         push @l, $new;
1061                                 }
1062                                 $parents = \%p;
1063                                 $linear_refs = \@l;
1064                                 undef $last_rev;
1065                         }
1066                 }
1067         }
1068
1069         if ($old_head) {
1070                 my $new_head = command_oneline(qw/rev-parse HEAD/);
1071                 my $new_is_symbolic = eval {
1072                         command_oneline(qw/symbolic-ref -q HEAD/);
1073                 };
1074                 if ($new_is_symbolic) {
1075                         print "dcommitted the branch ", $head, "\n";
1076                 } else {
1077                         print "dcommitted on a detached HEAD because you gave ",
1078                               "a revision argument.\n",
1079                               "The rewritten commit is: ", $new_head, "\n";
1080                 }
1081                 command(['checkout', $old_head], STDERR => 0);
1082         }
1083
1084         unlink $gs->{index};
1085 }
1086
1087 sub cmd_branch {
1088         my ($branch_name, $head) = @_;
1089
1090         unless (defined $branch_name && length $branch_name) {
1091                 die(($_tag ? "tag" : "branch") . " name required\n");
1092         }
1093         $head ||= 'HEAD';
1094
1095         my (undef, $rev, undef, $gs) = working_head_info($head);
1096         my $src = $gs->full_pushurl;
1097
1098         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1099         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1100         my $glob;
1101         if ($#{$allglobs} == 0) {
1102                 $glob = $allglobs->[0];
1103         } else {
1104                 unless(defined $_branch_dest) {
1105                         die "Multiple ",
1106                             $_tag ? "tag" : "branch",
1107                             " paths defined for Subversion repository.\n",
1108                             "You must specify where you want to create the ",
1109                             $_tag ? "tag" : "branch",
1110                             " with the --destination argument.\n";
1111                 }
1112                 foreach my $g (@{$allglobs}) {
1113                         my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1114                         if ($_branch_dest =~ /$re/) {
1115                                 $glob = $g;
1116                                 last;
1117                         }
1118                 }
1119                 unless (defined $glob) {
1120                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1121                         foreach my $g (@{$allglobs}) {
1122                                 $g->{path}->{left} =~ /$dest_re/ or next;
1123                                 if (defined $glob) {
1124                                         die "Ambiguous destination: ",
1125                                             $_branch_dest, "\nmatches both '",
1126                                             $glob->{path}->{left}, "' and '",
1127                                             $g->{path}->{left}, "'\n";
1128                                 }
1129                                 $glob = $g;
1130                         }
1131                         unless (defined $glob) {
1132                                 die "Unknown ",
1133                                     $_tag ? "tag" : "branch",
1134                                     " destination $_branch_dest\n";
1135                         }
1136                 }
1137         }
1138         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1139         my $url;
1140         if (defined $_commit_url) {
1141                 $url = $_commit_url;
1142         } else {
1143                 $url = eval { command_oneline('config', '--get',
1144                         "svn-remote.$gs->{repo_id}.commiturl") };
1145                 if (!$url) {
1146                         $url = $remote->{pushurl} || $remote->{url};
1147                 }
1148         }
1149         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1150
1151         if ($dst =~ /^https:/ && $src =~ /^http:/) {
1152                 $src=~s/^http:/https:/;
1153         }
1154
1155         ::_req_svn();
1156
1157         my $ctx = SVN::Client->new(
1158                 auth    => Git::SVN::Ra::_auth_providers(),
1159                 log_msg => sub {
1160                         ${ $_[0] } = defined $_message
1161                                 ? $_message
1162                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1163                                 . $branch_name;
1164                 },
1165         );
1166
1167         eval {
1168                 $ctx->ls($dst, 'HEAD', 0);
1169         } and die "branch ${branch_name} already exists\n";
1170
1171         print "Copying ${src} at r${rev} to ${dst}...\n";
1172         $ctx->copy($src, $rev, $dst)
1173                 unless $_dry_run;
1174
1175         $gs->fetch_all;
1176 }
1177
1178 sub cmd_find_rev {
1179         my $revision_or_hash = shift or die "SVN or git revision required ",
1180                                             "as a command-line argument\n";
1181         my $result;
1182         if ($revision_or_hash =~ /^r\d+$/) {
1183                 my $head = shift;
1184                 $head ||= 'HEAD';
1185                 my @refs;
1186                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1187                 unless ($gs) {
1188                         die "Unable to determine upstream SVN information from ",
1189                             "$head history\n";
1190                 }
1191                 my $desired_revision = substr($revision_or_hash, 1);
1192                 if ($_before) {
1193                         $result = $gs->find_rev_before($desired_revision, 1);
1194                 } elsif ($_after) {
1195                         $result = $gs->find_rev_after($desired_revision, 1);
1196                 } else {
1197                         $result = $gs->rev_map_get($desired_revision, $uuid);
1198                 }
1199         } else {
1200                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1201                 $result = $rev;
1202         }
1203         print "$result\n" if $result;
1204 }
1205
1206 sub auto_create_empty_directories {
1207         my ($gs) = @_;
1208         my $var = eval { command_oneline('config', '--get', '--bool',
1209                                          "svn-remote.$gs->{repo_id}.automkdirs") };
1210         # By default, create empty directories by consulting the unhandled log,
1211         # but allow setting it to 'false' to skip it.
1212         return !($var && $var eq 'false');
1213 }
1214
1215 sub cmd_rebase {
1216         command_noisy(qw/update-index --refresh/);
1217         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1218         unless ($gs) {
1219                 die "Unable to determine upstream SVN information from ",
1220                     "working tree history\n";
1221         }
1222         if ($_dry_run) {
1223                 print "Remote Branch: " . $gs->refname . "\n";
1224                 print "SVN URL: " . $url . "\n";
1225                 return;
1226         }
1227         if (command(qw/diff-index HEAD --/)) {
1228                 print STDERR "Cannot rebase with uncommited changes:\n";
1229                 command_noisy('status');
1230                 exit 1;
1231         }
1232         unless ($_local) {
1233                 # rebase will checkout for us, so no need to do it explicitly
1234                 $_no_checkout = 'true';
1235                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1236         }
1237         command_noisy(rebase_cmd(), $gs->refname);
1238         if (auto_create_empty_directories($gs)) {
1239                 $gs->mkemptydirs;
1240         }
1241 }
1242
1243 sub cmd_show_ignore {
1244         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1245         $gs ||= Git::SVN->new;
1246         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1247         $gs->prop_walk($gs->path, $r, sub {
1248                 my ($gs, $path, $props) = @_;
1249                 print STDOUT "\n# $path\n";
1250                 my $s = $props->{'svn:ignore'} or return;
1251                 $s =~ s/[\r\n]+/\n/g;
1252                 $s =~ s/^\n+//;
1253                 chomp $s;
1254                 $s =~ s#^#$path#gm;
1255                 print STDOUT "$s\n";
1256         });
1257 }
1258
1259 sub cmd_show_externals {
1260         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1261         $gs ||= Git::SVN->new;
1262         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1263         $gs->prop_walk($gs->path, $r, sub {
1264                 my ($gs, $path, $props) = @_;
1265                 print STDOUT "\n# $path\n";
1266                 my $s = $props->{'svn:externals'} or return;
1267                 $s =~ s/[\r\n]+/\n/g;
1268                 chomp $s;
1269                 $s =~ s#^#$path#gm;
1270                 print STDOUT "$s\n";
1271         });
1272 }
1273
1274 sub cmd_create_ignore {
1275         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1276         $gs ||= Git::SVN->new;
1277         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1278         $gs->prop_walk($gs->path, $r, sub {
1279                 my ($gs, $path, $props) = @_;
1280                 # $path is of the form /path/to/dir/
1281                 $path = '.' . $path;
1282                 # SVN can have attributes on empty directories,
1283                 # which git won't track
1284                 mkpath([$path]) unless -d $path;
1285                 my $ignore = $path . '.gitignore';
1286                 my $s = $props->{'svn:ignore'} or return;
1287                 open(GITIGNORE, '>', $ignore)
1288                   or fatal("Failed to open `$ignore' for writing: $!");
1289                 $s =~ s/[\r\n]+/\n/g;
1290                 $s =~ s/^\n+//;
1291                 chomp $s;
1292                 # Prefix all patterns so that the ignore doesn't apply
1293                 # to sub-directories.
1294                 $s =~ s#^#/#gm;
1295                 print GITIGNORE "$s\n";
1296                 close(GITIGNORE)
1297                   or fatal("Failed to close `$ignore': $!");
1298                 command_noisy('add', '-f', $ignore);
1299         });
1300 }
1301
1302 sub cmd_mkdirs {
1303         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1304         $gs ||= Git::SVN->new;
1305         $gs->mkemptydirs($_revision);
1306 }
1307
1308 # get_svnprops(PATH)
1309 # ------------------
1310 # Helper for cmd_propget and cmd_proplist below.
1311 sub get_svnprops {
1312         my $path = shift;
1313         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1314         $gs ||= Git::SVN->new;
1315
1316         # prefix THE PATH by the sub-directory from which the user
1317         # invoked us.
1318         $path = $cmd_dir_prefix . $path;
1319         fatal("No such file or directory: $path") unless -e $path;
1320         my $is_dir = -d $path ? 1 : 0;
1321         $path = join_paths($gs->path, $path);
1322
1323         # canonicalize the path (otherwise libsvn will abort or fail to
1324         # find the file)
1325         $path = canonicalize_path($path);
1326
1327         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1328         my $props;
1329         if ($is_dir) {
1330                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1331         }
1332         else {
1333                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1334         }
1335         return $props;
1336 }
1337
1338 # cmd_propget (PROP, PATH)
1339 # ------------------------
1340 # Print the SVN property PROP for PATH.
1341 sub cmd_propget {
1342         my ($prop, $path) = @_;
1343         $path = '.' if not defined $path;
1344         usage(1) if not defined $prop;
1345         my $props = get_svnprops($path);
1346         if (not defined $props->{$prop}) {
1347                 fatal("`$path' does not have a `$prop' SVN property.");
1348         }
1349         print $props->{$prop} . "\n";
1350 }
1351
1352 # cmd_proplist (PATH)
1353 # -------------------
1354 # Print the list of SVN properties for PATH.
1355 sub cmd_proplist {
1356         my $path = shift;
1357         $path = '.' if not defined $path;
1358         my $props = get_svnprops($path);
1359         print "Properties on '$path':\n";
1360         foreach (sort keys %{$props}) {
1361                 print "  $_\n";
1362         }
1363 }
1364
1365 sub cmd_multi_init {
1366         my $url = shift;
1367         unless (defined $_trunk || @_branches || @_tags) {
1368                 usage(1);
1369         }
1370
1371         $_prefix = '' unless defined $_prefix;
1372         if (defined $url) {
1373                 $url = canonicalize_url($url);
1374                 init_subdir(@_);
1375         }
1376         do_git_init_db();
1377         if (defined $_trunk) {
1378                 $_trunk =~ s#^/+##;
1379                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1380                 # try both old-style and new-style lookups:
1381                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1382                 unless ($gs_trunk) {
1383                         my ($trunk_url, $trunk_path) =
1384                                               complete_svn_url($url, $_trunk);
1385                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1386                                                    undef, $trunk_ref);
1387                 }
1388         }
1389         return unless @_branches || @_tags;
1390         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1391         foreach my $path (@_branches) {
1392                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1393         }
1394         foreach my $path (@_tags) {
1395                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1396         }
1397 }
1398
1399 sub cmd_multi_fetch {
1400         $Git::SVN::no_reuse_existing = undef;
1401         my $remotes = Git::SVN::read_all_remotes();
1402         foreach my $repo_id (sort keys %$remotes) {
1403                 if ($remotes->{$repo_id}->{url}) {
1404                         Git::SVN::fetch_all($repo_id, $remotes);
1405                 }
1406         }
1407 }
1408
1409 # this command is special because it requires no metadata
1410 sub cmd_commit_diff {
1411         my ($ta, $tb, $url) = @_;
1412         my $usage = "usage: $0 commit-diff -r<revision> ".
1413                     "<tree-ish> <tree-ish> [<URL>]";
1414         fatal($usage) if (!defined $ta || !defined $tb);
1415         my $svn_path = '';
1416         if (!defined $url) {
1417                 my $gs = eval { Git::SVN->new };
1418                 if (!$gs) {
1419                         fatal("Needed URL or usable git-svn --id in ",
1420                               "the command-line\n", $usage);
1421                 }
1422                 $url = $gs->url;
1423                 $svn_path = $gs->path;
1424         }
1425         unless (defined $_revision) {
1426                 fatal("-r|--revision is a required argument\n", $usage);
1427         }
1428         if (defined $_message && defined $_file) {
1429                 fatal("Both --message/-m and --file/-F specified ",
1430                       "for the commit message.\n",
1431                       "I have no idea what you mean");
1432         }
1433         if (defined $_file) {
1434                 $_message = file_to_s($_file);
1435         } else {
1436                 $_message ||= get_commit_entry($tb)->{log};
1437         }
1438         my $ra ||= Git::SVN::Ra->new($url);
1439         my $r = $_revision;
1440         if ($r eq 'HEAD') {
1441                 $r = $ra->get_latest_revnum;
1442         } elsif ($r !~ /^\d+$/) {
1443                 die "revision argument: $r not understood by git-svn\n";
1444         }
1445         my %ed_opts = ( r => $r,
1446                         log => $_message,
1447                         ra => $ra,
1448                         tree_a => $ta,
1449                         tree_b => $tb,
1450                         editor_cb => sub { print "Committed r$_[0]\n" },
1451                         svn_path => $svn_path );
1452         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1453                 print "No changes\n$ta == $tb\n";
1454         }
1455 }
1456
1457
1458 sub cmd_info {
1459         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1460         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1461         if (exists $_[1]) {
1462                 die "Too many arguments specified\n";
1463         }
1464
1465         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1466
1467         if (!$file_type && !$diff_status) {
1468                 print STDERR "svn: '$path' is not under version control\n";
1469                 exit 1;
1470         }
1471
1472         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1473         unless ($gs) {
1474                 die "Unable to determine upstream SVN information from ",
1475                     "working tree history\n";
1476         }
1477
1478         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1479         $path = "." if $path eq "";
1480
1481         my $full_url = canonicalize_url( add_path_to_url( $url, $fullpath ) );
1482
1483         if ($_url) {
1484                 print "$full_url\n";
1485                 return;
1486         }
1487
1488         my $result = "Path: $path\n";
1489         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1490         $result .= "URL: $full_url\n";
1491
1492         eval {
1493                 my $repos_root = $gs->repos_root;
1494                 Git::SVN::remove_username($repos_root);
1495                 $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n";
1496         };
1497         if ($@) {
1498                 $result .= "Repository Root: (offline)\n";
1499         }
1500         ::_req_svn();
1501         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1502                 (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1503         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1504
1505         $result .= "Node Kind: " .
1506                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1507
1508         my $schedule = $diff_status eq "A"
1509                        ? "add"
1510                        : ($diff_status eq "D" ? "delete" : "normal");
1511         $result .= "Schedule: $schedule\n";
1512
1513         if ($diff_status eq "A") {
1514                 print $result, "\n";
1515                 return;
1516         }
1517
1518         my ($lc_author, $lc_rev, $lc_date_utc);
1519         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1520         my $log = command_output_pipe(@args);
1521         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1522         while (<$log>) {
1523                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1524                         $lc_author = $1;
1525                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1526                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1527                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1528                 }
1529         }
1530         close $log;
1531
1532         Git::SVN::Log::set_local_timezone();
1533
1534         $result .= "Last Changed Author: $lc_author\n";
1535         $result .= "Last Changed Rev: $lc_rev\n";
1536         $result .= "Last Changed Date: " .
1537                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1538
1539         if ($file_type ne "dir") {
1540                 my $text_last_updated_date =
1541                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1542                 $result .=
1543                     "Text Last Updated: " .
1544                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1545                     "\n";
1546                 my $checksum;
1547                 if ($diff_status eq "D") {
1548                         my ($fh, $ctx) =
1549                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1550                         if ($file_type eq "link") {
1551                                 my $file_name = <$fh>;
1552                                 $checksum = md5sum("link $file_name");
1553                         } else {
1554                                 $checksum = md5sum($fh);
1555                         }
1556                         command_close_pipe($fh, $ctx);
1557                 } elsif ($file_type eq "link") {
1558                         my $file_name =
1559                             command(qw(cat-file blob), "HEAD:$path");
1560                         $checksum =
1561                             md5sum("link " . $file_name);
1562                 } else {
1563                         open FILE, "<", $path or die $!;
1564                         $checksum = md5sum(\*FILE);
1565                         close FILE or die $!;
1566                 }
1567                 $result .= "Checksum: " . $checksum . "\n";
1568         }
1569
1570         print $result, "\n";
1571 }
1572
1573 sub cmd_reset {
1574         my $target = shift || $_revision or die "SVN revision required\n";
1575         $target = $1 if $target =~ /^r(\d+)$/;
1576         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1577         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1578         unless ($gs) {
1579                 die "Unable to determine upstream SVN information from ".
1580                     "history\n";
1581         }
1582         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1583         die "Cannot find SVN revision $target\n" unless defined($c);
1584         $gs->rev_map_set($r, $c, 'reset', $uuid);
1585         print "r$r = $c ($gs->{ref_id})\n";
1586 }
1587
1588 sub cmd_gc {
1589         if (!can_compress()) {
1590                 warn "Compress::Zlib could not be found; unhandled.log " .
1591                      "files will not be compressed.\n";
1592         }
1593         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1594 }
1595
1596 ########################### utility functions #########################
1597
1598 sub rebase_cmd {
1599         my @cmd = qw/rebase/;
1600         push @cmd, '-v' if $_verbose;
1601         push @cmd, qw/--merge/ if $_merge;
1602         push @cmd, "--strategy=$_strategy" if $_strategy;
1603         push @cmd, "--preserve-merges" if $_preserve_merges;
1604         @cmd;
1605 }
1606
1607 sub post_fetch_checkout {
1608         return if $_no_checkout;
1609         return if verify_ref('HEAD^0');
1610         my $gs = $Git::SVN::_head or return;
1611
1612         # look for "trunk" ref if it exists
1613         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1614         my $fetch = $remote->{fetch};
1615         if ($fetch) {
1616                 foreach my $p (keys %$fetch) {
1617                         basename($fetch->{$p}) eq 'trunk' or next;
1618                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1619                         last;
1620                 }
1621         }
1622
1623         command_noisy(qw(update-ref HEAD), $gs->refname);
1624         return unless verify_ref('HEAD^0');
1625
1626         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1627         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1628         return if -f $index;
1629
1630         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1631         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1632         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1633         print STDERR "Checked out HEAD:\n  ",
1634                      $gs->full_url, " r", $gs->last_rev, "\n";
1635         if (auto_create_empty_directories($gs)) {
1636                 $gs->mkemptydirs($gs->last_rev);
1637         }
1638 }
1639
1640 sub complete_svn_url {
1641         my ($url, $path) = @_;
1642         $path = canonicalize_path($path);
1643
1644         # If the path is not a URL...
1645         if ($path !~ m#^[a-z\+]+://#) {
1646                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1647                         fatal("E: '$path' is not a complete URL ",
1648                               "and a separate URL is not specified");
1649                 }
1650                 return ($url, $path);
1651         }
1652         return ($path, '');
1653 }
1654
1655 sub complete_url_ls_init {
1656         my ($ra, $repo_path, $switch, $pfx) = @_;
1657         unless ($repo_path) {
1658                 print STDERR "W: $switch not specified\n";
1659                 return;
1660         }
1661         $repo_path = canonicalize_path($repo_path);
1662         if ($repo_path =~ m#^[a-z\+]+://#) {
1663                 $ra = Git::SVN::Ra->new($repo_path);
1664                 $repo_path = '';
1665         } else {
1666                 $repo_path =~ s#^/+##;
1667                 unless ($ra) {
1668                         fatal("E: '$repo_path' is not a complete URL ",
1669                               "and a separate URL is not specified");
1670                 }
1671         }
1672         my $url = $ra->url;
1673         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1674         my $k = "svn-remote.$gs->{repo_id}.url";
1675         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1676         if ($orig_url && ($orig_url ne $gs->url)) {
1677                 die "$k already set: $orig_url\n",
1678                     "wanted to set to: $gs->url\n";
1679         }
1680         command_oneline('config', $k, $gs->url) unless $orig_url;
1681
1682         my $remote_path = join_paths( $gs->path, $repo_path );
1683         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1684         $remote_path =~ s#^/##g;
1685         $remote_path .= "/*" if $remote_path !~ /\*/;
1686         my ($n) = ($switch =~ /^--(\w+)/);
1687         if (length $pfx && $pfx !~ m#/$#) {
1688                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1689         }
1690         command_noisy('config',
1691                       '--add',
1692                       "svn-remote.$gs->{repo_id}.$n",
1693                       "$remote_path:refs/remotes/$pfx*" .
1694                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1695 }
1696
1697 sub verify_ref {
1698         my ($ref) = @_;
1699         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1700                                { STDERR => 0 }); };
1701 }
1702
1703 sub get_tree_from_treeish {
1704         my ($treeish) = @_;
1705         # $treeish can be a symbolic ref, too:
1706         my $type = command_oneline(qw/cat-file -t/, $treeish);
1707         my $expected;
1708         while ($type eq 'tag') {
1709                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1710         }
1711         if ($type eq 'commit') {
1712                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1713                                                     $treeish))[0];
1714                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1715                 die "Unable to get tree from $treeish\n" unless $expected;
1716         } elsif ($type eq 'tree') {
1717                 $expected = $treeish;
1718         } else {
1719                 die "$treeish is a $type, expected tree, tag or commit\n";
1720         }
1721         return $expected;
1722 }
1723
1724 sub get_commit_entry {
1725         my ($treeish) = shift;
1726         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1727         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1728         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1729         open my $log_fh, '>', $commit_editmsg or croak $!;
1730
1731         my $type = command_oneline(qw/cat-file -t/, $treeish);
1732         if ($type eq 'commit' || $type eq 'tag') {
1733                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1734                                                          $type, $treeish);
1735                 my $in_msg = 0;
1736                 my $author;
1737                 my $saw_from = 0;
1738                 my $msgbuf = "";
1739                 while (<$msg_fh>) {
1740                         if (!$in_msg) {
1741                                 $in_msg = 1 if (/^\s*$/);
1742                                 $author = $1 if (/^author (.*>)/);
1743                         } elsif (/^git-svn-id: /) {
1744                                 # skip this for now, we regenerate the
1745                                 # correct one on re-fetch anyways
1746                                 # TODO: set *:merge properties or like...
1747                         } else {
1748                                 if (/^From:/ || /^Signed-off-by:/) {
1749                                         $saw_from = 1;
1750                                 }
1751                                 $msgbuf .= $_;
1752                         }
1753                 }
1754                 $msgbuf =~ s/\s+$//s;
1755                 if ($Git::SVN::_add_author_from && defined($author)
1756                     && !$saw_from) {
1757                         $msgbuf .= "\n\nFrom: $author";
1758                 }
1759                 print $log_fh $msgbuf or croak $!;
1760                 command_close_pipe($msg_fh, $ctx);
1761         }
1762         close $log_fh or croak $!;
1763
1764         if ($_edit || ($type eq 'tree')) {
1765                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1766                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1767         }
1768         rename $commit_editmsg, $commit_msg or croak $!;
1769         {
1770                 require Encode;
1771                 # SVN requires messages to be UTF-8 when entering the repo
1772                 local $/;
1773                 open $log_fh, '<', $commit_msg or croak $!;
1774                 binmode $log_fh;
1775                 chomp($log_entry{log} = <$log_fh>);
1776
1777                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1778                 my $msg = $log_entry{log};
1779
1780                 eval { $msg = Encode::decode($enc, $msg, 1) };
1781                 if ($@) {
1782                         die "Could not decode as $enc:\n", $msg,
1783                             "\nPerhaps you need to set i18n.commitencoding\n";
1784                 }
1785
1786                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1787                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1788
1789                 $log_entry{log} = $msg;
1790
1791                 close $log_fh or croak $!;
1792         }
1793         unlink $commit_msg;
1794         \%log_entry;
1795 }
1796
1797 sub s_to_file {
1798         my ($str, $file, $mode) = @_;
1799         open my $fd,'>',$file or croak $!;
1800         print $fd $str,"\n" or croak $!;
1801         close $fd or croak $!;
1802         chmod ($mode &~ umask, $file) if (defined $mode);
1803 }
1804
1805 sub file_to_s {
1806         my $file = shift;
1807         open my $fd,'<',$file or croak "$!: file: $file\n";
1808         local $/;
1809         my $ret = <$fd>;
1810         close $fd or croak $!;
1811         $ret =~ s/\s*$//s;
1812         return $ret;
1813 }
1814
1815 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1816 sub load_authors {
1817         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1818         my $log = $cmd eq 'log';
1819         while (<$authors>) {
1820                 chomp;
1821                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1822                 my ($user, $name, $email) = ($1, $2, $3);
1823                 if ($log) {
1824                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1825                 } else {
1826                         $users{$user} = [$name, $email];
1827                 }
1828         }
1829         close $authors or croak $!;
1830 }
1831
1832 # convert GetOpt::Long specs for use by git-config
1833 sub read_git_config {
1834         my $opts = shift;
1835         my @config_only;
1836         foreach my $o (keys %$opts) {
1837                 # if we have mixedCase and a long option-only, then
1838                 # it's a config-only variable that we don't need for
1839                 # the command-line.
1840                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1841                 my $v = $opts->{$o};
1842                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1843                 $key =~ s/-//g;
1844                 my $arg = 'git config';
1845                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1846                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1847                 if (ref $v eq 'ARRAY') {
1848                         chomp(my @tmp = `$arg --get-all svn.$key`);
1849                         @$v = @tmp if @tmp;
1850                 } else {
1851                         chomp(my $tmp = `$arg --get svn.$key`);
1852                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1853                                 $$v = $tmp;
1854                         }
1855                 }
1856         }
1857         delete @$opts{@config_only} if @config_only;
1858 }
1859
1860 sub extract_metadata {
1861         my $id = shift or return (undef, undef, undef);
1862         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1863                                                         \s([a-f\d\-]+)$/ix);
1864         if (!defined $rev || !$uuid || !$url) {
1865                 # some of the original repositories I made had
1866                 # identifiers like this:
1867                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1868         }
1869         return ($url, $rev, $uuid);
1870 }
1871
1872 sub cmt_metadata {
1873         return extract_metadata((grep(/^git-svn-id: /,
1874                 command(qw/cat-file commit/, shift)))[-1]);
1875 }
1876
1877 sub cmt_sha2rev_batch {
1878         my %s2r;
1879         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1880         my $list = shift;
1881
1882         foreach my $sha (@{$list}) {
1883                 my $first = 1;
1884                 my $size = 0;
1885                 print $out $sha, "\n";
1886
1887                 while (my $line = <$in>) {
1888                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1889                                 last;
1890                         } elsif ($first &&
1891                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1892                                 $first = 0;
1893                                 $size = $1;
1894                                 next;
1895                         } elsif ($line =~ /^(git-svn-id: )/) {
1896                                 my (undef, $rev, undef) =
1897                                                       extract_metadata($line);
1898                                 $s2r{$sha} = $rev;
1899                         }
1900
1901                         $size -= length($line);
1902                         last if ($size == 0);
1903                 }
1904         }
1905
1906         command_close_bidi_pipe($pid, $in, $out, $ctx);
1907
1908         return \%s2r;
1909 }
1910
1911 sub working_head_info {
1912         my ($head, $refs) = @_;
1913         my @args = qw/rev-list --first-parent --pretty=medium/;
1914         my ($fh, $ctx) = command_output_pipe(@args, $head);
1915         my $hash;
1916         my %max;
1917         while (<$fh>) {
1918                 if ( m{^commit ($::sha1)$} ) {
1919                         unshift @$refs, $hash if $hash and $refs;
1920                         $hash = $1;
1921                         next;
1922                 }
1923                 next unless s{^\s*(git-svn-id:)}{$1};
1924                 my ($url, $rev, $uuid) = extract_metadata($_);
1925                 if (defined $url && defined $rev) {
1926                         next if $max{$url} and $max{$url} < $rev;
1927                         if (my $gs = Git::SVN->find_by_url($url)) {
1928                                 my $c = $gs->rev_map_get($rev, $uuid);
1929                                 if ($c && $c eq $hash) {
1930                                         close $fh; # break the pipe
1931                                         return ($url, $rev, $uuid, $gs);
1932                                 } else {
1933                                         $max{$url} ||= $gs->rev_map_max;
1934                                 }
1935                         }
1936                 }
1937         }
1938         command_close_pipe($fh, $ctx);
1939         (undef, undef, undef, undef);
1940 }
1941
1942 sub read_commit_parents {
1943         my ($parents, $c) = @_;
1944         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1945         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1946         @{$parents->{$c}} = split(/ /, $p);
1947 }
1948
1949 sub linearize_history {
1950         my ($gs, $refs) = @_;
1951         my %parents;
1952         foreach my $c (@$refs) {
1953                 read_commit_parents(\%parents, $c);
1954         }
1955
1956         my @linear_refs;
1957         my %skip = ();
1958         my $last_svn_commit = $gs->last_commit;
1959         foreach my $c (reverse @$refs) {
1960                 next if $c eq $last_svn_commit;
1961                 last if $skip{$c};
1962
1963                 unshift @linear_refs, $c;
1964                 $skip{$c} = 1;
1965
1966                 # we only want the first parent to diff against for linear
1967                 # history, we save the rest to inject when we finalize the
1968                 # svn commit
1969                 my $fp_a = verify_ref("$c~1");
1970                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1971                 if (!$fp_a || !$fp_b) {
1972                         die "Commit $c\n",
1973                             "has no parent commit, and therefore ",
1974                             "nothing to diff against.\n",
1975                             "You should be working from a repository ",
1976                             "originally created by git-svn\n";
1977                 }
1978                 if ($fp_a ne $fp_b) {
1979                         die "$c~1 = $fp_a, however parsing commit $c ",
1980                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1981                 }
1982
1983                 foreach my $p (@{$parents{$c}}) {
1984                         $skip{$p} = 1;
1985                 }
1986         }
1987         (\@linear_refs, \%parents);
1988 }
1989
1990 sub find_file_type_and_diff_status {
1991         my ($path) = @_;
1992         return ('dir', '') if $path eq '';
1993
1994         my $diff_output =
1995             command_oneline(qw(diff --cached --name-status --), $path) || "";
1996         my $diff_status = (split(' ', $diff_output))[0] || "";
1997
1998         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1999
2000         return (undef, undef) if !$diff_status && !$ls_tree;
2001
2002         if ($diff_status eq "A") {
2003                 return ("link", $diff_status) if -l $path;
2004                 return ("dir", $diff_status) if -d $path;
2005                 return ("file", $diff_status);
2006         }
2007
2008         my $mode = (split(' ', $ls_tree))[0] || "";
2009
2010         return ("link", $diff_status) if $mode eq "120000";
2011         return ("dir", $diff_status) if $mode eq "040000";
2012         return ("file", $diff_status);
2013 }
2014
2015 sub md5sum {
2016         my $arg = shift;
2017         my $ref = ref $arg;
2018         my $md5 = Digest::MD5->new();
2019         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
2020                 $md5->addfile($arg) or croak $!;
2021         } elsif ($ref eq 'SCALAR') {
2022                 $md5->add($$arg) or croak $!;
2023         } elsif (!$ref) {
2024                 $md5->add($arg) or croak $!;
2025         } else {
2026                 fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
2027         }
2028         return $md5->hexdigest();
2029 }
2030
2031 sub gc_directory {
2032         if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
2033                 my $out_filename = $_ . ".gz";
2034                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2035                 binmode $in_fh;
2036                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2037                                 die "Unable to open $out_filename: $!\n";
2038
2039                 my $res;
2040                 while ($res = sysread($in_fh, my $str, 1024)) {
2041                         $gz->gzwrite($str) or
2042                                 die "Unable to write: ".$gz->gzerror()."!\n";
2043                 }
2044                 unlink $_ or die "unlink $File::Find::name: $!\n";
2045         } elsif (-f $_ && basename($_) eq "index") {
2046                 unlink $_ or die "unlink $_: $!\n";
2047         }
2048 }
2049
2050 __END__
2051
2052 Data structures:
2053
2054
2055 $remotes = { # returned by read_all_remotes()
2056         'svn' => {
2057                 # svn-remote.svn.url=https://svn.musicpd.org
2058                 url => 'https://svn.musicpd.org',
2059                 # svn-remote.svn.fetch=mpd/trunk:trunk
2060                 fetch => {
2061                         'mpd/trunk' => 'trunk',
2062                 },
2063                 # svn-remote.svn.tags=mpd/tags/*:tags/*
2064                 tags => {
2065                         path => {
2066                                 left => 'mpd/tags',
2067                                 right => '',
2068                                 regex => qr!mpd/tags/([^/]+)$!,
2069                                 glob => 'tags/*',
2070                         },
2071                         ref => {
2072                                 left => 'tags',
2073                                 right => '',
2074                                 regex => qr!tags/([^/]+)$!,
2075                                 glob => 'tags/*',
2076                         },
2077                 }
2078         }
2079 };
2080
2081 $log_entry hashref as returned by libsvn_log_entry()
2082 {
2083         log => 'whitespace-formatted log entry
2084 ',                                              # trailing newline is preserved
2085         revision => '8',                        # integer
2086         date => '2004-02-24T17:01:44.108345Z',  # commit date
2087         author => 'committer name'
2088 };
2089
2090
2091 # this is generated by generate_diff();
2092 @mods = array of diff-index line hashes, each element represents one line
2093         of diff-index output
2094
2095 diff-index line ($m hash)
2096 {
2097         mode_a => first column of diff-index output, no leading ':',
2098         mode_b => second column of diff-index output,
2099         sha1_b => sha1sum of the final blob,
2100         chg => change type [MCRADT],
2101         file_a => original file name of a file (iff chg is 'C' or 'R')
2102         file_b => new/current file name of a file (any chg)
2103 }
2104 ;
2105
2106 # retval of read_url_paths{,_all}();
2107 $l_map = {
2108         # repository root url
2109         'https://svn.musicpd.org' => {
2110                 # repository path               # GIT_SVN_ID
2111                 'mpd/trunk'             =>      'trunk',
2112                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2113         },
2114 }
2115
2116 Notes:
2117         I don't trust the each() function on unless I created %hash myself
2118         because the internal iterator may not have started at base.