?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
Uninline prefixcmp()
[alt-git.git] / git-svn.perl
blob2c97b05885e4323fc175741e20a71f91bfbf27de
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 # From which subdir have we been invoked?
13 my $cmd_dir_prefix = eval {
14 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
15 } || '';
16
17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
18 $ENV{GIT_DIR} ||= '.git';
19 $Git::SVN::default_repo_id = 'svn';
20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
21 $Git::SVN::Ra::_log_window_size = 100;
22
23 $Git::SVN::Log::TZ = $ENV{TZ};
24 $ENV{TZ} = 'UTC';
25 $| = 1; # unbuffer STDOUT
26
27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
29 require SVN::Ra;
30 require SVN::Delta;
31 if ($SVN::Core::VERSION lt '1.1.0') {
32 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
33 }
34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
37 use Carp qw/croak/;
38 use Digest::MD5;
39 use IO::File qw//;
40 use File::Basename qw/dirname basename/;
41 use File::Path qw/mkpath/;
42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
43 use IPC::Open3;
44 use Git;
45
46 BEGIN {
47 # import functions from Git into our packages, en masse
48 no strict 'refs';
49 foreach (qw/command command_oneline command_noisy command_output_pipe
50 command_input_pipe command_close_pipe/) {
51 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
52 Git::SVN::Migration Git::SVN::Log Git::SVN),
53 __PACKAGE__) {
54 *{"${package}::$_"} = \&{"Git::$_"};
55 }
56 }
57 }
58
59 my ($SVN);
60
61 $sha1 = qr/[a-f\d]{40}/;
62 $sha1_short = qr/[a-f\d]{4,40}/;
63 my ($_stdin, $_help, $_edit,
64 $_message, $_file,
65 $_template, $_shared,
66 $_version, $_fetch_all, $_no_rebase,
67 $_merge, $_strategy, $_dry_run, $_local,
68 $_prefix, $_no_checkout, $_url, $_verbose);
69 $Git::SVN::_follow_parent = 1;
70 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
71 'config-dir=s' => \$Git::SVN::Ra::config_dir,
72 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
73 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
74 'authors-file|A=s' => \$_authors,
75 'repack:i' => \$Git::SVN::_repack,
76 'noMetadata' => \$Git::SVN::_no_metadata,
77 'useSvmProps' => \$Git::SVN::_use_svm_props,
78 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
79 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
80 'no-checkout' => \$_no_checkout,
81 'quiet|q' => \$_q,
82 'repack-flags|repack-args|repack-opts=s' =>
83 \$Git::SVN::_repack_flags,
84 'use-log-author' => \$Git::SVN::_use_log_author,
85 %remote_opts );
86
87 my ($_trunk, $_tags, $_branches, $_stdlayout);
88 my %icv;
89 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
90 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
91 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
92 'stdlayout|s' => \$_stdlayout,
93 'minimize-url|m' => \$Git::SVN::_minimize_url,
94 'no-metadata' => sub { $icv{noMetadata} = 1 },
95 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
96 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
97 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
98 %remote_opts );
99 my %cmt_opts = ( 'edit|e' => \$_edit,
100 'rmdir' => \$SVN::Git::Editor::_rmdir,
101 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
102 'l=i' => \$SVN::Git::Editor::_rename_limit,
103 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
104 );
105
106 my %cmd = (
107 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
108 { 'revision|r=s' => \$_revision,
109 'fetch-all|all' => \$_fetch_all,
110 %fc_opts } ],
111 clone => [ \&cmd_clone, "Initialize and fetch revisions",
112 { 'revision|r=s' => \$_revision,
113 %fc_opts, %init_opts } ],
114 init => [ \&cmd_init, "Initialize a repo for tracking" .
115 " (requires URL argument)",
116 \%init_opts ],
117 'multi-init' => [ \&cmd_multi_init,
118 "Deprecated alias for ".
119 "'$0 init -T<trunk> -b<branches> -t<tags>'",
120 \%init_opts ],
121 dcommit => [ \&cmd_dcommit,
122 'Commit several diffs to merge with upstream',
123 { 'merge|m|M' => \$_merge,
124 'strategy|s=s' => \$_strategy,
125 'verbose|v' => \$_verbose,
126 'dry-run|n' => \$_dry_run,
127 'fetch-all|all' => \$_fetch_all,
128 'no-rebase' => \$_no_rebase,
129 %cmt_opts, %fc_opts } ],
130 'set-tree' => [ \&cmd_set_tree,
131 "Set an SVN repository to a git tree-ish",
132 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
133 'create-ignore' => [ \&cmd_create_ignore,
134 'Create a .gitignore per svn:ignore',
135 { 'revision|r=i' => \$_revision
136 } ],
137 'propget' => [ \&cmd_propget,
138 'Print the value of a property on a file or directory',
139 { 'revision|r=i' => \$_revision } ],
140 'proplist' => [ \&cmd_proplist,
141 'List all properties of a file or directory',
142 { 'revision|r=i' => \$_revision } ],
143 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
144 { 'revision|r=i' => \$_revision
145 } ],
146 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
147 { 'revision|r=i' => \$_revision
148 } ],
149 'multi-fetch' => [ \&cmd_multi_fetch,
150 "Deprecated alias for $0 fetch --all",
151 { 'revision|r=s' => \$_revision, %fc_opts } ],
152 'migrate' => [ sub { },
153 # no-op, we automatically run this anyways,
154 'Migrate configuration/metadata/layout from
155 previous versions of git-svn',
156 { 'minimize' => \$Git::SVN::Migration::_minimize,
157 %remote_opts } ],
158 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
159 { 'limit=i' => \$Git::SVN::Log::limit,
160 'revision|r=s' => \$_revision,
161 'verbose|v' => \$Git::SVN::Log::verbose,
162 'incremental' => \$Git::SVN::Log::incremental,
163 'oneline' => \$Git::SVN::Log::oneline,
164 'show-commit' => \$Git::SVN::Log::show_commit,
165 'non-recursive' => \$Git::SVN::Log::non_recursive,
166 'authors-file|A=s' => \$_authors,
167 'color' => \$Git::SVN::Log::color,
168 'pager=s' => \$Git::SVN::Log::pager
169 } ],
170 'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
171 {} ],
172 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
173 { 'merge|m|M' => \$_merge,
174 'verbose|v' => \$_verbose,
175 'strategy|s=s' => \$_strategy,
176 'local|l' => \$_local,
177 'fetch-all|all' => \$_fetch_all,
178 %fc_opts } ],
179 'commit-diff' => [ \&cmd_commit_diff,
180 'Commit a diff between two trees',
181 { 'message|m=s' => \$_message,
182 'file|F=s' => \$_file,
183 'revision|r=s' => \$_revision,
184 %cmt_opts } ],
185 'info' => [ \&cmd_info,
186 "Show info about the latest SVN revision
187 on the current branch",
188 { 'url' => \$_url, } ],
189 );
190
191 my $cmd;
192 for (my $i = 0; $i < @ARGV; $i++) {
193 if (defined $cmd{$ARGV[$i]}) {
194 $cmd = $ARGV[$i];
195 splice @ARGV, $i, 1;
196 last;
197 }
198 };
199
200 # make sure we're always running at the top-level working directory
201 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
202 unless (-d $ENV{GIT_DIR}) {
203 if ($git_dir_user_set) {
204 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
205 "but it is not a directory\n";
206 }
207 my $git_dir = delete $ENV{GIT_DIR};
208 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
209 unless (length $cdup) {
210 die "Already at toplevel, but $git_dir ",
211 "not found '$cdup'\n";
212 }
213 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
214 unless (-d $git_dir) {
215 die "$git_dir still not found after going to ",
216 "'$cdup'\n";
217 }
218 $ENV{GIT_DIR} = $git_dir;
219 }
220 }
221
222 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
223
224 read_repo_config(\%opts);
225 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
226 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
227 'minimize-connections' => \$Git::SVN::Migration::_minimize,
228 'id|i=s' => \$Git::SVN::default_ref_id,
229 'svn-remote|remote|R=s' => sub {
230 $Git::SVN::no_reuse_existing = 1;
231 $Git::SVN::default_repo_id = $_[1] });
232 exit 1 if (!$rv && $cmd && $cmd ne 'log');
233
234 usage(0) if $_help;
235 version() if $_version;
236 usage(1) unless defined $cmd;
237 load_authors() if $_authors;
238
239 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
240 Git::SVN::Migration::migration_check();
241 }
242 Git::SVN::init_vars();
243 eval {
244 Git::SVN::verify_remotes_sanity();
245 $cmd{$cmd}->[0]->(@ARGV);
246 };
247 fatal $@ if $@;
248 post_fetch_checkout();
249 exit 0;
250
251 ####################### primary functions ######################
252 sub usage {
253 my $exit = shift || 0;
254 my $fd = $exit ? \*STDERR : \*STDOUT;
255 print $fd <<"";
256 git-svn - bidirectional operations between a single Subversion tree and git
257 Usage: $0 <command> [options] [arguments]\n
258
259 print $fd "Available commands:\n" unless $cmd;
260
261 foreach (sort keys %cmd) {
262 next if $cmd && $cmd ne $_;
263 next if /^multi-/; # don't show deprecated commands
264 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
265 foreach (sort keys %{$cmd{$_}->[2]}) {
266 # mixed-case options are for .git/config only
267 next if /[A-Z]/ && /^[a-z]+$/i;
268 # prints out arguments as they should be passed:
269 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
270 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
271 "--$_" : "-$_" }
272 split /\|/,$_)," $x\n";
273 }
274 }
275 print $fd <<"";
276 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
277 arbitrary identifier if you're tracking multiple SVN branches/repositories in
278 one git repository and want to keep them separate. See git-svn(1) for more
279 information.
280
281 exit $exit;
282 }
283
284 sub version {
285 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
286 exit 0;
287 }
288
289 sub do_git_init_db {
290 unless (-d $ENV{GIT_DIR}) {
291 my @init_db = ('init');
292 push @init_db, "--template=$_template" if defined $_template;
293 if (defined $_shared) {
294 if ($_shared =~ /[a-z]/) {
295 push @init_db, "--shared=$_shared";
296 } else {
297 push @init_db, "--shared";
298 }
299 }
300 command_noisy(@init_db);
301 }
302 my $set;
303 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
304 foreach my $i (keys %icv) {
305 die "'$set' and '$i' cannot both be set\n" if $set;
306 next unless defined $icv{$i};
307 command_noisy('config', "$pfx.$i", $icv{$i});
308 $set = $i;
309 }
310 }
311
312 sub init_subdir {
313 my $repo_path = shift or return;
314 mkpath([$repo_path]) unless -d $repo_path;
315 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
316 $ENV{GIT_DIR} = '.git';
317 }
318
319 sub cmd_clone {
320 my ($url, $path) = @_;
321 if (!defined $path &&
322 (defined $_trunk || defined $_branches || defined $_tags ||
323 defined $_stdlayout) &&
324 $url !~ m#^[a-z\+]+://#) {
325 $path = $url;
326 }
327 $path = basename($url) if !defined $path || !length $path;
328 cmd_init($url, $path);
329 Git::SVN::fetch_all($Git::SVN::default_repo_id);
330 }
331
332 sub cmd_init {
333 if (defined $_stdlayout) {
334 $_trunk = 'trunk' if (!defined $_trunk);
335 $_tags = 'tags' if (!defined $_tags);
336 $_branches = 'branches' if (!defined $_branches);
337 }
338 if (defined $_trunk || defined $_branches || defined $_tags) {
339 return cmd_multi_init(@_);
340 }
341 my $url = shift or die "SVN repository location required ",
342 "as a command-line argument\n";
343 init_subdir(@_);
344 do_git_init_db();
345
346 Git::SVN->init($url);
347 }
348
349 sub cmd_fetch {
350 if (grep /^\d+=./, @_) {
351 die "'<rev>=<commit>' fetch arguments are ",
352 "no longer supported.\n";
353 }
354 my ($remote) = @_;
355 if (@_ > 1) {
356 die "Usage: $0 fetch [--all] [svn-remote]\n";
357 }
358 $remote ||= $Git::SVN::default_repo_id;
359 if ($_fetch_all) {
360 cmd_multi_fetch();
361 } else {
362 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
363 }
364 }
365
366 sub cmd_set_tree {
367 my (@commits) = @_;
368 if ($_stdin || !@commits) {
369 print "Reading from stdin...\n";
370 @commits = ();
371 while (<STDIN>) {
372 if (/\b($sha1_short)\b/o) {
373 unshift @commits, $1;
374 }
375 }
376 }
377 my @revs;
378 foreach my $c (@commits) {
379 my @tmp = command('rev-parse',$c);
380 if (scalar @tmp == 1) {
381 push @revs, $tmp[0];
382 } elsif (scalar @tmp > 1) {
383 push @revs, reverse(command('rev-list',@tmp));
384 } else {
385 fatal "Failed to rev-parse $c";
386 }
387 }
388 my $gs = Git::SVN->new;
389 my ($r_last, $cmt_last) = $gs->last_rev_commit;
390 $gs->fetch;
391 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
392 fatal "There are new revisions that were fetched ",
393 "and need to be merged (or acknowledged) ",
394 "before committing.\nlast rev: $r_last\n",
395 " current: $gs->{last_rev}";
396 }
397 $gs->set_tree($_) foreach @revs;
398 print "Done committing ",scalar @revs," revisions to SVN\n";
399 unlink $gs->{index};
400 }
401
402 sub cmd_dcommit {
403 my $head = shift;
404 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
405 'Cannot dcommit with a dirty index. Commit your changes first, '
406 . "or stash them with `git stash'.\n";
407 $head ||= 'HEAD';
408 my @refs;
409 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
410 print "Committing to $url ...\n";
411 unless ($gs) {
412 die "Unable to determine upstream SVN information from ",
413 "$head history\n";
414 }
415 my $last_rev;
416 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
417 if ($_no_rebase && scalar(@$linear_refs) > 1) {
418 warn "Attempting to commit more than one change while ",
419 "--no-rebase is enabled.\n",
420 "If these changes depend on each other, re-running ",
421 "without --no-rebase may be required."
422 }
423 while (1) {
424 my $d = shift @$linear_refs or last;
425 unless (defined $last_rev) {
426 (undef, $last_rev, undef) = cmt_metadata("$d~1");
427 unless (defined $last_rev) {
428 fatal "Unable to extract revision information ",
429 "from commit $d~1";
430 }
431 }
432 if ($_dry_run) {
433 print "diff-tree $d~1 $d\n";
434 } else {
435 my $cmt_rev;
436 my %ed_opts = ( r => $last_rev,
437 log => get_commit_entry($d)->{log},
438 ra => Git::SVN::Ra->new($gs->full_url),
439 config => SVN::Core::config_get_config(
440 $Git::SVN::Ra::config_dir
441 ),
442 tree_a => "$d~1",
443 tree_b => $d,
444 editor_cb => sub {
445 print "Committed r$_[0]\n";
446 $cmt_rev = $_[0];
447 },
448 svn_path => '');
449 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
450 print "No changes\n$d~1 == $d\n";
451 } elsif ($parents->{$d} && @{$parents->{$d}}) {
452 $gs->{inject_parents_dcommit}->{$cmt_rev} =
453 $parents->{$d};
454 }
455 $_fetch_all ? $gs->fetch_all : $gs->fetch;
456 $last_rev = $cmt_rev;
457 next if $_no_rebase;
458
459 # we always want to rebase against the current HEAD,
460 # not any head that was passed to us
461 my @diff = command('diff-tree', $d,
462 $gs->refname, '--');
463 my @finish;
464 if (@diff) {
465 @finish = rebase_cmd();
466 print STDERR "W: $d and ", $gs->refname,
467 " differ, using @finish:\n",
468 join("\n", @diff), "\n";
469 } else {
470 print "No changes between current HEAD and ",
471 $gs->refname,
472 "\nResetting to the latest ",
473 $gs->refname, "\n";
474 @finish = qw/reset --mixed/;
475 }
476 command_noisy(@finish, $gs->refname);
477 if (@diff) {
478 @refs = ();
479 my ($url_, $rev_, $uuid_, $gs_) =
480 working_head_info($head, \@refs);
481 my ($linear_refs_, $parents_) =
482 linearize_history($gs_, \@refs);
483 if (scalar(@$linear_refs) !=
484 scalar(@$linear_refs_)) {
485 fatal "# of revisions changed ",
486 "\nbefore:\n",
487 join("\n", @$linear_refs),
488 "\n\nafter:\n",
489 join("\n", @$linear_refs_), "\n",
490 'If you are attempting to commit ',
491 "merges, try running:\n\t",
492 'git rebase --interactive',
493 '--preserve-merges ',
494 $gs->refname,
495 "\nBefore dcommitting";
496 }
497 if ($url_ ne $url) {
498 fatal "URL mismatch after rebase: ",
499 "$url_ != $url";
500 }
501 if ($uuid_ ne $uuid) {
502 fatal "uuid mismatch after rebase: ",
503 "$uuid_ != $uuid";
504 }
505 # remap parents
506 my (%p, @l, $i);
507 for ($i = 0; $i < scalar @$linear_refs; $i++) {
508 my $new = $linear_refs_->[$i] or next;
509 $p{$new} =
510 $parents->{$linear_refs->[$i]};
511 push @l, $new;
512 }
513 $parents = \%p;
514 $linear_refs = \@l;
515 }
516 }
517 }
518 unlink $gs->{index};
519 }
520
521 sub cmd_find_rev {
522 my $revision_or_hash = shift;
523 my $result;
524 if ($revision_or_hash =~ /^r\d+$/) {
525 my $head = shift;
526 $head ||= 'HEAD';
527 my @refs;
528 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
529 unless ($gs) {
530 die "Unable to determine upstream SVN information from ",
531 "$head history\n";
532 }
533 my $desired_revision = substr($revision_or_hash, 1);
534 $result = $gs->rev_map_get($desired_revision);
535 } else {
536 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
537 $result = $rev;
538 }
539 print "$result\n" if $result;
540 }
541
542 sub cmd_rebase {
543 command_noisy(qw/update-index --refresh/);
544 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
545 unless ($gs) {
546 die "Unable to determine upstream SVN information from ",
547 "working tree history\n";
548 }
549 if (command(qw/diff-index HEAD --/)) {
550 print STDERR "Cannot rebase with uncommited changes:\n";
551 command_noisy('status');
552 exit 1;
553 }
554 unless ($_local) {
555 # rebase will checkout for us, so no need to do it explicitly
556 $_no_checkout = 'true';
557 $_fetch_all ? $gs->fetch_all : $gs->fetch;
558 }
559 command_noisy(rebase_cmd(), $gs->refname);
560 }
561
562 sub cmd_show_ignore {
563 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
564 $gs ||= Git::SVN->new;
565 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
566 $gs->prop_walk($gs->{path}, $r, sub {
567 my ($gs, $path, $props) = @_;
568 print STDOUT "\n# $path\n";
569 my $s = $props->{'svn:ignore'} or return;
570 $s =~ s/[\r\n]+/\n/g;
571 chomp $s;
572 $s =~ s#^#$path#gm;
573 print STDOUT "$s\n";
574 });
575 }
576
577 sub cmd_show_externals {
578 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
579 $gs ||= Git::SVN->new;
580 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
581 $gs->prop_walk($gs->{path}, $r, sub {
582 my ($gs, $path, $props) = @_;
583 print STDOUT "\n# $path\n";
584 my $s = $props->{'svn:externals'} or return;
585 $s =~ s/[\r\n]+/\n/g;
586 chomp $s;
587 $s =~ s#^#$path#gm;
588 print STDOUT "$s\n";
589 });
590 }
591
592 sub cmd_create_ignore {
593 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
594 $gs ||= Git::SVN->new;
595 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
596 $gs->prop_walk($gs->{path}, $r, sub {
597 my ($gs, $path, $props) = @_;
598 # $path is of the form /path/to/dir/
599 my $ignore = '.' . $path . '.gitignore';
600 my $s = $props->{'svn:ignore'} or return;
601 open(GITIGNORE, '>', $ignore)
602 or fatal("Failed to open `$ignore' for writing: $!");
603 $s =~ s/[\r\n]+/\n/g;
604 chomp $s;
605 # Prefix all patterns so that the ignore doesn't apply
606 # to sub-directories.
607 $s =~ s#^#/#gm;
608 print GITIGNORE "$s\n";
609 close(GITIGNORE)
610 or fatal("Failed to close `$ignore': $!");
611 command_noisy('add', $ignore);
612 });
613 }
614
615 sub canonicalize_path {
616 my ($path) = @_;
617 my $dot_slash_added = 0;
618 if (substr($path, 0, 1) ne "/") {
619 $path = "./" . $path;
620 $dot_slash_added = 1;
621 }
622 # File::Spec->canonpath doesn't collapse x/../y into y (for a
623 # good reason), so let's do this manually.
624 $path =~ s#/+#/#g;
625 $path =~ s#/\.(?:/|$)#/#g;
626 $path =~ s#/[^/]+/\.\.##g;
627 $path =~ s#/$##g;
628 $path =~ s#^\./## if $dot_slash_added;
629 return $path;
630 }
631
632 # get_svnprops(PATH)
633 # ------------------
634 # Helper for cmd_propget and cmd_proplist below.
635 sub get_svnprops {
636 my $path = shift;
637 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
638 $gs ||= Git::SVN->new;
639
640 # prefix THE PATH by the sub-directory from which the user
641 # invoked us.
642 $path = $cmd_dir_prefix . $path;
643 fatal("No such file or directory: $path") unless -e $path;
644 my $is_dir = -d $path ? 1 : 0;
645 $path = $gs->{path} . '/' . $path;
646
647 # canonicalize the path (otherwise libsvn will abort or fail to
648 # find the file)
649 $path = canonicalize_path($path);
650
651 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
652 my $props;
653 if ($is_dir) {
654 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
655 }
656 else {
657 (undef, $props) = $gs->ra->get_file($path, $r, undef);
658 }
659 return $props;
660 }
661
662 # cmd_propget (PROP, PATH)
663 # ------------------------
664 # Print the SVN property PROP for PATH.
665 sub cmd_propget {
666 my ($prop, $path) = @_;
667 $path = '.' if not defined $path;
668 usage(1) if not defined $prop;
669 my $props = get_svnprops($path);
670 if (not defined $props->{$prop}) {
671 fatal("`$path' does not have a `$prop' SVN property.");
672 }
673 print $props->{$prop} . "\n";
674 }
675
676 # cmd_proplist (PATH)
677 # -------------------
678 # Print the list of SVN properties for PATH.
679 sub cmd_proplist {
680 my $path = shift;
681 $path = '.' if not defined $path;
682 my $props = get_svnprops($path);
683 print "Properties on '$path':\n";
684 foreach (sort keys %{$props}) {
685 print " $_\n";
686 }
687 }
688
689 sub cmd_multi_init {
690 my $url = shift;
691 unless (defined $_trunk || defined $_branches || defined $_tags) {
692 usage(1);
693 }
694
695 # there are currently some bugs that prevent multi-init/multi-fetch
696 # setups from working well without this.
697 $Git::SVN::_minimize_url = 1;
698
699 $_prefix = '' unless defined $_prefix;
700 if (defined $url) {
701 $url =~ s#/+$##;
702 init_subdir(@_);
703 }
704 do_git_init_db();
705 if (defined $_trunk) {
706 my $trunk_ref = $_prefix . 'trunk';
707 # try both old-style and new-style lookups:
708 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
709 unless ($gs_trunk) {
710 my ($trunk_url, $trunk_path) =
711 complete_svn_url($url, $_trunk);
712 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
713 undef, $trunk_ref);
714 }
715 }
716 return unless defined $_branches || defined $_tags;
717 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
718 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
719 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
720 }
721
722 sub cmd_multi_fetch {
723 my $remotes = Git::SVN::read_all_remotes();
724 foreach my $repo_id (sort keys %$remotes) {
725 if ($remotes->{$repo_id}->{url}) {
726 Git::SVN::fetch_all($repo_id, $remotes);
727 }
728 }
729 }
730
731 # this command is special because it requires no metadata
732 sub cmd_commit_diff {
733 my ($ta, $tb, $url) = @_;
734 my $usage = "Usage: $0 commit-diff -r<revision> ".
735 "<tree-ish> <tree-ish> [<URL>]";
736 fatal($usage) if (!defined $ta || !defined $tb);
737 my $svn_path;
738 if (!defined $url) {
739 my $gs = eval { Git::SVN->new };
740 if (!$gs) {
741 fatal("Needed URL or usable git-svn --id in ",
742 "the command-line\n", $usage);
743 }
744 $url = $gs->{url};
745 $svn_path = $gs->{path};
746 }
747 unless (defined $_revision) {
748 fatal("-r|--revision is a required argument\n", $usage);
749 }
750 if (defined $_message && defined $_file) {
751 fatal("Both --message/-m and --file/-F specified ",
752 "for the commit message.\n",
753 "I have no idea what you mean");
754 }
755 if (defined $_file) {
756 $_message = file_to_s($_file);
757 } else {
758 $_message ||= get_commit_entry($tb)->{log};
759 }
760 my $ra ||= Git::SVN::Ra->new($url);
761 $svn_path ||= $ra->{svn_path};
762 my $r = $_revision;
763 if ($r eq 'HEAD') {
764 $r = $ra->get_latest_revnum;
765 } elsif ($r !~ /^\d+$/) {
766 die "revision argument: $r not understood by git-svn\n";
767 }
768 my %ed_opts = ( r => $r,
769 log => $_message,
770 ra => $ra,
771 tree_a => $ta,
772 tree_b => $tb,
773 editor_cb => sub { print "Committed r$_[0]\n" },
774 svn_path => $svn_path );
775 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
776 print "No changes\n$ta == $tb\n";
777 }
778 }
779
780 sub cmd_info {
781 my $path = canonicalize_path(shift or ".");
782 unless (scalar(@_) == 0) {
783 die "Too many arguments specified\n";
784 }
785
786 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
787
788 if (!$file_type && !$diff_status) {
789 print STDERR "$path: (Not a versioned resource)\n\n";
790 return;
791 }
792
793 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
794 unless ($gs) {
795 die "Unable to determine upstream SVN information from ",
796 "working tree history\n";
797 }
798 my $full_url = $url . ($path eq "." ? "" : "/$path");
799
800 if ($_url) {
801 print $full_url, "\n";
802 return;
803 }
804
805 my $result = "Path: $path\n";
806 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
807 $result .= "URL: " . $full_url . "\n";
808
809 eval {
810 my $repos_root = $gs->repos_root;
811 Git::SVN::remove_username($repos_root);
812 $result .= "Repository Root: $repos_root\n";
813 };
814 if ($@) {
815 $result .= "Repository Root: (offline)\n";
816 }
817 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
818 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
819
820 $result .= "Node Kind: " .
821 ($file_type eq "dir" ? "directory" : "file") . "\n";
822
823 my $schedule = $diff_status eq "A"
824 ? "add"
825 : ($diff_status eq "D" ? "delete" : "normal");
826 $result .= "Schedule: $schedule\n";
827
828 if ($diff_status eq "A") {
829 print $result, "\n";
830 return;
831 }
832
833 my ($lc_author, $lc_rev, $lc_date_utc);
834 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
835 my $log = command_output_pipe(@args);
836 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
837 while (<$log>) {
838 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
839 $lc_author = $1;
840 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
841 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
842 (undef, $lc_rev, undef) = ::extract_metadata($1);
843 }
844 }
845 close $log;
846
847 Git::SVN::Log::set_local_timezone();
848
849 $result .= "Last Changed Author: $lc_author\n";
850 $result .= "Last Changed Rev: $lc_rev\n";
851 $result .= "Last Changed Date: " .
852 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
853
854 if ($file_type ne "dir") {
855 my $text_last_updated_date =
856 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
857 $result .=
858 "Text Last Updated: " .
859 Git::SVN::Log::format_svn_date($text_last_updated_date) .
860 "\n";
861 my $checksum;
862 if ($diff_status eq "D") {
863 my ($fh, $ctx) =
864 command_output_pipe(qw(cat-file blob), "HEAD:$path");
865 if ($file_type eq "link") {
866 my $file_name = <$fh>;
867 $checksum = md5sum("link $file_name");
868 } else {
869 $checksum = md5sum($fh);
870 }
871 command_close_pipe($fh, $ctx);
872 } elsif ($file_type eq "link") {
873 my $file_name =
874 command(qw(cat-file blob), "HEAD:$path");
875 $checksum =
876 md5sum("link " . $file_name);
877 } else {
878 open FILE, "<", $path or die $!;
879 $checksum = md5sum(\*FILE);
880 close FILE or die $!;
881 }
882 $result .= "Checksum: " . $checksum . "\n";
883 }
884
885 print $result, "\n";
886 }
887
888 ########################### utility functions #########################
889
890 sub rebase_cmd {
891 my @cmd = qw/rebase/;
892 push @cmd, '-v' if $_verbose;
893 push @cmd, qw/--merge/ if $_merge;
894 push @cmd, "--strategy=$_strategy" if $_strategy;
895 @cmd;
896 }
897
898 sub post_fetch_checkout {
899 return if $_no_checkout;
900 my $gs = $Git::SVN::_head or return;
901 return if verify_ref('refs/heads/master^0');
902
903 my $valid_head = verify_ref('HEAD^0');
904 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
905 return if ($valid_head || !verify_ref('HEAD^0'));
906
907 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
908 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
909 return if -f $index;
910
911 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
912 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
913 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
914 print STDERR "Checked out HEAD:\n ",
915 $gs->full_url, " r", $gs->last_rev, "\n";
916 }
917
918 sub complete_svn_url {
919 my ($url, $path) = @_;
920 $path =~ s#/+$##;
921 if ($path !~ m#^[a-z\+]+://#) {
922 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
923 fatal("E: '$path' is not a complete URL ",
924 "and a separate URL is not specified");
925 }
926 return ($url, $path);
927 }
928 return ($path, '');
929 }
930
931 sub complete_url_ls_init {
932 my ($ra, $repo_path, $switch, $pfx) = @_;
933 unless ($repo_path) {
934 print STDERR "W: $switch not specified\n";
935 return;
936 }
937 $repo_path =~ s#/+$##;
938 if ($repo_path =~ m#^[a-z\+]+://#) {
939 $ra = Git::SVN::Ra->new($repo_path);
940 $repo_path = '';
941 } else {
942 $repo_path =~ s#^/+##;
943 unless ($ra) {
944 fatal("E: '$repo_path' is not a complete URL ",
945 "and a separate URL is not specified");
946 }
947 }
948 my $url = $ra->{url};
949 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
950 my $k = "svn-remote.$gs->{repo_id}.url";
951 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
952 if ($orig_url && ($orig_url ne $gs->{url})) {
953 die "$k already set: $orig_url\n",
954 "wanted to set to: $gs->{url}\n";
955 }
956 command_oneline('config', $k, $gs->{url}) unless $orig_url;
957 my $remote_path = "$ra->{svn_path}/$repo_path/*";
958 $remote_path =~ s#/+#/#g;
959 $remote_path =~ s#^/##g;
960 my ($n) = ($switch =~ /^--(\w+)/);
961 if (length $pfx && $pfx !~ m#/$#) {
962 die "--prefix='$pfx' must have a trailing slash '/'\n";
963 }
964 command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
965 "$remote_path:refs/remotes/$pfx*");
966 }
967
968 sub verify_ref {
969 my ($ref) = @_;
970 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
971 { STDERR => 0 }); };
972 }
973
974 sub get_tree_from_treeish {
975 my ($treeish) = @_;
976 # $treeish can be a symbolic ref, too:
977 my $type = command_oneline(qw/cat-file -t/, $treeish);
978 my $expected;
979 while ($type eq 'tag') {
980 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
981 }
982 if ($type eq 'commit') {
983 $expected = (grep /^tree /, command(qw/cat-file commit/,
984 $treeish))[0];
985 ($expected) = ($expected =~ /^tree ($sha1)$/o);
986 die "Unable to get tree from $treeish\n" unless $expected;
987 } elsif ($type eq 'tree') {
988 $expected = $treeish;
989 } else {
990 die "$treeish is a $type, expected tree, tag or commit\n";
991 }
992 return $expected;
993 }
994
995 sub get_commit_entry {
996 my ($treeish) = shift;
997 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
998 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
999 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1000 open my $log_fh, '>', $commit_editmsg or croak $!;
1001
1002 my $type = command_oneline(qw/cat-file -t/, $treeish);
1003 if ($type eq 'commit' || $type eq 'tag') {
1004 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1005 $type, $treeish);
1006 my $in_msg = 0;
1007 while (<$msg_fh>) {
1008 if (!$in_msg) {
1009 $in_msg = 1 if (/^\s*$/);
1010 } elsif (/^git-svn-id: /) {
1011 # skip this for now, we regenerate the
1012 # correct one on re-fetch anyways
1013 # TODO: set *:merge properties or like...
1014 } else {
1015 print $log_fh $_ or croak $!;
1016 }
1017 }
1018 command_close_pipe($msg_fh, $ctx);
1019 }
1020 close $log_fh or croak $!;
1021
1022 if ($_edit || ($type eq 'tree')) {
1023 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1024 # TODO: strip out spaces, comments, like git-commit.sh
1025 system($editor, $commit_editmsg);
1026 }
1027 rename $commit_editmsg, $commit_msg or croak $!;
1028 open $log_fh, '<', $commit_msg or croak $!;
1029 { local $/; chomp($log_entry{log} = <$log_fh>); }
1030 close $log_fh or croak $!;
1031 unlink $commit_msg;
1032 \%log_entry;
1033 }
1034
1035 sub s_to_file {
1036 my ($str, $file, $mode) = @_;
1037 open my $fd,'>',$file or croak $!;
1038 print $fd $str,"\n" or croak $!;
1039 close $fd or croak $!;
1040 chmod ($mode &~ umask, $file) if (defined $mode);
1041 }
1042
1043 sub file_to_s {
1044 my $file = shift;
1045 open my $fd,'<',$file or croak "$!: file: $file\n";
1046 local $/;
1047 my $ret = <$fd>;
1048 close $fd or croak $!;
1049 $ret =~ s/\s*$//s;
1050 return $ret;
1051 }
1052
1053 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1054 sub load_authors {
1055 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1056 my $log = $cmd eq 'log';
1057 while (<$authors>) {
1058 chomp;
1059 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1060 my ($user, $name, $email) = ($1, $2, $3);
1061 if ($log) {
1062 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1063 } else {
1064 $users{$user} = [$name, $email];
1065 }
1066 }
1067 close $authors or croak $!;
1068 }
1069
1070 # convert GetOpt::Long specs for use by git-config
1071 sub read_repo_config {
1072 return unless -d $ENV{GIT_DIR};
1073 my $opts = shift;
1074 my @config_only;
1075 foreach my $o (keys %$opts) {
1076 # if we have mixedCase and a long option-only, then
1077 # it's a config-only variable that we don't need for
1078 # the command-line.
1079 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1080 my $v = $opts->{$o};
1081 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1082 $key =~ s/-//g;
1083 my $arg = 'git-config';
1084 $arg .= ' --int' if ($o =~ /[:=]i$/);
1085 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1086 if (ref $v eq 'ARRAY') {
1087 chomp(my @tmp = `$arg --get-all svn.$key`);
1088 @$v = @tmp if @tmp;
1089 } else {
1090 chomp(my $tmp = `$arg --get svn.$key`);
1091 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1092 $$v = $tmp;
1093 }
1094 }
1095 }
1096 delete @$opts{@config_only} if @config_only;
1097 }
1098
1099 sub extract_metadata {
1100 my $id = shift or return (undef, undef, undef);
1101 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1102 \s([a-f\d\-]+)$/x);
1103 if (!defined $rev || !$uuid || !$url) {
1104 # some of the original repositories I made had
1105 # identifiers like this:
1106 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1107 }
1108 return ($url, $rev, $uuid);
1109 }
1110
1111 sub cmt_metadata {
1112 return extract_metadata((grep(/^git-svn-id: /,
1113 command(qw/cat-file commit/, shift)))[-1]);
1114 }
1115
1116 sub working_head_info {
1117 my ($head, $refs) = @_;
1118 my @args = ('log', '--no-color', '--first-parent');
1119 my ($fh, $ctx) = command_output_pipe(@args, $head);
1120 my $hash;
1121 my %max;
1122 while (<$fh>) {
1123 if ( m{^commit ($::sha1)$} ) {
1124 unshift @$refs, $hash if $hash and $refs;
1125 $hash = $1;
1126 next;
1127 }
1128 next unless s{^\s*(git-svn-id:)}{$1};
1129 my ($url, $rev, $uuid) = extract_metadata($_);
1130 if (defined $url && defined $rev) {
1131 next if $max{$url} and $max{$url} < $rev;
1132 if (my $gs = Git::SVN->find_by_url($url)) {
1133 my $c = $gs->rev_map_get($rev);
1134 if ($c && $c eq $hash) {
1135 close $fh; # break the pipe
1136 return ($url, $rev, $uuid, $gs);
1137 } else {
1138 $max{$url} ||= $gs->rev_map_max;
1139 }
1140 }
1141 }
1142 }
1143 command_close_pipe($fh, $ctx);
1144 (undef, undef, undef, undef);
1145 }
1146
1147 sub read_commit_parents {
1148 my ($parents, $c) = @_;
1149 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1150 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1151 @{$parents->{$c}} = split(/ /, $p);
1152 }
1153
1154 sub linearize_history {
1155 my ($gs, $refs) = @_;
1156 my %parents;
1157 foreach my $c (@$refs) {
1158 read_commit_parents(\%parents, $c);
1159 }
1160
1161 my @linear_refs;
1162 my %skip = ();
1163 my $last_svn_commit = $gs->last_commit;
1164 foreach my $c (reverse @$refs) {
1165 next if $c eq $last_svn_commit;
1166 last if $skip{$c};
1167
1168 unshift @linear_refs, $c;
1169 $skip{$c} = 1;
1170
1171 # we only want the first parent to diff against for linear
1172 # history, we save the rest to inject when we finalize the
1173 # svn commit
1174 my $fp_a = verify_ref("$c~1");
1175 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1176 if (!$fp_a || !$fp_b) {
1177 die "Commit $c\n",
1178 "has no parent commit, and therefore ",
1179 "nothing to diff against.\n",
1180 "You should be working from a repository ",
1181 "originally created by git-svn\n";
1182 }
1183 if ($fp_a ne $fp_b) {
1184 die "$c~1 = $fp_a, however parsing commit $c ",
1185 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1186 }
1187
1188 foreach my $p (@{$parents{$c}}) {
1189 $skip{$p} = 1;
1190 }
1191 }
1192 (\@linear_refs, \%parents);
1193 }
1194
1195 sub find_file_type_and_diff_status {
1196 my ($path) = @_;
1197 return ('dir', '') if $path eq '.';
1198
1199 my $diff_output =
1200 command_oneline(qw(diff --cached --name-status --), $path) || "";
1201 my $diff_status = (split(' ', $diff_output))[0] || "";
1202
1203 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1204
1205 return (undef, undef) if !$diff_status && !$ls_tree;
1206
1207 if ($diff_status eq "A") {
1208 return ("link", $diff_status) if -l $path;
1209 return ("dir", $diff_status) if -d $path;
1210 return ("file", $diff_status);
1211 }
1212
1213 my $mode = (split(' ', $ls_tree))[0] || "";
1214
1215 return ("link", $diff_status) if $mode eq "120000";
1216 return ("dir", $diff_status) if $mode eq "040000";
1217 return ("file", $diff_status);
1218 }
1219
1220 sub md5sum {
1221 my $arg = shift;
1222 my $ref = ref $arg;
1223 my $md5 = Digest::MD5->new();
1224 if ($ref eq 'GLOB' || $ref eq 'IO::File') {
1225 $md5->addfile($arg) or croak $!;
1226 } elsif ($ref eq 'SCALAR') {
1227 $md5->add($$arg) or croak $!;
1228 } elsif (!$ref) {
1229 $md5->add($arg) or croak $!;
1230 } else {
1231 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1232 }
1233 return $md5->hexdigest();
1234 }
1235
1236 package Git::SVN;
1237 use strict;
1238 use warnings;
1239 use Fcntl qw/:DEFAULT :seek/;
1240 use constant rev_map_fmt => 'NH40';
1241 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1242 $_repack $_repack_flags $_use_svm_props $_head
1243 $_use_svnsync_props $no_reuse_existing $_minimize_url
1244 $_use_log_author/;
1245 use Carp qw/croak/;
1246 use File::Path qw/mkpath/;
1247 use File::Copy qw/copy/;
1248 use IPC::Open3;
1249
1250 my $_repack_nr;
1251 # properties that we do not log:
1252 my %SKIP_PROP;
1253 BEGIN {
1254 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1255 svn:special svn:executable
1256 svn:entry:committed-rev
1257 svn:entry:last-author
1258 svn:entry:uuid
1259 svn:entry:committed-date/;
1260
1261 # some options are read globally, but can be overridden locally
1262 # per [svn-remote "..."] section. Command-line options will *NOT*
1263 # override options set in an [svn-remote "..."] section
1264 no strict 'refs';
1265 for my $option (qw/follow_parent no_metadata use_svm_props
1266 use_svnsync_props/) {
1267 my $key = $option;
1268 $key =~ tr/_//d;
1269 my $prop = "-$option";
1270 *$option = sub {
1271 my ($self) = @_;
1272 return $self->{$prop} if exists $self->{$prop};
1273 my $k = "svn-remote.$self->{repo_id}.$key";
1274 eval { command_oneline(qw/config --get/, $k) };
1275 if ($@) {
1276 $self->{$prop} = ${"Git::SVN::_$option"};
1277 } else {
1278 my $v = command_oneline(qw/config --bool/,$k);
1279 $self->{$prop} = $v eq 'false' ? 0 : 1;
1280 }
1281 return $self->{$prop};
1282 }
1283 }
1284 }
1285
1286 my (%LOCKFILES, %INDEX_FILES);
1287 END {
1288 unlink keys %LOCKFILES if %LOCKFILES;
1289 unlink keys %INDEX_FILES if %INDEX_FILES;
1290 }
1291
1292 sub resolve_local_globs {
1293 my ($url, $fetch, $glob_spec) = @_;
1294 return unless defined $glob_spec;
1295 my $ref = $glob_spec->{ref};
1296 my $path = $glob_spec->{path};
1297 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1298 next unless m#^refs/remotes/$ref->{regex}$#;
1299 my $p = $1;
1300 my $pathname = desanitize_refname($path->full_path($p));
1301 my $refname = desanitize_refname($ref->full_path($p));
1302 if (my $existing = $fetch->{$pathname}) {
1303 if ($existing ne $refname) {
1304 die "Refspec conflict:\n",
1305 "existing: refs/remotes/$existing\n",
1306 " globbed: refs/remotes/$refname\n";
1307 }
1308 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1309 $u =~ s!^\Q$url\E(/|$)!! or die
1310 "refs/remotes/$refname: '$url' not found in '$u'\n";
1311 if ($pathname ne $u) {
1312 warn "W: Refspec glob conflict ",
1313 "(ref: refs/remotes/$refname):\n",
1314 "expected path: $pathname\n",
1315 " real path: $u\n",
1316 "Continuing ahead with $u\n";
1317 next;
1318 }
1319 } else {
1320 $fetch->{$pathname} = $refname;
1321 }
1322 }
1323 }
1324
1325 sub parse_revision_argument {
1326 my ($base, $head) = @_;
1327 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1328 return ($base, $head);
1329 }
1330 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1331 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1332 return ($head, $head) if ($::_revision eq 'HEAD');
1333 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1334 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1335 die "revision argument: $::_revision not understood by git-svn\n";
1336 }
1337
1338 sub fetch_all {
1339 my ($repo_id, $remotes) = @_;
1340 if (ref $repo_id) {
1341 my $gs = $repo_id;
1342 $repo_id = undef;
1343 $repo_id = $gs->{repo_id};
1344 }
1345 $remotes ||= read_all_remotes();
1346 my $remote = $remotes->{$repo_id} or
1347 die "[svn-remote \"$repo_id\"] unknown\n";
1348 my $fetch = $remote->{fetch};
1349 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1350 my (@gs, @globs);
1351 my $ra = Git::SVN::Ra->new($url);
1352 my $uuid = $ra->get_uuid;
1353 my $head = $ra->get_latest_revnum;
1354 my $base = defined $fetch ? $head : 0;
1355
1356 # read the max revs for wildcard expansion (branches/*, tags/*)
1357 foreach my $t (qw/branches tags/) {
1358 defined $remote->{$t} or next;
1359 push @globs, $remote->{$t};
1360 my $max_rev = eval { tmp_config(qw/--int --get/,
1361 "svn-remote.$repo_id.${t}-maxRev") };
1362 if (defined $max_rev && ($max_rev < $base)) {
1363 $base = $max_rev;
1364 } elsif (!defined $max_rev) {
1365 $base = 0;
1366 }
1367 }
1368
1369 if ($fetch) {
1370 foreach my $p (sort keys %$fetch) {
1371 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1372 my $lr = $gs->rev_map_max;
1373 if (defined $lr) {
1374 $base = $lr if ($lr < $base);
1375 }
1376 push @gs, $gs;
1377 }
1378 }
1379
1380 ($base, $head) = parse_revision_argument($base, $head);
1381 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1382 }
1383
1384 sub read_all_remotes {
1385 my $r = {};
1386 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1387 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1388 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1389 $local_ref =~ s{^/}{};
1390 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1391 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1392 $r->{$1}->{url} = $2;
1393 } elsif (m!^(.+)\.(branches|tags)=
1394 (.*):refs/remotes/(.+)\s*$/!x) {
1395 my ($p, $g) = ($3, $4);
1396 my $rs = $r->{$1}->{$2} = {
1397 t => $2,
1398 remote => $1,
1399 path => Git::SVN::GlobSpec->new($p),
1400 ref => Git::SVN::GlobSpec->new($g) };
1401 if (length($rs->{ref}->{right}) != 0) {
1402 die "The '*' glob character must be the last ",
1403 "character of '$g'\n";
1404 }
1405 }
1406 }
1407 $r;
1408 }
1409
1410 sub init_vars {
1411 if (defined $_repack) {
1412 $_repack = 1000 if ($_repack <= 0);
1413 $_repack_nr = $_repack;
1414 $_repack_flags ||= '-d';
1415 }
1416 }
1417
1418 sub verify_remotes_sanity {
1419 return unless -d $ENV{GIT_DIR};
1420 my %seen;
1421 foreach (command(qw/config -l/)) {
1422 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1423 if ($seen{$1}) {
1424 die "Remote ref refs/remote/$1 is tracked by",
1425 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1426 "Please resolve this ambiguity in ",
1427 "your git configuration file before ",
1428 "continuing\n";
1429 }
1430 $seen{$1} = $_;
1431 }
1432 }
1433 }
1434
1435 # we allow more chars than remotes2config.sh...
1436 sub sanitize_remote_name {
1437 my ($name) = @_;
1438 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1439 $name;
1440 }
1441
1442 sub find_existing_remote {
1443 my ($url, $remotes) = @_;
1444 return undef if $no_reuse_existing;
1445 my $existing;
1446 foreach my $repo_id (keys %$remotes) {
1447 my $u = $remotes->{$repo_id}->{url} or next;
1448 next if $u ne $url;
1449 $existing = $repo_id;
1450 last;
1451 }
1452 $existing;
1453 }
1454
1455 sub init_remote_config {
1456 my ($self, $url, $no_write) = @_;
1457 $url =~ s!/+$!!; # strip trailing slash
1458 my $r = read_all_remotes();
1459 my $existing = find_existing_remote($url, $r);
1460 if ($existing) {
1461 unless ($no_write) {
1462 print STDERR "Using existing ",
1463 "[svn-remote \"$existing\"]\n";
1464 }
1465 $self->{repo_id} = $existing;
1466 } elsif ($_minimize_url) {
1467 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1468 $existing = find_existing_remote($min_url, $r);
1469 if ($existing) {
1470 unless ($no_write) {
1471 print STDERR "Using existing ",
1472 "[svn-remote \"$existing\"]\n";
1473 }
1474 $self->{repo_id} = $existing;
1475 }
1476 if ($min_url ne $url) {
1477 unless ($no_write) {
1478 print STDERR "Using higher level of URL: ",
1479 "$url => $min_url\n";
1480 }
1481 my $old_path = $self->{path};
1482 $self->{path} = $url;
1483 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1484 if (length $old_path) {
1485 $self->{path} .= "/$old_path";
1486 }
1487 $url = $min_url;
1488 }
1489 }
1490 my $orig_url;
1491 if (!$existing) {
1492 # verify that we aren't overwriting anything:
1493 $orig_url = eval {
1494 command_oneline('config', '--get',
1495 "svn-remote.$self->{repo_id}.url")
1496 };
1497 if ($orig_url && ($orig_url ne $url)) {
1498 die "svn-remote.$self->{repo_id}.url already set: ",
1499 "$orig_url\nwanted to set to: $url\n";
1500 }
1501 }
1502 my ($xrepo_id, $xpath) = find_ref($self->refname);
1503 if (defined $xpath) {
1504 die "svn-remote.$xrepo_id.fetch already set to track ",
1505 "$xpath:refs/remotes/", $self->refname, "\n";
1506 }
1507 unless ($no_write) {
1508 command_noisy('config',
1509 "svn-remote.$self->{repo_id}.url", $url);
1510 $self->{path} =~ s{^/}{};
1511 command_noisy('config', '--add',
1512 "svn-remote.$self->{repo_id}.fetch",
1513 "$self->{path}:".$self->refname);
1514 }
1515 $self->{url} = $url;
1516 }
1517
1518 sub find_by_url { # repos_root and, path are optional
1519 my ($class, $full_url, $repos_root, $path) = @_;
1520
1521 return undef unless defined $full_url;
1522 remove_username($full_url);
1523 remove_username($repos_root) if defined $repos_root;
1524 my $remotes = read_all_remotes();
1525 if (defined $full_url && defined $repos_root && !defined $path) {
1526 $path = $full_url;
1527 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1528 }
1529 foreach my $repo_id (keys %$remotes) {
1530 my $u = $remotes->{$repo_id}->{url} or next;
1531 remove_username($u);
1532 next if defined $repos_root && $repos_root ne $u;
1533
1534 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1535 foreach (qw/branches tags/) {
1536 resolve_local_globs($u, $fetch,
1537 $remotes->{$repo_id}->{$_});
1538 }
1539 my $p = $path;
1540 unless (defined $p) {
1541 $p = $full_url;
1542 $p =~ s#^\Q$u\E(?:/|$)## or next;
1543 }
1544 foreach my $f (keys %$fetch) {
1545 next if $f ne $p;
1546 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1547 }
1548 }
1549 undef;
1550 }
1551
1552 sub init {
1553 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1554 my $self = _new($class, $repo_id, $ref_id, $path);
1555 if (defined $url) {
1556 $self->init_remote_config($url, $no_write);
1557 }
1558 $self;
1559 }
1560
1561 sub find_ref {
1562 my ($ref_id) = @_;
1563 foreach (command(qw/config -l/)) {
1564 next unless m!^svn-remote\.(.+)\.fetch=
1565 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1566 my ($repo_id, $path, $ref) = ($1, $2, $3);
1567 if ($ref eq $ref_id) {
1568 $path = '' if ($path =~ m#^\./?#);
1569 return ($repo_id, $path);
1570 }
1571 }
1572 (undef, undef, undef);
1573 }
1574
1575 sub new {
1576 my ($class, $ref_id, $repo_id, $path) = @_;
1577 if (defined $ref_id && !defined $repo_id && !defined $path) {
1578 ($repo_id, $path) = find_ref($ref_id);
1579 if (!defined $repo_id) {
1580 die "Could not find a \"svn-remote.*.fetch\" key ",
1581 "in the repository configuration matching: ",
1582 "refs/remotes/$ref_id\n";
1583 }
1584 }
1585 my $self = _new($class, $repo_id, $ref_id, $path);
1586 if (!defined $self->{path} || !length $self->{path}) {
1587 my $fetch = command_oneline('config', '--get',
1588 "svn-remote.$repo_id.fetch",
1589 ":refs/remotes/$ref_id\$") or
1590 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1591 "\":refs/remotes/$ref_id\$\" in config\n";
1592 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1593 }
1594 $self->{url} = command_oneline('config', '--get',
1595 "svn-remote.$repo_id.url") or
1596 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1597 $self->rebuild;
1598 $self;
1599 }
1600
1601 sub refname {
1602 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1603
1604 # It cannot end with a slash /, we'll throw up on this because
1605 # SVN can't have directories with a slash in their name, either:
1606 if ($refname =~ m{/$}) {
1607 die "ref: '$refname' ends with a trailing slash, this is ",
1608 "not permitted by git nor Subversion\n";
1609 }
1610
1611 # It cannot have ASCII control character space, tilde ~, caret ^,
1612 # colon :, question-mark ?, asterisk *, space, or open bracket [
1613 # anywhere.
1614 #
1615 # Additionally, % must be escaped because it is used for escaping
1616 # and we want our escaped refname to be reversible
1617 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1618
1619 # no slash-separated component can begin with a dot .
1620 # /.* becomes /%2E*
1621 $refname =~ s{/\.}{/%2E}g;
1622
1623 # It cannot have two consecutive dots .. anywhere
1624 # .. becomes %2E%2E
1625 $refname =~ s{\.\.}{%2E%2E}g;
1626
1627 return $refname;
1628 }
1629
1630 sub desanitize_refname {
1631 my ($refname) = @_;
1632 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1633 return $refname;
1634 }
1635
1636 sub svm_uuid {
1637 my ($self) = @_;
1638 return $self->{svm}->{uuid} if $self->svm;
1639 $self->ra;
1640 unless ($self->{svm}) {
1641 die "SVM UUID not cached, and reading remotely failed\n";
1642 }
1643 $self->{svm}->{uuid};
1644 }
1645
1646 sub svm {
1647 my ($self) = @_;
1648 return $self->{svm} if $self->{svm};
1649 my $svm;
1650 # see if we have it in our config, first:
1651 eval {
1652 my $section = "svn-remote.$self->{repo_id}";
1653 $svm = {
1654 source => tmp_config('--get', "$section.svm-source"),
1655 uuid => tmp_config('--get', "$section.svm-uuid"),
1656 replace => tmp_config('--get', "$section.svm-replace"),
1657 }
1658 };
1659 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1660 $self->{svm} = $svm;
1661 }
1662 $self->{svm};
1663 }
1664
1665 sub _set_svm_vars {
1666 my ($self, $ra) = @_;
1667 return $ra if $self->svm;
1668
1669 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1670 "(svm:source, svm:uuid) ",
1671 "from the following URLs:\n" );
1672 sub read_svm_props {
1673 my ($self, $ra, $path, $r) = @_;
1674 my $props = ($ra->get_dir($path, $r))[2];
1675 my $src = $props->{'svm:source'};
1676 my $uuid = $props->{'svm:uuid'};
1677 return undef if (!$src || !$uuid);
1678
1679 chomp($src, $uuid);
1680
1681 $uuid =~ m{^[0-9a-f\-]{30,}$}
1682 or die "doesn't look right - svm:uuid is '$uuid'\n";
1683
1684 # the '!' is used to mark the repos_root!/relative/path
1685 $src =~ s{/?!/?}{/};
1686 $src =~ s{/+$}{}; # no trailing slashes please
1687 # username is of no interest
1688 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1689
1690 my $replace = $ra->{url};
1691 $replace .= "/$path" if length $path;
1692
1693 my $section = "svn-remote.$self->{repo_id}";
1694 tmp_config("$section.svm-source", $src);
1695 tmp_config("$section.svm-replace", $replace);
1696 tmp_config("$section.svm-uuid", $uuid);
1697 $self->{svm} = {
1698 source => $src,
1699 uuid => $uuid,
1700 replace => $replace
1701 };
1702 }
1703
1704 my $r = $ra->get_latest_revnum;
1705 my $path = $self->{path};
1706 my %tried;
1707 while (length $path) {
1708 unless ($tried{"$self->{url}/$path"}) {
1709 return $ra if $self->read_svm_props($ra, $path, $r);
1710 $tried{"$self->{url}/$path"} = 1;
1711 }
1712 $path =~ s#/?[^/]+$##;
1713 }
1714 die "Path: '$path' should be ''\n" if $path ne '';
1715 return $ra if $self->read_svm_props($ra, $path, $r);
1716 $tried{"$self->{url}/$path"} = 1;
1717
1718 if ($ra->{repos_root} eq $self->{url}) {
1719 die @err, (map { " $_\n" } keys %tried), "\n";
1720 }
1721
1722 # nope, make sure we're connected to the repository root:
1723 my $ok;
1724 my @tried_b;
1725 $path = $ra->{svn_path};
1726 $ra = Git::SVN::Ra->new($ra->{repos_root});
1727 while (length $path) {
1728 unless ($tried{"$ra->{url}/$path"}) {
1729 $ok = $self->read_svm_props($ra, $path, $r);
1730 last if $ok;
1731 $tried{"$ra->{url}/$path"} = 1;
1732 }
1733 $path =~ s#/?[^/]+$##;
1734 }
1735 die "Path: '$path' should be ''\n" if $path ne '';
1736 $ok ||= $self->read_svm_props($ra, $path, $r);
1737 $tried{"$ra->{url}/$path"} = 1;
1738 if (!$ok) {
1739 die @err, (map { " $_\n" } keys %tried), "\n";
1740 }
1741 Git::SVN::Ra->new($self->{url});
1742 }
1743
1744 sub svnsync {
1745 my ($self) = @_;
1746 return $self->{svnsync} if $self->{svnsync};
1747
1748 if ($self->no_metadata) {
1749 die "Can't have both 'noMetadata' and ",
1750 "'useSvnsyncProps' options set!\n";
1751 }
1752 if ($self->rewrite_root) {
1753 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1754 "options set!\n";
1755 }
1756
1757 my $svnsync;
1758 # see if we have it in our config, first:
1759 eval {
1760 my $section = "svn-remote.$self->{repo_id}";
1761 $svnsync = {
1762 url => tmp_config('--get', "$section.svnsync-url"),
1763 uuid => tmp_config('--get', "$section.svnsync-uuid"),
1764 }
1765 };
1766 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1767 return $self->{svnsync} = $svnsync;
1768 }
1769
1770 my $err = "useSvnsyncProps set, but failed to read " .
1771 "svnsync property: svn:sync-from-";
1772 my $rp = $self->ra->rev_proplist(0);
1773
1774 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1775 $url =~ m{^[a-z\+]+://} or
1776 die "doesn't look right - svn:sync-from-url is '$url'\n";
1777
1778 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1779 $uuid =~ m{^[0-9a-f\-]{30,}$} or
1780 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1781
1782 my $section = "svn-remote.$self->{repo_id}";
1783 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1784 tmp_config('--add', "$section.svnsync-url", $url);
1785 return $self->{svnsync} = { url => $url, uuid => $uuid };
1786 }
1787
1788 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1789 # remote lookup (useful for 'git svn log').
1790 sub ra_uuid {
1791 my ($self) = @_;
1792 unless ($self->{ra_uuid}) {
1793 my $key = "svn-remote.$self->{repo_id}.uuid";
1794 my $uuid = eval { tmp_config('--get', $key) };
1795 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1796 $self->{ra_uuid} = $uuid;
1797 } else {
1798 die "ra_uuid called without URL\n" unless $self->{url};
1799 $self->{ra_uuid} = $self->ra->get_uuid;
1800 tmp_config('--add', $key, $self->{ra_uuid});
1801 }
1802 }
1803 $self->{ra_uuid};
1804 }
1805
1806 sub _set_repos_root {
1807 my ($self, $repos_root) = @_;
1808 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1809 $repos_root ||= $self->ra->{repos_root};
1810 tmp_config($k, $repos_root);
1811 $repos_root;
1812 }
1813
1814 sub repos_root {
1815 my ($self) = @_;
1816 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1817 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1818 }
1819
1820 sub ra {
1821 my ($self) = shift;
1822 my $ra = Git::SVN::Ra->new($self->{url});
1823 $self->_set_repos_root($ra->{repos_root});
1824 if ($self->use_svm_props && !$self->{svm}) {
1825 if ($self->no_metadata) {
1826 die "Can't have both 'noMetadata' and ",
1827 "'useSvmProps' options set!\n";
1828 } elsif ($self->use_svnsync_props) {
1829 die "Can't have both 'useSvnsyncProps' and ",
1830 "'useSvmProps' options set!\n";
1831 }
1832 $ra = $self->_set_svm_vars($ra);
1833 $self->{-want_revprops} = 1;
1834 }
1835 $ra;
1836 }
1837
1838 sub rel_path {
1839 my ($self) = @_;
1840 my $repos_root = $self->ra->{repos_root};
1841 return $self->{path} if ($self->{url} eq $repos_root);
1842 my $url = $self->{url} .
1843 (length $self->{path} ? "/$self->{path}" : $self->{path});
1844 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1845 $url;
1846 }
1847
1848 # prop_walk(PATH, REV, SUB)
1849 # -------------------------
1850 # Recursively traverse PATH at revision REV and invoke SUB for each
1851 # directory that contains a SVN property. SUB will be invoked as
1852 # follows: &SUB(gs, path, props); where `gs' is this instance of
1853 # Git::SVN, `path' the path to the directory where the properties
1854 # `props' were found. The `path' will be relative to point of checkout,
1855 # that is, if url://repo/trunk is the current Git branch, and that
1856 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1857 # as `path' (note the trailing `/').
1858 sub prop_walk {
1859 my ($self, $path, $rev, $sub) = @_;
1860
1861 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1862 $path =~ s#^/*#/#g;
1863 my $p = $path;
1864 # Strip the irrelevant part of the path.
1865 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1866 # Ensure the path is terminated by a `/'.
1867 $p =~ s#/*$#/#;
1868
1869 # The properties contain all the internal SVN stuff nobody
1870 # (usually) cares about.
1871 my $interesting_props = 0;
1872 foreach (keys %{$props}) {
1873 # If it doesn't start with `svn:', it must be a
1874 # user-defined property.
1875 ++$interesting_props and next if $_ !~ /^svn:/;
1876 # FIXME: Fragile, if SVN adds new public properties,
1877 # this needs to be updated.
1878 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1879 |eol-style|mime-type
1880 |externals|needs-lock)$/x;
1881 }
1882 &$sub($self, $p, $props) if $interesting_props;
1883
1884 foreach (sort keys %$dirent) {
1885 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1886 $self->prop_walk($path . '/' . $_, $rev, $sub);
1887 }
1888 }
1889
1890 sub last_rev { ($_[0]->last_rev_commit)[0] }
1891 sub last_commit { ($_[0]->last_rev_commit)[1] }
1892
1893 # returns the newest SVN revision number and newest commit SHA1
1894 sub last_rev_commit {
1895 my ($self) = @_;
1896 if (defined $self->{last_rev} && defined $self->{last_commit}) {
1897 return ($self->{last_rev}, $self->{last_commit});
1898 }
1899 my $c = ::verify_ref($self->refname.'^0');
1900 if ($c && !$self->use_svm_props && !$self->no_metadata) {
1901 my $rev = (::cmt_metadata($c))[1];
1902 if (defined $rev) {
1903 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1904 return ($rev, $c);
1905 }
1906 }
1907 my $map_path = $self->map_path;
1908 unless (-e $map_path) {
1909 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1910 return (undef, undef);
1911 }
1912 my ($rev, $commit) = $self->rev_map_max(1);
1913 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
1914 return ($rev, $commit);
1915 }
1916
1917 sub get_fetch_range {
1918 my ($self, $min, $max) = @_;
1919 $max ||= $self->ra->get_latest_revnum;
1920 $min ||= $self->rev_map_max;
1921 (++$min, $max);
1922 }
1923
1924 sub tmp_config {
1925 my (@args) = @_;
1926 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1927 my $config = "$ENV{GIT_DIR}/svn/.metadata";
1928 if (! -f $config && -f $old_def_config) {
1929 rename $old_def_config, $config or
1930 die "Failed rename $old_def_config => $config: $!\n";
1931 }
1932 my $old_config = $ENV{GIT_CONFIG};
1933 $ENV{GIT_CONFIG} = $config;
1934 $@ = undef;
1935 my @ret = eval {
1936 unless (-f $config) {
1937 mkfile($config);
1938 open my $fh, '>', $config or
1939 die "Can't open $config: $!\n";
1940 print $fh "; This file is used internally by ",
1941 "git-svn\n" or die
1942 "Couldn't write to $config: $!\n";
1943 print $fh "; You should not have to edit it\n" or
1944 die "Couldn't write to $config: $!\n";
1945 close $fh or die "Couldn't close $config: $!\n";
1946 }
1947 command('config', @args);
1948 };
1949 my $err = $@;
1950 if (defined $old_config) {
1951 $ENV{GIT_CONFIG} = $old_config;
1952 } else {
1953 delete $ENV{GIT_CONFIG};
1954 }
1955 die $err if $err;
1956 wantarray ? @ret : $ret[0];
1957 }
1958
1959 sub tmp_index_do {
1960 my ($self, $sub) = @_;
1961 my $old_index = $ENV{GIT_INDEX_FILE};
1962 $ENV{GIT_INDEX_FILE} = $self->{index};
1963 $@ = undef;
1964 my @ret = eval {
1965 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1966 mkpath([$dir]) unless -d $dir;
1967 &$sub;
1968 };
1969 my $err = $@;
1970 if (defined $old_index) {
1971 $ENV{GIT_INDEX_FILE} = $old_index;
1972 } else {
1973 delete $ENV{GIT_INDEX_FILE};
1974 }
1975 die $err if $err;
1976 wantarray ? @ret : $ret[0];
1977 }
1978
1979 sub assert_index_clean {
1980 my ($self, $treeish) = @_;
1981
1982 $self->tmp_index_do(sub {
1983 command_noisy('read-tree', $treeish) unless -e $self->{index};
1984 my $x = command_oneline('write-tree');
1985 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1986 /^tree ($::sha1)/mo);
1987 return if $y eq $x;
1988
1989 warn "Index mismatch: $y != $x\nrereading $treeish\n";
1990 unlink $self->{index} or die "unlink $self->{index}: $!\n";
1991 command_noisy('read-tree', $treeish);
1992 $x = command_oneline('write-tree');
1993 if ($y ne $x) {
1994 ::fatal "trees ($treeish) $y != $x\n",
1995 "Something is seriously wrong...";
1996 }
1997 });
1998 }
1999
2000 sub get_commit_parents {
2001 my ($self, $log_entry) = @_;
2002 my (%seen, @ret, @tmp);
2003 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2004 if (my $ip = $self->{inject_parents}) {
2005 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2006 push @tmp, $commit;
2007 }
2008 }
2009 if (my $cur = ::verify_ref($self->refname.'^0')) {
2010 push @tmp, $cur;
2011 }
2012 if (my $ipd = $self->{inject_parents_dcommit}) {
2013 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2014 push @tmp, @$commit;
2015 }
2016 }
2017 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2018 while (my $p = shift @tmp) {
2019 next if $seen{$p};
2020 $seen{$p} = 1;
2021 push @ret, $p;
2022 # MAXPARENT is defined to 16 in commit-tree.c:
2023 last if @ret >= 16;
2024 }
2025 if (@tmp) {
2026 die "r$log_entry->{revision}: No room for parents:\n\t",
2027 join("\n\t", @tmp), "\n";
2028 }
2029 @ret;
2030 }
2031
2032 sub rewrite_root {
2033 my ($self) = @_;
2034 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2035 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2036 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2037 if ($rwr) {
2038 $rwr =~ s#/+$##;
2039 if ($rwr !~ m#^[a-z\+]+://#) {
2040 die "$rwr is not a valid URL (key: $k)\n";
2041 }
2042 }
2043 $self->{-rewrite_root} = $rwr;
2044 }
2045
2046 sub metadata_url {
2047 my ($self) = @_;
2048 ($self->rewrite_root || $self->{url}) .
2049 (length $self->{path} ? '/' . $self->{path} : '');
2050 }
2051
2052 sub full_url {
2053 my ($self) = @_;
2054 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2055 }
2056
2057
2058 sub set_commit_header_env {
2059 my ($log_entry) = @_;
2060 my %env;
2061 foreach my $ned (qw/NAME EMAIL DATE/) {
2062 foreach my $ac (qw/AUTHOR COMMITTER/) {
2063 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2064 }
2065 }
2066
2067 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2068 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2069 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2070
2071 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2072 ? $log_entry->{commit_name}
2073 : $log_entry->{name};
2074 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2075 ? $log_entry->{commit_email}
2076 : $log_entry->{email};
2077 \%env;
2078 }
2079
2080 sub restore_commit_header_env {
2081 my ($env) = @_;
2082 foreach my $ned (qw/NAME EMAIL DATE/) {
2083 foreach my $ac (qw/AUTHOR COMMITTER/) {
2084 my $k = "GIT_${ac}_${ned}";
2085 if (defined $env->{$k}) {
2086 $ENV{$k} = $env->{$k};
2087 } else {
2088 delete $ENV{$k};
2089 }
2090 }
2091 }
2092 }
2093
2094 sub do_git_commit {
2095 my ($self, $log_entry) = @_;
2096 my $lr = $self->last_rev;
2097 if (defined $lr && $lr >= $log_entry->{revision}) {
2098 die "Last fetched revision of ", $self->refname,
2099 " was r$lr, but we are about to fetch: ",
2100 "r$log_entry->{revision}!\n";
2101 }
2102 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2103 croak "$log_entry->{revision} = $c already exists! ",
2104 "Why are we refetching it?\n";
2105 }
2106 my $old_env = set_commit_header_env($log_entry);
2107 my $tree = $log_entry->{tree};
2108 if (!defined $tree) {
2109 $tree = $self->tmp_index_do(sub {
2110 command_oneline('write-tree') });
2111 }
2112 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2113
2114 my @exec = ('git-commit-tree', $tree);
2115 foreach ($self->get_commit_parents($log_entry)) {
2116 push @exec, '-p', $_;
2117 }
2118 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2119 or croak $!;
2120 print $msg_fh $log_entry->{log} or croak $!;
2121 restore_commit_header_env($old_env);
2122 unless ($self->no_metadata) {
2123 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2124 or croak $!;
2125 }
2126 $msg_fh->flush == 0 or croak $!;
2127 close $msg_fh or croak $!;
2128 chomp(my $commit = do { local $/; <$out_fh> });
2129 close $out_fh or croak $!;
2130 waitpid $pid, 0;
2131 croak $? if $?;
2132 if ($commit !~ /^$::sha1$/o) {
2133 die "Failed to commit, invalid sha1: $commit\n";
2134 }
2135
2136 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2137
2138 $self->{last_rev} = $log_entry->{revision};
2139 $self->{last_commit} = $commit;
2140 print "r$log_entry->{revision}";
2141 if (defined $log_entry->{svm_revision}) {
2142 print " (\@$log_entry->{svm_revision})";
2143 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2144 0, $self->svm_uuid);
2145 }
2146 print " = $commit ($self->{ref_id})\n";
2147 if (defined $_repack && (--$_repack_nr == 0)) {
2148 $_repack_nr = $_repack;
2149 # repack doesn't use any arguments with spaces in them, does it?
2150 print "Running git repack $_repack_flags ...\n";
2151 command_noisy('repack', split(/\s+/, $_repack_flags));
2152 print "Done repacking\n";
2153 }
2154 return $commit;
2155 }
2156
2157 sub match_paths {
2158 my ($self, $paths, $r) = @_;
2159 return 1 if $self->{path} eq '';
2160 if (my $path = $paths->{"/$self->{path}"}) {
2161 return ($path->{action} eq 'D') ? 0 : 1;
2162 }
2163 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2164 if (grep /$self->{path_regex}/, keys %$paths) {
2165 return 1;
2166 }
2167 my $c = '';
2168 foreach (split m#/#, $self->{path}) {
2169 $c .= "/$_";
2170 next unless ($paths->{$c} &&
2171 ($paths->{$c}->{action} =~ /^[AR]$/));
2172 if ($self->ra->check_path($self->{path}, $r) ==
2173 $SVN::Node::dir) {
2174 return 1;
2175 }
2176 }
2177 return 0;
2178 }
2179
2180 sub find_parent_branch {
2181 my ($self, $paths, $rev) = @_;
2182 return undef unless $self->follow_parent;
2183 unless (defined $paths) {
2184 my $err_handler = $SVN::Error::handler;
2185 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2186 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2187 $paths =
2188 Git::SVN::Ra::dup_changed_paths($_[0]) });
2189 $SVN::Error::handler = $err_handler;
2190 }
2191 return undef unless defined $paths;
2192
2193 # look for a parent from another branch:
2194 my @b_path_components = split m#/#, $self->rel_path;
2195 my @a_path_components;
2196 my $i;
2197 while (@b_path_components) {
2198 $i = $paths->{'/'.join('/', @b_path_components)};
2199 last if $i && defined $i->{copyfrom_path};
2200 unshift(@a_path_components, pop(@b_path_components));
2201 }
2202 return undef unless defined $i && defined $i->{copyfrom_path};
2203 my $branch_from = $i->{copyfrom_path};
2204 if (@a_path_components) {
2205 print STDERR "branch_from: $branch_from => ";
2206 $branch_from .= '/'.join('/', @a_path_components);
2207 print STDERR $branch_from, "\n";
2208 }
2209 my $r = $i->{copyfrom_rev};
2210 my $repos_root = $self->ra->{repos_root};
2211 my $url = $self->ra->{url};
2212 my $new_url = $repos_root . $branch_from;
2213 print STDERR "Found possible branch point: ",
2214 "$new_url => ", $self->full_url, ", $r\n";
2215 $branch_from =~ s#^/##;
2216 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2217 unless ($gs) {
2218 my $ref_id = $self->{ref_id};
2219 $ref_id =~ s/\@\d+$//;
2220 $ref_id .= "\@$r";
2221 # just grow a tail if we're not unique enough :x
2222 $ref_id .= '-' while find_ref($ref_id);
2223 print STDERR "Initializing parent: $ref_id\n";
2224 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
2225 }
2226 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2227 if (!defined $r0 || !defined $parent) {
2228 my ($base, $head) = parse_revision_argument(0, $r);
2229 if ($base <= $r) {
2230 $gs->fetch($base, $r);
2231 }
2232 ($r0, $parent) = $gs->last_rev_commit;
2233 }
2234 if (defined $r0 && defined $parent) {
2235 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2236 my $ed;
2237 if ($self->ra->can_do_switch) {
2238 $self->assert_index_clean($parent);
2239 print STDERR "Following parent with do_switch\n";
2240 # do_switch works with svn/trunk >= r22312, but that
2241 # is not included with SVN 1.4.3 (the latest version
2242 # at the moment), so we can't rely on it
2243 $self->{last_commit} = $parent;
2244 $ed = SVN::Git::Fetcher->new($self);
2245 $gs->ra->gs_do_switch($r0, $rev, $gs,
2246 $self->full_url, $ed)
2247 or die "SVN connection failed somewhere...\n";
2248 } elsif ($self->ra->trees_match($new_url, $r0,
2249 $self->full_url, $rev)) {
2250 print STDERR "Trees match:\n",
2251 " $new_url\@$r0\n",
2252 " ${\$self->full_url}\@$rev\n",
2253 "Following parent with no changes\n";
2254 $self->tmp_index_do(sub {
2255 command_noisy('read-tree', $parent);
2256 });
2257 $self->{last_commit} = $parent;
2258 } else {
2259 print STDERR "Following parent with do_update\n";
2260 $ed = SVN::Git::Fetcher->new($self);
2261 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2262 or die "SVN connection failed somewhere...\n";
2263 }
2264 print STDERR "Successfully followed parent\n";
2265 return $self->make_log_entry($rev, [$parent], $ed);
2266 }
2267 return undef;
2268 }
2269
2270 sub do_fetch {
2271 my ($self, $paths, $rev) = @_;
2272 my $ed;
2273 my ($last_rev, @parents);
2274 if (my $lc = $self->last_commit) {
2275 # we can have a branch that was deleted, then re-added
2276 # under the same name but copied from another path, in
2277 # which case we'll have multiple parents (we don't
2278 # want to break the original ref, nor lose copypath info):
2279 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2280 push @{$log_entry->{parents}}, $lc;
2281 return $log_entry;
2282 }
2283 $ed = SVN::Git::Fetcher->new($self);
2284 $last_rev = $self->{last_rev};
2285 $ed->{c} = $lc;
2286 @parents = ($lc);
2287 } else {
2288 $last_rev = $rev;
2289 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2290 return $log_entry;
2291 }
2292 $ed = SVN::Git::Fetcher->new($self);
2293 }
2294 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2295 die "SVN connection failed somewhere...\n";
2296 }
2297 $self->make_log_entry($rev, \@parents, $ed);
2298 }
2299
2300 sub get_untracked {
2301 my ($self, $ed) = @_;
2302 my @out;
2303 my $h = $ed->{empty};
2304 foreach (sort keys %$h) {
2305 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2306 push @out, " $act: " . uri_encode($_);
2307 warn "W: $act: $_\n";
2308 }
2309 foreach my $t (qw/dir_prop file_prop/) {
2310 $h = $ed->{$t} or next;
2311 foreach my $path (sort keys %$h) {
2312 my $ppath = $path eq '' ? '.' : $path;
2313 foreach my $prop (sort keys %{$h->{$path}}) {
2314 next if $SKIP_PROP{$prop};
2315 my $v = $h->{$path}->{$prop};
2316 my $t_ppath_prop = "$t: " .
2317 uri_encode($ppath) . ' ' .
2318 uri_encode($prop);
2319 if (defined $v) {
2320 push @out, " +$t_ppath_prop " .
2321 uri_encode($v);
2322 } else {
2323 push @out, " -$t_ppath_prop";
2324 }
2325 }
2326 }
2327 }
2328 foreach my $t (qw/absent_file absent_directory/) {
2329 $h = $ed->{$t} or next;
2330 foreach my $parent (sort keys %$h) {
2331 foreach my $path (sort @{$h->{$parent}}) {
2332 push @out, " $t: " .
2333 uri_encode("$parent/$path");
2334 warn "W: $t: $parent/$path ",
2335 "Insufficient permissions?\n";
2336 }
2337 }
2338 }
2339 \@out;
2340 }
2341
2342 sub parse_svn_date {
2343 my $date = shift || return '+0000 1970-01-01 00:00:00';
2344 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2345 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2346 croak "Unable to parse date: $date\n";
2347 "+0000 $Y-$m-$d $H:$M:$S";
2348 }
2349
2350 sub check_author {
2351 my ($author) = @_;
2352 if (!defined $author || length $author == 0) {
2353 $author = '(no author)';
2354 }
2355 if (defined $::_authors && ! defined $::users{$author}) {
2356 die "Author: $author not defined in $::_authors file\n";
2357 }
2358 $author;
2359 }
2360
2361 sub make_log_entry {
2362 my ($self, $rev, $parents, $ed) = @_;
2363 my $untracked = $self->get_untracked($ed);
2364
2365 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2366 print $un "r$rev\n" or croak $!;
2367 print $un $_, "\n" foreach @$untracked;
2368 my %log_entry = ( parents => $parents || [], revision => $rev,
2369 log => '');
2370
2371 my $headrev;
2372 my $logged = delete $self->{logged_rev_props};
2373 if (!$logged || $self->{-want_revprops}) {
2374 my $rp = $self->ra->rev_proplist($rev);
2375 foreach (sort keys %$rp) {
2376 my $v = $rp->{$_};
2377 if (/^svn:(author|date|log)$/) {
2378 $log_entry{$1} = $v;
2379 } elsif ($_ eq 'svm:headrev') {
2380 $headrev = $v;
2381 } else {
2382 print $un " rev_prop: ", uri_encode($_), ' ',
2383 uri_encode($v), "\n";
2384 }
2385 }
2386 } else {
2387 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2388 }
2389 close $un or croak $!;
2390
2391 $log_entry{date} = parse_svn_date($log_entry{date});
2392 $log_entry{log} .= "\n";
2393 my $author = $log_entry{author} = check_author($log_entry{author});
2394 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2395 : ($author, undef);
2396
2397 my ($commit_name, $commit_email) = ($name, $email);
2398 if ($_use_log_author) {
2399 my $name_field;
2400 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2401 $name_field = $1;
2402 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2403 $name_field = $1;
2404 }
2405 if (!defined $name_field) {
2406 #
2407 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2408 ($name, $email) = ($1, $2);
2409 } elsif ($name_field =~ /(.*)@/) {
2410 ($name, $email) = ($1, $name_field);
2411 } else {
2412 ($name, $email) = ($name_field, 'unknown');
2413 }
2414 }
2415 if (defined $headrev && $self->use_svm_props) {
2416 if ($self->rewrite_root) {
2417 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2418 "options set!\n";
2419 }
2420 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2421 # we don't want "SVM: initializing mirror for junk" ...
2422 return undef if $r == 0;
2423 my $svm = $self->svm;
2424 if ($uuid ne $svm->{uuid}) {
2425 die "UUID mismatch on SVM path:\n",
2426 "expected: $svm->{uuid}\n",
2427 " got: $uuid\n";
2428 }
2429 my $full_url = $self->full_url;
2430 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2431 die "Failed to replace '$svm->{replace}' with ",
2432 "'$svm->{source}' in $full_url\n";
2433 # throw away username for storing in records
2434 remove_username($full_url);
2435 $log_entry{metadata} = "$full_url\@$r $uuid";
2436 $log_entry{svm_revision} = $r;
2437 $email ||= "$author\@$uuid";
2438 $commit_email ||= "$author\@$uuid";
2439 } elsif ($self->use_svnsync_props) {
2440 my $full_url = $self->svnsync->{url};
2441 $full_url .= "/$self->{path}" if length $self->{path};
2442 remove_username($full_url);
2443 my $uuid = $self->svnsync->{uuid};
2444 $log_entry{metadata} = "$full_url\@$rev $uuid";
2445 $email ||= "$author\@$uuid";
2446 $commit_email ||= "$author\@$uuid";
2447 } else {
2448 my $url = $self->metadata_url;
2449 remove_username($url);
2450 $log_entry{metadata} = "$url\@$rev " .
2451 $self->ra->get_uuid;
2452 $email ||= "$author\@" . $self->ra->get_uuid;
2453 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2454 }
2455 $log_entry{name} = $name;
2456 $log_entry{email} = $email;
2457 $log_entry{commit_name} = $commit_name;
2458 $log_entry{commit_email} = $commit_email;
2459 \%log_entry;
2460 }
2461
2462 sub fetch {
2463 my ($self, $min_rev, $max_rev, @parents) = @_;
2464 my ($last_rev, $last_commit) = $self->last_rev_commit;
2465 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2466 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2467 }
2468
2469 sub set_tree_cb {
2470 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2471 $self->{inject_parents} = { $rev => $tree };
2472 $self->fetch(undef, undef);
2473 }
2474
2475 sub set_tree {
2476 my ($self, $tree) = (shift, shift);
2477 my $log_entry = ::get_commit_entry($tree);
2478 unless ($self->{last_rev}) {
2479 fatal("Must have an existing revision to commit");
2480 }
2481 my %ed_opts = ( r => $self->{last_rev},
2482 log => $log_entry->{log},
2483 ra => $self->ra,
2484 tree_a => $self->{last_commit},
2485 tree_b => $tree,
2486 editor_cb => sub {
2487 $self->set_tree_cb($log_entry, $tree, @_) },
2488 svn_path => $self->{path} );
2489 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2490 print "No changes\nr$self->{last_rev} = $tree\n";
2491 }
2492 }
2493
2494 sub rebuild_from_rev_db {
2495 my ($self, $path) = @_;
2496 my $r = -1;
2497 open my $fh, '<', $path or croak "open: $!";
2498 while (<$fh>) {
2499 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2500 chomp($_);
2501 ++$r;
2502 next if $_ eq ('0' x 40);
2503 $self->rev_map_set($r, $_);
2504 print "r$r = $_\n";
2505 }
2506 close $fh or croak "close: $!";
2507 unlink $path or croak "unlink: $!";
2508 }
2509
2510 sub rebuild {
2511 my ($self) = @_;
2512 my $map_path = $self->map_path;
2513 return if (-e $map_path && ! -z $map_path);
2514 return unless ::verify_ref($self->refname.'^0');
2515 if ($self->use_svm_props || $self->no_metadata) {
2516 my $rev_db = $self->rev_db_path;
2517 $self->rebuild_from_rev_db($rev_db);
2518 if ($self->use_svm_props) {
2519 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2520 $self->rebuild_from_rev_db($svm_rev_db);
2521 }
2522 $self->unlink_rev_db_symlink;
2523 return;
2524 }
2525 print "Rebuilding $map_path ...\n";
2526 my ($log, $ctx) =
2527 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2528 $self->refname, '--');
2529 my $full_url = $self->full_url;
2530 remove_username($full_url);
2531 my $svn_uuid = $self->ra_uuid;
2532 my $c;
2533 while (<$log>) {
2534 if ( m{^commit ($::sha1)$} ) {
2535 $c = $1;
2536 next;
2537 }
2538 next unless s{^\s*(git-svn-id:)}{$1};
2539 my ($url, $rev, $uuid) = ::extract_metadata($_);
2540 remove_username($url);
2541
2542 # ignore merges (from set-tree)
2543 next if (!defined $rev || !$uuid);
2544
2545 # if we merged or otherwise started elsewhere, this is
2546 # how we break out of it
2547 if (($uuid ne $svn_uuid) ||
2548 ($full_url && $url && ($url ne $full_url))) {
2549 next;
2550 }
2551
2552 $self->rev_map_set($rev, $c);
2553 print "r$rev = $c\n";
2554 }
2555 command_close_pipe($log, $ctx);
2556 print "Done rebuilding $map_path\n";
2557 my $rev_db_path = $self->rev_db_path;
2558 if (-f $self->rev_db_path) {
2559 unlink $self->rev_db_path or croak "unlink: $!";
2560 }
2561 $self->unlink_rev_db_symlink;
2562 }
2563
2564 # rev_map:
2565 # Tie::File seems to be prone to offset errors if revisions get sparse,
2566 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2567 # one of my favorite modules is out :< Next up would be one of the DBM
2568 # modules, but I'm not sure which is most portable...
2569 #
2570 # This is the replacement for the rev_db format, which was too big
2571 # and inefficient for large repositories with a lot of sparse history
2572 # (mainly tags)
2573 #
2574 # The format is this:
2575 # - 24 bytes for every record,
2576 # * 4 bytes for the integer representing an SVN revision number
2577 # * 20 bytes representing the sha1 of a git commit
2578 # - No empty padding records like the old format
2579 # (except the last record, which can be overwritten)
2580 # - new records are written append-only since SVN revision numbers
2581 # increase monotonically
2582 # - lookups on SVN revision number are done via a binary search
2583 # - Piping the file to xxd -c24 is a good way of dumping it for
2584 # viewing or editing (piped back through xxd -r), should the need
2585 # ever arise.
2586 # - The last record can be padding revision with an all-zero sha1
2587 # This is used to optimize fetch performance when using multiple
2588 # "fetch" directives in .git/config
2589 #
2590 # These files are disposable unless noMetadata or useSvmProps is set
2591
2592 sub _rev_map_set {
2593 my ($fh, $rev, $commit) = @_;
2594
2595 my $size = (stat($fh))[7];
2596 ($size % 24) == 0 or croak "inconsistent size: $size";
2597
2598 my $wr_offset = 0;
2599 if ($size > 0) {
2600 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2601 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2602 $read == 24 or croak "read only $read bytes (!= 24)";
2603 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2604 if ($last_commit eq ('0' x40)) {
2605 if ($size >= 48) {
2606 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2607 $read = sysread($fh, $buf, 24) or
2608 croak "read: $!";
2609 $read == 24 or
2610 croak "read only $read bytes (!= 24)";
2611 ($last_rev, $last_commit) =
2612 unpack(rev_map_fmt, $buf);
2613 if ($last_commit eq ('0' x40)) {
2614 croak "inconsistent .rev_map\n";
2615 }
2616 }
2617 if ($last_rev >= $rev) {
2618 croak "last_rev is higher!: $last_rev >= $rev";
2619 }
2620 $wr_offset = -24;
2621 }
2622 }
2623 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2624 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2625 croak "write: $!";
2626 }
2627
2628 sub mkfile {
2629 my ($path) = @_;
2630 unless (-e $path) {
2631 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2632 mkpath([$dir]) unless -d $dir;
2633 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2634 close $fh or die "Couldn't close (create) $path: $!\n";
2635 }
2636 }
2637
2638 sub rev_map_set {
2639 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2640 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2641 my $db = $self->map_path($uuid);
2642 my $db_lock = "$db.lock";
2643 my $sig;
2644 if ($update_ref) {
2645 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2646 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2647 }
2648 mkfile($db);
2649
2650 $LOCKFILES{$db_lock} = 1;
2651 my $sync;
2652 # both of these options make our .rev_db file very, very important
2653 # and we can't afford to lose it because rebuild() won't work
2654 if ($self->use_svm_props || $self->no_metadata) {
2655 $sync = 1;
2656 copy($db, $db_lock) or die "rev_map_set(@_): ",
2657 "Failed to copy: ",
2658 "$db => $db_lock ($!)\n";
2659 } else {
2660 rename $db, $db_lock or die "rev_map_set(@_): ",
2661 "Failed to rename: ",
2662 "$db => $db_lock ($!)\n";
2663 }
2664
2665 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2666 or croak "Couldn't open $db_lock: $!\n";
2667 _rev_map_set($fh, $rev, $commit);
2668 if ($sync) {
2669 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2670 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2671 }
2672 close $fh or croak $!;
2673 if ($update_ref) {
2674 $_head = $self;
2675 command_noisy('update-ref', '-m', "r$rev",
2676 $self->refname, $commit);
2677 }
2678 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2679 "$db_lock => $db ($!)\n";
2680 delete $LOCKFILES{$db_lock};
2681 if ($update_ref) {
2682 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2683 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2684 kill $sig, $$ if defined $sig;
2685 }
2686 }
2687
2688 # If want_commit, this will return an array of (rev, commit) where
2689 # commit _must_ be a valid commit in the archive.
2690 # Otherwise, it'll return the max revision (whether or not the
2691 # commit is valid or just a 0x40 placeholder).
2692 sub rev_map_max {
2693 my ($self, $want_commit) = @_;
2694 $self->rebuild;
2695 my $map_path = $self->map_path;
2696 stat $map_path or return $want_commit ? (0, undef) : 0;
2697 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2698 my $size = (stat($fh))[7];
2699 ($size % 24) == 0 or croak "inconsistent size: $size";
2700
2701 if ($size == 0) {
2702 close $fh or croak "close: $!";
2703 return $want_commit ? (0, undef) : 0;
2704 }
2705
2706 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2707 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2708 my ($r, $c) = unpack(rev_map_fmt, $buf);
2709 if ($want_commit && $c eq ('0' x40)) {
2710 if ($size < 48) {
2711 return $want_commit ? (0, undef) : 0;
2712 }
2713 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2714 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2715 ($r, $c) = unpack(rev_map_fmt, $buf);
2716 if ($c eq ('0'x40)) {
2717 croak "Penultimate record is all-zeroes in $map_path";
2718 }
2719 }
2720 close $fh or croak "close: $!";
2721 $want_commit ? ($r, $c) : $r;
2722 }
2723
2724 sub rev_map_get {
2725 my ($self, $rev, $uuid) = @_;
2726 my $map_path = $self->map_path($uuid);
2727 return undef unless -e $map_path;
2728
2729 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2730 my $size = (stat($fh))[7];
2731 ($size % 24) == 0 or croak "inconsistent size: $size";
2732
2733 if ($size == 0) {
2734 close $fh or croak "close: $fh";
2735 return undef;
2736 }
2737
2738 my ($l, $u) = (0, $size - 24);
2739 my ($r, $c, $buf);
2740
2741 while ($l <= $u) {
2742 my $i = int(($l/24 + $u/24) / 2) * 24;
2743 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2744 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2745 my ($r, $c) = unpack('NH40', $buf);
2746
2747 if ($r < $rev) {
2748 $l = $i + 24;
2749 } elsif ($r > $rev) {
2750 $u = $i - 24;
2751 } else { # $r == $rev
2752 close($fh) or croak "close: $!";
2753 return $c eq ('0' x 40) ? undef : $c;
2754 }
2755 }
2756 close($fh) or croak "close: $!";
2757 undef;
2758 }
2759
2760 # Finds the first svn revision that exists on (if $eq_ok is true) or
2761 # before $rev for the current branch. It will not search any lower
2762 # than $min_rev. Returns the git commit hash and svn revision number
2763 # if found, else (undef, undef).
2764 sub find_rev_before {
2765 my ($self, $rev, $eq_ok, $min_rev) = @_;
2766 --$rev unless $eq_ok;
2767 $min_rev ||= 1;
2768 while ($rev >= $min_rev) {
2769 if (my $c = $self->rev_map_get($rev)) {
2770 return ($rev, $c);
2771 }
2772 --$rev;
2773 }
2774 return (undef, undef);
2775 }
2776
2777 # Finds the first svn revision that exists on (if $eq_ok is true) or
2778 # after $rev for the current branch. It will not search any higher
2779 # than $max_rev. Returns the git commit hash and svn revision number
2780 # if found, else (undef, undef).
2781 sub find_rev_after {
2782 my ($self, $rev, $eq_ok, $max_rev) = @_;
2783 ++$rev unless $eq_ok;
2784 $max_rev ||= $self->rev_map_max;
2785 while ($rev <= $max_rev) {
2786 if (my $c = $self->rev_map_get($rev)) {
2787 return ($rev, $c);
2788 }
2789 ++$rev;
2790 }
2791 return (undef, undef);
2792 }
2793
2794 sub _new {
2795 my ($class, $repo_id, $ref_id, $path) = @_;
2796 unless (defined $repo_id && length $repo_id) {
2797 $repo_id = $Git::SVN::default_repo_id;
2798 }
2799 unless (defined $ref_id && length $ref_id) {
2800 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2801 }
2802 $_[1] = $repo_id = sanitize_remote_name($repo_id);
2803 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2804 $_[3] = $path = '' unless (defined $path);
2805 mkpath(["$ENV{GIT_DIR}/svn"]);
2806 bless {
2807 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2808 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2809 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2810 }
2811
2812 # for read-only access of old .rev_db formats
2813 sub unlink_rev_db_symlink {
2814 my ($self) = @_;
2815 my $link = $self->rev_db_path;
2816 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2817 if (-l $link) {
2818 unlink $link or croak "unlink: $link failed!";
2819 }
2820 }
2821
2822 sub rev_db_path {
2823 my ($self, $uuid) = @_;
2824 my $db_path = $self->map_path($uuid);
2825 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2826 or croak "map_path: $db_path does not contain '/.rev_map.' !";
2827 $db_path;
2828 }
2829
2830 # the new replacement for .rev_db
2831 sub map_path {
2832 my ($self, $uuid) = @_;
2833 $uuid ||= $self->ra_uuid;
2834 "$self->{map_root}.$uuid";
2835 }
2836
2837 sub uri_encode {
2838 my ($f) = @_;
2839 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2840 $f
2841 }
2842
2843 sub remove_username {
2844 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2845 }
2846
2847 package Git::SVN::Prompt;
2848 use strict;
2849 use warnings;
2850 require SVN::Core;
2851 use vars qw/$_no_auth_cache $_username/;
2852
2853 sub simple {
2854 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2855 $may_save = undef if $_no_auth_cache;
2856 $default_username = $_username if defined $_username;
2857 if (defined $default_username && length $default_username) {
2858 if (defined $realm && length $realm) {
2859 print STDERR "Authentication realm: $realm\n";
2860 STDERR->flush;
2861 }
2862 $cred->username($default_username);
2863 } else {
2864 username($cred, $realm, $may_save, $pool);
2865 }
2866 $cred->password(_read_password("Password for '" .
2867 $cred->username . "': ", $realm));
2868 $cred->may_save($may_save);
2869 $SVN::_Core::SVN_NO_ERROR;
2870 }
2871
2872 sub ssl_server_trust {
2873 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2874 $may_save = undef if $_no_auth_cache;
2875 print STDERR "Error validating server certificate for '$realm':\n";
2876 {
2877 no warnings 'once';
2878 # All variables SVN::Auth::SSL::* are used only once,
2879 # so we're shutting up Perl warnings about this.
2880 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2881 print STDERR " - The certificate is not issued ",
2882 "by a trusted authority. Use the\n",
2883 " fingerprint to validate ",
2884 "the certificate manually!\n";
2885 }
2886 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2887 print STDERR " - The certificate hostname ",
2888 "does not match.\n";
2889 }
2890 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2891 print STDERR " - The certificate is not yet valid.\n";
2892 }
2893 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2894 print STDERR " - The certificate has expired.\n";
2895 }
2896 if ($failures & $SVN::Auth::SSL::OTHER) {
2897 print STDERR " - The certificate has ",
2898 "an unknown error.\n";
2899 }
2900 } # no warnings 'once'
2901 printf STDERR
2902 "Certificate information:\n".
2903 " - Hostname: %s\n".
2904 " - Valid: from %s until %s\n".
2905 " - Issuer: %s\n".
2906 " - Fingerprint: %s\n",
2907 map $cert_info->$_, qw(hostname valid_from valid_until
2908 issuer_dname fingerprint);
2909 my $choice;
2910 prompt:
2911 print STDERR $may_save ?
2912 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2913 "(R)eject or accept (t)emporarily? ";
2914 STDERR->flush;
2915 $choice = lc(substr(<STDIN> || 'R', 0, 1));
2916 if ($choice =~ /^t$/i) {
2917 $cred->may_save(undef);
2918 } elsif ($choice =~ /^r$/i) {
2919 return -1;
2920 } elsif ($may_save && $choice =~ /^p$/i) {
2921 $cred->may_save($may_save);
2922 } else {
2923 goto prompt;
2924 }
2925 $cred->accepted_failures($failures);
2926 $SVN::_Core::SVN_NO_ERROR;
2927 }
2928
2929 sub ssl_client_cert {
2930 my ($cred, $realm, $may_save, $pool) = @_;
2931 $may_save = undef if $_no_auth_cache;
2932 print STDERR "Client certificate filename: ";
2933 STDERR->flush;
2934 chomp(my $filename = <STDIN>);
2935 $cred->cert_file($filename);
2936 $cred->may_save($may_save);
2937 $SVN::_Core::SVN_NO_ERROR;
2938 }
2939
2940 sub ssl_client_cert_pw {
2941 my ($cred, $realm, $may_save, $pool) = @_;
2942 $may_save = undef if $_no_auth_cache;
2943 $cred->password(_read_password("Password: ", $realm));
2944 $cred->may_save($may_save);
2945 $SVN::_Core::SVN_NO_ERROR;
2946 }
2947
2948 sub username {
2949 my ($cred, $realm, $may_save, $pool) = @_;
2950 $may_save = undef if $_no_auth_cache;
2951 if (defined $realm && length $realm) {
2952 print STDERR "Authentication realm: $realm\n";
2953 }
2954 my $username;
2955 if (defined $_username) {
2956 $username = $_username;
2957 } else {
2958 print STDERR "Username: ";
2959 STDERR->flush;
2960 chomp($username = <STDIN>);
2961 }
2962 $cred->username($username);
2963 $cred->may_save($may_save);
2964 $SVN::_Core::SVN_NO_ERROR;
2965 }
2966
2967 sub _read_password {
2968 my ($prompt, $realm) = @_;
2969 print STDERR $prompt;
2970 STDERR->flush;
2971 require Term::ReadKey;
2972 Term::ReadKey::ReadMode('noecho');
2973 my $password = '';
2974 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2975 last if $key =~ /[\012\015]/; # \n\r
2976 $password .= $key;
2977 }
2978 Term::ReadKey::ReadMode('restore');
2979 print STDERR "\n";
2980 STDERR->flush;
2981 $password;
2982 }
2983
2984 package SVN::Git::Fetcher;
2985 use vars qw/@ISA/;
2986 use strict;
2987 use warnings;
2988 use Carp qw/croak/;
2989 use IO::File qw//;
2990
2991 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
2992 sub new {
2993 my ($class, $git_svn) = @_;
2994 my $self = SVN::Delta::Editor->new;
2995 bless $self, $class;
2996 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
2997 $self->{empty} = {};
2998 $self->{dir_prop} = {};
2999 $self->{file_prop} = {};
3000 $self->{absent_dir} = {};
3001 $self->{absent_file} = {};
3002 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3003 $self;
3004 }
3005
3006 sub set_path_strip {
3007 my ($self, $path) = @_;
3008 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3009 }
3010
3011 sub open_root {
3012 { path => '' };
3013 }
3014
3015 sub open_directory {
3016 my ($self, $path, $pb, $rev) = @_;
3017 { path => $path };
3018 }
3019
3020 sub git_path {
3021 my ($self, $path) = @_;
3022 if ($self->{path_strip}) {
3023 $path =~ s!$self->{path_strip}!! or
3024 die "Failed to strip path '$path' ($self->{path_strip})\n";
3025 }
3026 $path;
3027 }
3028
3029 sub delete_entry {
3030 my ($self, $path, $rev, $pb) = @_;
3031
3032 my $gpath = $self->git_path($path);
3033 return undef if ($gpath eq '');
3034
3035 # remove entire directories.
3036 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3037 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3038 -r --name-only -z/,
3039 $self->{c}, '--', $gpath);
3040 local $/ = "\0";
3041 while (<$ls>) {
3042 chomp;
3043 $self->{gii}->remove($_);
3044 print "\tD\t$_\n" unless $::_q;
3045 }
3046 print "\tD\t$gpath/\n" unless $::_q;
3047 command_close_pipe($ls, $ctx);
3048 $self->{empty}->{$path} = 0
3049 } else {
3050 $self->{gii}->remove($gpath);
3051 print "\tD\t$gpath\n" unless $::_q;
3052 }
3053 undef;
3054 }
3055
3056 sub open_file {
3057 my ($self, $path, $pb, $rev) = @_;
3058 my $gpath = $self->git_path($path);
3059 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3060 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3061 unless (defined $mode && defined $blob) {
3062 die "$path was not found in commit $self->{c} (r$rev)\n";
3063 }
3064 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3065 pool => SVN::Pool->new, action => 'M' };
3066 }
3067
3068 sub add_file {
3069 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3070 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3071 delete $self->{empty}->{$dir};
3072 { path => $path, mode_a => 100644, mode_b => 100644,
3073 pool => SVN::Pool->new, action => 'A' };
3074 }
3075
3076 sub add_directory {
3077 my ($self, $path, $cp_path, $cp_rev) = @_;
3078 my $gpath = $self->git_path($path);
3079 if ($gpath eq '') {
3080 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3081 -r --name-only -z/,
3082 $self->{c});
3083 local $/ = "\0";
3084 while (<$ls>) {
3085 chomp;
3086 $self->{gii}->remove($_);
3087 print "\tD\t$_\n" unless $::_q;
3088 }
3089 command_close_pipe($ls, $ctx);
3090 $self->{empty}->{$path} = 0;
3091 }
3092 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3093 delete $self->{empty}->{$dir};
3094 $self->{empty}->{$path} = 1;
3095 { path => $path };
3096 }
3097
3098 sub change_dir_prop {
3099 my ($self, $db, $prop, $value) = @_;
3100 $self->{dir_prop}->{$db->{path}} ||= {};
3101 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3102 undef;
3103 }
3104
3105 sub absent_directory {
3106 my ($self, $path, $pb) = @_;
3107 $self->{absent_dir}->{$pb->{path}} ||= [];
3108 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3109 undef;
3110 }
3111
3112 sub absent_file {
3113 my ($self, $path, $pb) = @_;
3114 $self->{absent_file}->{$pb->{path}} ||= [];
3115 push @{$self->{absent_file}->{$pb->{path}}}, $path;
3116 undef;
3117 }
3118
3119 sub change_file_prop {
3120 my ($self, $fb, $prop, $value) = @_;
3121 if ($prop eq 'svn:executable') {
3122 if ($fb->{mode_b} != 120000) {
3123 $fb->{mode_b} = defined $value ? 100755 : 100644;
3124 }
3125 } elsif ($prop eq 'svn:special') {
3126 $fb->{mode_b} = defined $value ? 120000 : 100644;
3127 } else {
3128 $self->{file_prop}->{$fb->{path}} ||= {};
3129 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3130 }
3131 undef;
3132 }
3133
3134 sub apply_textdelta {
3135 my ($self, $fb, $exp) = @_;
3136 my $fh = IO::File->new_tmpfile;
3137 $fh->autoflush(1);
3138 # $fh gets auto-closed() by SVN::TxDelta::apply(),
3139 # (but $base does not,) so dup() it for reading in close_file
3140 open my $dup, '<&', $fh or croak $!;
3141 my $base = IO::File->new_tmpfile;
3142 $base->autoflush(1);
3143 if ($fb->{blob}) {
3144 defined (my $pid = fork) or croak $!;
3145 if (!$pid) {
3146 open STDOUT, '>&', $base or croak $!;
3147 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
3148 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
3149 }
3150 waitpid $pid, 0;
3151 croak $? if $?;
3152
3153 if (defined $exp) {
3154 seek $base, 0, 0 or croak $!;
3155 my $got = ::md5sum($base);
3156 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3157 "expected: $exp\n",
3158 " got: $got\n" if ($got ne $exp);
3159 }
3160 }
3161 seek $base, 0, 0 or croak $!;
3162 $fb->{fh} = $dup;
3163 $fb->{base} = $base;
3164 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
3165 }
3166
3167 sub close_file {
3168 my ($self, $fb, $exp) = @_;
3169 my $hash;
3170 my $path = $self->git_path($fb->{path});
3171 if (my $fh = $fb->{fh}) {
3172 if (defined $exp) {
3173 seek($fh, 0, 0) or croak $!;
3174 my $got = ::md5sum($fh);
3175 if ($got ne $exp) {
3176 die "Checksum mismatch: $path\n",
3177 "expected: $exp\n got: $got\n";
3178 }
3179 }
3180 sysseek($fh, 0, 0) or croak $!;
3181 if ($fb->{mode_b} == 120000) {
3182 eval {
3183 sysread($fh, my $buf, 5) == 5 or croak $!;
3184 $buf eq 'link ' or die "$path has mode 120000",
3185 " but is not a link";
3186 };
3187 if ($@) {
3188 warn "$@\n";
3189 sysseek($fh, 0, 0) or croak $!;
3190 }
3191 }
3192 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
3193 if (!$pid) {
3194 open STDIN, '<&', $fh or croak $!;
3195 exec qw/git-hash-object -w --stdin/ or croak $!;
3196 }
3197 chomp($hash = do { local $/; <$out> });
3198 close $out or croak $!;
3199 close $fh or croak $!;
3200 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3201 close $fb->{base} or croak $!;
3202 } else {
3203 $hash = $fb->{blob} or die "no blob information\n";
3204 }
3205 $fb->{pool}->clear;
3206 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3207 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3208 undef;
3209 }
3210
3211 sub abort_edit {
3212 my $self = shift;
3213 $self->{nr} = $self->{gii}->{nr};
3214 delete $self->{gii};
3215 $self->SUPER::abort_edit(@_);
3216 }
3217
3218 sub close_edit {
3219 my $self = shift;
3220 $self->{git_commit_ok} = 1;
3221 $self->{nr} = $self->{gii}->{nr};
3222 delete $self->{gii};
3223 $self->SUPER::close_edit(@_);
3224 }
3225
3226 package SVN::Git::Editor;
3227 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3228 use strict;
3229 use warnings;
3230 use Carp qw/croak/;
3231 use IO::File;
3232
3233 sub new {
3234 my ($class, $opts) = @_;
3235 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3236 die "$_ required!\n" unless (defined $opts->{$_});
3237 }
3238
3239 my $pool = SVN::Pool->new;
3240 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3241 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3242 $opts->{r}, $mods);
3243
3244 # $opts->{ra} functions should not be used after this:
3245 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
3246 $opts->{editor_cb}, $pool);
3247 my $self = SVN::Delta::Editor->new(@ce, $pool);
3248 bless $self, $class;
3249 foreach (qw/svn_path r tree_a tree_b/) {
3250 $self->{$_} = $opts->{$_};
3251 }
3252 $self->{url} = $opts->{ra}->{url};
3253 $self->{mods} = $mods;
3254 $self->{types} = $types;
3255 $self->{pool} = $pool;
3256 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3257 $self->{rm} = { };
3258 $self->{path_prefix} = length $self->{svn_path} ?
3259 "$self->{svn_path}/" : '';
3260 return $self;
3261 }
3262
3263 sub generate_diff {
3264 my ($tree_a, $tree_b) = @_;
3265 my @diff_tree = qw(diff-tree -z -r);
3266 if ($_cp_similarity) {
3267 push @diff_tree, "-C$_cp_similarity";
3268 } else {
3269 push @diff_tree, '-C';
3270 }
3271 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3272 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3273 push @diff_tree, $tree_a, $tree_b;
3274 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3275 local $/ = "\0";
3276 my $state = 'meta';
3277 my @mods;
3278 while (<$diff_fh>) {
3279 chomp $_; # this gets rid of the trailing "\0"
3280 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3281 $::sha1\s($::sha1)\s
3282 ([MTCRAD])\d*$/xo) {
3283 push @mods, { mode_a => $1, mode_b => $2,
3284 sha1_b => $3, chg => $4 };
3285 if ($4 =~ /^(?:C|R)$/) {
3286 $state = 'file_a';
3287 } else {
3288 $state = 'file_b';
3289 }
3290 } elsif ($state eq 'file_a') {
3291 my $x = $mods[$#mods] or croak "Empty array\n";
3292 if ($x->{chg} !~ /^(?:C|R)$/) {
3293 croak "Error parsing $_, $x->{chg}\n";
3294 }
3295 $x->{file_a} = $_;
3296 $state = 'file_b';
3297 } elsif ($state eq 'file_b') {
3298 my $x = $mods[$#mods] or croak "Empty array\n";
3299 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3300 croak "Error parsing $_, $x->{chg}\n";
3301 }
3302 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3303 croak "Error parsing $_, $x->{chg}\n";
3304 }
3305 $x->{file_b} = $_;
3306 $state = 'meta';
3307 } else {
3308 croak "Error parsing $_\n";
3309 }
3310 }
3311 command_close_pipe($diff_fh, $ctx);
3312 \@mods;
3313 }
3314
3315 sub check_diff_paths {
3316 my ($ra, $pfx, $rev, $mods) = @_;
3317 my %types;
3318 $pfx .= '/' if length $pfx;
3319
3320 sub type_diff_paths {
3321 my ($ra, $types, $path, $rev) = @_;
3322 my @p = split m#/+#, $path;
3323 my $c = shift @p;
3324 unless (defined $types->{$c}) {
3325 $types->{$c} = $ra->check_path($c, $rev);
3326 }
3327 while (@p) {
3328 $c .= '/' . shift @p;
3329 next if defined $types->{$c};
3330 $types->{$c} = $ra->check_path($c, $rev);
3331 }
3332 }
3333
3334 foreach my $m (@$mods) {
3335 foreach my $f (qw/file_a file_b/) {
3336 next unless defined $m->{$f};
3337 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3338 if (length $pfx.$dir && ! defined $types{$dir}) {
3339 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3340 }
3341 }
3342 }
3343 \%types;
3344 }
3345
3346 sub split_path {
3347 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3348 }
3349
3350 sub repo_path {
3351 my ($self, $path) = @_;
3352 $self->{path_prefix}.(defined $path ? $path : '');
3353 }
3354
3355 sub url_path {
3356 my ($self, $path) = @_;
3357 if ($self->{url} =~ m#^https?://#) {
3358 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3359 }
3360 $self->{url} . '/' . $self->repo_path($path);
3361 }
3362
3363 sub rmdirs {
3364 my ($self) = @_;
3365 my $rm = $self->{rm};
3366 delete $rm->{''}; # we never delete the url we're tracking
3367 return unless %$rm;
3368
3369 foreach (keys %$rm) {
3370 my @d = split m#/#, $_;
3371 my $c = shift @d;
3372 $rm->{$c} = 1;
3373 while (@d) {
3374 $c .= '/' . shift @d;
3375 $rm->{$c} = 1;
3376 }
3377 }
3378 delete $rm->{$self->{svn_path}};
3379 delete $rm->{''}; # we never delete the url we're tracking
3380 return unless %$rm;
3381
3382 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3383 $self->{tree_b});
3384 local $/ = "\0";
3385 while (<$fh>) {
3386 chomp;
3387 my @dn = split m#/#, $_;
3388 while (pop @dn) {
3389 delete $rm->{join '/', @dn};
3390 }
3391 unless (%$rm) {
3392 close $fh;
3393 return;
3394 }
3395 }
3396 command_close_pipe($fh, $ctx);
3397
3398 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3399 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3400 $self->close_directory($bat->{$d}, $p);
3401 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3402 print "\tD+\t$d/\n" unless $::_q;
3403 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3404 delete $bat->{$d};
3405 }
3406 }
3407
3408 sub open_or_add_dir {
3409 my ($self, $full_path, $baton) = @_;
3410 my $t = $self->{types}->{$full_path};
3411 if (!defined $t) {
3412 die "$full_path not known in r$self->{r} or we have a bug!\n";
3413 }
3414 {
3415 no warnings 'once';
3416 # SVN::Node::none and SVN::Node::file are used only once,
3417 # so we're shutting up Perl's warnings about them.
3418 if ($t == $SVN::Node::none) {
3419 return $self->add_directory($full_path, $baton,
3420 undef, -1, $self->{pool});
3421 } elsif ($t == $SVN::Node::dir) {
3422 return $self->open_directory($full_path, $baton,
3423 $self->{r}, $self->{pool});
3424 } # no warnings 'once'
3425 print STDERR "$full_path already exists in repository at ",
3426 "r$self->{r} and it is not a directory (",
3427 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3428 } # no warnings 'once'
3429 exit 1;
3430 }
3431
3432 sub ensure_path {
3433 my ($self, $path) = @_;
3434 my $bat = $self->{bat};
3435 my $repo_path = $self->repo_path($path);
3436 return $bat->{''} unless (length $repo_path);
3437 my @p = split m#/+#, $repo_path;
3438 my $c = shift @p;
3439 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3440 while (@p) {
3441 my $c0 = $c;
3442 $c .= '/' . shift @p;
3443 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3444 }
3445 return $bat->{$c};
3446 }
3447
3448 sub A {
3449 my ($self, $m) = @_;
3450 my ($dir, $file) = split_path($m->{file_b});
3451 my $pbat = $self->ensure_path($dir);
3452 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3453 undef, -1);
3454 print "\tA\t$m->{file_b}\n" unless $::_q;
3455 $self->chg_file($fbat, $m);
3456 $self->close_file($fbat,undef,$self->{pool});
3457 }
3458
3459 sub C {
3460 my ($self, $m) = @_;
3461 my ($dir, $file) = split_path($m->{file_b});
3462 my $pbat = $self->ensure_path($dir);
3463 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3464 $self->url_path($m->{file_a}), $self->{r});
3465 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3466 $self->chg_file($fbat, $m);
3467 $self->close_file($fbat,undef,$self->{pool});
3468 }
3469
3470 sub delete_entry {
3471 my ($self, $path, $pbat) = @_;
3472 my $rpath = $self->repo_path($path);
3473 my ($dir, $file) = split_path($rpath);
3474 $self->{rm}->{$dir} = 1;
3475 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3476 }
3477
3478 sub R {
3479 my ($self, $m) = @_;
3480 my ($dir, $file) = split_path($m->{file_b});
3481 my $pbat = $self->ensure_path($dir);
3482 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3483 $self->url_path($m->{file_a}), $self->{r});
3484 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3485 $self->chg_file($fbat, $m);
3486 $self->close_file($fbat,undef,$self->{pool});
3487
3488 ($dir, $file) = split_path($m->{file_a});
3489 $pbat = $self->ensure_path($dir);
3490 $self->delete_entry($m->{file_a}, $pbat);
3491 }
3492
3493 sub M {
3494 my ($self, $m) = @_;
3495 my ($dir, $file) = split_path($m->{file_b});
3496 my $pbat = $self->ensure_path($dir);
3497 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3498 $pbat,$self->{r},$self->{pool});
3499 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3500 $self->chg_file($fbat, $m);
3501 $self->close_file($fbat,undef,$self->{pool});
3502 }
3503
3504 sub T { shift->M(@_) }
3505
3506 sub change_file_prop {
3507 my ($self, $fbat, $pname, $pval) = @_;
3508 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3509 }
3510
3511 sub chg_file {
3512 my ($self, $fbat, $m) = @_;
3513 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3514 $self->change_file_prop($fbat,'svn:executable','*');
3515 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3516 $self->change_file_prop($fbat,'svn:executable',undef);
3517 }
3518 my $fh = IO::File->new_tmpfile or croak $!;
3519 if ($m->{mode_b} =~ /^120/) {
3520 print $fh 'link ' or croak $!;
3521 $self->change_file_prop($fbat,'svn:special','*');
3522 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3523 $self->change_file_prop($fbat,'svn:special',undef);
3524 }
3525 defined(my $pid = fork) or croak $!;
3526 if (!$pid) {
3527 open STDOUT, '>&', $fh or croak $!;
3528 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3529 }
3530 waitpid $pid, 0;
3531 croak $? if $?;
3532 $fh->flush == 0 or croak $!;
3533 seek $fh, 0, 0 or croak $!;
3534
3535 my $exp = ::md5sum($fh);
3536 seek $fh, 0, 0 or croak $!;
3537
3538 my $pool = SVN::Pool->new;
3539 my $atd = $self->apply_textdelta($fbat, undef, $pool);
3540 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3541 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3542 $pool->clear;
3543
3544 close $fh or croak $!;
3545 }
3546
3547 sub D {
3548 my ($self, $m) = @_;
3549 my ($dir, $file) = split_path($m->{file_b});
3550 my $pbat = $self->ensure_path($dir);
3551 print "\tD\t$m->{file_b}\n" unless $::_q;
3552 $self->delete_entry($m->{file_b}, $pbat);
3553 }
3554
3555 sub close_edit {
3556 my ($self) = @_;
3557 my ($p,$bat) = ($self->{pool}, $self->{bat});
3558 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3559 next if $_ eq '';
3560 $self->close_directory($bat->{$_}, $p);
3561 }
3562 $self->close_directory($bat->{''}, $p);
3563 $self->SUPER::close_edit($p);
3564 $p->clear;
3565 }
3566
3567 sub abort_edit {
3568 my ($self) = @_;
3569 $self->SUPER::abort_edit($self->{pool});
3570 }
3571
3572 sub DESTROY {
3573 my $self = shift;
3574 $self->SUPER::DESTROY(@_);
3575 $self->{pool}->clear;
3576 }
3577
3578 # this drives the editor
3579 sub apply_diff {
3580 my ($self) = @_;
3581 my $mods = $self->{mods};
3582 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3583 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3584 my $f = $m->{chg};
3585 if (defined $o{$f}) {
3586 $self->$f($m);
3587 } else {
3588 fatal("Invalid change type: $f");
3589 }
3590 }
3591 $self->rmdirs if $_rmdir;
3592 if (@$mods == 0) {
3593 $self->abort_edit;
3594 } else {
3595 $self->close_edit;
3596 }
3597 return scalar @$mods;
3598 }
3599
3600 package Git::SVN::Ra;
3601 use vars qw/@ISA $config_dir $_log_window_size/;
3602 use strict;
3603 use warnings;
3604 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3605
3606 BEGIN {
3607 # enforce temporary pool usage for some simple functions
3608 no strict 'refs';
3609 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3610 my $SUPER = "SUPER::$f";
3611 *$f = sub {
3612 my $self = shift;
3613 my $pool = SVN::Pool->new;
3614 my @ret = $self->$SUPER(@_,$pool);
3615 $pool->clear;
3616 wantarray ? @ret : $ret[0];
3617 };
3618 }
3619 }
3620
3621 sub _auth_providers () {
3622 [
3623 SVN::Client::get_simple_provider(),
3624 SVN::Client::get_ssl_server_trust_file_provider(),
3625 SVN::Client::get_simple_prompt_provider(
3626 \&Git::SVN::Prompt::simple, 2),
3627 SVN::Client::get_ssl_client_cert_file_provider(),
3628 SVN::Client::get_ssl_client_cert_prompt_provider(
3629 \&Git::SVN::Prompt::ssl_client_cert, 2),
3630 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3631 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3632 SVN::Client::get_username_provider(),
3633 SVN::Client::get_ssl_server_trust_prompt_provider(
3634 \&Git::SVN::Prompt::ssl_server_trust),
3635 SVN::Client::get_username_prompt_provider(
3636 \&Git::SVN::Prompt::username, 2)
3637 ]
3638 }
3639
3640 sub escape_uri_only {
3641 my ($uri) = @_;
3642 my @tmp;
3643 foreach (split m{/}, $uri) {
3644 s/([^\w.-])/sprintf("%%%02X",ord($1))/eg;
3645 push @tmp, $_;
3646 }
3647 join('/', @tmp);
3648 }
3649
3650 sub escape_url {
3651 my ($url) = @_;
3652 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3653 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3654 $url = "$scheme://$domain$uri";
3655 }
3656 $url;
3657 }
3658
3659 sub new {
3660 my ($class, $url) = @_;
3661 $url =~ s!/+$!!;
3662 return $RA if ($RA && $RA->{url} eq $url);
3663
3664 SVN::_Core::svn_config_ensure($config_dir, undef);
3665 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3666 my $config = SVN::Core::config_get_config($config_dir);
3667 $RA = undef;
3668 my $dont_store_passwords = 1;
3669 my $conf_t = ${$config}{'config'};
3670 {
3671 no warnings 'once';
3672 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3673 # produces warnings that variables are used only once.
3674 # I had not found the better way to shut them up, so
3675 # the warnings of type 'once' are disabled in this block.
3676 if (SVN::_Core::svn_config_get_bool($conf_t,
3677 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3678 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3679 1) == 0) {
3680 SVN::_Core::svn_auth_set_parameter($baton,
3681 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3682 bless (\$dont_store_passwords, "_p_void"));
3683 }
3684 if (SVN::_Core::svn_config_get_bool($conf_t,
3685 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3686 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3687 1) == 0) {
3688 $Git::SVN::Prompt::_no_auth_cache = 1;
3689 }
3690 } # no warnings 'once'
3691 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3692 config => $config,
3693 pool => SVN::Pool->new,
3694 auth_provider_callbacks => $callbacks);
3695 $self->{url} = $url;
3696 $self->{svn_path} = $url;
3697 $self->{repos_root} = $self->get_repos_root;
3698 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3699 $self->{cache} = { check_path => { r => 0, data => {} },
3700 get_dir => { r => 0, data => {} } };
3701 $RA = bless $self, $class;
3702 }
3703
3704 sub check_path {
3705 my ($self, $path, $r) = @_;
3706 my $cache = $self->{cache}->{check_path};
3707 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3708 return $cache->{data}->{$path};
3709 }
3710 my $pool = SVN::Pool->new;
3711 my $t = $self->SUPER::check_path($path, $r, $pool);
3712 $pool->clear;
3713 if ($r != $cache->{r}) {
3714 %{$cache->{data}} = ();
3715 $cache->{r} = $r;
3716 }
3717 $cache->{data}->{$path} = $t;
3718 }
3719
3720 sub get_dir {
3721 my ($self, $dir, $r) = @_;
3722 my $cache = $self->{cache}->{get_dir};
3723 if ($r == $cache->{r}) {
3724 if (my $x = $cache->{data}->{$dir}) {
3725 return wantarray ? @$x : $x->[0];
3726 }
3727 }
3728 my $pool = SVN::Pool->new;
3729 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3730 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3731 $pool->clear;
3732 if ($r != $cache->{r}) {
3733 %{$cache->{data}} = ();
3734 $cache->{r} = $r;
3735 }
3736 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3737 wantarray ? (\%dirents, $r, $props) : \%dirents;
3738 }
3739
3740 sub DESTROY {
3741 # do not call the real DESTROY since we store ourselves in $RA
3742 }
3743
3744 sub get_log {
3745 my ($self, @args) = @_;
3746 my $pool = SVN::Pool->new;
3747 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3748 my $ret = $self->SUPER::get_log(@args, $pool);
3749 $pool->clear;
3750 $ret;
3751 }
3752
3753 sub trees_match {
3754 my ($self, $url1, $rev1, $url2, $rev2) = @_;
3755 my $ctx = SVN::Client->new(auth => _auth_providers);
3756 my $out = IO::File->new_tmpfile;
3757
3758 # older SVN (1.1.x) doesn't take $pool as the last parameter for
3759 # $ctx->diff(), so we'll create a default one
3760 my $pool = SVN::Pool->new_default_sub;
3761
3762 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3763 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3764 $out->flush;
3765 my $ret = (($out->stat)[7] == 0);
3766 close $out or croak $!;
3767
3768 $ret;
3769 }
3770
3771 sub get_commit_editor {
3772 my ($self, $log, $cb, $pool) = @_;
3773 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3774 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3775 }
3776
3777 sub gs_do_update {
3778 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3779 my $new = ($rev_a == $rev_b);
3780 my $path = $gs->{path};
3781
3782 if ($new && -e $gs->{index}) {
3783 unlink $gs->{index} or die
3784 "Couldn't unlink index: $gs->{index}: $!\n";
3785 }
3786 my $pool = SVN::Pool->new;
3787 $editor->set_path_strip($path);
3788 my (@pc) = split m#/#, $path;
3789 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3790 1, $editor, $pool);
3791 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3792
3793 # Since we can't rely on svn_ra_reparent being available, we'll
3794 # just have to do some magic with set_path to make it so
3795 # we only want a partial path.
3796 my $sp = '';
3797 my $final = join('/', @pc);
3798 while (@pc) {
3799 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3800 $sp .= '/' if length $sp;
3801 $sp .= shift @pc;
3802 }
3803 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3804
3805 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3806
3807 $reporter->finish_report($pool);
3808 $pool->clear;
3809 $editor->{git_commit_ok};
3810 }
3811
3812 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3813 # svn_ra_reparent didn't work before 1.4)
3814 sub gs_do_switch {
3815 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3816 my $path = $gs->{path};
3817 my $pool = SVN::Pool->new;
3818
3819 my $full_url = $self->{url};
3820 my $old_url = $full_url;
3821 $full_url .= '/' . escape_uri_only($path) if length $path;
3822 my ($ra, $reparented);
3823 if ($old_url ne $full_url) {
3824 if ($old_url !~ m#^svn(\+ssh)?://#) {
3825 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3826 $pool);
3827 $self->{url} = $full_url;
3828 $reparented = 1;
3829 } else {
3830 $_[0] = undef;
3831 $self = undef;
3832 $RA = undef;
3833 $ra = Git::SVN::Ra->new($full_url);
3834 $ra_invalid = 1;
3835 }
3836 }
3837 $ra ||= $self;
3838 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3839 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3840 $reporter->set_path('', $rev_a, 0, @lock, $pool);
3841 $reporter->finish_report($pool);
3842
3843 if ($reparented) {
3844 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3845 $self->{url} = $old_url;
3846 }
3847
3848 $pool->clear;
3849 $editor->{git_commit_ok};
3850 }
3851
3852 sub longest_common_path {
3853 my ($gsv, $globs) = @_;
3854 my %common;
3855 my $common_max = scalar @$gsv;
3856
3857 foreach my $gs (@$gsv) {
3858 my @tmp = split m#/#, $gs->{path};
3859 my $p = '';
3860 foreach (@tmp) {
3861 $p .= length($p) ? "/$_" : $_;
3862 $common{$p} ||= 0;
3863 $common{$p}++;
3864 }
3865 }
3866 $globs ||= [];
3867 $common_max += scalar @$globs;
3868 foreach my $glob (@$globs) {
3869 my @tmp = split m#/#, $glob->{path}->{left};
3870 my $p = '';
3871 foreach (@tmp) {
3872 $p .= length($p) ? "/$_" : $_;
3873 $common{$p} ||= 0;
3874 $common{$p}++;
3875 }
3876 }
3877
3878 my $longest_path = '';
3879 foreach (sort {length $b <=> length $a} keys %common) {
3880 if ($common{$_} == $common_max) {
3881 $longest_path = $_;
3882 last;
3883 }
3884 }
3885 $longest_path;
3886 }
3887
3888 sub gs_fetch_loop_common {
3889 my ($self, $base, $head, $gsv, $globs) = @_;
3890 return if ($base > $head);
3891 my $inc = $_log_window_size;
3892 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3893 my $longest_path = longest_common_path($gsv, $globs);
3894 my $ra_url = $self->{url};
3895 while (1) {
3896 my %revs;
3897 my $err;
3898 my $err_handler = $SVN::Error::handler;
3899 $SVN::Error::handler = sub {
3900 ($err) = @_;
3901 skip_unknown_revs($err);
3902 };
3903 sub _cb {
3904 my ($paths, $r, $author, $date, $log) = @_;
3905 [ dup_changed_paths($paths),
3906 { author => $author, date => $date, log => $log } ];
3907 }
3908 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3909 sub { $revs{$_[1]} = _cb(@_) });
3910 if ($err && $max >= $head) {
3911 print STDERR "Path '$longest_path' ",
3912 "was probably deleted:\n",
3913 $err->expanded_message,
3914 "\nWill attempt to follow ",
3915 "revisions r$min .. r$max ",
3916 "committed before the deletion\n";
3917 my $hi = $max;
3918 while (--$hi >= $min) {
3919 my $ok;
3920 $self->get_log([$longest_path], $min, $hi,
3921 0, 1, 1, sub {
3922 $ok ||= $_[1];
3923 $revs{$_[1]} = _cb(@_) });
3924 if ($ok) {
3925 print STDERR "r$min .. r$ok OK\n";
3926 last;
3927 }
3928 }
3929 }
3930 $SVN::Error::handler = $err_handler;
3931
3932 my %exists = map { $_->{path} => $_ } @$gsv;
3933 foreach my $r (sort {$a <=> $b} keys %revs) {
3934 my ($paths, $logged) = @{$revs{$r}};
3935
3936 foreach my $gs ($self->match_globs(\%exists, $paths,
3937 $globs, $r)) {
3938 if ($gs->rev_map_max >= $r) {
3939 next;
3940 }
3941 next unless $gs->match_paths($paths, $r);
3942 $gs->{logged_rev_props} = $logged;
3943 if (my $last_commit = $gs->last_commit) {
3944 $gs->assert_index_clean($last_commit);
3945 }
3946 my $log_entry = $gs->do_fetch($paths, $r);
3947 if ($log_entry) {
3948 $gs->do_git_commit($log_entry);
3949 }
3950 $INDEX_FILES{$gs->{index}} = 1;
3951 }
3952 foreach my $g (@$globs) {
3953 my $k = "svn-remote.$g->{remote}." .
3954 "$g->{t}-maxRev";
3955 Git::SVN::tmp_config($k, $r);
3956 }
3957 if ($ra_invalid) {
3958 $_[0] = undef;
3959 $self = undef;
3960 $RA = undef;
3961 $self = Git::SVN::Ra->new($ra_url);
3962 $ra_invalid = undef;
3963 }
3964 }
3965 # pre-fill the .rev_db since it'll eventually get filled in
3966 # with '0' x40 if something new gets committed
3967 foreach my $gs (@$gsv) {
3968 next if $gs->rev_map_max >= $max;
3969 next if defined $gs->rev_map_get($max);
3970 $gs->rev_map_set($max, 0 x40);
3971 }
3972 foreach my $g (@$globs) {
3973 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3974 Git::SVN::tmp_config($k, $max);
3975 }
3976 last if $max >= $head;
3977 $min = $max + 1;
3978 $max += $inc;
3979 $max = $head if ($max > $head);
3980 }
3981 }
3982
3983 sub match_globs {
3984 my ($self, $exists, $paths, $globs, $r) = @_;
3985
3986 sub get_dir_check {
3987 my ($self, $exists, $g, $r) = @_;
3988 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
3989 return unless scalar @x == 3;
3990 my $dirents = $x[0];
3991 foreach my $de (keys %$dirents) {
3992 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
3993 my $p = $g->{path}->full_path($de);
3994 next if $exists->{$p};
3995 next if (length $g->{path}->{right} &&
3996 ($self->check_path($p, $r) !=
3997 $SVN::Node::dir));
3998 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
3999 $g->{ref}->full_path($de), 1);
4000 }
4001 }
4002 foreach my $g (@$globs) {
4003 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4004 if ($path->{action} =~ /^[AR]$/) {
4005 get_dir_check($self, $exists, $g, $r);
4006 }
4007 }
4008 foreach (keys %$paths) {
4009 if (/$g->{path}->{left_regex}/ &&
4010 !/$g->{path}->{regex}/) {
4011 next if $paths->{$_}->{action} !~ /^[AR]$/;
4012 get_dir_check($self, $exists, $g, $r);
4013 }
4014 next unless /$g->{path}->{regex}/;
4015 my $p = $1;
4016 my $pathname = $g->{path}->full_path($p);
4017 next if $exists->{$pathname};
4018 next if ($self->check_path($pathname, $r) !=
4019 $SVN::Node::dir);
4020 $exists->{$pathname} = Git::SVN->init(
4021 $self->{url}, $pathname, undef,
4022 $g->{ref}->full_path($p), 1);
4023 }
4024 my $c = '';
4025 foreach (split m#/#, $g->{path}->{left}) {
4026 $c .= "/$_";
4027 next unless ($paths->{$c} &&
4028 ($paths->{$c}->{action} =~ /^[AR]$/));
4029 get_dir_check($self, $exists, $g, $r);
4030 }
4031 }
4032 values %$exists;
4033 }
4034
4035 sub minimize_url {
4036 my ($self) = @_;
4037 return $self->{url} if ($self->{url} eq $self->{repos_root});
4038 my $url = $self->{repos_root};
4039 my @components = split(m!/!, $self->{svn_path});
4040 my $c = '';
4041 do {
4042 $url .= "/$c" if length $c;
4043 eval { (ref $self)->new($url)->get_latest_revnum };
4044 } while ($@ && ($c = shift @components));
4045 $url;
4046 }
4047
4048 sub can_do_switch {
4049 my $self = shift;
4050 unless (defined $can_do_switch) {
4051 my $pool = SVN::Pool->new;
4052 my $rep = eval {
4053 $self->do_switch(1, '', 0, $self->{url},
4054 SVN::Delta::Editor->new, $pool);
4055 };
4056 if ($@) {
4057 $can_do_switch = 0;
4058 } else {
4059 $rep->abort_report($pool);
4060 $can_do_switch = 1;
4061 }
4062 $pool->clear;
4063 }
4064 $can_do_switch;
4065 }
4066
4067 sub skip_unknown_revs {
4068 my ($err) = @_;
4069 my $errno = $err->apr_err();
4070 # Maybe the branch we're tracking didn't
4071 # exist when the repo started, so it's
4072 # not an error if it doesn't, just continue
4073 #
4074 # Wonderfully consistent library, eh?
4075 # 160013 - svn:// and file://
4076 # 175002 - http(s)://
4077 # 175007 - http(s):// (this repo required authorization, too...)
4078 # More codes may be discovered later...
4079 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4080 my $err_key = $err->expanded_message;
4081 # revision numbers change every time, filter them out
4082 $err_key =~ s/\d+/\0/g;
4083 $err_key = "$errno\0$err_key";
4084 unless ($ignored_err{$err_key}) {
4085 warn "W: Ignoring error from SVN, path probably ",
4086 "does not exist: ($errno): ",
4087 $err->expanded_message,"\n";
4088 $ignored_err{$err_key} = 1;
4089 }
4090 return;
4091 }
4092 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4093 }
4094
4095 # svn_log_changed_path_t objects passed to get_log are likely to be
4096 # overwritten even if only the refs are copied to an external variable,
4097 # so we should dup the structures in their entirety. Using an externally
4098 # passed pool (instead of our temporary and quickly cleared pool in
4099 # Git::SVN::Ra) does not help matters at all...
4100 sub dup_changed_paths {
4101 my ($paths) = @_;
4102 return undef unless $paths;
4103 my %ret;
4104 foreach my $p (keys %$paths) {
4105 my $i = $paths->{$p};
4106 my %s = map { $_ => $i->$_ }
4107 qw/copyfrom_path copyfrom_rev action/;
4108 $ret{$p} = \%s;
4109 }
4110 \%ret;
4111 }
4112
4113 package Git::SVN::Log;
4114 use strict;
4115 use warnings;
4116 use POSIX qw/strftime/;
4117 use constant commit_log_separator => ('-' x 72) . "\n";
4118 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4119 %rusers $show_commit $incremental/;
4120 my $l_fmt;
4121
4122 sub cmt_showable {
4123 my ($c) = @_;
4124 return 1 if defined $c->{r};
4125
4126 # big commit message got truncated by the 16k pretty buffer in rev-list
4127 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4128 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4129 @{$c->{l}} = ();
4130 my @log = command(qw/cat-file commit/, $c->{c});
4131
4132 # shift off the headers
4133 shift @log while ($log[0] ne '');
4134 shift @log;
4135
4136 # TODO: make $c->{l} not have a trailing newline in the future
4137 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4138
4139 (undef, $c->{r}, undef) = ::extract_metadata(
4140 (grep(/^git-svn-id: /, @log))[-1]);
4141 }
4142 return defined $c->{r};
4143 }
4144
4145 sub log_use_color {
4146 return $color || Git->repository->get_colorbool('color.diff');
4147 }
4148
4149 sub git_svn_log_cmd {
4150 my ($r_min, $r_max, @args) = @_;
4151 my $head = 'HEAD';
4152 my (@files, @log_opts);
4153 foreach my $x (@args) {
4154 if ($x eq '--' || @files) {
4155 push @files, $x;
4156 } else {
4157 if (::verify_ref("$x^0")) {
4158 $head = $x;
4159 } else {
4160 push @log_opts, $x;
4161 }
4162 }
4163 }
4164
4165 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4166 $gs ||= Git::SVN->_new;
4167 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4168 $gs->refname);
4169 push @cmd, '-r' unless $non_recursive;
4170 push @cmd, qw/--raw --name-status/ if $verbose;
4171 push @cmd, '--color' if log_use_color();
4172 push @cmd, @log_opts;
4173 if (defined $r_max && $r_max == $r_min) {
4174 push @cmd, '--max-count=1';
4175 if (my $c = $gs->rev_map_get($r_max)) {
4176 push @cmd, $c;
4177 }
4178 } elsif (defined $r_max) {
4179 if ($r_max < $r_min) {
4180 ($r_min, $r_max) = ($r_max, $r_min);
4181 }
4182 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4183 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4184 # If there are no commits in the range, both $c_max and $c_min
4185 # will be undefined. If there is at least 1 commit in the
4186 # range, both will be defined.
4187 return () if !defined $c_min || !defined $c_max;
4188 if ($c_min eq $c_max) {
4189 push @cmd, '--max-count=1', $c_min;
4190 } else {
4191 push @cmd, '--boundary', "$c_min..$c_max";
4192 }
4193 }
4194 return (@cmd, @files);
4195 }
4196
4197 # adapted from pager.c
4198 sub config_pager {
4199 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4200 if (!defined $pager) {
4201 $pager = 'less';
4202 } elsif (length $pager == 0 || $pager eq 'cat') {
4203 $pager = undef;
4204 }
4205 $ENV{GIT_PAGER_IN_USE} = defined($pager);
4206 }
4207
4208 sub run_pager {
4209 return unless -t *STDOUT && defined $pager;
4210 pipe my $rfd, my $wfd or return;
4211 defined(my $pid = fork) or ::fatal "Can't fork: $!";
4212 if (!$pid) {
4213 open STDOUT, '>&', $wfd or
4214 ::fatal "Can't redirect to stdout: $!";
4215 return;
4216 }
4217 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4218 $ENV{LESS} ||= 'FRSX';
4219 exec $pager or ::fatal "Can't run pager: $! ($pager)";
4220 }
4221
4222 sub format_svn_date {
4223 return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4224 }
4225
4226 sub parse_git_date {
4227 my ($t, $tz) = @_;
4228 # Date::Parse isn't in the standard Perl distro :(
4229 if ($tz =~ s/^\+//) {
4230 $t += tz_to_s_offset($tz);
4231 } elsif ($tz =~ s/^\-//) {
4232 $t -= tz_to_s_offset($tz);
4233 }
4234 return $t;
4235 }
4236
4237 sub set_local_timezone {
4238 if (defined $TZ) {
4239 $ENV{TZ} = $TZ;
4240 } else {
4241 delete $ENV{TZ};
4242 }
4243 }
4244
4245 sub tz_to_s_offset {
4246 my ($tz) = @_;
4247 $tz =~ s/(\d\d)$//;
4248 return ($1 * 60) + ($tz * 3600);
4249 }
4250
4251 sub get_author_info {
4252 my ($dest, $author, $t, $tz) = @_;
4253 $author =~ s/(?:^\s*|\s*$)//g;
4254 $dest->{a_raw} = $author;
4255 my $au;
4256 if ($::_authors) {
4257 $au = $rusers{$author} || undef;
4258 }
4259 if (!$au) {
4260 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4261 }
4262 $dest->{t} = $t;
4263 $dest->{tz} = $tz;
4264 $dest->{a} = $au;
4265 $dest->{t_utc} = parse_git_date($t, $tz);
4266 }
4267
4268 sub process_commit {
4269 my ($c, $r_min, $r_max, $defer) = @_;
4270 if (defined $r_min && defined $r_max) {
4271 if ($r_min == $c->{r} && $r_min == $r_max) {
4272 show_commit($c);
4273 return 0;
4274 }
4275 return 1 if $r_min == $r_max;
4276 if ($r_min < $r_max) {
4277 # we need to reverse the print order
4278 return 0 if (defined $limit && --$limit < 0);
4279 push @$defer, $c;
4280 return 1;
4281 }
4282 if ($r_min != $r_max) {
4283 return 1 if ($r_min < $c->{r});
4284 return 1 if ($r_max > $c->{r});
4285 }
4286 }
4287 return 0 if (defined $limit && --$limit < 0);
4288 show_commit($c);
4289 return 1;
4290 }
4291
4292 sub show_commit {
4293 my $c = shift;
4294 if ($oneline) {
4295 my $x = "\n";
4296 if (my $l = $c->{l}) {
4297 while ($l->[0] =~ /^\s*$/) { shift @$l }
4298 $x = $l->[0];
4299 }
4300 $l_fmt ||= 'A' . length($c->{r});
4301 print 'r',pack($l_fmt, $c->{r}),' | ';
4302 print "$c->{c} | " if $show_commit;
4303 print $x;
4304 } else {
4305 show_commit_normal($c);
4306 }
4307 }
4308
4309 sub show_commit_changed_paths {
4310 my ($c) = @_;
4311 return unless $c->{changed};
4312 print "Changed paths:\n", @{$c->{changed}};
4313 }
4314
4315 sub show_commit_normal {
4316 my ($c) = @_;
4317 print commit_log_separator, "r$c->{r} | ";
4318 print "$c->{c} | " if $show_commit;
4319 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4320 my $nr_line = 0;
4321
4322 if (my $l = $c->{l}) {
4323 while ($l->[$#$l] eq "\n" && $#$l > 0
4324 && $l->[($#$l - 1)] eq "\n") {
4325 pop @$l;
4326 }
4327 $nr_line = scalar @$l;
4328 if (!$nr_line) {
4329 print "1 line\n\n\n";
4330 } else {
4331 if ($nr_line == 1) {
4332 $nr_line = '1 line';
4333 } else {
4334 $nr_line .= ' lines';
4335 }
4336 print $nr_line, "\n";
4337 show_commit_changed_paths($c);
4338 print "\n";
4339 print $_ foreach @$l;
4340 }
4341 } else {
4342 print "1 line\n";
4343 show_commit_changed_paths($c);
4344 print "\n";
4345
4346 }
4347 foreach my $x (qw/raw stat diff/) {
4348 if ($c->{$x}) {
4349 print "\n";
4350 print $_ foreach @{$c->{$x}}
4351 }
4352 }
4353 }
4354
4355 sub cmd_show_log {
4356 my (@args) = @_;
4357 my ($r_min, $r_max);
4358 my $r_last = -1; # prevent dupes
4359 set_local_timezone();
4360 if (defined $::_revision) {
4361 if ($::_revision =~ /^(\d+):(\d+)$/) {
4362 ($r_min, $r_max) = ($1, $2);
4363 } elsif ($::_revision =~ /^\d+$/) {
4364 $r_min = $r_max = $::_revision;
4365 } else {
4366 ::fatal "-r$::_revision is not supported, use ",
4367 "standard 'git log' arguments instead";
4368 }
4369 }
4370
4371 config_pager();
4372 @args = git_svn_log_cmd($r_min, $r_max, @args);
4373 if (!@args) {
4374 print commit_log_separator unless $incremental || $oneline;
4375 return;
4376 }
4377 my $log = command_output_pipe(@args);
4378 run_pager();
4379 my (@k, $c, $d, $stat);
4380 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4381 while (<$log>) {
4382 if (/^${esc_color}commit -?($::sha1_short)/o) {
4383 my $cmt = $1;
4384 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4385 $r_last = $c->{r};
4386 process_commit($c, $r_min, $r_max, \@k) or
4387 goto out;
4388 }
4389 $d = undef;
4390 $c = { c => $cmt };
4391 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4392 get_author_info($c, $1, $2, $3);
4393 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4394 # ignore
4395 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4396 push @{$c->{raw}}, $_;
4397 } elsif (/^${esc_color}[ACRMDT]\t/) {
4398 # we could add $SVN->{svn_path} here, but that requires
4399 # remote access at the moment (repo_path_split)...
4400 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
4401 push @{$c->{changed}}, $_;
4402 } elsif (/^${esc_color}diff /o) {
4403 $d = 1;
4404 push @{$c->{diff}}, $_;
4405 } elsif ($d) {
4406 push @{$c->{diff}}, $_;
4407 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4408 $esc_color*[\+\-]*$esc_color$/x) {
4409 $stat = 1;
4410 push @{$c->{stat}}, $_;
4411 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4412 push @{$c->{stat}}, $_;
4413 $stat = undef;
4414 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
4415 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4416 } elsif (s/^${esc_color} //o) {
4417 push @{$c->{l}}, $_;
4418 }
4419 }
4420 if ($c && defined $c->{r} && $c->{r} != $r_last) {
4421 $r_last = $c->{r};
4422 process_commit($c, $r_min, $r_max, \@k);
4423 }
4424 if (@k) {
4425 ($r_min, $r_max) = ($r_max, $r_min);
4426 process_commit($_, $r_min, $r_max) foreach reverse @k;
4427 }
4428 out:
4429 close $log;
4430 print commit_log_separator unless $incremental || $oneline;
4431 }
4432
4433 package Git::SVN::Migration;
4434 # these version numbers do NOT correspond to actual version numbers
4435 # of git nor git-svn. They are just relative.
4436 #
4437 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4438 #
4439 # v1 layout: .git/$id/info/url, refs/remotes/$id
4440 #
4441 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4442 #
4443 # v3 layout: .git/svn/$id, refs/remotes/$id
4444 # - info/url may remain for backwards compatibility
4445 # - this is what we migrate up to this layout automatically,
4446 # - this will be used by git svn init on single branches
4447 # v3.1 layout (auto migrated):
4448 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4449 # for backwards compatibility
4450 #
4451 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4452 # - this is only created for newly multi-init-ed
4453 # repositories. Similar in spirit to the
4454 # --use-separate-remotes option in git-clone (now default)
4455 # - we do not automatically migrate to this (following
4456 # the example set by core git)
4457 #
4458 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4459 # - newer, more-efficient format that uses 24-bytes per record
4460 # with no filler space.
4461 # - use xxd -c24 < .rev_map.$UUID to view and debug
4462 # - This is a one-way migration, repositories updated to the
4463 # new format will not be able to use old git-svn without
4464 # rebuilding the .rev_db. Rebuilding the rev_db is not
4465 # possible if noMetadata or useSvmProps are set; but should
4466 # be no problem for users that use the (sensible) defaults.
4467 use strict;
4468 use warnings;
4469 use Carp qw/croak/;
4470 use File::Path qw/mkpath/;
4471 use File::Basename qw/dirname basename/;
4472 use vars qw/$_minimize/;
4473
4474 sub migrate_from_v0 {
4475 my $git_dir = $ENV{GIT_DIR};
4476 return undef unless -d $git_dir;
4477 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4478 my $migrated = 0;
4479 while (<$fh>) {
4480 chomp;
4481 my ($id, $orig_ref) = ($_, $_);
4482 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4483 next unless -f "$git_dir/$id/info/url";
4484 my $new_ref = "refs/remotes/$id";
4485 if (::verify_ref("$new_ref^0")) {
4486 print STDERR "W: $orig_ref is probably an old ",
4487 "branch used by an ancient version of ",
4488 "git-svn.\n",
4489 "However, $new_ref also exists.\n",
4490 "We will not be able ",
4491 "to use this branch until this ",
4492 "ambiguity is resolved.\n";
4493 next;
4494 }
4495 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4496 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4497 command_noisy('update-ref', $new_ref, $orig_ref);
4498 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4499 $migrated++;
4500 }
4501 command_close_pipe($fh, $ctx);
4502 print STDERR "Done migrating from v0 layout...\n" if $migrated;
4503 $migrated;
4504 }
4505
4506 sub migrate_from_v1 {
4507 my $git_dir = $ENV{GIT_DIR};
4508 my $migrated = 0;
4509 return $migrated unless -d $git_dir;
4510 my $svn_dir = "$git_dir/svn";
4511
4512 # just in case somebody used 'svn' as their $id at some point...
4513 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4514
4515 print STDERR "Migrating from a git-svn v1 layout...\n";
4516 mkpath([$svn_dir]);
4517 print STDERR "Data from a previous version of git-svn exists, but\n\t",
4518 "$svn_dir\n\t(required for this version ",
4519 "($::VERSION) of git-svn) does not. exist\n";
4520 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4521 while (<$fh>) {
4522 my $x = $_;
4523 next unless $x =~ s#^refs/remotes/##;
4524 chomp $x;
4525 next unless -f "$git_dir/$x/info/url";
4526 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4527 next unless $u;
4528 my $dn = dirname("$git_dir/svn/$x");
4529 mkpath([$dn]) unless -d $dn;
4530 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4531 mkpath(["$git_dir/svn/svn"]);
4532 print STDERR " - $git_dir/$x/info => ",
4533 "$git_dir/svn/$x/info\n";
4534 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4535 croak "$!: $x";
4536 # don't worry too much about these, they probably
4537 # don't exist with repos this old (save for index,
4538 # and we can easily regenerate that)
4539 foreach my $f (qw/unhandled.log index .rev_db/) {
4540 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4541 }
4542 } else {
4543 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4544 rename "$git_dir/$x", "$git_dir/svn/$x" or
4545 croak "$!: $x";
4546 }
4547 $migrated++;
4548 }
4549 command_close_pipe($fh, $ctx);
4550 print STDERR "Done migrating from a git-svn v1 layout\n";
4551 $migrated;
4552 }
4553
4554 sub read_old_urls {
4555 my ($l_map, $pfx, $path) = @_;
4556 my @dir;
4557 foreach (<$path/*>) {
4558 if (-r "$_/info/url") {
4559 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4560 my $ref_id = $pfx . basename $_;
4561 my $url = ::file_to_s("$_/info/url");
4562 $l_map->{$ref_id} = $url;
4563 } elsif (-d $_) {
4564 push @dir, $_;
4565 }
4566 }
4567 foreach (@dir) {
4568 my $x = $_;
4569 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4570 read_old_urls($l_map, $x, $_);
4571 }
4572 }
4573
4574 sub migrate_from_v2 {
4575 my @cfg = command(qw/config -l/);
4576 return if grep /^svn-remote\..+\.url=/, @cfg;
4577 my %l_map;
4578 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4579 my $migrated = 0;
4580
4581 foreach my $ref_id (sort keys %l_map) {
4582 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4583 if ($@) {
4584 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4585 }
4586 $migrated++;
4587 }
4588 $migrated;
4589 }
4590
4591 sub minimize_connections {
4592 my $r = Git::SVN::read_all_remotes();
4593 my $new_urls = {};
4594 my $root_repos = {};
4595 foreach my $repo_id (keys %$r) {
4596 my $url = $r->{$repo_id}->{url} or next;
4597 my $fetch = $r->{$repo_id}->{fetch} or next;
4598 my $ra = Git::SVN::Ra->new($url);
4599
4600 # skip existing cases where we already connect to the root
4601 if (($ra->{url} eq $ra->{repos_root}) ||
4602 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4603 $repo_id)) {
4604 $root_repos->{$ra->{url}} = $repo_id;
4605 next;
4606 }
4607
4608 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4609 my $root_path = $ra->{url};
4610 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4611 foreach my $path (keys %$fetch) {
4612 my $ref_id = $fetch->{$path};
4613 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4614
4615 # make sure we can read when connecting to
4616 # a higher level of a repository
4617 my ($last_rev, undef) = $gs->last_rev_commit;
4618 if (!defined $last_rev) {
4619 $last_rev = eval {
4620 $root_ra->get_latest_revnum;
4621 };
4622 next if $@;
4623 }
4624 my $new = $root_path;
4625 $new .= length $path ? "/$path" : '';
4626 eval {
4627 $root_ra->get_log([$new], $last_rev, $last_rev,
4628 0, 0, 1, sub { });
4629 };
4630 next if $@;
4631 $new_urls->{$ra->{repos_root}}->{$new} =
4632 { ref_id => $ref_id,
4633 old_repo_id => $repo_id,
4634 old_path => $path };
4635 }
4636 }
4637
4638 my @emptied;
4639 foreach my $url (keys %$new_urls) {
4640 # see if we can re-use an existing [svn-remote "repo_id"]
4641 # instead of creating a(n ugly) new section:
4642 my $repo_id = $root_repos->{$url} ||
4643 Git::SVN::sanitize_remote_name($url);
4644
4645 my $fetch = $new_urls->{$url};
4646 foreach my $path (keys %$fetch) {
4647 my $x = $fetch->{$path};
4648 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4649 my $pfx = "svn-remote.$x->{old_repo_id}";
4650
4651 my $old_fetch = quotemeta("$x->{old_path}:".
4652 "refs/remotes/$x->{ref_id}");
4653 command_noisy(qw/config --unset/,
4654 "$pfx.fetch", '^'. $old_fetch . '$');
4655 delete $r->{$x->{old_repo_id}}->
4656 {fetch}->{$x->{old_path}};
4657 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4658 command_noisy(qw/config --unset/,
4659 "$pfx.url");
4660 push @emptied, $x->{old_repo_id}
4661 }
4662 }
4663 }
4664 if (@emptied) {
4665 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4666 "$ENV{GIT_DIR}/config";
4667 print STDERR <<EOF;
4668 The following [svn-remote] sections in your config file ($file) are empty
4669 and can be safely removed:
4670 EOF
4671 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4672 }
4673 }
4674
4675 sub migration_check {
4676 migrate_from_v0();
4677 migrate_from_v1();
4678 migrate_from_v2();
4679 minimize_connections() if $_minimize;
4680 }
4681
4682 package Git::IndexInfo;
4683 use strict;
4684 use warnings;
4685 use Git qw/command_input_pipe command_close_pipe/;
4686
4687 sub new {
4688 my ($class) = @_;
4689 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4690 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4691 }
4692
4693 sub remove {
4694 my ($self, $path) = @_;
4695 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4696 return ++$self->{nr};
4697 }
4698 undef;
4699 }
4700
4701 sub update {
4702 my ($self, $mode, $hash, $path) = @_;
4703 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4704 return ++$self->{nr};
4705 }
4706 undef;
4707 }
4708
4709 sub DESTROY {
4710 my ($self) = @_;
4711 command_close_pipe($self->{gui}, $self->{ctx});
4712 }
4713
4714 package Git::SVN::GlobSpec;
4715 use strict;
4716 use warnings;
4717
4718 sub new {
4719 my ($class, $glob) = @_;
4720 my $re = $glob;
4721 $re =~ s!/+$!!g; # no need for trailing slashes
4722 my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4723 my ($left, $right) = ($1, $2);
4724 if ($nr > 1) {
4725 die "Only one '*' wildcard expansion ",
4726 "is supported (got $nr): '$glob'\n";
4727 } elsif ($nr == 0) {
4728 die "One '*' is needed for glob: '$glob'\n";
4729 }
4730 $re = quotemeta($left) . $re . quotemeta($right);
4731 if (length $left && !($left =~ s!/+$!!g)) {
4732 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4733 }
4734 if (length $right && !($right =~ s!^/+!!g)) {
4735 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4736 }
4737 my $left_re = qr/^\/\Q$left\E(\/|$)/;
4738 bless { left => $left, right => $right, left_regex => $left_re,
4739 regex => qr/$re/, glob => $glob }, $class;
4740 }
4741
4742 sub full_path {
4743 my ($self, $path) = @_;
4744 return (length $self->{left} ? "$self->{left}/" : '') .
4745 $path . (length $self->{right} ? "/$self->{right}" : '');
4746 }
4747
4748 __END__
4749
4750 Data structures:
4751
4752
4753 $remotes = { # returned by read_all_remotes()
4754 'svn' => {
4755 # svn-remote.svn.url=https://svn.musicpd.org
4756 url => 'https://svn.musicpd.org',
4757 # svn-remote.svn.fetch=mpd/trunk:trunk
4758 fetch => {
4759 'mpd/trunk' => 'trunk',
4760 },
4761 # svn-remote.svn.tags=mpd/tags/*:tags/*
4762 tags => {
4763 path => {
4764 left => 'mpd/tags',
4765 right => '',
4766 regex => qr!mpd/tags/([^/]+)$!,
4767 glob => 'tags/*',
4768 },
4769 ref => {
4770 left => 'tags',
4771 right => '',
4772 regex => qr!tags/([^/]+)$!,
4773 glob => 'tags/*',
4774 },
4775 }
4776 }
4777 };
4778
4779 $log_entry hashref as returned by libsvn_log_entry()
4780 {
4781 log => 'whitespace-formatted log entry
4782 ', # trailing newline is preserved
4783 revision => '8', # integer
4784 date => '2004-02-24T17:01:44.108345Z', # commit date
4785 author => 'committer name'
4786 };
4787
4788
4789 # this is generated by generate_diff();
4790 @mods = array of diff-index line hashes, each element represents one line
4791 of diff-index output
4792
4793 diff-index line ($m hash)
4794 {
4795 mode_a => first column of diff-index output, no leading ':',
4796 mode_b => second column of diff-index output,
4797 sha1_b => sha1sum of the final blob,
4798 chg => change type [MCRADT],
4799 file_a => original file name of a file (iff chg is 'C' or 'R')
4800 file_b => new/current file name of a file (any chg)
4801 }
4802 ;
4803
4804 # retval of read_url_paths{,_all}();
4805 $l_map = {
4806 # repository root url
4807 'https://svn.musicpd.org' => {
4808 # repository path # GIT_SVN_ID
4809 'mpd/trunk' => 'trunk',
4810 'mpd/tags/0.11.5' => 'tags/0.11.5',
4811 },
4812 }
4813
4814 Notes:
4815 I don't trust the each() function on unless I created %hash myself
4816 because the internal iterator may not have started at base.
Alternate source for your git.git needs