git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 $SIG{INT} = sub { print color("reset"), "\n"; exit };
  28
  29 package FakeTerm;
  30 sub new {
  31         my ($class, $reason) = @_;
  32         return bless \$reason, shift;
  33 }
  34 sub readline {
  35         my $self = shift;
  36         die "Cannot use readline on FakeTerm: $$self";
  37 }
  38 package main;
  39
  40
  41 sub usage {
  42         print <<EOT;
  43 git-send-email [options] <file | directory>...
  44 Options:
  45    --from         Specify the "From:" line of the email to be sent.
  46
  47    --to           Specify the primary "To:" line of the email.
  48
  49    --cc           Specify an initial "Cc:" list for the entire series
  50                   of emails.
  51
  52    --cc-cmd       Specify a command to execute per file which adds
  53                   per file specific cc address entries
  54
  55    --bcc          Specify a list of email addresses that should be Bcc:
  56                   on all the emails.
  57
  58    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  59                   an introductory message for the patch series.
  60
  61    --subject      Specify the initial "Subject:" line.
  62                   Only necessary if --compose is also set.  If --compose
  63                   is not set, this will be prompted for.
  64
  65    --in-reply-to  Specify the first "In-Reply-To:" header line.
  66                   Only used if --compose is also set.  If --compose is not
  67                   set, this will be prompted for.
  68
  69    --chain-reply-to If set, the replies will all be to the previous
  70                   email sent, rather than to the first email sent.
  71                   Defaults to on.
  72
  73    --signed-off-cc Automatically add email addresses that appear in
  74                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  75
  76    --identity     The configuration identity, a subsection to prioritise over
  77                   the default section.
  78
  79    --smtp-server  If set, specifies the outgoing SMTP server to use.
  80                   Defaults to localhost.  Port number can be specified here with
  81                   hostname:port format or by using --smtp-server-port option.
  82
  83    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  84
  85    --smtp-user    The username for SMTP-AUTH.
  86
  87    --smtp-pass    The password for SMTP-AUTH.
  88
  89    --smtp-ssl     If set, connects to the SMTP server using SSL.
  90
  91    --suppress-from Suppress sending emails to yourself. Defaults to off.
  92
  93    --thread       Specify that the "In-Reply-To:" header should be set on all
  94                   emails. Defaults to on.
  95
  96    --quiet        Make git-send-email less verbose.  One line per email
  97                   should be all that is output.
  98
  99    --dry-run      Do everything except actually send the emails.
 100
 101    --envelope-sender    Specify the envelope sender used to send the emails.
 102
 103 EOT
 104         exit(1);
 105 }
 106
 107 # most mail servers generate the Date: header, but not all...
 108 sub format_2822_time {
 109         my ($time) = @_;
 110         my @localtm = localtime($time);
 111         my @gmttm = gmtime($time);
 112         my $localmin = $localtm[1] + $localtm[2] * 60;
 113         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 114         if ($localtm[0] != $gmttm[0]) {
 115                 die "local zone differs from GMT by a non-minute interval\n";
 116         }
 117         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 118                 $localmin += 1440;
 119         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 120                 $localmin -= 1440;
 121         } elsif ($gmttm[6] != $localtm[6]) {
 122                 die "local time offset greater than or equal to 24 hours\n";
 123         }
 124         my $offset = $localmin - $gmtmin;
 125         my $offhour = $offset / 60;
 126         my $offmin = abs($offset % 60);
 127         if (abs($offhour) >= 24) {
 128                 die ("local time offset greater than or equal to 24 hours\n");
 129         }
 130
 131         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 132                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 133                        $localtm[3],
 134                        qw(Jan Feb Mar Apr May Jun
 135                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 136                        $localtm[5]+1900,
 137                        $localtm[2],
 138                        $localtm[1],
 139                        $localtm[0],
 140                        ($offset >= 0) ? '+' : '-',
 141                        abs($offhour),
 142                        $offmin,
 143                        );
 144 }
 145
 146 my $have_email_valid = eval { require Email::Valid; 1 };
 147 my $smtp;
 148 my $auth;
 149
 150 sub unique_email_list(@);
 151 sub cleanup_compose_files();
 152
 153 # Constants (essentially)
 154 my $compose_filename = ".msg.$$";
 155
 156 # Variables we fill in automatically, or via prompting:
 157 my (@to,@cc,@initial_cc,@bcclist,@xh,
 158         $initial_reply_to,$initial_subject,@files,$author,$sender,$compose,$time);
 159
 160 my $envelope_sender;
 161
 162 # Example reply to:
 163 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 164
 165 my $repo = Git->repository();
 166 my $term = eval {
 167         new Term::ReadLine 'git-send-email';
 168 };
 169 if ($@) {
 170         $term = new FakeTerm "$@: going non-interactive";
 171 }
 172
 173 # Behavior modification variables
 174 my ($quiet, $dry_run) = (0, 0);
 175
 176 # Variables with corresponding config settings
 177 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 178 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_authpass, $smtp_ssl);
 179 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 180
 181 my %config_bool_settings = (
 182     "thread" => [\$thread, 1],
 183     "chainreplyto" => [\$chain_reply_to, 1],
 184     "suppressfrom" => [\$suppress_from, 0],
 185     "signedoffcc" => [\$signed_off_cc, 1],
 186     "smtpssl" => [\$smtp_ssl, 0],
 187 );
 188
 189 my %config_settings = (
 190     "smtpserver" => \$smtp_server,
 191     "smtpserverport" => \$smtp_server_port,
 192     "smtpuser" => \$smtp_authuser,
 193     "smtppass" => \$smtp_authpass,
 194     "to" => \@to,
 195     "cccmd" => \$cc_cmd,
 196     "aliasfiletype" => \$aliasfiletype,
 197     "bcc" => \@bcclist,
 198     "aliasesfile" => \@alias_files,
 199 );
 200
 201 # Begin by accumulating all the variables (defined above), that we will end up
 202 # needing, first, from the command line:
 203
 204 my $rc = GetOptions("sender|from=s" => \$sender,
 205                     "in-reply-to=s" => \$initial_reply_to,
 206                     "subject=s" => \$initial_subject,
 207                     "to=s" => \@to,
 208                     "cc=s" => \@initial_cc,
 209                     "bcc=s" => \@bcclist,
 210                     "chain-reply-to!" => \$chain_reply_to,
 211                     "smtp-server=s" => \$smtp_server,
 212                     "smtp-server-port=s" => \$smtp_server_port,
 213                     "smtp-user=s" => \$smtp_authuser,
 214                     "smtp-pass=s" => \$smtp_authpass,
 215                     "smtp-ssl!" => \$smtp_ssl,
 216                     "identity=s" => \$identity,
 217                     "compose" => \$compose,
 218                     "quiet" => \$quiet,
 219                     "cc-cmd=s" => \$cc_cmd,
 220                     "suppress-from!" => \$suppress_from,
 221                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 222                     "dry-run" => \$dry_run,
 223                     "envelope-sender=s" => \$envelope_sender,
 224                     "thread!" => \$thread,
 225          );
 226
 227 unless ($rc) {
 228     usage();
 229 }
 230
 231 # Now, let's fill any that aren't set in with defaults:
 232
 233 sub read_config {
 234         my ($prefix) = @_;
 235
 236         foreach my $setting (keys %config_bool_settings) {
 237                 my $target = $config_bool_settings{$setting}->[0];
 238                 $$target = $repo->config_bool("$prefix.$setting") unless (defined $$target);
 239         }
 240
 241         foreach my $setting (keys %config_settings) {
 242                 my $target = $config_settings{$setting};
 243                 if (ref($target) eq "ARRAY") {
 244                         unless (@$target) {
 245                                 my @values = $repo->config("$prefix.$setting");
 246                                 @$target = @values if (@values && defined $values[0]);
 247                         }
 248                 }
 249                 else {
 250                         $$target = $repo->config("$prefix.$setting") unless (defined $$target);
 251                 }
 252         }
 253 }
 254
 255 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 256 $identity = $repo->config("sendemail.identity") unless (defined $identity);
 257 read_config("sendemail.$identity") if (defined $identity);
 258 read_config("sendemail");
 259
 260 # fall back on builtin bool defaults
 261 foreach my $setting (values %config_bool_settings) {
 262         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 263 }
 264
 265 my ($repoauthor) = $repo->ident_person('author');
 266 my ($repocommitter) = $repo->ident_person('committer');
 267
 268 # Verify the user input
 269
 270 foreach my $entry (@to) {
 271         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 272 }
 273
 274 foreach my $entry (@initial_cc) {
 275         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 276 }
 277
 278 foreach my $entry (@bcclist) {
 279         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 280 }
 281
 282 my %aliases;
 283 my %parse_alias = (
 284         # multiline formats can be supported in the future
 285         mutt => sub { my $fh = shift; while (<$fh>) {
 286                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 287                         my ($alias, $addr) = ($1, $2);
 288                         $addr =~ s/#.*$//; # mutt allows # comments
 289                          # commas delimit multiple addresses
 290                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 291                 }}},
 292         mailrc => sub { my $fh = shift; while (<$fh>) {
 293                 if (/^alias\s+(\S+)\s+(.*)$/) {
 294                         # spaces delimit multiple addresses
 295                         $aliases{$1} = [ split(/\s+/, $2) ];
 296                 }}},
 297         pine => sub { my $fh = shift; while (<$fh>) {
 298                 if (/^(\S+)\t.*\t(.*)$/) {
 299                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 300                 }}},
 301         gnus => sub { my $fh = shift; while (<$fh>) {
 302                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 303                         $aliases{$1} = [ $2 ];
 304                 }}}
 305 );
 306
 307 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 308         foreach my $file (@alias_files) {
 309                 open my $fh, '<', $file or die "opening $file: $!\n";
 310                 $parse_alias{$aliasfiletype}->($fh);
 311                 close $fh;
 312         }
 313 }
 314
 315 ($sender) = expand_aliases($sender) if defined $sender;
 316
 317 my $prompting = 0;
 318 if (!defined $sender) {
 319         $sender = $repoauthor || $repocommitter;
 320         do {
 321                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 322         } while (!defined $_);
 323
 324         $sender = $_ if ($_);
 325         print "Emails will be sent from: ", $sender, "\n";
 326         $prompting++;
 327 }
 328
 329 if (!@to) {
 330         do {
 331                 $_ = $term->readline("Who should the emails be sent to? ",
 332                                 "");
 333         } while (!defined $_);
 334         my $to = $_;
 335         push @to, split /,/, $to;
 336         $prompting++;
 337 }
 338
 339 sub expand_aliases {
 340         my @cur = @_;
 341         my @last;
 342         do {
 343                 @last = @cur;
 344                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 345         } while (join(',',@cur) ne join(',',@last));
 346         return @cur;
 347 }
 348
 349 @to = expand_aliases(@to);
 350 @to = (map { sanitize_address($_) } @to);
 351 @initial_cc = expand_aliases(@initial_cc);
 352 @bcclist = expand_aliases(@bcclist);
 353
 354 if (!defined $initial_subject && $compose) {
 355         do {
 356                 $_ = $term->readline("What subject should the initial email start with? ",
 357                         $initial_subject);
 358         } while (!defined $_);
 359         $initial_subject = $_;
 360         $prompting++;
 361 }
 362
 363 if ($thread && !defined $initial_reply_to && $prompting) {
 364         do {
 365                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
 366                         $initial_reply_to);
 367         } while (!defined $_);
 368
 369         $initial_reply_to = $_;
 370 }
 371 if (defined $initial_reply_to && $_ ne "") {
 372         $initial_reply_to =~ s/^\s*<?/</;
 373         $initial_reply_to =~ s/>?\s*$/>/;
 374 }
 375
 376 if (!defined $smtp_server) {
 377         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 378                 if (-x $_) {
 379                         $smtp_server = $_;
 380                         last;
 381                 }
 382         }
 383         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 384 }
 385
 386 if ($compose) {
 387         # Note that this does not need to be secure, but we will make a small
 388         # effort to have it be unique
 389         open(C,">",$compose_filename)
 390                 or die "Failed to open for writing $compose_filename: $!";
 391         print C "From $sender # This line is ignored.\n";
 392         printf C "Subject: %s\n\n", $initial_subject;
 393         printf C <<EOT;
 394 GIT: Please enter your email below.
 395 GIT: Lines beginning in "GIT: " will be removed.
 396 GIT: Consider including an overall diffstat or table of contents
 397 GIT: for the patch you are writing.
 398
 399 EOT
 400         close(C);
 401
 402         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 403         system($editor, $compose_filename);
 404
 405         open(C2,">",$compose_filename . ".final")
 406                 or die "Failed to open $compose_filename.final : " . $!;
 407
 408         open(C,"<",$compose_filename)
 409                 or die "Failed to open $compose_filename : " . $!;
 410
 411         while(<C>) {
 412                 next if m/^GIT: /;
 413                 print C2 $_;
 414         }
 415         close(C);
 416         close(C2);
 417
 418         do {
 419                 $_ = $term->readline("Send this email? (y|n) ");
 420         } while (!defined $_);
 421
 422         if (uc substr($_,0,1) ne 'Y') {
 423                 cleanup_compose_files();
 424                 exit(0);
 425         }
 426
 427         @files = ($compose_filename . ".final");
 428 }
 429
 430
 431 # Now that all the defaults are set, process the rest of the command line
 432 # arguments and collect up the files that need to be processed.
 433 for my $f (@ARGV) {
 434         if (-d $f) {
 435                 opendir(DH,$f)
 436                         or die "Failed to opendir $f: $!";
 437
 438                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 439                                 sort readdir(DH);
 440
 441         } elsif (-f $f) {
 442                 push @files, $f;
 443
 444         } else {
 445                 print STDERR "Skipping $f - not found.\n";
 446         }
 447 }
 448
 449 if (@files) {
 450         unless ($quiet) {
 451                 print $_,"\n" for (@files);
 452         }
 453 } else {
 454         print STDERR "\nNo patch files specified!\n\n";
 455         usage();
 456 }
 457
 458 # Variables we set as part of the loop over files
 459 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 460
 461 sub extract_valid_address {
 462         my $address = shift;
 463         my $local_part_regexp = '[^<>"\s@]+';
 464         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 465
 466         # check for a local address:
 467         return $address if ($address =~ /^($local_part_regexp)$/);
 468
 469         $address =~ s/^\s*<(.*)>\s*$/$1/;
 470         if ($have_email_valid) {
 471                 return scalar Email::Valid->address($address);
 472         } else {
 473                 # less robust/correct than the monster regexp in Email::Valid,
 474                 # but still does a 99% job, and one less dependency
 475                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 476                 return $1;
 477         }
 478 }
 479
 480 # Usually don't need to change anything below here.
 481
 482 # we make a "fake" message id by taking the current number
 483 # of seconds since the beginning of Unix time and tacking on
 484 # a random number to the end, in case we are called quicker than
 485 # 1 second since the last time we were called.
 486
 487 # We'll setup a template for the message id, using the "from" address:
 488
 489 my ($message_id_stamp, $message_id_serial);
 490 sub make_message_id
 491 {
 492         my $uniq;
 493         if (!defined $message_id_stamp) {
 494                 $message_id_stamp = sprintf("%s-%s", time, $$);
 495                 $message_id_serial = 0;
 496         }
 497         $message_id_serial++;
 498         $uniq = "$message_id_stamp-$message_id_serial";
 499
 500         my $du_part;
 501         for ($sender, $repocommitter, $repoauthor) {
 502                 $du_part = extract_valid_address(sanitize_address($_));
 503                 last if (defined $du_part and $du_part ne '');
 504         }
 505         if (not defined $du_part or $du_part eq '') {
 506                 use Sys::Hostname qw();
 507                 $du_part = 'user@' . Sys::Hostname::hostname();
 508         }
 509         my $message_id_template = "<%s-git-send-email-%s>";
 510         $message_id = sprintf($message_id_template, $uniq, $du_part);
 511         #print "new message id = $message_id\n"; # Was useful for debugging
 512 }
 513
 514
 515
 516 $time = time - scalar $#files;
 517
 518 sub unquote_rfc2047 {
 519         local ($_) = @_;
 520         my $encoding;
 521         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 522                 $encoding = $1;
 523                 s/_/ /g;
 524                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 525         }
 526         return wantarray ? ($_, $encoding) : $_;
 527 }
 528
 529 # use the simplest quoting being able to handle the recipient
 530 sub sanitize_address
 531 {
 532         my ($recipient) = @_;
 533         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 534
 535         if (not $recipient_name) {
 536                 return "$recipient";
 537         }
 538
 539         # if recipient_name is already quoted, do nothing
 540         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 541                 return $recipient;
 542         }
 543
 544         # rfc2047 is needed if a non-ascii char is included
 545         if ($recipient_name =~ /[^[:ascii:]]/) {
 546                 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 547                 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
 548         }
 549
 550         # double quotes are needed if specials or CTLs are included
 551         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 552                 $recipient_name =~ s/(["\\\r])/\\$1/;
 553                 $recipient_name = "\"$recipient_name\"";
 554         }
 555
 556         return "$recipient_name $recipient_addr";
 557
 558 }
 559
 560 sub send_message
 561 {
 562         my @recipients = unique_email_list(@to);
 563         @cc = (grep { my $cc = extract_valid_address($_);
 564                       not grep { $cc eq $_ } @recipients
 565                     }
 566                map { sanitize_address($_) }
 567                @cc);
 568         my $to = join (",\n\t", @recipients);
 569         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 570         @recipients = (map { extract_valid_address($_) } @recipients);
 571         my $date = format_2822_time($time++);
 572         my $gitversion = '@@GIT_VERSION@@';
 573         if ($gitversion =~ m/..GIT_VERSION../) {
 574             $gitversion = Git::version();
 575         }
 576
 577         my $cc = join(", ", unique_email_list(@cc));
 578         my $ccline = "";
 579         if ($cc ne '') {
 580                 $ccline = "\nCc: $cc";
 581         }
 582         my $sanitized_sender = sanitize_address($sender);
 583         make_message_id() unless defined($message_id);
 584
 585         my $header = "From: $sanitized_sender
 586 To: $to${ccline}
 587 Subject: $subject
 588 Date: $date
 589 Message-Id: $message_id
 590 X-Mailer: git-send-email $gitversion
 591 ";
 592         if ($thread && $reply_to) {
 593
 594                 $header .= "In-Reply-To: $reply_to\n";
 595                 $header .= "References: $references\n";
 596         }
 597         if (@xh) {
 598                 $header .= join("\n", @xh) . "\n";
 599         }
 600
 601         my @sendmail_parameters = ('-i', @recipients);
 602         my $raw_from = $sanitized_sender;
 603         $raw_from = $envelope_sender if (defined $envelope_sender);
 604         $raw_from = extract_valid_address($raw_from);
 605         unshift (@sendmail_parameters,
 606                         '-f', $raw_from) if(defined $envelope_sender);
 607
 608         if ($dry_run) {
 609                 # We don't want to send the email.
 610         } elsif ($smtp_server =~ m#^/#) {
 611                 my $pid = open my $sm, '|-';
 612                 defined $pid or die $!;
 613                 if (!$pid) {
 614                         exec($smtp_server, @sendmail_parameters) or die $!;
 615                 }
 616                 print $sm "$header\n$message";
 617                 close $sm or die $?;
 618         } else {
 619
 620                 if (!defined $smtp_server) {
 621                         die "The required SMTP server is not properly defined."
 622                 }
 623
 624                 if ($smtp_ssl) {
 625                         $smtp_server_port ||= 465; # ssmtp
 626                         require Net::SMTP::SSL;
 627                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 628                 }
 629                 else {
 630                         require Net::SMTP;
 631                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 632                                                  ? "$smtp_server:$smtp_server_port"
 633                                                  : $smtp_server);
 634                 }
 635
 636                 if (!$smtp) {
 637                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 638                 }
 639
 640                 if ((defined $smtp_authuser) && (defined $smtp_authpass)) {
 641                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 642                 }
 643                 $smtp->mail( $raw_from ) or die $smtp->message;
 644                 $smtp->to( @recipients ) or die $smtp->message;
 645                 $smtp->data or die $smtp->message;
 646                 $smtp->datasend("$header\n$message") or die $smtp->message;
 647                 $smtp->dataend() or die $smtp->message;
 648                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 649         }
 650         if ($quiet) {
 651                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 652         } else {
 653                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 654                 if ($smtp_server !~ m#^/#) {
 655                         print "Server: $smtp_server\n";
 656                         print "MAIL FROM:<$raw_from>\n";
 657                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 658                 } else {
 659                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 660                 }
 661                 print $header, "\n";
 662                 if ($smtp) {
 663                         print "Result: ", $smtp->code, ' ',
 664                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 665                 } else {
 666                         print "Result: OK\n";
 667                 }
 668         }
 669 }
 670
 671 $reply_to = $initial_reply_to;
 672 $references = $initial_reply_to || '';
 673 $subject = $initial_subject;
 674
 675 foreach my $t (@files) {
 676         open(F,"<",$t) or die "can't open file $t";
 677
 678         my $author = undef;
 679         my $author_encoding;
 680         my $has_content_type;
 681         my $body_encoding;
 682         @cc = @initial_cc;
 683         @xh = ();
 684         my $input_format = undef;
 685         my $header_done = 0;
 686         $message = "";
 687         while(<F>) {
 688                 if (!$header_done) {
 689                         if (/^From /) {
 690                                 $input_format = 'mbox';
 691                                 next;
 692                         }
 693                         chomp;
 694                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 695                                 $input_format = 'mbox';
 696                         }
 697
 698                         if (defined $input_format && $input_format eq 'mbox') {
 699                                 if (/^Subject:\s+(.*)$/) {
 700                                         $subject = $1;
 701
 702                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 703                                         if (unquote_rfc2047($2) eq $sender) {
 704                                                 next if ($suppress_from);
 705                                         }
 706                                         elsif ($1 eq 'From') {
 707                                                 ($author, $author_encoding)
 708                                                   = unquote_rfc2047($2);
 709                                         }
 710                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 711                                                 $2, $_) unless $quiet;
 712                                         push @cc, $2;
 713                                 }
 714                                 elsif (/^Content-type:/i) {
 715                                         $has_content_type = 1;
 716                                         if (/charset="?[^ "]+/) {
 717                                                 $body_encoding = $1;
 718                                         }
 719                                         push @xh, $_;
 720                                 }
 721                                 elsif (/^Message-Id: (.*)/i) {
 722                                         $message_id = $1;
 723                                 }
 724                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 725                                         push @xh, $_;
 726                                 }
 727
 728                         } else {
 729                                 # In the traditional
 730                                 # "send lots of email" format,
 731                                 # line 1 = cc
 732                                 # line 2 = subject
 733                                 # So let's support that, too.
 734                                 $input_format = 'lots';
 735                                 if (@cc == 0) {
 736                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 737                                                 $_, $_) unless $quiet;
 738
 739                                         push @cc, $_;
 740
 741                                 } elsif (!defined $subject) {
 742                                         $subject = $_;
 743                                 }
 744                         }
 745
 746                         # A whitespace line will terminate the headers
 747                         if (m/^\s*$/) {
 748                                 $header_done = 1;
 749                         }
 750                 } else {
 751                         $message .=  $_;
 752                         if (/^(Signed-off-by|Cc): (.*)$/i && $signed_off_cc) {
 753                                 my $c = $2;
 754                                 chomp $c;
 755                                 next if ($c eq $sender and $suppress_from);
 756                                 push @cc, $c;
 757                                 printf("(sob) Adding cc: %s from line '%s'\n",
 758                                         $c, $_) unless $quiet;
 759                         }
 760                 }
 761         }
 762         close F;
 763
 764         if (defined $cc_cmd) {
 765                 open(F, "$cc_cmd $t |")
 766                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 767                 while(<F>) {
 768                         my $c = $_;
 769                         $c =~ s/^\s*//g;
 770                         $c =~ s/\n$//g;
 771                         next if ($c eq $sender and $suppress_from);
 772                         push @cc, $c;
 773                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 774                                 $c, $cc_cmd) unless $quiet;
 775                 }
 776                 close F
 777                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 778         }
 779
 780         if (defined $author) {
 781                 $message = "From: $author\n\n$message";
 782                 if (defined $author_encoding) {
 783                         if ($has_content_type) {
 784                                 if ($body_encoding eq $author_encoding) {
 785                                         # ok, we already have the right encoding
 786                                 }
 787                                 else {
 788                                         # uh oh, we should re-encode
 789                                 }
 790                         }
 791                         else {
 792                                 push @xh,
 793                                   'MIME-Version: 1.0',
 794                                   "Content-Type: text/plain; charset=$author_encoding",
 795                                   'Content-Transfer-Encoding: 8bit';
 796                         }
 797                 }
 798         }
 799
 800         send_message();
 801
 802         # set up for the next message
 803         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 804                 $reply_to = $message_id;
 805                 if (length $references > 0) {
 806                         $references .= "\n $message_id";
 807                 } else {
 808                         $references = "$message_id";
 809                 }
 810         }
 811         $message_id = undef;
 812 }
 813
 814 if ($compose) {
 815         cleanup_compose_files();
 816 }
 817
 818 sub cleanup_compose_files() {
 819         unlink($compose_filename, $compose_filename . ".final");
 820
 821 }
 822
 823 $smtp->quit if $smtp;
 824
 825 sub unique_email_list(@) {
 826         my %seen;
 827         my @emails;
 828
 829         foreach my $entry (@_) {
 830                 if (my $clean = extract_valid_address($entry)) {
 831                         $seen{$clean} ||= 0;
 832                         next if $seen{$clean}++;
 833                         push @emails, $entry;
 834                 } else {
 835                         print STDERR "W: unable to extract a valid address",
 836                                         " from: $entry\n";
 837                 }
 838         }
 839         return @emails;
 840 }