compiler.l

   1 %{
   2 /*
   3
   4     Ann Hell Ex Machina - Music Software
   5     Copyright (C) 2003/2006 Angel Ortega <angel@triptico.com>
   6
   7     compiler.l - Scripting language [F]lex lexer
   8
   9     This program is free software; you can redistribute it and/or
  10     modify it under the terms of the GNU General Public License
  11     as published by the Free Software Foundation; either version 2
  12     of the License, or (at your option) any later version.
  13
  14     This program is distributed in the hope that it will be useful,
  15     but WITHOUT ANY WARRANTY; without even the implied warranty of
  16     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17     GNU General Public License for more details.
  18
  19     You should have received a copy of the GNU General Public License
  20     along with this program; if not, write to the Free Software
  21     Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  22
  23     http://www.triptico.com
  24
  25 */
  26
  27 #include <stdio.h>
  28 #include <stdlib.h>
  29 #include <string.h>
  30 #include <math.h>
  31 #include "y.tab.h"
  32
  33 #include "ahxm.h"
  34
  35 void yyerror(char * s);
  36 int yy_input_for_flex(char * buf, int max);
  37
  38 /* the notes */
  39 static char * ascii_notes = "ccddeffggaab";
  40
  41 /* redefinition of input function for GNU Flex */
  42 #undef YY_INPUT
  43 #define YY_INPUT(b,r,m) (r = yy_input_for_flex(b,m))
  44
  45 struct code_stack
  46 {
  47         char * code;    /* code string */
  48         int offset;     /* current offset */
  49 };
  50
  51 static struct code_stack * code_stack = NULL;
  52 static int code_stack_i = -1;
  53
  54 /* dynamic string manipulation macros */
  55 #ifndef ds_init
  56 struct ds { char * d; int p; int s; };
  57 #define ds_init(x) do { x.d = (char *)0; x.p = x.s = 0; } while(0)
  58 #define ds_rewind(x) x.p = 0;
  59 #define ds_free(x) do { if(x.d) free(x.d); ds_init(x); } while(0)
  60 #define ds_redim(x) do { if(x.p >= x.s) x.d = realloc(x.d, x.s += 32); } while(0)
  61 #define ds_poke(x,c) do { ds_redim(x); x.d[x.p++] = c; } while(0)
  62 #define ds_pokes(x,t) do { char *p = t; while(*p) ds_poke(x, *p++); } while(0)
  63 #endif /* ds_init */
  64
  65 /* block dynstring */
  66 static struct ds ds_blk;
  67
  68 /* count of parentheses */
  69 static int ds_blk_i;
  70
  71 /* line number */
  72 int yyline = 0;
  73
  74 %}
  75
  76 DIGIT           [0-9]
  77 P_INTEGER       {DIGIT}+
  78 S_INTEGER       [-+]{P_INTEGER}
  79 P_REAL          {DIGIT}*[\.]?{DIGIT}+
  80 S_REAL          [-+]{P_REAL}
  81
  82 NOTE_P          [a-g]
  83 NOTE_T3         \/3
  84 NOTE_T5         \/5
  85
  86 MARKNAME        [-a-zA-Z0-9_]+
  87 NEW_MARK        \^{MARKNAME}
  88 GOTO_MARK       @{MARKNAME}
  89 ASSERT_MARK     !{MARKNAME}
  90
  91 BLOCKNAME       [-a-zA-Z0-9_#&]+
  92
  93 WSPACE          [ \t]+
  94
  95 ALTSTR          A[-&#]*
  96
  97 %x REM XC REMXC BLK
  98
  99 %%
 100
 101 {P_INTEGER}             {
 102                                 /* integers without sign */
 103                                 yylval.i = atoi(yytext);
 104                                 return(P_INTEGER);
 105                         }
 106 {S_INTEGER}             {
 107                                 /* signed integers */
 108                                 yylval.i = atoi(yytext);
 109                                 return(S_INTEGER);
 110                         }
 111 {P_REAL}                {
 112                                 /* real numbers without sign */
 113                                 yylval.d = atof(yytext);
 114                                 return(P_REAL);
 115                         }
 116 {S_REAL}                {
 117                                 /* signel real numbers */
 118                                 yylval.d = atof(yytext);
 119                                 return(S_REAL);
 120                         }
 121
 122 {NOTE_P}                {
 123                                 /* note pitch */
 124                                 yylval.i = strchr(ascii_notes, *yytext) - ascii_notes;
 125                                 return(NOTE_P);
 126                         }
 127 {NOTE_T3}               { return(NOTE_T3); }
 128 {NOTE_T5}               { return(NOTE_T5); }
 129
 130 {NEW_MARK}              {
 131                                 /* create new mark */
 132                                 yylval.p = yytext + 1;
 133                                 return(NEW_MARK);
 134                         }
 135 {GOTO_MARK}             {
 136                                 /* go to mark */
 137                                 yylval.p = yytext + 1;
 138                                 return(GOTO_MARK);
 139                         }
 140 {ASSERT_MARK}           {
 141                                 /* assert mark */
 142                                 yylval.p = yytext + 1;
 143                                 return(ASSERT_MARK);
 144                         }
 145
 146 {ALTSTR}                {
 147                                 /* alteration string */
 148                                 yylval.p = yytext + 1;
 149                                 return(ALTSTR);
 150                         }
 151
 152 {WSPACE}                { ; /* ignore blanks */ }
 153
 154 \n                      { yyline++; }
 155
 156 \/\*                    { BEGIN REM; /* C-like comments */ }
 157 <REM>\*\/               { BEGIN 0; }
 158 <REM>\n                 { yyline++; }
 159 <REM>.                  { ; /* drop anything inside a comment */ }
 160
 161 \{                      { BEGIN XC; /* start of extended commands */ }
 162 <XC>\"[^\"]*\"          {
 163                                 /* double-quoted string */
 164                                 yytext[yyleng - 1] = '\0';
 165                                 yylval.p = strdup(yytext + 1);
 166                                 return(XC_STR);
 167                         }
 168 <XC>\'[^\']*\'          {
 169                                 /* single-quoted string */
 170                                 yytext[yyleng - 1] = '\0';
 171                                 yylval.p = strdup(yytext + 1);
 172                                 return(XC_STR);
 173                         }
 174 <XC>{P_INTEGER}         {
 175                                 yylval.i = atoi(yytext);
 176                                 return(P_INTEGER);
 177                         }
 178 <XC>{S_INTEGER}         {
 179                                 yylval.i = atoi(yytext);
 180                                 return(S_INTEGER);
 181                         }
 182 <XC>{P_REAL}            {
 183                                 yylval.d = atof(yytext);
 184                                 return(P_REAL);
 185                         }
 186 <XC>{S_REAL}            {
 187                                 yylval.d = atof(yytext);
 188                                 return(S_REAL);
 189                         }
 190 <XC>{P_REAL}s           {
 191                                 /* frame count, in seconds */
 192                                 yytext[yyleng - 1] = '\0';
 193                                 yylval.d = atof(yytext) * 1000;
 194                                 return(XC_MSECS);
 195                         }
 196 <XC>{P_REAL}ms          {
 197                                 /* frame count, in milliseconds */
 198                                 yytext[yyleng - 2] = '\0';
 199                                 yylval.d = atof(yytext);
 200                                 return(XC_MSECS);
 201                         }
 202 <XC>{NOTE_P}[\#\&]?{P_INTEGER} {
 203                                 char * ptr = yytext;
 204
 205                                 /* process note */
 206                                 yylval.i = strchr(ascii_notes, *ptr) - ascii_notes;
 207                                 ptr++;
 208
 209                                 /* process optional sharps or flats */
 210                                 if(*ptr == '#')
 211                                 {
 212                                         yylval.i++;
 213                                         ptr++;
 214                                 }
 215                                 else
 216                                 if(*ptr == '&')
 217                                 {
 218                                         yylval.i--;
 219                                         ptr++;
 220                                 }
 221
 222                                 /* process octave */
 223                                 yylval.i += atoi(ptr) * 12;
 224
 225                                 return(XC_ABSNOTE);
 226                         }
 227
 228 <XC>wav                 { return(SS_WAV); }
 229 <XC>pat                 { return(SS_PAT); }
 230 <XC>sustain             { return(SS_SUSTAIN); }
 231 <XC>vibrato             { return(SS_VIBRATO); }
 232 <XC>portamento          { return(SS_PORTAMENTO); }
 233 <XC>channel             { return(SS_CHANNEL); }
 234 <XC>vol                 { return(SS_VOL); }
 235
 236 <XC>delay               { return(SS_EFF_DELAY); }
 237 <XC>echo                { return(SS_EFF_ECHO); }
 238 <XC>comb                { return(SS_EFF_COMB); }
 239 <XC>allpass             { return(SS_EFF_ALLPASS); }
 240 <XC>flanger             { return(SS_EFF_FLANGER); }
 241 <XC>wobble              { return(SS_EFF_WOBBLE); }
 242 <XC>square_wobble       { return(SS_EFF_SQWOBBLE); }
 243 <XC>half_wobble         { return(SS_EFF_HFWOBBLE); }
 244 <XC>fader               { return(SS_EFF_FADER); }
 245 <XC>reverb              { return(SS_EFF_REVERB); }
 246 <XC>foldback            { return(SS_EFF_FOLDBACK); }
 247 <XC>off                 { return(SS_EFF_OFF); }
 248
 249 <XC>pitch_stretch       { return(SS_PITCH_STRETCH); }
 250 <XC>time_stretch        { return(SS_TIME_STRETCH); }
 251 <XC>print_wave_tempo    { return(SS_PRINT_WAVE_TEMPO); }
 252
 253 <XC>song_info           { return(SONG_INFO); }
 254
 255 <XC>midi_channel        { return(MIDI_CHANNEL); }
 256 <XC>midi_program        { return(MIDI_PROGRAM); }
 257 <XC>midi_generic        { return(MIDI_GENERIC); }
 258
 259 <XC>\/\*                { BEGIN REMXC; /* C-like comments inside XC */ }
 260 <REMXC>\*\/             { BEGIN XC; /* jump back to XC processing */ }
 261 <REMXC>\n               { yyline++; }
 262 <REMXC>.                { ; }
 263
 264 <XC>\}                  { BEGIN 0; }
 265 <XC>{WSPACE}            { ; /* ignore blanks */ }
 266 <XC>\n                  { yyline++; }
 267 <XC>.                   { return(*yytext); }
 268
 269 \(                      {
 270                                 /* start of block */
 271                                 ds_init(ds_blk);
 272                                 ds_blk_i = 1;
 273                                 BEGIN BLK;
 274                         }
 275 <BLK>\(                 { ds_blk_i++; ds_poke(ds_blk, *yytext); }
 276 <BLK>\)                 {
 277                                 /* one parentheses less */
 278                                 ds_blk_i--;
 279
 280                                 /* ok with block? */
 281                                 if(ds_blk_i == 0)
 282                                 {
 283                                         ds_poke(ds_blk, '\0');
 284                                         yylval.p = ds_blk.d;
 285
 286                                         BEGIN 0;
 287                                         return(BLOCK);
 288                                 }
 289                                 else
 290                                         ds_poke(ds_blk, ')');
 291                         }
 292 <BLK>\n                 { ds_poke(ds_blk, ' '); yyline++; }
 293 <BLK>.                  { ds_poke(ds_blk, *yytext); }
 294
 295 =[ \t\n]*{BLOCKNAME}    {
 296                                 /* block assignation */
 297                                 yylval.p = yytext + 1;
 298
 299                                 /* skip (possible) spaces between
 300                                    the = and the blockname; this lex
 301                                    rule is written this way to avoid
 302                                    having a global match for {BLOCKNAME},
 303                                    that could swallow notes and such,
 304                                    being mismatched as blocknames */
 305                                 while(*yylval.p == ' ' ||
 306                                       *yylval.p == '\n' ||
 307                                       *yylval.p == '\t')
 308                                         yylval.p++;
 309
 310                                 return(BLK_ASSIGN);
 311                         }
 312 \${BLOCKNAME}           {
 313                                 /* block insertion */
 314                                 yylval.p = yytext + 1;
 315                                 return(BLK_INSERT);
 316                         }
 317 `.+`                    {
 318                                 /* file inclusion */
 319                                 yytext[yyleng - 1] = '\0';
 320                                 yylval.p = yytext + 1;
 321                                 return(FILE_INSERT);
 322                         }
 323
 324 .                       { return(*yytext); }
 325
 326 %%
 327
 328 int yywrap(void) { return(1); }
 329
 330 char * ds_load(char * file)
 331 {
 332         struct ds s;
 333         int c;
 334         FILE * f;
 335
 336         if((f = libpath_fopen(file, "r")) == NULL)
 337                 return(NULL);
 338
 339         ds_init(s);
 340
 341         while((c = fgetc(f)) != EOF)
 342                 ds_poke(s, c);
 343
 344         ds_poke(s, '\0');
 345         fclose(f);
 346
 347         return(s.d);
 348 }
 349
 350
 351 int push_code(char * code)
 352 {
 353         struct code_stack * cs;
 354
 355         code_stack_i++;
 356         GROW(code_stack, code_stack_i, struct code_stack);
 357
 358         cs = &code_stack[code_stack_i];
 359
 360         cs->code = code;
 361         cs->offset = 0;
 362
 363         return(1);
 364 }
 365
 366
 367 int push_code_from_file(char * file)
 368 {
 369         char * c;
 370
 371         if((c = ds_load(file)) == NULL)
 372                 return(0);
 373
 374         push_code(c);
 375         return(1);
 376 }
 377
 378
 379 int code_getchar(void)
 380 {
 381         struct code_stack * cs;
 382         int c = '\0';
 383
 384         while(c == '\0' && code_stack_i > -1)
 385         {
 386                 /* get current char */
 387                 cs = &code_stack[code_stack_i];
 388                 c = cs->code[cs->offset++];
 389
 390                 /* end of code? */
 391                 if(c == '\0')
 392                 {
 393                         /* free */
 394                         free(cs->code);
 395
 396                         /* move to previous */
 397                         code_stack_i--;
 398
 399                         /* in any case, return a separator */
 400                         c = ' ';
 401                 }
 402         }
 403
 404         return(c);
 405 }
 406
 407
 408 int yy_input_for_flex(char * buf, int max)
 409 {
 410         buf[0] = code_getchar();
 411
 412         return(buf[0] == '\0' ? 0 : 1);
 413 }