git-svn.perl

   1 #!/usr/bin/perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use 5.008;
   5 use warnings;
   6 use strict;
   7 use vars qw/    $AUTHOR $VERSION
   8                 $sha1 $sha1_short $_revision $_repository
   9                 $_q $_authors $_authors_prog %users/;
  10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11 $VERSION = '@@GIT_VERSION@@';
  12
  13 use Carp qw/croak/;
  14 use Digest::MD5;
  15 use IO::File qw//;
  16 use File::Basename qw/dirname basename/;
  17 use File::Path qw/mkpath/;
  18 use File::Spec;
  19 use File::Find;
  20 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  21 use IPC::Open3;
  22 use Memoize;
  23
  24 use Git::SVN;
  25 use Git::SVN::Editor;
  26 use Git::SVN::Fetcher;
  27 use Git::SVN::Ra;
  28 use Git::SVN::Prompt;
  29 use Git::SVN::Log;
  30 use Git::SVN::Migration;
  31
  32 use Git::SVN::Utils qw(
  33         fatal
  34         can_compress
  35         canonicalize_path
  36         canonicalize_url
  37         join_paths
  38         add_path_to_url
  39         join_paths
  40 );
  41
  42 use Git qw(
  43         git_cmd_try
  44         command
  45         command_oneline
  46         command_noisy
  47         command_output_pipe
  48         command_close_pipe
  49         command_bidi_pipe
  50         command_close_bidi_pipe
  51 );
  52
  53 BEGIN {
  54         Memoize::memoize 'Git::config';
  55         Memoize::memoize 'Git::config_bool';
  56 }
  57
  58
  59 # From which subdir have we been invoked?
  60 my $cmd_dir_prefix = eval {
  61         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  62 } || '';
  63
  64 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  65 $ENV{GIT_DIR} ||= '.git';
  66 $Git::SVN::Ra::_log_window_size = 100;
  67
  68 if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
  69         $ENV{SVN_SSH} = $ENV{GIT_SSH};
  70 }
  71
  72 if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
  73         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  74         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  75 }
  76
  77 $Git::SVN::Log::TZ = $ENV{TZ};
  78 $ENV{TZ} = 'UTC';
  79 $| = 1; # unbuffer STDOUT
  80
  81 # All SVN commands do it.  Otherwise we may die on SIGPIPE when the remote
  82 # repository decides to close the connection which we expect to be kept alive.
  83 $SIG{PIPE} = 'IGNORE';
  84
  85 # Given a dot separated version number, "subtract" it from
  86 # the SVN::Core::VERSION; non-negaitive return means the SVN::Core
  87 # is at least at the version the caller asked for.
  88 sub compare_svn_version {
  89         my (@ours) = split(/\./, $SVN::Core::VERSION);
  90         my (@theirs) = split(/\./, $_[0]);
  91         my ($i, $diff);
  92
  93         for ($i = 0; $i < @ours && $i < @theirs; $i++) {
  94                 $diff = $ours[$i] - $theirs[$i];
  95                 return $diff if ($diff);
  96         }
  97         return 1 if ($i < @ours);
  98         return -1 if ($i < @theirs);
  99         return 0;
 100 }
 101
 102 sub _req_svn {
 103         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
 104         require SVN::Ra;
 105         require SVN::Delta;
 106         if (::compare_svn_version('1.1.0') < 0) {
 107                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
 108         }
 109 }
 110
 111 $sha1 = qr/[a-f\d]{40}/;
 112 $sha1_short = qr/[a-f\d]{4,40}/;
 113 my ($_stdin, $_help, $_edit,
 114         $_message, $_file, $_branch_dest,
 115         $_template, $_shared,
 116         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
 117         $_merge, $_strategy, $_preserve_merges, $_dry_run, $_local,
 118         $_prefix, $_no_checkout, $_url, $_verbose,
 119         $_commit_url, $_tag, $_merge_info, $_interactive);
 120
 121 # This is a refactoring artifact so Git::SVN can get at this git-svn switch.
 122 sub opt_prefix { return $_prefix || '' }
 123
 124 $Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
 125 $_q ||= 0;
 126 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
 127                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
 128                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
 129                     'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
 130                     'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
 131 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
 132                 'authors-file|A=s' => \$_authors,
 133                 'authors-prog=s' => \$_authors_prog,
 134                 'repack:i' => \$Git::SVN::_repack,
 135                 'noMetadata' => \$Git::SVN::_no_metadata,
 136                 'useSvmProps' => \$Git::SVN::_use_svm_props,
 137                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 138                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 139                 'no-checkout' => \$_no_checkout,
 140                 'quiet|q+' => \$_q,
 141                 'repack-flags|repack-args|repack-opts=s' =>
 142                    \$Git::SVN::_repack_flags,
 143                 'use-log-author' => \$Git::SVN::_use_log_author,
 144                 'add-author-from' => \$Git::SVN::_add_author_from,
 145                 'localtime' => \$Git::SVN::_localtime,
 146                 %remote_opts );
 147
 148 my ($_trunk, @_tags, @_branches, $_stdlayout);
 149 my %icv;
 150 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 151                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 152                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 153                   'stdlayout|s' => \$_stdlayout,
 154                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 155                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 156                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 157                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 158                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 159                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 160                   %remote_opts );
 161 my %cmt_opts = ( 'edit|e' => \$_edit,
 162                 'rmdir' => \$Git::SVN::Editor::_rmdir,
 163                 'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
 164                 'l=i' => \$Git::SVN::Editor::_rename_limit,
 165                 'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
 166 );
 167
 168 my %cmd = (
 169         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 170                         { 'revision|r=s' => \$_revision,
 171                           'fetch-all|all' => \$_fetch_all,
 172                           'parent|p' => \$_fetch_parent,
 173                            %fc_opts } ],
 174         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 175                         { 'revision|r=s' => \$_revision,
 176                           'preserve-empty-dirs' =>
 177                                 \$Git::SVN::Fetcher::_preserve_empty_dirs,
 178                           'placeholder-filename=s' =>
 179                                 \$Git::SVN::Fetcher::_placeholder_filename,
 180                            %fc_opts, %init_opts } ],
 181         init => [ \&cmd_init, "Initialize a repo for tracking" .
 182                           " (requires URL argument)",
 183                           \%init_opts ],
 184         'multi-init' => [ \&cmd_multi_init,
 185                           "Deprecated alias for ".
 186                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 187                           \%init_opts ],
 188         dcommit => [ \&cmd_dcommit,
 189                      'Commit several diffs to merge with upstream',
 190                         { 'merge|m|M' => \$_merge,
 191                           'strategy|s=s' => \$_strategy,
 192                           'verbose|v' => \$_verbose,
 193                           'dry-run|n' => \$_dry_run,
 194                           'fetch-all|all' => \$_fetch_all,
 195                           'commit-url=s' => \$_commit_url,
 196                           'revision|r=i' => \$_revision,
 197                           'no-rebase' => \$_no_rebase,
 198                           'mergeinfo=s' => \$_merge_info,
 199                           'interactive|i' => \$_interactive,
 200                         %cmt_opts, %fc_opts } ],
 201         branch => [ \&cmd_branch,
 202                     'Create a branch in the SVN repository',
 203                     { 'message|m=s' => \$_message,
 204                       'destination|d=s' => \$_branch_dest,
 205                       'dry-run|n' => \$_dry_run,
 206                       'tag|t' => \$_tag,
 207                       'username=s' => \$Git::SVN::Prompt::_username,
 208                       'commit-url=s' => \$_commit_url } ],
 209         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 210                  'Create a tag in the SVN repository',
 211                  { 'message|m=s' => \$_message,
 212                    'destination|d=s' => \$_branch_dest,
 213                    'dry-run|n' => \$_dry_run,
 214                    'username=s' => \$Git::SVN::Prompt::_username,
 215                    'commit-url=s' => \$_commit_url } ],
 216         'set-tree' => [ \&cmd_set_tree,
 217                         "Set an SVN repository to a git tree-ish",
 218                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 219         'create-ignore' => [ \&cmd_create_ignore,
 220                              'Create a .gitignore per svn:ignore',
 221                              { 'revision|r=i' => \$_revision
 222                              } ],
 223         'mkdirs' => [ \&cmd_mkdirs ,
 224                       "recreate empty directories after a checkout",
 225                       { 'revision|r=i' => \$_revision } ],
 226         'propget' => [ \&cmd_propget,
 227                        'Print the value of a property on a file or directory',
 228                        { 'revision|r=i' => \$_revision } ],
 229         'proplist' => [ \&cmd_proplist,
 230                        'List all properties of a file or directory',
 231                        { 'revision|r=i' => \$_revision } ],
 232         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 233                         { 'revision|r=i' => \$_revision
 234                         } ],
 235         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 236                         { 'revision|r=i' => \$_revision
 237                         } ],
 238         'multi-fetch' => [ \&cmd_multi_fetch,
 239                            "Deprecated alias for $0 fetch --all",
 240                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 241         'migrate' => [ sub { },
 242                        # no-op, we automatically run this anyways,
 243                        'Migrate configuration/metadata/layout from
 244                         previous versions of git-svn',
 245                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 246                          %remote_opts } ],
 247         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 248                         { 'limit=i' => \$Git::SVN::Log::limit,
 249                           'revision|r=s' => \$_revision,
 250                           'verbose|v' => \$Git::SVN::Log::verbose,
 251                           'incremental' => \$Git::SVN::Log::incremental,
 252                           'oneline' => \$Git::SVN::Log::oneline,
 253                           'show-commit' => \$Git::SVN::Log::show_commit,
 254                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 255                           'authors-file|A=s' => \$_authors,
 256                           'color' => \$Git::SVN::Log::color,
 257                           'pager=s' => \$Git::SVN::Log::pager
 258                         } ],
 259         'find-rev' => [ \&cmd_find_rev,
 260                         "Translate between SVN revision numbers and tree-ish",
 261                         {} ],
 262         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 263                         { 'merge|m|M' => \$_merge,
 264                           'verbose|v' => \$_verbose,
 265                           'strategy|s=s' => \$_strategy,
 266                           'local|l' => \$_local,
 267                           'fetch-all|all' => \$_fetch_all,
 268                           'dry-run|n' => \$_dry_run,
 269                           'preserve-merges|p' => \$_preserve_merges,
 270                           %fc_opts } ],
 271         'commit-diff' => [ \&cmd_commit_diff,
 272                            'Commit a diff between two trees',
 273                         { 'message|m=s' => \$_message,
 274                           'file|F=s' => \$_file,
 275                           'revision|r=s' => \$_revision,
 276                         %cmt_opts } ],
 277         'info' => [ \&cmd_info,
 278                     "Show info about the latest SVN revision
 279                      on the current branch",
 280                     { 'url' => \$_url, } ],
 281         'blame' => [ \&Git::SVN::Log::cmd_blame,
 282                     "Show what revision and author last modified each line of a file",
 283                     { 'git-format' => \$Git::SVN::Log::_git_format } ],
 284         'reset' => [ \&cmd_reset,
 285                      "Undo fetches back to the specified SVN revision",
 286                      { 'revision|r=s' => \$_revision,
 287                        'parent|p' => \$_fetch_parent } ],
 288         'gc' => [ \&cmd_gc,
 289                   "Compress unhandled.log files in .git/svn and remove " .
 290                   "index files in .git/svn",
 291                 {} ],
 292 );
 293
 294 use Term::ReadLine;
 295 package FakeTerm;
 296 sub new {
 297         my ($class, $reason) = @_;
 298         return bless \$reason, shift;
 299 }
 300 sub readline {
 301         my $self = shift;
 302         die "Cannot use readline on FakeTerm: $$self";
 303 }
 304 package main;
 305
 306 my $term = eval {
 307         $ENV{"GIT_SVN_NOTTY"}
 308                 ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
 309                 : new Term::ReadLine 'git-svn';
 310 };
 311 if ($@) {
 312         $term = new FakeTerm "$@: going non-interactive";
 313 }
 314
 315 my $cmd;
 316 for (my $i = 0; $i < @ARGV; $i++) {
 317         if (defined $cmd{$ARGV[$i]}) {
 318                 $cmd = $ARGV[$i];
 319                 splice @ARGV, $i, 1;
 320                 last;
 321         } elsif ($ARGV[$i] eq 'help') {
 322                 $cmd = $ARGV[$i+1];
 323                 usage(0);
 324         }
 325 };
 326
 327 # make sure we're always running at the top-level working directory
 328 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 329         unless (-d $ENV{GIT_DIR}) {
 330                 if ($git_dir_user_set) {
 331                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 332                             "but it is not a directory\n";
 333                 }
 334                 my $git_dir = delete $ENV{GIT_DIR};
 335                 my $cdup = undef;
 336                 git_cmd_try {
 337                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 338                         $git_dir = '.' unless ($cdup);
 339                         chomp $cdup if ($cdup);
 340                         $cdup = "." unless ($cdup && length $cdup);
 341                 } "Already at toplevel, but $git_dir not found\n";
 342                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 343                 unless (-d $git_dir) {
 344                         die "$git_dir still not found after going to ",
 345                             "'$cdup'\n";
 346                 }
 347                 $ENV{GIT_DIR} = $git_dir;
 348         }
 349         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 350 }
 351
 352 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 353
 354 read_git_config(\%opts);
 355 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 356         Getopt::Long::Configure('pass_through');
 357 }
 358 my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
 359                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 360                     'id|i=s' => \$Git::SVN::default_ref_id,
 361                     'svn-remote|remote|R=s' => sub {
 362                        $Git::SVN::no_reuse_existing = 1;
 363                        $Git::SVN::default_repo_id = $_[1] });
 364 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 365
 366 usage(0) if $_help;
 367 version() if $_version;
 368 usage(1) unless defined $cmd;
 369 load_authors() if $_authors;
 370 if (defined $_authors_prog) {
 371         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 372 }
 373
 374 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 375         Git::SVN::Migration::migration_check();
 376 }
 377 Git::SVN::init_vars();
 378 eval {
 379         Git::SVN::verify_remotes_sanity();
 380         $cmd{$cmd}->[0]->(@ARGV);
 381         post_fetch_checkout();
 382 };
 383 fatal $@ if $@;
 384 exit 0;
 385
 386 ####################### primary functions ######################
 387 sub usage {
 388         my $exit = shift || 0;
 389         my $fd = $exit ? \*STDERR : \*STDOUT;
 390         print $fd <<"";
 391 git-svn - bidirectional operations between a single Subversion tree and git
 392 Usage: git svn <command> [options] [arguments]\n
 393
 394         print $fd "Available commands:\n" unless $cmd;
 395
 396         foreach (sort keys %cmd) {
 397                 next if $cmd && $cmd ne $_;
 398                 next if /^multi-/; # don't show deprecated commands
 399                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 400                 foreach (sort keys %{$cmd{$_}->[2]}) {
 401                         # mixed-case options are for .git/config only
 402                         next if /[A-Z]/ && /^[a-z]+$/i;
 403                         # prints out arguments as they should be passed:
 404                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 405                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 406                                                         "--$_" : "-$_" }
 407                                                 split /\|/,$_)," $x\n";
 408                 }
 409         }
 410         print $fd <<"";
 411 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 412 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 413 one git repository and want to keep them separate.  See git-svn(1) for more
 414 information.
 415
 416         exit $exit;
 417 }
 418
 419 sub version {
 420         ::_req_svn();
 421         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 422         exit 0;
 423 }
 424
 425 sub ask {
 426         my ($prompt, %arg) = @_;
 427         my $valid_re = $arg{valid_re};
 428         my $default = $arg{default};
 429         my $resp;
 430         my $i = 0;
 431
 432         if ( !( defined($term->IN)
 433             && defined( fileno($term->IN) )
 434             && defined( $term->OUT )
 435             && defined( fileno($term->OUT) ) ) ){
 436                 return defined($default) ? $default : undef;
 437         }
 438
 439         while ($i++ < 10) {
 440                 $resp = $term->readline($prompt);
 441                 if (!defined $resp) { # EOF
 442                         print "\n";
 443                         return defined $default ? $default : undef;
 444                 }
 445                 if ($resp eq '' and defined $default) {
 446                         return $default;
 447                 }
 448                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 449                         return $resp;
 450                 }
 451         }
 452         return undef;
 453 }
 454
 455 sub do_git_init_db {
 456         unless (-d $ENV{GIT_DIR}) {
 457                 my @init_db = ('init');
 458                 push @init_db, "--template=$_template" if defined $_template;
 459                 if (defined $_shared) {
 460                         if ($_shared =~ /[a-z]/) {
 461                                 push @init_db, "--shared=$_shared";
 462                         } else {
 463                                 push @init_db, "--shared";
 464                         }
 465                 }
 466                 command_noisy(@init_db);
 467                 $_repository = Git->repository(Repository => ".git");
 468         }
 469         my $set;
 470         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 471         foreach my $i (keys %icv) {
 472                 die "'$set' and '$i' cannot both be set\n" if $set;
 473                 next unless defined $icv{$i};
 474                 command_noisy('config', "$pfx.$i", $icv{$i});
 475                 $set = $i;
 476         }
 477         my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
 478         command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
 479                 if defined $$ignore_paths_regex;
 480         my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
 481         command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
 482                 if defined $$ignore_refs_regex;
 483
 484         if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
 485                 my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
 486                 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
 487                 command_noisy('config', "$pfx.placeholder-filename", $$fname);
 488         }
 489 }
 490
 491 sub init_subdir {
 492         my $repo_path = shift or return;
 493         mkpath([$repo_path]) unless -d $repo_path;
 494         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 495         $ENV{GIT_DIR} = '.git';
 496         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 497 }
 498
 499 sub cmd_clone {
 500         my ($url, $path) = @_;
 501         if (!defined $path &&
 502             (defined $_trunk || @_branches || @_tags ||
 503              defined $_stdlayout) &&
 504             $url !~ m#^[a-z\+]+://#) {
 505                 $path = $url;
 506         }
 507         $path = basename($url) if !defined $path || !length $path;
 508         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 509         cmd_init($url, $path);
 510         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 511             if $_authors;
 512         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 513 }
 514
 515 sub cmd_init {
 516         if (defined $_stdlayout) {
 517                 $_trunk = 'trunk' if (!defined $_trunk);
 518                 @_tags = 'tags' if (! @_tags);
 519                 @_branches = 'branches' if (! @_branches);
 520         }
 521         if (defined $_trunk || @_branches || @_tags) {
 522                 return cmd_multi_init(@_);
 523         }
 524         my $url = shift or die "SVN repository location required ",
 525                                "as a command-line argument\n";
 526         $url = canonicalize_url($url);
 527         init_subdir(@_);
 528         do_git_init_db();
 529
 530         if ($Git::SVN::_minimize_url eq 'unset') {
 531                 $Git::SVN::_minimize_url = 0;
 532         }
 533
 534         Git::SVN->init($url);
 535 }
 536
 537 sub cmd_fetch {
 538         if (grep /^\d+=./, @_) {
 539                 die "'<rev>=<commit>' fetch arguments are ",
 540                     "no longer supported.\n";
 541         }
 542         my ($remote) = @_;
 543         if (@_ > 1) {
 544                 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 545         }
 546         $Git::SVN::no_reuse_existing = undef;
 547         if ($_fetch_parent) {
 548                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 549                 unless ($gs) {
 550                         die "Unable to determine upstream SVN information from ",
 551                             "working tree history\n";
 552                 }
 553                 # just fetch, don't checkout.
 554                 $_no_checkout = 'true';
 555                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 556         } elsif ($_fetch_all) {
 557                 cmd_multi_fetch();
 558         } else {
 559                 $remote ||= $Git::SVN::default_repo_id;
 560                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 561         }
 562 }
 563
 564 sub cmd_set_tree {
 565         my (@commits) = @_;
 566         if ($_stdin || !@commits) {
 567                 print "Reading from stdin...\n";
 568                 @commits = ();
 569                 while (<STDIN>) {
 570                         if (/\b($sha1_short)\b/o) {
 571                                 unshift @commits, $1;
 572                         }
 573                 }
 574         }
 575         my @revs;
 576         foreach my $c (@commits) {
 577                 my @tmp = command('rev-parse',$c);
 578                 if (scalar @tmp == 1) {
 579                         push @revs, $tmp[0];
 580                 } elsif (scalar @tmp > 1) {
 581                         push @revs, reverse(command('rev-list',@tmp));
 582                 } else {
 583                         fatal "Failed to rev-parse $c";
 584                 }
 585         }
 586         my $gs = Git::SVN->new;
 587         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 588         $gs->fetch;
 589         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 590                 fatal "There are new revisions that were fetched ",
 591                       "and need to be merged (or acknowledged) ",
 592                       "before committing.\nlast rev: $r_last\n",
 593                       " current: $gs->{last_rev}";
 594         }
 595         $gs->set_tree($_) foreach @revs;
 596         print "Done committing ",scalar @revs," revisions to SVN\n";
 597         unlink $gs->{index};
 598 }
 599
 600 sub split_merge_info_range {
 601         my ($range) = @_;
 602         if ($range =~ /(\d+)-(\d+)/) {
 603                 return (int($1), int($2));
 604         } else {
 605                 return (int($range), int($range));
 606         }
 607 }
 608
 609 sub combine_ranges {
 610         my ($in) = @_;
 611
 612         my @fnums = ();
 613         my @arr = split(/,/, $in);
 614         for my $element (@arr) {
 615                 my ($start, $end) = split_merge_info_range($element);
 616                 push @fnums, $start;
 617         }
 618
 619         my @sorted = @arr [ sort {
 620                 $fnums[$a] <=> $fnums[$b]
 621         } 0..$#arr ];
 622
 623         my @return = ();
 624         my $last = -1;
 625         my $first = -1;
 626         for my $element (@sorted) {
 627                 my ($start, $end) = split_merge_info_range($element);
 628
 629                 if ($last == -1) {
 630                         $first = $start;
 631                         $last = $end;
 632                         next;
 633                 }
 634                 if ($start <= $last+1) {
 635                         if ($end > $last) {
 636                                 $last = $end;
 637                         }
 638                         next;
 639                 }
 640                 if ($first == $last) {
 641                         push @return, "$first";
 642                 } else {
 643                         push @return, "$first-$last";
 644                 }
 645                 $first = $start;
 646                 $last = $end;
 647         }
 648
 649         if ($first != -1) {
 650                 if ($first == $last) {
 651                         push @return, "$first";
 652                 } else {
 653                         push @return, "$first-$last";
 654                 }
 655         }
 656
 657         return join(',', @return);
 658 }
 659
 660 sub merge_revs_into_hash {
 661         my ($hash, $minfo) = @_;
 662         my @lines = split(' ', $minfo);
 663
 664         for my $line (@lines) {
 665                 my ($branchpath, $revs) = split(/:/, $line);
 666
 667                 if (exists($hash->{$branchpath})) {
 668                         # Merge the two revision sets
 669                         my $combined = "$hash->{$branchpath},$revs";
 670                         $hash->{$branchpath} = combine_ranges($combined);
 671                 } else {
 672                         # Just do range combining for consolidation
 673                         $hash->{$branchpath} = combine_ranges($revs);
 674                 }
 675         }
 676 }
 677
 678 sub merge_merge_info {
 679         my ($mergeinfo_one, $mergeinfo_two) = @_;
 680         my %result_hash = ();
 681
 682         merge_revs_into_hash(\%result_hash, $mergeinfo_one);
 683         merge_revs_into_hash(\%result_hash, $mergeinfo_two);
 684
 685         my $result = '';
 686         # Sort below is for consistency's sake
 687         for my $branchname (sort keys(%result_hash)) {
 688                 my $revlist = $result_hash{$branchname};
 689                 $result .= "$branchname:$revlist\n"
 690         }
 691         return $result;
 692 }
 693
 694 sub populate_merge_info {
 695         my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
 696
 697         my %parentshash;
 698         read_commit_parents(\%parentshash, $d);
 699         my @parents = @{$parentshash{$d}};
 700         if ($#parents > 0) {
 701                 # Merge commit
 702                 my $all_parents_ok = 1;
 703                 my $aggregate_mergeinfo = '';
 704                 my $rooturl = $gs->repos_root;
 705
 706                 if (defined($rewritten_parent)) {
 707                         # Replace first parent with newly-rewritten version
 708                         shift @parents;
 709                         unshift @parents, $rewritten_parent;
 710                 }
 711
 712                 foreach my $parent (@parents) {
 713                         my ($branchurl, $svnrev, $paruuid) =
 714                                 cmt_metadata($parent);
 715
 716                         unless (defined($svnrev)) {
 717                                 # Should have been caught be preflight check
 718                                 fatal "merge commit $d has ancestor $parent, but that change "
 719                      ."does not have git-svn metadata!";
 720                         }
 721                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 722                                 fatal "commit $parent git-svn metadata changed mid-run!";
 723                         }
 724                         my $branchpath = $1;
 725
 726                         my $ra = Git::SVN::Ra->new($branchurl);
 727                         my (undef, undef, $props) =
 728                                 $ra->get_dir(canonicalize_path("."), $svnrev);
 729                         my $par_mergeinfo = $props->{'svn:mergeinfo'};
 730                         unless (defined $par_mergeinfo) {
 731                                 $par_mergeinfo = '';
 732                         }
 733                         # Merge previous mergeinfo values
 734                         $aggregate_mergeinfo =
 735                                 merge_merge_info($aggregate_mergeinfo,
 736                                                                  $par_mergeinfo, 0);
 737
 738                         next if $parent eq $parents[0]; # Skip first parent
 739                         # Add new changes being placed in tree by merge
 740                         my @cmd = (qw/rev-list --reverse/,
 741                                            $parent, qw/--not/);
 742                         foreach my $par (@parents) {
 743                                 unless ($par eq $parent) {
 744                                         push @cmd, $par;
 745                                 }
 746                         }
 747                         my @revsin = ();
 748                         my ($revlist, $ctx) = command_output_pipe(@cmd);
 749                         while (<$revlist>) {
 750                                 my $irev = $_;
 751                                 chomp $irev;
 752                                 my (undef, $csvnrev, undef) =
 753                                         cmt_metadata($irev);
 754                                 unless (defined $csvnrev) {
 755                                         # A child is missing SVN annotations...
 756                                         # this might be OK, or might not be.
 757                                         warn "W:child $irev is merged into revision "
 758                                                  ."$d but does not have git-svn metadata. "
 759                                                  ."This means git-svn cannot determine the "
 760                                                  ."svn revision numbers to place into the "
 761                                                  ."svn:mergeinfo property. You must ensure "
 762                                                  ."a branch is entirely committed to "
 763                                                  ."SVN before merging it in order for "
 764                                                  ."svn:mergeinfo population to function "
 765                                                  ."properly";
 766                                 }
 767                                 push @revsin, $csvnrev;
 768                         }
 769                         command_close_pipe($revlist, $ctx);
 770
 771                         last unless $all_parents_ok;
 772
 773                         # We now have a list of all SVN revnos which are
 774                         # merged by this particular parent. Integrate them.
 775                         next if $#revsin == -1;
 776                         my $newmergeinfo = "$branchpath:" . join(',', @revsin);
 777                         $aggregate_mergeinfo =
 778                                 merge_merge_info($aggregate_mergeinfo,
 779                                                                  $newmergeinfo, 1);
 780                 }
 781                 if ($all_parents_ok and $aggregate_mergeinfo) {
 782                         return $aggregate_mergeinfo;
 783                 }
 784         }
 785
 786         return undef;
 787 }
 788
 789 sub dcommit_rebase {
 790         my ($is_last, $current, $fetched_ref, $svn_error) = @_;
 791         my @diff;
 792
 793         if ($svn_error) {
 794                 print STDERR "\nERROR from SVN:\n",
 795                                 $svn_error->expanded_message, "\n";
 796         }
 797         unless ($_no_rebase) {
 798                 # we always want to rebase against the current HEAD,
 799                 # not any head that was passed to us
 800                 @diff = command('diff-tree', $current,
 801                            $fetched_ref, '--');
 802                 my @finish;
 803                 if (@diff) {
 804                         @finish = rebase_cmd();
 805                         print STDERR "W: $current and ", $fetched_ref,
 806                                      " differ, using @finish:\n",
 807                                      join("\n", @diff), "\n";
 808                 } elsif ($is_last) {
 809                         print "No changes between ", $current, " and ",
 810                               $fetched_ref,
 811                               "\nResetting to the latest ",
 812                               $fetched_ref, "\n";
 813                         @finish = qw/reset --mixed/;
 814                 }
 815                 command_noisy(@finish, $fetched_ref) if @finish;
 816         }
 817         if ($svn_error) {
 818                 die "ERROR: Not all changes have been committed into SVN"
 819                         .($_no_rebase ? ".\n" : ", however the committed\n"
 820                         ."ones (if any) seem to be successfully integrated "
 821                         ."into the working tree.\n")
 822                         ."Please see the above messages for details.\n";
 823         }
 824         return @diff;
 825 }
 826
 827 sub cmd_dcommit {
 828         my $head = shift;
 829         command_noisy(qw/update-index --refresh/);
 830         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 831                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 832                 . "or stash them with `git stash'.\n";
 833         $head ||= 'HEAD';
 834
 835         my $old_head;
 836         if ($head ne 'HEAD') {
 837                 $old_head = eval {
 838                         command_oneline([qw/symbolic-ref -q HEAD/])
 839                 };
 840                 if ($old_head) {
 841                         $old_head =~ s{^refs/heads/}{};
 842                 } else {
 843                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 844                 }
 845                 command(['checkout', $head], STDERR => 0);
 846         }
 847
 848         my @refs;
 849         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 850         unless ($gs) {
 851                 die "Unable to determine upstream SVN information from ",
 852                     "$head history.\nPerhaps the repository is empty.";
 853         }
 854
 855         if (defined $_commit_url) {
 856                 $url = $_commit_url;
 857         } else {
 858                 $url = eval { command_oneline('config', '--get',
 859                               "svn-remote.$gs->{repo_id}.commiturl") };
 860                 if (!$url) {
 861                         $url = $gs->full_pushurl
 862                 }
 863         }
 864
 865         my $last_rev = $_revision if defined $_revision;
 866         if ($url) {
 867                 print "Committing to $url ...\n";
 868         }
 869         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 870         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 871                 warn "Attempting to commit more than one change while ",
 872                      "--no-rebase is enabled.\n",
 873                      "If these changes depend on each other, re-running ",
 874                      "without --no-rebase may be required."
 875         }
 876
 877         if (defined $_interactive){
 878                 my $ask_default = "y";
 879                 foreach my $d (@$linear_refs){
 880                         my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
 881                         while (<$fh>){
 882                                 print $_;
 883                         }
 884                         command_close_pipe($fh, $ctx);
 885                         $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
 886                                  valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 887                                  default => $ask_default);
 888                         die "Commit this patch reply required" unless defined $_;
 889                         if (/^[nq]/i) {
 890                                 exit(0);
 891                         } elsif (/^a/i) {
 892                                 last;
 893                         }
 894                 }
 895         }
 896
 897         my $expect_url = $url;
 898
 899         my $push_merge_info = eval {
 900                 command_oneline(qw/config --get svn.pushmergeinfo/)
 901                 };
 902         if (not defined($push_merge_info)
 903                         or $push_merge_info eq "false"
 904                         or $push_merge_info eq "no"
 905                         or $push_merge_info eq "never") {
 906                 $push_merge_info = 0;
 907         }
 908
 909         unless (defined($_merge_info) || ! $push_merge_info) {
 910                 # Preflight check of changes to ensure no issues with mergeinfo
 911                 # This includes check for uncommitted-to-SVN parents
 912                 # (other than the first parent, which we will handle),
 913                 # information from different SVN repos, and paths
 914                 # which are not underneath this repository root.
 915                 my $rooturl = $gs->repos_root;
 916                 foreach my $d (@$linear_refs) {
 917                         my %parentshash;
 918                         read_commit_parents(\%parentshash, $d);
 919                         my @realparents = @{$parentshash{$d}};
 920                         if ($#realparents > 0) {
 921                                 # Merge commit
 922                                 shift @realparents; # Remove/ignore first parent
 923                                 foreach my $parent (@realparents) {
 924                                         my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
 925                                         unless (defined $paruuid) {
 926                                                 # A parent is missing SVN annotations...
 927                                                 # abort the whole operation.
 928                                                 fatal "$parent is merged into revision $d, "
 929                                                          ."but does not have git-svn metadata. "
 930                                                          ."Either dcommit the branch or use a "
 931                                                          ."local cherry-pick, FF merge, or rebase "
 932                                                          ."instead of an explicit merge commit.";
 933                                         }
 934
 935                                         unless ($paruuid eq $uuid) {
 936                                                 # Parent has SVN metadata from different repository
 937                                                 fatal "merge parent $parent for change $d has "
 938                                                          ."git-svn uuid $paruuid, while current change "
 939                                                          ."has uuid $uuid!";
 940                                         }
 941
 942                                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 943                                                 # This branch is very strange indeed.
 944                                                 fatal "merge parent $parent for $d is on branch "
 945                                                          ."$branchurl, which is not under the "
 946                                                          ."git-svn root $rooturl!";
 947                                         }
 948                                 }
 949                         }
 950                 }
 951         }
 952
 953         my $rewritten_parent;
 954         my $current_head = command_oneline(qw/rev-parse HEAD/);
 955         Git::SVN::remove_username($expect_url);
 956         if (defined($_merge_info)) {
 957                 $_merge_info =~ tr{ }{\n};
 958         }
 959         while (1) {
 960                 my $d = shift @$linear_refs or last;
 961                 unless (defined $last_rev) {
 962                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 963                         unless (defined $last_rev) {
 964                                 fatal "Unable to extract revision information ",
 965                                       "from commit $d~1";
 966                         }
 967                 }
 968                 if ($_dry_run) {
 969                         print "diff-tree $d~1 $d\n";
 970                 } else {
 971                         my $cmt_rev;
 972
 973                         unless (defined($_merge_info) || ! $push_merge_info) {
 974                                 $_merge_info = populate_merge_info($d, $gs,
 975                                                              $uuid,
 976                                                              $linear_refs,
 977                                                              $rewritten_parent);
 978                         }
 979
 980                         my %ed_opts = ( r => $last_rev,
 981                                         log => get_commit_entry($d)->{log},
 982                                         ra => Git::SVN::Ra->new($url),
 983                                         config => SVN::Core::config_get_config(
 984                                                 $Git::SVN::Ra::config_dir
 985                                         ),
 986                                         tree_a => "$d~1",
 987                                         tree_b => $d,
 988                                         editor_cb => sub {
 989                                                print "Committed r$_[0]\n";
 990                                                $cmt_rev = $_[0];
 991                                         },
 992                                         mergeinfo => $_merge_info,
 993                                         svn_path => '');
 994
 995                         my $err_handler = $SVN::Error::handler;
 996                         $SVN::Error::handler = sub {
 997                                 my $err = shift;
 998                                 dcommit_rebase(1, $current_head, $gs->refname,
 999                                         $err);
1000                         };
1001
1002                         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1003                                 print "No changes\n$d~1 == $d\n";
1004                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
1005                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
1006                                                                $parents->{$d};
1007                         }
1008                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
1009                         $SVN::Error::handler = $err_handler;
1010                         $last_rev = $cmt_rev;
1011                         next if $_no_rebase;
1012
1013                         my @diff = dcommit_rebase(@$linear_refs == 0, $d,
1014                                                 $gs->refname, undef);
1015
1016                         $rewritten_parent = command_oneline(qw/rev-parse/,
1017                                                         $gs->refname);
1018
1019                         if (@diff) {
1020                                 $current_head = command_oneline(qw/rev-parse
1021                                                                 HEAD/);
1022                                 @refs = ();
1023                                 my ($url_, $rev_, $uuid_, $gs_) =
1024                                               working_head_info('HEAD', \@refs);
1025                                 my ($linear_refs_, $parents_) =
1026                                               linearize_history($gs_, \@refs);
1027                                 if (scalar(@$linear_refs) !=
1028                                     scalar(@$linear_refs_)) {
1029                                         fatal "# of revisions changed ",
1030                                           "\nbefore:\n",
1031                                           join("\n", @$linear_refs),
1032                                           "\n\nafter:\n",
1033                                           join("\n", @$linear_refs_), "\n",
1034                                           'If you are attempting to commit ',
1035                                           "merges, try running:\n\t",
1036                                           'git rebase --interactive',
1037                                           '--preserve-merges ',
1038                                           $gs->refname,
1039                                           "\nBefore dcommitting";
1040                                 }
1041                                 if ($url_ ne $expect_url) {
1042                                         if ($url_ eq $gs->metadata_url) {
1043                                                 print
1044                                                   "Accepting rewritten URL:",
1045                                                   " $url_\n";
1046                                         } else {
1047                                                 fatal
1048                                                   "URL mismatch after rebase:",
1049                                                   " $url_ != $expect_url";
1050                                         }
1051                                 }
1052                                 if ($uuid_ ne $uuid) {
1053                                         fatal "uuid mismatch after rebase: ",
1054                                               "$uuid_ != $uuid";
1055                                 }
1056                                 # remap parents
1057                                 my (%p, @l, $i);
1058                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
1059                                         my $new = $linear_refs_->[$i] or next;
1060                                         $p{$new} =
1061                                                 $parents->{$linear_refs->[$i]};
1062                                         push @l, $new;
1063                                 }
1064                                 $parents = \%p;
1065                                 $linear_refs = \@l;
1066                                 undef $last_rev;
1067                         }
1068                 }
1069         }
1070
1071         if ($old_head) {
1072                 my $new_head = command_oneline(qw/rev-parse HEAD/);
1073                 my $new_is_symbolic = eval {
1074                         command_oneline(qw/symbolic-ref -q HEAD/);
1075                 };
1076                 if ($new_is_symbolic) {
1077                         print "dcommitted the branch ", $head, "\n";
1078                 } else {
1079                         print "dcommitted on a detached HEAD because you gave ",
1080                               "a revision argument.\n",
1081                               "The rewritten commit is: ", $new_head, "\n";
1082                 }
1083                 command(['checkout', $old_head], STDERR => 0);
1084         }
1085
1086         unlink $gs->{index};
1087 }
1088
1089 sub cmd_branch {
1090         my ($branch_name, $head) = @_;
1091
1092         unless (defined $branch_name && length $branch_name) {
1093                 die(($_tag ? "tag" : "branch") . " name required\n");
1094         }
1095         $head ||= 'HEAD';
1096
1097         my (undef, $rev, undef, $gs) = working_head_info($head);
1098         my $src = $gs->full_pushurl;
1099
1100         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1101         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1102         my $glob;
1103         if ($#{$allglobs} == 0) {
1104                 $glob = $allglobs->[0];
1105         } else {
1106                 unless(defined $_branch_dest) {
1107                         die "Multiple ",
1108                             $_tag ? "tag" : "branch",
1109                             " paths defined for Subversion repository.\n",
1110                             "You must specify where you want to create the ",
1111                             $_tag ? "tag" : "branch",
1112                             " with the --destination argument.\n";
1113                 }
1114                 foreach my $g (@{$allglobs}) {
1115                         my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1116                         if ($_branch_dest =~ /$re/) {
1117                                 $glob = $g;
1118                                 last;
1119                         }
1120                 }
1121                 unless (defined $glob) {
1122                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1123                         foreach my $g (@{$allglobs}) {
1124                                 $g->{path}->{left} =~ /$dest_re/ or next;
1125                                 if (defined $glob) {
1126                                         die "Ambiguous destination: ",
1127                                             $_branch_dest, "\nmatches both '",
1128                                             $glob->{path}->{left}, "' and '",
1129                                             $g->{path}->{left}, "'\n";
1130                                 }
1131                                 $glob = $g;
1132                         }
1133                         unless (defined $glob) {
1134                                 die "Unknown ",
1135                                     $_tag ? "tag" : "branch",
1136                                     " destination $_branch_dest\n";
1137                         }
1138                 }
1139         }
1140         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1141         my $url;
1142         if (defined $_commit_url) {
1143                 $url = $_commit_url;
1144         } else {
1145                 $url = eval { command_oneline('config', '--get',
1146                         "svn-remote.$gs->{repo_id}.commiturl") };
1147                 if (!$url) {
1148                         $url = $remote->{pushurl} || $remote->{url};
1149                 }
1150         }
1151         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1152
1153         if ($dst =~ /^https:/ && $src =~ /^http:/) {
1154                 $src=~s/^http:/https:/;
1155         }
1156
1157         ::_req_svn();
1158
1159         my $ctx = SVN::Client->new(
1160                 auth    => Git::SVN::Ra::_auth_providers(),
1161                 log_msg => sub {
1162                         ${ $_[0] } = defined $_message
1163                                 ? $_message
1164                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1165                                 . $branch_name;
1166                 },
1167         );
1168
1169         eval {
1170                 $ctx->ls($dst, 'HEAD', 0);
1171         } and die "branch ${branch_name} already exists\n";
1172
1173         print "Copying ${src} at r${rev} to ${dst}...\n";
1174         $ctx->copy($src, $rev, $dst)
1175                 unless $_dry_run;
1176
1177         $gs->fetch_all;
1178 }
1179
1180 sub cmd_find_rev {
1181         my $revision_or_hash = shift or die "SVN or git revision required ",
1182                                             "as a command-line argument\n";
1183         my $result;
1184         if ($revision_or_hash =~ /^r\d+$/) {
1185                 my $head = shift;
1186                 $head ||= 'HEAD';
1187                 my @refs;
1188                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1189                 unless ($gs) {
1190                         die "Unable to determine upstream SVN information from ",
1191                             "$head history\n";
1192                 }
1193                 my $desired_revision = substr($revision_or_hash, 1);
1194                 $result = $gs->rev_map_get($desired_revision, $uuid);
1195         } else {
1196                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1197                 $result = $rev;
1198         }
1199         print "$result\n" if $result;
1200 }
1201
1202 sub auto_create_empty_directories {
1203         my ($gs) = @_;
1204         my $var = eval { command_oneline('config', '--get', '--bool',
1205                                          "svn-remote.$gs->{repo_id}.automkdirs") };
1206         # By default, create empty directories by consulting the unhandled log,
1207         # but allow setting it to 'false' to skip it.
1208         return !($var && $var eq 'false');
1209 }
1210
1211 sub cmd_rebase {
1212         command_noisy(qw/update-index --refresh/);
1213         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1214         unless ($gs) {
1215                 die "Unable to determine upstream SVN information from ",
1216                     "working tree history\n";
1217         }
1218         if ($_dry_run) {
1219                 print "Remote Branch: " . $gs->refname . "\n";
1220                 print "SVN URL: " . $url . "\n";
1221                 return;
1222         }
1223         if (command(qw/diff-index HEAD --/)) {
1224                 print STDERR "Cannot rebase with uncommited changes:\n";
1225                 command_noisy('status');
1226                 exit 1;
1227         }
1228         unless ($_local) {
1229                 # rebase will checkout for us, so no need to do it explicitly
1230                 $_no_checkout = 'true';
1231                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1232         }
1233         command_noisy(rebase_cmd(), $gs->refname);
1234         if (auto_create_empty_directories($gs)) {
1235                 $gs->mkemptydirs;
1236         }
1237 }
1238
1239 sub cmd_show_ignore {
1240         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1241         $gs ||= Git::SVN->new;
1242         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1243         $gs->prop_walk($gs->path, $r, sub {
1244                 my ($gs, $path, $props) = @_;
1245                 print STDOUT "\n# $path\n";
1246                 my $s = $props->{'svn:ignore'} or return;
1247                 $s =~ s/[\r\n]+/\n/g;
1248                 $s =~ s/^\n+//;
1249                 chomp $s;
1250                 $s =~ s#^#$path#gm;
1251                 print STDOUT "$s\n";
1252         });
1253 }
1254
1255 sub cmd_show_externals {
1256         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1257         $gs ||= Git::SVN->new;
1258         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1259         $gs->prop_walk($gs->path, $r, sub {
1260                 my ($gs, $path, $props) = @_;
1261                 print STDOUT "\n# $path\n";
1262                 my $s = $props->{'svn:externals'} or return;
1263                 $s =~ s/[\r\n]+/\n/g;
1264                 chomp $s;
1265                 $s =~ s#^#$path#gm;
1266                 print STDOUT "$s\n";
1267         });
1268 }
1269
1270 sub cmd_create_ignore {
1271         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1272         $gs ||= Git::SVN->new;
1273         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1274         $gs->prop_walk($gs->path, $r, sub {
1275                 my ($gs, $path, $props) = @_;
1276                 # $path is of the form /path/to/dir/
1277                 $path = '.' . $path;
1278                 # SVN can have attributes on empty directories,
1279                 # which git won't track
1280                 mkpath([$path]) unless -d $path;
1281                 my $ignore = $path . '.gitignore';
1282                 my $s = $props->{'svn:ignore'} or return;
1283                 open(GITIGNORE, '>', $ignore)
1284                   or fatal("Failed to open `$ignore' for writing: $!");
1285                 $s =~ s/[\r\n]+/\n/g;
1286                 $s =~ s/^\n+//;
1287                 chomp $s;
1288                 # Prefix all patterns so that the ignore doesn't apply
1289                 # to sub-directories.
1290                 $s =~ s#^#/#gm;
1291                 print GITIGNORE "$s\n";
1292                 close(GITIGNORE)
1293                   or fatal("Failed to close `$ignore': $!");
1294                 command_noisy('add', '-f', $ignore);
1295         });
1296 }
1297
1298 sub cmd_mkdirs {
1299         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1300         $gs ||= Git::SVN->new;
1301         $gs->mkemptydirs($_revision);
1302 }
1303
1304 # get_svnprops(PATH)
1305 # ------------------
1306 # Helper for cmd_propget and cmd_proplist below.
1307 sub get_svnprops {
1308         my $path = shift;
1309         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1310         $gs ||= Git::SVN->new;
1311
1312         # prefix THE PATH by the sub-directory from which the user
1313         # invoked us.
1314         $path = $cmd_dir_prefix . $path;
1315         fatal("No such file or directory: $path") unless -e $path;
1316         my $is_dir = -d $path ? 1 : 0;
1317         $path = join_paths($gs->path, $path);
1318
1319         # canonicalize the path (otherwise libsvn will abort or fail to
1320         # find the file)
1321         $path = canonicalize_path($path);
1322
1323         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1324         my $props;
1325         if ($is_dir) {
1326                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1327         }
1328         else {
1329                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1330         }
1331         return $props;
1332 }
1333
1334 # cmd_propget (PROP, PATH)
1335 # ------------------------
1336 # Print the SVN property PROP for PATH.
1337 sub cmd_propget {
1338         my ($prop, $path) = @_;
1339         $path = '.' if not defined $path;
1340         usage(1) if not defined $prop;
1341         my $props = get_svnprops($path);
1342         if (not defined $props->{$prop}) {
1343                 fatal("`$path' does not have a `$prop' SVN property.");
1344         }
1345         print $props->{$prop} . "\n";
1346 }
1347
1348 # cmd_proplist (PATH)
1349 # -------------------
1350 # Print the list of SVN properties for PATH.
1351 sub cmd_proplist {
1352         my $path = shift;
1353         $path = '.' if not defined $path;
1354         my $props = get_svnprops($path);
1355         print "Properties on '$path':\n";
1356         foreach (sort keys %{$props}) {
1357                 print "  $_\n";
1358         }
1359 }
1360
1361 sub cmd_multi_init {
1362         my $url = shift;
1363         unless (defined $_trunk || @_branches || @_tags) {
1364                 usage(1);
1365         }
1366
1367         $_prefix = '' unless defined $_prefix;
1368         if (defined $url) {
1369                 $url = canonicalize_url($url);
1370                 init_subdir(@_);
1371         }
1372         do_git_init_db();
1373         if (defined $_trunk) {
1374                 $_trunk =~ s#^/+##;
1375                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1376                 # try both old-style and new-style lookups:
1377                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1378                 unless ($gs_trunk) {
1379                         my ($trunk_url, $trunk_path) =
1380                                               complete_svn_url($url, $_trunk);
1381                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1382                                                    undef, $trunk_ref);
1383                 }
1384         }
1385         return unless @_branches || @_tags;
1386         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1387         foreach my $path (@_branches) {
1388                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1389         }
1390         foreach my $path (@_tags) {
1391                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1392         }
1393 }
1394
1395 sub cmd_multi_fetch {
1396         $Git::SVN::no_reuse_existing = undef;
1397         my $remotes = Git::SVN::read_all_remotes();
1398         foreach my $repo_id (sort keys %$remotes) {
1399                 if ($remotes->{$repo_id}->{url}) {
1400                         Git::SVN::fetch_all($repo_id, $remotes);
1401                 }
1402         }
1403 }
1404
1405 # this command is special because it requires no metadata
1406 sub cmd_commit_diff {
1407         my ($ta, $tb, $url) = @_;
1408         my $usage = "Usage: $0 commit-diff -r<revision> ".
1409                     "<tree-ish> <tree-ish> [<URL>]";
1410         fatal($usage) if (!defined $ta || !defined $tb);
1411         my $svn_path = '';
1412         if (!defined $url) {
1413                 my $gs = eval { Git::SVN->new };
1414                 if (!$gs) {
1415                         fatal("Needed URL or usable git-svn --id in ",
1416                               "the command-line\n", $usage);
1417                 }
1418                 $url = $gs->url;
1419                 $svn_path = $gs->path;
1420         }
1421         unless (defined $_revision) {
1422                 fatal("-r|--revision is a required argument\n", $usage);
1423         }
1424         if (defined $_message && defined $_file) {
1425                 fatal("Both --message/-m and --file/-F specified ",
1426                       "for the commit message.\n",
1427                       "I have no idea what you mean");
1428         }
1429         if (defined $_file) {
1430                 $_message = file_to_s($_file);
1431         } else {
1432                 $_message ||= get_commit_entry($tb)->{log};
1433         }
1434         my $ra ||= Git::SVN::Ra->new($url);
1435         my $r = $_revision;
1436         if ($r eq 'HEAD') {
1437                 $r = $ra->get_latest_revnum;
1438         } elsif ($r !~ /^\d+$/) {
1439                 die "revision argument: $r not understood by git-svn\n";
1440         }
1441         my %ed_opts = ( r => $r,
1442                         log => $_message,
1443                         ra => $ra,
1444                         tree_a => $ta,
1445                         tree_b => $tb,
1446                         editor_cb => sub { print "Committed r$_[0]\n" },
1447                         svn_path => $svn_path );
1448         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1449                 print "No changes\n$ta == $tb\n";
1450         }
1451 }
1452
1453
1454 sub cmd_info {
1455         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1456         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1457         if (exists $_[1]) {
1458                 die "Too many arguments specified\n";
1459         }
1460
1461         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1462
1463         if (!$file_type && !$diff_status) {
1464                 print STDERR "svn: '$path' is not under version control\n";
1465                 exit 1;
1466         }
1467
1468         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1469         unless ($gs) {
1470                 die "Unable to determine upstream SVN information from ",
1471                     "working tree history\n";
1472         }
1473
1474         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1475         $path = "." if $path eq "";
1476
1477         my $full_url = canonicalize_url( add_path_to_url( $url, $fullpath ) );
1478
1479         if ($_url) {
1480                 print "$full_url\n";
1481                 return;
1482         }
1483
1484         my $result = "Path: $path\n";
1485         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1486         $result .= "URL: $full_url\n";
1487
1488         eval {
1489                 my $repos_root = $gs->repos_root;
1490                 Git::SVN::remove_username($repos_root);
1491                 $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n";
1492         };
1493         if ($@) {
1494                 $result .= "Repository Root: (offline)\n";
1495         }
1496         ::_req_svn();
1497         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1498                 (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1499         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1500
1501         $result .= "Node Kind: " .
1502                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1503
1504         my $schedule = $diff_status eq "A"
1505                        ? "add"
1506                        : ($diff_status eq "D" ? "delete" : "normal");
1507         $result .= "Schedule: $schedule\n";
1508
1509         if ($diff_status eq "A") {
1510                 print $result, "\n";
1511                 return;
1512         }
1513
1514         my ($lc_author, $lc_rev, $lc_date_utc);
1515         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1516         my $log = command_output_pipe(@args);
1517         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1518         while (<$log>) {
1519                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1520                         $lc_author = $1;
1521                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1522                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1523                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1524                 }
1525         }
1526         close $log;
1527
1528         Git::SVN::Log::set_local_timezone();
1529
1530         $result .= "Last Changed Author: $lc_author\n";
1531         $result .= "Last Changed Rev: $lc_rev\n";
1532         $result .= "Last Changed Date: " .
1533                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1534
1535         if ($file_type ne "dir") {
1536                 my $text_last_updated_date =
1537                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1538                 $result .=
1539                     "Text Last Updated: " .
1540                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1541                     "\n";
1542                 my $checksum;
1543                 if ($diff_status eq "D") {
1544                         my ($fh, $ctx) =
1545                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1546                         if ($file_type eq "link") {
1547                                 my $file_name = <$fh>;
1548                                 $checksum = md5sum("link $file_name");
1549                         } else {
1550                                 $checksum = md5sum($fh);
1551                         }
1552                         command_close_pipe($fh, $ctx);
1553                 } elsif ($file_type eq "link") {
1554                         my $file_name =
1555                             command(qw(cat-file blob), "HEAD:$path");
1556                         $checksum =
1557                             md5sum("link " . $file_name);
1558                 } else {
1559                         open FILE, "<", $path or die $!;
1560                         $checksum = md5sum(\*FILE);
1561                         close FILE or die $!;
1562                 }
1563                 $result .= "Checksum: " . $checksum . "\n";
1564         }
1565
1566         print $result, "\n";
1567 }
1568
1569 sub cmd_reset {
1570         my $target = shift || $_revision or die "SVN revision required\n";
1571         $target = $1 if $target =~ /^r(\d+)$/;
1572         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1573         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1574         unless ($gs) {
1575                 die "Unable to determine upstream SVN information from ".
1576                     "history\n";
1577         }
1578         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1579         die "Cannot find SVN revision $target\n" unless defined($c);
1580         $gs->rev_map_set($r, $c, 'reset', $uuid);
1581         print "r$r = $c ($gs->{ref_id})\n";
1582 }
1583
1584 sub cmd_gc {
1585         if (!can_compress()) {
1586                 warn "Compress::Zlib could not be found; unhandled.log " .
1587                      "files will not be compressed.\n";
1588         }
1589         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1590 }
1591
1592 ########################### utility functions #########################
1593
1594 sub rebase_cmd {
1595         my @cmd = qw/rebase/;
1596         push @cmd, '-v' if $_verbose;
1597         push @cmd, qw/--merge/ if $_merge;
1598         push @cmd, "--strategy=$_strategy" if $_strategy;
1599         push @cmd, "--preserve-merges" if $_preserve_merges;
1600         @cmd;
1601 }
1602
1603 sub post_fetch_checkout {
1604         return if $_no_checkout;
1605         return if verify_ref('HEAD^0');
1606         my $gs = $Git::SVN::_head or return;
1607
1608         # look for "trunk" ref if it exists
1609         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1610         my $fetch = $remote->{fetch};
1611         if ($fetch) {
1612                 foreach my $p (keys %$fetch) {
1613                         basename($fetch->{$p}) eq 'trunk' or next;
1614                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1615                         last;
1616                 }
1617         }
1618
1619         command_noisy(qw(update-ref HEAD), $gs->refname);
1620         return unless verify_ref('HEAD^0');
1621
1622         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1623         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1624         return if -f $index;
1625
1626         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1627         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1628         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1629         print STDERR "Checked out HEAD:\n  ",
1630                      $gs->full_url, " r", $gs->last_rev, "\n";
1631         if (auto_create_empty_directories($gs)) {
1632                 $gs->mkemptydirs($gs->last_rev);
1633         }
1634 }
1635
1636 sub complete_svn_url {
1637         my ($url, $path) = @_;
1638         $path = canonicalize_path($path);
1639
1640         # If the path is not a URL...
1641         if ($path !~ m#^[a-z\+]+://#) {
1642                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1643                         fatal("E: '$path' is not a complete URL ",
1644                               "and a separate URL is not specified");
1645                 }
1646                 return ($url, $path);
1647         }
1648         return ($path, '');
1649 }
1650
1651 sub complete_url_ls_init {
1652         my ($ra, $repo_path, $switch, $pfx) = @_;
1653         unless ($repo_path) {
1654                 print STDERR "W: $switch not specified\n";
1655                 return;
1656         }
1657         $repo_path = canonicalize_path($repo_path);
1658         if ($repo_path =~ m#^[a-z\+]+://#) {
1659                 $ra = Git::SVN::Ra->new($repo_path);
1660                 $repo_path = '';
1661         } else {
1662                 $repo_path =~ s#^/+##;
1663                 unless ($ra) {
1664                         fatal("E: '$repo_path' is not a complete URL ",
1665                               "and a separate URL is not specified");
1666                 }
1667         }
1668         my $url = $ra->url;
1669         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1670         my $k = "svn-remote.$gs->{repo_id}.url";
1671         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1672         if ($orig_url && ($orig_url ne $gs->url)) {
1673                 die "$k already set: $orig_url\n",
1674                     "wanted to set to: $gs->url\n";
1675         }
1676         command_oneline('config', $k, $gs->url) unless $orig_url;
1677
1678         my $remote_path = join_paths( $gs->path, $repo_path );
1679         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1680         $remote_path =~ s#^/##g;
1681         $remote_path .= "/*" if $remote_path !~ /\*/;
1682         my ($n) = ($switch =~ /^--(\w+)/);
1683         if (length $pfx && $pfx !~ m#/$#) {
1684                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1685         }
1686         command_noisy('config',
1687                       '--add',
1688                       "svn-remote.$gs->{repo_id}.$n",
1689                       "$remote_path:refs/remotes/$pfx*" .
1690                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1691 }
1692
1693 sub verify_ref {
1694         my ($ref) = @_;
1695         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1696                                { STDERR => 0 }); };
1697 }
1698
1699 sub get_tree_from_treeish {
1700         my ($treeish) = @_;
1701         # $treeish can be a symbolic ref, too:
1702         my $type = command_oneline(qw/cat-file -t/, $treeish);
1703         my $expected;
1704         while ($type eq 'tag') {
1705                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1706         }
1707         if ($type eq 'commit') {
1708                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1709                                                     $treeish))[0];
1710                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1711                 die "Unable to get tree from $treeish\n" unless $expected;
1712         } elsif ($type eq 'tree') {
1713                 $expected = $treeish;
1714         } else {
1715                 die "$treeish is a $type, expected tree, tag or commit\n";
1716         }
1717         return $expected;
1718 }
1719
1720 sub get_commit_entry {
1721         my ($treeish) = shift;
1722         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1723         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1724         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1725         open my $log_fh, '>', $commit_editmsg or croak $!;
1726
1727         my $type = command_oneline(qw/cat-file -t/, $treeish);
1728         if ($type eq 'commit' || $type eq 'tag') {
1729                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1730                                                          $type, $treeish);
1731                 my $in_msg = 0;
1732                 my $author;
1733                 my $saw_from = 0;
1734                 my $msgbuf = "";
1735                 while (<$msg_fh>) {
1736                         if (!$in_msg) {
1737                                 $in_msg = 1 if (/^\s*$/);
1738                                 $author = $1 if (/^author (.*>)/);
1739                         } elsif (/^git-svn-id: /) {
1740                                 # skip this for now, we regenerate the
1741                                 # correct one on re-fetch anyways
1742                                 # TODO: set *:merge properties or like...
1743                         } else {
1744                                 if (/^From:/ || /^Signed-off-by:/) {
1745                                         $saw_from = 1;
1746                                 }
1747                                 $msgbuf .= $_;
1748                         }
1749                 }
1750                 $msgbuf =~ s/\s+$//s;
1751                 if ($Git::SVN::_add_author_from && defined($author)
1752                     && !$saw_from) {
1753                         $msgbuf .= "\n\nFrom: $author";
1754                 }
1755                 print $log_fh $msgbuf or croak $!;
1756                 command_close_pipe($msg_fh, $ctx);
1757         }
1758         close $log_fh or croak $!;
1759
1760         if ($_edit || ($type eq 'tree')) {
1761                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1762                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1763         }
1764         rename $commit_editmsg, $commit_msg or croak $!;
1765         {
1766                 require Encode;
1767                 # SVN requires messages to be UTF-8 when entering the repo
1768                 local $/;
1769                 open $log_fh, '<', $commit_msg or croak $!;
1770                 binmode $log_fh;
1771                 chomp($log_entry{log} = <$log_fh>);
1772
1773                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1774                 my $msg = $log_entry{log};
1775
1776                 eval { $msg = Encode::decode($enc, $msg, 1) };
1777                 if ($@) {
1778                         die "Could not decode as $enc:\n", $msg,
1779                             "\nPerhaps you need to set i18n.commitencoding\n";
1780                 }
1781
1782                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1783                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1784
1785                 $log_entry{log} = $msg;
1786
1787                 close $log_fh or croak $!;
1788         }
1789         unlink $commit_msg;
1790         \%log_entry;
1791 }
1792
1793 sub s_to_file {
1794         my ($str, $file, $mode) = @_;
1795         open my $fd,'>',$file or croak $!;
1796         print $fd $str,"\n" or croak $!;
1797         close $fd or croak $!;
1798         chmod ($mode &~ umask, $file) if (defined $mode);
1799 }
1800
1801 sub file_to_s {
1802         my $file = shift;
1803         open my $fd,'<',$file or croak "$!: file: $file\n";
1804         local $/;
1805         my $ret = <$fd>;
1806         close $fd or croak $!;
1807         $ret =~ s/\s*$//s;
1808         return $ret;
1809 }
1810
1811 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1812 sub load_authors {
1813         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1814         my $log = $cmd eq 'log';
1815         while (<$authors>) {
1816                 chomp;
1817                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1818                 my ($user, $name, $email) = ($1, $2, $3);
1819                 if ($log) {
1820                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1821                 } else {
1822                         $users{$user} = [$name, $email];
1823                 }
1824         }
1825         close $authors or croak $!;
1826 }
1827
1828 # convert GetOpt::Long specs for use by git-config
1829 sub read_git_config {
1830         my $opts = shift;
1831         my @config_only;
1832         foreach my $o (keys %$opts) {
1833                 # if we have mixedCase and a long option-only, then
1834                 # it's a config-only variable that we don't need for
1835                 # the command-line.
1836                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1837                 my $v = $opts->{$o};
1838                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1839                 $key =~ s/-//g;
1840                 my $arg = 'git config';
1841                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1842                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1843                 if (ref $v eq 'ARRAY') {
1844                         chomp(my @tmp = `$arg --get-all svn.$key`);
1845                         @$v = @tmp if @tmp;
1846                 } else {
1847                         chomp(my $tmp = `$arg --get svn.$key`);
1848                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1849                                 $$v = $tmp;
1850                         }
1851                 }
1852         }
1853         delete @$opts{@config_only} if @config_only;
1854 }
1855
1856 sub extract_metadata {
1857         my $id = shift or return (undef, undef, undef);
1858         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1859                                                         \s([a-f\d\-]+)$/ix);
1860         if (!defined $rev || !$uuid || !$url) {
1861                 # some of the original repositories I made had
1862                 # identifiers like this:
1863                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1864         }
1865         return ($url, $rev, $uuid);
1866 }
1867
1868 sub cmt_metadata {
1869         return extract_metadata((grep(/^git-svn-id: /,
1870                 command(qw/cat-file commit/, shift)))[-1]);
1871 }
1872
1873 sub cmt_sha2rev_batch {
1874         my %s2r;
1875         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1876         my $list = shift;
1877
1878         foreach my $sha (@{$list}) {
1879                 my $first = 1;
1880                 my $size = 0;
1881                 print $out $sha, "\n";
1882
1883                 while (my $line = <$in>) {
1884                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1885                                 last;
1886                         } elsif ($first &&
1887                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1888                                 $first = 0;
1889                                 $size = $1;
1890                                 next;
1891                         } elsif ($line =~ /^(git-svn-id: )/) {
1892                                 my (undef, $rev, undef) =
1893                                                       extract_metadata($line);
1894                                 $s2r{$sha} = $rev;
1895                         }
1896
1897                         $size -= length($line);
1898                         last if ($size == 0);
1899                 }
1900         }
1901
1902         command_close_bidi_pipe($pid, $in, $out, $ctx);
1903
1904         return \%s2r;
1905 }
1906
1907 sub working_head_info {
1908         my ($head, $refs) = @_;
1909         my @args = qw/rev-list --first-parent --pretty=medium/;
1910         my ($fh, $ctx) = command_output_pipe(@args, $head);
1911         my $hash;
1912         my %max;
1913         while (<$fh>) {
1914                 if ( m{^commit ($::sha1)$} ) {
1915                         unshift @$refs, $hash if $hash and $refs;
1916                         $hash = $1;
1917                         next;
1918                 }
1919                 next unless s{^\s*(git-svn-id:)}{$1};
1920                 my ($url, $rev, $uuid) = extract_metadata($_);
1921                 if (defined $url && defined $rev) {
1922                         next if $max{$url} and $max{$url} < $rev;
1923                         if (my $gs = Git::SVN->find_by_url($url)) {
1924                                 my $c = $gs->rev_map_get($rev, $uuid);
1925                                 if ($c && $c eq $hash) {
1926                                         close $fh; # break the pipe
1927                                         return ($url, $rev, $uuid, $gs);
1928                                 } else {
1929                                         $max{$url} ||= $gs->rev_map_max;
1930                                 }
1931                         }
1932                 }
1933         }
1934         command_close_pipe($fh, $ctx);
1935         (undef, undef, undef, undef);
1936 }
1937
1938 sub read_commit_parents {
1939         my ($parents, $c) = @_;
1940         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1941         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1942         @{$parents->{$c}} = split(/ /, $p);
1943 }
1944
1945 sub linearize_history {
1946         my ($gs, $refs) = @_;
1947         my %parents;
1948         foreach my $c (@$refs) {
1949                 read_commit_parents(\%parents, $c);
1950         }
1951
1952         my @linear_refs;
1953         my %skip = ();
1954         my $last_svn_commit = $gs->last_commit;
1955         foreach my $c (reverse @$refs) {
1956                 next if $c eq $last_svn_commit;
1957                 last if $skip{$c};
1958
1959                 unshift @linear_refs, $c;
1960                 $skip{$c} = 1;
1961
1962                 # we only want the first parent to diff against for linear
1963                 # history, we save the rest to inject when we finalize the
1964                 # svn commit
1965                 my $fp_a = verify_ref("$c~1");
1966                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1967                 if (!$fp_a || !$fp_b) {
1968                         die "Commit $c\n",
1969                             "has no parent commit, and therefore ",
1970                             "nothing to diff against.\n",
1971                             "You should be working from a repository ",
1972                             "originally created by git-svn\n";
1973                 }
1974                 if ($fp_a ne $fp_b) {
1975                         die "$c~1 = $fp_a, however parsing commit $c ",
1976                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1977                 }
1978
1979                 foreach my $p (@{$parents{$c}}) {
1980                         $skip{$p} = 1;
1981                 }
1982         }
1983         (\@linear_refs, \%parents);
1984 }
1985
1986 sub find_file_type_and_diff_status {
1987         my ($path) = @_;
1988         return ('dir', '') if $path eq '';
1989
1990         my $diff_output =
1991             command_oneline(qw(diff --cached --name-status --), $path) || "";
1992         my $diff_status = (split(' ', $diff_output))[0] || "";
1993
1994         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1995
1996         return (undef, undef) if !$diff_status && !$ls_tree;
1997
1998         if ($diff_status eq "A") {
1999                 return ("link", $diff_status) if -l $path;
2000                 return ("dir", $diff_status) if -d $path;
2001                 return ("file", $diff_status);
2002         }
2003
2004         my $mode = (split(' ', $ls_tree))[0] || "";
2005
2006         return ("link", $diff_status) if $mode eq "120000";
2007         return ("dir", $diff_status) if $mode eq "040000";
2008         return ("file", $diff_status);
2009 }
2010
2011 sub md5sum {
2012         my $arg = shift;
2013         my $ref = ref $arg;
2014         my $md5 = Digest::MD5->new();
2015         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
2016                 $md5->addfile($arg) or croak $!;
2017         } elsif ($ref eq 'SCALAR') {
2018                 $md5->add($$arg) or croak $!;
2019         } elsif (!$ref) {
2020                 $md5->add($arg) or croak $!;
2021         } else {
2022                 fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
2023         }
2024         return $md5->hexdigest();
2025 }
2026
2027 sub gc_directory {
2028         if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
2029                 my $out_filename = $_ . ".gz";
2030                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2031                 binmode $in_fh;
2032                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2033                                 die "Unable to open $out_filename: $!\n";
2034
2035                 my $res;
2036                 while ($res = sysread($in_fh, my $str, 1024)) {
2037                         $gz->gzwrite($str) or
2038                                 die "Unable to write: ".$gz->gzerror()."!\n";
2039                 }
2040                 unlink $_ or die "unlink $File::Find::name: $!\n";
2041         } elsif (-f $_ && basename($_) eq "index") {
2042                 unlink $_ or die "unlink $_: $!\n";
2043         }
2044 }
2045
2046 __END__
2047
2048 Data structures:
2049
2050
2051 $remotes = { # returned by read_all_remotes()
2052         'svn' => {
2053                 # svn-remote.svn.url=https://svn.musicpd.org
2054                 url => 'https://svn.musicpd.org',
2055                 # svn-remote.svn.fetch=mpd/trunk:trunk
2056                 fetch => {
2057                         'mpd/trunk' => 'trunk',
2058                 },
2059                 # svn-remote.svn.tags=mpd/tags/*:tags/*
2060                 tags => {
2061                         path => {
2062                                 left => 'mpd/tags',
2063                                 right => '',
2064                                 regex => qr!mpd/tags/([^/]+)$!,
2065                                 glob => 'tags/*',
2066                         },
2067                         ref => {
2068                                 left => 'tags',
2069                                 right => '',
2070                                 regex => qr!tags/([^/]+)$!,
2071                                 glob => 'tags/*',
2072                         },
2073                 }
2074         }
2075 };
2076
2077 $log_entry hashref as returned by libsvn_log_entry()
2078 {
2079         log => 'whitespace-formatted log entry
2080 ',                                              # trailing newline is preserved
2081         revision => '8',                        # integer
2082         date => '2004-02-24T17:01:44.108345Z',  # commit date
2083         author => 'committer name'
2084 };
2085
2086
2087 # this is generated by generate_diff();
2088 @mods = array of diff-index line hashes, each element represents one line
2089         of diff-index output
2090
2091 diff-index line ($m hash)
2092 {
2093         mode_a => first column of diff-index output, no leading ':',
2094         mode_b => second column of diff-index output,
2095         sha1_b => sha1sum of the final blob,
2096         chg => change type [MCRADT],
2097         file_a => original file name of a file (iff chg is 'C' or 'R')
2098         file_b => new/current file name of a file (any chg)
2099 }
2100 ;
2101
2102 # retval of read_url_paths{,_all}();
2103 $l_map = {
2104         # repository root url
2105         'https://svn.musicpd.org' => {
2106                 # repository path               # GIT_SVN_ID
2107                 'mpd/trunk'             =>      'trunk',
2108                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2109         },
2110 }
2111
2112 Notes:
2113         I don't trust the each() function on unless I created %hash myself
2114         because the internal iterator may not have started at base.