lists.lisp

   1 (in-package :alexandria)
   2
   3 (defun alist-plist (alist)
   4   "Returns a property list containing the same keys and values as the
   5 association list ALIST in the same order."
   6   (let (plist)
   7     (dolist (pair alist)
   8       (push (car pair) plist)
   9       (push (cdr pair) plist))
  10     (nreverse plist)))
  11
  12 (defun plist-alist (plist)
  13   "Returns an association list containing the same keys and values as the
  14 property list PLIST in the same order."
  15   (let (alist)
  16     (do ((tail plist (cddr tail)))
  17         ((endp tail) (nreverse alist))
  18       (push (cons (car tail) (cadr tail)) alist))))
  19
  20 (define-modify-macro appendf (&rest lists) append
  21   "Modify-macro for APPEND. Appends LISTS to the place designated by the first
  22 argument.")
  23
  24 (define-modify-macro unionf (list) union
  25   "Modify-macro for UNION. Saves the union of LIST and the contents of the
  26 place designated by the first argument to the designated place.")
  27
  28 (define-modify-macro nunionf (list) nunion
  29   "Modify-macro for NUNION. Saves the union of LIST and the contents of the
  30 place designated by the first argument to the designated place. May modify
  31 either argument.")
  32
  33 (defun circular-list (&rest elements)
  34   "Creates a circular list of ELEMENTS."
  35   (let ((cycle (copy-list elements)))
  36     (nconc cycle cycle)))
  37
  38 (defun circular-list-p (object)
  39   "Returns true if OBJECT is a circular list, NIL otherwise."
  40   (and (listp object)
  41        (do ((fast object (cddr fast))
  42             (slow (cons (car object) (cdr object)) (cdr slow)))
  43            (nil)
  44          (unless (and (consp fast) (listp (cdr fast)))
  45            (return nil))
  46          (when (eq fast slow)
  47            (return t)))))
  48
  49 (defun circular-tree-p (object)
  50   "Returns true if OBJECT is a circular tree, NIL otherwise."
  51   (labels ((circularp (object seen)
  52              (and (consp object)
  53                   (do ((fast (cons (car object) (cdr object)) (cddr fast))
  54                        (slow object (cdr slow)))
  55                       ((or (not (consp fast)) (not (consp (cdr slow))))
  56                        (do ((tail object (cdr tail)))
  57                            ((not (consp tail))
  58                             nil)
  59                          (let ((elt (car tail)))
  60                            (circularp elt (cons object seen)))))
  61                     (when (or (eq fast slow) (member slow seen))
  62                       (return-from circular-tree-p t))))))
  63     (circularp object nil)))
  64
  65 (defun proper-list-p (object)
  66   "Returns true if OBJECT is a proper list."
  67   (cond ((not object)
  68          t)
  69         ((consp object)
  70          (do ((fast object (cddr fast))
  71               (slow (cons (car object) (cdr object)) (cdr slow)))
  72              (nil)
  73            (unless (and (listp fast) (consp (cdr fast)))
  74              (return (and (listp fast) (not (cdr fast)))))
  75            (when (eq fast slow)
  76              (return nil))))
  77         (t
  78          nil)))
  79
  80 (deftype proper-list ()
  81   "Type designator for proper lists. Implemented as a SATISFIES type, hence
  82 not recommended for performance intensive use. Main usefullness as a type
  83 designator of the expected type in a TYPE-ERROR."
  84   `(satisfies proper-list-p))
  85
  86 (defun lastcar (list)
  87   "Returns the last element of LIST. Signals a type-error if LIST is not a
  88 proper list."
  89   (do ((last list fast)
  90        (fast list (cddr fast))
  91        (slow (cons (car list) (cdr list)) (cdr slow)))
  92       (nil)
  93     (when (endp fast)
  94       (return (cadr last)))
  95     (when (endp (cdr fast))
  96       (return (car fast)))
  97     (when (eq fast slow)
  98       (error 'type-error
  99              :datum list
 100              :expected-type '(and list (not circular-list))))))
 101
 102 (defun (setf lastcar) (object list)
 103   "Sets the last element of LIST. Signals a type-error if LIST is not a proper
 104 list."
 105   (do ((last list fast)
 106        (fast list (cddr fast))
 107        (slow (cons (car list) (cdr list)) (cdr slow)))
 108       (nil)
 109     (when (endp fast)
 110       (return (setf (cadr last) object)))
 111     (when (endp (cdr fast))
 112       (return (setf (car fast) object)))
 113     (when (eq fast slow)
 114       (error 'type-error
 115              :datum list
 116              :expected-type '(and list (not circular-list))))))
 117
 118 (defun make-circular-list (length &key initial-element)
 119   "Creates a circular list of LENGTH with the given INITIAL-ELEMENT."
 120   (let ((cycle (make-list length :initial-element initial-element)))
 121     (nconc cycle cycle)))
 122
 123 (deftype circular-list ()
 124   "Type designator for circular lists. Implemented as a SATISFIES type, so not
 125 recommended for performance intensive use. Main usefullness as the
 126 expected-type designator of a TYPE-ERROR."
 127   `(satisfies circular-list-p))
 128
 129 (defun ensure-cons (cons)
 130   "If CONS is a cons, it is returned. Otherwise returns a fresh cons with CONS
 131   in the car, and NIL in the cdr."
 132   (if (consp cons)
 133       cons
 134       (cons cons nil)))
 135
 136 (defun ensure-list (list)
 137   "If LIST is a list, it is returned. Otherwise returns the list designated by LIST."
 138   (if (listp list)
 139       list
 140       (list list)))
 141
 142 (defun remove-from-plist (plist &rest keys)
 143   "Returns a propery-list with same keys and values as PLIST, except that keys
 144 in the list designated by KEYS and values corresponding to them are removed.
 145 The returned property-list may share structure with the PLIST, but PLIST is
 146 not destructively modified. Keys are compared using EQ."
 147   (declare (optimize (speed 3)))
 148   ;; FIXME: unoptimal: (sans '(:a 1 :b 2) :a) has no need to copy the
 149   ;; tail.
 150   (loop for cell = plist :then (cddr cell)
 151         for key = (car cell)
 152         while cell
 153         unless (member key keys :test #'eq)
 154         collect key
 155         and do (assert (cdr cell) () "Not a proper plist")
 156         and collect (cadr cell)))
 157
 158 (defun delete-from-plist (plist &rest keys)
 159   "Just like REMOVE-FROM-PLIST, but this version may destructively modify the
 160 provided plist."
 161   ;; FIXME unoptimal
 162   (apply 'remove-from-plist plist keys))
 163
 164 (define-modify-macro remove-from-plistf (plist &rest keys) remove-from-plist)
 165 (define-modify-macro delete-from-plistf (plist &rest keys) delete-from-plist)
 166
 167 (declaim (inline sans))
 168 (defun sans (plist &rest keys)
 169   "Alias of REMOVE-FROM-PLIST for backward compatibility."
 170   (apply #'remove-from-plist plist keys))
 171
 172 (defun mappend (function &rest lists)
 173   "Applies FUNCTION to respective element(s) of each LIST, appending all the
 174 all the result list to a single list. FUNCTION must return a list."
 175   (loop for results in (apply #'mapcar function lists)
 176         append results))
 177
 178 (defun setp (object &key (test #'eql) (key #'identity))
 179   "Returns true if OBJECT is a list that denotes a set, NIL otherwise. A list
 180 denotes a set if each element of the list is unique under KEY and TEST."
 181   (and (listp object)
 182        (let (seen)
 183          (dolist (elt object t)
 184            (let ((key (funcall key elt)))
 185              (if (member key seen :test test)
 186                  (return nil)
 187                  (push key seen)))))))
 188
 189 (defun set-equal (list1 list2 &key (test #'eql) (key nil keyp))
 190   "Returns true if every element of LIST1 matches some element of LIST2 and
 191 every element of LIST2 matches some element of LIST1. Otherwise returns false."
 192   (let ((keylist1 (if keyp (mapcar key list1) list1))
 193         (keylist2 (if keyp (mapcar key list2) list2)))
 194     (and (dolist (elt keylist1 t)
 195            (or (member elt keylist2 :test test)
 196                (return nil)))
 197          (dolist (elt keylist2 t)
 198            (or (member elt keylist1 :test test)
 199                (return nil))))))
 200
 201 (defun map-product (function list &rest more-lists)
 202   "Returns a list containing the results of calling FUNCTION with one argument
 203 from LIST, and one from each of MORE-LISTS for each combination of arguments.
 204 In other words, returns the product of LIST and MORE-LISTS using FUNCTION.
 205
 206 Example:
 207
 208  (map-product 'list '(1 2) '(3 4) '(5 6)) => ((1 3 5) (1 3 6) (1 4 5) (1 4 6)
 209                                               (2 3 5) (2 3 6) (2 4 5) (2 4 6))
 210 "
 211   (labels ((%map-product (f lists)
 212              (let ((more (cdr lists))
 213                    (one (car lists)))
 214                (if (not more)
 215                    (mapcar f one)
 216                    (mappend (lambda (x)
 217                               (%map-product (curry f x) more))
 218                             one)))))
 219     (%map-product (if (functionp function)
 220                       function
 221                       (fdefinition function))
 222                   (cons list more-lists))))
 223
 224 (defun flatten (tree)
 225   "Traverses the tree in order, collecting non-null leaves into a list."
 226   (let (list)
 227     (labels ((traverse (subtree)
 228                (when subtree
 229                  (if (consp subtree)
 230                      (progn
 231                        (traverse (car subtree))
 232                        (traverse (cdr subtree)))
 233                      (push subtree list)))))
 234       (traverse tree))
 235     (nreverse list)))