doc/xsl/pdfdoc.xsl

   1 <xsl:stylesheet
   2  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   3  xmlns:fo="http://www.w3.org/1999/XSL/Format"
   4  version="1.0">
   5
   6 <xsl:import href="./db_pdfdoc.xsl"/>
   7 <xsl:import href="./defaults.xsl"/>
   8 <xsl:import href="./tgit.xsl"/>
   9 <xsl:param name="paper.type" select="'A4'"></xsl:param>
  10 <xsl:param name="page.orientation">portrait</xsl:param>
  11 <xsl:param name="double.sided" select="0"></xsl:param>
  12 <xsl:param name="variablelist.as.blocks" select="1"></xsl:param>
  13 <xsl:param name="symbol.font.family" select="'Symbol,ZapfDingbats'"></xsl:param>
  14
  15 <xsl:param name="table.frame.border.thickness" select="'1pt'"></xsl:param>
  16 <xsl:param name="table.frame.border.style" select="'solid'"></xsl:param>
  17 <xsl:param name="table.frame.border.color" select="'#7099C5'"></xsl:param>
  18 <xsl:param name="table.cell.border.thickness" select="'1pt'"></xsl:param>
  19 <xsl:param name="table.cell.border.style" select="'solid'"></xsl:param>
  20 <xsl:param name="table.cell.border.color" select="'#7099C5'"></xsl:param>
  21
  22 <xsl:attribute-set name="formal.object.properties">
  23   <xsl:attribute name="keep-together.within-column">auto</xsl:attribute>
  24 </xsl:attribute-set>
  25
  26
  27 <xsl:param name="formal.title.placement">
  28   figure after
  29   example after
  30   equation after
  31   table after
  32   procedure after
  33 </xsl:param>
  34
  35 <xsl:template match="menuchoice">
  36   <fo:inline font-family="Helvetica">
  37     <xsl:call-template name="process.menuchoice"/>
  38   </fo:inline>
  39 </xsl:template>
  40
  41 <xsl:template match="guilabel">
  42   <fo:inline font-family="Helvetica">
  43     <xsl:call-template name="inline.charseq"/>
  44   </fo:inline>
  45 </xsl:template>
  46
  47 <xsl:template match="guibutton">
  48   <fo:inline font-family="Helvetica">
  49     <xsl:call-template name="inline.charseq"/>
  50   </fo:inline>
  51 </xsl:template>
  52
  53 <xsl:template match="keysym">
  54   <fo:inline font-family="Symbol">
  55     <xsl:call-template name="inline.charseq"/>
  56   </fo:inline>
  57 </xsl:template>
  58
  59 <xsl:template match="thead">
  60   <xsl:variable name="tgroup" select="parent::*"/>
  61
  62   <fo:table-header
  63     font-weight="bold"
  64     color="#ffffff"
  65     background-color="#7099C5">
  66     <xsl:apply-templates select="row[1]">
  67       <xsl:with-param name="spans">
  68         <xsl:call-template name="blank.spans">
  69           <xsl:with-param name="cols" select="../@cols"/>
  70         </xsl:call-template>
  71       </xsl:with-param>
  72     </xsl:apply-templates>
  73   </fo:table-header>
  74 </xsl:template>
  75
  76 <xsl:template match="tfoot">
  77   <xsl:variable name="tgroup" select="parent::*"/>
  78
  79   <fo:table-footer
  80     background-color="#f0f0ff">
  81     <xsl:apply-templates select="row[1]">
  82       <xsl:with-param name="spans">
  83         <xsl:call-template name="blank.spans">
  84           <xsl:with-param name="cols" select="../@cols"/>
  85         </xsl:call-template>
  86       </xsl:with-param>
  87     </xsl:apply-templates>
  88   </fo:table-footer>
  89 </xsl:template>
  90
  91 <xsl:template match="tbody">
  92   <xsl:variable name="tgroup" select="parent::*"/>
  93
  94   <fo:table-body
  95     background-color="#f0f0ff">
  96     <xsl:choose>
  97       <!-- Use recursion if @morerows is used -->
  98       <xsl:when test="row/entry/@morerows|row/entrytbl/@morerows">
  99         <xsl:apply-templates select="row[1]">
 100           <xsl:with-param name="spans">
 101             <xsl:call-template name="blank.spans">
 102               <xsl:with-param name="cols" select="../@cols"/>
 103             </xsl:call-template>
 104           </xsl:with-param>
 105           <xsl:with-param name="browserows" select="'recurse'"/>
 106         </xsl:apply-templates>
 107       </xsl:when>
 108       <xsl:otherwise>
 109         <xsl:apply-templates select="row">
 110           <xsl:with-param name="spans">
 111             <xsl:call-template name="blank.spans">
 112               <xsl:with-param name="cols" select="../@cols"/>
 113             </xsl:call-template>
 114           </xsl:with-param>
 115           <xsl:with-param name="browserows" select="'loop'" />
 116         </xsl:apply-templates>
 117       </xsl:otherwise>
 118     </xsl:choose>
 119   </fo:table-body>
 120 </xsl:template>
 121
 122 <xsl:attribute-set name="xref.properties">
 123   <xsl:attribute name="color">
 124     <xsl:choose>
 125       <xsl:when test="self::ulink">blue</xsl:when>
 126       <xsl:otherwise>red</xsl:otherwise>
 127     </xsl:choose>
 128   </xsl:attribute>
 129 </xsl:attribute-set>
 130
 131 <xsl:attribute-set name="monospace.verbatim.properties">
 132   <xsl:attribute name="wrap-option">wrap</xsl:attribute>
 133   <!-- TODO: set a hyphenation-character, currently unsupported by FOP; http://www.sagehill.net/docbookxsl/FittingText.html#BreakLongLines -->
 134 </xsl:attribute-set>
 135
 136 </xsl:stylesheet>