configure.ac

   1 nl Initialize autoconf and automake
   2 AC_INIT
   3 AC_CONFIG_SRCDIR(src/main.c)
   4 AC_PREREQ(2.52)
   5 AM_INIT_AUTOMAKE(adesklets,0.6.2)
   6 AM_MAINTAINER_MODE
   7
   8 dnl Language selection
   9 AC_LANG(C)
  10
  11 dnl Locate required external software
  12 AC_PROG_CPP
  13 if test "x$CPP" != 'x'; then
  14 :
  15 AC_SUBST(CPP)
  16 fi
  17 AC_PROG_CC
  18 AM_PROG_LEX
  19 if test "x$LEX" != 'xflex'; then
  20 AC_MSG_WARN([
  21 -----------------------------------------------------
  22 `flex' was not found on your system. If you encounter
  23 problems recompiling a `l' file, please try `flex'
  24 first. You can get it from any GNU archive site.
  25 You will not need `flex' as long as you do not
  26 modify `l' files.
  27 ----------------------------------------------------])
  28 fi
  29 AC_PROG_YACC
  30 if test "x$YACC" != "xbison -y"; then
  31 AC_MSG_WARN([
  32 -----------------------------------------------------
  33 Nor `byacc' or `yacc' parsers had been used
  34 for developing adesklets. If you encounter problems
  35 recompiling a `y' file, please try `bison' instead.
  36 You can get it from any GNU archive site. You will
  37 not need `bison' as long as you do not modify
  38 `y' files.
  39 -----------------------------------------------------])
  40 fi
  41 AC_PROG_INSTALL
  42
  43 dnl Check for python support
  44 withval=
  45 AC_ARG_WITH(python-support,
  46 [  --without-python-support
  47                           do not install adesklets python package
  48                           Do not set this option unless you have
  49                           good reasons])
  50 : ${withval:=yes}
  51 if test x$withval = "xyes"; then
  52 withval=
  53 AC_ARG_WITH(python-force-detection,
  54 [  --with-python-force-detection
  55                           bypass all the python version check mechanism.
  56                           When using this, make sure you have a version
  57                           greater or egal to python 2.3 installed
  58                           as 'python' in your path [default=no]])
  59 : ${withval:=no}
  60 if test x$withval = "xno"; then
  61 AM_PATH_PYTHON([2.3])
  62 else
  63 AM_PATH_PYTHON()
  64 fi
  65 AC_PYTHON_DEVEL
  66 withval=
  67 AC_ARG_WITH(python-install-submission-scripts,
  68 [  --with-python-install-submission-scripts
  69                           install in the path the submission-related scripts
  70                           from submit/ in the $PREFIX/bin program path.
  71                           Useful for desklets author [default=no]])
  72 : ${withval:=no}
  73 if test x$withval = "xyes"; then
  74 AM_CONDITIONAL(PYTHON_INSTALL_SUBMISSION_SCRIPTS, true)
  75 else
  76 AM_CONDITIONAL(PYTHON_INSTALL_SUBMISSION_SCRIPTS, false)
  77 fi
  78 AC_CHECK_FUNCS(sigprocmask,
  79 [HAVE_SIGPROCMASK="#define HAVE_SIGPROCMASK 1", SIGPROC=yes],
  80 [HAVE_SIGPROCMASK="#undef HAVE_SIGPROCMASK"])
  81 else
  82 HAVE_SIGPROCMASK="#undef HAVE_SIGPROCMASK"
  83 fi
  84 AC_SUBST(HAVE_SIGPROCMASK)
  85 AM_CONDITIONAL(PYTHON_SUPPORT, test "x$PYTHON" != "x")
  86 AM_CONDITIONAL(PYTHON_INSTALL_SUBMISSION_SCRIPTS, true)
  87
  88 dnl Check for Perl support
  89 withval=
  90 AC_ARG_WITH(perl-support,
  91 [  --without-perl-support  do not install adesklets Perl package
  92                           Do not set this option unless you have
  93                           good reasons])
  94 : ${withval:=yes}
  95 perl_ok=false
  96 if test x$withval = "xyes"; then
  97 AC_PATH_PROG(PERL, perl)
  98 AC_PROG_PERL_VERSION(5.8.2,
  99         AC_PROG_PERL_MODULES(IPC::Open3, perl_ok=true),
 100         AC_MSG_WARN(['Perl >= 5.8.2 could not be found']))
 101 fi
 102 AM_CONDITIONAL(PERL_SUPPORT,$perl_ok)
 103
 104 dnl help2man presence
 105 AC_PATH_PROG(HELP2MAN, help2man)
 106 AM_CONDITIONAL(HELP2MAN_SUPPORT, test "x$HELP2MAN" != "x")
 107
 108 dnl htmltidy presence
 109 AC_PATH_PROG(TIDY,tidy)
 110
 111 dnl doxygen presence
 112 AC_PATH_PROG(DOXYGEN,doxygen)
 113 AM_CONDITIONAL(DOXYGEN_SUPPORT, test "x$DOXYGEN" != "x")
 114
 115 dnl makeinfo support:
 116 dnl Also test the presence of the full documentation package
 117 AM_CONDITIONAL(MAKEINFO_SUPPORT,
 118 test "x$MAKEINFO:" != "x" && test -f doc/Makefile.am)
 119
 120 dnl Try to enforce ISO C (iso9899 1999)
 121 dnl This will more likely work
 122 dnl only with gcc. In fact,
 123 dnl expect for variadic macros, this program
 124 dnl should be ansi C (ISO C90).
 125 TMP_CFLAGS="$CFLAGS"
 126 CFLAGS="$CFLAGS -std=c99 -pedantic -Wall"
 127 AC_MSG_CHECKING([for ISO C99 warnings generation])
 128 AC_TRY_COMPILE(
 129 ,
 130 int
 131 main(void)
 132 {
 133    return 0L;
 134 },
 135 AC_MSG_RESULT([yes]),
 136 AC_MSG_RESULT([no])
 137 CFLAGS="$TMP_CFLAGS"
 138 )
 139
 140 dnl Define source to be BSD compliant (ISO C, POSIX, and 4.3BSD)
 141 AC_DEFINE(_BSD_SOURCE,1,[Source is BSD compliant (ISO C, POSIX and 4.3BSD)])
 142 if test "x`uname`" = xNetBSD; then
 143 dnl NetBSD (at least version 1.6.1) is following the standard less closely than
 144 dnl the other... Hence, we declare the source specifically as _POSIX_SOURCE
 145 dnl instead of the newer _POSIX_C_SOURCE 199309
 146 AC_DEFINE(_POSIX_SOURCE,1,[Source is POSIX 1 compliant (IEEE Std 1003.1)])
 147 else
 148 dnl For some unspecified reason, it as been reported than FreeBSD [5|6|7].x
 149 dnl doesn't like those POSIX keywords either
 150 UNAME_REDUX=`uname -r -s | sed 's/\..*//' 2> /dev/null`
 151 if test "$UNAME_REDUX" != 'FreeBSD 5' && \
 152    test "$UNAME_REDUX" != 'FreeBSD 6' && \
 153    test "$UNAME_REDUX" != 'FreeBSD 7'
 154 then
 155 AC_DEFINE(_POSIX_C_SOURCE,199309,[Source is POSIX 4 compliant (IEEE Std 1003.1b)])
 156 fi
 157 fi
 158
 159 dnl Check for system header files
 160 AC_HEADER_STDC
 161 AC_CHECK_HEADERS(stdio.h stdarg.h errno.h fcntl.h signal.h time.h math.h sys/time.h sys/types.h sys/stat.h grp.h pwd.h libgen.h dirent.h iconv.h)
 162
 163 dnl Enable debugging
 164 dnl This will filter out optimisation switch (-O[s0-9])
 165 dnl for gcc compiler
 166 AC_ARG_ENABLE(
 167   debug, [  --enable-debug        enable debugging symbols and supplementary
 168                           messages generation in final binary])
 169
 170 : ${enableval="no"}
 171 AC_MSG_CHECKING([for debugging symbols generation])
 172 if test x$enableval = "xyes"; then
 173    AC_MSG_RESULT([yes])
 174    AC_DEFINE(DEBUG, 1, [Debug mode is on if defined.])
 175    CFLAGS="$CFLAGS -g"
 176    DEBUG=yes
 177 else
 178    AC_MSG_RESULT([no])
 179    CFLAGS=`echo "$CFLAGS" | sed 's/^-g$//; s/^-g@<:@@<:@:space:@:>@@:>@\+// ; s/@<:@@<:@:space:@:>@@:>@\+-g$//; s/@<:@@<:@:space:@:>@@:>@\+-g@<:@@<:@:space:@:>@@:>@\+/ /'`
 180 fi
 181
 182 dnl SIGKILL timeout setting
 183 enableval=
 184 AC_MSG_CHECKING([for sigkill timeout])
 185 AC_ARG_ENABLE(sigkill-timeout,
 186 [  --enable-sigkill-timeout=SEC
 187                           timeout (in seconds) before sending `kill'
 188                           signal to parent process in case of restart
 189                           if `term' has no effect [default=5]])
 190 : ${enableval:=5}
 191 test $enableval -gt 0 2> /dev/null || {
 192 AC_MSG_RESULT([no])
 193 AC_MSG_ERROR([Given sigkill timeout was not understood])
 194 }
 195 AC_MSG_RESULT([yes])
 196 AC_DEFINE_UNQUOTED(SIGKILL_TIMEOUT,$enableval,
 197 [Delay between SIGTERM ans SIGKILL to parent process in case of restart.])
 198
 199 dnl X polling frequency setting
 200 enableval=
 201 period=
 202 AC_MSG_CHECKING([for polling frequency])
 203 AC_ARG_ENABLE(x-polling-frequency,
 204 [  --enable-x-polling-frequency=FREQ
 205                           default frequency (in hertz) for polling the X server
 206                           for events. Lower values leads to less responsive,
 207                           but less CPU hungry desklets [default=50]])
 208 : ${enableval:=50}
 209 X_POLLING_FREQ=$enableval
 210 test $enableval -gt 0 2> /dev/null || {
 211 AC_MSG_RESULT([no])
 212 AC_MSG_ERROR([Positive, integer value is required as x-polling-frequency])
 213 }
 214
 215 AC_CHECK_PROG(EXISTS,bc,yes,no)
 216 if test $enableval -ne 50; then
 217 if test x$EXISTS = "xyes"; then
 218    period=`echo "1000000 / $enableval" | bc`
 219 else
 220    AC_MSG_WARN([Could not find the `bc' calculator to perform arithmetic
 221 computation of X server polling period value. Default 50 Hz is assumed.])
 222 fi
 223 fi
 224 : ${period:=20000}
 225 AC_DEFINE_UNQUOTED(X_POLLING_PERIOD,$period,
 226 [Default polling period (in 10e-6 seconds) of stdin between two cycles of events loop.])
 227 X_POLLING_PERIOD=$period
 228 AC_SUBST(X_POLLING_FREQ)
 229
 230 dnl Lock files directory setting
 231 enableval=
 232 AC_MSG_CHECKING([for lock files directory setting])
 233 AC_ARG_ENABLE(lockfiles-dir,
 234 [  --enable-lockfiles-dir=DIR
 235                           directory to put lock files in [default=/tmp]])
 236 : ${enableval:=/tmp}
 237 test -d $enableval || {
 238 AC_MSG_RESULT([no])
 239 AC_MSG_ERROR([Given lock files directory does not exist on your system])
 240 }
 241 AC_MSG_RESULT([yes])
 242 AC_DEFINE_UNQUOTED(LOCKFILES_DIR,"$enableval",
 243 [Directory to put lock files in.])
 244 LOCKFILES_DIR=$enableval
 245 AC_SUBST(LOCKFILES_DIR)
 246
 247 dnl Control modifier on context menu
 248 enableval=
 249 AC_MSG_CHECKING([for control modifier on context menu])
 250 AC_ARG_ENABLE(control-on-context-menu,
 251 [  --enable-control-on-context-menu
 252                           force CTRL to be pressed to fire context menu
 253                           [default=no]])
 254 : ${enableval:=no}
 255 if test x$enableval != "xno" ; then
 256 AC_MSG_RESULT([yes])
 257 AC_DEFINE(CONTROL_ON_CONTEXT_MENU, 1,
 258 [Force CTRL to be pressed to fire context menu])
 259 else
 260 AC_MSG_RESULT([no])
 261 fi
 262
 263 dnl Legacy Window Manager detection code
 264 enableval=
 265 AC_MSG_CHECKING([for legacy fake root window detection code])
 266 AC_ARG_ENABLE(legacy-fake-root-window-detection,
 267 [  --enable-legacy-fake-root-window-detection
 268                           Use the old code to detect fake root windows
 269                           [default=no]])
 270 : ${enableval:=no}
 271 if test x$enableval != "xno" ; then
 272 AC_MSG_RESULT([yes])
 273 AC_DEFINE(WM_DETECTION_OLD_STYLE, 1,
 274 [Use former fake root window detection code])
 275 else
 276 AC_MSG_RESULT([no])
 277 fi
 278
 279 dnl New frontend driver
 280 enableval=
 281 AC_MSG_CHECKING([for frontend shell driver])
 282 AC_ARG_ENABLE(frontend-shell-driver,
 283 [  --disable-frontend-shell-driver
 284                           Do not invoke the frontend shell-based driver
 285                           for adesklets [default=no]])
 286 : ${enableval:=yes}
 287 if test x$enableval != "xyes" ; then
 288 AM_CONDITIONAL(FRONTEND_SHELL_SUPPORT, test 1 -eq 0)
 289 AC_MSG_RESULT([no])
 290 else
 291 AC_DEFINE(FRONTEND_SHELL_DRIVER, 1,
 292 [Enable the frontend shell driver mecanism])
 293 AM_CONDITIONAL(FRONTEND_SHELL_SUPPORT, test 1 -eq 1)
 294 AC_MSG_RESULT([yes])
 295 fi
 296
 297 dnl Collect various system informations strings,
 298 dnl for embedding into final executable
 299 EXISTS=
 300 WELCOME1="\"$PACKAGE $VERSION"
 301 AC_CHECK_PROG(EXISTS,date,yes)
 302 if test x$EXISTS = "xyes"; then
 303    WELCOME1="$WELCOME1 ("`date | sed 's/@<:@@<:@:space:@:>@@:>@\+/ /g'`")"
 304 else
 305    WELCOME1="$WELCOME1 (unknown time)"
 306 fi
 307 EXISTS=
 308 AC_CHECK_PROG(EXISTS,uname,yes)
 309 if test x$EXISTS = "xyes"; then
 310    if uname -rs &> /dev/null; then
 311       WELCOME1="$WELCOME1, on "`uname -rs`"\""
 312    else
 313       WELCOME1="$WELCOME1, on an unknown OS\""
 314    fi
 315 else
 316    WELCOME1="$WELCOME1, on an unknown OS\""
 317 fi
 318 AC_DEFINE_UNQUOTED(WELCOME_LINE_1, $WELCOME1, [Welcome message, first line.])
 319 dnl Note: @<:@ and @:>@ are respective quadrigraphs for `[' and `]'
 320 ${CC} --version &> /dev/null && \
 321       WELCOME2="\"${CC} "`${CC} --version | sed -n '1 s/^@<:@^0-9@:>@*//p'`"\""
 322 : ${WELCOME2:=\"${CC} unknown version\"}
 323 AC_DEFINE_UNQUOTED(WELCOME_LINE_2, $WELCOME2, [Welcome message, second line.])
 324
 325 dnl Variables save: all changes to CFLAGS, LIBS and LDFLAGS beyond
 326 dnl this point will be wiped
 327 TMP_CFLAGS="$CFLAGS"
 328 TMP_LIBS="$LIBS"
 329 TMP_LDFLAGS="$LDFLAGS"
 330
 331 dnl Check for readline
 332 AC_CHECK_LIB(ncurses, tputs, HaveLibTermcap=yes; LibTermcap=ncurses,
 333    AC_CHECK_LIB(termcap, tputs, HaveLibTermcap=yes; LibTermcap=termcap,
 334       AC_CHECK_LIB(curses, tputs, HaveLibTermcap=yes; LibTermcap=curses,
 335                    HaveLibTermcap=no)))
 336 if test $HaveLibTermcap = "yes" ; then
 337    LIBS="$LIBS -l$LibTermcap"
 338 else
 339    AC_MSG_ERROR([Could not find terminal management library for readline
 340 (either ncurses, termcap or curses).])
 341 fi
 342 AC_CHECK_LIB(readline,readline,
 343   READLINE_LIBS="-l$LibTermcap -lreadline",
 344   AC_MSG_ERROR([Could not find the readline library]),
 345   $LFLAGS)
 346 LIBS="$TMP_LIBS"
 347
 348 dnl Check for libhistory support
 349 withval=
 350 AC_ARG_WITH(history,
 351 [  --without-history       remove history support in interactive use
 352                           of the interpreter])
 353 : ${withval:=yes}
 354 if test x$withval = "xyes"; then
 355 AC_CHECK_LIB(history,add_history,
 356         READLINE_LIBS="$READLINE_LIBS -lhistory";
 357         HaveLibHistory=history,
 358         AC_CHECK_LIB(readline,add_history,
 359         HaveLibHistory=readline,
 360         HaveLibHistory=no,
 361         $READLINE_LIBS),
 362         $READLINE_LIBS)
 363
 364 if test $HaveLibHistory = "no"; then
 365 AC_MSG_WARN([Could not find GNU history library in the system])
 366 else
 367 AC_DEFINE(HAVE_READLINE_HISTORY_H,1,
 368         [Define to 1 if you have the <readline/history.h> header file.])
 369 AC_CHECK_LIB($HaveLibHistory,free_history_entry,
 370         AC_DEFINE(HAVE_FREE_HISTORY_ENTRY,1,
 371         [Define to 1 if you have the `free_history_entry' function.]),,
 372         $READLINE_LIBS)
 373 fi
 374
 375 AC_MSG_CHECKING([for history max command lenght])
 376 enableval=
 377 AC_ARG_ENABLE(history-max-command-lenght,
 378 [  --enable-history-max-command-lenght=LEN
 379                           maximum string lenght (in characters) that a single
 380                           command can have and still be kept in history
 381                           (a lenght of zero meaning no limits) [default=256]])
 382 : ${enableval:=256}
 383
 384 if test $enableval -ge 0 ; then
 385 AC_MSG_RESULT([yes])
 386 AC_DEFINE_UNQUOTED(HISTORY_MAX_COMMAND_LENGHT,$enableval,
 387 [maximum history string lenght.])
 388 else
 389 AC_MSG_RESULT([no])
 390 AC_MSG_ERROR([history max command lenght must be positive or null])
 391 fi
 392
 393 fi
 394 AC_SUBST(READLINE_LIBS)
 395
 396 dnl Check for 8 bit characters support forcing
 397 enableval=
 398 AC_ARG_ENABLE(force-extended-characters-input,
 399 [  --enable-force-extended-characters-input
 400                           force input and ouput of unescaped
 401                           height bits characters through GNU readline,
 402                           regardless of the inputrc settings [default=no]])
 403 : ${enableval:=no}
 404 if ! test x$enableval = "xno" ; then
 405 AC_DEFINE(FORCE_EXTENDED_CHARACTERS_INPUT,1,
 406 [force 8 bit characters support in GNU readline])
 407 fi
 408
 409 dnl Check for fontconfig
 410 withval=
 411 AC_ARG_WITH(fontconfig,
 412 [  --without-fontconfig    remove fontconfig support enabling automatic
 413                           detection of all truetype fonts already available
 414                           on the machine])
 415 : ${withval:=yes}
 416 if test x$withval = "xyes"; then
 417 AC_PATH_PROG(PKG_CONFIG, pkg-config)
 418 if ! test x$PKG_CONFIG = "x" ; then
 419    if $PKG_CONFIG --exists fontconfig 2> /dev/null; then
 420       FONTCONFIG_LIBS=`pkg-config --libs fontconfig`
 421       FONTCONFIG_CFLAGS=`pkg-config --cflags fontconfig`
 422    fi
 423 fi
 424 if test x$FONTCONFIG_LIBS = "x"; then
 425    FONTCONFIG_LIBS=-lfontconfig
 426 fi
 427 LIBS="$LIBS $FONTCONFIG_LIBS"
 428 CFLAGS="$CFLAGS $FONTCONFIG_CFLAGS"
 429 AC_MSG_CHECKING([for fontconfig])
 430 AC_TRY_LINK(
 431 #include <fontconfig/fontconfig.h>
 432 , FcInit(),
 433 AC_MSG_RESULT([yes])
 434 AC_DEFINE(HAVE_FONTCONFIG_FONTCONFIG_H,1,[Define to 1 if you have the <fontconfig/fontconfig.h> header file.])
 435
 436 AC_MSG_CHECKING([For fontconfig FcFini()])
 437 AC_TRY_LINK(
 438 #include <fontconfig/fontconfig.h>
 439 , FcFini(),
 440 AC_MSG_RESULT([yes])
 441 AC_DEFINE(HAVE_FONTCONFIG_FCFINI,1,[Define to 1 if FcFini() call exists])
 442 ,
 443 AC_MSG_RESULT([no]))
 444
 445 ,
 446 AC_MSG_RESULT([no])
 447 FONTCONFIG_LIBS=
 448 FONTCONFIG_CFLAGS=
 449 AC_MSG_WARN([
 450 -----------------------------------------------------
 451 `fontconfig' was not found on your system.
 452 Although `adesklets' will work anyway system-wide
 453 automatic font detection will not occur:
 454 it is therefore quite possible that only the
 455 default font provided with the package will display.
 456 -----------------------------------------------------]))
 457 AC_SUBST(FONTCONFIG_LIBS)
 458 AC_SUBST(FONTCONFIG_CFLAGS)
 459 LIBS="$TMP_LIBS"
 460 CFLAGS="$TMP_CFLAGS"
 461 fi
 462
 463 dnl Check for fork() system call
 464 AC_CHECK_FUNCS(fork,,
 465 AC_MSG_ERROR([Could not find the fork() system call]))
 466
 467 dnl Check for X headers and libraries
 468 AC_PATH_X
 469
 470 if test x$no_x != "xyes"; then
 471
 472 if test x$x_includes != "x" ; then
 473    X_CFLAGS="-I$x_includes"
 474    CFLAGS="$CFLAGS $X_CFLAGS"
 475 fi
 476
 477 if test x$x_libraries != "x" ; then
 478    X_LIBS="-L$x_libraries"
 479    LDFLAGS="$LDFLAGS $X_LIBS"
 480 fi
 481
 482 dnl Check for required functions in -lX11
 483 AC_CHECK_LIB(X11, XOpenDisplay,
 484   X_LIBS="$X_LIBS -lX11"
 485   LIBS="$LIBS -lX11",
 486   AC_MSG_ERROR([Could not find XOpenDisplay in -lX11.])
 487 )
 488 AC_DEFINE(X_DISPLAY_SUPPORT,1,[Define to 1 if the X Window System is supported, 0 otherwise.])
 489 else
 490 AC_DEFINE(X_DISPLAY_SUPPORT,0,[Define to 1 if the X Window System is supported, 0 otherwise.])
 491    X_CFLAGS=
 492    X_LIBS=
 493 AC_DEFINE(X_DISPLAY_MISSING,,[Defined if the X headers were not found])
 494 fi
 495 AC_SUBST(X_CFLAGS)
 496 AC_SUBST(X_LIBS)
 497
 498 dnl Imlib2 detection
 499 withval=
 500 AC_ARG_WITH(imlib2,
 501         [  --with-imlib2=DIR       use imlib2 in <DIR>],
 502         [CFLAGS="$CFLAGS -I$withval/include"
 503         LIBS="-L$withval/lib $LIBS"])
 504
 505 AC_PATH_GENERIC_MODIFIED(imlib2, 1.1.2,,
 506   AC_MSG_ERROR([Cannot find imlib2: Is imlib2-config in the path?]),
 507   1.2.0,,
 508   AC_MSG_WARN([
 509 -----------------------------------------------------
 510 $PACKAGE should work with your version of imlib2...
 511 But for better results you are _warmly_ encouraged
 512 to try out version 1.2.0 or above;
 513 known bugs are still lurking in dark corners
 514 with what you have installed: beware strange problems
 515 with dynamic image filters for instance!
 516 -----------------------------------------------------]))
 517
 518 LIBS="$LIBS -lImlib2"
 519 dnl CFLAGS="$CFLAGS $IMLIB2_CFLAGS"
 520
 521 AC_MSG_CHECKING([for imlib2 program linking with ad-hoc flags])
 522 AC_TRY_LINK(
 523 #ifndef X_DISPLAY_MISSING
 524         #include <X11/Xlib.h>
 525         #include <X11/Xutil.h>
 526         #include <X11/Xos.h>
 527         #include <X11/Xatom.h>
 528 #endif
 529         #include <Imlib2.h>
 530 ,       Imlib_Image image;
 531         image = imlib_load_image("toto.png");
 532 #ifndef X_DISPLAY_MISSING
 533         imlib_context_set_display(NULL);
 534 #endif
 535 ,
 536         AC_MSG_RESULT([yes])
 537         IMLIB2_CFLAGS=""
 538         IMLIB2_LIBS="-lImlib2",
 539         AC_MSG_RESULT([no])
 540         CFLAGS="$TMP_CFLAGS $IMLIB2_CFLAGS"
 541         LIBS="$TMP_LIBS $IMLIB2_LIBS"
 542         AC_MSG_CHECKING([for imlib2 program linking])
 543         AC_TRY_LINK(
 544 #ifndef X_DISPLAY_MISSING
 545         #include <X11/Xlib.h>
 546         #include <X11/Xutil.h>
 547         #include <X11/Xos.h>
 548         #include <X11/Xatom.h>
 549 #endif
 550         #include <Imlib2.h>
 551 ,       Imlib_Image image;
 552         image = imlib_load_image("toto.png");
 553 #ifndef X_DISPLAY_MISSING
 554         imlib_context_set_display(NULL);
 555 #endif
 556 ,
 557         AC_MSG_RESULT([yes]),
 558         AC_MSG_RESULT([no])
 559         AC_MSG_ERROR([Cannot link Imlib2 program.
 560 If you specified you did not want X support this can be caused
 561 by your Imlib2 installment being configured so it needs it
 562 or conversely. In that case reinstall Imlib2 with proper
 563 --enable-x11-support parameter (as from enlightement CVS)
 564 before retrying to configure this package.])))
 565
 566 AC_SUBST(IMLIB2_CFLAGS)
 567 AC_SUBST(IMLIB2_LIBS)
 568
 569
 570 dnl Test for uint typedef
 571 AC_MSG_CHECKING([for uint typedef in standard library])
 572 AC_TRY_COMPILE(
 573 #ifdef HAVE_SYS_TYPES_H
 574         #include <sys/types.h>
 575 #endif
 576 #ifdef HAVE_UNISTD_H
 577         #include <unistd.h>
 578 #endif
 579 ,       uint i,
 580         AC_MSG_RESULT([yes]),
 581         AC_MSG_RESULT([no])
 582         AC_DEFINE(UINT_NOT_DEFINED,1,
 583                   [Define to 1 if compability type uint is not detected.])
 584 )
 585
 586 dnl Important variables reset
 587 CFLAGS="$TMP_CFLAGS"
 588 LIBS="$TMP_LIBS"
 589 LDFLAGS="$TMP_LDFLAGS"
 590
 591 dnl PKGDATADIR definition
 592 dnl PKGDATADIR is only well constructed in make context,
 593 dnl so let's put this AFTER all tests.
 594 CFLAGS="$CFLAGS"' -DPKGDATADIR=\"$(pkgdatadir)\"'
 595
 596 dnl Output files
 597 AM_CONFIG_HEADER(src/config.h)
 598 AC_OUTPUT(Makefile
 599 src/Makefile
 600 data/Makefile
 601 utils/Makefile
 602 doc/Makefile
 603 doc/adesklets_checkin.1
 604 doc/adesklets_submit.1
 605 doc/htmldoc.sh
 606 doc/imlib2/Makefile
 607 scripting/Makefile
 608 scripting/protoize.sh
 609 scripting/python/Makefile
 610 scripting/python/config.h
 611 scripting/python/setup.py
 612 scripting/perl/Makefile
 613 scripting/perl/Makefile.PL
 614 scripting/perl/updateproto.pl
 615 utils/adesklets_frontend.sh
 616 )
 617
 618 dnl Change script(s) permissions
 619 chmod +x scripting/protoize.sh scripting/perl/updateproto.pl \
 620       doc/htmldoc.sh utils/adesklets_frontend.sh
 621
 622 dnl Final warning, if needed
 623 if test x$DEBUG = "xyes"; then
 624 AC_MSG_WARN([
 625 -----------------------------------------------------
 626 you choosed to make a `debug' compilation: this will
 627 generate a significantly bigger executable
 628 that produces on stderr (by default) a lot of outputs
 629 unwanted during normal use; set up the ADESKLETS_LOG
 630 environment variable to a filename the interpreter
 631 can safely suffix with a pid related extension
 632 than truncate to collect all debug outputs
 633 there instead. Be also aware that all optimisation
 634 settings (-O flags in CFLAGS) are discarded when
 635 enabling this.
 636 -----------------------------------------------------])
 637 fi
 638 if test x$no_x = "xyes"; then
 639 AC_MSG_WARN([
 640 -----------------------------------------------------
 641 you choosed to perform an `X Window less' build -
 642 which means you will eventually end up with
 643 a strictly command line program free of all
 644 dependencies on xlib. If it is not what you intended
 645 please reconfigure. For this to work you do need first
 646 to configure your Imlib2 incantation for not using
 647 X Window itself.
 648 -----------------------------------------------------
 649 ])
 650 fi
 651
 652 if test x$PYTHON != "x" ; then
 653 if test x$SIGPROC != "xyes" ; then
 654 AC_MSG_WARN([
 655 -----------------------------------------------------
 656 your system does not seem to support reliable POSIX
 657 signal calls such as `sigprocmask', `sigpending' or
 658 `sigsuspend'. Although this does not affect $PACKAGE
 659 directly, it seriously impedes python ability
 660 to handle things well through its package.
 661 To our knowledge, no modern UNIX platforms lack
 662 those system calls...
 663 -----------------------------------------------------
 664 ])
 665 fi
 666 fi