git-cvsimport.perl

   1 #!/usr/bin/perl -w
   2
   3 # This tool is copyright (c) 2005, Matthias Urlichs.
   4 # It is released under the Gnu Public License, version 2.
   5 #
   6 # The basic idea is to aggregate CVS check-ins into related changes.
   7 # Fortunately, "cvsps" does that for us; all we have to do is to parse
   8 # its output.
   9 #
  10 # Checking out the files is done by a single long-running CVS connection
  11 # / server process.
  12 #
  13 # The head revision is on branch "origin" by default.
  14 # You can change that with the '-o' option.
  15
  16 use strict;
  17 use warnings;
  18 use Getopt::Std;
  19 use File::Spec;
  20 use File::Temp qw(tempfile);
  21 use File::Path qw(mkpath);
  22 use File::Basename qw(basename dirname);
  23 use Time::Local;
  24 use IO::Socket;
  25 use IO::Pipe;
  26 use POSIX qw(strftime dup2);
  27 use IPC::Open2;
  28
  29 $SIG{'PIPE'}="IGNORE";
  30 $ENV{'TZ'}="UTC";
  31
  32 our($opt_h,$opt_o,$opt_v,$opt_k,$opt_u,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i,$opt_P, $opt_s,$opt_m,$opt_M);
  33
  34 sub usage() {
  35         print STDERR <<END;
  36 Usage: ${\basename $0}     # fetch/update GIT from CVS
  37        [-o branch-for-HEAD] [-h] [-v] [-d CVSROOT]
  38        [-p opts-for-cvsps] [-C GIT_repository] [-z fuzz]
  39        [-i] [-k] [-u] [-s subst] [-m] [-M regex] [CVS_module]
  40 END
  41         exit(1);
  42 }
  43
  44 getopts("hivmkuo:d:p:C:z:s:M:P:") or usage();
  45 usage if $opt_h;
  46
  47 @ARGV <= 1 or usage();
  48
  49 if($opt_d) {
  50         $ENV{"CVSROOT"} = $opt_d;
  51 } elsif(-f 'CVS/Root') {
  52         open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
  53         $opt_d = <$f>;
  54         chomp $opt_d;
  55         close $f;
  56         $ENV{"CVSROOT"} = $opt_d;
  57 } elsif($ENV{"CVSROOT"}) {
  58         $opt_d = $ENV{"CVSROOT"};
  59 } else {
  60         die "CVSROOT needs to be set";
  61 }
  62 $opt_o ||= "origin";
  63 $opt_s ||= "-";
  64 my $git_tree = $opt_C;
  65 $git_tree ||= ".";
  66
  67 my $cvs_tree;
  68 if ($#ARGV == 0) {
  69         $cvs_tree = $ARGV[0];
  70 } elsif (-f 'CVS/Repository') {
  71         open my $f, '<', 'CVS/Repository' or
  72             die 'Failed to open CVS/Repository';
  73         $cvs_tree = <$f>;
  74         chomp $cvs_tree;
  75         close $f;
  76 } else {
  77         usage();
  78 }
  79
  80 our @mergerx = ();
  81 if ($opt_m) {
  82         @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
  83 }
  84 if ($opt_M) {
  85         push (@mergerx, qr/$opt_M/);
  86 }
  87
  88 select(STDERR); $|=1; select(STDOUT);
  89
  90
  91 package CVSconn;
  92 # Basic CVS dialog.
  93 # We're only interested in connecting and downloading, so ...
  94
  95 use File::Spec;
  96 use File::Temp qw(tempfile);
  97 use POSIX qw(strftime dup2);
  98
  99 sub new {
 100         my($what,$repo,$subdir) = @_;
 101         $what=ref($what) if ref($what);
 102
 103         my $self = {};
 104         $self->{'buffer'} = "";
 105         bless($self,$what);
 106
 107         $repo =~ s#/+$##;
 108         $self->{'fullrep'} = $repo;
 109         $self->conn();
 110
 111         $self->{'subdir'} = $subdir;
 112         $self->{'lines'} = undef;
 113
 114         return $self;
 115 }
 116
 117 sub conn {
 118         my $self = shift;
 119         my $repo = $self->{'fullrep'};
 120         if($repo =~ s/^:pserver:(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
 121                 my($user,$pass,$serv,$port) = ($1,$2,$3,$4);
 122                 $user="anonymous" unless defined $user;
 123                 my $rr2 = "-";
 124                 unless($port) {
 125                         $rr2 = ":pserver:$user\@$serv:$repo";
 126                         $port=2401;
 127                 }
 128                 my $rr = ":pserver:$user\@$serv:$port$repo";
 129
 130                 unless($pass) {
 131                         open(H,$ENV{'HOME'}."/.cvspass") and do {
 132                                 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
 133                                 while(<H>) {
 134                                         chomp;
 135                                         s/^\/\d+\s+//;
 136                                         my ($w,$p) = split(/\s/,$_,2);
 137                                         if($w eq $rr or $w eq $rr2) {
 138                                                 $pass = $p;
 139                                                 last;
 140                                         }
 141                                 }
 142                         };
 143                 }
 144                 $pass="A" unless $pass;
 145
 146                 my $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
 147                 die "Socket to $serv: $!\n" unless defined $s;
 148                 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
 149                         or die "Write to $serv: $!\n";
 150                 $s->flush();
 151
 152                 my $rep = <$s>;
 153
 154                 if($rep ne "I LOVE YOU\n") {
 155                         $rep="<unknown>" unless $rep;
 156                         die "AuthReply: $rep\n";
 157                 }
 158                 $self->{'socketo'} = $s;
 159                 $self->{'socketi'} = $s;
 160         } else { # local or ext: Fork off our own cvs server.
 161                 my $pr = IO::Pipe->new();
 162                 my $pw = IO::Pipe->new();
 163                 my $pid = fork();
 164                 die "Fork: $!\n" unless defined $pid;
 165                 my $cvs = 'cvs';
 166                 $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
 167                 my $rsh = 'rsh';
 168                 $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
 169
 170                 my @cvs = ($cvs, 'server');
 171                 my ($local, $user, $host);
 172                 $local = $repo =~ s/:local://;
 173                 if (!$local) {
 174                     $repo =~ s/:ext://;
 175                     $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
 176                     ($user, $host) = ($1, $2);
 177                 }
 178                 if (!$local) {
 179                     if ($user) {
 180                         unshift @cvs, $rsh, '-l', $user, $host;
 181                     } else {
 182                         unshift @cvs, $rsh, $host;
 183                     }
 184                 }
 185
 186                 unless($pid) {
 187                         $pr->writer();
 188                         $pw->reader();
 189                         dup2($pw->fileno(),0);
 190                         dup2($pr->fileno(),1);
 191                         $pr->close();
 192                         $pw->close();
 193                         exec(@cvs);
 194                 }
 195                 $pw->writer();
 196                 $pr->reader();
 197                 $self->{'socketo'} = $pw;
 198                 $self->{'socketi'} = $pr;
 199         }
 200         $self->{'socketo'}->write("Root $repo\n");
 201
 202         # Trial and error says that this probably is the minimum set
 203         $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E Checked-in Created Updated Merged Removed\n");
 204
 205         $self->{'socketo'}->write("valid-requests\n");
 206         $self->{'socketo'}->flush();
 207
 208         chomp(my $rep=$self->readline());
 209         if($rep !~ s/^Valid-requests\s*//) {
 210                 $rep="<unknown>" unless $rep;
 211                 die "Expected Valid-requests from server, but got: $rep\n";
 212         }
 213         chomp(my $res=$self->readline());
 214         die "validReply: $res\n" if $res ne "ok";
 215
 216         $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
 217         $self->{'repo'} = $repo;
 218 }
 219
 220 sub readline {
 221         my($self) = @_;
 222         return $self->{'socketi'}->getline();
 223 }
 224
 225 sub _file {
 226         # Request a file with a given revision.
 227         # Trial and error says this is a good way to do it. :-/
 228         my($self,$fn,$rev) = @_;
 229         $self->{'socketo'}->write("Argument -N\n") or return undef;
 230         $self->{'socketo'}->write("Argument -P\n") or return undef;
 231         # -kk: Linus' version doesn't use it - defaults to off
 232         if ($opt_k) {
 233             $self->{'socketo'}->write("Argument -kk\n") or return undef;
 234         }
 235         $self->{'socketo'}->write("Argument -r\n") or return undef;
 236         $self->{'socketo'}->write("Argument $rev\n") or return undef;
 237         $self->{'socketo'}->write("Argument --\n") or return undef;
 238         $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
 239         $self->{'socketo'}->write("Directory .\n") or return undef;
 240         $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
 241         # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
 242         $self->{'socketo'}->write("co\n") or return undef;
 243         $self->{'socketo'}->flush() or return undef;
 244         $self->{'lines'} = 0;
 245         return 1;
 246 }
 247 sub _line {
 248         # Read a line from the server.
 249         # ... except that 'line' may be an entire file. ;-)
 250         my($self, $fh) = @_;
 251         die "Not in lines" unless defined $self->{'lines'};
 252
 253         my $line;
 254         my $res=0;
 255         while(defined($line = $self->readline())) {
 256                 # M U gnupg-cvs-rep/AUTHORS
 257                 # Updated gnupg-cvs-rep/
 258                 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
 259                 # /AUTHORS/1.1///T1.1
 260                 # u=rw,g=rw,o=rw
 261                 # 0
 262                 # ok
 263
 264                 if($line =~ s/^(?:Created|Updated) //) {
 265                         $line = $self->readline(); # path
 266                         $line = $self->readline(); # Entries line
 267                         my $mode = $self->readline(); chomp $mode;
 268                         $self->{'mode'} = $mode;
 269                         defined (my $cnt = $self->readline())
 270                                 or die "EOF from server after 'Changed'\n";
 271                         chomp $cnt;
 272                         die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
 273                         $line="";
 274                         $res=0;
 275                         while($cnt) {
 276                                 my $buf;
 277                                 my $num = $self->{'socketi'}->read($buf,$cnt);
 278                                 die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
 279                                 print $fh $buf;
 280                                 $res += $num;
 281                                 $cnt -= $num;
 282                         }
 283                 } elsif($line =~ s/^ //) {
 284                         print $fh $line;
 285                         $res += length($line);
 286                 } elsif($line =~ /^M\b/) {
 287                         # output, do nothing
 288                 } elsif($line =~ /^Mbinary\b/) {
 289                         my $cnt;
 290                         die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
 291                         chomp $cnt;
 292                         die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
 293                         $line="";
 294                         while($cnt) {
 295                                 my $buf;
 296                                 my $num = $self->{'socketi'}->read($buf,$cnt);
 297                                 die "S: Mbinary $cnt: $num: $!\n" if not defined $num or $num<=0;
 298                                 print $fh $buf;
 299                                 $res += $num;
 300                                 $cnt -= $num;
 301                         }
 302                 } else {
 303                         chomp $line;
 304                         if($line eq "ok") {
 305                                 # print STDERR "S: ok (".length($res).")\n";
 306                                 return $res;
 307                         } elsif($line =~ s/^E //) {
 308                                 # print STDERR "S: $line\n";
 309                         } elsif($line =~ /^Remove-entry /i) {
 310                                 $line = $self->readline(); # filename
 311                                 $line = $self->readline(); # OK
 312                                 chomp $line;
 313                                 die "Unknown: $line" if $line ne "ok";
 314                                 return -1;
 315                         } else {
 316                                 die "Unknown: $line\n";
 317                         }
 318                 }
 319         }
 320 }
 321 sub file {
 322         my($self,$fn,$rev) = @_;
 323         my $res;
 324
 325         my ($fh, $name) = tempfile('gitcvs.XXXXXX',
 326                     DIR => File::Spec->tmpdir(), UNLINK => 1);
 327
 328         $self->_file($fn,$rev) and $res = $self->_line($fh);
 329
 330         if (!defined $res) {
 331             # retry
 332             $self->conn();
 333             $self->_file($fn,$rev)
 334                     or die "No file command send\n";
 335             $res = $self->_line($fh);
 336             die "No input: $fn $rev\n" unless defined $res;
 337         }
 338         close ($fh);
 339
 340         if ($res eq '') {
 341             die "Looks like the server has gone away while fetching $fn $rev -- exiting!";
 342         }
 343
 344         return ($name, $res);
 345 }
 346
 347
 348 package main;
 349
 350 my $cvs = CVSconn->new($opt_d, $cvs_tree);
 351
 352
 353 sub pdate($) {
 354         my($d) = @_;
 355         m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
 356                 or die "Unparseable date: $d\n";
 357         my $y=$1; $y-=1900 if $y>1900;
 358         return timegm($6||0,$5,$4,$3,$2-1,$y);
 359 }
 360
 361 sub pmode($) {
 362         my($mode) = @_;
 363         my $m = 0;
 364         my $mm = 0;
 365         my $um = 0;
 366         for my $x(split(//,$mode)) {
 367                 if($x eq ",") {
 368                         $m |= $mm&$um;
 369                         $mm = 0;
 370                         $um = 0;
 371                 } elsif($x eq "u") { $um |= 0700;
 372                 } elsif($x eq "g") { $um |= 0070;
 373                 } elsif($x eq "o") { $um |= 0007;
 374                 } elsif($x eq "r") { $mm |= 0444;
 375                 } elsif($x eq "w") { $mm |= 0222;
 376                 } elsif($x eq "x") { $mm |= 0111;
 377                 } elsif($x eq "=") { # do nothing
 378                 } else { die "Unknown mode: $mode\n";
 379                 }
 380         }
 381         $m |= $mm&$um;
 382         return $m;
 383 }
 384
 385 sub getwd() {
 386         my $pwd = `pwd`;
 387         chomp $pwd;
 388         return $pwd;
 389 }
 390
 391
 392 sub get_headref($$) {
 393     my $name    = shift;
 394     my $git_dir = shift;
 395     my $sha;
 396
 397     if (open(C,"$git_dir/refs/heads/$name")) {
 398         chomp($sha = <C>);
 399         close(C);
 400         length($sha) == 40
 401             or die "Cannot get head id for $name ($sha): $!\n";
 402     }
 403     return $sha;
 404 }
 405
 406
 407 -d $git_tree
 408         or mkdir($git_tree,0777)
 409         or die "Could not create $git_tree: $!";
 410 chdir($git_tree);
 411
 412 my $last_branch = "";
 413 my $orig_branch = "";
 414 my $forward_master = 0;
 415 my %branch_date;
 416
 417 my $git_dir = $ENV{"GIT_DIR"} || ".git";
 418 $git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 419 $ENV{"GIT_DIR"} = $git_dir;
 420 my $orig_git_index;
 421 $orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 422 my ($git_ih, $git_index) = tempfile('gitXXXXXX', SUFFIX => '.idx',
 423                                     DIR => File::Spec->tmpdir());
 424 close ($git_ih);
 425 $ENV{GIT_INDEX_FILE} = $git_index;
 426 unless(-d $git_dir) {
 427         system("git-init-db");
 428         die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 429         system("git-read-tree");
 430         die "Cannot init an empty tree: $?\n" if $?;
 431
 432         $last_branch = $opt_o;
 433         $orig_branch = "";
 434 } else {
 435         -f "$git_dir/refs/heads/$opt_o"
 436                 or die "Branch '$opt_o' does not exist.\n".
 437                        "Either use the correct '-o branch' option,\n".
 438                        "or import to a new repository.\n";
 439
 440         open(F, "git-symbolic-ref HEAD |") or
 441                 die "Cannot run git-symbolic-ref: $!\n";
 442         chomp ($last_branch = <F>);
 443         $last_branch = basename($last_branch);
 444         close(F);
 445         unless($last_branch) {
 446                 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 447                 $last_branch = "master";
 448         }
 449         $orig_branch = $last_branch;
 450         if (-f "$git_dir/CVS2GIT_HEAD") {
 451                 die <<EOM;
 452 CVS2GIT_HEAD exists.
 453 Make sure your working directory corresponds to HEAD and remove CVS2GIT_HEAD.
 454 You may need to run
 455
 456     git-read-tree -m -u CVS2GIT_HEAD HEAD
 457 EOM
 458         }
 459         system('cp', "$git_dir/HEAD", "$git_dir/CVS2GIT_HEAD");
 460
 461         $forward_master =
 462             $opt_o ne 'master' && -f "$git_dir/refs/heads/master" &&
 463             system('cmp', '-s', "$git_dir/refs/heads/master",
 464                                 "$git_dir/refs/heads/$opt_o") == 0;
 465
 466         # populate index
 467         system('git-read-tree', $last_branch);
 468         die "read-tree failed: $?\n" if $?;
 469
 470         # Get the last import timestamps
 471         opendir(D,"$git_dir/refs/heads");
 472         while(defined(my $head = readdir(D))) {
 473                 next if $head =~ /^\./;
 474                 open(F,"$git_dir/refs/heads/$head")
 475                         or die "Bad head branch: $head: $!\n";
 476                 chomp(my $ftag = <F>);
 477                 close(F);
 478                 open(F,"git-cat-file commit $ftag |");
 479                 while(<F>) {
 480                         next unless /^author\s.*\s(\d+)\s[-+]\d{4}$/;
 481                         $branch_date{$head} = $1;
 482                         last;
 483                 }
 484                 close(F);
 485         }
 486         closedir(D);
 487 }
 488
 489 -d $git_dir
 490         or die "Could not create git subdir ($git_dir).\n";
 491
 492 my $pid = open(CVS,"-|");
 493 die "Cannot fork: $!\n" unless defined $pid;
 494 unless($pid) {
 495         my @opt;
 496         @opt = split(/,/,$opt_p) if defined $opt_p;
 497         unshift @opt, '-z', $opt_z if defined $opt_z;
 498         unshift @opt, '-q'         unless defined $opt_v;
 499         unless (defined($opt_p) && $opt_p =~ m/--no-cvs-direct/) {
 500                 push @opt, '--cvs-direct';
 501         }
 502         if ($opt_P) {
 503             exec("cat", $opt_P);
 504         } else {
 505             exec("cvsps",@opt,"-u","-A",'--root',$opt_d,$cvs_tree);
 506             die "Could not start cvsps: $!\n";
 507         }
 508 }
 509
 510
 511 ## cvsps output:
 512 #---------------------
 513 #PatchSet 314
 514 #Date: 1999/09/18 13:03:59
 515 #Author: wkoch
 516 #Branch: STABLE-BRANCH-1-0
 517 #Ancestor branch: HEAD
 518 #Tag: (none)
 519 #Log:
 520 #    See ChangeLog: Sat Sep 18 13:03:28 CEST 1999  Werner Koch
 521 #Members:
 522 #       README:1.57->1.57.2.1
 523 #       VERSION:1.96->1.96.2.1
 524 #
 525 #---------------------
 526
 527 my $state = 0;
 528
 529 my($patchset,$date,$author_name,$author_email,$branch,$ancestor,$tag,$logmsg);
 530 my(@old,@new);
 531 my $commit = sub {
 532         my $pid;
 533         while(@old) {
 534                 my @o2;
 535                 if(@old > 55) {
 536                         @o2 = splice(@old,0,50);
 537                 } else {
 538                         @o2 = @old;
 539                         @old = ();
 540                 }
 541                 system("git-update-index","--force-remove","--",@o2);
 542                 die "Cannot remove files: $?\n" if $?;
 543         }
 544         while(@new) {
 545                 my @n2;
 546                 if(@new > 12) {
 547                         @n2 = splice(@new,0,10);
 548                 } else {
 549                         @n2 = @new;
 550                         @new = ();
 551                 }
 552                 system("git-update-index","--add",
 553                         (map { ('--cacheinfo', @$_) } @n2));
 554                 die "Cannot add files: $?\n" if $?;
 555         }
 556
 557         $pid = open(C,"-|");
 558         die "Cannot fork: $!" unless defined $pid;
 559         unless($pid) {
 560                 exec("git-write-tree");
 561                 die "Cannot exec git-write-tree: $!\n";
 562         }
 563         chomp(my $tree = <C>);
 564         length($tree) == 40
 565                 or die "Cannot get tree id ($tree): $!\n";
 566         close(C)
 567                 or die "Error running git-write-tree: $?\n";
 568         print "Tree ID $tree\n" if $opt_v;
 569
 570         my $parent = "";
 571         if(open(C,"$git_dir/refs/heads/$last_branch")) {
 572                 chomp($parent = <C>);
 573                 close(C);
 574                 length($parent) == 40
 575                         or die "Cannot get parent id ($parent): $!\n";
 576                 print "Parent ID $parent\n" if $opt_v;
 577         }
 578
 579         my $pr = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 580         my $pw = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 581         $pid = fork();
 582         die "Fork: $!\n" unless defined $pid;
 583         unless($pid) {
 584                 $pr->writer();
 585                 $pw->reader();
 586                 open(OUT,">&STDOUT");
 587                 dup2($pw->fileno(),0);
 588                 dup2($pr->fileno(),1);
 589                 $pr->close();
 590                 $pw->close();
 591
 592                 my @par = ();
 593                 @par = ("-p",$parent) if $parent;
 594
 595                 # loose detection of merges
 596                 # based on the commit msg
 597                 foreach my $rx (@mergerx) {
 598                         if ($logmsg =~ $rx) {
 599                                 my $mparent = $1;
 600                                 if ($mparent eq 'HEAD') { $mparent = $opt_o };
 601                                 if ( -e "$git_dir/refs/heads/$mparent") {
 602                                         $mparent = get_headref($mparent, $git_dir);
 603                                         push @par, '-p', $mparent;
 604                                         print OUT "Merge parent branch: $mparent\n" if $opt_v;
 605                                 }
 606                         }
 607                 }
 608
 609                 exec("env",
 610                         "GIT_AUTHOR_NAME=$author_name",
 611                         "GIT_AUTHOR_EMAIL=$author_email",
 612                         "GIT_AUTHOR_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 613                         "GIT_COMMITTER_NAME=$author_name",
 614                         "GIT_COMMITTER_EMAIL=$author_email",
 615                         "GIT_COMMITTER_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 616                         "git-commit-tree", $tree,@par);
 617                 die "Cannot exec git-commit-tree: $!\n";
 618         }
 619         $pw->writer();
 620         $pr->reader();
 621
 622         # compatibility with git2cvs
 623         substr($logmsg,32767) = "" if length($logmsg) > 32767;
 624         $logmsg =~ s/[\s\n]+\z//;
 625
 626         print $pw "$logmsg\n"
 627                 or die "Error writing to git-commit-tree: $!\n";
 628         $pw->close();
 629
 630         print "Committed patch $patchset ($branch ".strftime("%Y-%m-%d %H:%M:%S",gmtime($date)).")\n" if $opt_v;
 631         chomp(my $cid = <$pr>);
 632         length($cid) == 40
 633                 or die "Cannot get commit id ($cid): $!\n";
 634         print "Commit ID $cid\n" if $opt_v;
 635         $pr->close();
 636
 637         waitpid($pid,0);
 638         die "Error running git-commit-tree: $?\n" if $?;
 639
 640         open(C,">$git_dir/refs/heads/$branch")
 641                 or die "Cannot open branch $branch for update: $!\n";
 642         print C "$cid\n"
 643                 or die "Cannot write branch $branch for update: $!\n";
 644         close(C)
 645                 or die "Cannot write branch $branch for update: $!\n";
 646
 647         if($tag) {
 648                 my($in, $out) = ('','');
 649                 my($xtag) = $tag;
 650                 $xtag =~ s/\s+\*\*.*$//; # Remove stuff like ** INVALID ** and ** FUNKY **
 651                 $xtag =~ tr/_/\./ if ( $opt_u );
 652
 653                 my $pid = open2($in, $out, 'git-mktag');
 654                 print $out "object $cid\n".
 655                     "type commit\n".
 656                     "tag $xtag\n".
 657                     "tagger $author_name <$author_email>\n"
 658                     or die "Cannot create tag object $xtag: $!\n";
 659                 close($out)
 660                     or die "Cannot create tag object $xtag: $!\n";
 661
 662                 my $tagobj = <$in>;
 663                 chomp $tagobj;
 664
 665                 if ( !close($in) or waitpid($pid, 0) != $pid or
 666                      $? != 0 or $tagobj !~ /^[0123456789abcdef]{40}$/ ) {
 667                     die "Cannot create tag object $xtag: $!\n";
 668                 }
 669
 670
 671                 open(C,">$git_dir/refs/tags/$xtag")
 672                         or die "Cannot create tag $xtag: $!\n";
 673                 print C "$tagobj\n"
 674                         or die "Cannot write tag $xtag: $!\n";
 675                 close(C)
 676                         or die "Cannot write tag $xtag: $!\n";
 677
 678                 print "Created tag '$xtag' on '$branch'\n" if $opt_v;
 679         }
 680 };
 681
 682 while(<CVS>) {
 683         chomp;
 684         if($state == 0 and /^-+$/) {
 685                 $state = 1;
 686         } elsif($state == 0) {
 687                 $state = 1;
 688                 redo;
 689         } elsif(($state==0 or $state==1) and s/^PatchSet\s+//) {
 690                 $patchset = 0+$_;
 691                 $state=2;
 692         } elsif($state == 2 and s/^Date:\s+//) {
 693                 $date = pdate($_);
 694                 unless($date) {
 695                         print STDERR "Could not parse date: $_\n";
 696                         $state=0;
 697                         next;
 698                 }
 699                 $state=3;
 700         } elsif($state == 3 and s/^Author:\s+//) {
 701                 s/\s+$//;
 702                 if (/^(.*?)\s+<(.*)>/) {
 703                     ($author_name, $author_email) = ($1, $2);
 704                 } else {
 705                     $author_name = $author_email = $_;
 706                 }
 707                 $state = 4;
 708         } elsif($state == 4 and s/^Branch:\s+//) {
 709                 s/\s+$//;
 710                 s/[\/]/$opt_s/g;
 711                 $branch = $_;
 712                 $state = 5;
 713         } elsif($state == 5 and s/^Ancestor branch:\s+//) {
 714                 s/\s+$//;
 715                 $ancestor = $_;
 716                 $ancestor = $opt_o if $ancestor eq "HEAD";
 717                 $state = 6;
 718         } elsif($state == 5) {
 719                 $ancestor = undef;
 720                 $state = 6;
 721                 redo;
 722         } elsif($state == 6 and s/^Tag:\s+//) {
 723                 s/\s+$//;
 724                 if($_ eq "(none)") {
 725                         $tag = undef;
 726                 } else {
 727                         $tag = $_;
 728                 }
 729                 $state = 7;
 730         } elsif($state == 7 and /^Log:/) {
 731                 $logmsg = "";
 732                 $state = 8;
 733         } elsif($state == 8 and /^Members:/) {
 734                 $branch = $opt_o if $branch eq "HEAD";
 735                 if(defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
 736                         # skip
 737                         print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
 738                         $state = 11;
 739                         next;
 740                 }
 741                 if($ancestor) {
 742                         if(-f "$git_dir/refs/heads/$branch") {
 743                                 print STDERR "Branch $branch already exists!\n";
 744                                 $state=11;
 745                                 next;
 746                         }
 747                         unless(open(H,"$git_dir/refs/heads/$ancestor")) {
 748                                 print STDERR "Branch $ancestor does not exist!\n";
 749                                 $state=11;
 750                                 next;
 751                         }
 752                         chomp(my $id = <H>);
 753                         close(H);
 754                         unless(open(H,"> $git_dir/refs/heads/$branch")) {
 755                                 print STDERR "Could not create branch $branch: $!\n";
 756                                 $state=11;
 757                                 next;
 758                         }
 759                         print H "$id\n"
 760                                 or die "Could not write branch $branch: $!";
 761                         close(H)
 762                                 or die "Could not write branch $branch: $!";
 763                 }
 764                 if(($ancestor || $branch) ne $last_branch) {
 765                         print "Switching from $last_branch to $branch\n" if $opt_v;
 766                         system("git-read-tree", $branch);
 767                         die "read-tree failed: $?\n" if $?;
 768                 }
 769                 $last_branch = $branch if $branch ne $last_branch;
 770                 $state = 9;
 771         } elsif($state == 8) {
 772                 $logmsg .= "$_\n";
 773         } elsif($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
 774 #       VERSION:1.96->1.96.2.1
 775                 my $init = ($2 eq "INITIAL");
 776                 my $fn = $1;
 777                 my $rev = $3;
 778                 $fn =~ s#^/+##;
 779                 my ($tmpname, $size) = $cvs->file($fn,$rev);
 780                 if($size == -1) {
 781                         push(@old,$fn);
 782                         print "Drop $fn\n" if $opt_v;
 783                 } else {
 784                         print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
 785                         open my $F, '-|', "git-hash-object -w $tmpname"
 786                                 or die "Cannot create object: $!\n";
 787                         my $sha = <$F>;
 788                         chomp $sha;
 789                         close $F;
 790                         my $mode = pmode($cvs->{'mode'});
 791                         push(@new,[$mode, $sha, $fn]); # may be resurrected!
 792                 }
 793                 unlink($tmpname);
 794         } elsif($state == 9 and /^\s+(.+?):\d+(?:\.\d+)+->(\d+(?:\.\d+)+)\(DEAD\)\s*$/) {
 795                 my $fn = $1;
 796                 $fn =~ s#^/+##;
 797                 push(@old,$fn);
 798                 print "Delete $fn\n" if $opt_v;
 799         } elsif($state == 9 and /^\s*$/) {
 800                 $state = 10;
 801         } elsif(($state == 9 or $state == 10) and /^-+$/) {
 802                 &$commit();
 803                 $state = 1;
 804         } elsif($state == 11 and /^-+$/) {
 805                 $state = 1;
 806         } elsif(/^-+$/) { # end of unknown-line processing
 807                 $state = 1;
 808         } elsif($state != 11) { # ignore stuff when skipping
 809                 print "* UNKNOWN LINE * $_\n";
 810         }
 811 }
 812 &$commit() if $branch and $state != 11;
 813
 814 unlink($git_index);
 815
 816 if (defined $orig_git_index) {
 817         $ENV{GIT_INDEX_FILE} = $orig_git_index;
 818 } else {
 819         delete $ENV{GIT_INDEX_FILE};
 820 }
 821
 822 # Now switch back to the branch we were in before all of this happened
 823 if($orig_branch) {
 824         print "DONE\n" if $opt_v;
 825         system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 826                 if $forward_master;
 827         unless ($opt_i) {
 828                 system('git-read-tree', '-m', '-u', 'CVS2GIT_HEAD', 'HEAD');
 829                 die "read-tree failed: $?\n" if $?;
 830         }
 831 } else {
 832         $orig_branch = "master";
 833         print "DONE; creating $orig_branch branch\n" if $opt_v;
 834         system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 835                 unless -f "$git_dir/refs/heads/master";
 836         system('git-update-ref', 'HEAD', "$orig_branch");
 837         unless ($opt_i) {
 838                 system('git checkout');
 839                 die "checkout failed: $?\n" if $?;
 840         }
 841 }
 842 unlink("$git_dir/CVS2GIT_HEAD");