m4/m4_ax_prog_cc_for_build.m4

   1 # ===========================================================================
   2 #   https://www.gnu.org/software/autoconf-archive/ax_prog_cc_for_build.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_PROG_CC_FOR_BUILD
   8 #
   9 # DESCRIPTION
  10 #
  11 #   This macro searches for a C compiler that generates native executables,
  12 #   that is a C compiler that surely is not a cross-compiler. This can be
  13 #   useful if you have to generate source code at compile-time like for
  14 #   example GCC does.
  15 #
  16 #   The macro sets the CC_FOR_BUILD and CPP_FOR_BUILD macros to anything
  17 #   needed to compile or link (CC_FOR_BUILD) and preprocess (CPP_FOR_BUILD).
  18 #   The value of these variables can be overridden by the user by specifying
  19 #   a compiler with an environment variable (like you do for standard CC).
  20 #
  21 #   It also sets BUILD_EXEEXT and BUILD_OBJEXT to the executable and object
  22 #   file extensions for the build platform, and GCC_FOR_BUILD to `yes' if
  23 #   the compiler we found is GCC. All these variables but GCC_FOR_BUILD are
  24 #   substituted in the Makefile.
  25 #
  26 # LICENSE
  27 #
  28 #   Copyright (c) 2008 Paolo Bonzini <bonzini@gnu.org>
  29 #
  30 #   Copying and distribution of this file, with or without modification, are
  31 #   permitted in any medium without royalty provided the copyright notice
  32 #   and this notice are preserved. This file is offered as-is, without any
  33 #   warranty.
  34
  35 #serial 20
  36
  37 AU_ALIAS([AC_PROG_CC_FOR_BUILD], [AX_PROG_CC_FOR_BUILD])
  38 AC_DEFUN([AX_PROG_CC_FOR_BUILD], [dnl
  39 AC_REQUIRE([AC_PROG_CC])dnl
  40 AC_REQUIRE([AC_PROG_CPP])dnl
  41 AC_REQUIRE([AC_CANONICAL_BUILD])dnl
  42
  43 dnl Use the standard macros, but make them use other variable names
  44 dnl
  45 pushdef([ac_cv_prog_CPP], ac_cv_build_prog_CPP)dnl
  46 pushdef([ac_cv_prog_cc_c89], ac_cv_build_prog_cc_c89)dnl
  47 pushdef([ac_cv_prog_cc_c99], ac_cv_build_prog_cc_c99)dnl
  48 pushdef([ac_cv_prog_cc_c11], ac_cv_build_prog_cc_c11)dnl
  49 pushdef([ac_cv_prog_gcc], ac_cv_build_prog_gcc)dnl
  50 pushdef([ac_cv_prog_cc_works], ac_cv_build_prog_cc_works)dnl
  51 pushdef([ac_cv_prog_cc_cross], ac_cv_build_prog_cc_cross)dnl
  52 pushdef([ac_cv_prog_cc_g], ac_cv_build_prog_cc_g)dnl
  53 pushdef([ac_cv_c_compiler_gnu], ac_cv_build_c_compiler_gnu)dnl
  54 pushdef([ac_cv_exeext], ac_cv_build_exeext)dnl
  55 pushdef([ac_cv_objext], ac_cv_build_objext)dnl
  56 pushdef([ac_exeext], ac_build_exeext)dnl
  57 pushdef([ac_objext], ac_build_objext)dnl
  58 pushdef([CC], CC_FOR_BUILD)dnl
  59 pushdef([CPP], CPP_FOR_BUILD)dnl
  60 pushdef([GCC], GCC_FOR_BUILD)dnl
  61 pushdef([CFLAGS], CFLAGS_FOR_BUILD)dnl
  62 pushdef([CPPFLAGS], CPPFLAGS_FOR_BUILD)dnl
  63 pushdef([EXEEXT], BUILD_EXEEXT)dnl
  64 pushdef([LDFLAGS], LDFLAGS_FOR_BUILD)dnl
  65 pushdef([OBJEXT], BUILD_OBJEXT)dnl
  66 pushdef([host], build)dnl
  67 pushdef([host_alias], build_alias)dnl
  68 pushdef([host_cpu], build_cpu)dnl
  69 pushdef([host_vendor], build_vendor)dnl
  70 pushdef([host_os], build_os)dnl
  71 pushdef([ac_cv_host], ac_cv_build)dnl
  72 pushdef([ac_cv_host_alias], ac_cv_build_alias)dnl
  73 pushdef([ac_cv_host_cpu], ac_cv_build_cpu)dnl
  74 pushdef([ac_cv_host_vendor], ac_cv_build_vendor)dnl
  75 pushdef([ac_cv_host_os], ac_cv_build_os)dnl
  76 pushdef([ac_tool_prefix], ac_build_tool_prefix)dnl
  77 pushdef([am_cv_CC_dependencies_compiler_type], am_cv_build_CC_dependencies_compiler_type)dnl
  78 pushdef([am_cv_prog_cc_c_o], am_cv_build_prog_cc_c_o)dnl
  79 pushdef([cross_compiling], cross_compiling_build)dnl
  80
  81 cross_compiling_build=no
  82
  83 ac_build_tool_prefix=
  84 AS_IF([test -n "$build"],      [ac_build_tool_prefix="$build-"],
  85       [test -n "$build_alias"],[ac_build_tool_prefix="$build_alias-"])
  86
  87 AC_LANG_PUSH([C])
  88
  89 dnl The pushdef([ac_cv_c_compiler_gnu], ...) currently does not cover
  90 dnl the use of this variable in _AC_LANG_COMPILER_GNU called by
  91 dnl AC_PROG_CC. Unset this cache variable temporarily as a workaround.
  92 was_set_ac_cv_c_compiler_gnu=${[ac_cv_c_compiler_gnu]+y}
  93 AS_IF([test ${was_set_ac_cv_c_compiler_gnu}],
  94     [saved_ac_cv_c_compiler_gnu=$[ac_cv_c_compiler_gnu]
  95     AS_UNSET([[ac_cv_c_compiler_gnu]])])
  96
  97 AC_PROG_CC
  98
  99 dnl Restore ac_cv_c_compiler_gnu
 100 AS_IF([test ${was_set_ac_cv_c_compiler_gnu}],
 101   [[ac_cv_c_compiler_gnu]=saved_ac_cv_c_compiler_gnu])
 102
 103 _AC_COMPILER_EXEEXT
 104 _AC_COMPILER_OBJEXT
 105 AC_PROG_CPP
 106
 107 dnl Restore the old definitions
 108 dnl
 109 popdef([cross_compiling])dnl
 110 popdef([am_cv_prog_cc_c_o])dnl
 111 popdef([am_cv_CC_dependencies_compiler_type])dnl
 112 popdef([ac_tool_prefix])dnl
 113 popdef([ac_cv_host_os])dnl
 114 popdef([ac_cv_host_vendor])dnl
 115 popdef([ac_cv_host_cpu])dnl
 116 popdef([ac_cv_host_alias])dnl
 117 popdef([ac_cv_host])dnl
 118 popdef([host_os])dnl
 119 popdef([host_vendor])dnl
 120 popdef([host_cpu])dnl
 121 popdef([host_alias])dnl
 122 popdef([host])dnl
 123 popdef([OBJEXT])dnl
 124 popdef([LDFLAGS])dnl
 125 popdef([EXEEXT])dnl
 126 popdef([CPPFLAGS])dnl
 127 popdef([CFLAGS])dnl
 128 popdef([GCC])dnl
 129 popdef([CPP])dnl
 130 popdef([CC])dnl
 131 popdef([ac_objext])dnl
 132 popdef([ac_exeext])dnl
 133 popdef([ac_cv_objext])dnl
 134 popdef([ac_cv_exeext])dnl
 135 popdef([ac_cv_c_compiler_gnu])dnl
 136 popdef([ac_cv_prog_cc_g])dnl
 137 popdef([ac_cv_prog_cc_cross])dnl
 138 popdef([ac_cv_prog_cc_works])dnl
 139 popdef([ac_cv_prog_cc_c89])dnl
 140 popdef([ac_cv_prog_gcc])dnl
 141 popdef([ac_cv_prog_CPP])dnl
 142
 143 dnl restore global variables ac_ext, ac_cpp, ac_compile,
 144 dnl ac_link, ac_compiler_gnu (dependant on the current
 145 dnl language after popping):
 146 AC_LANG_POP([C])
 147
 148 dnl Finally, set Makefile variables
 149 dnl
 150 AC_SUBST(BUILD_EXEEXT)dnl
 151 AC_SUBST(BUILD_OBJEXT)dnl
 152 AC_SUBST([CFLAGS_FOR_BUILD])dnl
 153 AC_SUBST([CPPFLAGS_FOR_BUILD])dnl
 154 AC_SUBST([LDFLAGS_FOR_BUILD])dnl
 155 ])