selftest/target/Samba3.pm

   1 #!/usr/bin/perl
   2 # Bootstrap Samba and run a number of tests against it.
   3 # Copyright (C) 2005-2007 Jelmer Vernooij <jelmer@samba.org>
   4 # Published under the GNU GPL, v3 or later.
   5
   6 package Samba3;
   7
   8 use strict;
   9 use Cwd qw(abs_path);
  10 use FindBin qw($RealBin);
  11 use POSIX;
  12 use target::Samba;
  13
  14 sub have_ads($) {
  15         my ($self) = @_;
  16         my $found_ads = 0;
  17         my $smbd_build_options = Samba::bindir_path($self, "smbd") . " -b|";
  18         open(IN, $smbd_build_options) or die("Unable to run $smbd_build_options: $!");
  19
  20         while (<IN>) {
  21                 if (/WITH_ADS/) {
  22                        $found_ads = 1;
  23                 }
  24         }
  25         close IN;
  26
  27         # If we were not built with ADS support, pretend we were never even available
  28         return $found_ads;
  29 }
  30
  31 sub new($$) {
  32         my ($classname, $bindir, $binary_mapping, $srcdir, $server_maxtime) = @_;
  33         my $self = { vars => {},
  34                      bindir => $bindir,
  35                      binary_mapping => $binary_mapping,
  36                      srcdir => $srcdir,
  37                      server_maxtime => $server_maxtime
  38         };
  39         bless $self;
  40         return $self;
  41 }
  42
  43 sub teardown_env($$)
  44 {
  45         my ($self, $envvars) = @_;
  46         my $count = 0;
  47
  48         # This should cause smbd to terminate gracefully
  49         close($envvars->{STDIN_PIPE});
  50
  51         my $smbdpid = $envvars->{SMBD_TL_PID};
  52         my $nmbdpid = $envvars->{NMBD_TL_PID};
  53         my $winbinddpid = $envvars->{WINBINDD_TL_PID};
  54
  55         # This should give it time to write out the gcov data
  56         until ($count > 20) {
  57             my $smbdchild = Samba::cleanup_child($smbdpid, "smbd");
  58             my $nmbdchild = Samba::cleanup_child($nmbdpid, "nmbd");
  59             my $winbinddchild = Samba::cleanup_child($winbinddpid, "winbindd");
  60             if ($smbdchild == -1
  61                 && $nmbdchild == -1
  62                 && $winbinddchild == -1) {
  63                 last;
  64             }
  65             sleep(1);
  66             $count++;
  67         }
  68
  69         if ($count <= 20 && kill(0, $smbdpid, $nmbdpid, $winbinddpid) == 0) {
  70             return;
  71         }
  72
  73         $self->stop_sig_term($smbdpid);
  74         $self->stop_sig_term($nmbdpid);
  75         $self->stop_sig_term($winbinddpid);
  76
  77         $count = 0;
  78         until ($count > 10) {
  79             my $smbdchild = Samba::cleanup_child($smbdpid, "smbd");
  80             my $nmbdchild = Samba::cleanup_child($nmbdpid, "nmbd");
  81             my $winbinddchild = Samba::cleanup_child($winbinddpid, "winbindd");
  82             if ($smbdchild == -1
  83                 && $nmbdchild == -1
  84                 && $winbinddchild == -1) {
  85                 last;
  86             }
  87             sleep(1);
  88             $count++;
  89         }
  90
  91         if ($count <= 10 && kill(0, $smbdpid, $nmbdpid, $winbinddpid) == 0) {
  92             return;
  93         }
  94
  95         warn("timelimit process did not quit on SIGTERM, sending SIGKILL");
  96         $self->stop_sig_kill($smbdpid);
  97         $self->stop_sig_kill($nmbdpid);
  98         $self->stop_sig_kill($winbinddpid);
  99
 100         return 0;
 101 }
 102
 103 sub getlog_env_app($$$)
 104 {
 105         my ($self, $envvars, $name) = @_;
 106
 107         my $title = "$name LOG of: $envvars->{NETBIOSNAME}\n";
 108         my $out = $title;
 109
 110         open(LOG, "<".$envvars->{$name."_TEST_LOG"});
 111
 112         seek(LOG, $envvars->{$name."_TEST_LOG_POS"}, SEEK_SET);
 113         while (<LOG>) {
 114                 $out .= $_;
 115         }
 116         $envvars->{$name."_TEST_LOG_POS"} = tell(LOG);
 117         close(LOG);
 118
 119         return "" if $out eq $title;
 120
 121         return $out;
 122 }
 123
 124 sub getlog_env($$)
 125 {
 126         my ($self, $envvars) = @_;
 127         my $ret = "";
 128
 129         $ret .= $self->getlog_env_app($envvars, "SMBD");
 130         $ret .= $self->getlog_env_app($envvars, "NMBD");
 131         $ret .= $self->getlog_env_app($envvars, "WINBINDD");
 132
 133         return $ret;
 134 }
 135
 136 sub check_env($$)
 137 {
 138         my ($self, $envvars) = @_;
 139
 140         my $childpid = waitpid(-1, WNOHANG);
 141
 142         # TODO ...
 143         return 1;
 144 }
 145
 146 sub setup_env($$$)
 147 {
 148         my ($self, $envname, $path) = @_;
 149
 150         if (defined($self->{vars}->{$envname})) {
 151                 return $self->{vars}->{$envname};
 152         }
 153
 154         if ($envname eq "s3dc") {
 155                 return $self->setup_s3dc("$path/s3dc");
 156         } elsif ($envname eq "simpleserver") {
 157                 return $self->setup_simpleserver("$path/simpleserver");
 158         } elsif ($envname eq "maptoguest") {
 159                 return $self->setup_maptoguest("$path/maptoguest");
 160         } elsif ($envname eq "ktest") {
 161                 return $self->setup_ktest("$path/ktest");
 162         } elsif ($envname eq "member") {
 163                 if (not defined($self->{vars}->{s3dc})) {
 164                         if (not defined($self->setup_s3dc("$path/s3dc"))) {
 165                                 return undef;
 166                         }
 167                 }
 168                 return $self->setup_member("$path/member", $self->{vars}->{s3dc});
 169         } else {
 170                 return "UNKNOWN";
 171         }
 172 }
 173
 174 sub setup_s3dc($$)
 175 {
 176         my ($self, $path) = @_;
 177
 178         print "PROVISIONING S3DC...";
 179
 180         my $s3dc_options = "
 181         domain master = yes
 182         domain logons = yes
 183         lanman auth = yes
 184
 185         rpc_server:epmapper = external
 186         rpc_server:spoolss = external
 187         rpc_server:lsarpc = external
 188         rpc_server:samr = external
 189         rpc_server:netlogon = external
 190         rpc_server:register_embedded_np = yes
 191
 192         rpc_daemon:epmd = fork
 193         rpc_daemon:spoolssd = fork
 194         rpc_daemon:lsasd = fork
 195 ";
 196
 197         my $vars = $self->provision($path,
 198                                     "LOCALS3DC2",
 199                                     "locals3dc2pass",
 200                                     $s3dc_options);
 201
 202         $vars or return undef;
 203
 204         $self->check_or_start($vars,
 205                                "yes", "yes", "yes");
 206
 207         if (not $self->wait_for_start($vars)) {
 208                return undef;
 209         }
 210
 211         $vars->{DC_SERVER} = $vars->{SERVER};
 212         $vars->{DC_SERVER_IP} = $vars->{SERVER_IP};
 213         $vars->{DC_NETBIOSNAME} = $vars->{NETBIOSNAME};
 214         $vars->{DC_USERNAME} = $vars->{USERNAME};
 215         $vars->{DC_PASSWORD} = $vars->{PASSWORD};
 216
 217         $self->{vars}->{s3dc} = $vars;
 218
 219         return $vars;
 220 }
 221
 222 sub setup_member($$$)
 223 {
 224         my ($self, $prefix, $s3dcvars) = @_;
 225
 226         print "PROVISIONING MEMBER...";
 227
 228         my $member_options = "
 229         security = domain
 230         server signing = on
 231 ";
 232         my $ret = $self->provision($prefix,
 233                                    "LOCALMEMBER3",
 234                                    "localmember3pass",
 235                                    $member_options);
 236
 237         $ret or return undef;
 238
 239         my $net = Samba::bindir_path($self, "net");
 240         my $cmd = "";
 241         $cmd .= "SOCKET_WRAPPER_DEFAULT_IFACE=\"$ret->{SOCKET_WRAPPER_DEFAULT_IFACE}\" ";
 242         $cmd .= "$net join $ret->{CONFIGURATION} $s3dcvars->{DOMAIN} member";
 243         $cmd .= " -U$s3dcvars->{USERNAME}\%$s3dcvars->{PASSWORD}";
 244
 245         if (system($cmd) != 0) {
 246             warn("Join failed\n$cmd");
 247             return undef;
 248         }
 249
 250         $self->check_or_start($ret, "yes", "yes", "yes");
 251
 252         if (not $self->wait_for_start($ret)) {
 253                return undef;
 254         }
 255
 256         $ret->{DC_SERVER} = $s3dcvars->{SERVER};
 257         $ret->{DC_SERVER_IP} = $s3dcvars->{SERVER_IP};
 258         $ret->{DC_NETBIOSNAME} = $s3dcvars->{NETBIOSNAME};
 259         $ret->{DC_USERNAME} = $s3dcvars->{USERNAME};
 260         $ret->{DC_PASSWORD} = $s3dcvars->{PASSWORD};
 261
 262         return $ret;
 263 }
 264
 265 sub setup_admember($$$$)
 266 {
 267         my ($self, $prefix, $dcvars) = @_;
 268
 269         # If we didn't build with ADS, pretend this env was never available
 270         if (not $self->have_ads()) {
 271                 return "UNKNOWN";
 272         }
 273
 274         print "PROVISIONING S3 AD MEMBER...";
 275
 276         my $member_options = "
 277         security = ads
 278         server signing = on
 279         workgroup = $dcvars->{DOMAIN}
 280         realm = $dcvars->{REALM}
 281 ";
 282
 283         my $ret = $self->provision($prefix,
 284                                    "LOCALADMEMBER",
 285                                    "loCalMemberPass",
 286                                    $member_options);
 287
 288         $ret or return undef;
 289
 290         close(USERMAP);
 291         $ret->{DOMAIN} = $dcvars->{DOMAIN};
 292         $ret->{REALM} = $dcvars->{REALM};
 293
 294         my $ctx;
 295         my $prefix_abs = abs_path($prefix);
 296         $ctx = {};
 297         $ctx->{krb5_conf} = "$prefix_abs/lib/krb5.conf";
 298         $ctx->{domain} = $dcvars->{DOMAIN};
 299         $ctx->{realm} = $dcvars->{REALM};
 300         $ctx->{dnsname} = lc($dcvars->{REALM});
 301         $ctx->{kdc_ipv4} = $dcvars->{SERVER_IP};
 302         Samba::mk_krb5_conf($ctx, "");
 303
 304         $ret->{KRB5_CONFIG} = $ctx->{krb5_conf};
 305
 306         my $net = Samba::bindir_path($self, "net");
 307         my $cmd = "";
 308         $cmd .= "SOCKET_WRAPPER_DEFAULT_IFACE=\"$ret->{SOCKET_WRAPPER_DEFAULT_IFACE}\" ";
 309         $cmd .= "KRB5_CONFIG=\"$ret->{KRB5_CONFIG}\" ";
 310         $cmd .= "$net join $ret->{CONFIGURATION}";
 311         $cmd .= " -U$dcvars->{USERNAME}\%$dcvars->{PASSWORD}";
 312
 313         if (system($cmd) != 0) {
 314             warn("Join failed\n$cmd");
 315             return undef;
 316         }
 317
 318         # We need world access to this share, as otherwise the domain
 319         # administrator from the AD domain provided by Samba4 can't
 320         # access the share for tests.
 321         chmod 0777, "$prefix/share";
 322
 323         $self->check_or_start($ret,
 324                               "yes", "yes", "yes");
 325
 326         $self->wait_for_start($ret);
 327
 328         $ret->{DC_SERVER} = $dcvars->{SERVER};
 329         $ret->{DC_SERVER_IP} = $dcvars->{SERVER_IP};
 330         $ret->{DC_NETBIOSNAME} = $dcvars->{NETBIOSNAME};
 331         $ret->{DC_USERNAME} = $dcvars->{USERNAME};
 332         $ret->{DC_PASSWORD} = $dcvars->{PASSWORD};
 333
 334         # Special case, this is called from Samba4.pm but needs to use the Samba3 check_env and get_log_env
 335         $ret->{target} = $self;
 336
 337         return $ret;
 338 }
 339
 340 sub setup_simpleserver($$)
 341 {
 342         my ($self, $path) = @_;
 343         my $vfs_modulesdir_abs = $ENV{VFSLIBDIR};
 344
 345         print "PROVISIONING server with security=share...";
 346
 347         my $prefix_abs = abs_path($path);
 348
 349         my $simpleserver_options = "
 350         lanman auth = yes
 351         vfs objects = $vfs_modulesdir_abs/xattr_tdb.so $vfs_modulesdir_abs/streams_depot.so
 352
 353 [vfs_aio_fork]
 354         path = $prefix_abs/share
 355         vfs objects = $vfs_modulesdir_abs/aio_fork.so
 356         read only = no
 357         vfs_aio_fork:erratic_testing_mode=yes
 358 ";
 359
 360         my $vars = $self->provision($path,
 361                                     "LOCALSHARE4",
 362                                     "local4pass",
 363                                     $simpleserver_options);
 364
 365         $vars or return undef;
 366
 367         $self->check_or_start($vars, "yes", "no", "yes");
 368
 369         if (not $self->wait_for_start($vars)) {
 370                return undef;
 371         }
 372
 373         $self->{vars}->{simpleserver} = $vars;
 374
 375         return $vars;
 376 }
 377
 378 sub setup_ktest($$$)
 379 {
 380         my ($self, $prefix) = @_;
 381
 382         # If we didn't build with ADS, pretend this env was never available
 383         if (not $self->have_ads()) {
 384                 return "UNKNOWN";
 385         }
 386
 387         print "PROVISIONING server with security=ads...";
 388
 389         my $ktest_options = "
 390         workgroup = KTEST
 391         realm = ktest.samba.example.com
 392         security = ads
 393         username map = $prefix/lib/username.map
 394         server signing = required
 395 ";
 396
 397         my $ret = $self->provision($prefix,
 398                                    "LOCALKTEST6",
 399                                    "localktest6pass",
 400                                    $ktest_options);
 401
 402         $ret or return undef;
 403
 404         my $ctx;
 405         my $prefix_abs = abs_path($prefix);
 406         $ctx = {};
 407         $ctx->{krb5_conf} = "$prefix_abs/lib/krb5.conf";
 408         $ctx->{domain} = "KTEST";
 409         $ctx->{realm} = "KTEST.SAMBA.EXAMPLE.COM";
 410         $ctx->{dnsname} = lc($ctx->{realm});
 411         $ctx->{kdc_ipv4} = "0.0.0.0";
 412         Samba::mk_krb5_conf($ctx, "");
 413
 414         $ret->{KRB5_CONFIG} = $ctx->{krb5_conf};
 415
 416         open(USERMAP, ">$prefix/lib/username.map") or die("Unable to open $prefix/lib/username.map");
 417         print USERMAP "
 418 $ret->{USERNAME} = KTEST\\Administrator
 419 ";
 420         close(USERMAP);
 421
 422 #This is the secrets.tdb created by 'net ads join' from Samba3 to a
 423 #Samba4 DC with the same parameters as are being used here.  The
 424 #domain SID is S-1-5-21-1071277805-689288055-3486227160
 425
 426         system("cp $self->{srcdir}/source3/selftest/ktest-secrets.tdb $prefix/private/secrets.tdb");
 427         chmod 0600, "$prefix/private/secrets.tdb";
 428
 429 #This uses a pre-calculated krb5 credentials cache, obtained by running Samba4 with:
 430 # "--option=kdc:service ticket lifetime=239232" "--option=kdc:user ticket lifetime=239232" "--option=kdc:renewal lifetime=239232"
 431 #
 432 #and having in krb5.conf:
 433 # ticket_lifetime = 799718400
 434 # renew_lifetime = 799718400
 435 #
 436 # The commands for the -2 keytab where were:
 437 # kinit administrator@KTEST.SAMBA.EXAMPLE.COM
 438 # kvno host/localktest6@KTEST.SAMBA.EXAMPLE.COM
 439 # kvno cifs/localktest6@KTEST.SAMBA.EXAMPLE.COM
 440 # kvno host/LOCALKTEST6@KTEST.SAMBA.EXAMPLE.COM
 441 # kvno cifs/LOCALKTEST6@KTEST.SAMBA.EXAMPLE.COM
 442 #
 443 # and then for the -3 keytab, I did
 444 #
 445 # net changetrustpw; kdestroy and the same again.
 446 #
 447 # This creates a credential cache with a very long lifetime (2036 at
 448 # at 2011-04), and shows that running 'net changetrustpw' does not
 449 # break existing logins (for the secrets.tdb method at least).
 450 #
 451
 452         $ret->{KRB5_CCACHE}="FILE:$prefix/krb5_ccache";
 453
 454         system("cp $self->{srcdir}/source3/selftest/ktest-krb5_ccache-2 $prefix/krb5_ccache-2");
 455         chmod 0600, "$prefix/krb5_ccache-2";
 456
 457         system("cp $self->{srcdir}/source3/selftest/ktest-krb5_ccache-3 $prefix/krb5_ccache-3");
 458         chmod 0600, "$prefix/krb5_ccache-3";
 459
 460         # We need world access to this share, as otherwise the domain
 461         # administrator from the AD domain provided by ktest can't
 462         # access the share for tests.
 463         chmod 0777, "$prefix/share";
 464
 465         $self->check_or_start($ret, "yes", "no", "yes");
 466
 467         if (not $self->wait_for_start($ret)) {
 468                return undef;
 469         }
 470         return $ret;
 471 }
 472
 473 sub setup_maptoguest($$)
 474 {
 475         my ($self, $path) = @_;
 476
 477         print "PROVISIONING maptoguest...";
 478
 479         my $options = "
 480 map to guest = bad user
 481 ";
 482
 483         my $vars = $self->provision($path,
 484                                     "maptoguest",
 485                                     "maptoguestpass",
 486                                     $options);
 487
 488         $vars or return undef;
 489
 490         $self->check_or_start($vars,
 491                                "yes", "no", "yes");
 492
 493         if (not $self->wait_for_start($vars)) {
 494                return undef;
 495         }
 496
 497         $self->{vars}->{s3maptoguest} = $vars;
 498
 499         return $vars;
 500 }
 501
 502 sub stop_sig_term($$) {
 503         my ($self, $pid) = @_;
 504         kill("USR1", $pid) or kill("ALRM", $pid) or warn("Unable to kill $pid: $!");
 505 }
 506
 507 sub stop_sig_kill($$) {
 508         my ($self, $pid) = @_;
 509         kill("ALRM", $pid) or warn("Unable to kill $pid: $!");
 510 }
 511
 512 sub write_pid($$$)
 513 {
 514         my ($env_vars, $app, $pid) = @_;
 515
 516         open(PID, ">$env_vars->{PIDDIR}/timelimit.$app.pid");
 517         print PID $pid;
 518         close(PID);
 519 }
 520
 521 sub read_pid($$)
 522 {
 523         my ($env_vars, $app) = @_;
 524
 525         open(PID, "<$env_vars->{PIDDIR}/timelimit.$app.pid");
 526         my $pid = <PID>;
 527         close(PID);
 528         return $pid;
 529 }
 530
 531 sub check_or_start($$$$$) {
 532         my ($self, $env_vars, $nmbd, $winbindd, $smbd) = @_;
 533
 534         # use a pipe for stdin in the child processes. This allows
 535         # those processes to monitor the pipe for EOF to ensure they
 536         # exit when the test script exits
 537         pipe(STDIN_READER, $env_vars->{STDIN_PIPE});
 538
 539         unlink($env_vars->{NMBD_TEST_LOG});
 540         print "STARTING NMBD...";
 541         my $pid = fork();
 542         if ($pid == 0) {
 543                 open STDOUT, ">$env_vars->{NMBD_TEST_LOG}";
 544                 open STDERR, '>&STDOUT';
 545
 546                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 547
 548                 $ENV{KRB5_CONFIG} = $env_vars->{KRB5_CONFIG};
 549                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 550                 $ENV{NMBD_SOCKET_DIR} = $env_vars->{NMBD_SOCKET_DIR};
 551
 552                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 553                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 554                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 555
 556                 $ENV{UID_WRAPPER} = "1";
 557
 558                 if ($nmbd ne "yes") {
 559                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 560                                 my $signame = shift;
 561                                 print("Skip nmbd received signal $signame");
 562                                 exit 0;
 563                         };
 564                         sleep($self->{server_maxtime});
 565                         exit 0;
 566                 }
 567
 568                 my @optargs = ("-d0");
 569                 if (defined($ENV{NMBD_OPTIONS})) {
 570                         @optargs = split(/ /, $ENV{NMBD_OPTIONS});
 571                 }
 572
 573                 $ENV{MAKE_TEST_BINARY} = Samba::bindir_path($self, "nmbd");
 574
 575                 my @preargs = (Samba::bindir_path($self, "timelimit"), $self->{server_maxtime});
 576                 if(defined($ENV{NMBD_VALGRIND})) {
 577                         @preargs = split(/ /, $ENV{NMBD_VALGRIND});
 578                 }
 579
 580                 close($env_vars->{STDIN_PIPE});
 581                 open STDIN, ">&", \*STDIN_READER or die "can't dup STDIN_READER to STDIN: $!";
 582
 583                 exec(@preargs, Samba::bindir_path($self, "nmbd"), "-F", "--no-process-group", "--log-stdout", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start nmbd: $!");
 584         }
 585         $env_vars->{NMBD_TL_PID} = $pid;
 586         write_pid($env_vars, "nmbd", $pid);
 587         print "DONE\n";
 588
 589         unlink($env_vars->{WINBINDD_TEST_LOG});
 590         print "STARTING WINBINDD...";
 591         $pid = fork();
 592         if ($pid == 0) {
 593                 open STDOUT, ">$env_vars->{WINBINDD_TEST_LOG}";
 594                 open STDERR, '>&STDOUT';
 595
 596                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 597
 598                 $ENV{KRB5_CONFIG} = $env_vars->{KRB5_CONFIG};
 599                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 600                 $ENV{NMBD_SOCKET_DIR} = $env_vars->{NMBD_SOCKET_DIR};
 601
 602                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 603                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 604                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 605
 606                 $ENV{UID_WRAPPER} = "1";
 607
 608                 if ($winbindd ne "yes") {
 609                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 610                                 my $signame = shift;
 611                                 print("Skip winbindd received signal $signame");
 612                                 exit 0;
 613                         };
 614                         sleep($self->{server_maxtime});
 615                         exit 0;
 616                 }
 617
 618                 my @optargs = ("-d0");
 619                 if (defined($ENV{WINBINDD_OPTIONS})) {
 620                         @optargs = split(/ /, $ENV{WINBINDD_OPTIONS});
 621                 }
 622
 623                 $ENV{MAKE_TEST_BINARY} = Samba::bindir_path($self, "winbindd");
 624
 625                 my @preargs = (Samba::bindir_path($self, "timelimit"), $self->{server_maxtime});
 626                 if(defined($ENV{WINBINDD_VALGRIND})) {
 627                         @preargs = split(/ /, $ENV{WINBINDD_VALGRIND});
 628                 }
 629
 630                 print "Starting winbindd with config $env_vars->{SERVERCONFFILE}\n";
 631
 632                 close($env_vars->{STDIN_PIPE});
 633                 open STDIN, ">&", \*STDIN_READER or die "can't dup STDIN_READER to STDIN: $!";
 634
 635                 exec(@preargs, Samba::bindir_path($self, "winbindd"), "-F", "--no-process-group", "--stdout", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start winbindd: $!");
 636         }
 637         $env_vars->{WINBINDD_TL_PID} = $pid;
 638         write_pid($env_vars, "winbindd", $pid);
 639         print "DONE\n";
 640
 641         unlink($env_vars->{SMBD_TEST_LOG});
 642         print "STARTING SMBD...";
 643         $pid = fork();
 644         if ($pid == 0) {
 645                 open STDOUT, ">$env_vars->{SMBD_TEST_LOG}";
 646                 open STDERR, '>&STDOUT';
 647
 648                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 649
 650                 $ENV{KRB5_CONFIG} = $env_vars->{KRB5_CONFIG};
 651                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 652                 $ENV{NMBD_SOCKET_DIR} = $env_vars->{NMBD_SOCKET_DIR};
 653
 654                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 655                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 656                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 657
 658                 $ENV{UID_WRAPPER} = "1";
 659
 660                 if ($smbd ne "yes") {
 661                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 662                                 my $signame = shift;
 663                                 print("Skip smbd received signal $signame");
 664                                 exit 0;
 665                         };
 666                         sleep($self->{server_maxtime});
 667                         exit 0;
 668                 }
 669
 670                 $ENV{MAKE_TEST_BINARY} = Samba::bindir_path($self, "smbd");
 671                 my @optargs = ("-d0");
 672                 if (defined($ENV{SMBD_OPTIONS})) {
 673                         @optargs = split(/ /, $ENV{SMBD_OPTIONS});
 674                 }
 675                 my @preargs = (Samba::bindir_path($self, "timelimit"), $self->{server_maxtime});
 676                 if(defined($ENV{SMBD_VALGRIND})) {
 677                         @preargs = split(/ /,$ENV{SMBD_VALGRIND});
 678                 }
 679
 680                 close($env_vars->{STDIN_PIPE});
 681                 open STDIN, ">&", \*STDIN_READER or die "can't dup STDIN_READER to STDIN: $!";
 682
 683                 exec(@preargs, Samba::bindir_path($self, "smbd"), "-F", "--no-process-group", "--log-stdout", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start smbd: $!");
 684         }
 685         $env_vars->{SMBD_TL_PID} = $pid;
 686         write_pid($env_vars, "smbd", $pid);
 687         print "DONE\n";
 688
 689         close(STDIN_READER);
 690
 691         return 0;
 692 }
 693
 694 sub provision($$$$$$)
 695 {
 696         my ($self, $prefix, $server, $password, $extra_options, $no_delete_prefix) = @_;
 697
 698         ##
 699         ## setup the various environment variables we need
 700         ##
 701
 702         my $swiface = Samba::get_interface($server);
 703         my %ret = ();
 704         my $server_ip = "127.0.0.$swiface";
 705         my $domain = "SAMBA-TEST";
 706
 707         my $unix_name = ($ENV{USER} or $ENV{LOGNAME} or `PATH=/usr/ucb:$ENV{PATH} whoami`);
 708         chomp $unix_name;
 709         my $unix_uid = $>;
 710         my $unix_gids_str = $);
 711         my @unix_gids = split(" ", $unix_gids_str);
 712
 713         my $prefix_abs = abs_path($prefix);
 714         my $bindir_abs = abs_path($self->{bindir});
 715         my $vfs_modulesdir_abs = ($ENV{VFSLIBDIR} or $bindir_abs);
 716
 717         my $dns_host_file = "$ENV{SELFTEST_PREFIX}/dns_host_file";
 718
 719         my @dirs = ();
 720
 721         my $shrdir="$prefix_abs/share";
 722         push(@dirs,$shrdir);
 723
 724         my $libdir="$prefix_abs/lib";
 725         push(@dirs,$libdir);
 726
 727         my $piddir="$prefix_abs/pid";
 728         push(@dirs,$piddir);
 729
 730         my $privatedir="$prefix_abs/private";
 731         push(@dirs,$privatedir);
 732
 733         my $lockdir="$prefix_abs/lockdir";
 734         push(@dirs,$lockdir);
 735
 736         my $eventlogdir="$prefix_abs/lockdir/eventlog";
 737         push(@dirs,$eventlogdir);
 738
 739         my $logdir="$prefix_abs/logs";
 740         push(@dirs,$logdir);
 741
 742         my $driver32dir="$shrdir/W32X86";
 743         push(@dirs,$driver32dir);
 744
 745         my $driver64dir="$shrdir/x64";
 746         push(@dirs,$driver64dir);
 747
 748         my $driver40dir="$shrdir/WIN40";
 749         push(@dirs,$driver40dir);
 750
 751         my $ro_shrdir="$shrdir/root-tmp";
 752         push(@dirs,$ro_shrdir);
 753
 754         my $msdfs_shrdir="$shrdir/msdfsshare";
 755         push(@dirs,$msdfs_shrdir);
 756
 757         my $msdfs_deeppath="$msdfs_shrdir/deeppath";
 758         push(@dirs,$msdfs_deeppath);
 759
 760         # this gets autocreated by winbindd
 761         my $wbsockdir="$prefix_abs/winbindd";
 762         my $wbsockprivdir="$lockdir/winbindd_privileged";
 763
 764         my $nmbdsockdir="$prefix_abs/nmbd";
 765         unlink($nmbdsockdir);
 766
 767         ##
 768         ## create the test directory layout
 769         ##
 770         die ("prefix_abs = ''") if $prefix_abs eq "";
 771         die ("prefix_abs = '/'") if $prefix_abs eq "/";
 772
 773         mkdir($prefix_abs, 0777);
 774         print "CREATE TEST ENVIRONMENT IN '$prefix'...";
 775         if (not defined($no_delete_prefix) or not $no_delete_prefix) {
 776             system("rm -rf $prefix_abs/*");
 777         }
 778         mkdir($_, 0777) foreach(@dirs);
 779
 780         ##
 781         ## create ro and msdfs share layout
 782         ##
 783
 784         chmod 0755, $ro_shrdir;
 785         my $unreadable_file = "$ro_shrdir/unreadable_file";
 786         unless (open(UNREADABLE_FILE, ">$unreadable_file")) {
 787                 warn("Unable to open $unreadable_file");
 788                 return undef;
 789         }
 790         close(UNREADABLE_FILE);
 791         chmod 0600, $unreadable_file;
 792
 793         my $msdfs_target = "$ro_shrdir/msdfs-target";
 794         unless (open(MSDFS_TARGET, ">$msdfs_target")) {
 795                 warn("Unable to open $msdfs_target");
 796                 return undef;
 797         }
 798         close(MSDFS_TARGET);
 799         chmod 0666, $msdfs_target;
 800         symlink "msdfs:$server_ip\\ro-tmp", "$msdfs_shrdir/msdfs-src1";
 801         symlink "msdfs:$server_ip\\ro-tmp", "$msdfs_shrdir/deeppath/msdfs-src2";
 802
 803         my $conffile="$libdir/server.conf";
 804
 805         my $nss_wrapper_pl = "$ENV{PERL} $self->{srcdir}/lib/nss_wrapper/nss_wrapper.pl";
 806         my $nss_wrapper_passwd = "$privatedir/passwd";
 807         my $nss_wrapper_group = "$privatedir/group";
 808
 809         my $mod_printer_pl = "$ENV{PERL} $self->{srcdir}/source3/script/tests/printing/modprinter.pl";
 810
 811         my @eventlog_list = ("dns server", "application");
 812
 813         ##
 814         ## calculate uids and gids
 815         ##
 816
 817         my ($max_uid, $max_gid);
 818         my ($uid_nobody, $uid_root, $uid_pdbtest);
 819         my ($gid_nobody, $gid_nogroup, $gid_root, $gid_domusers);
 820
 821         if ($unix_uid < 0xffff - 2) {
 822                 $max_uid = 0xffff;
 823         } else {
 824                 $max_uid = $unix_uid;
 825         }
 826
 827         $uid_root = $max_uid - 1;
 828         $uid_nobody = $max_uid - 2;
 829         $uid_pdbtest = $max_uid - 3;
 830
 831         if ($unix_gids[0] < 0xffff - 3) {
 832                 $max_gid = 0xffff;
 833         } else {
 834                 $max_gid = $unix_gids[0];
 835         }
 836
 837         $gid_nobody = $max_gid - 1;
 838         $gid_nogroup = $max_gid - 2;
 839         $gid_root = $max_gid - 3;
 840         $gid_domusers = $max_gid - 4;
 841
 842         ##
 843         ## create conffile
 844         ##
 845
 846         unless (open(CONF, ">$conffile")) {
 847                 warn("Unable to open $conffile");
 848                 return undef;
 849         }
 850         print CONF "
 851 [global]
 852         netbios name = $server
 853         interfaces = $server_ip/8
 854         bind interfaces only = yes
 855         panic action = $self->{srcdir}/selftest/gdb_backtrace %d %\$(MAKE_TEST_BINARY)
 856         smbd:suicide mode = yes
 857
 858         workgroup = $domain
 859
 860         private dir = $privatedir
 861         pid directory = $piddir
 862         lock directory = $lockdir
 863         log file = $logdir/log.\%m
 864         log level = 1
 865         debug pid = yes
 866         max log size = 0
 867
 868         state directory = $lockdir
 869         cache directory = $lockdir
 870
 871         passdb backend = tdbsam
 872
 873         time server = yes
 874
 875         add user script =               $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action add --name %u --gid $gid_nogroup
 876         add group script =              $nss_wrapper_pl --group_path  $nss_wrapper_group  --type group  --action add --name %g
 877         add machine script =            $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action add --name %u --gid $gid_nogroup
 878         add user to group script =      $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type member --action add --member %u --name %g --group_path $nss_wrapper_group
 879         delete user script =            $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action delete --name %u
 880         delete group script =           $nss_wrapper_pl --group_path  $nss_wrapper_group  --type group  --action delete --name %g
 881         delete user from group script = $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type member --action delete --member %u --name %g --group_path $nss_wrapper_group
 882
 883         addprinter command =            $mod_printer_pl -a -s $conffile --
 884         deleteprinter command =         $mod_printer_pl -d -s $conffile --
 885
 886         eventlog list = application \"dns server\"
 887
 888         kernel oplocks = no
 889         kernel change notify = no
 890
 891         syslog = no
 892         printing = bsd
 893         printcap name = /dev/null
 894
 895         winbindd:socket dir = $wbsockdir
 896         nmbd:socket dir = $nmbdsockdir
 897         idmap config * : range = 100000-200000
 898         winbind enum users = yes
 899         winbind enum groups = yes
 900
 901 #       min receivefile size = 4000
 902
 903         read only = no
 904         server signing = auto
 905
 906         smbd:sharedelay = 100000
 907         smbd:writetimeupdatedelay = 500000
 908         map hidden = no
 909         map system = no
 910         map readonly = no
 911         store dos attributes = yes
 912         create mask = 0777
 913         directory mask = 0777
 914         dos filemode = yes
 915         vfs objects = $vfs_modulesdir_abs/acl_xattr.so $vfs_modulesdir_abs/fake_acls.so $vfs_modulesdir_abs/xattr_tdb.so $vfs_modulesdir_abs/streams_depot.so
 916
 917         printing = vlp
 918         print command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb print %p %s
 919         lpq command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lpq %p
 920         lp rm command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lprm %p %j
 921         lp pause command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lppause %p %j
 922         lp resume command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lpresume %p %j
 923         queue pause command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb queuepause %p
 924         queue resume command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb queueresume %p
 925         lpq cache time = 0
 926
 927         ncalrpc dir = $prefix_abs/ncalrpc
 928         resolv:host file = $dns_host_file
 929
 930         # The samba3.blackbox.smbclient_s3 test uses this to test that
 931         # sending messages works, and that the %m sub works.
 932         message command = mv %s $shrdir/message.%m
 933
 934         # Begin extra options
 935         $extra_options
 936         # End extra options
 937
 938         #Include user defined custom parameters if set
 939 ";
 940
 941         if (defined($ENV{INCLUDE_CUSTOM_CONF})) {
 942                 print CONF "\t$ENV{INCLUDE_CUSTOM_CONF}\n";
 943         }
 944
 945         print CONF "
 946 [tmp]
 947         path = $shrdir
 948         comment = smb username is [%U]
 949 [tmpenc]
 950         path = $shrdir
 951         comment = encrypt smb username is [%U]
 952         smb encrypt = required
 953 [tmpguest]
 954         path = $shrdir
 955         guest ok = yes
 956 [guestonly]
 957         path = $shrdir
 958         guest only = yes
 959         guest ok = yes
 960 [forceuser]
 961         path = $shrdir
 962         force user = $unix_name
 963         guest ok = yes
 964 [forcegroup]
 965         path = $shrdir
 966         force group = nogroup
 967         guest ok = yes
 968 [ro-tmp]
 969         path = $ro_shrdir
 970         guest ok = yes
 971 [msdfs-share]
 972         path = $msdfs_shrdir
 973         msdfs root = yes
 974         guest ok = yes
 975 [hideunread]
 976         copy = tmp
 977         hide unreadable = yes
 978 [tmpcase]
 979         copy = tmp
 980         case sensitive = yes
 981 [hideunwrite]
 982         copy = tmp
 983         hide unwriteable files = yes
 984 [durable]
 985         copy = tmp
 986         kernel share modes = no
 987         kernel oplocks = no
 988         posix locking = no
 989 [print1]
 990         copy = tmp
 991         printable = yes
 992
 993 [print2]
 994         copy = print1
 995 [print3]
 996         copy = print1
 997 [lp]
 998         copy = print1
 999 [xcopy_share]
