git-svn.perl

   1 #!/usr/bin/perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use 5.008;
   5 use warnings;
   6 use strict;
   7 use vars qw/    $AUTHOR $VERSION
   8                 $sha1 $sha1_short $_revision $_repository
   9                 $_q $_authors $_authors_prog %users/;
  10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11 $VERSION = '@@GIT_VERSION@@';
  12
  13 use Carp qw/croak/;
  14 use File::Basename qw/dirname basename/;
  15 use File::Path qw/mkpath/;
  16 use File::Spec;
  17 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  18 use Memoize;
  19
  20 use Git::SVN;
  21 use Git::SVN::Editor;
  22 use Git::SVN::Fetcher;
  23 use Git::SVN::Ra;
  24 use Git::SVN::Prompt;
  25 use Git::SVN::Log;
  26 use Git::SVN::Migration;
  27
  28 use Git::SVN::Utils qw(
  29         fatal
  30         can_compress
  31         canonicalize_path
  32         canonicalize_url
  33         join_paths
  34         add_path_to_url
  35         join_paths
  36 );
  37
  38 use Git qw(
  39         git_cmd_try
  40         command
  41         command_oneline
  42         command_noisy
  43         command_output_pipe
  44         command_close_pipe
  45         command_bidi_pipe
  46         command_close_bidi_pipe
  47 );
  48
  49 BEGIN {
  50         Memoize::memoize 'Git::config';
  51         Memoize::memoize 'Git::config_bool';
  52 }
  53
  54
  55 # From which subdir have we been invoked?
  56 my $cmd_dir_prefix = eval {
  57         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  58 } || '';
  59
  60 $Git::SVN::Ra::_log_window_size = 100;
  61
  62 if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
  63         $ENV{SVN_SSH} = $ENV{GIT_SSH};
  64 }
  65
  66 if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
  67         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  68         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  69 }
  70
  71 $Git::SVN::Log::TZ = $ENV{TZ};
  72 $ENV{TZ} = 'UTC';
  73 $| = 1; # unbuffer STDOUT
  74
  75 # All SVN commands do it.  Otherwise we may die on SIGPIPE when the remote
  76 # repository decides to close the connection which we expect to be kept alive.
  77 $SIG{PIPE} = 'IGNORE';
  78
  79 # Given a dot separated version number, "subtract" it from
  80 # the SVN::Core::VERSION; non-negaitive return means the SVN::Core
  81 # is at least at the version the caller asked for.
  82 sub compare_svn_version {
  83         my (@ours) = split(/\./, $SVN::Core::VERSION);
  84         my (@theirs) = split(/\./, $_[0]);
  85         my ($i, $diff);
  86
  87         for ($i = 0; $i < @ours && $i < @theirs; $i++) {
  88                 $diff = $ours[$i] - $theirs[$i];
  89                 return $diff if ($diff);
  90         }
  91         return 1 if ($i < @ours);
  92         return -1 if ($i < @theirs);
  93         return 0;
  94 }
  95
  96 sub _req_svn {
  97         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  98         require SVN::Ra;
  99         require SVN::Delta;
 100         if (::compare_svn_version('1.1.0') < 0) {
 101                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
 102         }
 103 }
 104
 105 $sha1 = qr/[a-f\d]{40}/;
 106 $sha1_short = qr/[a-f\d]{4,40}/;
 107 my ($_stdin, $_help, $_edit,
 108         $_message, $_file, $_branch_dest,
 109         $_template, $_shared,
 110         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
 111         $_before, $_after,
 112         $_merge, $_strategy, $_preserve_merges, $_dry_run, $_parents, $_local,
 113         $_prefix, $_no_checkout, $_url, $_verbose,
 114         $_commit_url, $_tag, $_merge_info, $_interactive, $_set_svn_props);
 115
 116 # This is a refactoring artifact so Git::SVN can get at this git-svn switch.
 117 sub opt_prefix { return $_prefix || '' }
 118
 119 $Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
 120 $_q ||= 0;
 121 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
 122                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
 123                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
 124                     'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
 125                     'include-paths=s' => \$Git::SVN::Fetcher::_include_regex,
 126                     'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
 127 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
 128                 'authors-file|A=s' => \$_authors,
 129                 'authors-prog=s' => \$_authors_prog,
 130                 'repack:i' => \$Git::SVN::_repack,
 131                 'noMetadata' => \$Git::SVN::_no_metadata,
 132                 'useSvmProps' => \$Git::SVN::_use_svm_props,
 133                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 134                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 135                 'no-checkout' => \$_no_checkout,
 136                 'quiet|q+' => \$_q,
 137                 'repack-flags|repack-args|repack-opts=s' =>
 138                    \$Git::SVN::_repack_flags,
 139                 'use-log-author' => \$Git::SVN::_use_log_author,
 140                 'add-author-from' => \$Git::SVN::_add_author_from,
 141                 'localtime' => \$Git::SVN::_localtime,
 142                 %remote_opts );
 143
 144 my ($_trunk, @_tags, @_branches, $_stdlayout);
 145 my %icv;
 146 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 147                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 148                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 149                   'stdlayout|s' => \$_stdlayout,
 150                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 151                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 152                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 153                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 154                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 155                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 156                   %remote_opts );
 157 my %cmt_opts = ( 'edit|e' => \$_edit,
 158                 'rmdir' => \$Git::SVN::Editor::_rmdir,
 159                 'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
 160                 'l=i' => \$Git::SVN::Editor::_rename_limit,
 161                 'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
 162 );
 163
 164 my %cmd = (
 165         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 166                         { 'revision|r=s' => \$_revision,
 167                           'fetch-all|all' => \$_fetch_all,
 168                           'parent|p' => \$_fetch_parent,
 169                            %fc_opts } ],
 170         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 171                         { 'revision|r=s' => \$_revision,
 172                           'preserve-empty-dirs' =>
 173                                 \$Git::SVN::Fetcher::_preserve_empty_dirs,
 174                           'placeholder-filename=s' =>
 175                                 \$Git::SVN::Fetcher::_placeholder_filename,
 176                            %fc_opts, %init_opts } ],
 177         init => [ \&cmd_init, "Initialize a repo for tracking" .
 178                           " (requires URL argument)",
 179                           \%init_opts ],
 180         'multi-init' => [ \&cmd_multi_init,
 181                           "Deprecated alias for ".
 182                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 183                           \%init_opts ],
 184         dcommit => [ \&cmd_dcommit,
 185                      'Commit several diffs to merge with upstream',
 186                         { 'merge|m|M' => \$_merge,
 187                           'strategy|s=s' => \$_strategy,
 188                           'verbose|v' => \$_verbose,
 189                           'dry-run|n' => \$_dry_run,
 190                           'fetch-all|all' => \$_fetch_all,
 191                           'commit-url=s' => \$_commit_url,
 192                           'set-svn-props=s' => \$_set_svn_props,
 193                           'revision|r=i' => \$_revision,
 194                           'no-rebase' => \$_no_rebase,
 195                           'mergeinfo=s' => \$_merge_info,
 196                           'interactive|i' => \$_interactive,
 197                         %cmt_opts, %fc_opts } ],
 198         branch => [ \&cmd_branch,
 199                     'Create a branch in the SVN repository',
 200                     { 'message|m=s' => \$_message,
 201                       'destination|d=s' => \$_branch_dest,
 202                       'dry-run|n' => \$_dry_run,
 203                       'parents' => \$_parents,
 204                       'tag|t' => \$_tag,
 205                       'username=s' => \$Git::SVN::Prompt::_username,
 206                       'commit-url=s' => \$_commit_url } ],
 207         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 208                  'Create a tag in the SVN repository',
 209                  { 'message|m=s' => \$_message,
 210                    'destination|d=s' => \$_branch_dest,
 211                    'dry-run|n' => \$_dry_run,
 212                    'parents' => \$_parents,
 213                    'username=s' => \$Git::SVN::Prompt::_username,
 214                    'commit-url=s' => \$_commit_url } ],
 215         'set-tree' => [ \&cmd_set_tree,
 216                         "Set an SVN repository to a git tree-ish",
 217                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 218         'create-ignore' => [ \&cmd_create_ignore,
 219                              'Create a .gitignore per svn:ignore',
 220                              { 'revision|r=i' => \$_revision
 221                              } ],
 222         'mkdirs' => [ \&cmd_mkdirs ,
 223                       "recreate empty directories after a checkout",
 224                       { 'revision|r=i' => \$_revision } ],
 225         'propget' => [ \&cmd_propget,
 226                        'Print the value of a property on a file or directory',
 227                        { 'revision|r=i' => \$_revision } ],
 228         'propset' => [ \&cmd_propset,
 229                        'Set the value of a property on a file or directory - will be set on commit',
 230                        {} ],
 231         'proplist' => [ \&cmd_proplist,
 232                        'List all properties of a file or directory',
 233                        { 'revision|r=i' => \$_revision } ],
 234         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 235                         { 'revision|r=i' => \$_revision
 236                         } ],
 237         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 238                         { 'revision|r=i' => \$_revision
 239                         } ],
 240         'multi-fetch' => [ \&cmd_multi_fetch,
 241                            "Deprecated alias for $0 fetch --all",
 242                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 243         'migrate' => [ sub { },
 244                        # no-op, we automatically run this anyways,
 245                        'Migrate configuration/metadata/layout from
 246                         previous versions of git-svn',
 247                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 248                          %remote_opts } ],
 249         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 250                         { 'limit=i' => \$Git::SVN::Log::limit,
 251                           'revision|r=s' => \$_revision,
 252                           'verbose|v' => \$Git::SVN::Log::verbose,
 253                           'incremental' => \$Git::SVN::Log::incremental,
 254                           'oneline' => \$Git::SVN::Log::oneline,
 255                           'show-commit' => \$Git::SVN::Log::show_commit,
 256                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 257                           'authors-file|A=s' => \$_authors,
 258                           'color' => \$Git::SVN::Log::color,
 259                           'pager=s' => \$Git::SVN::Log::pager
 260                         } ],
 261         'find-rev' => [ \&cmd_find_rev,
 262                         "Translate between SVN revision numbers and tree-ish",
 263                         { 'B|before' => \$_before,
 264                           'A|after' => \$_after } ],
 265         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 266                         { 'merge|m|M' => \$_merge,
 267                           'verbose|v' => \$_verbose,
 268                           'strategy|s=s' => \$_strategy,
 269                           'local|l' => \$_local,
 270                           'fetch-all|all' => \$_fetch_all,
 271                           'dry-run|n' => \$_dry_run,
 272                           'preserve-merges|p' => \$_preserve_merges,
 273                           %fc_opts } ],
 274         'commit-diff' => [ \&cmd_commit_diff,
 275                            'Commit a diff between two trees',
 276                         { 'message|m=s' => \$_message,
 277                           'file|F=s' => \$_file,
 278                           'revision|r=s' => \$_revision,
 279                         %cmt_opts } ],
 280         'info' => [ \&cmd_info,
 281                     "Show info about the latest SVN revision
 282                      on the current branch",
 283                     { 'url' => \$_url, } ],
 284         'blame' => [ \&Git::SVN::Log::cmd_blame,
 285                     "Show what revision and author last modified each line of a file",
 286                     { 'git-format' => \$Git::SVN::Log::_git_format } ],
 287         'reset' => [ \&cmd_reset,
 288                      "Undo fetches back to the specified SVN revision",
 289                      { 'revision|r=s' => \$_revision,
 290                        'parent|p' => \$_fetch_parent } ],
 291         'gc' => [ \&cmd_gc,
 292                   "Compress unhandled.log files in .git/svn and remove " .
 293                   "index files in .git/svn",
 294                 {} ],
 295 );
 296
 297 package FakeTerm;
 298 sub new {
 299         my ($class, $reason) = @_;
 300         return bless \$reason, shift;
 301 }
 302 sub readline {
 303         my $self = shift;
 304         die "Cannot use readline on FakeTerm: $$self";
 305 }
 306 package main;
 307
 308 my $term;
 309 sub term_init {
 310         $term = eval {
 311                 require Term::ReadLine;
 312                 $ENV{"GIT_SVN_NOTTY"}
 313                         ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
 314                         : new Term::ReadLine 'git-svn';
 315         };
 316         if ($@) {
 317                 $term = new FakeTerm "$@: going non-interactive";
 318         }
 319 }
 320
 321 my $cmd;
 322 for (my $i = 0; $i < @ARGV; $i++) {
 323         if (defined $cmd{$ARGV[$i]}) {
 324                 $cmd = $ARGV[$i];
 325                 splice @ARGV, $i, 1;
 326                 last;
 327         } elsif ($ARGV[$i] eq 'help') {
 328                 $cmd = $ARGV[$i+1];
 329                 usage(0);
 330         }
 331 };
 332
 333 # make sure we're always running at the top-level working directory
 334 if ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 335         $ENV{GIT_DIR} ||= ".git";
 336         # catch the submodule case
 337         if (-f $ENV{GIT_DIR}) {
 338                 open(my $fh, '<', $ENV{GIT_DIR}) or
 339                         die "failed to open $ENV{GIT_DIR}: $!\n";
 340                 $ENV{GIT_DIR} = $1 if <$fh> =~ /^gitdir: (.+)$/;
 341         }
 342 } elsif ($cmd) {
 343         my ($git_dir, $cdup);
 344         git_cmd_try {
 345                 $git_dir = command_oneline([qw/rev-parse --git-dir/]);
 346         } "Unable to find .git directory\n";
 347         git_cmd_try {
 348                 $cdup = command_oneline(qw/rev-parse --show-cdup/);
 349                 chomp $cdup if ($cdup);
 350                 $cdup = "." unless ($cdup && length $cdup);
 351         } "Already at toplevel, but $git_dir not found\n";
 352         $ENV{GIT_DIR} = $git_dir;
 353         chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 354         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 355 }
 356
 357 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 358
 359 read_git_config(\%opts) if $ENV{GIT_DIR};
 360 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 361         Getopt::Long::Configure('pass_through');
 362 }
 363 my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
 364                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 365                     'id|i=s' => \$Git::SVN::default_ref_id,
 366                     'svn-remote|remote|R=s' => sub {
 367                        $Git::SVN::no_reuse_existing = 1;
 368                        $Git::SVN::default_repo_id = $_[1] });
 369 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 370
 371 usage(0) if $_help;
 372 version() if $_version;
 373 usage(1) unless defined $cmd;
 374 load_authors() if $_authors;
 375 if (defined $_authors_prog) {
 376         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 377 }
 378
 379 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 380         Git::SVN::Migration::migration_check();
 381 }
 382 Git::SVN::init_vars();
 383 eval {
 384         Git::SVN::verify_remotes_sanity();
 385         $cmd{$cmd}->[0]->(@ARGV);
 386         post_fetch_checkout();
 387 };
 388 fatal $@ if $@;
 389 exit 0;
 390
 391 ####################### primary functions ######################
 392 sub usage {
 393         my $exit = shift || 0;
 394         my $fd = $exit ? \*STDERR : \*STDOUT;
 395         print $fd <<"";
 396 git-svn - bidirectional operations between a single Subversion tree and git
 397 usage: git svn <command> [options] [arguments]\n
 398
 399         print $fd "Available commands:\n" unless $cmd;
 400
 401         foreach (sort keys %cmd) {
 402                 next if $cmd && $cmd ne $_;
 403                 next if /^multi-/; # don't show deprecated commands
 404                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 405                 foreach (sort keys %{$cmd{$_}->[2]}) {
 406                         # mixed-case options are for .git/config only
 407                         next if /[A-Z]/ && /^[a-z]+$/i;
 408                         # prints out arguments as they should be passed:
 409                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 410                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 411                                                         "--$_" : "-$_" }
 412                                                 split /\|/,$_)," $x\n";
 413                 }
 414         }
 415         print $fd <<"";
 416 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 417 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 418 one git repository and want to keep them separate.  See git-svn(1) for more
 419 information.
 420
 421         exit $exit;
 422 }
 423
 424 sub version {
 425         ::_req_svn();
 426         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 427         exit 0;
 428 }
 429
 430 sub ask {
 431         my ($prompt, %arg) = @_;
 432         my $valid_re = $arg{valid_re};
 433         my $default = $arg{default};
 434         my $resp;
 435         my $i = 0;
 436         term_init() unless $term;
 437
 438         if ( !( defined($term->IN)
 439             && defined( fileno($term->IN) )
 440             && defined( $term->OUT )
 441             && defined( fileno($term->OUT) ) ) ){
 442                 return defined($default) ? $default : undef;
 443         }
 444
 445         while ($i++ < 10) {
 446                 $resp = $term->readline($prompt);
 447                 if (!defined $resp) { # EOF
 448                         print "\n";
 449                         return defined $default ? $default : undef;
 450                 }
 451                 if ($resp eq '' and defined $default) {
 452                         return $default;
 453                 }
 454                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 455                         return $resp;
 456                 }
 457         }
 458         return undef;
 459 }
 460
 461 sub do_git_init_db {
 462         unless (-d $ENV{GIT_DIR}) {
 463                 my @init_db = ('init');
 464                 push @init_db, "--template=$_template" if defined $_template;
 465                 if (defined $_shared) {
 466                         if ($_shared =~ /[a-z]/) {
 467                                 push @init_db, "--shared=$_shared";
 468                         } else {
 469                                 push @init_db, "--shared";
 470                         }
 471                 }
 472                 command_noisy(@init_db);
 473                 $_repository = Git->repository(Repository => ".git");
 474         }
 475         my $set;
 476         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 477         foreach my $i (keys %icv) {
 478                 die "'$set' and '$i' cannot both be set\n" if $set;
 479                 next unless defined $icv{$i};
 480                 command_noisy('config', "$pfx.$i", $icv{$i});
 481                 $set = $i;
 482         }
 483         my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
 484         command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
 485                 if defined $$ignore_paths_regex;
 486         my $include_paths_regex = \$Git::SVN::Fetcher::_include_regex;
 487         command_noisy('config', "$pfx.include-paths", $$include_paths_regex)
 488                 if defined $$include_paths_regex;
 489         my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
 490         command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
 491                 if defined $$ignore_refs_regex;
 492
 493         if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
 494                 my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
 495                 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
 496                 command_noisy('config', "$pfx.placeholder-filename", $$fname);
 497         }
 498 }
 499
 500 sub init_subdir {
 501         my $repo_path = shift or return;
 502         mkpath([$repo_path]) unless -d $repo_path;
 503         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 504         $ENV{GIT_DIR} = '.git';
 505         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 506 }
 507
 508 sub cmd_clone {
 509         my ($url, $path) = @_;
 510         if (!$url) {
 511                 die "SVN repository location required ",
 512                     "as a command-line argument\n";
 513         } elsif (!defined $path &&
 514             (defined $_trunk || @_branches || @_tags ||
 515              defined $_stdlayout) &&
 516             $url !~ m#^[a-z\+]+://#) {
 517                 $path = $url;
 518         }
 519         $path = basename($url) if !defined $path || !length $path;
 520         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 521         cmd_init($url, $path);
 522         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 523             if $_authors;
 524         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 525 }
 526
 527 sub cmd_init {
 528         if (defined $_stdlayout) {
 529                 $_trunk = 'trunk' if (!defined $_trunk);
 530                 @_tags = 'tags' if (! @_tags);
 531                 @_branches = 'branches' if (! @_branches);
 532         }
 533         if (defined $_trunk || @_branches || @_tags) {
 534                 return cmd_multi_init(@_);
 535         }
 536         my $url = shift or die "SVN repository location required ",
 537                                "as a command-line argument\n";
 538         $url = canonicalize_url($url);
 539         init_subdir(@_);
 540         do_git_init_db();
 541
 542         if ($Git::SVN::_minimize_url eq 'unset') {
 543                 $Git::SVN::_minimize_url = 0;
 544         }
 545
 546         Git::SVN->init($url);
 547 }
 548
 549 sub cmd_fetch {
 550         if (grep /^\d+=./, @_) {
 551                 die "'<rev>=<commit>' fetch arguments are ",
 552                     "no longer supported.\n";
 553         }
 554         my ($remote) = @_;
 555         if (@_ > 1) {
 556                 die "usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 557         }
 558         $Git::SVN::no_reuse_existing = undef;
 559         if ($_fetch_parent) {
 560                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 561                 unless ($gs) {
 562                         die "Unable to determine upstream SVN information from ",
 563                             "working tree history\n";
 564                 }
 565                 # just fetch, don't checkout.
 566                 $_no_checkout = 'true';
 567                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 568         } elsif ($_fetch_all) {
 569                 cmd_multi_fetch();
 570         } else {
 571                 $remote ||= $Git::SVN::default_repo_id;
 572                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 573         }
 574 }
 575
 576 sub cmd_set_tree {
 577         my (@commits) = @_;
 578         if ($_stdin || !@commits) {
 579                 print "Reading from stdin...\n";
 580                 @commits = ();
 581                 while (<STDIN>) {
 582                         if (/\b($sha1_short)\b/o) {
 583                                 unshift @commits, $1;
 584                         }
 585                 }
 586         }
 587         my @revs;
 588         foreach my $c (@commits) {
 589                 my @tmp = command('rev-parse',$c);
 590                 if (scalar @tmp == 1) {
 591                         push @revs, $tmp[0];
 592                 } elsif (scalar @tmp > 1) {
 593                         push @revs, reverse(command('rev-list',@tmp));
 594                 } else {
 595                         fatal "Failed to rev-parse $c";
 596                 }
 597         }
 598         my $gs = Git::SVN->new;
 599         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 600         $gs->fetch;
 601         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 602                 fatal "There are new revisions that were fetched ",
 603                       "and need to be merged (or acknowledged) ",
 604                       "before committing.\nlast rev: $r_last\n",
 605                       " current: $gs->{last_rev}";
 606         }
 607         $gs->set_tree($_) foreach @revs;
 608         print "Done committing ",scalar @revs," revisions to SVN\n";
 609         unlink $gs->{index};
 610 }
 611
 612 sub split_merge_info_range {
 613         my ($range) = @_;
 614         if ($range =~ /(\d+)-(\d+)/) {
 615                 return (int($1), int($2));
 616         } else {
 617                 return (int($range), int($range));
 618         }
 619 }
 620
 621 sub combine_ranges {
 622         my ($in) = @_;
 623
 624         my @fnums = ();
 625         my @arr = split(/,/, $in);
 626         for my $element (@arr) {
 627                 my ($start, $end) = split_merge_info_range($element);
 628                 push @fnums, $start;
 629         }
 630
 631         my @sorted = @arr [ sort {
 632                 $fnums[$a] <=> $fnums[$b]
 633         } 0..$#arr ];
 634
 635         my @return = ();
 636         my $last = -1;
 637         my $first = -1;
 638         for my $element (@sorted) {
 639                 my ($start, $end) = split_merge_info_range($element);
 640
 641                 if ($last == -1) {
 642                         $first = $start;
 643                         $last = $end;
 644                         next;
 645                 }
 646                 if ($start <= $last+1) {
 647                         if ($end > $last) {
 648                                 $last = $end;
 649                         }
 650                         next;
 651                 }
 652                 if ($first == $last) {
 653                         push @return, "$first";
 654                 } else {
 655                         push @return, "$first-$last";
 656                 }
 657                 $first = $start;
 658                 $last = $end;
 659         }
 660
 661         if ($first != -1) {
 662                 if ($first == $last) {
 663                         push @return, "$first";
 664                 } else {
 665                         push @return, "$first-$last";
 666                 }
 667         }
 668
 669         return join(',', @return);
 670 }
 671
 672 sub merge_revs_into_hash {
 673         my ($hash, $minfo) = @_;
 674         my @lines = split(' ', $minfo);
 675
 676         for my $line (@lines) {
 677                 my ($branchpath, $revs) = split(/:/, $line);
 678
 679                 if (exists($hash->{$branchpath})) {
 680                         # Merge the two revision sets
 681                         my $combined = "$hash->{$branchpath},$revs";
 682                         $hash->{$branchpath} = combine_ranges($combined);
 683                 } else {
 684                         # Just do range combining for consolidation
 685                         $hash->{$branchpath} = combine_ranges($revs);
 686                 }
 687         }
 688 }
 689
 690 sub merge_merge_info {
 691         my ($mergeinfo_one, $mergeinfo_two, $ignore_branch) = @_;
 692         my %result_hash = ();
 693
 694         merge_revs_into_hash(\%result_hash, $mergeinfo_one);
 695         merge_revs_into_hash(\%result_hash, $mergeinfo_two);
 696
 697         delete $result_hash{$ignore_branch} if $ignore_branch;
 698
 699         my $result = '';
 700         # Sort below is for consistency's sake
 701         for my $branchname (sort keys(%result_hash)) {
 702                 my $revlist = $result_hash{$branchname};
 703                 $result .= "$branchname:$revlist\n"
 704         }
 705         return $result;
 706 }
 707
 708 sub populate_merge_info {
 709         my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
 710
 711         my %parentshash;
 712         read_commit_parents(\%parentshash, $d);
 713         my @parents = @{$parentshash{$d}};
 714         if ($#parents > 0) {
 715                 # Merge commit
 716                 my $all_parents_ok = 1;
 717                 my $aggregate_mergeinfo = '';
 718                 my $rooturl = $gs->repos_root;
 719                 my ($target_branch) = $gs->full_pushurl =~ /^\Q$rooturl\E(.*)/;
 720
 721                 if (defined($rewritten_parent)) {
 722                         # Replace first parent with newly-rewritten version
 723                         shift @parents;
 724                         unshift @parents, $rewritten_parent;
 725                 }
 726
 727                 foreach my $parent (@parents) {
 728                         my ($branchurl, $svnrev, $paruuid) =
 729                                 cmt_metadata($parent);
 730
 731                         unless (defined($svnrev)) {
 732                                 # Should have been caught be preflight check
 733                                 fatal "merge commit $d has ancestor $parent, but that change "
 734                      ."does not have git-svn metadata!";
 735                         }
 736                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 737                                 fatal "commit $parent git-svn metadata changed mid-run!";
 738                         }
 739                         my $branchpath = $1;
 740
 741                         my $ra = Git::SVN::Ra->new($branchurl);
 742                         my (undef, undef, $props) =
 743                                 $ra->get_dir(canonicalize_path("."), $svnrev);
 744                         my $par_mergeinfo = $props->{'svn:mergeinfo'};
 745                         unless (defined $par_mergeinfo) {
 746                                 $par_mergeinfo = '';
 747                         }
 748                         # Merge previous mergeinfo values
 749                         $aggregate_mergeinfo =
 750                                 merge_merge_info($aggregate_mergeinfo,
 751                                                                 $par_mergeinfo,
 752                                                                 $target_branch);
 753
 754                         next if $parent eq $parents[0]; # Skip first parent
 755                         # Add new changes being placed in tree by merge
 756                         my @cmd = (qw/rev-list --reverse/,
 757                                            $parent, qw/--not/);
 758                         foreach my $par (@parents) {
 759                                 unless ($par eq $parent) {
 760                                         push @cmd, $par;
 761                                 }
 762                         }
 763                         my @revsin = ();
 764                         my ($revlist, $ctx) = command_output_pipe(@cmd);
 765                         while (<$revlist>) {
 766                                 my $irev = $_;
 767                                 chomp $irev;
 768                                 my (undef, $csvnrev, undef) =
 769                                         cmt_metadata($irev);
 770                                 unless (defined $csvnrev) {
 771                                         # A child is missing SVN annotations...
 772                                         # this might be OK, or might not be.
 773                                         warn "W:child $irev is merged into revision "
 774                                                  ."$d but does not have git-svn metadata. "
 775                                                  ."This means git-svn cannot determine the "
 776                                                  ."svn revision numbers to place into the "
 777                                                  ."svn:mergeinfo property. You must ensure "
 778                                                  ."a branch is entirely committed to "
 779                                                  ."SVN before merging it in order for "
 780                                                  ."svn:mergeinfo population to function "
 781                                                  ."properly";
 782                                 }
 783                                 push @revsin, $csvnrev;
 784                         }
 785                         command_close_pipe($revlist, $ctx);
 786
 787                         last unless $all_parents_ok;
 788
 789                         # We now have a list of all SVN revnos which are
 790                         # merged by this particular parent. Integrate them.
 791                         next if $#revsin == -1;
 792                         my $newmergeinfo = "$branchpath:" . join(',', @revsin);
 793                         $aggregate_mergeinfo =
 794                                 merge_merge_info($aggregate_mergeinfo,
 795                                                                 $newmergeinfo,
 796                                                                 $target_branch);
 797                 }
 798                 if ($all_parents_ok and $aggregate_mergeinfo) {
 799                         return $aggregate_mergeinfo;
 800                 }
 801         }
 802
 803         return undef;
 804 }
 805
 806 sub dcommit_rebase {
 807         my ($is_last, $current, $fetched_ref, $svn_error) = @_;
 808         my @diff;
 809
 810         if ($svn_error) {
 811                 print STDERR "\nERROR from SVN:\n",
 812                                 $svn_error->expanded_message, "\n";
 813         }
 814         unless ($_no_rebase) {
 815                 # we always want to rebase against the current HEAD,
 816                 # not any head that was passed to us
 817                 @diff = command('diff-tree', $current,
 818                            $fetched_ref, '--');
 819                 my @finish;
 820                 if (@diff) {
 821                         @finish = rebase_cmd();
 822                         print STDERR "W: $current and ", $fetched_ref,
 823                                      " differ, using @finish:\n",
 824                                      join("\n", @diff), "\n";
 825                 } elsif ($is_last) {
 826                         print "No changes between ", $current, " and ",
 827                               $fetched_ref,
 828                               "\nResetting to the latest ",
 829                               $fetched_ref, "\n";
 830                         @finish = qw/reset --mixed/;
 831                 }
 832                 command_noisy(@finish, $fetched_ref) if @finish;
 833         }
 834         if ($svn_error) {
 835                 die "ERROR: Not all changes have been committed into SVN"
 836                         .($_no_rebase ? ".\n" : ", however the committed\n"
 837                         ."ones (if any) seem to be successfully integrated "
 838                         ."into the working tree.\n")
 839                         ."Please see the above messages for details.\n";
 840         }
 841         return @diff;
 842 }
 843
 844 sub cmd_dcommit {
 845         my $head = shift;
 846         command_noisy(qw/update-index --refresh/);
 847         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD --/) }
 848                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 849                 . "or stash them with `git stash'.\n";
 850         $head ||= 'HEAD';
 851
 852         my $old_head;
 853         if ($head ne 'HEAD') {
 854                 $old_head = eval {
 855                         command_oneline([qw/symbolic-ref -q HEAD/])
 856                 };
 857                 if ($old_head) {
 858                         $old_head =~ s{^refs/heads/}{};
 859                 } else {
 860                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 861                 }
 862                 command(['checkout', $head], STDERR => 0);
 863         }
 864
 865         my @refs;
 866         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 867         unless ($gs) {
 868                 die "Unable to determine upstream SVN information from ",
 869                     "$head history.\nPerhaps the repository is empty.";
 870         }
 871
 872         if (defined $_commit_url) {
 873                 $url = $_commit_url;
 874         } else {
 875                 $url = eval { command_oneline('config', '--get',
 876                               "svn-remote.$gs->{repo_id}.commiturl") };
 877                 if (!$url) {
 878                         $url = $gs->full_pushurl
 879                 }
 880         }
 881
 882         my $last_rev = $_revision if defined $_revision;
 883         if ($url) {
 884                 print "Committing to $url ...\n";
 885         }
 886         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 887         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 888                 warn "Attempting to commit more than one change while ",
 889                      "--no-rebase is enabled.\n",
 890                      "If these changes depend on each other, re-running ",
 891                      "without --no-rebase may be required."
 892         }
 893
 894         if (defined $_interactive){
 895                 my $ask_default = "y";
 896                 foreach my $d (@$linear_refs){
 897                         my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
 898                         while (<$fh>){
 899                                 print $_;
 900                         }
 901                         command_close_pipe($fh, $ctx);
 902                         $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
 903                                  valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 904                                  default => $ask_default);
 905                         die "Commit this patch reply required" unless defined $_;
 906                         if (/^[nq]/i) {
 907                                 exit(0);
 908                         } elsif (/^a/i) {
 909                                 last;
 910                         }
 911                 }
 912         }
 913
 914         my $expect_url = $url;
 915
 916         my $push_merge_info = eval {
 917                 command_oneline(qw/config --get svn.pushmergeinfo/)
 918                 };
 919         if (not defined($push_merge_info)
 920                         or $push_merge_info eq "false"
 921                         or $push_merge_info eq "no"
 922                         or $push_merge_info eq "never") {
 923                 $push_merge_info = 0;
 924         }
 925
 926         unless (defined($_merge_info) || ! $push_merge_info) {
 927                 # Preflight check of changes to ensure no issues with mergeinfo
 928                 # This includes check for uncommitted-to-SVN parents
 929                 # (other than the first parent, which we will handle),
 930                 # information from different SVN repos, and paths
 931                 # which are not underneath this repository root.
 932                 my $rooturl = $gs->repos_root;
 933                 foreach my $d (@$linear_refs) {
 934                         my %parentshash;
 935                         read_commit_parents(\%parentshash, $d);
 936                         my @realparents = @{$parentshash{$d}};
 937                         if ($#realparents > 0) {
 938                                 # Merge commit
 939                                 shift @realparents; # Remove/ignore first parent
 940                                 foreach my $parent (@realparents) {
 941                                         my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
 942                                         unless (defined $paruuid) {
 943                                                 # A parent is missing SVN annotations...
 944                                                 # abort the whole operation.
 945                                                 fatal "$parent is merged into revision $d, "
 946                                                          ."but does not have git-svn metadata. "
 947                                                          ."Either dcommit the branch or use a "
 948                                                          ."local cherry-pick, FF merge, or rebase "
 949                                                          ."instead of an explicit merge commit.";
 950                                         }
 951
 952                                         unless ($paruuid eq $uuid) {
 953                                                 # Parent has SVN metadata from different repository
 954                                                 fatal "merge parent $parent for change $d has "
 955                                                          ."git-svn uuid $paruuid, while current change "
 956                                                          ."has uuid $uuid!";
 957                                         }
 958
 959                                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 960                                                 # This branch is very strange indeed.
 961                                                 fatal "merge parent $parent for $d is on branch "
 962                                                          ."$branchurl, which is not under the "
 963                                                          ."git-svn root $rooturl!";
 964                                         }
 965                                 }
 966                         }
 967                 }
 968         }
 969
 970         my $rewritten_parent;
 971         my $current_head = command_oneline(qw/rev-parse HEAD/);
 972         Git::SVN::remove_username($expect_url);
 973         if (defined($_merge_info)) {
 974                 $_merge_info =~ tr{ }{\n};
 975         }
 976         while (1) {
 977                 my $d = shift @$linear_refs or last;
 978                 unless (defined $last_rev) {
 979                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 980                         unless (defined $last_rev) {
 981                                 fatal "Unable to extract revision information ",
 982                                       "from commit $d~1";
 983                         }
 984                 }
 985                 if ($_dry_run) {
 986                         print "diff-tree $d~1 $d\n";
 987                 } else {
 988                         my $cmt_rev;
 989
 990                         unless (defined($_merge_info) || ! $push_merge_info) {
 991                                 $_merge_info = populate_merge_info($d, $gs,
 992                                                              $uuid,
 993                                                              $linear_refs,
 994                                                              $rewritten_parent);
 995                         }
 996
 997                         my %ed_opts = ( r => $last_rev,
 998                                         log => get_commit_entry($d)->{log},
 999                                         ra => Git::SVN::Ra->new($url),
1000                                         config => SVN::Core::config_get_config(
1001                                                 $Git::SVN::Ra::config_dir
1002                                         ),
1003                                         tree_a => "$d~1",
1004                                         tree_b => $d,
1005                                         editor_cb => sub {
1006                                                print "Committed r$_[0]\n";
1007                                                $cmt_rev = $_[0];
1008                                         },
1009                                         mergeinfo => $_merge_info,
1010                                         svn_path => '');
1011
1012                         my $err_handler = $SVN::Error::handler;
1013                         $SVN::Error::handler = sub {
1014                                 my $err = shift;
1015                                 dcommit_rebase(1, $current_head, $gs->refname,
1016                                         $err);
1017                         };
1018
1019                         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1020                                 print "No changes\n$d~1 == $d\n";
1021                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
1022                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
1023                                                                $parents->{$d};
1024                         }
1025                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
1026                         $SVN::Error::handler = $err_handler;
1027                         $last_rev = $cmt_rev;
1028                         next if $_no_rebase;
1029
1030                         my @diff = dcommit_rebase(@$linear_refs == 0, $d,
1031                                                 $gs->refname, undef);
1032
1033                         $rewritten_parent = command_oneline(qw/rev-parse/,
1034                                                         $gs->refname);
1035
1036                         if (@diff) {
1037                                 $current_head = command_oneline(qw/rev-parse
1038                                                                 HEAD/);
1039                                 @refs = ();
1040                                 my ($url_, $rev_, $uuid_, $gs_) =
1041                                               working_head_info('HEAD', \@refs);
1042                                 my ($linear_refs_, $parents_) =
1043                                               linearize_history($gs_, \@refs);
1044                                 if (scalar(@$linear_refs) !=
1045                                     scalar(@$linear_refs_)) {
1046                                         fatal "# of revisions changed ",
1047                                           "\nbefore:\n",
1048                                           join("\n", @$linear_refs),
1049                                           "\n\nafter:\n",
1050                                           join("\n", @$linear_refs_), "\n",
1051                                           'If you are attempting to commit ',
1052                                           "merges, try running:\n\t",
1053                                           'git rebase --interactive',
1054                                           '--preserve-merges ',
1055                                           $gs->refname,
1056                                           "\nBefore dcommitting";
1057                                 }
1058                                 if ($url_ ne $expect_url) {
1059                                         if ($url_ eq $gs->metadata_url) {
1060                                                 print
1061                                                   "Accepting rewritten URL:",
1062                                                   " $url_\n";
1063                                         } else {
1064                                                 fatal
1065                                                   "URL mismatch after rebase:",
1066                                                   " $url_ != $expect_url";
1067                                         }
1068                                 }
1069                                 if ($uuid_ ne $uuid) {
1070                                         fatal "uuid mismatch after rebase: ",
1071                                               "$uuid_ != $uuid";
1072                                 }
1073                                 # remap parents
1074                                 my (%p, @l, $i);
1075                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
1076                                         my $new = $linear_refs_->[$i] or next;
1077                                         $p{$new} =
1078                                                 $parents->{$linear_refs->[$i]};
1079                                         push @l, $new;
1080                                 }
1081                                 $parents = \%p;
1082                                 $linear_refs = \@l;
1083                                 undef $last_rev;
1084                         }
1085                 }
1086         }
1087
1088         if ($old_head) {
1089                 my $new_head = command_oneline(qw/rev-parse HEAD/);
1090                 my $new_is_symbolic = eval {
1091                         command_oneline(qw/symbolic-ref -q HEAD/);
1092                 };
1093                 if ($new_is_symbolic) {
1094                         print "dcommitted the branch ", $head, "\n";
1095                 } else {
1096                         print "dcommitted on a detached HEAD because you gave ",
1097                               "a revision argument.\n",
1098                               "The rewritten commit is: ", $new_head, "\n";
1099                 }
1100                 command(['checkout', $old_head], STDERR => 0);
1101         }
1102
1103         unlink $gs->{index};
1104 }
1105
1106 sub cmd_branch {
1107         my ($branch_name, $head) = @_;
1108
1109         unless (defined $branch_name && length $branch_name) {
1110                 die(($_tag ? "tag" : "branch") . " name required\n");
1111         }
1112         $head ||= 'HEAD';
1113
1114         my (undef, $rev, undef, $gs) = working_head_info($head);
1115         my $src = $gs->full_pushurl;
1116
1117         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1118         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1119         my $glob;
1120         if ($#{$allglobs} == 0) {
1121                 $glob = $allglobs->[0];
1122         } else {
1123                 unless(defined $_branch_dest) {
1124                         die "Multiple ",
1125                             $_tag ? "tag" : "branch",
1126                             " paths defined for Subversion repository.\n",
1127                             "You must specify where you want to create the ",
1128                             $_tag ? "tag" : "branch",
1129                             " with the --destination argument.\n";
1130                 }
1131                 foreach my $g (@{$allglobs}) {
1132                         my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1133                         if ($_branch_dest =~ /$re/) {
1134                                 $glob = $g;
1135                                 last;
1136                         }
1137                 }
1138                 unless (defined $glob) {
1139                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1140                         foreach my $g (@{$allglobs}) {
1141                                 $g->{path}->{left} =~ /$dest_re/ or next;
1142                                 if (defined $glob) {
1143                                         die "Ambiguous destination: ",
1144                                             $_branch_dest, "\nmatches both '",
1145                                             $glob->{path}->{left}, "' and '",
1146                                             $g->{path}->{left}, "'\n";
1147                                 }
1148                                 $glob = $g;
1149                         }
1150                         unless (defined $glob) {
1151                                 die "Unknown ",
1152                                     $_tag ? "tag" : "branch",
1153                                     " destination $_branch_dest\n";
1154                         }
1155                 }
1156         }
1157         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1158         my $url;
1159         if (defined $_commit_url) {
1160                 $url = $_commit_url;
1161         } else {
1162                 $url = eval { command_oneline('config', '--get',
1163                         "svn-remote.$gs->{repo_id}.commiturl") };
1164                 if (!$url) {
1165                         $url = $remote->{pushurl} || $remote->{url};
1166                 }
1167         }
1168         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1169
1170         if ($dst =~ /^https:/ && $src =~ /^http:/) {
1171                 $src=~s/^http:/https:/;
1172         }
1173
1174         ::_req_svn();
1175         require SVN::Client;
1176
1177         my $ctx = SVN::Client->new(
1178                 config => SVN::Core::config_get_config(
1179                         $Git::SVN::Ra::config_dir
1180                 ),
1181                 log_msg => sub {
1182                         ${ $_[0] } = defined $_message
1183                                 ? $_message
1184                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1185                                 . $branch_name;
1186                 },
1187         );
1188
1189         eval {
1190                 $ctx->ls($dst, 'HEAD', 0);
1191         } and die "branch ${branch_name} already exists\n";
1192
1193         if ($_parents) {
1194                 mk_parent_dirs($ctx, $dst);
1195         }
1196
1197         print "Copying ${src} at r${rev} to ${dst}...\n";
1198         $ctx->copy($src, $rev, $dst)
1199                 unless $_dry_run;
1200
1201         $gs->fetch_all;
1202 }
1203
1204 sub mk_parent_dirs {
1205         my ($ctx, $parent) = @_;
1206         $parent =~ s{/[^/]*$}{};
1207
1208         if (!eval{$ctx->ls($parent, 'HEAD', 0)}) {
1209                 mk_parent_dirs($ctx, $parent);
1210                 print "Creating parent folder ${parent} ...\n";
1211                 $ctx->mkdir($parent) unless $_dry_run;
1212         }
1213 }
1214
1215 sub cmd_find_rev {
1216         my $revision_or_hash = shift or die "SVN or git revision required ",
1217                                             "as a command-line argument\n";
1218         my $result;
1219         if ($revision_or_hash =~ /^r\d+$/) {
1220                 my $head = shift;
1221                 $head ||= 'HEAD';
1222                 my @refs;
1223                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1224                 unless ($gs) {
1225                         die "Unable to determine upstream SVN information from ",
1226                             "$head history\n";
1227                 }
1228                 my $desired_revision = substr($revision_or_hash, 1);
1229                 if ($_before) {
1230                         $result = $gs->find_rev_before($desired_revision, 1);
1231                 } elsif ($_after) {
1232                         $result = $gs->find_rev_after($desired_revision, 1);
1233                 } else {
1234                         $result = $gs->rev_map_get($desired_revision, $uuid);
1235                 }
1236         } else {
1237                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1238                 $result = $rev;
1239         }
1240         print "$result\n" if $result;
1241 }
1242
1243 sub auto_create_empty_directories {
1244         my ($gs) = @_;
1245         my $var = eval { command_oneline('config', '--get', '--bool',
1246                                          "svn-remote.$gs->{repo_id}.automkdirs") };
1247         # By default, create empty directories by consulting the unhandled log,
1248         # but allow setting it to 'false' to skip it.
1249         return !($var && $var eq 'false');
1250 }
1251
1252 sub cmd_rebase {
1253         command_noisy(qw/update-index --refresh/);
1254         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1255         unless ($gs) {
1256                 die "Unable to determine upstream SVN information from ",
1257                     "working tree history\n";
1258         }
1259         if ($_dry_run) {
1260                 print "Remote Branch: " . $gs->refname . "\n";
1261                 print "SVN URL: " . $url . "\n";
1262                 return;
1263         }
1264         if (command(qw/diff-index HEAD --/)) {
1265                 print STDERR "Cannot rebase with uncommitted changes:\n";
1266                 command_noisy('status');
1267                 exit 1;
1268         }
1269         unless ($_local) {
1270                 # rebase will checkout for us, so no need to do it explicitly
1271                 $_no_checkout = 'true';
1272                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1273         }
1274         command_noisy(rebase_cmd(), $gs->refname);
1275         if (auto_create_empty_directories($gs)) {
1276                 $gs->mkemptydirs;
1277         }
1278 }
1279
1280 sub cmd_show_ignore {
1281         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1282         $gs ||= Git::SVN->new;
1283         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1284         $gs->prop_walk($gs->path, $r, sub {
1285                 my ($gs, $path, $props) = @_;
1286                 print STDOUT "\n# $path\n";
1287                 my $s = $props->{'svn:ignore'} or return;
1288                 $s =~ s/[\r\n]+/\n/g;
1289                 $s =~ s/^\n+//;
1290                 chomp $s;
1291                 $s =~ s#^#$path#gm;
1292                 print STDOUT "$s\n";
1293         });
1294 }
1295
1296 sub cmd_show_externals {
1297         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1298         $gs ||= Git::SVN->new;
1299         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1300         $gs->prop_walk($gs->path, $r, sub {
1301                 my ($gs, $path, $props) = @_;
1302                 print STDOUT "\n# $path\n";
1303                 my $s = $props->{'svn:externals'} or return;
1304                 $s =~ s/[\r\n]+/\n/g;
1305                 chomp $s;
1306                 $s =~ s#^#$path#gm;
1307                 print STDOUT "$s\n";
1308         });
1309 }
1310
1311 sub cmd_create_ignore {
1312         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1313         $gs ||= Git::SVN->new;
1314         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1315         $gs->prop_walk($gs->path, $r, sub {
1316                 my ($gs, $path, $props) = @_;
1317                 # $path is of the form /path/to/dir/
1318                 $path = '.' . $path;
1319                 # SVN can have attributes on empty directories,
1320                 # which git won't track
1321                 mkpath([$path]) unless -d $path;
1322                 my $ignore = $path . '.gitignore';
1323                 my $s = $props->{'svn:ignore'} or return;
1324                 open(GITIGNORE, '>', $ignore)
1325                   or fatal("Failed to open `$ignore' for writing: $!");
1326                 $s =~ s/[\r\n]+/\n/g;
1327                 $s =~ s/^\n+//;
1328                 chomp $s;
1329                 # Prefix all patterns so that the ignore doesn't apply
1330                 # to sub-directories.
1331                 $s =~ s#^#/#gm;
1332                 print GITIGNORE "$s\n";
1333                 close(GITIGNORE)
1334                   or fatal("Failed to close `$ignore': $!");
1335                 command_noisy('add', '-f', $ignore);
1336         });
1337 }
1338
1339 sub cmd_mkdirs {
1340         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1341         $gs ||= Git::SVN->new;
1342         $gs->mkemptydirs($_revision);
1343 }
1344
1345 # get_svnprops(PATH)
1346 # ------------------
1347 # Helper for cmd_propget and cmd_proplist below.
1348 sub get_svnprops {
1349         my $path = shift;
1350         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1351         $gs ||= Git::SVN->new;
1352
1353         # prefix THE PATH by the sub-directory from which the user
1354         # invoked us.
1355         $path = $cmd_dir_prefix . $path;
1356         fatal("No such file or directory: $path") unless -e $path;
1357         my $is_dir = -d $path ? 1 : 0;
1358         $path = join_paths($gs->path, $path);
1359
1360         # canonicalize the path (otherwise libsvn will abort or fail to
1361         # find the file)
1362         $path = canonicalize_path($path);
1363
1364         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1365         my $props;
1366         if ($is_dir) {
1367                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1368         }
1369         else {
1370                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1371         }
1372         return $props;
1373 }
1374
1375 # cmd_propget (PROP, PATH)
1376 # ------------------------
1377 # Print the SVN property PROP for PATH.
1378 sub cmd_propget {
1379         my ($prop, $path) = @_;
1380         $path = '.' if not defined $path;
1381         usage(1) if not defined $prop;
1382         my $props = get_svnprops($path);
1383         if (not defined $props->{$prop}) {
1384                 fatal("`$path' does not have a `$prop' SVN property.");
1385         }
1386         print $props->{$prop} . "\n";
1387 }
1388
1389 # cmd_propset (PROPNAME, PROPVAL, PATH)
1390 # ------------------------
1391 # Adjust the SVN property PROPNAME to PROPVAL for PATH.
1392 sub cmd_propset {
1393         my ($propname, $propval, $path) = @_;
1394         $path = '.' if not defined $path;
1395         $path = $cmd_dir_prefix . $path;
1396         usage(1) if not defined $propname;
1397         usage(1) if not defined $propval;
1398         my $file = basename($path);
1399         my $dn = dirname($path);
1400         my $cur_props = Git::SVN::Editor::check_attr( "svn-properties", $path );
1401         my @new_props;
1402         if (!$cur_props || $cur_props eq "unset" || $cur_props eq "" || $cur_props eq "set") {
1403                 push @new_props, "$propname=$propval";
1404         } else {
1405                 # TODO: handle combining properties better
1406                 my @props = split(/;/, $cur_props);
1407                 my $replaced_prop;
1408                 foreach my $prop (@props) {
1409                         # Parse 'name=value' syntax and set the property.
1410                         if ($prop =~ /([^=]+)=(.*)/) {
1411                                 my ($n,$v) = ($1,$2);
1412                                 if ($n eq $propname) {
1413                                         $v = $propval;
1414                                         $replaced_prop = 1;
1415                                 }
1416                                 push @new_props, "$n=$v";
1417                         }
1418                 }
1419                 if (!$replaced_prop) {
1420                         push @new_props, "$propname=$propval";
1421                 }
1422         }
1423         my $attrfile = "$dn/.gitattributes";
1424         open my $attrfh, '>>', $attrfile or die "Can't open $attrfile: $!\n";
1425         # TODO: don't simply append here if $file already has svn-properties
1426         my $new_props = join(';', @new_props);
1427         print $attrfh "$file svn-properties=$new_props\n" or
1428                 die "write to $attrfile: $!\n";
1429         close $attrfh or die "close $attrfile: $!\n";
1430 }
1431
1432 # cmd_proplist (PATH)
1433 # -------------------
1434 # Print the list of SVN properties for PATH.
1435 sub cmd_proplist {
1436         my $path = shift;
1437         $path = '.' if not defined $path;
1438         my $props = get_svnprops($path);
1439         print "Properties on '$path':\n";
1440         foreach (sort keys %{$props}) {
1441                 print "  $_\n";
1442         }
1443 }
1444
1445 sub cmd_multi_init {
1446         my $url = shift;
1447         unless (defined $_trunk || @_branches || @_tags) {
1448                 usage(1);
1449         }
1450
1451         $_prefix = 'origin/' unless defined $_prefix;
1452         if (defined $url) {
1453                 $url = canonicalize_url($url);
1454                 init_subdir(@_);
1455         }
1456         do_git_init_db();
1457         if (defined $_trunk) {
1458                 $_trunk =~ s#^/+##;
1459                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1460                 # try both old-style and new-style lookups:
1461                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1462                 unless ($gs_trunk) {
1463                         my ($trunk_url, $trunk_path) =
1464                                               complete_svn_url($url, $_trunk);
1465                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1466                                                    undef, $trunk_ref);
1467                 }
1468         }
1469         return unless @_branches || @_tags;
1470         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1471         foreach my $path (@_branches) {
1472                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1473         }
1474         foreach my $path (@_tags) {
1475                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1476         }
1477 }
1478
1479 sub cmd_multi_fetch {
1480         $Git::SVN::no_reuse_existing = undef;
1481         my $remotes = Git::SVN::read_all_remotes();
1482         foreach my $repo_id (sort keys %$remotes) {
1483                 if ($remotes->{$repo_id}->{url}) {
1484                         Git::SVN::fetch_all($repo_id, $remotes);
1485                 }
1486         }
1487 }
1488
1489 # this command is special because it requires no metadata
1490 sub cmd_commit_diff {
1491         my ($ta, $tb, $url) = @_;
1492         my $usage = "usage: $0 commit-diff -r<revision> ".
1493                     "<tree-ish> <tree-ish> [<URL>]";
1494         fatal($usage) if (!defined $ta || !defined $tb);
1495         my $svn_path = '';
1496         if (!defined $url) {
1497                 my $gs = eval { Git::SVN->new };
1498                 if (!$gs) {
1499                         fatal("Needed URL or usable git-svn --id in ",
1500                               "the command-line\n", $usage);
1501                 }
1502                 $url = $gs->url;
1503                 $svn_path = $gs->path;
1504         }
1505         unless (defined $_revision) {
1506                 fatal("-r|--revision is a required argument\n", $usage);
1507         }
1508         if (defined $_message && defined $_file) {
1509                 fatal("Both --message/-m and --file/-F specified ",
1510                       "for the commit message.\n",
1511                       "I have no idea what you mean");
1512         }
1513         if (defined $_file) {
1514                 $_message = file_to_s($_file);
1515         } else {
1516                 $_message ||= get_commit_entry($tb)->{log};
1517         }
1518         my $ra ||= Git::SVN::Ra->new($url);
1519         my $r = $_revision;
1520         if ($r eq 'HEAD') {
1521                 $r = $ra->get_latest_revnum;
1522         } elsif ($r !~ /^\d+$/) {
1523                 die "revision argument: $r not understood by git-svn\n";
1524         }
1525         my %ed_opts = ( r => $r,
1526                         log => $_message,
1527                         ra => $ra,
1528                         tree_a => $ta,
1529                         tree_b => $tb,
1530                         editor_cb => sub { print "Committed r$_[0]\n" },
1531                         svn_path => $svn_path );
1532         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1533                 print "No changes\n$ta == $tb\n";
1534         }
1535 }
1536
1537 sub cmd_info {
1538         my $path_arg = defined($_[0]) ? $_[0] : '.';
1539         my $path = $path_arg;
1540         if (File::Spec->file_name_is_absolute($path)) {
1541                 $path = canonicalize_path($path);
1542
1543                 my $toplevel = eval {
1544                         my @cmd = qw/rev-parse --show-toplevel/;
1545                         command_oneline(\@cmd, STDERR => 0);
1546                 };
1547
1548                 # remove $toplevel from the absolute path:
1549                 my ($vol, $dirs, $file) = File::Spec->splitpath($path);
1550                 my (undef, $tdirs, $tfile) = File::Spec->splitpath($toplevel);
1551                 my @dirs = File::Spec->splitdir($dirs);
1552                 my @tdirs = File::Spec->splitdir($tdirs);
1553                 pop @dirs if $dirs[-1] eq '';
1554                 pop @tdirs if $tdirs[-1] eq '';
1555                 push @dirs, $file;
1556                 push @tdirs, $tfile;
1557                 while (@tdirs && @dirs && $tdirs[0] eq $dirs[0]) {
1558                         shift @dirs;
1559                         shift @tdirs;
1560                 }
1561                 $dirs = File::Spec->catdir(@dirs);
1562                 $path = File::Spec->catpath($vol, $dirs);
1563
1564                 $path = canonicalize_path($path);
1565         } else {
1566                 $path = canonicalize_path($cmd_dir_prefix . $path);
1567         }
1568         if (exists $_[1]) {
1569                 die "Too many arguments specified\n";
1570         }
1571
1572         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1573
1574         if (!$file_type && !$diff_status) {
1575                 print STDERR "svn: '$path' is not under version control\n";
1576                 exit 1;
1577         }
1578
1579         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1580         unless ($gs) {
1581                 die "Unable to determine upstream SVN information from ",
1582                     "working tree history\n";
1583         }
1584
1585         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1586         $path = "." if $path eq "";
1587
1588         my $full_url = canonicalize_url( add_path_to_url( $url, $path ) );
1589
1590         if ($_url) {
1591                 print "$full_url\n";
1592                 return;
1593         }
1594
1595         my $result = "Path: $path_arg\n";
1596         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1597         $result .= "URL: $full_url\n";
1598
1599         eval {
1600                 my $repos_root = $gs->repos_root;
1601                 Git::SVN::remove_username($repos_root);
1602                 $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n";
1603         };
1604         if ($@) {
1605                 $result .= "Repository Root: (offline)\n";
1606         }
1607         ::_req_svn();
1608         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1609                 (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1610         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1611
1612         $result .= "Node Kind: " .
1613                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1614
1615         my $schedule = $diff_status eq "A"
1616                        ? "add"
1617                        : ($diff_status eq "D" ? "delete" : "normal");
1618         $result .= "Schedule: $schedule\n";
1619
1620         if ($diff_status eq "A") {
1621                 print $result, "\n";
1622                 return;
1623         }
1624
1625         my ($lc_author, $lc_rev, $lc_date_utc);
1626         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
1627         my $log = command_output_pipe(@args);
1628         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1629         while (<$log>) {
1630                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1631                         $lc_author = $1;
1632                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1633                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1634                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1635                 }
1636         }
1637         close $log;
1638
1639         Git::SVN::Log::set_local_timezone();
1640
1641         $result .= "Last Changed Author: $lc_author\n";
1642         $result .= "Last Changed Rev: $lc_rev\n";
1643         $result .= "Last Changed Date: " .
1644                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1645
1646         if ($file_type ne "dir") {
1647                 my $text_last_updated_date =
1648                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1649                 $result .=
1650                     "Text Last Updated: " .
1651                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1652                     "\n";
1653                 my $checksum;
1654                 if ($diff_status eq "D") {
1655                         my ($fh, $ctx) =
1656                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1657                         if ($file_type eq "link") {
1658                                 my $file_name = <$fh>;
1659                                 $checksum = md5sum("link $file_name");
1660                         } else {
1661                                 $checksum = md5sum($fh);
1662                         }
1663                         command_close_pipe($fh, $ctx);
1664                 } elsif ($file_type eq "link") {
1665                         my $file_name =
1666                             command(qw(cat-file blob), "HEAD:$path");
1667                         $checksum =
1668                             md5sum("link " . $file_name);
1669                 } else {
1670                         open FILE, "<", $path or die $!;
1671                         $checksum = md5sum(\*FILE);
1672                         close FILE or die $!;
1673                 }
1674                 $result .= "Checksum: " . $checksum . "\n";
1675         }
1676
1677         print $result, "\n";
1678 }
1679
1680 sub cmd_reset {
1681         my $target = shift || $_revision or die "SVN revision required\n";
1682         $target = $1 if $target =~ /^r(\d+)$/;
1683         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1684         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1685         unless ($gs) {
1686                 die "Unable to determine upstream SVN information from ".
1687                     "history\n";
1688         }
1689         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1690         die "Cannot find SVN revision $target\n" unless defined($c);
1691         $gs->rev_map_set($r, $c, 'reset', $uuid);
1692         print "r$r = $c ($gs->{ref_id})\n";
1693 }
1694
1695 sub cmd_gc {
1696         require File::Find;
1697         if (!can_compress()) {
1698                 warn "Compress::Zlib could not be found; unhandled.log " .
1699                      "files will not be compressed.\n";
1700         }
1701         File::Find::find({ wanted => \&gc_directory, no_chdir => 1},
1702                          "$ENV{GIT_DIR}/svn");
1703 }
1704
1705 ########################### utility functions #########################
1706
1707 sub rebase_cmd {
1708         my @cmd = qw/rebase/;
1709         push @cmd, '-v' if $_verbose;
1710         push @cmd, qw/--merge/ if $_merge;
1711         push @cmd, "--strategy=$_strategy" if $_strategy;
1712         push @cmd, "--preserve-merges" if $_preserve_merges;
1713         @cmd;
1714 }
1715
1716 sub post_fetch_checkout {
1717         return if $_no_checkout;
1718         return if verify_ref('HEAD^0');
1719         my $gs = $Git::SVN::_head or return;
1720
1721         # look for "trunk" ref if it exists
1722         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1723         my $fetch = $remote->{fetch};
1724         if ($fetch) {
1725                 foreach my $p (keys %$fetch) {
1726                         basename($fetch->{$p}) eq 'trunk' or next;
1727                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1728                         last;
1729                 }
1730         }
1731
1732         command_noisy(qw(update-ref HEAD), $gs->refname);
1733         return unless verify_ref('HEAD^0');
1734
1735         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1736         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1737         return if -f $index;
1738
1739         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1740         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1741         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1742         print STDERR "Checked out HEAD:\n  ",
1743                      $gs->full_url, " r", $gs->last_rev, "\n";
1744         if (auto_create_empty_directories($gs)) {
1745                 $gs->mkemptydirs($gs->last_rev);
1746         }
1747 }
1748
1749 sub complete_svn_url {
1750         my ($url, $path) = @_;
1751
1752         if ($path =~ m#^[a-z\+]+://#i) { # path is a URL
1753                 $path = canonicalize_url($path);
1754         } else {
1755                 $path = canonicalize_path($path);
1756                 if (!defined $url || $url !~ m#^[a-z\+]+://#i) {
1757                         fatal("E: '$path' is not a complete URL ",
1758                               "and a separate URL is not specified");
1759                 }
1760                 return ($url, $path);
1761         }
1762         return ($path, '');
1763 }
1764
1765 sub complete_url_ls_init {
1766         my ($ra, $repo_path, $switch, $pfx) = @_;
1767         unless ($repo_path) {
1768                 print STDERR "W: $switch not specified\n";
1769                 return;
1770         }
1771         if ($repo_path =~ m#^[a-z\+]+://#i) {
1772                 $repo_path = canonicalize_url($repo_path);
1773                 $ra = Git::SVN::Ra->new($repo_path);
1774                 $repo_path = '';
1775         } else {
1776                 $repo_path = canonicalize_path($repo_path);
1777                 $repo_path =~ s#^/+##;
1778                 unless ($ra) {
1779                         fatal("E: '$repo_path' is not a complete URL ",
1780                               "and a separate URL is not specified");
1781                 }
1782         }
1783         my $url = $ra->url;
1784         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1785         my $k = "svn-remote.$gs->{repo_id}.url";
1786         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1787         if ($orig_url && ($orig_url ne $gs->url)) {
1788                 die "$k already set: $orig_url\n",
1789                     "wanted to set to: $gs->url\n";
1790         }
1791         command_oneline('config', $k, $gs->url) unless $orig_url;
1792
1793         my $remote_path = join_paths( $gs->path, $repo_path );
1794         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1795         $remote_path =~ s#^/##g;
1796         $remote_path .= "/*" if $remote_path !~ /\*/;
1797         my ($n) = ($switch =~ /^--(\w+)/);
1798         if (length $pfx && $pfx !~ m#/$#) {
1799                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1800         }
1801         command_noisy('config',
1802                       '--add',
1803                       "svn-remote.$gs->{repo_id}.$n",
1804                       "$remote_path:refs/remotes/$pfx*" .
1805                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1806 }
1807
1808 sub verify_ref {
1809         my ($ref) = @_;
1810         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1811                                { STDERR => 0 }); };
1812 }
1813
1814 sub get_tree_from_treeish {
1815         my ($treeish) = @_;
1816         # $treeish can be a symbolic ref, too:
1817         my $type = command_oneline(qw/cat-file -t/, $treeish);
1818         my $expected;
1819         while ($type eq 'tag') {
1820                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1821         }
1822         if ($type eq 'commit') {
1823                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1824                                                     $treeish))[0];
1825                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1826                 die "Unable to get tree from $treeish\n" unless $expected;
1827         } elsif ($type eq 'tree') {
1828                 $expected = $treeish;
1829         } else {
1830                 die "$treeish is a $type, expected tree, tag or commit\n";
1831         }
1832         return $expected;
1833 }
1834
1835 sub get_commit_entry {
1836         my ($treeish) = shift;
1837         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1838         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1839         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1840         open my $log_fh, '>', $commit_editmsg or croak $!;
1841
1842         my $type = command_oneline(qw/cat-file -t/, $treeish);
1843         if ($type eq 'commit' || $type eq 'tag') {
1844                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1845                                                          $type, $treeish);
1846                 my $in_msg = 0;
1847                 my $author;
1848                 my $saw_from = 0;
1849                 my $msgbuf = "";
1850                 while (<$msg_fh>) {
1851                         if (!$in_msg) {
1852                                 $in_msg = 1 if (/^$/);
1853                                 $author = $1 if (/^author (.*>)/);
1854                         } elsif (/^git-svn-id: /) {
1855                                 # skip this for now, we regenerate the
1856                                 # correct one on re-fetch anyways
1857                                 # TODO: set *:merge properties or like...
1858                         } else {
1859                                 if (/^From:/ || /^Signed-off-by:/) {
1860                                         $saw_from = 1;
1861                                 }
1862                                 $msgbuf .= $_;
1863                         }
1864                 }
1865                 $msgbuf =~ s/\s+$//s;
1866                 if ($Git::SVN::_add_author_from && defined($author)
1867                     && !$saw_from) {
1868                         $msgbuf .= "\n\nFrom: $author";
1869                 }
1870                 print $log_fh $msgbuf or croak $!;
1871                 command_close_pipe($msg_fh, $ctx);
1872         }
1873         close $log_fh or croak $!;
1874
1875         if ($_edit || ($type eq 'tree')) {
1876                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1877                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1878         }
1879         rename $commit_editmsg, $commit_msg or croak $!;
1880         {
1881                 require Encode;
1882                 # SVN requires messages to be UTF-8 when entering the repo
1883                 local $/;
1884                 open $log_fh, '<', $commit_msg or croak $!;
1885                 binmode $log_fh;
1886                 chomp($log_entry{log} = <$log_fh>);
1887
1888                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1889                 my $msg = $log_entry{log};
1890
1891                 eval { $msg = Encode::decode($enc, $msg, 1) };
1892                 if ($@) {
1893                         die "Could not decode as $enc:\n", $msg,
1894                             "\nPerhaps you need to set i18n.commitencoding\n";
1895                 }
1896
1897                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1898                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1899
1900                 $log_entry{log} = $msg;
1901
1902                 close $log_fh or croak $!;
1903         }
1904         unlink $commit_msg;
1905         \%log_entry;
1906 }
1907
1908 sub s_to_file {
1909         my ($str, $file, $mode) = @_;
1910         open my $fd,'>',$file or croak $!;
1911         print $fd $str,"\n" or croak $!;
1912         close $fd or croak $!;
1913         chmod ($mode &~ umask, $file) if (defined $mode);
1914 }
1915
1916 sub file_to_s {
1917         my $file = shift;
1918         open my $fd,'<',$file or croak "$!: file: $file\n";
1919         local $/;
1920         my $ret = <$fd>;
1921         close $fd or croak $!;
1922         $ret =~ s/\s*$//s;
1923         return $ret;
1924 }
1925
1926 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1927 sub load_authors {
1928         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1929         my $log = $cmd eq 'log';
1930         while (<$authors>) {
1931                 chomp;
1932                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.*)>\s*$/;
1933                 my ($user, $name, $email) = ($1, $2, $3);
1934                 if ($log) {
1935                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1936                 } else {
1937                         $users{$user} = [$name, $email];
1938                 }
1939         }
1940         close $authors or croak $!;
1941 }
1942
1943 # convert GetOpt::Long specs for use by git-config
1944 sub read_git_config {
1945         my $opts = shift;
1946         my @config_only;
1947         foreach my $o (keys %$opts) {
1948                 # if we have mixedCase and a long option-only, then
1949                 # it's a config-only variable that we don't need for
1950                 # the command-line.
1951                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1952                 my $v = $opts->{$o};
1953                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1954                 $key =~ s/-//g;
1955                 my $arg = 'git config';
1956                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1957                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1958                 if (ref $v eq 'ARRAY') {
1959                         chomp(my @tmp = `$arg --get-all svn.$key`);
1960                         @$v = @tmp if @tmp;
1961                 } else {
1962                         chomp(my $tmp = `$arg --get svn.$key`);
1963                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1964                                 $$v = $tmp;
1965                         }
1966                 }
1967         }
1968         delete @$opts{@config_only} if @config_only;
1969 }
1970
1971 sub extract_metadata {
1972         my $id = shift or return (undef, undef, undef);
1973         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1974                                                         \s([a-f\d\-]+)$/ix);
1975         if (!defined $rev || !$uuid || !$url) {
1976                 # some of the original repositories I made had
1977                 # identifiers like this:
1978                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1979         }
1980         return ($url, $rev, $uuid);
1981 }
1982
1983 sub cmt_metadata {
1984         return extract_metadata((grep(/^git-svn-id: /,
1985                 command(qw/cat-file commit/, shift)))[-1]);
1986 }
1987
1988 sub cmt_sha2rev_batch {
1989         my %s2r;
1990         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1991         my $list = shift;
1992
1993         foreach my $sha (@{$list}) {
1994                 my $first = 1;
1995                 my $size = 0;
1996                 print $out $sha, "\n";
1997
1998                 while (my $line = <$in>) {
1999                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
2000                                 last;
2001                         } elsif ($first &&
2002                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
2003                                 $first = 0;
2004                                 $size = $1;
2005                                 next;
2006                         } elsif ($line =~ /^(git-svn-id: )/) {
2007                                 my (undef, $rev, undef) =
2008                                                       extract_metadata($line);
2009                                 $s2r{$sha} = $rev;
2010                         }
2011
2012                         $size -= length($line);
2013                         last if ($size == 0);
2014                 }
2015         }
2016
2017         command_close_bidi_pipe($pid, $in, $out, $ctx);
2018
2019         return \%s2r;
2020 }
2021
2022 sub working_head_info {
2023         my ($head, $refs) = @_;
2024         my @args = qw/rev-list --first-parent --pretty=medium/;
2025         my ($fh, $ctx) = command_output_pipe(@args, $head, "--");
2026         my $hash;
2027         my %max;
2028         while (<$fh>) {
2029                 if ( m{^commit ($::sha1)$} ) {
2030                         unshift @$refs, $hash if $hash and $refs;
2031                         $hash = $1;
2032                         next;
2033                 }
2034                 next unless s{^\s*(git-svn-id:)}{$1};
2035                 my ($url, $rev, $uuid) = extract_metadata($_);
2036                 if (defined $url && defined $rev) {
2037                         next if $max{$url} and $max{$url} < $rev;
2038                         if (my $gs = Git::SVN->find_by_url($url)) {
2039                                 my $c = $gs->rev_map_get($rev, $uuid);
2040                                 if ($c && $c eq $hash) {
2041                                         close $fh; # break the pipe
2042                                         return ($url, $rev, $uuid, $gs);
2043                                 } else {
2044                                         $max{$url} ||= $gs->rev_map_max;
2045                                 }
2046                         }
2047                 }
2048         }
2049         command_close_pipe($fh, $ctx);
2050         (undef, undef, undef, undef);
2051 }
2052
2053 sub read_commit_parents {
2054         my ($parents, $c) = @_;
2055         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
2056         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
2057         @{$parents->{$c}} = split(/ /, $p);
2058 }
2059
2060 sub linearize_history {
2061         my ($gs, $refs) = @_;
2062         my %parents;
2063         foreach my $c (@$refs) {
2064                 read_commit_parents(\%parents, $c);
2065         }
2066
2067         my @linear_refs;
2068         my %skip = ();
2069         my $last_svn_commit = $gs->last_commit;
2070         foreach my $c (reverse @$refs) {
2071                 next if $c eq $last_svn_commit;
2072                 last if $skip{$c};
2073
2074                 unshift @linear_refs, $c;
2075                 $skip{$c} = 1;
2076
2077                 # we only want the first parent to diff against for linear
2078                 # history, we save the rest to inject when we finalize the
2079                 # svn commit
2080                 my $fp_a = verify_ref("$c~1");
2081                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
2082                 if (!$fp_a || !$fp_b) {
2083                         die "Commit $c\n",
2084                             "has no parent commit, and therefore ",
2085                             "nothing to diff against.\n",
2086                             "You should be working from a repository ",
2087                             "originally created by git-svn\n";
2088                 }
2089                 if ($fp_a ne $fp_b) {
2090                         die "$c~1 = $fp_a, however parsing commit $c ",
2091                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
2092                 }
2093
2094                 foreach my $p (@{$parents{$c}}) {
2095                         $skip{$p} = 1;
2096                 }
2097         }
2098         (\@linear_refs, \%parents);
2099 }
2100
2101 sub find_file_type_and_diff_status {
2102         my ($path) = @_;
2103         return ('dir', '') if $path eq '';
2104
2105         my $diff_output =
2106             command_oneline(qw(diff --cached --name-status --), $path) || "";
2107         my $diff_status = (split(' ', $diff_output))[0] || "";
2108
2109         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
2110
2111         return (undef, undef) if !$diff_status && !$ls_tree;
2112
2113         if ($diff_status eq "A") {
2114                 return ("link", $diff_status) if -l $path;
2115                 return ("dir", $diff_status) if -d $path;
2116                 return ("file", $diff_status);
2117         }
2118
2119         my $mode = (split(' ', $ls_tree))[0] || "";
2120
2121         return ("link", $diff_status) if $mode eq "120000";
2122         return ("dir", $diff_status) if $mode eq "040000";
2123         return ("file", $diff_status);
2124 }
2125
2126 sub md5sum {
2127         my $arg = shift;
2128         my $ref = ref $arg;
2129         require Digest::MD5;
2130         my $md5 = Digest::MD5->new();
2131         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
2132                 $md5->addfile($arg) or croak $!;
2133         } elsif ($ref eq 'SCALAR') {
2134                 $md5->add($$arg) or croak $!;
2135         } elsif (!$ref) {
2136                 $md5->add($arg) or croak $!;
2137         } else {
2138                 fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
2139         }
2140         return $md5->hexdigest();
2141 }
2142
2143 sub gc_directory {
2144         if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
2145                 my $out_filename = $_ . ".gz";
2146                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2147                 binmode $in_fh;
2148                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2149                                 die "Unable to open $out_filename: $!\n";
2150
2151                 my $res;
2152                 while ($res = sysread($in_fh, my $str, 1024)) {
2153                         $gz->gzwrite($str) or
2154                                 die "Unable to write: ".$gz->gzerror()."!\n";
2155                 }
2156                 no warnings 'once'; # $File::Find::name would warn
2157                 unlink $_ or die "unlink $File::Find::name: $!\n";
2158         } elsif (-f $_ && basename($_) eq "index") {
2159                 unlink $_ or die "unlink $_: $!\n";
2160         }
2161 }
2162
2163 __END__
2164
2165 Data structures:
2166
2167
2168 $remotes = { # returned by read_all_remotes()
2169         'svn' => {
2170                 # svn-remote.svn.url=https://svn.musicpd.org
2171                 url => 'https://svn.musicpd.org',
2172                 # svn-remote.svn.fetch=mpd/trunk:trunk
2173                 fetch => {
2174                         'mpd/trunk' => 'trunk',
2175                 },
2176                 # svn-remote.svn.tags=mpd/tags/*:tags/*
2177                 tags => {
2178                         path => {
2179                                 left => 'mpd/tags',
2180                                 right => '',
2181                                 regex => qr!mpd/tags/([^/]+)$!,
2182                                 glob => 'tags/*',
2183                         },
2184                         ref => {
2185                                 left => 'tags',
2186                                 right => '',
2187                                 regex => qr!tags/([^/]+)$!,
2188                                 glob => 'tags/*',
2189                         },
2190                 }
2191         }
2192 };
2193
2194 $log_entry hashref as returned by libsvn_log_entry()
2195 {
2196         log => 'whitespace-formatted log entry
2197 ',                                              # trailing newline is preserved
2198         revision => '8',                        # integer
2199         date => '2004-02-24T17:01:44.108345Z',  # commit date
2200         author => 'committer name'
2201 };
2202
2203
2204 # this is generated by generate_diff();
2205 @mods = array of diff-index line hashes, each element represents one line
2206         of diff-index output
2207
2208 diff-index line ($m hash)
2209 {
2210         mode_a => first column of diff-index output, no leading ':',
2211         mode_b => second column of diff-index output,
2212         sha1_b => sha1sum of the final blob,
2213         chg => change type [MCRADT],
2214         file_a => original file name of a file (iff chg is 'C' or 'R')
2215         file_b => new/current file name of a file (any chg)
2216 }
2217 ;
2218
2219 # retval of read_url_paths{,_all}();
2220 $l_map = {
2221         # repository root url
2222         'https://svn.musicpd.org' => {
2223                 # repository path               # GIT_SVN_ID
2224                 'mpd/trunk'             =>      'trunk',
2225                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2226         },
2227 }
2228
2229 Notes:
2230         I don't trust the each() function on unless I created %hash myself
2231         because the internal iterator may not have started at base.