source3/lib/replace/libreplace.m4

   1 AC_DEFUN_ONCE(AC_LIBREPLACE_LOCATION_CHECKS,
   2 [
   3 echo "LIBREPLACE_LOCATION_CHECKS: START"
   4
   5 dnl find the libreplace sources. This is meant to work both for
   6 dnl libreplace standalone builds, and builds of packages using libreplace
   7 libreplacedir=""
   8 libreplacepaths="$srcdir $srcdir/lib/replace $srcdir/libreplace $srcdir/../libreplace $srcdir/../replace"
   9 for d in $libreplacepaths; do
  10         if test -f "$d/replace.c"; then
  11                 libreplacedir="$d"
  12                 AC_SUBST(libreplacedir)
  13                 break;
  14         fi
  15 done
  16 if test x"$libreplacedir" = "x"; then
  17         AC_MSG_ERROR([cannot find libreplace in $libreplacepaths])
  18 fi
  19 LIBREPLACEOBJ="replace.o"
  20 AC_SUBST(LIBREPLACEOBJ)
  21
  22 AC_CANONICAL_BUILD
  23 AC_CANONICAL_HOST
  24 AC_CANONICAL_TARGET
  25
  26 echo "LIBREPLACE_LOCATION_CHECKS: END"
  27 ]) dnl end AC_LIBREPLACE_LOCATION_CHECKS
  28
  29
  30 AC_DEFUN_ONCE(AC_LIBREPLACE_BROKEN_CHECKS,
  31 [
  32 echo "LIBREPLACE_BROKEN_CHECKS: START"
  33
  34 dnl find the libreplace sources. This is meant to work both for
  35 dnl libreplace standalone builds, and builds of packages using libreplace
  36 libreplacedir=""
  37 for d in "$srcdir" "$srcdir/lib/replace" "$srcdir/libreplace" "$srcdir/../libreplace" "$srcdir/../replace"; do
  38         if test -f "$d/replace.c"; then
  39                 libreplacedir="$d"
  40                 AC_SUBST(libreplacedir)
  41                 break;
  42         fi
  43 done
  44 LIBREPLACEOBJ="replace.o"
  45 AC_SUBST(LIBREPLACEOBJ)
  46
  47 LIBREPLACEOBJ="${LIBREPLACEOBJ} snprintf.o"
  48
  49 AC_TYPE_SIGNAL
  50 AC_TYPE_UID_T
  51 AC_TYPE_MODE_T
  52 AC_TYPE_OFF_T
  53 AC_TYPE_SIZE_T
  54 AC_TYPE_PID_T
  55 AC_STRUCT_ST_RDEV
  56 AC_CHECK_TYPE(ino_t,unsigned)
  57 AC_CHECK_TYPE(loff_t,off_t)
  58 AC_CHECK_TYPE(offset_t,loff_t)
  59
  60 AC_FUNC_MEMCMP
  61
  62 AC_CHECK_FUNCS(pipe strftime srandom random srand rand usleep setbuffer lstat getpgrp)
  63
  64 AC_CHECK_HEADERS(stdbool.h stdint.h sys/select.h)
  65 AC_CHECK_HEADERS(setjmp.h)
  66
  67 LIBREPLACE_PROVIDE_HEADER([stdint.h])
  68 LIBREPLACE_PROVIDE_HEADER([stdbool.h])
  69
  70 AC_CHECK_TYPE(bool,
  71 [AC_DEFINE(HAVE_BOOL, 1, [Whether the bool type is available])],,
  72 [
  73 AC_INCLUDES_DEFAULT
  74 #ifdef HAVE_STDBOOL_H
  75 #include <stdbool.h>
  76 #endif]
  77 )
  78
  79 AC_CHECK_TYPE(_Bool,
  80 [AC_DEFINE(HAVE__Bool, 1, [Whether the _Bool type is available])],,
  81 [
  82 AC_INCLUDES_DEFAULT
  83 #ifdef HAVE_STDBOOL_H
  84 #include <stdbool.h>
  85 #endif]
  86 )
  87
  88 AC_CACHE_CHECK([for working mmap],samba_cv_HAVE_MMAP,[
  89 AC_TRY_RUN([#include "$libreplacedir/test/shared_mmap.c"],
  90            samba_cv_HAVE_MMAP=yes,samba_cv_HAVE_MMAP=no,samba_cv_HAVE_MMAP=cross)])
  91 if test x"$samba_cv_HAVE_MMAP" = x"yes"; then
  92     AC_DEFINE(HAVE_MMAP,1,[Whether mmap works])
  93 fi
  94
  95
  96 AC_CHECK_HEADERS(sys/syslog.h syslog.h)
  97 AC_CHECK_HEADERS(sys/time.h time.h)
  98 AC_CHECK_HEADERS(stdarg.h vararg.h)
  99 AC_CHECK_HEADERS(sys/socket.h netinet/in.h netdb.h arpa/inet.h)
 100 AC_CHECK_HEADERS(netinet/ip.h netinet/tcp.h netinet/in_systm.h netinet/in_ip.h)
 101 AC_CHECK_HEADERS(sys/sockio.h sys/un.h)
 102 AC_CHECK_HEADERS(sys/mount.h mntent.h)
 103
 104 dnl we need to check that net/if.h really can be used, to cope with hpux
 105 dnl where including it always fails
 106 AC_CACHE_CHECK([for usable net/if.h],libreplace_cv_USABLE_NET_IF_H,[
 107         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 108                 AC_INCLUDES_DEFAULT
 109                 #if HAVE_SYS_SOCKET_H
 110                 # include <sys/socket.h>
 111                 #endif
 112                 #include <net/if.h>
 113                 int main(void) {return 0;}])],
 114                 [libreplace_cv_USABLE_NET_IF_H=yes],
 115                 [libreplace_cv_USABLE_NET_IF_H=no]
 116         )
 117 ])
 118 if test x"$libreplace_cv_USABLE_NET_IF_H" = x"yes";then
 119         AC_DEFINE(HAVE_NET_IF_H, 1, usability of net/if.h)
 120 fi
 121
 122 AC_CACHE_CHECK([for broken inet_ntoa],samba_cv_REPLACE_INET_NTOA,[
 123 AC_TRY_RUN([
 124 #include <stdio.h>
 125 #include <unistd.h>
 126 #include <sys/types.h>
 127 #include <netinet/in.h>
 128 #ifdef HAVE_ARPA_INET_H
 129 #include <arpa/inet.h>
 130 #endif
 131 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 132 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 133     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(0); }
 134 exit(1);}],
 135            samba_cv_REPLACE_INET_NTOA=yes,samba_cv_REPLACE_INET_NTOA=no,samba_cv_REPLACE_INET_NTOA=cross)])
 136 if test x"$samba_cv_REPLACE_INET_NTOA" = x"yes"; then
 137     AC_DEFINE(REPLACE_INET_NTOA,1,[Whether inet_ntoa should be replaced])
 138 fi
 139
 140 dnl Provided by replace.c:
 141 AC_TRY_COMPILE([
 142 #include <sys/types.h>
 143 #if STDC_HEADERS
 144 #include <stdlib.h>
 145 #include <stddef.h>
 146 #endif
 147 #include <sys/socket.h>],
 148 [socklen_t foo;],,
 149 [AC_DEFINE(socklen_t, int,[Socket length type])])
 150
 151 AC_CHECK_FUNCS(seteuid setresuid setegid setresgid chroot bzero strerror)
 152 AC_CHECK_FUNCS(vsyslog setlinebuf mktime ftruncate chsize rename)
 153 AC_CHECK_FUNCS(waitpid strlcpy strlcat initgroups memmove strdup)
 154 AC_CHECK_FUNCS(pread pwrite strndup strcasestr strtok_r mkdtemp socketpair)
 155 AC_CHECK_FUNCS(isatty)
 156 AC_HAVE_DECL(setresuid, [#include <unistd.h>])
 157 AC_HAVE_DECL(setresgid, [#include <unistd.h>])
 158 AC_HAVE_DECL(errno, [#include <errno.h>])
 159
 160 AC_CACHE_CHECK([for secure mkstemp],samba_cv_HAVE_SECURE_MKSTEMP,[
 161 AC_TRY_RUN([#include <stdlib.h>
 162 #include <sys/types.h>
 163 #include <sys/stat.h>
 164 #include <unistd.h>
 165 main() {
 166   struct stat st;
 167   char tpl[20]="/tmp/test.XXXXXX";
 168   int fd = mkstemp(tpl);
 169   if (fd == -1) exit(1);
 170   unlink(tpl);
 171   if (fstat(fd, &st) != 0) exit(1);
 172   if ((st.st_mode & 0777) != 0600) exit(1);
 173   exit(0);
 174 }],
 175 samba_cv_HAVE_SECURE_MKSTEMP=yes,
 176 samba_cv_HAVE_SECURE_MKSTEMP=no,
 177 samba_cv_HAVE_SECURE_MKSTEMP=cross)])
 178 if test x"$samba_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 179     AC_DEFINE(HAVE_SECURE_MKSTEMP,1,[Whether mkstemp is secure])
 180 fi
 181
 182 dnl Provided by snprintf.c:
 183 AC_CHECK_HEADERS(stdio.h strings.h)
 184 AC_CHECK_DECLS([snprintf, vsnprintf, asprintf, vasprintf])
 185 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 186
 187 AC_CACHE_CHECK([for C99 vsnprintf],samba_cv_HAVE_C99_VSNPRINTF,[
 188 AC_TRY_RUN([
 189 #include <sys/types.h>
 190 #include <stdio.h>
 191 #include <stdarg.h>
 192 #include <stdlib.h>
 193 void foo(const char *format, ...) {
 194        va_list ap;
 195        int len;
 196        char buf[20];
 197        long long l = 1234567890;
 198        l *= 100;
 199
 200        va_start(ap, format);
 201        len = vsnprintf(buf, 0, format, ap);
 202        va_end(ap);
 203        if (len != 5) exit(1);
 204
 205        va_start(ap, format);
 206        len = vsnprintf(0, 0, format, ap);
 207        va_end(ap);
 208        if (len != 5) exit(2);
 209
 210        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(3);
 211
 212        if (snprintf(buf, 20, "%lld", l) != 12 || strcmp(buf, "123456789000") != 0) exit(4);
 213        if (snprintf(buf, 20, "%zu", 123456789) != 9 || strcmp(buf, "123456789") != 0) exit(5);
 214        if (snprintf(buf, 20, "%2\$d %1\$d", 3, 4) != 3 || strcmp(buf, "4 3") != 0) exit(6);
 215        if (snprintf(buf, 20, "%s", 0) < 3) exit(7);
 216
 217        exit(0);
 218 }
 219 main() { foo("hello"); }
 220 ],
 221 samba_cv_HAVE_C99_VSNPRINTF=yes,samba_cv_HAVE_C99_VSNPRINTF=no,samba_cv_HAVE_C99_VSNPRINTF=cross)])
 222 if test x"$samba_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 223     AC_DEFINE(HAVE_C99_VSNPRINTF,1,[Whether there is a C99 compliant vsnprintf])
 224 fi
 225
 226
 227 dnl VA_COPY
 228 AC_CACHE_CHECK([for va_copy],samba_cv_HAVE_VA_COPY,[
 229 AC_TRY_LINK([#include <stdarg.h>
 230 va_list ap1,ap2;], [va_copy(ap1,ap2);],
 231 samba_cv_HAVE_VA_COPY=yes,samba_cv_HAVE_VA_COPY=no)])
 232 if test x"$samba_cv_HAVE_VA_COPY" = x"yes"; then
 233     AC_DEFINE(HAVE_VA_COPY,1,[Whether va_copy() is available])
 234 fi
 235
 236 if test x"$samba_cv_HAVE_VA_COPY" != x"yes"; then
 237 AC_CACHE_CHECK([for __va_copy],samba_cv_HAVE___VA_COPY,[
 238 AC_TRY_LINK([#include <stdarg.h>
 239 va_list ap1,ap2;], [__va_copy(ap1,ap2);],
 240 samba_cv_HAVE___VA_COPY=yes,samba_cv_HAVE___VA_COPY=no)])
 241 if test x"$samba_cv_HAVE___VA_COPY" = x"yes"; then
 242     AC_DEFINE(HAVE___VA_COPY,1,[Whether __va_copy() is available])
 243 fi
 244 fi
 245
 246 dnl __FUNCTION__ macro
 247 AC_CACHE_CHECK([for __FUNCTION__ macro],samba_cv_HAVE_FUNCTION_MACRO,[
 248 AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __FUNCTION__);],
 249 samba_cv_HAVE_FUNCTION_MACRO=yes,samba_cv_HAVE_FUNCTION_MACRO=no)])
 250 if test x"$samba_cv_HAVE_FUNCTION_MACRO" = x"yes"; then
 251     AC_DEFINE(HAVE_FUNCTION_MACRO,1,[Whether there is a __FUNCTION__ macro])
 252 else
 253     dnl __func__ macro
 254     AC_CACHE_CHECK([for __func__ macro],samba_cv_HAVE_func_MACRO,[
 255     AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __func__);],
 256     samba_cv_HAVE_func_MACRO=yes,samba_cv_HAVE_func_MACRO=no)])
 257     if test x"$samba_cv_HAVE_func_MACRO" = x"yes"; then
 258        AC_DEFINE(HAVE_func_MACRO,1,[Whether there is a __func__ macro])
 259     fi
 260 fi
 261
 262 AC_CHECK_HEADERS([sys/param.h limits.h])
 263
 264 AC_CHECK_TYPE(comparison_fn_t,
 265 [AC_DEFINE(HAVE_COMPARISON_FN_T, 1,[Whether or not we have comparison_fn_t])])
 266
 267 AC_HAVE_DECL(setenv, [#include <stdlib.h>])
 268 AC_CHECK_FUNCS(setenv unsetenv)
 269
 270 AC_CHECK_FUNCS(strnlen)
 271 AC_CHECK_FUNCS(strtoull __strtoull strtouq strtoll __strtoll strtoq)
 272
 273 # this test disabled as we don't actually need __VA_ARGS__ yet
 274 AC_TRY_CPP([
 275 #define eprintf(...) fprintf(stderr, __VA_ARGS__)
 276 eprintf("bla", "bar");
 277 ], AC_DEFINE(HAVE__VA_ARGS__MACRO, 1, [Whether the __VA_ARGS__ macro is available]))
 278
 279 # Check prerequisites
 280 AC_CHECK_FUNCS([memset printf syslog], [],
 281                            [ AC_MSG_ERROR([Required function not found])])
 282
 283 AC_CACHE_CHECK([for sig_atomic_t type],samba_cv_sig_atomic_t, [
 284     AC_TRY_COMPILE([
 285 #include <sys/types.h>
 286 #if STDC_HEADERS
 287 #include <stdlib.h>
 288 #include <stddef.h>
 289 #endif
 290 #include <signal.h>],[sig_atomic_t i = 0],
 291         samba_cv_sig_atomic_t=yes,samba_cv_sig_atomic_t=no)])
 292 if test x"$samba_cv_sig_atomic_t" = x"yes"; then
 293    AC_DEFINE(HAVE_SIG_ATOMIC_T_TYPE,1,[Whether we have the atomic_t variable type])
 294 fi
 295
 296
 297 AC_CACHE_CHECK([for O_DIRECT flag to open(2)],samba_cv_HAVE_OPEN_O_DIRECT,[
 298 AC_TRY_COMPILE([
 299 #include <unistd.h>
 300 #ifdef HAVE_FCNTL_H
 301 #include <fcntl.h>
 302 #endif],
 303 [int fd = open("/dev/null", O_DIRECT);],
 304 samba_cv_HAVE_OPEN_O_DIRECT=yes,samba_cv_HAVE_OPEN_O_DIRECT=no)])
 305 if test x"$samba_cv_HAVE_OPEN_O_DIRECT" = x"yes"; then
 306     AC_DEFINE(HAVE_OPEN_O_DIRECT,1,[Whether the open(2) accepts O_DIRECT])
 307 fi
 308
 309
 310 dnl Check if the C compiler understands volatile (it should, being ANSI).
 311 AC_CACHE_CHECK([that the C compiler understands volatile],samba_cv_volatile, [
 312         AC_TRY_COMPILE([#include <sys/types.h>],[volatile int i = 0],
 313                 samba_cv_volatile=yes,samba_cv_volatile=no)])
 314 if test x"$samba_cv_volatile" = x"yes"; then
 315         AC_DEFINE(HAVE_VOLATILE, 1, [Whether the C compiler understands volatile])
 316 fi
 317
 318 m4_include(system/config.m4)
 319
 320 m4_include(dlfcn.m4)
 321 m4_include(getpass.m4)
 322 m4_include(strptime.m4)
 323 m4_include(win32.m4)
 324 m4_include(timegm.m4)
 325 m4_include(inet_ntop.m4)
 326 m4_include(inet_pton.m4)
 327 m4_include(repdir.m4)
 328
 329 AC_CHECK_FUNCS([syslog memset memcpy],,[AC_MSG_ERROR([Required function not found])])
 330
 331 echo "LIBREPLACE_BROKEN_CHECKS: END"
 332 ]) dnl end AC_LIBREPLACE_BROKEN_CHECKS
 333
 334 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_START,
 335 [
 336 #LIBREPLACE_ALL_CHECKS: START"
 337 ])
 338 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_END,
 339 [
 340 #LIBREPLACE_ALL_CHECKS: END"
 341 ])
 342 m4_define(AC_LIBREPLACE_ALL_CHECKS,
 343 [
 344 AC__LIBREPLACE_ALL_CHECKS_START
 345 AC_LIBREPLACE_LOCATION_CHECKS
 346 AC_LIBREPLACE_CC_CHECKS
 347 AC_LIBREPLACE_BROKEN_CHECKS
 348 AC__LIBREPLACE_ALL_CHECKS_END
 349 CFLAGS="$CFLAGS -I$libreplacedir"
 350 ])
 351
 352 m4_include(libreplace_cc.m4)
 353 m4_include(libreplace_macros.m4)
 354 m4_include(autoconf-2.60.m4)