1000         path = $shrdir
1001         comment = smb username is [%U]
1002         create mask = 777
1003         force create mode = 777
1004 [posix_share]
1005         path = $shrdir
1006         comment = smb username is [%U]
1007         create mask = 0777
1008         force create mode = 0
1009         directory mask = 0777
1010         force directory mode = 0
1011         vfs objects = $vfs_modulesdir_abs/xattr_tdb.so
1012
1013 [print\$]
1014         copy = tmp
1015         ";
1016         close(CONF);
1017
1018         ##
1019         ## create a test account
1020         ##
1021
1022         unless (open(PASSWD, ">$nss_wrapper_passwd")) {
1023            warn("Unable to open $nss_wrapper_passwd");
1024            return undef;
1025         }
1026         print PASSWD "nobody:x:$uid_nobody:$gid_nobody:nobody gecos:$prefix_abs:/bin/false
1027 $unix_name:x:$unix_uid:$unix_gids[0]:$unix_name gecos:$prefix_abs:/bin/false
1028 pdbtest:x:$uid_pdbtest:$gid_nogroup:pdbtest gecos:$prefix_abs:/bin/false
1029 ";
1030         if ($unix_uid != 0) {
1031                 print PASSWD "root:x:$uid_root:$gid_root:root gecos:$prefix_abs:/bin/false";
1032         }
1033         close(PASSWD);
1034
1035         unless (open(GROUP, ">$nss_wrapper_group")) {
1036              warn("Unable to open $nss_wrapper_group");
1037              return undef;
1038         }
1039         print GROUP "nobody:x:$gid_nobody:
1040 nogroup:x:$gid_nogroup:nobody
1041 $unix_name-group:x:$unix_gids[0]:
1042 domusers:X:$gid_domusers:
1043 ";
1044         if ($unix_gids[0] != 0) {
1045                 print GROUP "root:x:$gid_root:";
1046         }
1047
1048         close(GROUP);
1049
1050         foreach my $evlog (@eventlog_list) {
1051                 my $evlogtdb = "$eventlogdir/$evlog.tdb";
1052                 open(EVENTLOG, ">$evlogtdb") or die("Unable to open $evlogtdb");
1053                 close(EVENTLOG);
1054         }
1055
1056         $ENV{NSS_WRAPPER_PASSWD} = $nss_wrapper_passwd;
1057         $ENV{NSS_WRAPPER_GROUP} = $nss_wrapper_group;
1058
1059         my $cmd = Samba::bindir_path($self, "smbpasswd")." -c $conffile -L -s -a $unix_name > /dev/null";
1060         unless (open(PWD, "|$cmd")) {
1061              warn("Unable to set password for test account\n$cmd");
1062              return undef;
1063         }
1064         print PWD "$password\n$password\n";
1065         unless (close(PWD)) {
1066              warn("Unable to set password for test account\n$cmd");
1067              return undef;
1068         }
1069         print "DONE\n";
1070
1071         open(DNS_UPDATE_LIST, ">$prefix/dns_update_list") or die("Unable to open $$prefix/dns_update_list");
1072         print DNS_UPDATE_LIST "A $server. $server_ip";
1073         close(DNS_UPDATE_LIST);
1074
1075         if (system("$ENV{SRCDIR_ABS}/source4/scripting/bin/samba_dnsupdate --all-interfaces --use-file=$dns_host_file -s $conffile --update-list=$prefix/dns_update_list --no-substiutions --no-credentials") != 0) {
1076                 die "Unable to update hostname into $dns_host_file";
1077         }
1078
1079         $ret{SERVER_IP} = $server_ip;
1080         $ret{NMBD_TEST_LOG} = "$prefix/nmbd_test.log";
1081         $ret{NMBD_TEST_LOG_POS} = 0;
1082         $ret{WINBINDD_TEST_LOG} = "$prefix/winbindd_test.log";
1083         $ret{WINBINDD_TEST_LOG_POS} = 0;
1084         $ret{SMBD_TEST_LOG} = "$prefix/smbd_test.log";
1085         $ret{SMBD_TEST_LOG_POS} = 0;
1086         $ret{SERVERCONFFILE} = $conffile;
1087         $ret{CONFIGURATION} ="-s $conffile";
1088         $ret{SERVER} = $server;
1089         $ret{USERNAME} = $unix_name;
1090         $ret{USERID} = $unix_uid;
1091         $ret{DOMAIN} = $domain;
1092         $ret{NETBIOSNAME} = $server;
1093         $ret{PASSWORD} = $password;
1094         $ret{PIDDIR} = $piddir;
1095         $ret{WINBINDD_SOCKET_DIR} = $wbsockdir;
1096         $ret{WINBINDD_PRIV_PIPE_DIR} = $wbsockprivdir;
1097         $ret{NMBD_SOCKET_DIR} = $nmbdsockdir;
1098         $ret{SOCKET_WRAPPER_DEFAULT_IFACE} = $swiface;
1099         $ret{NSS_WRAPPER_PASSWD} = $nss_wrapper_passwd;
1100         $ret{NSS_WRAPPER_GROUP} = $nss_wrapper_group;
1101         $ret{NSS_WRAPPER_WINBIND_SO_PATH} = Samba::nss_wrapper_winbind_so_path($self);
1102         $ret{LOCAL_PATH} = "$shrdir";
1103
1104         return \%ret;
1105 }
1106
1107 sub wait_for_start($$)
1108 {
1109         my ($self, $envvars) = @_;
1110
1111         # give time for nbt server to register its names
1112         print "delaying for nbt name registration\n";
1113         sleep(10);
1114         # This will return quickly when things are up, but be slow if we need to wait for (eg) SSL init
1115         my $nmblookup = Samba::bindir_path($self, "nmblookup3");
1116         system("$nmblookup $envvars->{CONFIGURATION} -U $envvars->{SERVER_IP} __SAMBA__");
1117         system("$nmblookup $envvars->{CONFIGURATION} __SAMBA__");
1118         system("$nmblookup $envvars->{CONFIGURATION} -U 127.255.255.255 __SAMBA__");
1119         system("$nmblookup $envvars->{CONFIGURATION} -U $envvars->{SERVER_IP} $envvars->{SERVER}");
1120         system("$nmblookup $envvars->{CONFIGURATION} $envvars->{SERVER}");
1121
1122         # make sure smbd is also up set
1123         print "wait for smbd\n";
1124
1125         my $count = 0;
1126         my $ret;
1127         do {
1128             $ret = system(Samba::bindir_path($self, "smbclient3") ." $envvars->{CONFIGURATION} -L $envvars->{SERVER} -U% -p 139");
1129             if ($ret != 0) {
1130                 sleep(2);
1131             }
1132             $count++
1133         } while ($ret != 0 && $count < 10);
1134         if ($count == 10) {
1135             print "SMBD failed to start up in a reasonable time (20sec)\n";
1136             teardown_env($self, $envvars);
1137             return 0;
1138         }
1139         # Ensure we have domain users mapped.
1140         $ret = system(Samba::bindir_path($self, "net") ." $envvars->{CONFIGURATION} groupmap add rid=513 unixgroup=domusers type=domain");
1141         if ($ret != 0) {
1142             return 1;
1143         }
1144
1145         print $self->getlog_env($envvars);
1146
1147         return 1;
1148 }
1149
1150 1;