configure.ac

   1 m4_define([adg_version],[0.9.0])
   2 m4_define([cpml_version],adg_version)
   3
   4 dnl How to handle {adg,cmpl}_lt_version (current:revision:age):
   5 dnl - ABI unmodified (e.g. refactoring):      current:revision+1:age
   6 dnl - Backward compatible ABI (e.g. new API): current+1:0:age+1
   7 dnl - Backward incompatible ABI:              current+1:0:0
   8 m4_define([adg_lt_version],[6:0:0])
   9 m4_define([cpml_lt_version],[3:1:1])
  10
  11 m4_define([gtkdoc_prereq],    [1.12]  )dnl Support introspection annotations
  12 m4_define([gobject_prereq],   [2.14.0])dnl Required by GRegex
  13 m4_define([cairo_prereq],     [1.7.4] )dnl Required by cairo_scaled_font_text_to_glyphs()
  14 m4_define([gtk2_prereq],      [2.18.0])dnl Required by gtk_widget_get_allocation()
  15 m4_define([gtk3_prereq],      [3.0.0] )dnl First stable release
  16 m4_define([pangocairo_prereq],[1.10.0])dnl Cairo support in Pango
  17 m4_define([gi_prereq],        [1.0.0] )dnl First stable release
  18
  19
  20 # Initialization
  21
  22 dnl autoconf 2.62 is required by GObject introspection:
  23 dnl http://live.gnome.org/GObjectIntrospection/AutotoolsIntegration
  24 AC_PREREQ([2.62])
  25 AC_INIT([adg-1],adg_version,[http://dev.entidi.com/p/adg/],[adg],[http://adg.entidi.com/])
  26 AC_CONFIG_SRCDIR([configure.ac])
  27 AC_CONFIG_HEADERS([src/config.h])
  28 AC_CONFIG_AUX_DIR([build])
  29 AC_CONFIG_MACRO_DIR([build])
  30 AM_INIT_AUTOMAKE([1.10 gnits no-dist-gzip dist-bzip2 -Wall -Wno-portability])
  31
  32 dnl m4 backward compatibility stuff
  33 m4_ifdef([AM_SILENT_RULES],
  34          [AM_SILENT_RULES([yes])],
  35          [AC_SUBST([AM_V_GEN],[])])
  36 m4_ifdef([AM_SUBST_NOTMAKE],[],
  37          [AC_DEFUN([AM_SUBST_NOTMAKE],[_AM_SUBST_NOTMAKE($@)])])
  38 m4_ifdef([AM_COND_IF],[],
  39          [AC_DEFUN([AM_COND_IF],
  40                    [AS_IF([test -z "$$1_TRUE"],[$2],[$3])])])
  41
  42 AC_DEFUN([ADG_DEPENDENCY],
  43          [EXTRADIR="$EXTRADIR --extra-dir=$($PKG_CONFIG --variable=prefix $1)/share/gtk-doc/html/$2"])
  44
  45 # Check for host information
  46
  47 AC_CANONICAL_HOST
  48 case "${host}" in
  49   *-*-linux*)
  50     guessed_host=linux
  51     ;;
  52   *-*-freebsd*)
  53     guessed_host=freebsd
  54     ;;
  55   *-*-mingw*)
  56     guessed_host=mingw
  57     ;;
  58   *-*-solaris*)
  59     guessed_host=solaris
  60     ;;
  61   *-*-darwin*)
  62     guessed_host=darwin
  63     ;;
  64   *-*-beos*)
  65     guessed_host=beos
  66     ;;
  67   *-*-cygwin*)
  68     guessed_host=cygwin
  69     ;;
  70   *-*-minix*)
  71     guessed_host=minix
  72     ;;
  73   *-*-aix*)
  74     guessed_host=aix
  75     ;;
  76   *)
  77     guessed_host=unknown
  78     ;;
  79 esac
  80 AM_CONDITIONAL([OS_UNIX],[test "${guessed_host}" != "mingw"])
  81 AM_CONDITIONAL([OS_WINDOWS],[test "${guessed_host}" = "mingw" -o "${guessed_host}" = "cygwin"])
  82
  83
  84 # Check for programs
  85
  86 AC_PROG_CC
  87 AC_PROG_SED
  88 PKG_PROG_PKG_CONFIG
  89 AC_PATH_PROG([XSLTPROC],[xsltproc],[/usr/bin/xsltproc])
  90 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums],[/usr/bin/glib-mkenums])
  91 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal],[/usr/bin/glib-genmarshal])
  92 AC_PATH_PROG([GTESTER],[gtester],[/usr/bin/gtester])
  93 AC_PATH_PROG([GTESTER_REPORT],[gtester-report],[/usr/bin/gtester-report])
  94 AC_PATH_PROG([GLADE3],[glade-3],[/usr/bin/glade-3])
  95 AC_ARG_VAR([TAR])
  96 AC_PATH_PROG([TAR],[tar],[/usr/bin/tar])
  97 AC_ARG_VAR([BZIP2])
  98 AC_PATH_PROG([BZIP2],[bzip2],[/usr/bin/bzip2])
  99
 100
 101 # Check for coverage build
 102
 103 dnl Coverage with gcov is available only for GNU gcc
 104 AS_IF([test "x$GNU" != "xyes"],
 105       [AC_ARG_ENABLE([gcov],
 106                      [AS_HELP_STRING([--enable-gcov],
 107                                      [enable coverage build @<:@default=no@:>@])],
 108                      [],[enable_gcov=no])])
 109 AS_IF([test "x$enable_gcov" = "xyes"],
 110       [AC_ARG_VAR([GCOV])
 111        AC_CHECK_TOOL([GCOV],[gcov],[/usr/bin/gcov])
 112        CFLAGS="$CFLAGS --coverage"
 113        LDFLAGS="$LDFLAGS --coverage"])
 114 AM_CONDITIONAL([ENABLE_GCOV],[test "x$enable_gcov" = "xyes"])
 115
 116
 117 # Check for libraries
 118
 119 AC_CHECK_LIB([m],[cos])
 120
 121 dnl On Windows, GLib 2.16 is required by _adg_dgettext() for the
 122 dnl g_win32_get_package_installation_directory_of_module() API.
 123 dnl On other platforms, it just needs to be in sync with GObject.
 124 AM_COND_IF([OS_WINDOWS],
 125            [AC_PATH_PROG([MAKENSIS],[makensis],[/usr/bin/makensis])
 126             AC_PATH_PROG([WINE],[wine])
 127             AC_ARG_VAR([WINDRES],[Command for Windows resources manipulation])
 128             AC_CHECK_TOOL([WINDRES],[windres])
 129             glib_prereq=2.16.0],
 130            [glib_prereq=]gobject_prereq)
 131
 132
 133 # Libtool initialization
 134
 135 AC_MSG_CHECKING([which libtool initialization strategy to adopt])
 136 AC_MSG_RESULT([m4_ifset([LT_INIT],[LT-INIT],[AC-PROG-LIBTOOL])])
 137 m4_ifset([LT_INIT],
 138          [LT_INIT([disable-static win32-dll])],
 139          [AC_DISABLE_STATIC
 140           AC_LIBTOOL_WIN32_DLL
 141           AC_PROG_LIBTOOL])
 142
 143
 144 # I18n
 145
 146 dnl The following macro is required in order to be able to use
 147 dnl autopoint (formerly called gettextize) from autoreconf.
 148 dnl The argument is a trade-off between modern and supported.
 149 AM_GNU_GETTEXT_VERSION([0.17])
 150
 151 AM_GNU_GETTEXT([external])
 152 AC_SUBST([ADG_API_PACKAGE],AC_PACKAGE_TARNAME)
 153 AC_SUBST([GETTEXT_PACKAGE],[${ADG_API_PACKAGE}])
 154 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${ADG_API_PACKAGE}"],
 155                    [Define to the domain used by gettext.])
 156
 157
 158 # Check for required packages
 159
 160 PKG_CHECK_MODULES([GLIB],[glib-2.0 >= ]${glib_prereq},
 161                   [glib_postfix=" (glib-$($PKG_CONFIG --modversion glib-2.0))"])
 162 ADG_DEPENDENCY([glib-2.0],[glib])
 163 PKG_CHECK_MODULES([GOBJECT],[gobject-2.0 >= ]gobject_prereq)
 164 ADG_DEPENDENCY([gobject-2.0],[gobject])
 165 PKG_CHECK_MODULES([CAIRO],[cairo >= ]cairo_prereq)
 166 ADG_DEPENDENCY([cairo],[cairo])
 167
 168
 169 # Check for optional packages
 170
 171 dnl PangoCairo
 172 AC_ARG_ENABLE([pango],
 173               [AS_HELP_STRING([--enable-pango],
 174                               [use pango for rendering text @<:@default=check@:>@])],
 175               [],[enable_pango=check])
 176 AS_IF([test "x${enable_pango}" != "xno"],
 177       [PKG_CHECK_MODULES([PANGO],[pangocairo >= ]pangocairo_prereq,
 178                          [enable_pango=yes
 179                           AC_DEFINE_UNQUOTED([PANGO_ENABLED],[1],
 180                                              [Defined if the pango support is enabled.])
 181                           ADG_DEPENDENCY([pangocairo],[pango])
 182                           pango_postfix=" (pangocairo-$($PKG_CONFIG --modversion pangocairo))"],
 183                          [AS_IF([test "x${enable_pango}" = "xyes"],
 184                                 [AC_MSG_ERROR([${PANGO_PKG_ERRORS} and pango support requested])],
 185                                 [enable_pango=no])])])
 186 AM_CONDITIONAL([HAVE_PANGO],[test "x${enable_pango}" = "xyes"])
 187
 188 dnl GTK+ support
 189 AC_ARG_WITH(gtk,
 190             [AS_HELP_STRING([--with-gtk@<:@=gtk2/gtk3@:>@],
 191                             [include GTK+ specific widgets @<:@default=check@:>@])],
 192             [],[with_gtk=check])
 193 AS_CASE(["${with_gtk}"],
 194         [gtk2],      [gtk2_pkg=yes; gtk3_pkg=no],
 195         [gtk3],      [gtk2_pkg=no;  gtk3_pkg=yes],
 196         [check|yes], [gtk2_pkg=yes; gtk3_pkg=yes],
 197         [no],        [gtk2_pkg=no;  gtk3_pkg=no],
 198         [AC_MSG_ERROR([Invalid option passed to --with-gtk])])
 199
 200 # GTK+ autodetection, giving precedence to GTK+3
 201 AS_IF([test "x${gtk3_pkg}" = "xyes"],
 202       [PKG_CHECK_MODULES([GTK3],[gtk+-3.0 >= ]gtk3_prereq,
 203                          [gtk_pkg=gtk3
 204                           ADG_DEPENDENCY([gtk+-3.0],[gtk3])],
 205                          [:])])
 206 AS_IF([test "x${gtk2_pkg}" = "xyes" -a "x${gtk_pkg}" = "x"],
 207       [PKG_CHECK_MODULES([GTK2],[gtk+-2.0 >= ]gtk2_prereq,
 208                          [gtk_pkg=gtk2
 209                           ADG_DEPENDENCY([gtk+-2.0],[gtk2])],
 210                          [:])])
 211 AS_IF([test "x${gtk_pkg}" != "x"],[with_gtk=${gtk_pkg}])
 212
 213 # Handle "check" graceful degradation
 214 AS_IF([test "x${with_gtk}" = "xcheck"],[with_gtk=no])
 215
 216 # Handle failures
 217 AS_IF([test "x${with_gtk}" != "xno" -a "x${gtk_pkg}" = "x"],
 218       [AC_MSG_ERROR([GTK+ support explicitely required but no valid GTK+ found])])
 219
 220 AS_IF([test "x${with_gtk}" = "xgtk3"],
 221       [gtk_postfix=" (gtk+-$($PKG_CONFIG --modversion gtk+-3.0))"
 222        AC_DEFINE_UNQUOTED([GTK3_ENABLED],[1],
 223                           [Defined if the GTK+3 support is enabled.])])
 224 AS_IF([test "x${with_gtk}" = "xgtk2"],
 225       [gtk_postfix=" (gtk+-$($PKG_CONFIG --modversion gtk+-2.0))"
 226        AC_DEFINE_UNQUOTED([GTK2_ENABLED],[1],
 227                           [Defined if the GTK+2 support is enabled.])])
 228
 229 AM_CONDITIONAL([HAVE_GTK], [test "x${with_gtk}" != "xno"])
 230 AM_CONDITIONAL([HAVE_GTK2],[test "x${with_gtk}" = "xgtk2"])
 231 AM_CONDITIONAL([HAVE_GTK3],[test "x${with_gtk}" = "xgtk3"])
 232
 233 dnl Glade catalog dir
 234 AC_ARG_WITH(glade_catalogdir,
 235             [AS_HELP_STRING([--with-glade-catalogdir@<:@=DIR@:>@],
 236                             [where to install the glade catalogs @<:@default=check@:>@])],
 237             [],[with_glade_catalogdir=check])
 238
 239 # Both "check" and "yes" mean gladeui autodetection,
 240 # but "yes" will fail on gladeui not found
 241 AS_IF([test "x${with_glade_catalogdir}" = "xcheck" -o "x${with_glade_catalogdir}" = "xyes"],
 242       [glade_pkg=check])
 243
 244 # gladeui autodetection, giving precedence to gladeui-2.0 if possible
 245 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_gtk}" != "xgtk2"],
 246       [PKG_CHECK_MODULES([GLADEUI2],[gladeui-2.0],[glade_pkg=gladeui-2.0],[:])])
 247 AS_IF([test "x${glade_pkg}" = "xcheck"],
 248       [PKG_CHECK_MODULES([GLADEUI1],[gladeui-1.0],[glade_pkg=gladeui-1.0],[:])])
 249 AS_IF([test "x${glade_pkg}" != "x" -a "x${glade_pkg}" != "xcheck"],
 250       [NTD_UNEXPAND([${glade_pkg}],
 251                     [catalogdir],
 252                     [with_glade_catalogdir="${NTD_UNEXPANDED}"],
 253                     [AC_MSG_ERROR([${glade_pkg} found but pkg-config file invalid])])])
 254
 255 # Handle "yes" failure
 256 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xyes"],
 257       [AC_MSG_ERROR([Glade support explicitely required but no valid gladeui found])])
 258
 259 # Handle "check" graceful degradation
 260 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xcheck"],
 261       [with_glade_catalogdir=no])
 262
 263 AM_CONDITIONAL([HAVE_GLADE],[test "x${with_glade_catalogdir}" != "xno"])
 264 AM_COND_IF([HAVE_GLADE],
 265            [enable_glade=yes
 266             report_glade="
 267                   Glade catalog dir: ${with_glade_catalogdir}"],
 268            [enable_glade=no
 269             report_glade=""])
 270 AC_SUBST([GLADE_CATALOGDIR],${with_glade_catalogdir})
 271
 272 dnl gtk-doc
 273 GTK_DOC_CHECK(gtkdoc_prereq)
 274 AS_IF([test "x$enable_gtk_doc" = "xyes"],
 275       [gtkdoc_postfix=" (gtk-doc-$($PKG_CONFIG --modversion gtk-doc))"])
 276
 277 dnl GObject introspection
 278 GOBJECT_INTROSPECTION_CHECK(gi_prereq)
 279
 280 dnl If introspection is used, GObject support in cairo must be enabled.
 281 dnl This in turn means cairo-gobject library must be present. That
 282 dnl library has been introduced in cairo 1.10.0.
 283 AS_IF([test "x$enable_introspection" = "xyes"],
 284       [PKG_CHECK_MODULES([CAIRO_GOBJECT],[cairo-gobject],
 285                          [AC_DEFINE_UNQUOTED([CAIRO_GOBJECT_ENABLED],[1],
 286                                              [Defined if GObject support in cairo is present.])],
 287                          [AC_MSG_ERROR([GObject introspection requires the cairo-gobject library])])])
 288 AS_IF([test "x$enable_introspection" = "xyes"],
 289       [report_introspection="
 290          Where to install gir files: $INTROSPECTION_GIRDIR
 291  Where to install the typelib files: $INTROSPECTION_TYPELIBDIR"],
 292       [report_introspection=""])
 293
 294
 295 dnl GLib test framework
 296 AC_ARG_ENABLE([test_framework],
 297               [AS_HELP_STRING([--enable-test-framework],
 298                               [enable GLib test framework @<:@default=check@:>@])],
 299               [],[enable_test_framework=check])
 300 AS_IF([test "x$enable_gcov" = "xyes"], [enable_test_framework=yes])
 301 AS_IF([test "x${enable_test_framework}" != "xno"],
 302       [PKG_CHECK_EXISTS([glib-2.0 >= 2.16.0],
 303                         [enable_test_framework=yes],
 304                         [AS_IF([test "x${enable_test_framework}" = "xyes"],
 305                                [AC_MSG_ERROR([The test framework needs glib2-2.16.0 or later])],
 306                                [enable_test_framework=no])])])
 307 AM_CONDITIONAL([HAVE_TEST_FRAMEWORK],[test "x${enable_test_framework}" = "xyes"])
 308
 309
 310 # Check for compiler characteristics
 311
 312 AC_C_CONST
 313
 314
 315 # Windows substitutions for NSis installer
 316
 317 dnl Get the HOSTPREFIX from gobject-2.0.pc: all the dependencies *must* be
 318 dnl installed under the same prefix.
 319 HOSTPREFIX="$($PKG_CONFIG --variable=prefix gobject-2.0)"
 320 AC_SUBST([HOSTPREFIX])
 321 AM_SUBST_NOTMAKE([HOSTPREFIX])
 322
 323 dnl -win$PACKAGE_ARCH will be appended to the installer file name
 324 AS_IF([test "x${host_cpu}" = "xx86_64"],[PACKAGE_ARCH=64],[PACKAGE_ARCH=32])
 325 AC_SUBST([PACKAGE_ARCH])
 326
 327
 328 # Additional substitutions
 329
 330 dnl The GObject dependency can be made optional by skipping
 331 dnl the building of the GObject wrappers.
 332 CPML_REQUIRES='cairo >= cairo_prereq gobject-2.0 >= gobject_prereq'
 333 AM_COND_IF([HAVE_PANGO],
 334       [ADG_REQUIRES='pangocairo >= pangocairo_prereq'
 335        ADG_H_ADDITIONAL='
 336 #include <pango/pango.h>
 337 #include "adg/adg-text.h"
 338 #include "adg/adg-pango-style.h"
 339 '],
 340       [ADG_REQUIRES='gobject-2.0 >= gobject_prereq'
 341        ADG_H_ADDITIONAL=''])
 342 AM_COND_IF([HAVE_GTK3],[ADG_REQUIRES='gtk+-3.0 >= gtk3_prereq'])
 343 AM_COND_IF([HAVE_GTK2],[ADG_REQUIRES='gtk+-2.0 >= gtk2_prereq'])
 344 AM_COND_IF([HAVE_GTK],
 345            [ADG_H_ADDITIONAL="${ADG_H_ADDITIONAL}
 346 #include <gtk/gtk.h>
 347 #include \"adg/adg-gtk-utils.h\"
 348 #include \"adg/adg-gtk-area.h\"
 349 #include \"adg/adg-gtk-layout.h\"
 350 "
 351             ADG_CANVAS_H_ADDITIONAL='
 352 #include <gtk/gtk.h>
 353
 354 void            adg_canvas_set_paper            (AdgCanvas      *canvas,
 355                                                  const gchar    *paper_name,
 356                                                  GtkPageOrientation orientation);
 357 void            adg_canvas_set_page_setup       (AdgCanvas      *canvas,
 358                                                  GtkPageSetup   *page_setup);
 359 GtkPageSetup *  adg_canvas_get_page_setup       (AdgCanvas      *canvas);
 360 '],
 361            [ADG_CANVAS_H_ADDITIONAL=''])
 362
 363 AC_SUBST([CPML_LT_VERSION],cpml_lt_version)
 364 AC_SUBST([CPML_REQUIRES])
 365 AC_SUBST([ADG_LT_VERSION],adg_lt_version)
 366 AC_SUBST([ADG_REQUIRES])
 367 AC_SUBST([ADG_H_ADDITIONAL])
 368 AC_SUBST([ADG_CANVAS_H_ADDITIONAL])
 369
 370 AM_SUBST_NOTMAKE([CPML_REQUIRES])
 371 AM_SUBST_NOTMAKE([ADG_REQUIRES])
 372 AM_SUBST_NOTMAKE([ADG_H_ADDITIONAL])
 373 AM_SUBST_NOTMAKE([ADG_CANVAS_H_ADDITIONAL])
 374
 375 dnl CPML compiler flags and library dependencies
 376 CPML_CFLAGS="$CAIRO_CFLAGS $GOBJECT_CFLAGS"
 377 CPML_LIBS="$CAIRO_LIBS $GOBJECT_LIBS"
 378 AC_SUBST([CPML_CFLAGS])
 379 AC_SUBST([CPML_LIBS])
 380
 381 dnl ADG compiler flags and library dependencies
 382 ADG_CFLAGS="$CAIRO_GOBJECT_CFLAGS"
 383 ADG_LIBS="$CAIRO_GOBJECT_LIBS"
 384 AM_COND_IF([HAVE_PANGO],
 385            [ADG_CFLAGS="$PANGO_CFLAGS $ADG_CFLAGS"
 386             ADG_LIBS="$PANGO_LIBS $ADG_LIBS"])
 387 AM_COND_IF([HAVE_GTK2],
 388            [ADG_CFLAGS="$GTK2_CFLAGS $ADG_CFLAGS"
 389             ADG_LIBS="$GTK2_LIBS $ADG_LIBS"])
 390 AM_COND_IF([HAVE_GTK3],
 391            [ADG_CFLAGS="$GTK3_CFLAGS $ADG_CFLAGS"
 392             ADG_LIBS="$GTK3_LIBS $ADG_LIBS"])
 393 AC_SUBST([ADG_CFLAGS])
 394 AC_SUBST([ADG_LIBS])
 395
 396 AC_SUBST([EXTRADIR])
 397
 398
 399 # Generation
 400
 401 AC_CONFIG_FILES([build/Custom.nsh
 402                  Makefile
 403                  src/Makefile
 404                  src/tests/Makefile
 405                  src/cpml/cpml-1.pc
 406                  src/cpml/Makefile
 407                  src/cpml/tests/Makefile
 408                  src/adg/adg-1.pc
 409                  src/adg.h
 410                  src/adg/Makefile
 411                  src/adg/adg-canvas.h
 412                  src/adg/tests/Makefile
 413                  demo/Makefile
 414                  demo/cpml-demo.ui
 415                  demo/adg-demo.ui
 416                  po/Makefile.in
 417                  docs/Makefile
 418                  docs/cpml/Makefile
 419                  docs/cpml/bookinfo.xml
 420                  docs/adg/Makefile
 421                  docs/adg/bookinfo.xml])
 422 AC_CONFIG_FILES([demo/adg-glade],[chmod +x demo/adg-glade])
 423 AC_OUTPUT
 424
 425
 426 # Report
 427
 428 AC_MSG_NOTICE([generating report
 429
 430 AC_PACKAGE_NAME adg_version will be built with the following options:
 431 ----------------------------------------------------------
 432                 CPML library to use: internal (cpml-adg_version)
 433          Build pango based entities: ${enable_pango}${pango_postfix}
 434                        GTK+ support: ${with_gtk}${gtk_postfix}
 435              Install glade catalogs: ${enable_glade}${report_glade}
 436                 Build API reference: ${enable_gtk_doc}${gtkdoc_postfix}
 437              GObject instrospection: ${enable_introspection}${report_introspection}
 438                 Test coverage build: ${enable_gcov}
 439              Test framework support: ${enable_test_framework}${glib_postfix}
 440 ])