nanocoat/CMakeLists.txt

   1 # ---------------------------------------------------------------------------
   2 # SquirrelJME
   3 #     Copyright (C) Stephanie Gawroriski <xer@multiphasicapps.net>
   4 # ---------------------------------------------------------------------------
   5 # SquirrelJME is under the Mozilla Public License Version 2.0.
   6 # See license.mkd for licensing and copyright information.
   7 # ---------------------------------------------------------------------------
   8 # DESCRIPTION: Defines the base project and the versioning info
   9
  10 # Easier includes
  11 include("${CMAKE_SOURCE_DIR}/cmake/easier-includes.cmake" NO_POLICY_SCOPE)
  12
  13 # Needed for some ancient RetroArch toolchains
  14 if(${CMAKE_VERSION} VERSION_LESS "3.13")
  15         message(STATUS "Ancient CMake has been detected (${CMAKE_VERSION})")
  16         cmake_minimum_required(VERSION 3.7)
  17
  18         # Needs to be this or newer
  19 else()
  20         message(STATUS "Detected CMake (${CMAKE_VERSION})")
  21         cmake_minimum_required(VERSION 3.13)
  22 endif()
  23
  24 # Determine version information
  25 squirreljme_include("identify-squirreljme-version.cmake")
  26
  27 # Fixes and otherwise for compatibility
  28 squirreljme_include("pre-fixes.cmake")
  29
  30 # Define project
  31 if(${CMAKE_VERSION} VERSION_LESS "3.12")
  32         project(SquirrelJME
  33                 VERSION ${SQUIRRELJME_VERSION}
  34                 LANGUAGES C)
  35 else()
  36         project(SquirrelJME
  37                 VERSION ${SQUIRRELJME_VERSION}
  38                 DESCRIPTION "SquirrelJME is a Java ME 8 \
  39 Virtual Machine for embedded and Internet of Things devices."
  40                 HOMEPAGE_URL https://squirreljme.cc/
  41                 LANGUAGES C)
  42 endif()
  43
  44 # Fixes and otherwise for compatibility
  45 squirreljme_include("fixes.cmake")
  46
  47 # Hardening options
  48 squirreljme_include("hardening.cmake")
  49
  50 # CMake Utilities, compiled and used during build
  51 squirreljme_include("utils.cmake")
  52
  53 # Doxygen
  54 squirreljme_include("doxygen.cmake")
  55
  56 # Threading and atomics
  57 squirreljme_include("threads.cmake")
  58
  59 # To Emily and Near...
  60 squirreljme_include("i-miss-you.cmake")
  61
  62 # Everything is C99
  63 set(CMAKE_C_STANDARD 99)
  64 set(CMAKE_C_STANDARD_REQUIRED True)
  65
  66 # Assets and otherwise, such as icons, etc.
  67 squirreljme_include("assets.cmake")
  68
  69 # Turn some warnings into errors
  70 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
  71         add_compile_options("-Werror=implicit-function-declaration")
  72 endif()
  73
  74 # Visual studio does not like a bunch of standard C functions, even those
  75 # that take sizes...
  76 if(MSVC)
  77         add_compile_definitions(_CRT_SECURE_NO_WARNINGS=1)
  78 endif()
  79
  80 # Declare Version
  81 add_compile_definitions(
  82         SQUIRRELJME_VERSION_TRIM=${SQUIRRELJME_VERSION})
  83
  84 # Debugging?
  85 if(SQUIRRELJME_IS_DEBUG)
  86         add_compile_definitions(SJME_CONFIG_DEBUG=1)
  87
  88         if(SQUIRRELJME_ENABLE_TESTING)
  89                 add_compile_definitions(SJME_CONFIG_UNIT_TEST=1)
  90         endif()
  91 endif()
  92
  93 # Valgrind Support on UNIX OSes, if debugging is enabled
  94 if(ANDROID OR SQUIRRELJME_IS_UNIX)
  95         if(SQUIRRELJME_IS_DEBUG)
  96                 squirreljme_include("valgrind.cmake")
  97         endif()
  98 endif()
  99
 100 # Where should dynamic libraries go when output?
 101 if(NOT DEFINED SQUIRRELJME_DYLIB_OUTPUT_DIR)
 102         set(SQUIRRELJME_DYLIB_OUTPUT_DIR
 103                 "${CMAKE_BINARY_DIR}" PARENT_SCOPE)
 104         set(SQUIRRELJME_DYLIB_OUTPUT_DIR
 105                 "${CMAKE_BINARY_DIR}")
 106 endif()
 107
 108 # Enable support for testing, this is needed here otherwise testing will not
 109 # work at all! Major headache this has caused...
 110 # From: https://cmake.org/cmake/help/v3.13/command/enable_testing.html
 111 # > Note that ctest expects to find a test file in the build directory root.
 112 # > Therefore, this command should be in the source directory root.
 113 if(SQUIRRELJME_ENABLE_TESTING OR
 114         NOT DEFINED SQUIRRELJME_ENABLE_TESTING)
 115         enable_testing()
 116 else()
 117         message(WARNING "Testing was disabled "
 118                 "(${SQUIRRELJME_ENABLE_TESTING})...")
 119 endif()
 120
 121 # CPack for installing
 122 if(SQUIRRELJME_ENABLE_PACKING OR
 123         NOT DEFINED SQUIRRELJME_ENABLE_PACKING)
 124         squirreljme_include("packing.cmake")
 125 endif()
 126
 127 # Include the base core first because it is completely standalone and it
 128 # uses nothing else
 129 add_subdirectory(src)
 130
 131 # Tests first since we add to these and when the ROMs register themselves
 132 # they will get their tests added accordingly
 133 if(SQUIRRELJME_ENABLE_TESTING OR
 134         NOT DEFINED SQUIRRELJME_ENABLE_TESTING)
 135         add_subdirectory(tests)
 136 else()
 137         message(WARNING "Testing was disabled "
 138                 "(${SQUIRRELJME_ENABLE_TESTING})...")
 139 endif()
 140
 141 # Front ends
 142 add_subdirectory(frontend)
 143
 144 # Directory where the ROM compiled sources exist
 145 add_subdirectory(rom)