contrib/buildsystems/CMakeLists.txt

   1 #
   2 #       Copyright (c) 2020 Sibi Siddharthan
   3 #
   4
   5 #[[
   6
   7 Instructions how to use this in Visual Studio:
   8
   9 Open the worktree as a folder. Visual Studio 2019 and later will detect
  10 the CMake configuration automatically and set everything up for you,
  11 ready to build. You can then run the tests in `t/` via a regular Git Bash.
  12
  13 Note: Visual Studio also has the option of opening `CMakeLists.txt`
  14 directly; Using this option, Visual Studio will not find the source code,
  15 though, therefore the `File>Open>Folder...` option is preferred.
  16
  17 Instructions to run CMake manually:
  18
  19     mkdir -p contrib/buildsystems/out
  20     cd contrib/buildsystems/out
  21     cmake ../ -DCMAKE_BUILD_TYPE=Release
  22
  23 This will build the git binaries in contrib/buildsystems/out
  24 directory (our top-level .gitignore file knows to ignore contents of
  25 this directory).
  26
  27 Possible build configurations(-DCMAKE_BUILD_TYPE) with corresponding
  28 compiler flags
  29 Debug : -g
  30 Release: -O3
  31 RelWithDebInfo : -O2 -g
  32 MinSizeRel : -Os
  33 empty(default) :
  34
  35 NOTE: -DCMAKE_BUILD_TYPE is optional. For multi-config generators like Visual Studio
  36 this option is ignored
  37
  38 This process generates a Makefile(Linux/*BSD/MacOS) , Visual Studio solution(Windows) by default.
  39 Run `make` to build Git on Linux/*BSD/MacOS.
  40 Open git.sln on Windows and build Git.
  41
  42 NOTE: By default CMake uses Makefile as the build tool on Linux and Visual Studio in Windows,
  43 to use another tool say `ninja` add this to the command line when configuring.
  44 `-G Ninja`
  45
  46 NOTE: By default CMake will install vcpkg locally to your source tree on configuration,
  47 to avoid this, add `-DNO_VCPKG=TRUE` to the command line when configuring.
  48
  49 ]]
  50 cmake_minimum_required(VERSION 3.14)
  51
  52 #set the source directory to root of git
  53 set(CMAKE_SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR}/../..)
  54
  55 option(USE_VCPKG "Whether or not to use vcpkg for obtaining dependencies.  Only applicable to Windows platforms" ON)
  56 if(NOT WIN32)
  57         set(USE_VCPKG OFF CACHE BOOL "" FORCE)
  58 endif()
  59
  60 if(NOT DEFINED CMAKE_EXPORT_COMPILE_COMMANDS)
  61         set(CMAKE_EXPORT_COMPILE_COMMANDS TRUE)
  62 endif()
  63
  64 if(USE_VCPKG)
  65         set(VCPKG_DIR "${CMAKE_SOURCE_DIR}/compat/vcbuild/vcpkg")
  66         if(NOT EXISTS ${VCPKG_DIR})
  67                 message("Initializing vcpkg and building the Git's dependencies (this will take a while...)")
  68                 execute_process(COMMAND ${CMAKE_SOURCE_DIR}/compat/vcbuild/vcpkg_install.bat)
  69         endif()
  70         list(APPEND CMAKE_PREFIX_PATH "${VCPKG_DIR}/installed/x64-windows")
  71
  72         # In the vcpkg edition, we need this to be able to link to libcurl
  73         set(CURL_NO_CURL_CMAKE ON)
  74
  75         # Copy the necessary vcpkg DLLs (like iconv) to the install dir
  76         set(X_VCPKG_APPLOCAL_DEPS_INSTALL ON)
  77         set(CMAKE_TOOLCHAIN_FILE ${VCPKG_DIR}/scripts/buildsystems/vcpkg.cmake CACHE STRING "Vcpkg toolchain file")
  78 endif()
  79
  80 find_program(SH_EXE sh PATHS "C:/Program Files/Git/bin" "$ENV{LOCALAPPDATA}/Programs/Git/bin")
  81 if(NOT SH_EXE)
  82         message(FATAL_ERROR "sh: shell interpreter was not found in your path, please install one."
  83                         "On Windows, you can get it as part of 'Git for Windows' install at https://gitforwindows.org/")
  84 endif()
  85
  86 #Create GIT-VERSION-FILE using GIT-VERSION-GEN
  87 if(NOT EXISTS ${CMAKE_SOURCE_DIR}/GIT-VERSION-FILE)
  88         message("Generating GIT-VERSION-FILE")
  89         execute_process(COMMAND ${SH_EXE} ${CMAKE_SOURCE_DIR}/GIT-VERSION-GEN
  90                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
  91 endif()
  92
  93 #Parse GIT-VERSION-FILE to get the version
  94 file(STRINGS ${CMAKE_SOURCE_DIR}/GIT-VERSION-FILE git_version REGEX "GIT_VERSION = (.*)")
  95 string(REPLACE "GIT_VERSION = " "" git_version ${git_version})
  96 string(FIND ${git_version} "GIT" location)
  97 if(location EQUAL -1)
  98         string(REGEX MATCH "[0-9]*\\.[0-9]*\\.[0-9]*" git_version ${git_version})
  99 else()
 100         string(REGEX MATCH "[0-9]*\\.[0-9]*" git_version ${git_version})
 101         string(APPEND git_version ".0") #for building from a snapshot
 102 endif()
 103
 104 project(git
 105         VERSION ${git_version}
 106         LANGUAGES C)
 107
 108
 109 #TODO gitk git-gui gitweb
 110 #TODO Enable NLS on windows natively
 111
 112 #macros for parsing the Makefile for sources and scripts
 113 macro(parse_makefile_for_sources list_var regex)
 114         file(STRINGS ${CMAKE_SOURCE_DIR}/Makefile ${list_var} REGEX "^${regex} \\+=(.*)")
 115         string(REPLACE "${regex} +=" "" ${list_var} ${${list_var}})
 116         string(REPLACE "$(COMPAT_OBJS)" "" ${list_var} ${${list_var}}) #remove "$(COMPAT_OBJS)" This is only for libgit.
 117         string(STRIP ${${list_var}} ${list_var}) #remove trailing/leading whitespaces
 118         string(REPLACE ".o" ".c;" ${list_var} ${${list_var}}) #change .o to .c, ; is for converting the string into a list
 119         list(TRANSFORM ${list_var} STRIP) #remove trailing/leading whitespaces for each element in list
 120         list(REMOVE_ITEM ${list_var} "") #remove empty list elements
 121 endmacro()
 122
 123 macro(parse_makefile_for_scripts list_var regex lang)
 124         file(STRINGS ${CMAKE_SOURCE_DIR}/Makefile ${list_var} REGEX "^${regex} \\+=(.*)")
 125         string(REPLACE "${regex} +=" "" ${list_var} ${${list_var}})
 126         string(STRIP ${${list_var}} ${list_var}) #remove trailing/leading whitespaces
 127         string(REPLACE " " ";" ${list_var} ${${list_var}}) #convert string to a list
 128         if(NOT ${lang}) #exclude for SCRIPT_LIB
 129                 list(TRANSFORM ${list_var} REPLACE "${lang}" "") #do the replacement
 130         endif()
 131 endmacro()
 132
 133 macro(parse_makefile_for_executables list_var regex)
 134         file(STRINGS ${CMAKE_SOURCE_DIR}/Makefile ${list_var} REGEX "^${regex} \\+= git-(.*)")
 135         string(REPLACE "${regex} +=" "" ${list_var} ${${list_var}})
 136         string(STRIP ${${list_var}} ${list_var}) #remove trailing/leading whitespaces
 137         string(REPLACE "git-" "" ${list_var} ${${list_var}}) #strip `git-` prefix
 138         string(REPLACE "\$X" ";" ${list_var} ${${list_var}}) #strip $X, ; is for converting the string into a list
 139         list(TRANSFORM ${list_var} STRIP) #remove trailing/leading whitespaces for each element in list
 140         list(REMOVE_ITEM ${list_var} "") #remove empty list elements
 141 endmacro()
 142
 143 include(CheckTypeSize)
 144 include(CheckCSourceRuns)
 145 include(CheckCSourceCompiles)
 146 include(CheckIncludeFile)
 147 include(CheckFunctionExists)
 148 include(CheckSymbolExists)
 149 include(CheckStructHasMember)
 150 include(CTest)
 151
 152 find_package(ZLIB REQUIRED)
 153 find_package(CURL)
 154 find_package(EXPAT)
 155 find_package(Iconv)
 156
 157 #Don't use libintl on Windows Visual Studio and Clang builds
 158 if(NOT (WIN32 AND (CMAKE_C_COMPILER_ID STREQUAL "MSVC" OR CMAKE_C_COMPILER_ID STREQUAL "Clang")))
 159         find_package(Intl)
 160 endif()
 161
 162 find_package(PkgConfig)
 163 if(PkgConfig_FOUND)
 164         pkg_check_modules(PCRE2 libpcre2-8)
 165         if(PCRE2_FOUND)
 166                 add_compile_definitions(USE_LIBPCRE2)
 167         endif()
 168 endif()
 169
 170 if(NOT Intl_FOUND)
 171         add_compile_definitions(NO_GETTEXT)
 172         if(NOT Iconv_FOUND)
 173                 add_compile_definitions(NO_ICONV)
 174         endif()
 175 endif()
 176
 177 include_directories(SYSTEM ${ZLIB_INCLUDE_DIRS})
 178 if(CURL_FOUND)
 179         include_directories(SYSTEM ${CURL_INCLUDE_DIRS})
 180 endif()
 181 if(EXPAT_FOUND)
 182         include_directories(SYSTEM ${EXPAT_INCLUDE_DIRS})
 183 endif()
 184 if(Iconv_FOUND)
 185         include_directories(SYSTEM ${Iconv_INCLUDE_DIRS})
 186 endif()
 187 if(Intl_FOUND)
 188         include_directories(SYSTEM ${Intl_INCLUDE_DIRS})
 189 endif()
 190 if(PCRE2_FOUND)
 191         include_directories(SYSTEM ${PCRE2_INCLUDE_DIRS})
 192 endif()
 193
 194
 195 if(WIN32 AND NOT MSVC)#not required for visual studio builds
 196         find_program(WINDRES_EXE windres)
 197         if(NOT WINDRES_EXE)
 198                 message(FATAL_ERROR "Install windres on Windows for resource files")
 199         endif()
 200 endif()
 201
 202 if(NO_GETTEXT)
 203         message(STATUS "msgfmt not used under NO_GETTEXT")
 204 else()
 205         find_program(MSGFMT_EXE msgfmt)
 206         if(NOT MSGFMT_EXE)
 207                 if(USE_VCPKG)
 208                         set(MSGFMT_EXE ${CMAKE_SOURCE_DIR}/compat/vcbuild/vcpkg/downloads/tools/msys2/msys64/usr/bin/msgfmt.exe)
 209                 endif()
 210                 if(NOT EXISTS ${MSGFMT_EXE})
 211                         message(WARNING "Text Translations won't be built")
 212                         unset(MSGFMT_EXE)
 213                 endif()
 214         endif()
 215 endif()
 216
 217 #Force all visual studio outputs to CMAKE_BINARY_DIR
 218 if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
 219         set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG ${CMAKE_BINARY_DIR})
 220         set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE ${CMAKE_BINARY_DIR})
 221         add_compile_options(/MP /std:c11)
 222 endif()
 223
 224 #default behaviour
 225 include_directories(${CMAKE_SOURCE_DIR})
 226 add_compile_definitions(GIT_HOST_CPU="${CMAKE_SYSTEM_PROCESSOR}")
 227 add_compile_definitions(SHA256_BLK INTERNAL_QSORT RUNTIME_PREFIX)
 228 add_compile_definitions(NO_OPENSSL SHA1_DC SHA1DC_NO_STANDARD_INCLUDES
 229                         SHA1DC_INIT_SAFE_HASH_DEFAULT=0
 230                         SHA1DC_CUSTOM_INCLUDE_SHA1_C="cache.h"
 231                         SHA1DC_CUSTOM_INCLUDE_UBC_CHECK_C="git-compat-util.h" )
 232 list(APPEND compat_SOURCES sha1dc_git.c sha1dc/sha1.c sha1dc/ubc_check.c block-sha1/sha1.c sha256/block/sha256.c compat/qsort_s.c)
 233
 234
 235 add_compile_definitions(PAGER_ENV="LESS=FRX LV=-c"
 236                         GIT_EXEC_PATH="libexec/git-core"
 237                         GIT_LOCALE_PATH="share/locale"
 238                         GIT_MAN_PATH="share/man"
 239                         GIT_INFO_PATH="share/info"
 240                         GIT_HTML_PATH="share/doc/git-doc"
 241                         DEFAULT_HELP_FORMAT="html"
 242                         DEFAULT_GIT_TEMPLATE_DIR="share/git-core/templates"
 243                         GIT_VERSION="${PROJECT_VERSION}.GIT"
 244                         GIT_USER_AGENT="git/${PROJECT_VERSION}.GIT"
 245                         BINDIR="bin"
 246                         GIT_BUILT_FROM_COMMIT="")
 247
 248 if(WIN32)
 249         set(FALLBACK_RUNTIME_PREFIX /mingw64)
 250         # Move system config into top-level /etc/
 251         add_compile_definitions(FALLBACK_RUNTIME_PREFIX="${FALLBACK_RUNTIME_PREFIX}"
 252                 ETC_GITATTRIBUTES="../etc/gitattributes"
 253                 ETC_GITCONFIG="../etc/gitconfig")
 254 else()
 255         set(FALLBACK_RUNTIME_PREFIX /home/$ENV{USER})
 256         add_compile_definitions(FALLBACK_RUNTIME_PREFIX="${FALLBACK_RUNTIME_PREFIX}"
 257                 ETC_GITATTRIBUTES="etc/gitattributes"
 258                 ETC_GITCONFIG="etc/gitconfig")
 259 endif()
 260
 261
 262 #Platform Specific
 263 if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
 264         if(CMAKE_C_COMPILER_ID STREQUAL "MSVC" OR CMAKE_C_COMPILER_ID STREQUAL "Clang")
 265                 include_directories(${CMAKE_SOURCE_DIR}/compat/vcbuild/include)
 266                 add_compile_definitions(_CRT_SECURE_NO_WARNINGS _CRT_NONSTDC_NO_DEPRECATE)
 267         endif()
 268         include_directories(${CMAKE_SOURCE_DIR}/compat/win32)
 269         add_compile_definitions(HAVE_ALLOCA_H NO_POSIX_GOODIES NATIVE_CRLF NO_UNIX_SOCKETS WIN32
 270                                 _CONSOLE DETECT_MSYS_TTY STRIP_EXTENSION=".exe"  NO_SYMLINK_HEAD UNRELIABLE_FSTAT
 271                                 NOGDI OBJECT_CREATION_MODE=1 __USE_MINGW_ANSI_STDIO=0
 272                                 USE_NED_ALLOCATOR OVERRIDE_STRDUP MMAP_PREVENTS_DELETE USE_WIN32_MMAP
 273                                 HAVE_WPGMPTR ENSURE_MSYSTEM_IS_SET HAVE_RTLGENRANDOM)
 274         list(APPEND compat_SOURCES
 275                 compat/mingw.c
 276                 compat/winansi.c
 277                 compat/win32/flush.c
 278                 compat/win32/path-utils.c
 279                 compat/win32/pthread.c
 280                 compat/win32mmap.c
 281                 compat/win32/syslog.c
 282                 compat/win32/trace2_win32_process_info.c
 283                 compat/win32/dirent.c
 284                 compat/nedmalloc/nedmalloc.c
 285                 compat/strdup.c)
 286         set(NO_UNIX_SOCKETS 1)
 287
 288 elseif(CMAKE_SYSTEM_NAME STREQUAL "Linux")
 289         add_compile_definitions(PROCFS_EXECUTABLE_PATH="/proc/self/exe" HAVE_DEV_TTY )
 290         list(APPEND compat_SOURCES unix-socket.c unix-stream-server.c compat/linux/procinfo.c)
 291 endif()
 292
 293 if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
 294         list(APPEND compat_SOURCES compat/simple-ipc/ipc-shared.c compat/simple-ipc/ipc-win32.c)
 295         add_compile_definitions(SUPPORTS_SIMPLE_IPC)
 296         set(SUPPORTS_SIMPLE_IPC 1)
 297 else()
 298         # Simple IPC requires both Unix sockets and pthreads on Unix-based systems.
 299         if(NOT NO_UNIX_SOCKETS AND NOT NO_PTHREADS)
 300                 list(APPEND compat_SOURCES compat/simple-ipc/ipc-shared.c compat/simple-ipc/ipc-unix-socket.c)
 301                 add_compile_definitions(SUPPORTS_SIMPLE_IPC)
 302                 set(SUPPORTS_SIMPLE_IPC 1)
 303         endif()
 304 endif()
 305
 306 if(SUPPORTS_SIMPLE_IPC)
 307         if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
 308                 add_compile_definitions(HAVE_FSMONITOR_DAEMON_BACKEND)
 309                 list(APPEND compat_SOURCES compat/fsmonitor/fsm-listen-win32.c)
 310                 list(APPEND compat_SOURCES compat/fsmonitor/fsm-health-win32.c)
 311
 312                 add_compile_definitions(HAVE_FSMONITOR_OS_SETTINGS)
 313                 list(APPEND compat_SOURCES compat/fsmonitor/fsm-settings-win32.c)
 314         elseif(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 315                 add_compile_definitions(HAVE_FSMONITOR_DAEMON_BACKEND)
 316                 list(APPEND compat_SOURCES compat/fsmonitor/fsm-listen-darwin.c)
 317                 list(APPEND compat_SOURCES compat/fsmonitor/fsm-health-darwin.c)
 318
 319                 add_compile_definitions(HAVE_FSMONITOR_OS_SETTINGS)
 320                 list(APPEND compat_SOURCES compat/fsmonitor/fsm-settings-darwin.c)
 321         endif()
 322 endif()
 323
 324 set(EXE_EXTENSION ${CMAKE_EXECUTABLE_SUFFIX})
 325
 326 #header checks
 327 check_include_file(libgen.h HAVE_LIBGEN_H)
 328 if(NOT HAVE_LIBGEN_H)
 329         add_compile_definitions(NO_LIBGEN_H)
 330         list(APPEND compat_SOURCES compat/basename.c)
 331 endif()
 332
 333 check_include_file(sys/sysinfo.h HAVE_SYSINFO)
 334 if(HAVE_SYSINFO)
 335         add_compile_definitions(HAVE_SYSINFO)
 336 endif()
 337
 338 check_c_source_compiles("
 339 #include <alloca.h>
 340
 341 int main(void)
 342 {
 343         char *p = (char *) alloca(2 * sizeof(int));
 344
 345         if (p)
 346                 return 0;
 347         return 0;
 348 }"
 349 HAVE_ALLOCA_H)
 350 if(HAVE_ALLOCA_H)
 351         add_compile_definitions(HAVE_ALLOCA_H)
 352 endif()
 353
 354 check_include_file(strings.h HAVE_STRINGS_H)
 355 if(HAVE_STRINGS_H)
 356         add_compile_definitions(HAVE_STRINGS_H)
 357 endif()
 358
 359 check_include_file(sys/select.h HAVE_SYS_SELECT_H)
 360 if(NOT HAVE_SYS_SELECT_H)
 361         add_compile_definitions(NO_SYS_SELECT_H)
 362 endif()
 363
 364 check_include_file(sys/poll.h HAVE_SYS_POLL_H)
 365 if(NOT HAVE_SYS_POLL_H)
 366         add_compile_definitions(NO_SYS_POLL_H)
 367 endif()
 368
 369 check_include_file(poll.h HAVE_POLL_H)
 370 if(NOT HAVE_POLL_H)
 371         add_compile_definitions(NO_POLL_H)
 372 endif()
 373
 374 check_include_file(inttypes.h HAVE_INTTYPES_H)
 375 if(NOT HAVE_INTTYPES_H)
 376         add_compile_definitions(NO_INTTYPES_H)
 377 endif()
 378
 379 check_include_file(paths.h HAVE_PATHS_H)
 380 if(HAVE_PATHS_H)
 381         add_compile_definitions(HAVE_PATHS_H)
 382 endif()
 383
 384 #function checks
 385 set(function_checks
 386         strcasestr memmem strlcpy strtoimax strtoumax strtoull
 387         setenv mkdtemp poll pread memmem)
 388
 389 #unsetenv,hstrerror are incompatible with windows build
 390 if(NOT WIN32)
 391         list(APPEND function_checks unsetenv hstrerror)
 392 endif()
 393
 394 foreach(f ${function_checks})
 395         string(TOUPPER ${f} uf)
 396         check_function_exists(${f} HAVE_${uf})
 397         if(NOT HAVE_${uf})
 398                 add_compile_definitions(NO_${uf})
 399         endif()
 400 endforeach()
 401
 402 if(NOT HAVE_POLL_H OR NOT HAVE_SYS_POLL_H OR NOT HAVE_POLL)
 403         include_directories(${CMAKE_SOURCE_DIR}/compat/poll)
 404         add_compile_definitions(NO_POLL)
 405         list(APPEND compat_SOURCES compat/poll/poll.c)
 406 endif()
 407
 408 if(NOT HAVE_STRCASESTR)
 409         list(APPEND compat_SOURCES compat/strcasestr.c)
 410 endif()
 411
 412 if(NOT HAVE_STRLCPY)
 413         list(APPEND compat_SOURCES compat/strlcpy.c)
 414 endif()
 415
 416 if(NOT HAVE_STRTOUMAX)
 417         list(APPEND compat_SOURCES compat/strtoumax.c compat/strtoimax.c)
 418 endif()
 419
 420 if(NOT HAVE_SETENV)
 421         list(APPEND compat_SOURCES compat/setenv.c)
 422 endif()
 423
 424 if(NOT HAVE_MKDTEMP)
 425         list(APPEND compat_SOURCES compat/mkdtemp.c)
 426 endif()
 427
 428 if(NOT HAVE_PREAD)
 429         list(APPEND compat_SOURCES compat/pread.c)
 430 endif()
 431
 432 if(NOT HAVE_MEMMEM)
 433         list(APPEND compat_SOURCES compat/memmem.c)
 434 endif()
 435
 436 if(NOT WIN32)
 437         if(NOT HAVE_UNSETENV)
 438                 list(APPEND compat_SOURCES compat/unsetenv.c)
 439         endif()
 440
 441         if(NOT HAVE_HSTRERROR)
 442                 list(APPEND compat_SOURCES compat/hstrerror.c)
 443         endif()
 444 endif()
 445
 446 check_function_exists(getdelim HAVE_GETDELIM)
 447 if(HAVE_GETDELIM)
 448         add_compile_definitions(HAVE_GETDELIM)
 449 endif()
 450
 451 check_function_exists(clock_gettime HAVE_CLOCK_GETTIME)
 452 check_symbol_exists(CLOCK_MONOTONIC "time.h" HAVE_CLOCK_MONOTONIC)
 453 if(HAVE_CLOCK_GETTIME)
 454         add_compile_definitions(HAVE_CLOCK_GETTIME)
 455 endif()
 456 if(HAVE_CLOCK_MONOTONIC)
 457         add_compile_definitions(HAVE_CLOCK_MONOTONIC)
 458 endif()
 459
 460 #check for st_blocks in struct stat
 461 check_struct_has_member("struct stat" st_blocks "sys/stat.h" STRUCT_STAT_HAS_ST_BLOCKS)
 462 if(NOT STRUCT_STAT_HAS_ST_BLOCKS)
 463         add_compile_definitions(NO_ST_BLOCKS_IN_STRUCT_STAT)
 464 endif()
 465
 466 #compile checks
 467 check_c_source_runs("
 468 #include<stdio.h>
 469 #include<stdarg.h>
 470 #include<string.h>
 471 #include<stdlib.h>
 472
 473 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 474 {
 475         int ret;
 476         va_list ap;
 477
 478         va_start(ap, format);
 479         ret = vsnprintf(str, maxsize, format, ap);
 480         va_end(ap);
 481         return ret;
 482 }
 483
 484 int main(void)
 485 {
 486         char buf[6];
 487
 488         if (test_vsnprintf(buf, 3, \"%s\", \"12345\") != 5
 489                 || strcmp(buf, \"12\"))
 490                         return 1;
 491         if (snprintf(buf, 3, \"%s\", \"12345\") != 5
 492                 || strcmp(buf, \"12\"))
 493                         return 1;
 494         return 0;
 495 }"
 496 SNPRINTF_OK)
 497 if(NOT SNPRINTF_OK)
 498         add_compile_definitions(SNPRINTF_RETURNS_BOGUS)
 499         list(APPEND compat_SOURCES compat/snprintf.c)
 500 endif()
 501
 502 check_c_source_runs("
 503 #include<stdio.h>
 504
 505 int main(void)
 506 {
 507         FILE *f = fopen(\".\", \"r\");
 508
 509         return f != NULL;
 510 }"
 511 FREAD_READS_DIRECTORIES_NO)
 512 if(NOT FREAD_READS_DIRECTORIES_NO)
 513         add_compile_definitions(FREAD_READS_DIRECTORIES)
 514         list(APPEND compat_SOURCES compat/fopen.c)
 515 endif()
 516
 517 check_c_source_compiles("
 518 #include <regex.h>
 519 #ifndef REG_STARTEND
 520 #error oops we dont have it
 521 #endif
 522
 523 int main(void)
 524 {
 525         return 0;
 526 }"
 527 HAVE_REGEX)
 528 if(NOT HAVE_REGEX)
 529         include_directories(${CMAKE_SOURCE_DIR}/compat/regex)
 530         list(APPEND compat_SOURCES compat/regex/regex.c )
 531         add_compile_definitions(NO_REGEX NO_MBSUPPORT GAWK)
 532 endif()
 533
 534
 535 check_c_source_compiles("
 536 #include <stddef.h>
 537 #include <sys/types.h>
 538 #include <sys/sysctl.h>
 539
 540 int main(void)
 541 {
 542         int val, mib[2];
 543         size_t len;
 544
 545         mib[0] = CTL_HW;
 546         mib[1] = 1;
 547         len = sizeof(val);
 548         return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0;
 549 }"
 550 HAVE_BSD_SYSCTL)
 551 if(HAVE_BSD_SYSCTL)
 552         add_compile_definitions(HAVE_BSD_SYSCTL)
 553 endif()
 554
 555 set(CMAKE_REQUIRED_LIBRARIES ${Iconv_LIBRARIES})
 556 set(CMAKE_REQUIRED_INCLUDES ${Iconv_INCLUDE_DIRS})
 557
 558 check_c_source_compiles("
 559 #include <iconv.h>
 560
 561 extern size_t iconv(iconv_t cd,
 562                 char **inbuf, size_t *inbytesleft,
 563                 char **outbuf, size_t *outbytesleft);
 564
 565 int main(void)
 566 {
 567         return 0;
 568 }"
 569 HAVE_NEW_ICONV)
 570 if(HAVE_NEW_ICONV)
 571         set(HAVE_OLD_ICONV 0)
 572 else()
 573         set(HAVE_OLD_ICONV 1)
 574 endif()
 575
 576 check_c_source_runs("
 577 #include <iconv.h>
 578 #if ${HAVE_OLD_ICONV}
 579 typedef const char *iconv_ibp;
 580 #else
 581 typedef char *iconv_ibp;
 582 #endif
 583
 584 int main(void)
 585 {
 586         int v;
 587         iconv_t conv;
 588         char in[] = \"a\";
 589         iconv_ibp pin = in;
 590         char out[20] = \"\";
 591         char *pout = out;
 592         size_t isz = sizeof(in);
 593         size_t osz = sizeof(out);
 594
 595         conv = iconv_open(\"UTF-16\", \"UTF-8\");
 596         iconv(conv, &pin, &isz, &pout, &osz);
 597         iconv_close(conv);
 598         v = (unsigned char)(out[0]) + (unsigned char)(out[1]);
 599         return v != 0xfe + 0xff;
 600 }"
 601 ICONV_DOESNOT_OMIT_BOM)
 602 if(NOT ICONV_DOESNOT_OMIT_BOM)
 603         add_compile_definitions(ICONV_OMITS_BOM)
 604 endif()
 605
 606 unset(CMAKE_REQUIRED_LIBRARIES)
 607 unset(CMAKE_REQUIRED_INCLUDES)
 608
 609
 610 #programs
 611 set(PROGRAMS_BUILT
 612         git git-daemon git-http-backend git-sh-i18n--envsubst
 613         git-shell scalar)
 614
 615 if(NOT CURL_FOUND)
 616         list(APPEND excluded_progs git-http-fetch git-http-push)
 617         add_compile_definitions(NO_CURL)
 618         message(WARNING "git-http-push and git-http-fetch will not be built")
 619 else()
 620         list(APPEND PROGRAMS_BUILT git-http-fetch git-http-push git-imap-send git-remote-http)
 621         if(CURL_VERSION_STRING VERSION_GREATER_EQUAL 7.34.0)
 622                 add_compile_definitions(USE_CURL_FOR_IMAP_SEND)
 623         endif()
 624 endif()
 625
 626 if(NOT EXPAT_FOUND)
 627         list(APPEND excluded_progs git-http-push)
 628         add_compile_definitions(NO_EXPAT)
 629 else()
 630         list(APPEND PROGRAMS_BUILT git-http-push)
 631         if(EXPAT_VERSION_STRING VERSION_LESS_EQUAL 1.2)
 632                 add_compile_definitions(EXPAT_NEEDS_XMLPARSE_H)
 633         endif()
 634 endif()
 635
 636 list(REMOVE_DUPLICATES excluded_progs)
 637 list(REMOVE_DUPLICATES PROGRAMS_BUILT)
 638
 639
 640 foreach(p ${excluded_progs})
 641         list(APPEND EXCLUSION_PROGS --exclude-program ${p} )
 642 endforeach()
 643
 644 #for comparing null values
 645 list(APPEND EXCLUSION_PROGS empty)
 646 set(EXCLUSION_PROGS_CACHE ${EXCLUSION_PROGS} CACHE STRING "Programs not built" FORCE)
 647
 648 if(NOT EXISTS ${CMAKE_BINARY_DIR}/command-list.h OR NOT EXCLUSION_PROGS_CACHE STREQUAL EXCLUSION_PROGS)
 649         list(REMOVE_ITEM EXCLUSION_PROGS empty)
 650         message("Generating command-list.h")
 651         execute_process(COMMAND ${SH_EXE} ${CMAKE_SOURCE_DIR}/generate-cmdlist.sh ${EXCLUSION_PROGS} command-list.txt
 652                         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 653                         OUTPUT_FILE ${CMAKE_BINARY_DIR}/command-list.h)
 654 endif()
 655
 656 if(NOT EXISTS ${CMAKE_BINARY_DIR}/config-list.h)
 657         message("Generating config-list.h")
 658         execute_process(COMMAND ${SH_EXE} ${CMAKE_SOURCE_DIR}/generate-configlist.sh
 659                         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 660                         OUTPUT_FILE ${CMAKE_BINARY_DIR}/config-list.h)
 661 endif()
 662
 663 if(NOT EXISTS ${CMAKE_BINARY_DIR}/hook-list.h)
 664         message("Generating hook-list.h")
 665         execute_process(COMMAND ${SH_EXE} ${CMAKE_SOURCE_DIR}/generate-hooklist.sh
 666                         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 667                         OUTPUT_FILE ${CMAKE_BINARY_DIR}/hook-list.h)
 668 endif()
 669
 670 include_directories(${CMAKE_BINARY_DIR})
 671
 672 #build
 673 #libgit
 674 parse_makefile_for_sources(libgit_SOURCES "LIB_OBJS")
 675
 676 list(TRANSFORM libgit_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 677 list(TRANSFORM compat_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 678 add_library(libgit ${libgit_SOURCES} ${compat_SOURCES})
 679
 680 #libxdiff
 681 parse_makefile_for_sources(libxdiff_SOURCES "XDIFF_OBJS")
 682
 683 list(TRANSFORM libxdiff_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 684 add_library(xdiff STATIC ${libxdiff_SOURCES})
 685
 686 #reftable
 687 parse_makefile_for_sources(reftable_SOURCES "REFTABLE_OBJS")
 688
 689 list(TRANSFORM reftable_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 690 add_library(reftable STATIC ${reftable_SOURCES})
 691
 692 if(WIN32)
 693         if(NOT MSVC)#use windres when compiling with gcc and clang
 694                 add_custom_command(OUTPUT ${CMAKE_BINARY_DIR}/git.res
 695                                 COMMAND ${WINDRES_EXE} -O coff -DMAJOR=${PROJECT_VERSION_MAJOR} -DMINOR=${PROJECT_VERSION_MINOR}
 696                                         -DMICRO=${PROJECT_VERSION_PATCH} -DPATCHLEVEL=0 -DGIT_VERSION="\\\"${PROJECT_VERSION}.GIT\\\""
 697                                         -i ${CMAKE_SOURCE_DIR}/git.rc -o ${CMAKE_BINARY_DIR}/git.res
 698                                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 699                                 VERBATIM)
 700         else()#MSVC use rc
 701                 add_custom_command(OUTPUT ${CMAKE_BINARY_DIR}/git.res
 702                                 COMMAND ${CMAKE_RC_COMPILER} /d MAJOR=${PROJECT_VERSION_MAJOR} /d MINOR=${PROJECT_VERSION_MINOR}
 703                                         /d MICRO=${PROJECT_VERSION_PATCH} /d PATCHLEVEL=0 /d GIT_VERSION="${PROJECT_VERSION}.GIT"
 704                                         /fo ${CMAKE_BINARY_DIR}/git.res ${CMAKE_SOURCE_DIR}/git.rc
 705                                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 706                                 VERBATIM)
 707         endif()
 708         add_custom_target(git-rc DEPENDS ${CMAKE_BINARY_DIR}/git.res)
 709 endif()
 710
 711 #link all required libraries to common-main
 712 add_library(common-main OBJECT ${CMAKE_SOURCE_DIR}/common-main.c)
 713
 714 target_link_libraries(common-main libgit xdiff reftable ${ZLIB_LIBRARIES})
 715 if(Intl_FOUND)
 716         target_link_libraries(common-main ${Intl_LIBRARIES})
 717 endif()
 718 if(Iconv_FOUND)
 719         target_link_libraries(common-main ${Iconv_LIBRARIES})
 720 endif()
 721 if(PCRE2_FOUND)
 722         target_link_libraries(common-main ${PCRE2_LIBRARIES})
 723         target_link_directories(common-main PUBLIC ${PCRE2_LIBRARY_DIRS})
 724 endif()
 725 if(WIN32)
 726         target_link_libraries(common-main ws2_32 ntdll ${CMAKE_BINARY_DIR}/git.res)
 727         add_dependencies(common-main git-rc)
 728         if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
 729                 target_link_options(common-main PUBLIC -municode -Wl,--nxcompat -Wl,--dynamicbase -Wl,--pic-executable,-e,mainCRTStartup)
 730         elseif(CMAKE_C_COMPILER_ID STREQUAL "Clang")
 731                 target_link_options(common-main PUBLIC -municode -Wl,-nxcompat -Wl,-dynamicbase -Wl,-entry:wmainCRTStartup -Wl,invalidcontinue.obj)
 732         elseif(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
 733                 target_link_options(common-main PUBLIC /IGNORE:4217 /IGNORE:4049 /NOLOGO /ENTRY:wmainCRTStartup /SUBSYSTEM:CONSOLE invalidcontinue.obj)
 734         else()
 735                 message(FATAL_ERROR "Unhandled compiler: ${CMAKE_C_COMPILER_ID}")
 736         endif()
 737 elseif(UNIX)
 738         target_link_libraries(common-main pthread rt)
 739 endif()
 740
 741 #git
 742 parse_makefile_for_sources(git_SOURCES "BUILTIN_OBJS")
 743
 744 list(TRANSFORM git_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 745 add_executable(git ${CMAKE_SOURCE_DIR}/git.c ${git_SOURCES})
 746 target_link_libraries(git common-main)
 747
 748 add_executable(git-daemon ${CMAKE_SOURCE_DIR}/daemon.c)
 749 target_link_libraries(git-daemon common-main)
 750
 751 add_executable(git-http-backend ${CMAKE_SOURCE_DIR}/http-backend.c)
 752 target_link_libraries(git-http-backend common-main)
 753
 754 add_executable(git-sh-i18n--envsubst ${CMAKE_SOURCE_DIR}/sh-i18n--envsubst.c)
 755 target_link_libraries(git-sh-i18n--envsubst common-main)
 756
 757 add_executable(git-shell ${CMAKE_SOURCE_DIR}/shell.c)
 758 target_link_libraries(git-shell common-main)
 759
 760 add_executable(scalar ${CMAKE_SOURCE_DIR}/scalar.c)
 761 target_link_libraries(scalar common-main)
 762
 763 if(CURL_FOUND)
 764         add_library(http_obj OBJECT ${CMAKE_SOURCE_DIR}/http.c)
 765
 766         add_executable(git-imap-send ${CMAKE_SOURCE_DIR}/imap-send.c)
 767         target_link_libraries(git-imap-send http_obj common-main ${CURL_LIBRARIES})
 768
 769         add_executable(git-http-fetch ${CMAKE_SOURCE_DIR}/http-walker.c ${CMAKE_SOURCE_DIR}/http-fetch.c)
 770         target_link_libraries(git-http-fetch http_obj common-main ${CURL_LIBRARIES})
 771
 772         add_executable(git-remote-http ${CMAKE_SOURCE_DIR}/http-walker.c ${CMAKE_SOURCE_DIR}/remote-curl.c)
 773         target_link_libraries(git-remote-http http_obj common-main ${CURL_LIBRARIES} )
 774
 775         if(EXPAT_FOUND)
 776                 add_executable(git-http-push ${CMAKE_SOURCE_DIR}/http-push.c)
 777                 target_link_libraries(git-http-push http_obj common-main ${CURL_LIBRARIES} ${EXPAT_LIBRARIES})
 778         endif()
 779 endif()
 780
 781 parse_makefile_for_executables(git_builtin_extra "BUILT_INS")
 782
 783 option(SKIP_DASHED_BUILT_INS "Skip hardlinking the dashed versions of the built-ins")
 784
 785 #Creating hardlinks
 786 if(NOT SKIP_DASHED_BUILT_INS)
 787 foreach(s ${git_SOURCES} ${git_builtin_extra})
 788         string(REPLACE "${CMAKE_SOURCE_DIR}/builtin/" "" s ${s})
 789         string(REPLACE ".c" "" s ${s})
 790         file(APPEND ${CMAKE_BINARY_DIR}/CreateLinks.cmake "file(CREATE_LINK git${EXE_EXTENSION} git-${s}${EXE_EXTENSION})\n")
 791         list(APPEND git_links ${CMAKE_BINARY_DIR}/git-${s}${EXE_EXTENSION})
 792 endforeach()
 793 endif()
 794
 795 if(CURL_FOUND)
 796         set(remote_exes
 797                 git-remote-https git-remote-ftp git-remote-ftps)
 798         foreach(s ${remote_exes})
 799                 file(APPEND ${CMAKE_BINARY_DIR}/CreateLinks.cmake "file(CREATE_LINK git-remote-http${EXE_EXTENSION} ${s}${EXE_EXTENSION})\n")
 800                 list(APPEND git_http_links ${CMAKE_BINARY_DIR}/${s}${EXE_EXTENSION})
 801         endforeach()
 802 endif()
 803
 804 add_custom_command(OUTPUT ${git_links} ${git_http_links}
 805                 COMMAND ${CMAKE_COMMAND} -P ${CMAKE_BINARY_DIR}/CreateLinks.cmake
 806                 DEPENDS git git-remote-http)
 807 add_custom_target(git-links ALL DEPENDS ${git_links} ${git_http_links})
 808
 809
 810 #creating required scripts
 811 set(SHELL_PATH /bin/sh)
 812 set(PERL_PATH /usr/bin/perl)
 813 set(LOCALEDIR ${FALLBACK_RUNTIME_PREFIX}/share/locale)
 814 set(GITWEBDIR ${FALLBACK_RUNTIME_PREFIX}/share/locale)
 815 set(INSTLIBDIR ${FALLBACK_RUNTIME_PREFIX}/share/perl5)
 816
 817 #shell scripts
 818 parse_makefile_for_scripts(git_sh_scripts "SCRIPT_SH" ".sh")
 819 parse_makefile_for_scripts(git_shlib_scripts "SCRIPT_LIB" "")
 820 set(git_shell_scripts
 821         ${git_sh_scripts} ${git_shlib_scripts} git-instaweb)
 822
 823 foreach(script ${git_shell_scripts})
 824         file(STRINGS ${CMAKE_SOURCE_DIR}/${script}.sh content NEWLINE_CONSUME)
 825         string(REPLACE "@SHELL_PATH@" "${SHELL_PATH}" content "${content}")
 826         string(REPLACE "@@DIFF@@" "diff" content "${content}")
 827         string(REPLACE "@LOCALEDIR@" "${LOCALEDIR}" content "${content}")
 828         string(REPLACE "@GITWEBDIR@" "${GITWEBDIR}" content "${content}")
 829         string(REPLACE "@@NO_CURL@@" "" content "${content}")
 830         string(REPLACE "@@USE_GETTEXT_SCHEME@@" "" content "${content}")
 831         string(REPLACE "# @@BROKEN_PATH_FIX@@" "" content "${content}")
 832         string(REPLACE "@@PERL@@" "${PERL_PATH}" content "${content}")
 833         string(REPLACE "@@PAGER_ENV@@" "LESS=FRX LV=-c" content "${content}")
 834         file(WRITE ${CMAKE_BINARY_DIR}/${script} ${content})
 835 endforeach()
 836
 837 #perl scripts
 838 parse_makefile_for_scripts(git_perl_scripts "SCRIPT_PERL" ".perl")
 839
 840 #create perl header
 841 file(STRINGS ${CMAKE_SOURCE_DIR}/perl/header_templates/fixed_prefix.template.pl perl_header )
 842 string(REPLACE "@@PATHSEP@@" ":" perl_header "${perl_header}")
 843 string(REPLACE "@@INSTLIBDIR@@" "${INSTLIBDIR}" perl_header "${perl_header}")
 844
 845 foreach(script ${git_perl_scripts})
 846         file(STRINGS ${CMAKE_SOURCE_DIR}/${script}.perl content NEWLINE_CONSUME)
 847         string(REPLACE "#!/usr/bin/perl" "#!/usr/bin/perl\n${perl_header}\n" content "${content}")
 848         string(REPLACE "@@GIT_VERSION@@" "${PROJECT_VERSION}" content "${content}")
 849         file(WRITE ${CMAKE_BINARY_DIR}/${script} ${content})
 850 endforeach()
 851
 852 #python script
 853 file(STRINGS ${CMAKE_SOURCE_DIR}/git-p4.py content NEWLINE_CONSUME)
 854 string(REPLACE "#!/usr/bin/env python" "#!/usr/bin/python" content "${content}")
 855 file(WRITE ${CMAKE_BINARY_DIR}/git-p4 ${content})
 856
 857 #perl modules
 858 file(GLOB_RECURSE perl_modules "${CMAKE_SOURCE_DIR}/perl/*.pm")
 859
 860 foreach(pm ${perl_modules})
 861         string(REPLACE "${CMAKE_SOURCE_DIR}/perl/" "" file_path ${pm})
 862         file(STRINGS ${pm} content NEWLINE_CONSUME)
 863         string(REPLACE "@@LOCALEDIR@@" "${LOCALEDIR}" content "${content}")
 864         string(REPLACE "@@NO_PERL_CPAN_FALLBACKS@@" "" content "${content}")
 865         file(WRITE ${CMAKE_BINARY_DIR}/perl/build/lib/${file_path} ${content})
 866 #test-lib.sh requires perl/build/lib to be the build directory of perl modules
 867 endforeach()
 868
 869
 870 #templates
 871 file(GLOB templates "${CMAKE_SOURCE_DIR}/templates/*")
 872 list(TRANSFORM templates REPLACE "${CMAKE_SOURCE_DIR}/templates/" "")
 873 list(REMOVE_ITEM templates ".gitignore")
 874 list(REMOVE_ITEM templates "Makefile")
 875 list(REMOVE_ITEM templates "blt")# Prevents an error when reconfiguring for in source builds
 876
 877 list(REMOVE_ITEM templates "branches--")
 878 file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/templates/blt/branches) #create branches
 879
 880 #templates have @.*@ replacement so use configure_file instead
 881 foreach(tm ${templates})
 882         string(REPLACE "--" "/" blt_tm ${tm})
 883         string(REPLACE "this" "" blt_tm ${blt_tm})# for this--
 884         configure_file(${CMAKE_SOURCE_DIR}/templates/${tm} ${CMAKE_BINARY_DIR}/templates/blt/${blt_tm} @ONLY)
 885 endforeach()
 886
 887
 888 #translations
 889 if(MSGFMT_EXE)
 890         file(GLOB po_files "${CMAKE_SOURCE_DIR}/po/*.po")
 891         list(TRANSFORM po_files REPLACE "${CMAKE_SOURCE_DIR}/po/" "")
 892         list(TRANSFORM po_files REPLACE ".po" "")
 893         foreach(po ${po_files})
 894                 file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES)
 895                 add_custom_command(OUTPUT ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES/git.mo
 896                                 COMMAND ${MSGFMT_EXE} --check --statistics -o ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES/git.mo ${CMAKE_SOURCE_DIR}/po/${po}.po)
 897                 list(APPEND po_gen ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES/git.mo)
 898         endforeach()
 899         add_custom_target(po-gen ALL DEPENDS ${po_gen})
 900 endif()
 901
 902
 903 #to help with the install
 904 list(TRANSFORM git_shell_scripts PREPEND "${CMAKE_BINARY_DIR}/")
 905 list(TRANSFORM git_perl_scripts PREPEND "${CMAKE_BINARY_DIR}/")
 906
 907 #install
 908 foreach(program ${PROGRAMS_BUILT})
 909 if(program MATCHES "^(git|git-shell|scalar)$")
 910 install(TARGETS ${program}
 911         RUNTIME DESTINATION bin)
 912 else()
 913 install(TARGETS ${program}
 914         RUNTIME DESTINATION libexec/git-core)
 915 endif()
 916 endforeach()
 917
 918 install(PROGRAMS ${CMAKE_BINARY_DIR}/git-cvsserver
 919         DESTINATION bin)
 920
 921 set(bin_links
 922         git-receive-pack git-upload-archive git-upload-pack)
 923
 924 foreach(b ${bin_links})
 925 install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/bin/${b}${EXE_EXTENSION})")
 926 endforeach()
 927
 928 install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/libexec/git-core/git${EXE_EXTENSION})")
 929 install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git-shell${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/libexec/git-core/git-shell${EXE_EXTENSION})")
 930
 931 foreach(b ${git_links})
 932         string(REPLACE "${CMAKE_BINARY_DIR}" "" b ${b})
 933         install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/libexec/git-core/${b})")
 934 endforeach()
 935
 936 foreach(b ${git_http_links})
 937         string(REPLACE "${CMAKE_BINARY_DIR}" "" b ${b})
 938         install(CODE "file(CREATE_LINK  ${CMAKE_INSTALL_PREFIX}/libexec/git-core/git-remote-http${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/libexec/git-core/${b})")
 939 endforeach()
 940
 941 install(PROGRAMS ${git_shell_scripts} ${git_perl_scripts} ${CMAKE_BINARY_DIR}/git-p4
 942         DESTINATION libexec/git-core)
 943
 944 install(DIRECTORY ${CMAKE_SOURCE_DIR}/mergetools DESTINATION libexec/git-core)
 945 install(DIRECTORY ${CMAKE_BINARY_DIR}/perl/build/lib/ DESTINATION share/perl5
 946         FILES_MATCHING PATTERN "*.pm")
 947 install(DIRECTORY ${CMAKE_BINARY_DIR}/templates/blt/ DESTINATION share/git-core/templates)
 948
 949 if(MSGFMT_EXE)
 950         install(DIRECTORY ${CMAKE_BINARY_DIR}/po/build/locale DESTINATION share)
 951 endif()
 952
 953
 954 if(BUILD_TESTING)
 955
 956 #tests-helpers
 957 add_executable(test-fake-ssh ${CMAKE_SOURCE_DIR}/t/helper/test-fake-ssh.c)
 958 target_link_libraries(test-fake-ssh common-main)
 959
 960 #reftable-tests
 961 parse_makefile_for_sources(test-reftable_SOURCES "REFTABLE_TEST_OBJS")
 962 list(TRANSFORM test-reftable_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 963
 964 #test-tool
 965 parse_makefile_for_sources(test-tool_SOURCES "TEST_BUILTINS_OBJS")
 966
 967 list(TRANSFORM test-tool_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/t/helper/")
 968 add_executable(test-tool ${CMAKE_SOURCE_DIR}/t/helper/test-tool.c ${test-tool_SOURCES} ${test-reftable_SOURCES})
 969 target_link_libraries(test-tool common-main)
 970
 971 set_target_properties(test-fake-ssh test-tool
 972                         PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/t/helper)
 973
 974 if(MSVC)
 975         set_target_properties(test-fake-ssh test-tool
 976                                 PROPERTIES RUNTIME_OUTPUT_DIRECTORY_DEBUG ${CMAKE_BINARY_DIR}/t/helper)
 977         set_target_properties(test-fake-ssh test-tool
 978                                 PROPERTIES RUNTIME_OUTPUT_DIRECTORY_RELEASE ${CMAKE_BINARY_DIR}/t/helper)
 979 endif()
 980
 981 #wrapper scripts
 982 set(wrapper_scripts
 983         git git-upload-pack git-receive-pack git-upload-archive git-shell git-remote-ext scalar)
 984
 985 set(wrapper_test_scripts
 986         test-fake-ssh test-tool)
 987
 988
 989 foreach(script ${wrapper_scripts})
 990         file(STRINGS ${CMAKE_SOURCE_DIR}/wrap-for-bin.sh content NEWLINE_CONSUME)
 991         string(REPLACE "@@BUILD_DIR@@" "${CMAKE_BINARY_DIR}" content "${content}")
 992         string(REPLACE "@@PROG@@" "${script}${EXE_EXTENSION}" content "${content}")
 993         file(WRITE ${CMAKE_BINARY_DIR}/bin-wrappers/${script} ${content})
 994 endforeach()
 995
 996 foreach(script ${wrapper_test_scripts})
 997         file(STRINGS ${CMAKE_SOURCE_DIR}/wrap-for-bin.sh content NEWLINE_CONSUME)
 998         string(REPLACE "@@BUILD_DIR@@" "${CMAKE_BINARY_DIR}" content "${content}")
 999         string(REPLACE "@@PROG@@" "t/helper/${script}${EXE_EXTENSION}" content "${content}")
1000         file(WRITE ${CMAKE_BINARY_DIR}/bin-wrappers/${script} ${content})
1001 endforeach()
1002
1003 file(STRINGS ${CMAKE_SOURCE_DIR}/wrap-for-bin.sh content NEWLINE_CONSUME)
1004 string(REPLACE "@@BUILD_DIR@@" "${CMAKE_BINARY_DIR}" content "${content}")
1005 string(REPLACE "@@PROG@@" "git-cvsserver" content "${content}")
1006 file(WRITE ${CMAKE_BINARY_DIR}/bin-wrappers/git-cvsserver ${content})
1007
1008 #options for configuring test options
1009 option(PERL_TESTS "Perform tests that use perl" ON)
1010 option(PYTHON_TESTS "Perform tests that use python" ON)
1011
1012 #GIT-BUILD-OPTIONS
1013 set(TEST_SHELL_PATH ${SHELL_PATH})
1014 set(DIFF diff)
1015 set(PYTHON_PATH /usr/bin/python)
1016 set(TAR tar)
1017 set(NO_CURL )
1018 set(NO_EXPAT )
1019 set(USE_LIBPCRE2 )
1020 set(NO_PERL )
1021 set(NO_PTHREADS )
1022 set(NO_PYTHON )
1023 set(PAGER_ENV "LESS=FRX LV=-c")
1024 set(DC_SHA1 YesPlease)
1025 set(RUNTIME_PREFIX true)
1026 set(NO_GETTEXT )
1027
1028 if(NOT CURL_FOUND)
1029         set(NO_CURL 1)
1030 endif()
1031
1032 if(NOT EXPAT_FOUND)
1033         set(NO_EXPAT 1)
1034 endif()
1035
1036 if(NOT Intl_FOUND)
1037         set(NO_GETTEXT 1)
1038 endif()
1039
1040 if(NOT PERL_TESTS)
1041         set(NO_PERL 1)
1042 endif()
1043
1044 if(NOT PYTHON_TESTS)
1045         set(NO_PYTHON 1)
1046 endif()
1047
1048 file(WRITE ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "SHELL_PATH='${SHELL_PATH}'\n")
1049 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "TEST_SHELL_PATH='${TEST_SHELL_PATH}'\n")
1050 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PERL_PATH='${PERL_PATH}'\n")
1051 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "DIFF='${DIFF}'\n")
1052 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PYTHON_PATH='${PYTHON_PATH}'\n")
1053 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "TAR='${TAR}'\n")
1054 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_CURL='${NO_CURL}'\n")
1055 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_EXPAT='${NO_EXPAT}'\n")
1056 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_PERL='${NO_PERL}'\n")
1057 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_PTHREADS='${NO_PTHREADS}'\n")
1058 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_UNIX_SOCKETS='${NO_UNIX_SOCKETS}'\n")
1059 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PAGER_ENV='${PAGER_ENV}'\n")
1060 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "DC_SHA1='${DC_SHA1}'\n")
1061 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "X='${EXE_EXTENSION}'\n")
1062 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_GETTEXT='${NO_GETTEXT}'\n")
1063 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "RUNTIME_PREFIX='${RUNTIME_PREFIX}'\n")
1064 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_PYTHON='${NO_PYTHON}'\n")
1065 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "SUPPORTS_SIMPLE_IPC='${SUPPORTS_SIMPLE_IPC}'\n")
1066 if(USE_VCPKG)
1067         file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PATH=\"$PATH:$TEST_DIRECTORY/../compat/vcbuild/vcpkg/installed/x64-windows/bin\"\n")
1068 endif()
1069
1070 #Make the tests work when building out of the source tree
1071 get_filename_component(CACHE_PATH ${CMAKE_CURRENT_LIST_DIR}/../../CMakeCache.txt ABSOLUTE)
1072 if(NOT ${CMAKE_BINARY_DIR}/CMakeCache.txt STREQUAL ${CACHE_PATH})
1073         file(RELATIVE_PATH BUILD_DIR_RELATIVE ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/CMakeCache.txt)
1074         string(REPLACE "/CMakeCache.txt" "" BUILD_DIR_RELATIVE ${BUILD_DIR_RELATIVE})
1075         #Setting the build directory in test-lib.sh before running tests
1076         file(WRITE ${CMAKE_BINARY_DIR}/CTestCustom.cmake
1077                 "file(STRINGS ${CMAKE_SOURCE_DIR}/t/test-lib.sh GIT_BUILD_DIR_REPL REGEX \"GIT_BUILD_DIR=(.*)\")\n"
1078                 "file(STRINGS ${CMAKE_SOURCE_DIR}/t/test-lib.sh content NEWLINE_CONSUME)\n"
1079                 "string(REPLACE \"\${GIT_BUILD_DIR_REPL}\" \"GIT_BUILD_DIR=\\\"$TEST_DIRECTORY/../${BUILD_DIR_RELATIVE}\\\"\" content \"\${content}\")\n"
1080                 "file(WRITE ${CMAKE_SOURCE_DIR}/t/test-lib.sh \${content})")
1081         #misc copies
1082         file(COPY ${CMAKE_SOURCE_DIR}/t/chainlint.pl DESTINATION ${CMAKE_BINARY_DIR}/t/)
1083         file(COPY ${CMAKE_SOURCE_DIR}/po/is.po DESTINATION ${CMAKE_BINARY_DIR}/po/)
1084         file(COPY ${CMAKE_SOURCE_DIR}/mergetools/tkdiff DESTINATION ${CMAKE_BINARY_DIR}/mergetools/)
1085         file(COPY ${CMAKE_SOURCE_DIR}/contrib/completion/git-prompt.sh DESTINATION ${CMAKE_BINARY_DIR}/contrib/completion/)
1086         file(COPY ${CMAKE_SOURCE_DIR}/contrib/completion/git-completion.bash DESTINATION ${CMAKE_BINARY_DIR}/contrib/completion/)
1087 endif()
1088
1089 file(GLOB test_scipts "${CMAKE_SOURCE_DIR}/t/t[0-9]*.sh")
1090
1091 #test
1092 foreach(tsh ${test_scipts})
1093         add_test(NAME ${tsh}
1094                 COMMAND ${SH_EXE} ${tsh}
1095                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/t)
1096 endforeach()
1097
1098 endif()#BUILD_TESTING