git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [encoding convertfrom utf-8 {
  14 Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title [mc "git-gui: fatal error"] \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86 }
  87
  88 ######################################################################
  89 ##
  90 ## Internationalization (i18n) through msgcat and gettext. See
  91 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  92
  93 package require msgcat
  94
  95 proc _mc_trim {fmt} {
  96         set cmk [string first @@ $fmt]
  97         if {$cmk > 0} {
  98                 return [string range $fmt 0 [expr {$cmk - 1}]]
  99         }
 100         return $fmt
 101 }
 102
 103 proc mc {en_fmt args} {
 104         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 105         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 106                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 107         }
 108         return $msg
 109 }
 110
 111 proc strcat {args} {
 112         return [join $args {}]
 113 }
 114
 115 ::msgcat::mcload $oguimsg
 116 unset oguimsg
 117
 118 ######################################################################
 119 ##
 120 ## read only globals
 121
 122 set _appname {Git Gui}
 123 set _gitdir {}
 124 set _gitexec {}
 125 set _reponame {}
 126 set _iscygwin {}
 127 set _search_path {}
 128
 129 set _trace [lsearch -exact $argv --trace]
 130 if {$_trace >= 0} {
 131         set argv [lreplace $argv $_trace $_trace]
 132         set _trace 1
 133 } else {
 134         set _trace 0
 135 }
 136
 137 proc appname {} {
 138         global _appname
 139         return $_appname
 140 }
 141
 142 proc gitdir {args} {
 143         global _gitdir
 144         if {$args eq {}} {
 145                 return $_gitdir
 146         }
 147         return [eval [list file join $_gitdir] $args]
 148 }
 149
 150 proc gitexec {args} {
 151         global _gitexec
 152         if {$_gitexec eq {}} {
 153                 if {[catch {set _gitexec [git --exec-path]} err]} {
 154                         error "Git not installed?\n\n$err"
 155                 }
 156                 if {[is_Cygwin]} {
 157                         set _gitexec [exec cygpath \
 158                                 --windows \
 159                                 --absolute \
 160                                 $_gitexec]
 161                 } else {
 162                         set _gitexec [file normalize $_gitexec]
 163                 }
 164         }
 165         if {$args eq {}} {
 166                 return $_gitexec
 167         }
 168         return [eval [list file join $_gitexec] $args]
 169 }
 170
 171 proc reponame {} {
 172         return $::_reponame
 173 }
 174
 175 proc is_MacOSX {} {
 176         if {[tk windowingsystem] eq {aqua}} {
 177                 return 1
 178         }
 179         return 0
 180 }
 181
 182 proc is_Windows {} {
 183         if {$::tcl_platform(platform) eq {windows}} {
 184                 return 1
 185         }
 186         return 0
 187 }
 188
 189 proc is_Cygwin {} {
 190         global _iscygwin
 191         if {$_iscygwin eq {}} {
 192                 if {$::tcl_platform(platform) eq {windows}} {
 193                         if {[catch {set p [exec cygpath --windir]} err]} {
 194                                 set _iscygwin 0
 195                         } else {
 196                                 set _iscygwin 1
 197                         }
 198                 } else {
 199                         set _iscygwin 0
 200                 }
 201         }
 202         return $_iscygwin
 203 }
 204
 205 proc is_enabled {option} {
 206         global enabled_options
 207         if {[catch {set on $enabled_options($option)}]} {return 0}
 208         return $on
 209 }
 210
 211 proc enable_option {option} {
 212         global enabled_options
 213         set enabled_options($option) 1
 214 }
 215
 216 proc disable_option {option} {
 217         global enabled_options
 218         set enabled_options($option) 0
 219 }
 220
 221 ######################################################################
 222 ##
 223 ## config
 224
 225 proc is_many_config {name} {
 226         switch -glob -- $name {
 227         gui.recentrepo -
 228         remote.*.fetch -
 229         remote.*.push
 230                 {return 1}
 231         *
 232                 {return 0}
 233         }
 234 }
 235
 236 proc is_config_true {name} {
 237         global repo_config
 238         if {[catch {set v $repo_config($name)}]} {
 239                 return 0
 240         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 241                 return 1
 242         } else {
 243                 return 0
 244         }
 245 }
 246
 247 proc get_config {name} {
 248         global repo_config
 249         if {[catch {set v $repo_config($name)}]} {
 250                 return {}
 251         } else {
 252                 return $v
 253         }
 254 }
 255
 256 ######################################################################
 257 ##
 258 ## handy utils
 259
 260 proc _trace_exec {cmd} {
 261         if {!$::_trace} return
 262         set d {}
 263         foreach v $cmd {
 264                 if {$d ne {}} {
 265                         append d { }
 266                 }
 267                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 268                         set v [sq $v]
 269                 }
 270                 append d $v
 271         }
 272         puts stderr $d
 273 }
 274
 275 proc _git_cmd {name} {
 276         global _git_cmd_path
 277
 278         if {[catch {set v $_git_cmd_path($name)}]} {
 279                 switch -- $name {
 280                   version   -
 281                 --version   -
 282                 --exec-path { return [list $::_git $name] }
 283                 }
 284
 285                 set p [gitexec git-$name$::_search_exe]
 286                 if {[file exists $p]} {
 287                         set v [list $p]
 288                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 289                         # Try to determine what sort of magic will make
 290                         # git-$name go and do its thing, because native
 291                         # Tcl on Windows doesn't know it.
 292                         #
 293                         set p [gitexec git-$name]
 294                         set f [open $p r]
 295                         set s [gets $f]
 296                         close $f
 297
 298                         switch -glob -- [lindex $s 0] {
 299                         #!*sh     { set i sh     }
 300                         #!*perl   { set i perl   }
 301                         #!*python { set i python }
 302                         default   { error "git-$name is not supported: $s" }
 303                         }
 304
 305                         upvar #0 _$i interp
 306                         if {![info exists interp]} {
 307                                 set interp [_which $i]
 308                         }
 309                         if {$interp eq {}} {
 310                                 error "git-$name requires $i (not in PATH)"
 311                         }
 312                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 313                 } else {
 314                         # Assume it is builtin to git somehow and we
 315                         # aren't actually able to see a file for it.
 316                         #
 317                         set v [list $::_git $name]
 318                 }
 319                 set _git_cmd_path($name) $v
 320         }
 321         return $v
 322 }
 323
 324 proc _which {what args} {
 325         global env _search_exe _search_path
 326
 327         if {$_search_path eq {}} {
 328                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 329                         set _search_path [split [exec cygpath \
 330                                 --windows \
 331                                 --path \
 332                                 --absolute \
 333                                 $env(PATH)] {;}]
 334                         set _search_exe .exe
 335                 } elseif {[is_Windows]} {
 336                         set gitguidir [file dirname [info script]]
 337                         regsub -all ";" $gitguidir "\\;" gitguidir
 338                         set env(PATH) "$gitguidir;$env(PATH)"
 339                         set _search_path [split $env(PATH) {;}]
 340                         set _search_exe .exe
 341                 } else {
 342                         set _search_path [split $env(PATH) :]
 343                         set _search_exe {}
 344                 }
 345         }
 346
 347         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 348                 set suffix {}
 349         } else {
 350                 set suffix $_search_exe
 351         }
 352
 353         foreach p $_search_path {
 354                 set p [file join $p $what$suffix]
 355                 if {[file exists $p]} {
 356                         return [file normalize $p]
 357                 }
 358         }
 359         return {}
 360 }
 361
 362 proc _lappend_nice {cmd_var} {
 363         global _nice
 364         upvar $cmd_var cmd
 365
 366         if {![info exists _nice]} {
 367                 set _nice [_which nice]
 368         }
 369         if {$_nice ne {}} {
 370                 lappend cmd $_nice
 371         }
 372 }
 373
 374 proc git {args} {
 375         set opt [list]
 376
 377         while {1} {
 378                 switch -- [lindex $args 0] {
 379                 --nice {
 380                         _lappend_nice opt
 381                 }
 382
 383                 default {
 384                         break
 385                 }
 386
 387                 }
 388
 389                 set args [lrange $args 1 end]
 390         }
 391
 392         set cmdp [_git_cmd [lindex $args 0]]
 393         set args [lrange $args 1 end]
 394
 395         _trace_exec [concat $opt $cmdp $args]
 396         set result [eval exec $opt $cmdp $args]
 397         if {$::_trace} {
 398                 puts stderr "< $result"
 399         }
 400         return $result
 401 }
 402
 403 proc _open_stdout_stderr {cmd} {
 404         _trace_exec $cmd
 405         if {[catch {
 406                         set fd [open [concat [list | ] $cmd] r]
 407                 } err]} {
 408                 if {   [lindex $cmd end] eq {2>@1}
 409                     && $err eq {can not find channel named "1"}
 410                         } {
 411                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 412                         # redirect operator.  Fallback to |& cat for those.
 413                         # The command was not actually started, so its safe
 414                         # to try to start it a second time.
 415                         #
 416                         set fd [open [concat \
 417                                 [list | ] \
 418                                 [lrange $cmd 0 end-1] \
 419                                 [list |& cat] \
 420                                 ] r]
 421                 } else {
 422                         error $err
 423                 }
 424         }
 425         fconfigure $fd -eofchar {}
 426         return $fd
 427 }
 428
 429 proc git_read {args} {
 430         set opt [list]
 431
 432         while {1} {
 433                 switch -- [lindex $args 0] {
 434                 --nice {
 435                         _lappend_nice opt
 436                 }
 437
 438                 --stderr {
 439                         lappend args 2>@1
 440                 }
 441
 442                 default {
 443                         break
 444                 }
 445
 446                 }
 447
 448                 set args [lrange $args 1 end]
 449         }
 450
 451         set cmdp [_git_cmd [lindex $args 0]]
 452         set args [lrange $args 1 end]
 453
 454         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 455 }
 456
 457 proc git_write {args} {
 458         set opt [list]
 459
 460         while {1} {
 461                 switch -- [lindex $args 0] {
 462                 --nice {
 463                         _lappend_nice opt
 464                 }
 465
 466                 default {
 467                         break
 468                 }
 469
 470                 }
 471
 472                 set args [lrange $args 1 end]
 473         }
 474
 475         set cmdp [_git_cmd [lindex $args 0]]
 476         set args [lrange $args 1 end]
 477
 478         _trace_exec [concat $opt $cmdp $args]
 479         return [open [concat [list | ] $opt $cmdp $args] w]
 480 }
 481
 482 proc githook_read {hook_name args} {
 483         set pchook [gitdir hooks $hook_name]
 484         lappend args 2>@1
 485
 486         # On Windows [file executable] might lie so we need to ask
 487         # the shell if the hook is executable.  Yes that's annoying.
 488         #
 489         if {[is_Windows]} {
 490                 upvar #0 _sh interp
 491                 if {![info exists interp]} {
 492                         set interp [_which sh]
 493                 }
 494                 if {$interp eq {}} {
 495                         error "hook execution requires sh (not in PATH)"
 496                 }
 497
 498                 set scr {if test -x "$1";then exec "$@";fi}
 499                 set sh_c [list $interp -c $scr $interp $pchook]
 500                 return [_open_stdout_stderr [concat $sh_c $args]]
 501         }
 502
 503         if {[file executable $pchook]} {
 504                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 505         }
 506
 507         return {}
 508 }
 509
 510 proc kill_file_process {fd} {
 511         set process [pid $fd]
 512
 513         catch {
 514                 if {[is_Windows]} {
 515                         # Use a Cygwin-specific flag to allow killing
 516                         # native Windows processes
 517                         exec kill -f $process
 518                 } else {
 519                         exec kill $process
 520                 }
 521         }
 522 }
 523
 524 proc sq {value} {
 525         regsub -all ' $value "'\\''" value
 526         return "'$value'"
 527 }
 528
 529 proc load_current_branch {} {
 530         global current_branch is_detached
 531
 532         set fd [open [gitdir HEAD] r]
 533         if {[gets $fd ref] < 1} {
 534                 set ref {}
 535         }
 536         close $fd
 537
 538         set pfx {ref: refs/heads/}
 539         set len [string length $pfx]
 540         if {[string equal -length $len $pfx $ref]} {
 541                 # We're on a branch.  It might not exist.  But
 542                 # HEAD looks good enough to be a branch.
 543                 #
 544                 set current_branch [string range $ref $len end]
 545                 set is_detached 0
 546         } else {
 547                 # Assume this is a detached head.
 548                 #
 549                 set current_branch HEAD
 550                 set is_detached 1
 551         }
 552 }
 553
 554 auto_load tk_optionMenu
 555 rename tk_optionMenu real__tkOptionMenu
 556 proc tk_optionMenu {w varName args} {
 557         set m [eval real__tkOptionMenu $w $varName $args]
 558         $m configure -font font_ui
 559         $w configure -font font_ui
 560         return $m
 561 }
 562
 563 proc rmsel_tag {text} {
 564         $text tag conf sel \
 565                 -background [$text cget -background] \
 566                 -foreground [$text cget -foreground] \
 567                 -borderwidth 0
 568         $text tag conf in_sel -background lightgray
 569         bind $text <Motion> break
 570         return $text
 571 }
 572
 573 set root_exists 0
 574 bind . <Visibility> {
 575         bind . <Visibility> {}
 576         set root_exists 1
 577 }
 578
 579 if {[is_Windows]} {
 580         wm iconbitmap . -default $oguilib/git-gui.ico
 581 }
 582
 583 ######################################################################
 584 ##
 585 ## config defaults
 586
 587 set cursor_ptr arrow
 588 font create font_diff -family Courier -size 10
 589 font create font_ui
 590 catch {
 591         label .dummy
 592         eval font configure font_ui [font actual [.dummy cget -font]]
 593         destroy .dummy
 594 }
 595
 596 font create font_uiitalic
 597 font create font_uibold
 598 font create font_diffbold
 599 font create font_diffitalic
 600
 601 foreach class {Button Checkbutton Entry Label
 602                 Labelframe Listbox Menu Message
 603                 Radiobutton Spinbox Text} {
 604         option add *$class.font font_ui
 605 }
 606 unset class
 607
 608 if {[is_Windows] || [is_MacOSX]} {
 609         option add *Menu.tearOff 0
 610 }
 611
 612 if {[is_MacOSX]} {
 613         set M1B M1
 614         set M1T Cmd
 615 } else {
 616         set M1B Control
 617         set M1T Ctrl
 618 }
 619
 620 proc bind_button3 {w cmd} {
 621         bind $w <Any-Button-3> $cmd
 622         if {[is_MacOSX]} {
 623                 # Mac OS X sends Button-2 on right click through three-button mouse,
 624                 # or through trackpad right-clicking (two-finger touch + click).
 625                 bind $w <Any-Button-2> $cmd
 626                 bind $w <Control-Button-1> $cmd
 627         }
 628 }
 629
 630 proc apply_config {} {
 631         global repo_config font_descs
 632
 633         foreach option $font_descs {
 634                 set name [lindex $option 0]
 635                 set font [lindex $option 1]
 636                 if {[catch {
 637                         set need_weight 1
 638                         foreach {cn cv} $repo_config(gui.$name) {
 639                                 if {$cn eq {-weight}} {
 640                                         set need_weight 0
 641                                 }
 642                                 font configure $font $cn $cv
 643                         }
 644                         if {$need_weight} {
 645                                 font configure $font -weight normal
 646                         }
 647                         } err]} {
 648                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 649                 }
 650                 foreach {cn cv} [font configure $font] {
 651                         font configure ${font}bold $cn $cv
 652                         font configure ${font}italic $cn $cv
 653                 }
 654                 font configure ${font}bold -weight bold
 655                 font configure ${font}italic -slant italic
 656         }
 657 }
 658
 659 set default_config(branch.autosetupmerge) true
 660 set default_config(merge.tool) {}
 661 set default_config(merge.keepbackup) true
 662 set default_config(merge.diffstat) true
 663 set default_config(merge.summary) false
 664 set default_config(merge.verbosity) 2
 665 set default_config(user.name) {}
 666 set default_config(user.email) {}
 667
 668 set default_config(gui.matchtrackingbranch) false
 669 set default_config(gui.pruneduringfetch) false
 670 set default_config(gui.trustmtime) false
 671 set default_config(gui.fastcopyblame) false
 672 set default_config(gui.copyblamethreshold) 40
 673 set default_config(gui.blamehistoryctx) 7
 674 set default_config(gui.diffcontext) 5
 675 set default_config(gui.commitmsgwidth) 75
 676 set default_config(gui.newbranchtemplate) {}
 677 set default_config(gui.spellingdictionary) {}
 678 set default_config(gui.fontui) [font configure font_ui]
 679 set default_config(gui.fontdiff) [font configure font_diff]
 680 set font_descs {
 681         {fontui   font_ui   {mc "Main Font"}}
 682         {fontdiff font_diff {mc "Diff/Console Font"}}
 683 }
 684
 685 ######################################################################
 686 ##
 687 ## find git
 688
 689 set _git  [_which git]
 690 if {$_git eq {}} {
 691         catch {wm withdraw .}
 692         tk_messageBox \
 693                 -icon error \
 694                 -type ok \
 695                 -title [mc "git-gui: fatal error"] \
 696                 -message [mc "Cannot find git in PATH."]
 697         exit 1
 698 }
 699
 700 ######################################################################
 701 ##
 702 ## version check
 703
 704 if {[catch {set _git_version [git --version]} err]} {
 705         catch {wm withdraw .}
 706         tk_messageBox \
 707                 -icon error \
 708                 -type ok \
 709                 -title [mc "git-gui: fatal error"] \
 710                 -message "Cannot determine Git version:
 711
 712 $err
 713
 714 [appname] requires Git 1.5.0 or later."
 715         exit 1
 716 }
 717 if {![regsub {^git version } $_git_version {} _git_version]} {
 718         catch {wm withdraw .}
 719         tk_messageBox \
 720                 -icon error \
 721                 -type ok \
 722                 -title [mc "git-gui: fatal error"] \
 723                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 724         exit 1
 725 }
 726
 727 set _real_git_version $_git_version
 728 regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 729 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 730 regsub {\.rc[0-9]+$} $_git_version {} _git_version
 731 regsub {\.GIT$} $_git_version {} _git_version
 732 regsub {\.[a-zA-Z]+\.[0-9]+$} $_git_version {} _git_version
 733
 734 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 735         catch {wm withdraw .}
 736         if {[tk_messageBox \
 737                 -icon warning \
 738                 -type yesno \
 739                 -default no \
 740                 -title "[appname]: warning" \
 741                  -message [mc "Git version cannot be determined.
 742
 743 %s claims it is version '%s'.
 744
 745 %s requires at least Git 1.5.0 or later.
 746
 747 Assume '%s' is version 1.5.0?
 748 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 749                 set _git_version 1.5.0
 750         } else {
 751                 exit 1
 752         }
 753 }
 754 unset _real_git_version
 755
 756 proc git-version {args} {
 757         global _git_version
 758
 759         switch [llength $args] {
 760         0 {
 761                 return $_git_version
 762         }
 763
 764         2 {
 765                 set op [lindex $args 0]
 766                 set vr [lindex $args 1]
 767                 set cm [package vcompare $_git_version $vr]
 768                 return [expr $cm $op 0]
 769         }
 770
 771         4 {
 772                 set type [lindex $args 0]
 773                 set name [lindex $args 1]
 774                 set parm [lindex $args 2]
 775                 set body [lindex $args 3]
 776
 777                 if {($type ne {proc} && $type ne {method})} {
 778                         error "Invalid arguments to git-version"
 779                 }
 780                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 781                         error "Last arm of $type $name must be default"
 782                 }
 783
 784                 foreach {op vr cb} [lrange $body 0 end-2] {
 785                         if {[git-version $op $vr]} {
 786                                 return [uplevel [list $type $name $parm $cb]]
 787                         }
 788                 }
 789
 790                 return [uplevel [list $type $name $parm [lindex $body end]]]
 791         }
 792
 793         default {
 794                 error "git-version >= x"
 795         }
 796
 797         }
 798 }
 799
 800 if {[git-version < 1.5]} {
 801         catch {wm withdraw .}
 802         tk_messageBox \
 803                 -icon error \
 804                 -type ok \
 805                 -title [mc "git-gui: fatal error"] \
 806                 -message "[appname] requires Git 1.5.0 or later.
 807
 808 You are using [git-version]:
 809
 810 [git --version]"
 811         exit 1
 812 }
 813
 814 ######################################################################
 815 ##
 816 ## configure our library
 817
 818 set idx [file join $oguilib tclIndex]
 819 if {[catch {set fd [open $idx r]} err]} {
 820         catch {wm withdraw .}
 821         tk_messageBox \
 822                 -icon error \
 823                 -type ok \
 824                 -title [mc "git-gui: fatal error"] \
 825                 -message $err
 826         exit 1
 827 }
 828 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 829         set idx [list]
 830         while {[gets $fd n] >= 0} {
 831                 if {$n ne {} && ![string match #* $n]} {
 832                         lappend idx $n
 833                 }
 834         }
 835 } else {
 836         set idx {}
 837 }
 838 close $fd
 839
 840 if {$idx ne {}} {
 841         set loaded [list]
 842         foreach p $idx {
 843                 if {[lsearch -exact $loaded $p] >= 0} continue
 844                 source [file join $oguilib $p]
 845                 lappend loaded $p
 846         }
 847         unset loaded p
 848 } else {
 849         set auto_path [concat [list $oguilib] $auto_path]
 850 }
 851 unset -nocomplain idx fd
 852
 853 ######################################################################
 854 ##
 855 ## config file parsing
 856
 857 git-version proc _parse_config {arr_name args} {
 858         >= 1.5.3 {
 859                 upvar $arr_name arr
 860                 array unset arr
 861                 set buf {}
 862                 catch {
 863                         set fd_rc [eval \
 864                                 [list git_read config] \
 865                                 $args \
 866                                 [list --null --list]]
 867                         fconfigure $fd_rc -translation binary
 868                         set buf [read $fd_rc]
 869                         close $fd_rc
 870                 }
 871                 foreach line [split $buf "\0"] {
 872                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 873                                 if {[is_many_config $name]} {
 874                                         lappend arr($name) $value
 875                                 } else {
 876                                         set arr($name) $value
 877                                 }
 878                         }
 879                 }
 880         }
 881         default {
 882                 upvar $arr_name arr
 883                 array unset arr
 884                 catch {
 885                         set fd_rc [eval [list git_read config --list] $args]
 886                         while {[gets $fd_rc line] >= 0} {
 887                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 888                                         if {[is_many_config $name]} {
 889                                                 lappend arr($name) $value
 890                                         } else {
 891                                                 set arr($name) $value
 892                                         }
 893                                 }
 894                         }
 895                         close $fd_rc
 896                 }
 897         }
 898 }
 899
 900 proc load_config {include_global} {
 901         global repo_config global_config default_config
 902
 903         if {$include_global} {
 904                 _parse_config global_config --global
 905         }
 906         _parse_config repo_config
 907
 908         foreach name [array names default_config] {
 909                 if {[catch {set v $global_config($name)}]} {
 910                         set global_config($name) $default_config($name)
 911                 }
 912                 if {[catch {set v $repo_config($name)}]} {
 913                         set repo_config($name) $default_config($name)
 914                 }
 915         }
 916 }
 917
 918 ######################################################################
 919 ##
 920 ## feature option selection
 921
 922 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
 923         unset _junk
 924 } else {
 925         set subcommand gui
 926 }
 927 if {$subcommand eq {gui.sh}} {
 928         set subcommand gui
 929 }
 930 if {$subcommand eq {gui} && [llength $argv] > 0} {
 931         set subcommand [lindex $argv 0]
 932         set argv [lrange $argv 1 end]
 933 }
 934
 935 enable_option multicommit
 936 enable_option branch
 937 enable_option transport
 938 disable_option bare
 939
 940 switch -- $subcommand {
 941 browser -
 942 blame {
 943         enable_option bare
 944
 945         disable_option multicommit
 946         disable_option branch
 947         disable_option transport
 948 }
 949 citool {
 950         enable_option singlecommit
 951
 952         disable_option multicommit
 953         disable_option branch
 954         disable_option transport
 955 }
 956 }
 957
 958 ######################################################################
 959 ##
 960 ## repository setup
 961
 962 if {[catch {
 963                 set _gitdir $env(GIT_DIR)
 964                 set _prefix {}
 965                 }]
 966         && [catch {
 967                 set _gitdir [git rev-parse --git-dir]
 968                 set _prefix [git rev-parse --show-prefix]
 969         } err]} {
 970         load_config 1
 971         apply_config
 972         choose_repository::pick
 973 }
 974 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
 975         catch {set _gitdir [exec cygpath --windows $_gitdir]}
 976 }
 977 if {![file isdirectory $_gitdir]} {
 978         catch {wm withdraw .}
 979         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
 980         exit 1
 981 }
 982 if {$_prefix ne {}} {
 983         regsub -all {[^/]+/} $_prefix ../ cdup
 984         if {[catch {cd $cdup} err]} {
 985                 catch {wm withdraw .}
 986                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
 987                 exit 1
 988         }
 989         unset cdup
 990 } elseif {![is_enabled bare]} {
 991         if {[lindex [file split $_gitdir] end] ne {.git}} {
 992                 catch {wm withdraw .}
 993                 error_popup [strcat [mc "Cannot use funny .git directory:"] "\n\n$_gitdir"]
 994                 exit 1
 995         }
 996         if {[catch {cd [file dirname $_gitdir]} err]} {
 997                 catch {wm withdraw .}
 998                 error_popup [strcat [mc "No working directory"] " [file dirname $_gitdir]:\n\n$err"]
 999                 exit 1
1000         }
1001 }
1002 set _reponame [file split [file normalize $_gitdir]]
1003 if {[lindex $_reponame end] eq {.git}} {
1004         set _reponame [lindex $_reponame end-1]
1005 } else {
1006         set _reponame [lindex $_reponame end]
1007 }
1008
1009 ######################################################################
1010 ##
1011 ## global init
1012
1013 set current_diff_path {}
1014 set current_diff_side {}
1015 set diff_actions [list]
1016
1017 set HEAD {}
1018 set PARENT {}
1019 set MERGE_HEAD [list]
1020 set commit_type {}
1021 set empty_tree {}
1022 set current_branch {}
1023 set is_detached 0
1024 set current_diff_path {}
1025 set is_3way_diff 0
1026 set selected_commit_type new
1027
1028 ######################################################################
1029 ##
1030 ## task management
1031
1032 set rescan_active 0
1033 set diff_active 0
1034 set last_clicked {}
1035
1036 set disable_on_lock [list]
1037 set index_lock_type none
1038
1039 proc lock_index {type} {
1040         global index_lock_type disable_on_lock
1041
1042         if {$index_lock_type eq {none}} {
1043                 set index_lock_type $type
1044                 foreach w $disable_on_lock {
1045                         uplevel #0 $w disabled
1046                 }
1047                 return 1
1048         } elseif {$index_lock_type eq "begin-$type"} {
1049                 set index_lock_type $type
1050                 return 1
1051         }
1052         return 0
1053 }
1054
1055 proc unlock_index {} {
1056         global index_lock_type disable_on_lock
1057
1058         set index_lock_type none
1059         foreach w $disable_on_lock {
1060                 uplevel #0 $w normal
1061         }
1062 }
1063
1064 ######################################################################
1065 ##
1066 ## status
1067
1068 proc repository_state {ctvar hdvar mhvar} {
1069         global current_branch
1070         upvar $ctvar ct $hdvar hd $mhvar mh
1071
1072         set mh [list]
1073
1074         load_current_branch
1075         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1076                 set hd {}
1077                 set ct initial
1078                 return
1079         }
1080
1081         set merge_head [gitdir MERGE_HEAD]
1082         if {[file exists $merge_head]} {
1083                 set ct merge
1084                 set fd_mh [open $merge_head r]
1085                 while {[gets $fd_mh line] >= 0} {
1086                         lappend mh $line
1087                 }
1088                 close $fd_mh
1089                 return
1090         }
1091
1092         set ct normal
1093 }
1094
1095 proc PARENT {} {
1096         global PARENT empty_tree
1097
1098         set p [lindex $PARENT 0]
1099         if {$p ne {}} {
1100                 return $p
1101         }
1102         if {$empty_tree eq {}} {
1103                 set empty_tree [git mktree << {}]
1104         }
1105         return $empty_tree
1106 }
1107
1108 proc rescan {after {honor_trustmtime 1}} {
1109         global HEAD PARENT MERGE_HEAD commit_type
1110         global ui_index ui_workdir ui_comm
1111         global rescan_active file_states
1112         global repo_config
1113
1114         if {$rescan_active > 0 || ![lock_index read]} return
1115
1116         repository_state newType newHEAD newMERGE_HEAD
1117         if {[string match amend* $commit_type]
1118                 && $newType eq {normal}
1119                 && $newHEAD eq $HEAD} {
1120         } else {
1121                 set HEAD $newHEAD
1122                 set PARENT $newHEAD
1123                 set MERGE_HEAD $newMERGE_HEAD
1124                 set commit_type $newType
1125         }
1126
1127         array unset file_states
1128
1129         if {!$::GITGUI_BCK_exists &&
1130                 (![$ui_comm edit modified]
1131                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1132                 if {[string match amend* $commit_type]} {
1133                 } elseif {[load_message GITGUI_MSG]} {
1134                 } elseif {[load_message MERGE_MSG]} {
1135                 } elseif {[load_message SQUASH_MSG]} {
1136                 }
1137                 $ui_comm edit reset
1138                 $ui_comm edit modified false
1139         }
1140
1141         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1142                 rescan_stage2 {} $after
1143         } else {
1144                 set rescan_active 1
1145                 ui_status [mc "Refreshing file status..."]
1146                 set fd_rf [git_read update-index \
1147                         -q \
1148                         --unmerged \
1149                         --ignore-missing \
1150                         --refresh \
1151                         ]
1152                 fconfigure $fd_rf -blocking 0 -translation binary
1153                 fileevent $fd_rf readable \
1154                         [list rescan_stage2 $fd_rf $after]
1155         }
1156 }
1157
1158 if {[is_Cygwin]} {
1159         set is_git_info_exclude {}
1160         proc have_info_exclude {} {
1161                 global is_git_info_exclude
1162
1163                 if {$is_git_info_exclude eq {}} {
1164                         if {[catch {exec test -f [gitdir info exclude]}]} {
1165                                 set is_git_info_exclude 0
1166                         } else {
1167                                 set is_git_info_exclude 1
1168                         }
1169                 }
1170                 return $is_git_info_exclude
1171         }
1172 } else {
1173         proc have_info_exclude {} {
1174                 return [file readable [gitdir info exclude]]
1175         }
1176 }
1177
1178 proc rescan_stage2 {fd after} {
1179         global rescan_active buf_rdi buf_rdf buf_rlo
1180
1181         if {$fd ne {}} {
1182                 read $fd
1183                 if {![eof $fd]} return
1184                 close $fd
1185         }
1186
1187         set ls_others [list --exclude-per-directory=.gitignore]
1188         if {[have_info_exclude]} {
1189                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1190         }
1191         set user_exclude [get_config core.excludesfile]
1192         if {$user_exclude ne {} && [file readable $user_exclude]} {
1193                 lappend ls_others "--exclude-from=$user_exclude"
1194         }
1195
1196         set buf_rdi {}
1197         set buf_rdf {}
1198         set buf_rlo {}
1199
1200         set rescan_active 3
1201         ui_status [mc "Scanning for modified files ..."]
1202         set fd_di [git_read diff-index --cached -z [PARENT]]
1203         set fd_df [git_read diff-files -z]
1204         set fd_lo [eval git_read ls-files --others -z $ls_others]
1205
1206         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1207         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1208         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1209         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1210         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1211         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1212 }
1213
1214 proc load_message {file} {
1215         global ui_comm
1216
1217         set f [gitdir $file]
1218         if {[file isfile $f]} {
1219                 if {[catch {set fd [open $f r]}]} {
1220                         return 0
1221                 }
1222                 fconfigure $fd -eofchar {}
1223                 set content [string trim [read $fd]]
1224                 close $fd
1225                 regsub -all -line {[ \r\t]+$} $content {} content
1226                 $ui_comm delete 0.0 end
1227                 $ui_comm insert end $content
1228                 return 1
1229         }
1230         return 0
1231 }
1232
1233 proc read_diff_index {fd after} {
1234         global buf_rdi
1235
1236         append buf_rdi [read $fd]
1237         set c 0
1238         set n [string length $buf_rdi]
1239         while {$c < $n} {
1240                 set z1 [string first "\0" $buf_rdi $c]
1241                 if {$z1 == -1} break
1242                 incr z1
1243                 set z2 [string first "\0" $buf_rdi $z1]
1244                 if {$z2 == -1} break
1245
1246                 incr c
1247                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1248                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1249                 merge_state \
1250                         [encoding convertfrom $p] \
1251                         [lindex $i 4]? \
1252                         [list [lindex $i 0] [lindex $i 2]] \
1253                         [list]
1254                 set c $z2
1255                 incr c
1256         }
1257         if {$c < $n} {
1258                 set buf_rdi [string range $buf_rdi $c end]
1259         } else {
1260                 set buf_rdi {}
1261         }
1262
1263         rescan_done $fd buf_rdi $after
1264 }
1265
1266 proc read_diff_files {fd after} {
1267         global buf_rdf
1268
1269         append buf_rdf [read $fd]
1270         set c 0
1271         set n [string length $buf_rdf]
1272         while {$c < $n} {
1273                 set z1 [string first "\0" $buf_rdf $c]
1274                 if {$z1 == -1} break
1275                 incr z1
1276                 set z2 [string first "\0" $buf_rdf $z1]
1277                 if {$z2 == -1} break
1278
1279                 incr c
1280                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1281                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1282                 merge_state \
1283                         [encoding convertfrom $p] \
1284                         ?[lindex $i 4] \
1285                         [list] \
1286                         [list [lindex $i 0] [lindex $i 2]]
1287                 set c $z2
1288                 incr c
1289         }
1290         if {$c < $n} {
1291                 set buf_rdf [string range $buf_rdf $c end]
1292         } else {
1293                 set buf_rdf {}
1294         }
1295
1296         rescan_done $fd buf_rdf $after
1297 }
1298
1299 proc read_ls_others {fd after} {
1300         global buf_rlo
1301
1302         append buf_rlo [read $fd]
1303         set pck [split $buf_rlo "\0"]
1304         set buf_rlo [lindex $pck end]
1305         foreach p [lrange $pck 0 end-1] {
1306                 set p [encoding convertfrom $p]
1307                 if {[string index $p end] eq {/}} {
1308                         set p [string range $p 0 end-1]
1309                 }
1310                 merge_state $p ?O
1311         }
1312         rescan_done $fd buf_rlo $after
1313 }
1314
1315 proc rescan_done {fd buf after} {
1316         global rescan_active current_diff_path
1317         global file_states repo_config
1318         upvar $buf to_clear
1319
1320         if {![eof $fd]} return
1321         set to_clear {}
1322         close $fd
1323         if {[incr rescan_active -1] > 0} return
1324
1325         prune_selection
1326         unlock_index
1327         display_all_files
1328         if {$current_diff_path ne {}} reshow_diff
1329         uplevel #0 $after
1330 }
1331
1332 proc prune_selection {} {
1333         global file_states selected_paths
1334
1335         foreach path [array names selected_paths] {
1336                 if {[catch {set still_here $file_states($path)}]} {
1337                         unset selected_paths($path)
1338                 }
1339         }
1340 }
1341
1342 ######################################################################
1343 ##
1344 ## ui helpers
1345
1346 proc mapicon {w state path} {
1347         global all_icons
1348
1349         if {[catch {set r $all_icons($state$w)}]} {
1350                 puts "error: no icon for $w state={$state} $path"
1351                 return file_plain
1352         }
1353         return $r
1354 }
1355
1356 proc mapdesc {state path} {
1357         global all_descs
1358
1359         if {[catch {set r $all_descs($state)}]} {
1360                 puts "error: no desc for state={$state} $path"
1361                 return $state
1362         }
1363         return $r
1364 }
1365
1366 proc ui_status {msg} {
1367         global main_status
1368         if {[info exists main_status]} {
1369                 $main_status show $msg
1370         }
1371 }
1372
1373 proc ui_ready {{test {}}} {
1374         global main_status
1375         if {[info exists main_status]} {
1376                 $main_status show [mc "Ready."] $test
1377         }
1378 }
1379
1380 proc escape_path {path} {
1381         regsub -all {\\} $path "\\\\" path
1382         regsub -all "\n" $path "\\n" path
1383         return $path
1384 }
1385
1386 proc short_path {path} {
1387         return [escape_path [lindex [file split $path] end]]
1388 }
1389
1390 set next_icon_id 0
1391 set null_sha1 [string repeat 0 40]
1392
1393 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1394         global file_states next_icon_id null_sha1
1395
1396         set s0 [string index $new_state 0]
1397         set s1 [string index $new_state 1]
1398
1399         if {[catch {set info $file_states($path)}]} {
1400                 set state __
1401                 set icon n[incr next_icon_id]
1402         } else {
1403                 set state [lindex $info 0]
1404                 set icon [lindex $info 1]
1405                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1406                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1407         }
1408
1409         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1410         elseif {$s0 eq {_}} {set s0 _}
1411
1412         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1413         elseif {$s1 eq {_}} {set s1 _}
1414
1415         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1416                 set head_info [list 0 $null_sha1]
1417         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1418                 && $head_info eq {}} {
1419                 set head_info $index_info
1420         }
1421
1422         set file_states($path) [list $s0$s1 $icon \
1423                 $head_info $index_info \
1424                 ]
1425         return $state
1426 }
1427
1428 proc display_file_helper {w path icon_name old_m new_m} {
1429         global file_lists
1430
1431         if {$new_m eq {_}} {
1432                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1433                 if {$lno >= 0} {
1434                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1435                         incr lno
1436                         $w conf -state normal
1437                         $w delete $lno.0 [expr {$lno + 1}].0
1438                         $w conf -state disabled
1439                 }
1440         } elseif {$old_m eq {_} && $new_m ne {_}} {
1441                 lappend file_lists($w) $path
1442                 set file_lists($w) [lsort -unique $file_lists($w)]
1443                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1444                 incr lno
1445                 $w conf -state normal
1446                 $w image create $lno.0 \
1447                         -align center -padx 5 -pady 1 \
1448                         -name $icon_name \
1449                         -image [mapicon $w $new_m $path]
1450                 $w insert $lno.1 "[escape_path $path]\n"
1451                 $w conf -state disabled
1452         } elseif {$old_m ne $new_m} {
1453                 $w conf -state normal
1454                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1455                 $w conf -state disabled
1456         }
1457 }
1458
1459 proc display_file {path state} {
1460         global file_states selected_paths
1461         global ui_index ui_workdir
1462
1463         set old_m [merge_state $path $state]
1464         set s $file_states($path)
1465         set new_m [lindex $s 0]
1466         set icon_name [lindex $s 1]
1467
1468         set o [string index $old_m 0]
1469         set n [string index $new_m 0]
1470         if {$o eq {U}} {
1471                 set o _
1472         }
1473         if {$n eq {U}} {
1474                 set n _
1475         }
1476         display_file_helper     $ui_index $path $icon_name $o $n
1477
1478         if {[string index $old_m 0] eq {U}} {
1479                 set o U
1480         } else {
1481                 set o [string index $old_m 1]
1482         }
1483         if {[string index $new_m 0] eq {U}} {
1484                 set n U
1485         } else {
1486                 set n [string index $new_m 1]
1487         }
1488         display_file_helper     $ui_workdir $path $icon_name $o $n
1489
1490         if {$new_m eq {__}} {
1491                 unset file_states($path)
1492                 catch {unset selected_paths($path)}
1493         }
1494 }
1495
1496 proc display_all_files_helper {w path icon_name m} {
1497         global file_lists
1498
1499         lappend file_lists($w) $path
1500         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1501         $w image create end \
1502                 -align center -padx 5 -pady 1 \
1503                 -name $icon_name \
1504                 -image [mapicon $w $m $path]
1505         $w insert end "[escape_path $path]\n"
1506 }
1507
1508 proc display_all_files {} {
1509         global ui_index ui_workdir
1510         global file_states file_lists
1511         global last_clicked
1512
1513         $ui_index conf -state normal
1514         $ui_workdir conf -state normal
1515
1516         $ui_index delete 0.0 end
1517         $ui_workdir delete 0.0 end
1518         set last_clicked {}
1519
1520         set file_lists($ui_index) [list]
1521         set file_lists($ui_workdir) [list]
1522
1523         foreach path [lsort [array names file_states]] {
1524                 set s $file_states($path)
1525                 set m [lindex $s 0]
1526                 set icon_name [lindex $s 1]
1527
1528                 set s [string index $m 0]
1529                 if {$s ne {U} && $s ne {_}} {
1530                         display_all_files_helper $ui_index $path \
1531                                 $icon_name $s
1532                 }
1533
1534                 if {[string index $m 0] eq {U}} {
1535                         set s U
1536                 } else {
1537                         set s [string index $m 1]
1538                 }
1539                 if {$s ne {_}} {
1540                         display_all_files_helper $ui_workdir $path \
1541                                 $icon_name $s
1542                 }
1543         }
1544
1545         $ui_index conf -state disabled
1546         $ui_workdir conf -state disabled
1547 }
1548
1549 ######################################################################
1550 ##
1551 ## icons
1552
1553 set filemask {
1554 #define mask_width 14
1555 #define mask_height 15
1556 static unsigned char mask_bits[] = {
1557    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1558    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1559    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1560 }
1561
1562 image create bitmap file_plain -background white -foreground black -data {
1563 #define plain_width 14
1564 #define plain_height 15
1565 static unsigned char plain_bits[] = {
1566    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1567    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1568    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1569 } -maskdata $filemask
1570
1571 image create bitmap file_mod -background white -foreground blue -data {
1572 #define mod_width 14
1573 #define mod_height 15
1574 static unsigned char mod_bits[] = {
1575    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1576    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1577    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1578 } -maskdata $filemask
1579
1580 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1581 #define file_fulltick_width 14
1582 #define file_fulltick_height 15
1583 static unsigned char file_fulltick_bits[] = {
1584    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1585    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1586    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1587 } -maskdata $filemask
1588
1589 image create bitmap file_parttick -background white -foreground "#005050" -data {
1590 #define parttick_width 14
1591 #define parttick_height 15
1592 static unsigned char parttick_bits[] = {
1593    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1594    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1595    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1596 } -maskdata $filemask
1597
1598 image create bitmap file_question -background white -foreground black -data {
1599 #define file_question_width 14
1600 #define file_question_height 15
1601 static unsigned char file_question_bits[] = {
1602    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1603    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1604    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1605 } -maskdata $filemask
1606
1607 image create bitmap file_removed -background white -foreground red -data {
1608 #define file_removed_width 14
1609 #define file_removed_height 15
1610 static unsigned char file_removed_bits[] = {
1611    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1612    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1613    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1614 } -maskdata $filemask
1615
1616 image create bitmap file_merge -background white -foreground blue -data {
1617 #define file_merge_width 14
1618 #define file_merge_height 15
1619 static unsigned char file_merge_bits[] = {
1620    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1621    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1622    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1623 } -maskdata $filemask
1624
1625 image create bitmap file_statechange -background white -foreground green -data {
1626 #define file_merge_width 14
1627 #define file_merge_height 15
1628 static unsigned char file_statechange_bits[] = {
1629    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1630    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1631    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1632 } -maskdata $filemask
1633
1634 set ui_index .vpane.files.index.list
1635 set ui_workdir .vpane.files.workdir.list
1636
1637 set all_icons(_$ui_index)   file_plain
1638 set all_icons(A$ui_index)   file_fulltick
1639 set all_icons(M$ui_index)   file_fulltick
1640 set all_icons(D$ui_index)   file_removed
1641 set all_icons(U$ui_index)   file_merge
1642 set all_icons(T$ui_index)   file_statechange
1643
1644 set all_icons(_$ui_workdir) file_plain
1645 set all_icons(M$ui_workdir) file_mod
1646 set all_icons(D$ui_workdir) file_question
1647 set all_icons(U$ui_workdir) file_merge
1648 set all_icons(O$ui_workdir) file_plain
1649 set all_icons(T$ui_workdir) file_statechange
1650
1651 set max_status_desc 0
1652 foreach i {
1653                 {__ {mc "Unmodified"}}
1654
1655                 {_M {mc "Modified, not staged"}}
1656                 {M_ {mc "Staged for commit"}}
1657                 {MM {mc "Portions staged for commit"}}
1658                 {MD {mc "Staged for commit, missing"}}
1659
1660                 {_T {mc "File type changed, not staged"}}
1661                 {T_ {mc "File type changed, staged"}}
1662
1663                 {_O {mc "Untracked, not staged"}}
1664                 {A_ {mc "Staged for commit"}}
1665                 {AM {mc "Portions staged for commit"}}
1666                 {AD {mc "Staged for commit, missing"}}
1667
1668                 {_D {mc "Missing"}}
1669                 {D_ {mc "Staged for removal"}}
1670                 {DO {mc "Staged for removal, still present"}}
1671
1672                 {U_ {mc "Requires merge resolution"}}
1673                 {UU {mc "Requires merge resolution"}}
1674                 {UM {mc "Requires merge resolution"}}
1675                 {UD {mc "Requires merge resolution"}}
1676         } {
1677         set text [eval [lindex $i 1]]
1678         if {$max_status_desc < [string length $text]} {
1679                 set max_status_desc [string length $text]
1680         }
1681         set all_descs([lindex $i 0]) $text
1682 }
1683 unset i
1684
1685 ######################################################################
1686 ##
1687 ## util
1688
1689 proc scrollbar2many {list mode args} {
1690         foreach w $list {eval $w $mode $args}
1691 }
1692
1693 proc many2scrollbar {list mode sb top bottom} {
1694         $sb set $top $bottom
1695         foreach w $list {$w $mode moveto $top}
1696 }
1697
1698 proc incr_font_size {font {amt 1}} {
1699         set sz [font configure $font -size]
1700         incr sz $amt
1701         font configure $font -size $sz
1702         font configure ${font}bold -size $sz
1703         font configure ${font}italic -size $sz
1704 }
1705
1706 ######################################################################
1707 ##
1708 ## ui commands
1709
1710 set starting_gitk_msg [mc "Starting gitk... please wait..."]
1711
1712 proc do_gitk {revs} {
1713         # -- Always start gitk through whatever we were loaded with.  This
1714         #    lets us bypass using shell process on Windows systems.
1715         #
1716         set exe [_which gitk -script]
1717         set cmd [list [info nameofexecutable] $exe]
1718         if {$exe eq {}} {
1719                 error_popup [mc "Couldn't find gitk in PATH"]
1720         } else {
1721                 global env
1722
1723                 if {[info exists env(GIT_DIR)]} {
1724                         set old_GIT_DIR $env(GIT_DIR)
1725                 } else {
1726                         set old_GIT_DIR {}
1727                 }
1728
1729                 set pwd [pwd]
1730                 cd [file dirname [gitdir]]
1731                 set env(GIT_DIR) [file tail [gitdir]]
1732
1733                 eval exec $cmd $revs &
1734
1735                 if {$old_GIT_DIR eq {}} {
1736                         unset env(GIT_DIR)
1737                 } else {
1738                         set env(GIT_DIR) $old_GIT_DIR
1739                 }
1740                 cd $pwd
1741
1742                 ui_status $::starting_gitk_msg
1743                 after 10000 {
1744                         ui_ready $starting_gitk_msg
1745                 }
1746         }
1747 }
1748
1749 set is_quitting 0
1750
1751 proc do_quit {} {
1752         global ui_comm is_quitting repo_config commit_type
1753         global GITGUI_BCK_exists GITGUI_BCK_i
1754         global ui_comm_spell
1755
1756         if {$is_quitting} return
1757         set is_quitting 1
1758
1759         if {[winfo exists $ui_comm]} {
1760                 # -- Stash our current commit buffer.
1761                 #
1762                 set save [gitdir GITGUI_MSG]
1763                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
1764                         file rename -force [gitdir GITGUI_BCK] $save
1765                         set GITGUI_BCK_exists 0
1766                 } else {
1767                         set msg [string trim [$ui_comm get 0.0 end]]
1768                         regsub -all -line {[ \r\t]+$} $msg {} msg
1769                         if {(![string match amend* $commit_type]
1770                                 || [$ui_comm edit modified])
1771                                 && $msg ne {}} {
1772                                 catch {
1773                                         set fd [open $save w]
1774                                         puts -nonewline $fd $msg
1775                                         close $fd
1776                                 }
1777                         } else {
1778                                 catch {file delete $save}
1779                         }
1780                 }
1781
1782                 # -- Cancel our spellchecker if its running.
1783                 #
1784                 if {[info exists ui_comm_spell]} {
1785                         $ui_comm_spell stop
1786                 }
1787
1788                 # -- Remove our editor backup, its not needed.
1789                 #
1790                 after cancel $GITGUI_BCK_i
1791                 if {$GITGUI_BCK_exists} {
1792                         catch {file delete [gitdir GITGUI_BCK]}
1793                 }
1794
1795                 # -- Stash our current window geometry into this repository.
1796                 #
1797                 set cfg_geometry [list]
1798                 lappend cfg_geometry [wm geometry .]
1799                 lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
1800                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
1801                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
1802                         set rc_geometry {}
1803                 }
1804                 if {$cfg_geometry ne $rc_geometry} {
1805                         catch {git config gui.geometry $cfg_geometry}
1806                 }
1807         }
1808
1809         destroy .
1810 }
1811
1812 proc do_rescan {} {
1813         rescan ui_ready
1814 }
1815
1816 proc do_commit {} {
1817         commit_tree
1818 }
1819
1820 proc next_diff {} {
1821         global next_diff_p next_diff_w next_diff_i
1822         show_diff $next_diff_p $next_diff_w $next_diff_i
1823 }
1824
1825 proc toggle_or_diff {w x y} {
1826         global file_states file_lists current_diff_path ui_index ui_workdir
1827         global last_clicked selected_paths
1828
1829         set pos [split [$w index @$x,$y] .]
1830         set lno [lindex $pos 0]
1831         set col [lindex $pos 1]
1832         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1833         if {$path eq {}} {
1834                 set last_clicked {}
1835                 return
1836         }
1837
1838         set last_clicked [list $w $lno]
1839         array unset selected_paths
1840         $ui_index tag remove in_sel 0.0 end
1841         $ui_workdir tag remove in_sel 0.0 end
1842
1843         # Do not stage files with conflicts
1844         if {[info exists file_states($path)]} {
1845                 set state [lindex $file_states($path) 0]
1846                 if {[string index $state 0] eq {U}} {
1847                         set col 1
1848                 }
1849         }
1850
1851         if {$col == 0 && $y > 1} {
1852                 set i [expr {$lno-1}]
1853                 set ll [expr {[llength $file_lists($w)]-1}]
1854
1855                 if {$i == $ll && $i == 0} {
1856                         set after {reshow_diff;}
1857                 } else {
1858                         global next_diff_p next_diff_w next_diff_i
1859
1860                         set next_diff_w $w
1861
1862                         if {$i < $ll} {
1863                                 set i [expr {$i + 1}]
1864                                 set next_diff_i $i
1865                         } else {
1866                                 set next_diff_i $i
1867                                 set i [expr {$i - 1}]
1868                         }
1869
1870                         set next_diff_p [lindex $file_lists($w) $i]
1871
1872                         if {$next_diff_p ne {} && $current_diff_path ne {}} {
1873                                 set after {next_diff;}
1874                         } else {
1875                                 set after {}
1876                         }
1877                 }
1878
1879                 if {$w eq $ui_index} {
1880                         update_indexinfo \
1881                                 "Unstaging [short_path $path] from commit" \
1882                                 [list $path] \
1883                                 [concat $after [list ui_ready]]
1884                 } elseif {$w eq $ui_workdir} {
1885                         update_index \
1886                                 "Adding [short_path $path]" \
1887                                 [list $path] \
1888                                 [concat $after [list ui_ready]]
1889                 }
1890         } else {
1891                 show_diff $path $w $lno
1892         }
1893 }
1894
1895 proc add_one_to_selection {w x y} {
1896         global file_lists last_clicked selected_paths
1897
1898         set lno [lindex [split [$w index @$x,$y] .] 0]
1899         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1900         if {$path eq {}} {
1901                 set last_clicked {}
1902                 return
1903         }
1904
1905         if {$last_clicked ne {}
1906                 && [lindex $last_clicked 0] ne $w} {
1907                 array unset selected_paths
1908                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
1909         }
1910
1911         set last_clicked [list $w $lno]
1912         if {[catch {set in_sel $selected_paths($path)}]} {
1913                 set in_sel 0
1914         }
1915         if {$in_sel} {
1916                 unset selected_paths($path)
1917                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
1918         } else {
1919                 set selected_paths($path) 1
1920                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
1921         }
1922 }
1923
1924 proc add_range_to_selection {w x y} {
1925         global file_lists last_clicked selected_paths
1926
1927         if {[lindex $last_clicked 0] ne $w} {
1928                 toggle_or_diff $w $x $y
1929                 return
1930         }
1931
1932         set lno [lindex [split [$w index @$x,$y] .] 0]
1933         set lc [lindex $last_clicked 1]
1934         if {$lc < $lno} {
1935                 set begin $lc
1936                 set end $lno
1937         } else {
1938                 set begin $lno
1939                 set end $lc
1940         }
1941
1942         foreach path [lrange $file_lists($w) \
1943                 [expr {$begin - 1}] \
1944                 [expr {$end - 1}]] {
1945                 set selected_paths($path) 1
1946         }
1947         $w tag add in_sel $begin.0 [expr {$end + 1}].0
1948 }
1949
1950 proc show_more_context {} {
1951         global repo_config
1952         if {$repo_config(gui.diffcontext) < 99} {
1953                 incr repo_config(gui.diffcontext)
1954                 reshow_diff
1955         }
1956 }
1957
1958 proc show_less_context {} {
1959         global repo_config
1960         if {$repo_config(gui.diffcontext) > 1} {
1961                 incr repo_config(gui.diffcontext) -1
1962                 reshow_diff
1963         }
1964 }
1965
1966 ######################################################################
1967 ##
1968 ## ui construction
1969
1970 load_config 0
1971 apply_config
1972 set ui_comm {}
1973
1974 # -- Menu Bar
1975 #
1976 menu .mbar -tearoff 0
1977 .mbar add cascade -label [mc Repository] -menu .mbar.repository
1978 .mbar add cascade -label [mc Edit] -menu .mbar.edit
1979 if {[is_enabled branch]} {
1980         .mbar add cascade -label [mc Branch] -menu .mbar.branch
1981 }
1982 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
1983         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
1984 }
1985 if {[is_enabled transport]} {
1986         .mbar add cascade -label [mc Merge] -menu .mbar.merge
1987         .mbar add cascade -label [mc Remote] -menu .mbar.remote
1988 }
1989 . configure -menu .mbar
1990
1991 # -- Repository Menu
1992 #
1993 menu .mbar.repository
1994
1995 .mbar.repository add command \
1996         -label [mc "Browse Current Branch's Files"] \
1997         -command {browser::new $current_branch}
1998 set ui_browse_current [.mbar.repository index last]
1999 .mbar.repository add command \
2000         -label [mc "Browse Branch Files..."] \
2001         -command browser_open::dialog
2002 .mbar.repository add separator
2003
2004 .mbar.repository add command \
2005         -label [mc "Visualize Current Branch's History"] \
2006         -command {do_gitk $current_branch}
2007 set ui_visualize_current [.mbar.repository index last]
2008 .mbar.repository add command \
2009         -label [mc "Visualize All Branch History"] \
2010         -command {do_gitk --all}
2011 .mbar.repository add separator
2012
2013 proc current_branch_write {args} {
2014         global current_branch
2015         .mbar.repository entryconf $::ui_browse_current \
2016                 -label [mc "Browse %s's Files" $current_branch]
2017         .mbar.repository entryconf $::ui_visualize_current \
2018                 -label [mc "Visualize %s's History" $current_branch]
2019 }
2020 trace add variable current_branch write current_branch_write
2021
2022 if {[is_enabled multicommit]} {
2023         .mbar.repository add command -label [mc "Database Statistics"] \
2024                 -command do_stats
2025
2026         .mbar.repository add command -label [mc "Compress Database"] \
2027                 -command do_gc
2028
2029         .mbar.repository add command -label [mc "Verify Database"] \
2030                 -command do_fsck_objects
2031
2032         .mbar.repository add separator
2033
2034         if {[is_Cygwin]} {
2035                 .mbar.repository add command \
2036                         -label [mc "Create Desktop Icon"] \
2037                         -command do_cygwin_shortcut
2038         } elseif {[is_Windows]} {
2039                 .mbar.repository add command \
2040                         -label [mc "Create Desktop Icon"] \
2041                         -command do_windows_shortcut
2042         } elseif {[is_MacOSX]} {
2043                 .mbar.repository add command \
2044                         -label [mc "Create Desktop Icon"] \
2045                         -command do_macosx_app
2046         }
2047 }
2048
2049 if {[is_MacOSX]} {
2050         proc ::tk::mac::Quit {args} { do_quit }
2051 } else {
2052         .mbar.repository add command -label [mc Quit] \
2053                 -command do_quit \
2054                 -accelerator $M1T-Q
2055 }
2056
2057 # -- Edit Menu
2058 #
2059 menu .mbar.edit
2060 .mbar.edit add command -label [mc Undo] \
2061         -command {catch {[focus] edit undo}} \
2062         -accelerator $M1T-Z
2063 .mbar.edit add command -label [mc Redo] \
2064         -command {catch {[focus] edit redo}} \
2065         -accelerator $M1T-Y
2066 .mbar.edit add separator
2067 .mbar.edit add command -label [mc Cut] \
2068         -command {catch {tk_textCut [focus]}} \
2069         -accelerator $M1T-X
2070 .mbar.edit add command -label [mc Copy] \
2071         -command {catch {tk_textCopy [focus]}} \
2072         -accelerator $M1T-C
2073 .mbar.edit add command -label [mc Paste] \
2074         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2075         -accelerator $M1T-V
2076 .mbar.edit add command -label [mc Delete] \
2077         -command {catch {[focus] delete sel.first sel.last}} \
2078         -accelerator Del
2079 .mbar.edit add separator
2080 .mbar.edit add command -label [mc "Select All"] \
2081         -command {catch {[focus] tag add sel 0.0 end}} \
2082         -accelerator $M1T-A
2083
2084 # -- Branch Menu
2085 #
2086 if {[is_enabled branch]} {
2087         menu .mbar.branch
2088
2089         .mbar.branch add command -label [mc "Create..."] \
2090                 -command branch_create::dialog \
2091                 -accelerator $M1T-N
2092         lappend disable_on_lock [list .mbar.branch entryconf \
2093                 [.mbar.branch index last] -state]
2094
2095         .mbar.branch add command -label [mc "Checkout..."] \
2096                 -command branch_checkout::dialog \
2097                 -accelerator $M1T-O
2098         lappend disable_on_lock [list .mbar.branch entryconf \
2099                 [.mbar.branch index last] -state]
2100
2101         .mbar.branch add command -label [mc "Rename..."] \
2102                 -command branch_rename::dialog
2103         lappend disable_on_lock [list .mbar.branch entryconf \
2104                 [.mbar.branch index last] -state]
2105
2106         .mbar.branch add command -label [mc "Delete..."] \
2107                 -command branch_delete::dialog
2108         lappend disable_on_lock [list .mbar.branch entryconf \
2109                 [.mbar.branch index last] -state]
2110
2111         .mbar.branch add command -label [mc "Reset..."] \
2112                 -command merge::reset_hard
2113         lappend disable_on_lock [list .mbar.branch entryconf \
2114                 [.mbar.branch index last] -state]
2115 }
2116
2117 # -- Commit Menu
2118 #
2119 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2120         menu .mbar.commit
2121
2122         .mbar.commit add radiobutton \
2123                 -label [mc "New Commit"] \
2124                 -command do_select_commit_type \
2125                 -variable selected_commit_type \
2126                 -value new
2127         lappend disable_on_lock \
2128                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2129
2130         .mbar.commit add radiobutton \
2131                 -label [mc "Amend Last Commit"] \
2132                 -command do_select_commit_type \
2133                 -variable selected_commit_type \
2134                 -value amend
2135         lappend disable_on_lock \
2136                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2137
2138         .mbar.commit add separator
2139
2140         .mbar.commit add command -label [mc Rescan] \
2141                 -command do_rescan \
2142                 -accelerator F5
2143         lappend disable_on_lock \
2144                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2145
2146         .mbar.commit add command -label [mc "Stage To Commit"] \
2147                 -command do_add_selection \
2148                 -accelerator $M1T-T
2149         lappend disable_on_lock \
2150                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2151
2152         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2153                 -command do_add_all \
2154                 -accelerator $M1T-I
2155         lappend disable_on_lock \
2156                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2157
2158         .mbar.commit add command -label [mc "Unstage From Commit"] \
2159                 -command do_unstage_selection
2160         lappend disable_on_lock \
2161                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2162
2163         .mbar.commit add command -label [mc "Revert Changes"] \
2164                 -command do_revert_selection
2165         lappend disable_on_lock \
2166                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2167
2168         .mbar.commit add separator
2169
2170         .mbar.commit add command -label [mc "Show Less Context"] \
2171                 -command show_less_context \
2172                 -accelerator $M1T-\-
2173
2174         .mbar.commit add command -label [mc "Show More Context"] \
2175                 -command show_more_context \
2176                 -accelerator $M1T-=
2177
2178         .mbar.commit add separator
2179
2180         .mbar.commit add command -label [mc "Sign Off"] \
2181                 -command do_signoff \
2182                 -accelerator $M1T-S
2183
2184         .mbar.commit add command -label [mc Commit@@verb] \
2185                 -command do_commit \
2186                 -accelerator $M1T-Return
2187         lappend disable_on_lock \
2188                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2189 }
2190
2191 # -- Merge Menu
2192 #
2193 if {[is_enabled branch]} {
2194         menu .mbar.merge
2195         .mbar.merge add command -label [mc "Local Merge..."] \
2196                 -command merge::dialog \
2197                 -accelerator $M1T-M
2198         lappend disable_on_lock \
2199                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2200         .mbar.merge add command -label [mc "Abort Merge..."] \
2201                 -command merge::reset_hard
2202         lappend disable_on_lock \
2203                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2204 }
2205
2206 # -- Transport Menu
2207 #
2208 if {[is_enabled transport]} {
2209         menu .mbar.remote
2210
2211         .mbar.remote add command \
2212                 -label [mc "Push..."] \
2213                 -command do_push_anywhere \
2214                 -accelerator $M1T-P
2215         .mbar.remote add command \
2216                 -label [mc "Delete..."] \
2217                 -command remote_branch_delete::dialog
2218 }
2219
2220 if {[is_MacOSX]} {
2221         # -- Apple Menu (Mac OS X only)
2222         #
2223         .mbar add cascade -label Apple -menu .mbar.apple
2224         menu .mbar.apple
2225
2226         .mbar.apple add command -label [mc "About %s" [appname]] \
2227                 -command do_about
2228         .mbar.apple add separator
2229         .mbar.apple add command \
2230                 -label [mc "Preferences..."] \
2231                 -command do_options \
2232                 -accelerator $M1T-,
2233         bind . <$M1B-,> do_options
2234 } else {
2235         # -- Edit Menu
2236         #
2237         .mbar.edit add separator
2238         .mbar.edit add command -label [mc "Options..."] \
2239                 -command do_options
2240 }
2241
2242 # -- Help Menu
2243 #
2244 .mbar add cascade -label [mc Help] -menu .mbar.help
2245 menu .mbar.help
2246
2247 if {![is_MacOSX]} {
2248         .mbar.help add command -label [mc "About %s" [appname]] \
2249                 -command do_about
2250 }
2251
2252 set browser {}
2253 catch {set browser $repo_config(instaweb.browser)}
2254 set doc_path [file dirname [gitexec]]
2255 set doc_path [file join $doc_path Documentation index.html]
2256
2257 if {[is_Cygwin]} {
2258         set doc_path [exec cygpath --mixed $doc_path]
2259 }
2260
2261 if {$browser eq {}} {
2262         if {[is_MacOSX]} {
2263                 set browser open
2264         } elseif {[is_Cygwin]} {
2265                 set program_files [file dirname [exec cygpath --windir]]
2266                 set program_files [file join $program_files {Program Files}]
2267                 set firefox [file join $program_files {Mozilla Firefox} firefox.exe]
2268                 set ie [file join $program_files {Internet Explorer} IEXPLORE.EXE]
2269                 if {[file exists $firefox]} {
2270                         set browser $firefox
2271                 } elseif {[file exists $ie]} {
2272                         set browser $ie
2273                 }
2274                 unset program_files firefox ie
2275         }
2276 }
2277
2278 if {[file isfile $doc_path]} {
2279         set doc_url "file:$doc_path"
2280 } else {
2281         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2282 }
2283
2284 if {$browser ne {}} {
2285         .mbar.help add command -label [mc "Online Documentation"] \
2286                 -command [list exec $browser $doc_url &]
2287 }
2288 unset browser doc_path doc_url
2289
2290 # -- Standard bindings
2291 #
2292 wm protocol . WM_DELETE_WINDOW do_quit
2293 bind all <$M1B-Key-q> do_quit
2294 bind all <$M1B-Key-Q> do_quit
2295 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2296 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2297
2298 set subcommand_args {}
2299 proc usage {} {
2300         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2301         exit 1
2302 }
2303
2304 # -- Not a normal commit type invocation?  Do that instead!
2305 #
2306 switch -- $subcommand {
2307 browser -
2308 blame {
2309         if {$subcommand eq "blame"} {
2310                 set subcommand_args {[--line=<num>] rev? path}
2311         } else {
2312                 set subcommand_args {rev? path}
2313         }
2314         if {$argv eq {}} usage
2315         set head {}
2316         set path {}
2317         set jump_spec {}
2318         set is_path 0
2319         foreach a $argv {
2320                 if {$is_path || [file exists $_prefix$a]} {
2321                         if {$path ne {}} usage
2322                         set path $_prefix$a
2323                         break
2324                 } elseif {$a eq {--}} {
2325                         if {$path ne {}} {
2326                                 if {$head ne {}} usage
2327                                 set head $path
2328                                 set path {}
2329                         }
2330                         set is_path 1
2331                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2332                         if {$jump_spec ne {} || $head ne {}} usage
2333                         set jump_spec [list $lnum]
2334                 } elseif {$head eq {}} {
2335                         if {$head ne {}} usage
2336                         set head $a
2337                         set is_path 1
2338                 } else {
2339                         usage
2340                 }
2341         }
2342         unset is_path
2343
2344         if {$head ne {} && $path eq {}} {
2345                 set path $_prefix$head
2346                 set head {}
2347         }
2348
2349         if {$head eq {}} {
2350                 load_current_branch
2351         } else {
2352                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2353                         if {[catch {
2354                                         set head [git rev-parse --verify $head]
2355                                 } err]} {
2356                                 puts stderr $err
2357                                 exit 1
2358                         }
2359                 }
2360                 set current_branch $head
2361         }
2362
2363         switch -- $subcommand {
2364         browser {
2365                 if {$jump_spec ne {}} usage
2366                 if {$head eq {}} {
2367                         if {$path ne {} && [file isdirectory $path]} {
2368                                 set head $current_branch
2369                         } else {
2370                                 set head $path
2371                                 set path {}
2372                         }
2373                 }
2374                 browser::new $head $path
2375         }
2376         blame   {
2377                 if {$head eq {} && ![file exists $path]} {
2378                         puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2379                         exit 1
2380                 }
2381                 blame::new $head $path $jump_spec
2382         }
2383         }
2384         return
2385 }
2386 citool -
2387 gui {
2388         if {[llength $argv] != 0} {
2389                 puts -nonewline stderr "usage: $argv0"
2390                 if {$subcommand ne {gui}
2391                         && [file tail $argv0] ne "git-$subcommand"} {
2392                         puts -nonewline stderr " $subcommand"
2393                 }
2394                 puts stderr {}
2395                 exit 1
2396         }
2397         # fall through to setup UI for commits
2398 }
2399 default {
2400         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2401         exit 1
2402 }
2403 }
2404
2405 # -- Branch Control
2406 #
2407 frame .branch \
2408         -borderwidth 1 \
2409         -relief sunken
2410 label .branch.l1 \
2411         -text [mc "Current Branch:"] \
2412         -anchor w \
2413         -justify left
2414 label .branch.cb \
2415         -textvariable current_branch \
2416         -anchor w \
2417         -justify left
2418 pack .branch.l1 -side left
2419 pack .branch.cb -side left -fill x
2420 pack .branch -side top -fill x
2421
2422 # -- Main Window Layout
2423 #
2424 panedwindow .vpane -orient horizontal
2425 panedwindow .vpane.files -orient vertical
2426 .vpane add .vpane.files -sticky nsew -height 100 -width 200
2427 pack .vpane -anchor n -side top -fill both -expand 1
2428
2429 # -- Index File List
2430 #
2431 frame .vpane.files.index -height 100 -width 200
2432 label .vpane.files.index.title -text [mc "Staged Changes (Will Commit)"] \
2433         -background lightgreen -foreground black
2434 text $ui_index -background white -foreground black \
2435         -borderwidth 0 \
2436         -width 20 -height 10 \
2437         -wrap none \
2438         -cursor $cursor_ptr \
2439         -xscrollcommand {.vpane.files.index.sx set} \
2440         -yscrollcommand {.vpane.files.index.sy set} \
2441         -state disabled
2442 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2443 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2444 pack .vpane.files.index.title -side top -fill x
2445 pack .vpane.files.index.sx -side bottom -fill x
2446 pack .vpane.files.index.sy -side right -fill y
2447 pack $ui_index -side left -fill both -expand 1
2448
2449 # -- Working Directory File List
2450 #
2451 frame .vpane.files.workdir -height 100 -width 200
2452 label .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2453         -background lightsalmon -foreground black
2454 text $ui_workdir -background white -foreground black \
2455         -borderwidth 0 \
2456         -width 20 -height 10 \
2457         -wrap none \
2458         -cursor $cursor_ptr \
2459         -xscrollcommand {.vpane.files.workdir.sx set} \
2460         -yscrollcommand {.vpane.files.workdir.sy set} \
2461         -state disabled
2462 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2463 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2464 pack .vpane.files.workdir.title -side top -fill x
2465 pack .vpane.files.workdir.sx -side bottom -fill x
2466 pack .vpane.files.workdir.sy -side right -fill y
2467 pack $ui_workdir -side left -fill both -expand 1
2468
2469 .vpane.files add .vpane.files.workdir -sticky nsew
2470 .vpane.files add .vpane.files.index -sticky nsew
2471
2472 foreach i [list $ui_index $ui_workdir] {
2473         rmsel_tag $i
2474         $i tag conf in_diff -background [$i tag cget in_sel -background]
2475 }
2476 unset i
2477
2478 # -- Diff and Commit Area
2479 #
2480 frame .vpane.lower -height 300 -width 400
2481 frame .vpane.lower.commarea
2482 frame .vpane.lower.diff -relief sunken -borderwidth 1
2483 pack .vpane.lower.diff -fill both -expand 1
2484 pack .vpane.lower.commarea -side bottom -fill x
2485 .vpane add .vpane.lower -sticky nsew
2486
2487 # -- Commit Area Buttons
2488 #
2489 frame .vpane.lower.commarea.buttons
2490 label .vpane.lower.commarea.buttons.l -text {} \
2491         -anchor w \
2492         -justify left
2493 pack .vpane.lower.commarea.buttons.l -side top -fill x
2494 pack .vpane.lower.commarea.buttons -side left -fill y
2495
2496 button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
2497         -command do_rescan
2498 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
2499 lappend disable_on_lock \
2500         {.vpane.lower.commarea.buttons.rescan conf -state}
2501
2502 button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
2503         -command do_add_all
2504 pack .vpane.lower.commarea.buttons.incall -side top -fill x
2505 lappend disable_on_lock \
2506         {.vpane.lower.commarea.buttons.incall conf -state}
2507
2508 button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
2509         -command do_signoff
2510 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
2511
2512 button .vpane.lower.commarea.buttons.commit -text [mc Commit@@verb] \
2513         -command do_commit
2514 pack .vpane.lower.commarea.buttons.commit -side top -fill x
2515 lappend disable_on_lock \
2516         {.vpane.lower.commarea.buttons.commit conf -state}
2517
2518 button .vpane.lower.commarea.buttons.push -text [mc Push] \
2519         -command do_push_anywhere
2520 pack .vpane.lower.commarea.buttons.push -side top -fill x
2521
2522 # -- Commit Message Buffer
2523 #
2524 frame .vpane.lower.commarea.buffer
2525 frame .vpane.lower.commarea.buffer.header
2526 set ui_comm .vpane.lower.commarea.buffer.t
2527 set ui_coml .vpane.lower.commarea.buffer.header.l
2528 radiobutton .vpane.lower.commarea.buffer.header.new \
2529         -text [mc "New Commit"] \
2530         -command do_select_commit_type \
2531         -variable selected_commit_type \
2532         -value new
2533 lappend disable_on_lock \
2534         [list .vpane.lower.commarea.buffer.header.new conf -state]
2535 radiobutton .vpane.lower.commarea.buffer.header.amend \
2536         -text [mc "Amend Last Commit"] \
2537         -command do_select_commit_type \
2538         -variable selected_commit_type \
2539         -value amend
2540 lappend disable_on_lock \
2541         [list .vpane.lower.commarea.buffer.header.amend conf -state]
2542 label $ui_coml \
2543         -anchor w \
2544         -justify left
2545 proc trace_commit_type {varname args} {
2546         global ui_coml commit_type
2547         switch -glob -- $commit_type {
2548         initial       {set txt [mc "Initial Commit Message:"]}
2549         amend         {set txt [mc "Amended Commit Message:"]}
2550         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
2551         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
2552         merge         {set txt [mc "Merge Commit Message:"]}
2553         *             {set txt [mc "Commit Message:"]}
2554         }
2555         $ui_coml conf -text $txt
2556 }
2557 trace add variable commit_type write trace_commit_type
2558 pack $ui_coml -side left -fill x
2559 pack .vpane.lower.commarea.buffer.header.amend -side right
2560 pack .vpane.lower.commarea.buffer.header.new -side right
2561
2562 text $ui_comm -background white -foreground black \
2563         -borderwidth 1 \
2564         -undo true \
2565         -maxundo 20 \
2566         -autoseparators true \
2567         -relief sunken \
2568         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
2569         -font font_diff \
2570         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
2571 scrollbar .vpane.lower.commarea.buffer.sby \
2572         -command [list $ui_comm yview]
2573 pack .vpane.lower.commarea.buffer.header -side top -fill x
2574 pack .vpane.lower.commarea.buffer.sby -side right -fill y
2575 pack $ui_comm -side left -fill y
2576 pack .vpane.lower.commarea.buffer -side left -fill y
2577
2578 # -- Commit Message Buffer Context Menu
2579 #
2580 set ctxm .vpane.lower.commarea.buffer.ctxm
2581 menu $ctxm -tearoff 0
2582 $ctxm add command \
2583         -label [mc Cut] \
2584         -command {tk_textCut $ui_comm}
2585 $ctxm add command \
2586         -label [mc Copy] \
2587         -command {tk_textCopy $ui_comm}
2588 $ctxm add command \
2589         -label [mc Paste] \
2590         -command {tk_textPaste $ui_comm}
2591 $ctxm add command \
2592         -label [mc Delete] \
2593         -command {$ui_comm delete sel.first sel.last}
2594 $ctxm add separator
2595 $ctxm add command \
2596         -label [mc "Select All"] \
2597         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
2598 $ctxm add command \
2599         -label [mc "Copy All"] \
2600         -command {
2601                 $ui_comm tag add sel 0.0 end
2602                 tk_textCopy $ui_comm
2603                 $ui_comm tag remove sel 0.0 end
2604         }
2605 $ctxm add separator
2606 $ctxm add command \
2607         -label [mc "Sign Off"] \
2608         -command do_signoff
2609 set ui_comm_ctxm $ctxm
2610
2611 # -- Diff Header
2612 #
2613 proc trace_current_diff_path {varname args} {
2614         global current_diff_path diff_actions file_states
2615         if {$current_diff_path eq {}} {
2616                 set s {}
2617                 set f {}
2618                 set p {}
2619                 set o disabled
2620         } else {
2621                 set p $current_diff_path
2622                 set s [mapdesc [lindex $file_states($p) 0] $p]
2623                 set f [mc "File:"]
2624                 set p [escape_path $p]
2625                 set o normal
2626         }
2627
2628         .vpane.lower.diff.header.status configure -text $s
2629         .vpane.lower.diff.header.file configure -text $f
2630         .vpane.lower.diff.header.path configure -text $p
2631         foreach w $diff_actions {
2632                 uplevel #0 $w $o
2633         }
2634 }
2635 trace add variable current_diff_path write trace_current_diff_path
2636
2637 frame .vpane.lower.diff.header -background gold
2638 label .vpane.lower.diff.header.status \
2639         -background gold \
2640         -foreground black \
2641         -width $max_status_desc \
2642         -anchor w \
2643         -justify left
2644 label .vpane.lower.diff.header.file \
2645         -background gold \
2646         -foreground black \
2647         -anchor w \
2648         -justify left
2649 label .vpane.lower.diff.header.path \
2650         -background gold \
2651         -foreground black \
2652         -anchor w \
2653         -justify left
2654 pack .vpane.lower.diff.header.status -side left
2655 pack .vpane.lower.diff.header.file -side left
2656 pack .vpane.lower.diff.header.path -fill x
2657 set ctxm .vpane.lower.diff.header.ctxm
2658 menu $ctxm -tearoff 0
2659 $ctxm add command \
2660         -label [mc Copy] \
2661         -command {
2662                 clipboard clear
2663                 clipboard append \
2664                         -format STRING \
2665                         -type STRING \
2666                         -- $current_diff_path
2667         }
2668 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2669 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
2670
2671 # -- Diff Body
2672 #
2673 frame .vpane.lower.diff.body
2674 set ui_diff .vpane.lower.diff.body.t
2675 text $ui_diff -background white -foreground black \
2676         -borderwidth 0 \
2677         -width 80 -height 15 -wrap none \
2678         -font font_diff \
2679         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
2680         -yscrollcommand {.vpane.lower.diff.body.sby set} \
2681         -state disabled
2682 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
2683         -command [list $ui_diff xview]
2684 scrollbar .vpane.lower.diff.body.sby -orient vertical \
2685         -command [list $ui_diff yview]
2686 pack .vpane.lower.diff.body.sbx -side bottom -fill x
2687 pack .vpane.lower.diff.body.sby -side right -fill y
2688 pack $ui_diff -side left -fill both -expand 1
2689 pack .vpane.lower.diff.header -side top -fill x
2690 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
2691
2692 $ui_diff tag conf d_cr -elide true
2693 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
2694 $ui_diff tag conf d_+ -foreground {#00a000}
2695 $ui_diff tag conf d_- -foreground red
2696
2697 $ui_diff tag conf d_++ -foreground {#00a000}
2698 $ui_diff tag conf d_-- -foreground red
2699 $ui_diff tag conf d_+s \
2700         -foreground {#00a000} \
2701         -background {#e2effa}
2702 $ui_diff tag conf d_-s \
2703         -foreground red \
2704         -background {#e2effa}
2705 $ui_diff tag conf d_s+ \
2706         -foreground {#00a000} \
2707         -background ivory1
2708 $ui_diff tag conf d_s- \
2709         -foreground red \
2710         -background ivory1
2711
2712 $ui_diff tag conf d<<<<<<< \
2713         -foreground orange \
2714         -font font_diffbold
2715 $ui_diff tag conf d======= \
2716         -foreground orange \
2717         -font font_diffbold
2718 $ui_diff tag conf d>>>>>>> \
2719         -foreground orange \
2720         -font font_diffbold
2721
2722 $ui_diff tag raise sel
2723
2724 # -- Diff Body Context Menu
2725 #
2726
2727 proc create_common_diff_popup {ctxm} {
2728         $ctxm add command \
2729                 -label [mc "Show Less Context"] \
2730                 -command show_less_context
2731         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2732         $ctxm add command \
2733                 -label [mc "Show More Context"] \
2734                 -command show_more_context
2735         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2736         $ctxm add separator
2737         $ctxm add command \
2738                 -label [mc Refresh] \
2739                 -command reshow_diff
2740         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2741         $ctxm add command \
2742                 -label [mc Copy] \
2743                 -command {tk_textCopy $ui_diff}
2744         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2745         $ctxm add command \
2746                 -label [mc "Select All"] \
2747                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
2748         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2749         $ctxm add command \
2750                 -label [mc "Copy All"] \
2751                 -command {
2752                         $ui_diff tag add sel 0.0 end
2753                         tk_textCopy $ui_diff
2754                         $ui_diff tag remove sel 0.0 end
2755                 }
2756         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2757         $ctxm add separator
2758         $ctxm add command \
2759                 -label [mc "Decrease Font Size"] \
2760                 -command {incr_font_size font_diff -1}
2761         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2762         $ctxm add command \
2763                 -label [mc "Increase Font Size"] \
2764                 -command {incr_font_size font_diff 1}
2765         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2766         $ctxm add separator
2767         $ctxm add command -label [mc "Options..."] \
2768                 -command do_options
2769 }
2770
2771 set ctxm .vpane.lower.diff.body.ctxm
2772 menu $ctxm -tearoff 0
2773 $ctxm add command \
2774         -label [mc "Apply/Reverse Hunk"] \
2775         -command {apply_hunk $cursorX $cursorY}
2776 set ui_diff_applyhunk [$ctxm index last]
2777 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
2778 $ctxm add command \
2779         -label [mc "Apply/Reverse Line"] \
2780         -command {apply_line $cursorX $cursorY; do_rescan}
2781 set ui_diff_applyline [$ctxm index last]
2782 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
2783 $ctxm add separator
2784 create_common_diff_popup $ctxm
2785
2786 set ctxmmg .vpane.lower.diff.body.ctxmmg
2787 menu $ctxmmg -tearoff 0
2788 $ctxmmg add command \
2789         -label [mc "Run Merge Tool"] \
2790         -command {merge_resolve_tool}
2791 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2792 $ctxmmg add separator
2793 $ctxmmg add command \
2794         -label [mc "Use Remote Version"] \
2795         -command {merge_resolve_one 3}
2796 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2797 $ctxmmg add command \
2798         -label [mc "Use Local Version"] \
2799         -command {merge_resolve_one 2}
2800 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2801 $ctxmmg add command \
2802         -label [mc "Revert To Base"] \
2803         -command {merge_resolve_one 1}
2804 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2805 $ctxmmg add separator
2806 create_common_diff_popup $ctxmmg
2807
2808 proc popup_diff_menu {ctxm ctxmmg x y X Y} {
2809         global current_diff_path file_states
2810         set ::cursorX $x
2811         set ::cursorY $y
2812         if {[info exists file_states($current_diff_path)]} {
2813                 set state [lindex $file_states($current_diff_path) 0]
2814         } else {
2815                 set state {__}
2816         }
2817         if {[string index $state 0] eq {U}} {
2818                 tk_popup $ctxmmg $X $Y
2819         } else {
2820                 if {$::ui_index eq $::current_diff_side} {
2821                         set l [mc "Unstage Hunk From Commit"]
2822                         set t [mc "Unstage Line From Commit"]
2823                 } else {
2824                         set l [mc "Stage Hunk For Commit"]
2825                         set t [mc "Stage Line For Commit"]
2826                 }
2827                 if {$::is_3way_diff
2828                         || $current_diff_path eq {}
2829                         || {__} eq $state
2830                         || {_O} eq $state
2831                         || {_T} eq $state
2832                         || {T_} eq $state} {
2833                         set s disabled
2834                 } else {
2835                         set s normal
2836                 }
2837                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
2838                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
2839                 tk_popup $ctxm $X $Y
2840         }
2841 }
2842 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg %x %y %X %Y]
2843
2844 # -- Status Bar
2845 #
2846 set main_status [::status_bar::new .status]
2847 pack .status -anchor w -side bottom -fill x
2848 $main_status show [mc "Initializing..."]
2849
2850 # -- Load geometry
2851 #
2852 catch {
2853 set gm $repo_config(gui.geometry)
2854 wm geometry . [lindex $gm 0]
2855 .vpane sash place 0 \
2856         [lindex $gm 1] \
2857         [lindex [.vpane sash coord 0] 1]
2858 .vpane.files sash place 0 \
2859         [lindex [.vpane.files sash coord 0] 0] \
2860         [lindex $gm 2]
2861 unset gm
2862 }
2863
2864 # -- Key Bindings
2865 #
2866 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
2867 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
2868 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
2869 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
2870 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
2871 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
2872 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
2873 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
2874 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
2875 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
2876 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
2877 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2878 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2879 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
2880 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
2881 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
2882 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
2883 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
2884
2885 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
2886 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
2887 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
2888 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
2889 bind $ui_diff <$M1B-Key-v> {break}
2890 bind $ui_diff <$M1B-Key-V> {break}
2891 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2892 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2893 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
2894 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
2895 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
2896 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
2897 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
2898 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
2899 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
2900 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
2901 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
2902 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
2903 bind $ui_diff <Button-1>   {focus %W}
2904
2905 if {[is_enabled branch]} {
2906         bind . <$M1B-Key-n> branch_create::dialog
2907         bind . <$M1B-Key-N> branch_create::dialog
2908         bind . <$M1B-Key-o> branch_checkout::dialog
2909         bind . <$M1B-Key-O> branch_checkout::dialog
2910         bind . <$M1B-Key-m> merge::dialog
2911         bind . <$M1B-Key-M> merge::dialog
2912 }
2913 if {[is_enabled transport]} {
2914         bind . <$M1B-Key-p> do_push_anywhere
2915         bind . <$M1B-Key-P> do_push_anywhere
2916 }
2917
2918 bind .   <Key-F5>     do_rescan
2919 bind .   <$M1B-Key-r> do_rescan
2920 bind .   <$M1B-Key-R> do_rescan
2921 bind .   <$M1B-Key-s> do_signoff
2922 bind .   <$M1B-Key-S> do_signoff
2923 bind .   <$M1B-Key-t> do_add_selection
2924 bind .   <$M1B-Key-T> do_add_selection
2925 bind .   <$M1B-Key-i> do_add_all
2926 bind .   <$M1B-Key-I> do_add_all
2927 bind .   <$M1B-Key-minus> {show_less_context;break}
2928 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
2929 bind .   <$M1B-Key-equal> {show_more_context;break}
2930 bind .   <$M1B-Key-plus> {show_more_context;break}
2931 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
2932 bind .   <$M1B-Key-Return> do_commit
2933 foreach i [list $ui_index $ui_workdir] {
2934         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
2935         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
2936         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
2937 }
2938 unset i
2939
2940 set file_lists($ui_index) [list]
2941 set file_lists($ui_workdir) [list]
2942
2943 wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
2944 focus -force $ui_comm
2945
2946 # -- Warn the user about environmental problems.  Cygwin's Tcl
2947 #    does *not* pass its env array onto any processes it spawns.
2948 #    This means that git processes get none of our environment.
2949 #
2950 if {[is_Cygwin]} {
2951         set ignored_env 0
2952         set suggest_user {}
2953         set msg [mc "Possible environment issues exist.
2954
2955 The following environment variables are probably
2956 going to be ignored by any Git subprocess run
2957 by %s:
2958
2959 " [appname]]
2960         foreach name [array names env] {
2961                 switch -regexp -- $name {
2962                 {^GIT_INDEX_FILE$} -
2963                 {^GIT_OBJECT_DIRECTORY$} -
2964                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
2965                 {^GIT_DIFF_OPTS$} -
2966                 {^GIT_EXTERNAL_DIFF$} -
2967                 {^GIT_PAGER$} -
2968                 {^GIT_TRACE$} -
2969                 {^GIT_CONFIG$} -
2970                 {^GIT_CONFIG_LOCAL$} -
2971                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
2972                         append msg " - $name\n"
2973                         incr ignored_env
2974                 }
2975                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
2976                         append msg " - $name\n"
2977                         incr ignored_env
2978                         set suggest_user $name
2979                 }
2980                 }
2981         }
2982         if {$ignored_env > 0} {
2983                 append msg [mc "
2984 This is due to a known issue with the
2985 Tcl binary distributed by Cygwin."]
2986
2987                 if {$suggest_user ne {}} {
2988                         append msg [mc "
2989
2990 A good replacement for %s
2991 is placing values for the user.name and
2992 user.email settings into your personal
2993 ~/.gitconfig file.
2994 " $suggest_user]
2995                 }
2996                 warn_popup $msg
2997         }
2998         unset ignored_env msg suggest_user name
2999 }
3000
3001 # -- Only initialize complex UI if we are going to stay running.
3002 #
3003 if {[is_enabled transport]} {
3004         load_all_remotes
3005
3006         set n [.mbar.remote index end]
3007         populate_push_menu
3008         populate_fetch_menu
3009         set n [expr {[.mbar.remote index end] - $n}]
3010         if {$n > 0} {
3011                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3012                 .mbar.remote insert $n separator
3013         }
3014         unset n
3015 }
3016
3017 if {[winfo exists $ui_comm]} {
3018         set GITGUI_BCK_exists [load_message GITGUI_BCK]
3019
3020         # -- If both our backup and message files exist use the
3021         #    newer of the two files to initialize the buffer.
3022         #
3023         if {$GITGUI_BCK_exists} {
3024                 set m [gitdir GITGUI_MSG]
3025                 if {[file isfile $m]} {
3026                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3027                                 catch {file delete [gitdir GITGUI_MSG]}
3028                         } else {
3029                                 $ui_comm delete 0.0 end
3030                                 $ui_comm edit reset
3031                                 $ui_comm edit modified false
3032                                 catch {file delete [gitdir GITGUI_BCK]}
3033                                 set GITGUI_BCK_exists 0
3034                         }
3035                 }
3036                 unset m
3037         }
3038
3039         proc backup_commit_buffer {} {
3040                 global ui_comm GITGUI_BCK_exists
3041
3042                 set m [$ui_comm edit modified]
3043                 if {$m || $GITGUI_BCK_exists} {
3044                         set msg [string trim [$ui_comm get 0.0 end]]
3045                         regsub -all -line {[ \r\t]+$} $msg {} msg
3046
3047                         if {$msg eq {}} {
3048                                 if {$GITGUI_BCK_exists} {
3049                                         catch {file delete [gitdir GITGUI_BCK]}
3050                                         set GITGUI_BCK_exists 0
3051                                 }
3052                         } elseif {$m} {
3053                                 catch {
3054                                         set fd [open [gitdir GITGUI_BCK] w]
3055                                         puts -nonewline $fd $msg
3056                                         close $fd
3057                                         set GITGUI_BCK_exists 1
3058                                 }
3059                         }
3060
3061                         $ui_comm edit modified false
3062                 }
3063
3064                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3065         }
3066
3067         backup_commit_buffer
3068
3069         # -- If the user has aspell available we can drive it
3070         #    in pipe mode to spellcheck the commit message.
3071         #
3072         set spell_cmd [list |]
3073         set spell_dict [get_config gui.spellingdictionary]
3074         lappend spell_cmd aspell
3075         if {$spell_dict ne {}} {
3076                 lappend spell_cmd --master=$spell_dict
3077         }
3078         lappend spell_cmd --mode=none
3079         lappend spell_cmd --encoding=utf-8
3080         lappend spell_cmd pipe
3081         if {$spell_dict eq {none}
3082          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3083                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3084         } else {
3085                 set ui_comm_spell [spellcheck::init \
3086                         $spell_fd \
3087                         $ui_comm \
3088                         $ui_comm_ctxm \
3089                 ]
3090         }
3091         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3092 }
3093
3094 lock_index begin-read
3095 if {![winfo ismapped .]} {
3096         wm deiconify .
3097 }
3098 after 1 do_rescan
3099 if {[is_enabled multicommit]} {
3100         after 1000 hint_gc
3101 }