configure.ac

   1 m4_define([adg_version],[0.7.5])
   2 m4_define([adg_api_version],[1.0])
   3 m4_define([adg_lt_version],[3:0:0])
   4
   5 m4_define([cpml_version],adg_version)
   6 m4_define([cpml_api_version],adg_api_version)
   7 m4_define([cpml_lt_version],[2:0:0])
   8
   9 m4_define([gtkdoc_prereq],    [1.12]  )dnl Support introspection annotations
  10 m4_define([gobject_prereq],   [2.10.1])dnl Required by GTypeInitiallyUnowned (glib 2.10.0 was broken)
  11 m4_define([cairo_prereq],     [1.7.4] )dnl Required by cairo_scaled_font_text_to_glyphs()
  12 m4_define([gtk2_prereq],      [2.18.0])dnl Required by gtk_widget_get_allocation()
  13 m4_define([gtk3_prereq],      [3.0.0] )dnl First stable release
  14 m4_define([pangocairo_prereq],[1.10.0])dnl Cairo support in Pango
  15 m4_define([gi_prereq],        [1.0.0] )dnl First stable release
  16
  17
  18 # Initialization
  19
  20 dnl autoconf 2.62 is required by GObject introspection:
  21 dnl http://live.gnome.org/GObjectIntrospection/AutotoolsIntegration
  22 AC_PREREQ([2.62])
  23 AC_INIT([adg-1],adg_version,[http://dev.entidi.com/p/adg/],[adg],[http://adg.entidi.com/])
  24 AC_CONFIG_SRCDIR([configure.ac])
  25 AC_CONFIG_HEADERS([src/config.h])
  26 AC_CONFIG_AUX_DIR([build])
  27 AC_CONFIG_MACRO_DIR([build])
  28 AM_INIT_AUTOMAKE([1.10 gnits no-dist-gzip dist-bzip2 -Wall -Wno-portability])
  29
  30 dnl m4 backward compatibility stuff
  31 m4_ifdef([AM_SILENT_RULES],
  32          [AM_SILENT_RULES([yes])],
  33          [AC_SUBST([AM_V_GEN],[])])
  34 m4_ifdef([AM_SUBST_NOTMAKE],[],
  35          [AC_DEFUN([AM_SUBST_NOTMAKE],[_AM_SUBST_NOTMAKE($@)])])
  36 m4_ifdef([AM_COND_IF],[],
  37          [AC_DEFUN([AM_COND_IF],
  38                    [AS_IF([test -z "$$1_TRUE"],[$2],[$3])])])
  39
  40 AC_DEFUN([ADG_DEPENDENCY],
  41          [EXTRADIR="$EXTRADIR --extra-dir=$($PKG_CONFIG --variable=prefix $1)/share/gtk-doc/html/$2"])
  42
  43 # Check for host information
  44
  45 AC_CANONICAL_HOST
  46 case "${host}" in
  47   *-*-linux*)
  48     guessed_host=linux
  49     ;;
  50   *-*-freebsd*)
  51     guessed_host=freebsd
  52     ;;
  53   *-*-mingw*)
  54     guessed_host=mingw
  55     ;;
  56   *-*-solaris*)
  57     guessed_host=solaris
  58     ;;
  59   *-*-darwin*)
  60     guessed_host=darwin
  61     ;;
  62   *-*-beos*)
  63     guessed_host=beos
  64     ;;
  65   *-*-cygwin*)
  66     guessed_host=cygwin
  67     ;;
  68   *-*-minix*)
  69     guessed_host=minix
  70     ;;
  71   *-*-aix*)
  72     guessed_host=aix
  73     ;;
  74   *)
  75     guessed_host=unknown
  76     ;;
  77 esac
  78 AM_CONDITIONAL([OS_UNIX],[test "${guessed_host}" != "mingw"])
  79 AM_CONDITIONAL([OS_WINDOWS],[test "${guessed_host}" = "mingw" -o "${guessed_host}" = "cygwin"])
  80
  81
  82 # Check for programs
  83
  84 AC_PROG_CC
  85 AC_PROG_SED
  86 PKG_PROG_PKG_CONFIG
  87 AC_PATH_PROG([XSLTPROC],[xsltproc],[/usr/bin/xsltproc])
  88 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums],[/usr/bin/glib-mkenums])
  89 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal],[/usr/bin/glib-genmarshal])
  90 AC_PATH_PROG([GTESTER],[gtester],[/usr/bin/gtester])
  91 AC_PATH_PROG([GTESTER_REPORT],[gtester-report],[/usr/bin/gtester-report])
  92 AC_PATH_PROG([GLADE3],[glade-3],[/usr/bin/glade-3])
  93
  94
  95 # Check for coverage build
  96
  97 dnl Coverage with gcov is available only for GNU gcc
  98 AS_IF([test "x$GNU" != "xyes"],
  99       [AC_ARG_ENABLE([gcov],
 100                      [AS_HELP_STRING([--enable-gcov],
 101                                      [enable coverage build @<:@default=no@:>@])],
 102                      [],[enable_gcov=no])])
 103 AS_IF([test "x$enable_gcov" = "xyes"],
 104       [AC_ARG_VAR([GCOV])
 105        AC_CHECK_TOOL([GCOV],[gcov],[/usr/bin/gcov])
 106        CFLAGS="$CFLAGS --coverage"
 107        LDFLAGS="$LDFLAGS --coverage"])
 108 AM_CONDITIONAL([ENABLE_GCOV],[test "x$enable_gcov" = "xyes"])
 109
 110
 111 # Check for libraries
 112
 113 AC_CHECK_LIB([m],[cos])
 114
 115
 116 dnl GLib 2.16 is required by _adg_dgettext() for
 117 dnl g_win32_get_package_installation_directory_of_module()
 118 AM_COND_IF([OS_WINDOWS],
 119            [AC_PATH_PROG([MAKENSIS],[makensis],[/usr/bin/makensis])
 120             AC_PATH_PROG([WINE],[wine])
 121             AC_ARG_VAR([WINDRES],[Command for Windows resources manipulation])
 122             AC_CHECK_TOOL([WINDRES],[windres])
 123             PKG_CHECK_MODULES([GLIB],[glib-2.0 >= 2.16])])
 124
 125
 126 # Libtool initialization
 127
 128 AC_MSG_CHECKING([which libtool initialization strategy to adopt])
 129 AC_MSG_RESULT([m4_ifset([LT_INIT],[LT-INIT],[AC-PROG-LIBTOOL])])
 130 m4_ifset([LT_INIT],
 131          [LT_INIT([disable-static win32-dll])],
 132          [AC_DISABLE_STATIC
 133           AC_LIBTOOL_WIN32_DLL
 134           AC_PROG_LIBTOOL])
 135
 136
 137 # I18n
 138
 139 dnl The following macro is required in order to be able to use
 140 dnl autopoint (formerly called gettextize) from autoreconf.
 141 dnl The argument is a trade-off between modern and supported.
 142 AM_GNU_GETTEXT_VERSION([0.17])
 143
 144 AM_GNU_GETTEXT([external])
 145 AC_SUBST([ADG_API_PACKAGE],AC_PACKAGE_TARNAME)
 146 AC_SUBST([GETTEXT_PACKAGE],[${ADG_API_PACKAGE}])
 147 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${ADG_API_PACKAGE}"],
 148                    [Define to the domain used by gettext.])
 149
 150
 151 # Check for required packages
 152
 153 PKG_CHECK_MODULES([GLIB],[glib-2.0])
 154 ADG_DEPENDENCY([glib-2.0],[glib])
 155 PKG_CHECK_MODULES([GOBJECT],[gobject-2.0 >= ]gobject_prereq)
 156 ADG_DEPENDENCY([gobject-2.0],[gobject])
 157 PKG_CHECK_MODULES([CAIRO],[cairo >= ]cairo_prereq)
 158 ADG_DEPENDENCY([cairo],[cairo])
 159
 160
 161 # Check for optional packages
 162
 163 dnl PangoCairo
 164 AC_ARG_ENABLE([pango],
 165               [AS_HELP_STRING([--enable-pango],
 166                               [use pango for rendering text @<:@default=check@:>@])],
 167               [],[enable_pango=check])
 168 AS_IF([test "x${enable_pango}" != "xno"],
 169       [PKG_CHECK_MODULES([PANGO],[pangocairo >= ]pangocairo_prereq,
 170                          [enable_pango=yes
 171                           AC_DEFINE_UNQUOTED([PANGO_ENABLED],[1],
 172                                              [Defined if the pango support is enabled.])
 173                           ADG_DEPENDENCY([pangocairo],[pango])],
 174                          [AS_IF([test "x${enable_pango}" = "xyes"],
 175                                 [AC_MSG_ERROR([${PANGO_PKG_ERRORS} and pango support requested])],
 176                                 [enable_pango=no])])])
 177 AM_CONDITIONAL([HAVE_PANGO],[test "x${enable_pango}" = "xyes"])
 178
 179 dnl GTK+ support
 180 AC_ARG_WITH(gtk,
 181             [AS_HELP_STRING([--with-gtk@<:@=gtk2/gtk3@:>@],
 182                             [include GTK+ specific widgets @<:@default=check@:>@])],
 183             [],[with_gtk=check])
 184 AS_CASE(["${with_gtk}"],
 185         [gtk2],      [gtk2_pkg=yes; gtk3_pkg=no],
 186         [gtk3],      [gtk2_pkg=no;  gtk3_pkg=yes],
 187         [check|yes], [gtk2_pkg=yes; gtk3_pkg=yes],
 188         [no],        [gtk2_pkg=no;  gtk3_pkg=no],
 189         [AC_MSG_ERROR([Invalid option passed to --with-gtk])])
 190
 191 # GTK+ autodetection, giving precedence to GTK+3
 192 AS_IF([test "x${gtk3_pkg}" = "xyes"],
 193       [PKG_CHECK_MODULES([GTK3],[gtk+-3.0 >= ]gtk3_prereq,
 194                          [gtk_pkg=gtk3
 195                           ADG_DEPENDENCY([gtk+-3.0],[gtk3])],
 196                          [:])])
 197 AS_IF([test "x${gtk2_pkg}" = "xyes" -a "x${gtk_pkg}" = "x"],
 198       [PKG_CHECK_MODULES([GTK2],[gtk+-2.0 >= ]gtk2_prereq,
 199                          [gtk_pkg=gtk2
 200                           ADG_DEPENDENCY([gtk+-2.0],[gtk2])],
 201                          [:])])
 202 AS_IF([test "x${gtk_pkg}" != "x"],[with_gtk=${gtk_pkg}])
 203
 204 # Handle "check" graceful degradation
 205 AS_IF([test "x${with_gtk}" = "xcheck"],[with_gtk=no])
 206
 207 # Handle failures
 208 AS_IF([test "x${with_gtk}" != "xno" -a "x${gtk_pkg}" = "x"],
 209       [AC_MSG_ERROR([GTK+ support explicitely required but no valid GTK+ found])])
 210
 211 AS_IF([test "x${with_gtk}" = "xgtk3"],
 212       [AC_DEFINE_UNQUOTED([GTK3_ENABLED],[1],
 213                           [Defined if the GTK+3 support is enabled.])])
 214 AS_IF([test "x${with_gtk}" = "xgtk2"],
 215       [AC_DEFINE_UNQUOTED([GTK2_ENABLED],[1],
 216                           [Defined if the GTK+2 support is enabled.])])
 217
 218 AM_CONDITIONAL([HAVE_GTK], [test "x${with_gtk}" != "xno"])
 219 AM_CONDITIONAL([HAVE_GTK2],[test "x${with_gtk}" = "xgtk2"])
 220 AM_CONDITIONAL([HAVE_GTK3],[test "x${with_gtk}" = "xgtk3"])
 221
 222 dnl Glade catalog dir
 223 AC_ARG_WITH(glade_catalogdir,
 224             [AS_HELP_STRING([--with-glade-catalogdir@<:@=DIR@:>@],
 225                             [where to install the glade catalogs @<:@default=check@:>@])],
 226             [],[with_glade_catalogdir=check])
 227
 228 # Both "check" and "yes" mean gladeui autodetection,
 229 # but "yes" will fail on gladeui not found
 230 AS_IF([test "x${with_glade_catalogdir}" = "xcheck" -o "x${with_glade_catalogdir}" = "xyes"],
 231       [glade_pkg=check])
 232
 233 # gladeui autodetection, giving precedence to gladeui-2.0 if possible
 234 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_gtk}" != "xgtk2"],
 235       [PKG_CHECK_MODULES([GLADEUI2],[gladeui-2.0],[glade_pkg=gladeui-2.0],[:])])
 236 AS_IF([test "x${glade_pkg}" = "xcheck"],
 237       [PKG_CHECK_MODULES([GLADEUI1],[gladeui-1.0],[glade_pkg=gladeui-1.0],[:])])
 238 AS_IF([test "x${glade_pkg}" != "x" -a "x${glade_pkg}" != "xcheck"],
 239       [NTD_UNEXPAND([${glade_pkg}],
 240                     [catalogdir],
 241                     [with_glade_catalogdir="${NTD_UNEXPANDED}"],
 242                     [AC_MSG_ERROR([${glade_pkg} found but pkg-config file invalid])])])
 243
 244 # Handle "yes" failure
 245 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xyes"],
 246       [AC_MSG_ERROR([Glade support explicitely required but no valid gladeui found])])
 247
 248 # Handle "check" graceful degradation
 249 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xcheck"],
 250       [with_glade_catalogdir=no])
 251
 252 AM_CONDITIONAL([HAVE_GLADE],[test "x${with_glade_catalogdir}" != "xno"])
 253 AM_COND_IF([HAVE_GLADE],
 254            [enable_glade=yes
 255             report_glade="
 256                   Glade catalog dir: ${with_glade_catalogdir}"],
 257            [enable_glade=no
 258             report_glade=""])
 259 AC_SUBST([GLADE_CATALOGDIR],${with_glade_catalogdir})
 260
 261 dnl gtk-doc
 262 GTK_DOC_CHECK(gtkdoc_prereq)
 263
 264 dnl GObject introspection
 265 GOBJECT_INTROSPECTION_CHECK(gi_prereq)
 266 AC_ARG_WITH(girdir,
 267             [AS_HELP_STRING([--with-girdir=DIR],
 268                             [where the gir files are installed @<:@default=check@:>@])],
 269             [],[with_girdir=check])
 270 AS_IF([test "x${enable_introspection}" = "xyes" -a "x${with_girdir}" = "xcheck"],
 271       [NTD_UNEXPAND([gobject-introspection-1.0],
 272                     [girdir],
 273                     [with_girdir="${NTD_UNEXPANDED}"])])
 274 AC_SUBST([GIRDIR],${with_girdir})
 275 AC_ARG_WITH(typelibdir,
 276             [AS_HELP_STRING([--with-typelibdir=DIR],
 277                             [where the typelib files are installed @<:@default=check@:>@])],
 278             [],[with_typelibdir=check])
 279 AS_IF([test "x${enable_introspection}" = "xyes" -a "x${with_typelibdir}" = "xcheck"],
 280       [NTD_UNEXPAND([gobject-introspection-1.0],
 281                     [typelibdir],
 282                     [with_typelibdir="${NTD_UNEXPANDED}"])])
 283 AC_SUBST([TYPELIBDIR],${with_typelibdir})
 284 AM_COND_IF([HAVE_INTROSPECTION],
 285            [report_introspection="
 286          Where to install gir files: ${with_girdir}
 287  Where to install the typelib files: ${with_typelibdir}"],
 288            [report_introspection=""])
 289
 290 dnl If introspection is used GObject support in cairo must be enabled,
 291 dnl that is the cairo-gobject library must be present. That support
 292 dnl was introduced since cairo 1.10.0.
 293 PKG_CHECK_MODULES([CAIRO_GOBJECT],[cairo-gobject],
 294                   [AC_DEFINE_UNQUOTED([CAIRO_GOBJECT_ENABLED],[1],
 295                                       [Defined if GObject support in cairo is present.])],
 296                   [AS_IF([test "x${enable_introspection}" = "xyes"],
 297                          [AC_MSG_ERROR([GObject introspection requires the cairo-gobject library])])])
 298
 299 dnl GLib test framework
 300 AC_ARG_ENABLE([test_framework],
 301               [AS_HELP_STRING([--enable-test-framework],
 302                               [enable GLib test framework @<:@default=check@:>@])],
 303               [],[enable_test_framework=check])
 304 AS_IF([test "x$enable_gcov" = "xyes"], [enable_test_framework=yes])
 305 AS_IF([test "x${enable_test_framework}" != "xno"],
 306       [PKG_CHECK_EXISTS([glib-2.0 >= 2.16.0],
 307                         [enable_test_framework=yes],
 308                         [AS_IF([test "x${enable_test_framework}" = "xyes"],
 309                                [AC_MSG_ERROR([The test framework needs glib2-2.16.0 or later])],
 310                                [enable_test_framework=no])])])
 311 AM_CONDITIONAL([HAVE_TEST_FRAMEWORK],[test "x${enable_test_framework}" = "xyes"])
 312
 313
 314 # Check for compiler characteristics
 315
 316 AC_C_CONST
 317
 318
 319 # Windows substitutions for NSis installer
 320
 321 dnl Get the USRDIR from gobject-2.0.pc: all the dependencies *must* be
 322 dnl installed under the same prefix.
 323 USRDIR="$($PKG_CONFIG --variable=prefix gobject-2.0)"
 324 AC_SUBST([USRDIR])
 325 AM_SUBST_NOTMAKE([USRDIR])
 326
 327 dnl -win$PACKAGE_ARCH will be appended to the installer file name
 328 AS_IF([test "x${host_cpu}" = "xx86_64"],[PACKAGE_ARCH=64],[PACKAGE_ARCH=32])
 329 AC_SUBST([PACKAGE_ARCH])
 330
 331
 332 # Additional substitutions
 333
 334 dnl The GObject dependency can be made optional by skipping
 335 dnl the building of the GObject wrappers.
 336 CPML_REQUIRES='cairo >= cairo_prereq gobject-2.0 >= gobject_prereq'
 337 AM_COND_IF([HAVE_PANGO],
 338       [ADG_REQUIRES='pangocairo >= pangocairo_prereq'
 339        ADG_H_ADDITIONAL='
 340 #include <pango/pango.h>
 341 #include "adg/adg-text.h"
 342 #include "adg/adg-pango-style.h"
 343 '],
 344       [ADG_REQUIRES='gobject-2.0 >= gobject_prereq'
 345        ADG_H_ADDITIONAL=''])
 346 AM_COND_IF([HAVE_GTK3],[ADG_REQUIRES='gtk+-3.0 >= gtk3_prereq'])
 347 AM_COND_IF([HAVE_GTK2],[ADG_REQUIRES='gtk+-2.0 >= gtk2_prereq'])
 348 AM_COND_IF([HAVE_GTK],
 349            [ADG_H_ADDITIONAL="${ADG_H_ADDITIONAL}
 350 #include <gtk/gtk.h>
 351 #include \"adg/adg-gtk-utils.h\"
 352 #include \"adg/adg-gtk-area.h\"
 353 #include \"adg/adg-gtk-layout.h\"
 354 "
 355             ADG_CANVAS_H_ADDITIONAL='
 356 #include <gtk/gtk.h>
 357
 358 void            adg_canvas_set_paper            (AdgCanvas      *canvas,
 359                                                  const gchar    *paper_name,
 360                                                  GtkPageOrientation orientation);
 361 void            adg_canvas_set_page_setup       (AdgCanvas      *canvas,
 362                                                  GtkPageSetup   *page_setup);
 363 GtkPageSetup *  adg_canvas_get_page_setup       (AdgCanvas      *canvas);
 364 '],
 365            [ADG_CANVAS_H_ADDITIONAL=''])
 366
 367 AC_SUBST([CPML_API_VERSION],cpml_api_version)
 368 AC_SUBST([CPML_LT_VERSION],cpml_lt_version)
 369 AC_SUBST([CPML_REQUIRES])
 370 AC_SUBST([ADG_API_VERSION],adg_api_version)
 371 AC_SUBST([ADG_LT_VERSION],adg_lt_version)
 372 AC_SUBST([ADG_REQUIRES])
 373 AC_SUBST([ADG_H_ADDITIONAL])
 374 AC_SUBST([ADG_CANVAS_H_ADDITIONAL])
 375
 376 AM_SUBST_NOTMAKE([CPML_REQUIRES])
 377 AM_SUBST_NOTMAKE([ADG_REQUIRES])
 378 AM_SUBST_NOTMAKE([ADG_H_ADDITIONAL])
 379 AM_SUBST_NOTMAKE([ADG_CANVAS_H_ADDITIONAL])
 380
 381 dnl CPML compiler flags and library dependencies
 382 CPML_CFLAGS="$CAIRO_CFLAGS $GOBJECT_CFLAGS"
 383 CPML_LIBS="$CAIRO_LIBS $GOBJECT_LIBS"
 384 AC_SUBST([CPML_CFLAGS])
 385 AC_SUBST([CPML_LIBS])
 386
 387 dnl ADG compiler flags and library dependencies
 388 ADG_CFLAGS="$CAIRO_GOBJECT_CFLAGS"
 389 ADG_LIBS="$CAIRO_GOBJECT_LIBS"
 390 AM_COND_IF([HAVE_PANGO],
 391            [ADG_CFLAGS="$PANGO_CFLAGS $ADG_CFLAGS"
 392             ADG_LIBS="$PANGO_LIBS $ADG_LIBS"])
 393 AM_COND_IF([HAVE_GTK2],
 394            [ADG_CFLAGS="$GTK2_CFLAGS $ADG_CFLAGS"
 395             ADG_LIBS="$GTK2_LIBS $ADG_LIBS"])
 396 AM_COND_IF([HAVE_GTK3],
 397            [ADG_CFLAGS="$GTK3_CFLAGS $ADG_CFLAGS"
 398             ADG_LIBS="$GTK3_LIBS $ADG_LIBS"])
 399 AC_SUBST([ADG_CFLAGS])
 400 AC_SUBST([ADG_LIBS])
 401
 402 AC_SUBST([EXTRADIR])
 403
 404
 405 # Generation
 406
 407 AC_CONFIG_FILES([build/Custom.nsh
 408                  Makefile
 409                  src/Makefile
 410                  src/cpml/cpml-1.pc
 411                  src/cpml/Makefile
 412                  src/cpml/tests/Makefile
 413                  src/adg/adg-1.pc
 414                  src/adg.h
 415                  src/adg/Makefile
 416                  src/adg/adg-canvas.h
 417                  src/adg/tests/Makefile
 418                  demo/Makefile
 419                  demo/cpml-demo.ui
 420                  demo/adg-demo.ui
 421                  po/Makefile.in
 422                  docs/Makefile
 423                  docs/cpml/Makefile
 424                  docs/cpml/bookinfo.xml
 425                  docs/adg/Makefile
 426                  docs/adg/bookinfo.xml])
 427 AC_CONFIG_FILES([demo/adg-glade],[chmod +x demo/adg-glade])
 428 AC_OUTPUT
 429
 430
 431 # Report
 432
 433 AC_MSG_NOTICE([generating report
 434
 435 AC_PACKAGE_NAME adg_version will be built with the following options:
 436 ----------------------------------------------------------
 437                   API compatibility: adg_api_version
 438                 CPML library to use: internal (cpml-adg_version)
 439          Build pango based entities: ${enable_pango}
 440                        GTK+ support: ${with_gtk}
 441              Install glade catalogs: ${enable_glade}${report_glade}
 442                 Build API reference: ${enable_gtk_doc}
 443              GObject instrospection: ${enable_introspection}${report_introspection}
 444                 Test coverage build: ${enable_gcov}
 445              Test framework support: ${enable_test_framework}
 446 ])