selftest/selftest.pl

   1 #!/usr/bin/perl
   2 # Bootstrap Samba and run a number of tests against it.
   3 # Copyright (C) 2005-2010 Jelmer Vernooij <jelmer@samba.org>
   4 # Copyright (C) 2007-2009 Stefan Metzmacher <metze@samba.org>
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 use strict;
  20
  21 use FindBin qw($RealBin $Script);
  22 use File::Spec;
  23 use File::Temp qw(tempfile);
  24 use Getopt::Long;
  25 use POSIX;
  26 use Cwd qw(abs_path);
  27 use lib "$RealBin";
  28 use Subunit;
  29 use SocketWrapper;
  30
  31 eval {
  32 require Time::HiRes;
  33 Time::HiRes->import("time");
  34 };
  35 if ($@) {
  36         print "You don't have Time::Hires installed !\n";
  37 }
  38
  39 my $opt_help = 0;
  40 my $opt_target = "samba";
  41 my $opt_quick = 0;
  42 my $opt_socket_wrapper = 0;
  43 my $opt_socket_wrapper_pcap = undef;
  44 my $opt_socket_wrapper_keep_pcap = undef;
  45 my $opt_random_order = 0;
  46 my $opt_one = 0;
  47 my @opt_exclude = ();
  48 my @opt_include = ();
  49 my $opt_testenv = 0;
  50 my $opt_list = 0;
  51 my $ldap = undef;
  52 my $opt_resetup_env = undef;
  53 my $opt_binary_mapping = "";
  54 my $opt_load_list = undef;
  55 my $opt_libnss_wrapper_so_path = "";
  56 my $opt_libuid_wrapper_so_path = "";
  57 my @testlists = ();
  58
  59 my $srcdir = ".";
  60 my $bindir = "./bin";
  61 my $prefix = "./st";
  62
  63 my @includes = ();
  64 my @excludes = ();
  65
  66 sub pipe_handler {
  67         my $sig = shift @_;
  68         print STDERR "Exiting early because of SIGPIPE.\n";
  69         exit(1);
  70 }
  71
  72 $SIG{PIPE} = \&pipe_handler;
  73
  74 sub find_in_list($$)
  75 {
  76         my ($list, $fullname) = @_;
  77
  78         foreach (@$list) {
  79                 if ($fullname =~ /$$_[0]/) {
  80                          return ($$_[1]) if ($$_[1]);
  81                          return "";
  82                 }
  83         }
  84
  85         return undef;
  86 }
  87
  88 sub skip($)
  89 {
  90         my ($name) = @_;
  91
  92         return find_in_list(\@excludes, $name);
  93 }
  94
  95 sub getlog_env($);
  96
  97 sub setup_pcap($)
  98 {
  99         my ($name) = @_;
 100
 101         return unless ($opt_socket_wrapper_pcap);
 102         return unless defined($ENV{SOCKET_WRAPPER_PCAP_DIR});
 103
 104         my $fname = $name;
 105         $fname =~ s%[^abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789\-]%_%g;
 106
 107         my $pcap_file = "$ENV{SOCKET_WRAPPER_PCAP_DIR}/$fname.pcap";
 108
 109         SocketWrapper::setup_pcap($pcap_file);
 110
 111         return $pcap_file;
 112 }
 113
 114 sub cleanup_pcap($$)
 115 {
 116         my ($pcap_file, $exitcode) = @_;
 117
 118         return unless ($opt_socket_wrapper_pcap);
 119         return if ($opt_socket_wrapper_keep_pcap);
 120         return unless ($exitcode == 0);
 121         return unless defined($pcap_file);
 122
 123         unlink($pcap_file);
 124 }
 125
 126 # expand strings from %ENV
 127 sub expand_environment_strings($)
 128 {
 129         my $s = shift;
 130         # we use a reverse sort so we do the longer ones first
 131         foreach my $k (sort { $b cmp $a } keys %ENV) {
 132                 $s =~ s/\$$k/$ENV{$k}/g;
 133         }
 134         return $s;
 135 }
 136
 137 sub run_testsuite($$$$$)
 138 {
 139         my ($envname, $name, $cmd, $i, $totalsuites) = @_;
 140         my $pcap_file = setup_pcap($name);
 141
 142         Subunit::start_testsuite($name);
 143         Subunit::progress_push();
 144         Subunit::report_time(time());
 145         system($cmd);
 146         Subunit::report_time(time());
 147         Subunit::progress_pop();
 148
 149         if ($? == -1) {
 150                 Subunit::progress_pop();
 151                 Subunit::end_testsuite($name, "error", "Unable to run $cmd: $!");
 152                 exit(1);
 153         } elsif ($? & 127) {
 154                 Subunit::end_testsuite($name, "error",
 155                         sprintf("%s died with signal %d, %s coredump\n", $cmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 156                 exit(1);
 157         }
 158
 159         my $exitcode = $? >> 8;
 160
 161         my $envlog = getlog_env($envname);
 162         if ($envlog ne "") {
 163                 print "envlog: $envlog\n";
 164         }
 165
 166         print "command: $cmd\n";
 167         printf "expanded command: %s\n", expand_environment_strings($cmd);
 168
 169         if ($exitcode == 0) {
 170                 Subunit::end_testsuite($name, "success");
 171         } else {
 172                 Subunit::end_testsuite($name, "failure", "Exit code was $exitcode");
 173         }
 174
 175         cleanup_pcap($pcap_file, $exitcode);
 176
 177         if (not $opt_socket_wrapper_keep_pcap and defined($pcap_file)) {
 178                 print "PCAP FILE: $pcap_file\n";
 179         }
 180
 181         if ($exitcode != 0) {
 182                 exit(1) if ($opt_one);
 183         }
 184
 185         return $exitcode;
 186 }
 187
 188 sub ShowHelp()
 189 {
 190         print "Samba test runner
 191 Copyright (C) Jelmer Vernooij <jelmer\@samba.org>
 192 Copyright (C) Stefan Metzmacher <metze\@samba.org>
 193
 194 Usage: $Script [OPTIONS] TESTNAME-REGEX
 195
 196 Generic options:
 197  --help                     this help page
 198  --target=samba[3]|win      Samba version to target
 199  --testlist=FILE            file to read available tests from
 200
 201 Paths:
 202  --prefix=DIR               prefix to run tests in [st]
 203  --srcdir=DIR               source directory [.]
 204  --bindir=DIR               binaries directory [./bin]
 205
 206 Preload cwrap:
 207  --nss_wrapper_so_path=FILE the nss_wrapper library to preload
 208  --uid_wrapper_so_path=FILE the uid_wrapper library to preload
 209
 210 Target Specific:
 211  --socket-wrapper-pcap      save traffic to pcap directories
 212  --socket-wrapper-keep-pcap keep all pcap files, not just those for tests that
 213                             failed
 214  --socket-wrapper           enable socket wrapper
 215
 216 Samba4 Specific:
 217  --ldap=openldap|fedora-ds  back samba onto specified ldap server
 218
 219 Behaviour:
 220  --quick                    run quick overall test
 221  --one                      abort when the first test fails
 222  --testenv                  run a shell in the requested test environment
 223  --list                     list available tests
 224 ";
 225         exit(0);
 226 }
 227
 228 my $result = GetOptions (
 229                 'help|h|?' => \$opt_help,
 230                 'target=s' => \$opt_target,
 231                 'prefix=s' => \$prefix,
 232                 'socket-wrapper' => \$opt_socket_wrapper,
 233                 'socket-wrapper-pcap' => \$opt_socket_wrapper_pcap,
 234                 'socket-wrapper-keep-pcap' => \$opt_socket_wrapper_keep_pcap,
 235                 'quick' => \$opt_quick,
 236                 'one' => \$opt_one,
 237                 'exclude=s' => \@opt_exclude,
 238                 'include=s' => \@opt_include,
 239                 'srcdir=s' => \$srcdir,
 240                 'bindir=s' => \$bindir,
 241                 'testenv' => \$opt_testenv,
 242                 'list' => \$opt_list,
 243                 'ldap:s' => \$ldap,
 244                 'resetup-environment' => \$opt_resetup_env,
 245                 'testlist=s' => \@testlists,
 246                 'random-order' => \$opt_random_order,
 247                 'load-list=s' => \$opt_load_list,
 248                 'binary-mapping=s' => \$opt_binary_mapping,
 249                 'nss_wrapper_so_path=s' => \$opt_libnss_wrapper_so_path,
 250                 'uid_wrapper_so_path=s' => \$opt_libuid_wrapper_so_path
 251             );
 252
 253 exit(1) if (not $result);
 254
 255 ShowHelp() if ($opt_help);
 256
 257 die("--list and --testenv are mutually exclusive") if ($opt_list and $opt_testenv);
 258
 259 # we want unbuffered output
 260 $| = 1;
 261
 262 my @tests = @ARGV;
 263
 264 # quick hack to disable rpc validation when using valgrind - its way too slow
 265 unless (defined($ENV{VALGRIND})) {
 266         $ENV{VALIDATE} = "validate";
 267         $ENV{MALLOC_CHECK_} = 3;
 268 }
 269
 270 # make all our python scripts unbuffered
 271 $ENV{PYTHONUNBUFFERED} = 1;
 272
 273 my $bindir_abs = abs_path($bindir);
 274
 275 # Backwards compatibility:
 276 if (defined($ENV{TEST_LDAP}) and $ENV{TEST_LDAP} eq "yes") {
 277         if (defined($ENV{FEDORA_DS_ROOT})) {
 278                 $ldap = "fedora-ds";
 279         } else {
 280                 $ldap = "openldap";
 281         }
 282 }
 283
 284 my $torture_maxtime = ($ENV{TORTURE_MAXTIME} or 1200);
 285 if ($ldap) {
 286         # LDAP is slow
 287         $torture_maxtime *= 2;
 288 }
 289
 290 $prefix =~ s+//+/+;
 291 $prefix =~ s+/./+/+;
 292 $prefix =~ s+/$++;
 293
 294 die("using an empty prefix isn't allowed") unless $prefix ne "";
 295
 296 # Ensure we have the test prefix around.
 297 #
 298 # We need restrictive
 299 # permissions on this as some subdirectories in this tree will have
 300 # wider permissions (ie 0777) and this would allow other users on the
 301 # host to subvert the test process.
 302 mkdir($prefix, 0700) unless -d $prefix;
 303 chmod 0700, $prefix;
 304
 305 my $prefix_abs = abs_path($prefix);
 306 my $tmpdir_abs = abs_path("$prefix/tmp");
 307 mkdir($tmpdir_abs, 0777) unless -d $tmpdir_abs;
 308
 309 my $srcdir_abs = abs_path($srcdir);
 310
 311 die("using an empty absolute prefix isn't allowed") unless $prefix_abs ne "";
 312 die("using '/' as absolute prefix isn't allowed") unless $prefix_abs ne "/";
 313
 314 $ENV{PREFIX} = $prefix;
 315 $ENV{KRB5CCNAME} = "$prefix/krb5ticket";
 316 $ENV{PREFIX_ABS} = $prefix_abs;
 317 $ENV{SRCDIR} = $srcdir;
 318 $ENV{SRCDIR_ABS} = $srcdir_abs;
 319 $ENV{BINDIR} = $bindir_abs;
 320
 321 my $tls_enabled = not $opt_quick;
 322 $ENV{TLS_ENABLED} = ($tls_enabled?"yes":"no");
 323
 324 sub prefix_pathvar($$)
 325 {
 326         my ($name, $newpath) = @_;
 327         if (defined($ENV{$name})) {
 328                 $ENV{$name} = "$newpath:$ENV{$name}";
 329         } else {
 330                 $ENV{$name} = $newpath;
 331         }
 332 }
 333 prefix_pathvar("PKG_CONFIG_PATH", "$bindir_abs/pkgconfig");
 334 prefix_pathvar("PYTHONPATH", "$bindir_abs/python");
 335
 336 if ($opt_socket_wrapper_keep_pcap) {
 337         # Socket wrapper keep pcap implies socket wrapper pcap
 338         $opt_socket_wrapper_pcap = 1;
 339 }
 340
 341 if ($opt_socket_wrapper_pcap) {
 342         # Socket wrapper pcap implies socket wrapper
 343         $opt_socket_wrapper = 1;
 344 }
 345
 346 my $ld_preload = $ENV{LD_PRELOAD};
 347
 348 if ($opt_libnss_wrapper_so_path) {
 349         if ($ld_preload) {
 350                 $ld_preload = "$ld_preload:$opt_libnss_wrapper_so_path";
 351         } else {
 352                 $ld_preload = "$opt_libnss_wrapper_so_path";
 353         }
 354 }
 355
 356 if ($opt_libuid_wrapper_so_path) {
 357         if ($ld_preload) {
 358                 $ld_preload = "$ld_preload:$opt_libuid_wrapper_so_path";
 359         } else {
 360                 $ld_preload = "$opt_libuid_wrapper_so_path";
 361         }
 362 }
 363
 364 $ENV{LD_PRELOAD} = $ld_preload;
 365 print "LD_PRELOAD=$ENV{LD_PRELOAD}\n";
 366
 367 # Enable uid_wrapper globally
 368 $ENV{UID_WRAPPER} = 1;
 369
 370 my $socket_wrapper_dir;
 371 if ($opt_socket_wrapper) {
 372         $socket_wrapper_dir = SocketWrapper::setup_dir("$prefix_abs/w", $opt_socket_wrapper_pcap);
 373         print "SOCKET_WRAPPER_DIR=$socket_wrapper_dir\n";
 374 } elsif (not $opt_list) {
 375          unless ($< == 0) {
 376                  warn("not using socket wrapper, but also not running as root. Will not be able to listen on proper ports");
 377          }
 378 }
 379
 380 my $target;
 381 my $testenv_default = "none";
 382
 383 my %binary_mapping = ();
 384 if ($opt_binary_mapping) {
 385     my @binmapping_list = split(/,/, $opt_binary_mapping);
 386     foreach my $mapping (@binmapping_list) {
 387         my ($bin, $map) = split(/\:/, $mapping);
 388         $binary_mapping{$bin} = $map;
 389     }
 390 }
 391
 392 $ENV{BINARY_MAPPING} = $opt_binary_mapping;
 393
 394 # After this many seconds, the server will self-terminate.  All tests
 395 # must terminate in this time, and testenv will only stay alive this
 396 # long
 397
 398 my $server_maxtime = 7500;
 399 if (defined($ENV{SMBD_MAXTIME}) and $ENV{SMBD_MAXTIME} ne "") {
 400     $server_maxtime = $ENV{SMBD_MAXTIME};
 401 }
 402
 403 unless ($opt_list) {
 404         if ($opt_target eq "samba") {
 405                 if ($opt_socket_wrapper and `$bindir/smbd -b | grep SOCKET_WRAPPER` eq "") {
 406                         die("You must include --enable-socket-wrapper when compiling Samba in order to execute 'make test'.  Exiting....");
 407                 }
 408                 $testenv_default = "dc";
 409                 require target::Samba;
 410                 $target = new Samba($bindir, \%binary_mapping, $ldap, $srcdir, $server_maxtime);
 411         } elsif ($opt_target eq "samba3") {
 412                 if ($opt_socket_wrapper and `$bindir/smbd -b | grep SOCKET_WRAPPER` eq "") {
 413                         die("You must include --enable-socket-wrapper when compiling Samba in order to execute 'make test'.  Exiting....");
 414                 }
 415                 $testenv_default = "member";
 416                 require target::Samba3;
 417                 $target = new Samba3($bindir, \%binary_mapping, $srcdir_abs, $server_maxtime);
 418         }
 419 }
 420
 421 sub read_test_regexes($)
 422 {
 423         my ($name) = @_;
 424         my @ret = ();
 425         open(LF, "<$name") or die("unable to read $name: $!");
 426         while (<LF>) {
 427                 chomp;
 428                 next if (/^#/);
 429                 if (/^(.*?)([ \t]+)\#([\t ]*)(.*?)$/) {
 430                         push (@ret, [$1, $4]);
 431                 } else {
 432                         s/^(.*?)([ \t]+)\#([\t ]*)(.*?)$//;
 433                         push (@ret, [$_, undef]);
 434                 }
 435         }
 436         close(LF);
 437         return @ret;
 438 }
 439
 440 foreach (@opt_exclude) {
 441         push (@excludes, read_test_regexes($_));
 442 }
 443
 444 foreach (@opt_include) {
 445         push (@includes, read_test_regexes($_));
 446 }
 447
 448 my $interfaces = join(',', ("127.0.0.11/8",
 449                             "127.0.0.12/8",
 450                             "127.0.0.13/8",
 451                             "127.0.0.14/8",
 452                             "127.0.0.15/8",
 453                             "127.0.0.16/8"));
 454
 455 my $clientdir = "$prefix_abs/client";
 456
 457 my $conffile = "$clientdir/client.conf";
 458 $ENV{SMB_CONF_PATH} = $conffile;
 459
 460 sub write_clientconf($$$)
 461 {
 462         my ($conffile, $clientdir, $vars) = @_;
 463
 464         mkdir("$clientdir", 0777) unless -d "$clientdir";
 465
 466         if ( -d "$clientdir/private" ) {
 467                 unlink <$clientdir/private/*>;
 468         } else {
 469                 mkdir("$clientdir/private", 0777);
 470         }
 471
 472         if ( -d "$clientdir/lockdir" ) {
 473                 unlink <$clientdir/lockdir/*>;
 474         } else {
 475                 mkdir("$clientdir/lockdir", 0777);
 476         }
 477
 478         if ( -d "$clientdir/statedir" ) {
 479                 unlink <$clientdir/statedir/*>;
 480         } else {
 481                 mkdir("$clientdir/statedir", 0777);
 482         }
 483
 484         if ( -d "$clientdir/cachedir" ) {
 485                 unlink <$clientdir/cachedir/*>;
 486         } else {
 487                 mkdir("$clientdir/cachedir", 0777);
 488         }
 489
 490         # this is ugly, but the ncalrpcdir needs exactly 0755
 491         # otherwise tests fail.
 492         my $mask = umask;
 493         umask 0022;
 494         if ( -d "$clientdir/ncalrpcdir/np" ) {
 495                 unlink <$clientdir/ncalrpcdir/np/*>;
 496                 rmdir "$clientdir/ncalrpcdir/np";
 497         }
 498         if ( -d "$clientdir/ncalrpcdir" ) {
 499                 unlink <$clientdir/ncalrpcdir/*>;
 500                 rmdir "$clientdir/ncalrpcdir";
 501         }
 502         mkdir("$clientdir/ncalrpcdir", 0755);
 503         umask $mask;
 504
 505         open(CF, ">$conffile");
 506         print CF "[global]\n";
 507         print CF "\tnetbios name = client\n";
 508         if (defined($vars->{DOMAIN})) {
 509                 print CF "\tworkgroup = $vars->{DOMAIN}\n";
 510         }
 511         if (defined($vars->{REALM})) {
 512                 print CF "\trealm = $vars->{REALM}\n";
 513         }
 514         if ($opt_socket_wrapper) {
 515                 print CF "\tinterfaces = $interfaces\n";
 516         }
 517         print CF "
 518         private dir = $clientdir/private
 519         lock dir = $clientdir/lockdir
 520         state directory = $clientdir/statedir
 521         cache directory = $clientdir/cachedir
 522         ncalrpc dir = $clientdir/ncalrpcdir
 523         name resolve order = file bcast
 524         panic action = $RealBin/gdb_backtrace \%d
 525         max xmit = 32K
 526         notify:inotify = false
 527         ldb:nosync = true
 528         system:anonymous = true
 529         client lanman auth = Yes
 530         log level = 1
 531         torture:basedir = $clientdir
 532 #We don't want to pass our self-tests if the PAC code is wrong
 533         gensec:require_pac = true
 534         resolv:host file = $prefix_abs/dns_host_file
 535 #We don't want to run 'speed' tests for very long
 536         torture:timelimit = 1
 537 ";
 538         close(CF);
 539 }
 540
 541 my @todo = ();
 542
 543 sub should_run_test($)
 544 {
 545         my $name = shift;
 546         if ($#tests == -1) {
 547                 return 1;
 548         }
 549         for (my $i=0; $i <= $#tests; $i++) {
 550                 if ($name =~ /$tests[$i]/i) {
 551                         return 1;
 552                 }
 553         }
 554         return 0;
 555 }
 556
 557 sub read_testlist($)
 558 {
 559         my ($filename) = @_;
 560
 561         my @ret = ();
 562         open(IN, $filename) or die("Unable to open $filename: $!");
 563
 564         while (<IN>) {
 565                 if (/-- TEST(-LOADLIST|-IDLIST|) --\n/) {
 566                         my $supports_loadlist = (defined($1) and $1 eq "-LOADLIST");
 567                         my $supports_idlist = (defined($1) and $1 eq "-IDLIST");
 568                         my $name = <IN>;
 569                         $name =~ s/\n//g;
 570                         my $env = <IN>;
 571                         $env =~ s/\n//g;
 572                         my $cmdline = <IN>;
 573                         $cmdline =~ s/\n//g;
 574                         if (should_run_test($name) == 1) {
 575                                 push (@ret, [$name, $env, $cmdline, $supports_loadlist, $supports_idlist]);
 576                         }
 577                 } else {
 578                         print;
 579                 }
 580         }
 581         close(IN) or die("Error creating recipe");
 582         return @ret;
 583 }
 584
 585 if ($#testlists == -1) {
 586         die("No testlists specified");
 587 }
 588
 589 $ENV{SELFTEST_PREFIX} = "$prefix_abs";
 590 $ENV{SELFTEST_TMPDIR} = "$tmpdir_abs";
 591 $ENV{TEST_DATA_PREFIX} = "$tmpdir_abs";
 592 if ($opt_socket_wrapper) {
 593         $ENV{SELFTEST_INTERFACES} = $interfaces;
 594 } else {
 595         $ENV{SELFTEST_INTERFACES} = "";
 596 }
 597 if ($opt_quick) {
 598         $ENV{SELFTEST_QUICK} = "1";
 599 } else {
 600         $ENV{SELFTEST_QUICK} = "";
 601 }
 602 $ENV{SELFTEST_MAXTIME} = $torture_maxtime;
 603
 604 my @available = ();
 605 foreach my $fn (@testlists) {
 606         foreach (read_testlist($fn)) {
 607                 my $name = $$_[0];
 608                 next if (@includes and not defined(find_in_list(\@includes, $name)));
 609                 push (@available, $_);
 610         }
 611 }
 612
 613 my $restricted = undef;
 614 my $restricted_used = {};
 615
 616 if ($opt_load_list) {
 617         $restricted = [];
 618         open(LOAD_LIST, "<$opt_load_list") or die("Unable to open $opt_load_list");
 619         while (<LOAD_LIST>) {
 620                 chomp;
 621                 push (@$restricted, $_);
 622         }
 623         close(LOAD_LIST);
 624 }
 625
 626 my $individual_tests = undef;
 627 $individual_tests = {};
 628
 629 foreach my $testsuite (@available) {
 630         my $name = $$testsuite[0];
 631         my $skipreason = skip($name);
 632         if (defined($restricted)) {
 633                 # Find the testsuite for this test
 634                 my $match = undef;
 635                 foreach my $r (@$restricted) {
 636                         if ($r eq $name) {
 637                                 $individual_tests->{$name} = [];
 638                                 $match = $r;
 639                                 $restricted_used->{$r} = 1;
 640                         } elsif (substr($r, 0, length($name)+1) eq "$name.") {
 641                                 push(@{$individual_tests->{$name}}, $r);
 642                                 $match = $r;
 643                                 $restricted_used->{$r} = 1;
 644                         }
 645                 }
 646                 if ($match) {
 647                         if (defined($skipreason)) {
 648                                 if (not $opt_list) {
 649                                         Subunit::skip_testsuite($name, $skipreason);
 650                                 }
 651                         } else {
 652                                 push(@todo, $testsuite);
 653                         }
 654                 }
 655         } elsif (defined($skipreason)) {
 656                 if (not $opt_list) {
 657                         Subunit::skip_testsuite($name, $skipreason);
 658                 }
 659         } else {
 660                 push(@todo, $testsuite);
 661         }
 662 }
 663
 664 if (defined($restricted)) {
 665         foreach (@$restricted) {
 666                 unless (defined($restricted_used->{$_})) {
 667                         print "No test or testsuite found matching $_\n";
 668                 }
 669         }
 670 } elsif ($#todo == -1) {
 671         print STDERR "No tests to run\n";
 672         exit(1);
 673 }
 674
 675 my $suitestotal = $#todo + 1;
 676
 677 unless ($opt_list) {
 678         Subunit::progress($suitestotal);
 679         Subunit::report_time(time());
 680 }
 681
 682 my $i = 0;
 683 $| = 1;
 684
 685 my %running_envs = ();
 686
 687 sub get_running_env($)
 688 {
 689         my ($name) = @_;
 690
 691         my $envname = $name;
 692
 693         $envname =~ s/:.*//;
 694
 695         return $running_envs{$envname};
 696 }
 697
 698 my @exported_envvars = (
 699         # domain stuff
 700         "DOMAIN",
 701         "REALM",
 702
 703         # domain controller stuff
 704         "DC_SERVER",
 705         "DC_SERVER_IP",
 706         "DC_NETBIOSNAME",
 707         "DC_NETBIOSALIAS",
 708
 709         # domain member
 710         "MEMBER_SERVER",
 711         "MEMBER_SERVER_IP",
 712         "MEMBER_NETBIOSNAME",
 713         "MEMBER_NETBIOSALIAS",
 714
 715         # rpc proxy controller stuff
 716         "RPC_PROXY_SERVER",
 717         "RPC_PROXY_SERVER_IP",
 718         "RPC_PROXY_NETBIOSNAME",
 719         "RPC_PROXY_NETBIOSALIAS",
 720
 721         # domain controller stuff for Vampired DC
 722         "VAMPIRE_DC_SERVER",
 723         "VAMPIRE_DC_SERVER_IP",
 724         "VAMPIRE_DC_NETBIOSNAME",
 725         "VAMPIRE_DC_NETBIOSALIAS",
 726
 727         "PROMOTED_DC_SERVER",
 728         "PROMOTED_DC_SERVER_IP",
 729         "PROMOTED_DC_NETBIOSNAME",
 730         "PROMOTED_DC_NETBIOSALIAS",
 731
 732         # server stuff
 733         "SERVER",
 734         "SERVER_IP",
 735         "NETBIOSNAME",
 736         "NETBIOSALIAS",
 737
 738         # user stuff
 739         "USERNAME",
 740         "USERID",
 741         "PASSWORD",
 742         "DC_USERNAME",
 743         "DC_PASSWORD",
 744
 745         # misc stuff
 746         "KRB5_CONFIG",
 747         "WINBINDD_SOCKET_DIR",
 748         "WINBINDD_PRIV_PIPE_DIR",
 749         "NMBD_SOCKET_DIR",
 750         "LOCAL_PATH",
 751
 752         # nss_wrapper
 753         "NSS_WRAPPER_PASSWD",
 754         "NSS_WRAPPER_GROUP",
 755
 756         # UID/GID for rfc2307 mapping tests
 757         "UID_RFC2307TEST",
 758         "GID_RFC2307TEST"
 759 );
 760
 761 $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 762         my $signame = shift;
 763         teardown_env($_) foreach(keys %running_envs);
 764         die("Received signal $signame");
 765 };
 766
 767 sub setup_env($$)
 768 {
 769         my ($name, $prefix) = @_;
 770
 771         my $testenv_vars = undef;
 772
 773         my $envname = $name;
 774         my $option = $name;
 775
 776         $envname =~ s/:.*//;
 777         $option =~ s/^[^:]*//;
 778         $option =~ s/^://;
 779
 780         $option = "client" if $option eq "";
 781
 782         if ($envname eq "none") {
 783                 $testenv_vars = {};
 784         } elsif (defined(get_running_env($envname))) {
 785                 $testenv_vars = get_running_env($envname);
 786                 if (not $testenv_vars->{target}->check_env($testenv_vars)) {
 787                         print $testenv_vars->{target}->getlog_env($testenv_vars);
 788                         $testenv_vars = undef;
 789                 }
 790         } else {
 791                 $testenv_vars = $target->setup_env($envname, $prefix);
 792                 if (defined($testenv_vars) and $testenv_vars eq "UNKNOWN") {
 793                     return $testenv_vars;
 794                 } elsif (defined($testenv_vars) && not defined($testenv_vars->{target})) {
 795                         $testenv_vars->{target} = $target;
 796                 }
 797                 if (not defined($testenv_vars)) {
 798                         warn("$opt_target can't start up known environment '$envname'");
 799                 }
 800         }
 801
 802
 803         return undef unless defined($testenv_vars);
 804
 805         $running_envs{$envname} = $testenv_vars;
 806
 807         if ($option eq "local") {
 808                 SocketWrapper::set_default_iface($testenv_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 809                 $ENV{SMB_CONF_PATH} = $testenv_vars->{SERVERCONFFILE};
 810         } elsif ($option eq "client") {
 811                 SocketWrapper::set_default_iface(11);
 812                 write_clientconf($conffile, $clientdir, $testenv_vars);
 813                 $ENV{SMB_CONF_PATH} = $conffile;
 814         } else {
 815                 die("Unknown option[$option] for envname[$envname]");
 816         }
 817
 818         foreach (@exported_envvars) {
 819                 if (defined($testenv_vars->{$_})) {
 820                         $ENV{$_} = $testenv_vars->{$_};
 821                 } else {
 822                         delete $ENV{$_};
 823                 }
 824         }
 825
 826         return $testenv_vars;
 827 }
 828
 829 sub exported_envvars_str($)
 830 {
 831         my ($testenv_vars) = @_;
 832         my $out = "";
 833
 834         foreach (@exported_envvars) {
 835                 next unless defined($testenv_vars->{$_});
 836                 $out .= $_."=".$testenv_vars->{$_}."\n";
 837         }
 838
 839         return $out;
 840 }
 841
 842 sub getlog_env($)
 843 {
 844         my ($envname) = @_;
 845         return "" if ($envname eq "none");
 846         my $env = get_running_env($envname);
 847         return $env->{target}->getlog_env($env);
 848 }
 849
 850 sub check_env($)
 851 {
 852         my ($envname) = @_;
 853         return 1 if ($envname eq "none");
 854         my $env = get_running_env($envname);
 855         return $env->{target}->check_env($env);
 856 }
 857
 858 sub teardown_env($)
 859 {
 860         my ($envname) = @_;
 861         return if ($envname eq "none");
 862         my $env = get_running_env($envname);
 863         $env->{target}->teardown_env($env);
 864         delete $running_envs{$envname};
 865 }
 866
 867 # This 'global' file needs to be empty when we start
 868 unlink("$prefix_abs/dns_host_file");
 869 unlink("$prefix_abs/hosts");
 870
 871 if ($opt_random_order) {
 872         require List::Util;
 873         my @newtodo = List::Util::shuffle(@todo);
 874         @todo = @newtodo;
 875 }
 876
 877 if ($opt_testenv) {
 878         my $testenv_name = $ENV{SELFTEST_TESTENV};
 879         $testenv_name = $testenv_default unless defined($testenv_name);
 880
 881         my $testenv_vars = setup_env($testenv_name, $prefix);
 882
 883         if (not $testenv_vars or $testenv_vars eq "UNKNOWN") {
 884                 die("Unable to setup environment $testenv_name");
 885         }
 886
 887         $ENV{PIDDIR} = $testenv_vars->{PIDDIR};
 888         $ENV{ENVNAME} = $testenv_name;
 889
 890         my $envvarstr = exported_envvars_str($testenv_vars);
 891
 892         my @term_args = ("echo -e \"
 893 Welcome to the Samba4 Test environment '$testenv_name'
 894
 895 This matches the client environment used in make test
 896 server is pid `cat \$PIDDIR/samba.pid`
 897
 898 Some useful environment variables:
 899 TORTURE_OPTIONS=\$TORTURE_OPTIONS
 900 SMB_CONF_PATH=\$SMB_CONF_PATH
 901
 902 $envvarstr
 903 \" && LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} bash");
 904         my @term = ();
 905         if ($ENV{TERMINAL}) {
 906             @term = ($ENV{TERMINAL});
 907         } else {
 908             @term = ("xterm", "-e");
 909             unshift(@term_args, ("bash", "-c"));
 910         }
 911
 912         system(@term, @term_args);
 913
 914         teardown_env($testenv_name);
 915 } elsif ($opt_list) {
 916         foreach (@todo) {
 917                 my $cmd = $$_[2];
 918                 my $name = $$_[0];
 919                 my $envname = $$_[1];
 920
 921                 unless($cmd =~ /\$LISTOPT/) {
 922                         warn("Unable to list tests in $name");
 923                         next;
 924                 }
 925
 926                 $cmd =~ s/\$LISTOPT/--list/g;
 927
 928                 system($cmd);
 929
 930                 if ($? == -1) {
 931                         die("Unable to run $cmd: $!");
 932                 } elsif ($? & 127) {
 933                         die(sprintf("%s died with signal %d, %s coredump\n", $cmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 934                 }
 935
 936                 my $exitcode = $? >> 8;
 937                 if ($exitcode != 0) {
 938                         die("$cmd exited with exit code $exitcode");
 939                 }
 940         }
 941 } else {
 942         foreach (@todo) {
 943                 $i++;
 944                 my $cmd = $$_[2];
 945                 my $name = $$_[0];
 946                 my $envname = $$_[1];
 947
 948                 my $envvars = setup_env($envname, $prefix);
 949                 if (not defined($envvars)) {
 950                         Subunit::start_testsuite($name);
 951                         Subunit::end_testsuite($name, "error",
 952                                 "unable to set up environment $envname - exiting");
 953                         next;
 954                 } elsif ($envvars eq "UNKNOWN") {
 955                         Subunit::start_testsuite($name);
 956                         Subunit::end_testsuite($name, "skip",
 957                                 "environment $envname is unknown in this test backend - skipping");
 958                         next;
 959                 }
 960
 961                 # Generate a file with the individual tests to run, if the
 962                 # test runner for this test suite supports it.
 963                 if ($individual_tests and $individual_tests->{$name}) {
 964                         if ($$_[3]) {
 965                                 my ($fh, $listid_file) = tempfile(UNLINK => 0);
 966                                 foreach my $test (@{$individual_tests->{$name}}) {
 967                                         print $fh substr($test, length($name)+1) . "\n";
 968                                 }
 969                                 $cmd =~ s/\$LOADLIST/--load-list=$listid_file/g;
 970                         } elsif ($$_[4]) {
 971                                 $cmd =~ s/\s+[^\s]+\s*$//;
 972                                 $cmd .= " " . join(' ', @{$individual_tests->{$name}});
 973                         }
 974                 }
 975
 976                 run_testsuite($envname, $name, $cmd, $i, $suitestotal);
 977
 978                 teardown_env($envname) if ($opt_resetup_env);
 979         }
 980 }
 981
 982 print "\n";
 983
 984 teardown_env($_) foreach (keys %running_envs);
 985
 986 my $failed = 0;
 987
 988 # if there were any valgrind failures, show them
 989 foreach (<$prefix/valgrind.log*>) {
 990         next unless (-s $_);
 991         print "VALGRIND FAILURE\n";
 992         $failed++;
 993         system("cat $_");
 994 }
 995 exit 0;