lib/replace/libreplace.m4

   1 AC_DEFUN_ONCE(AC_LIBREPLACE_LOCATION_CHECKS,
   2 [
   3 echo "LIBREPLACE_LOCATION_CHECKS: START"
   4
   5 dnl find the libreplace sources. This is meant to work both for
   6 dnl libreplace standalone builds, and builds of packages using libreplace
   7 libreplacedir=""
   8 libreplacepaths="$srcdir $srcdir/lib/replace $srcdir/libreplace $srcdir/../libreplace $srcdir/../replace $srcdir/../lib/replace $srcdir/../../../lib/replace"
   9 for d in $libreplacepaths; do
  10         if test -f "$d/replace.c"; then
  11                 libreplacedir="$d"
  12                 AC_SUBST(libreplacedir)
  13                 break;
  14         fi
  15 done
  16 if test x"$libreplacedir" = "x"; then
  17         AC_MSG_ERROR([cannot find libreplace in $libreplacepaths])
  18 fi
  19 LIBREPLACEOBJ="$libreplacedir/replace.o"
  20 AC_SUBST(LIBREPLACEOBJ)
  21
  22 AC_CANONICAL_BUILD
  23 AC_CANONICAL_HOST
  24 AC_CANONICAL_TARGET
  25
  26 echo "LIBREPLACE_LOCATION_CHECKS: END"
  27 ]) dnl end AC_LIBREPLACE_LOCATION_CHECKS
  28
  29
  30 AC_DEFUN_ONCE(AC_LIBREPLACE_BROKEN_CHECKS,
  31 [
  32 echo "LIBREPLACE_BROKEN_CHECKS: START"
  33
  34 dnl find the libreplace sources. This is meant to work both for
  35 dnl libreplace standalone builds, and builds of packages using libreplace
  36 libreplacedir=""
  37 libreplacepaths="$srcdir $srcdir/lib/replace $srcdir/libreplace $srcdir/../libreplace $srcdir/../replace $srcdir/../lib/replace $srcdir/../../../lib/replace"
  38 for d in $libreplacepaths; do
  39         if test -f "$d/replace.c"; then
  40                 libreplacedir="$d"
  41                 AC_SUBST(libreplacedir)
  42                 break;
  43         fi
  44 done
  45 if test x"$libreplacedir" = "x"; then
  46         AC_MSG_ERROR([cannot find libreplace in $libreplacepaths])
  47 fi
  48
  49 LIBREPLACEOBJ="$libreplacedir/replace.o"
  50 AC_SUBST(LIBREPLACEOBJ)
  51
  52 LIBREPLACEOBJ="${LIBREPLACEOBJ} $libreplacedir/snprintf.o  $libreplacedir/xattr.o"
  53
  54 AC_TYPE_UID_T
  55 AC_TYPE_MODE_T
  56 AC_TYPE_OFF_T
  57 AC_TYPE_SIZE_T
  58 AC_TYPE_PID_T
  59 AC_STRUCT_ST_RDEV
  60 AC_CHECK_TYPE(ino_t,unsigned)
  61 AC_CHECK_TYPE(loff_t,off_t)
  62 AC_CHECK_TYPE(offset_t,loff_t)
  63 AC_CHECK_TYPE(blksize_t,long)
  64 AC_CHECK_TYPE(blkcnt_t,long)
  65
  66 AC_FUNC_MEMCMP
  67
  68 AC_CHECK_FUNCS([pipe strftime srandom random srand rand usleep setbuffer lstat getpgrp utime utimes])
  69
  70 AC_CHECK_HEADERS(stdbool.h stdint.h sys/select.h)
  71 AC_CHECK_HEADERS(setjmp.h utime.h)
  72
  73 LIBREPLACE_PROVIDE_HEADER([stdint.h])
  74 LIBREPLACE_PROVIDE_HEADER([stdbool.h])
  75
  76 AC_DEFINE(HAVE_LIBREPLACE, 1, [We have libreplace])
  77
  78 AC_CHECK_TYPE(bool,
  79 [AC_DEFINE(HAVE_BOOL, 1, [Whether the bool type is available])],,
  80 [
  81 AC_INCLUDES_DEFAULT
  82 #ifdef HAVE_STDBOOL_H
  83 #include <stdbool.h>
  84 #endif]
  85 )
  86
  87 AC_CHECK_TYPE(_Bool,
  88 [AC_DEFINE(HAVE__Bool, 1, [Whether the _Bool type is available])],,
  89 [
  90 AC_INCLUDES_DEFAULT
  91 #ifdef HAVE_STDBOOL_H
  92 #include <stdbool.h>
  93 #endif]
  94 )
  95
  96 AC_CHECK_HEADERS(linux/types.h)
  97
  98 AC_CACHE_CHECK([for working mmap],libreplace_cv_HAVE_MMAP,[
  99 AC_TRY_RUN([#include "$libreplacedir/test/shared_mmap.c"],
 100            libreplace_cv_HAVE_MMAP=yes,libreplace_cv_HAVE_MMAP=no,libreplace_cv_HAVE_MMAP=cross)])
 101 if test x"$libreplace_cv_HAVE_MMAP" = x"yes"; then
 102     AC_DEFINE(HAVE_MMAP,1,[Whether mmap works])
 103 fi
 104
 105 AC_CACHE_CHECK([for working mremap],libreplace_cv_HAVE_MREMAP,[
 106 AC_TRY_RUN([#include "$libreplacedir/test/shared_mremap.c"],
 107            libreplace_cv_HAVE_MREMAP=yes,libreplace_cv_HAVE_MREMAP=no,libreplace_cv_HAVE_MREMAP=cross)])
 108 if test x"$libreplace_cv_HAVE_MREMAP" = x"yes"; then
 109     AC_DEFINE(HAVE_MREMAP,1,[Whether mremap works])
 110 fi
 111
 112 AC_CACHE_CHECK([for incoherent mmap],libreplace_cv_HAVE_INCOHERENT_MMAP,[
 113 AC_TRY_RUN([#include "$libreplacedir/test/incoherent_mmap.c"],
 114            libreplace_cv_HAVE_INCOHERENT_MMAP=yes,libreplace_cv_HAVE_INCOHERENT_MMAP=no,libreplace_cv_HAVE_INCOHERENT_MMAP=cross)])
 115 if test x"$libreplace_cv_HAVE_INCOHERENT_MMAP" = x"yes"; then
 116     AC_DEFINE(HAVE_INCOHERENT_MMAP,1,[Whether mmap is incoherent against write])
 117 fi
 118
 119
 120 AC_CHECK_HEADERS(sys/syslog.h syslog.h)
 121 AC_CHECK_HEADERS(sys/time.h time.h)
 122 AC_CHECK_HEADERS(stdarg.h vararg.h)
 123 AC_CHECK_HEADERS(sys/mount.h mntent.h)
 124 AC_CHECK_HEADERS(stropts.h)
 125 AC_CHECK_HEADERS(unix.h)
 126 AC_CHECK_HEADERS(malloc.h)
 127
 128 AC_CHECK_FUNCS(seteuid setreuid setresuid setegid setregid setresgid)
 129 AC_CHECK_FUNCS(chroot bzero strerror strerror_r memalign posix_memalign getpagesize)
 130 AC_CHECK_FUNCS(vsyslog setlinebuf mktime ftruncate chsize rename)
 131 AC_CHECK_FUNCS(waitpid wait4 strlcpy strlcat initgroups memmove strdup)
 132 AC_CHECK_FUNCS(pread pwrite strndup strcasestr strtok_r mkdtemp dup2 dprintf vdprintf)
 133 AC_CHECK_FUNCS(isatty chown lchown link readlink symlink realpath)
 134 AC_CHECK_FUNCS(fdatasync,,[
 135         # if we didn't find it, look in librt (Solaris hides it there...)
 136         AC_CHECK_LIB(rt, fdatasync,
 137                 [libreplace_cv_HAVE_FDATASYNC_IN_LIBRT=yes
 138                 AC_DEFINE(HAVE_FDATASYNC, 1, Define to 1 if there is support for fdatasync)])
 139 ])
 140 AC_HAVE_DECL(fdatasync, [#include <unistd.h>])
 141 AC_CHECK_FUNCS(clock_gettime,libreplace_cv_have_clock_gettime=yes,[
 142         AC_CHECK_LIB(rt, clock_gettime,
 143                 [libreplace_cv_HAVE_CLOCK_GETTIME_IN_LIBRT=yes
 144                 libreplace_cv_have_clock_gettime=yes
 145                 AC_DEFINE(HAVE_CLOCK_GETTIME, 1, Define to 1 if there is support for clock_gettime)])
 146 ])
 147
 148 AC_CHECK_HEADERS(sys/attributes.h attr/xattr.h sys/xattr.h sys/extattr.h sys/uio.h)
 149 AC_CHECK_HEADERS(sys/ea.h sys/proplist.h)
 150
 151 LIBREPLACE_FILESYS_LIBS=""
 152
 153 ############################################
 154 # Check for EA implementations
 155 case "$host_os" in
 156   *freebsd4* | *dragonfly* )
 157         AC_DEFINE(BROKEN_EXTATTR, 1, [Does extattr API work])
 158   ;;
 159   *)
 160         AC_SEARCH_LIBS(getxattr, [attr])
 161         AC_CHECK_FUNCS(attr_get attr_getf attr_list attr_listf attropen attr_remove)
 162         AC_CHECK_FUNCS(attr_removef attr_set attr_setf extattr_delete_fd extattr_delete_file)
 163         AC_CHECK_FUNCS(extattr_get_fd extattr_get_file extattr_list_fd extattr_list_file)
 164         AC_CHECK_FUNCS(extattr_set_fd extattr_set_file fgetea fgetxattr flistea flistxattr)
 165         AC_CHECK_FUNCS(fremoveea fremovexattr fsetea fsetxattr getea getxattr listea)
 166         AC_CHECK_FUNCS(listxattr removeea removexattr setea setxattr)
 167
 168         AC_CHECK_LIB_EXT(attr, LIBREPLACE_FILESYS_LIBS, flistea)
 169         AC_CHECK_LIB_EXT(attr, LIBREPLACE_FILESYS_LIBS, flistxattr)
 170         AC_CHECK_LIB_EXT(attr, LIBREPLACE_FILESYS_LIBS, attr_listf)
 171         AC_CHECK_LIB_EXT(attr, LIBREPLACE_FILESYS_LIBS, extattr_list_fd)
 172
 173   ;;
 174 esac
 175
 176
 177 ########################################################
 178 # Do xattr functions take additional options like on Darwin?
 179 if test x"$ac_cv_func_getxattr" = x"yes" ; then
 180         AC_CACHE_CHECK([whether xattr interface takes additional options], smb_attr_cv_xattr_add_opt, [
 181                 old_LIBS=$LIBS
 182                 LIBS="$LIBS $LIBREPLACE_FILESYS_LIBS"
 183                 AC_TRY_COMPILE([
 184                         #include <sys/types.h>
 185                         #if HAVE_ATTR_XATTR_H
 186                         #include <attr/xattr.h>
 187                         #elif HAVE_SYS_XATTR_H
 188                         #include <sys/xattr.h>
 189                         #endif
 190                 ],[
 191                         getxattr(0, 0, 0, 0, 0, 0);
 192                 ],
 193                 [smb_attr_cv_xattr_add_opt=yes],
 194                 [smb_attr_cv_xattr_add_opt=no;LIBS=$old_LIBS])
 195         ])
 196         if test x"$smb_attr_cv_xattr_add_opt" = x"yes"; then
 197                 AC_DEFINE(XATTR_ADDITIONAL_OPTIONS, 1, [xattr functions have additional options])
 198         fi
 199 fi
 200
 201 AC_CHECK_FUNCS(get_current_dir_name)
 202 AC_HAVE_DECL(setresuid, [#include <unistd.h>])
 203 AC_HAVE_DECL(setresgid, [#include <unistd.h>])
 204 AC_HAVE_DECL(errno, [#include <errno.h>])
 205
 206 AC_CACHE_CHECK([for secure mkstemp],libreplace_cv_HAVE_SECURE_MKSTEMP,[
 207 AC_TRY_RUN([#include <stdlib.h>
 208 #include <sys/types.h>
 209 #include <sys/stat.h>
 210 #include <unistd.h>
 211 main() {
 212   struct stat st;
 213   char tpl[20]="/tmp/test.XXXXXX";
 214   int fd = mkstemp(tpl);
 215   if (fd == -1) exit(1);
 216   unlink(tpl);
 217   if (fstat(fd, &st) != 0) exit(1);
 218   if ((st.st_mode & 0777) != 0600) exit(1);
 219   exit(0);
 220 }],
 221 libreplace_cv_HAVE_SECURE_MKSTEMP=yes,
 222 libreplace_cv_HAVE_SECURE_MKSTEMP=no,
 223 libreplace_cv_HAVE_SECURE_MKSTEMP=cross)])
 224 if test x"$libreplace_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 225     AC_DEFINE(HAVE_SECURE_MKSTEMP,1,[Whether mkstemp is secure])
 226 fi
 227
 228 dnl Provided by snprintf.c:
 229 AC_CHECK_HEADERS(stdio.h strings.h)
 230 AC_CHECK_DECLS([snprintf, vsnprintf, asprintf, vasprintf])
 231 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 232
 233 AC_CACHE_CHECK([for C99 vsnprintf],libreplace_cv_HAVE_C99_VSNPRINTF,[
 234 AC_TRY_RUN([
 235 #include <sys/types.h>
 236 #include <stdio.h>
 237 #include <stdarg.h>
 238 #include <stdlib.h>
 239 void foo(const char *format, ...) {
 240        va_list ap;
 241        int len;
 242        char buf[20];
 243        long long l = 1234567890;
 244        l *= 100;
 245
 246        va_start(ap, format);
 247        len = vsnprintf(buf, 0, format, ap);
 248        va_end(ap);
 249        if (len != 5) exit(1);
 250
 251        va_start(ap, format);
 252        len = vsnprintf(0, 0, format, ap);
 253        va_end(ap);
 254        if (len != 5) exit(2);
 255
 256        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(3);
 257
 258        if (snprintf(buf, 20, "%lld", l) != 12 || strcmp(buf, "123456789000") != 0) exit(4);
 259        if (snprintf(buf, 20, "%zu", 123456789) != 9 || strcmp(buf, "123456789") != 0) exit(5);
 260        if (snprintf(buf, 20, "%2\$d %1\$d", 3, 4) != 3 || strcmp(buf, "4 3") != 0) exit(6);
 261        if (snprintf(buf, 20, "%s", 0) < 3) exit(7);
 262
 263        exit(0);
 264 }
 265 main() { foo("hello"); }
 266 ],
 267 libreplace_cv_HAVE_C99_VSNPRINTF=yes,libreplace_cv_HAVE_C99_VSNPRINTF=no,libreplace_cv_HAVE_C99_VSNPRINTF=cross)])
 268 if test x"$libreplace_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 269     AC_DEFINE(HAVE_C99_VSNPRINTF,1,[Whether there is a C99 compliant vsnprintf])
 270 fi
 271
 272
 273 dnl VA_COPY
 274 AC_CACHE_CHECK([for va_copy],libreplace_cv_HAVE_VA_COPY,[
 275 AC_TRY_LINK([#include <stdarg.h>
 276 va_list ap1,ap2;], [va_copy(ap1,ap2);],
 277 libreplace_cv_HAVE_VA_COPY=yes,libreplace_cv_HAVE_VA_COPY=no)])
 278 if test x"$libreplace_cv_HAVE_VA_COPY" = x"yes"; then
 279     AC_DEFINE(HAVE_VA_COPY,1,[Whether va_copy() is available])
 280 fi
 281
 282 if test x"$libreplace_cv_HAVE_VA_COPY" != x"yes"; then
 283 AC_CACHE_CHECK([for __va_copy],libreplace_cv_HAVE___VA_COPY,[
 284 AC_TRY_LINK([#include <stdarg.h>
 285 va_list ap1,ap2;], [__va_copy(ap1,ap2);],
 286 libreplace_cv_HAVE___VA_COPY=yes,libreplace_cv_HAVE___VA_COPY=no)])
 287 if test x"$libreplace_cv_HAVE___VA_COPY" = x"yes"; then
 288     AC_DEFINE(HAVE___VA_COPY,1,[Whether __va_copy() is available])
 289 fi
 290 fi
 291
 292 dnl __FUNCTION__ macro
 293 AC_CACHE_CHECK([for __FUNCTION__ macro],libreplace_cv_HAVE_FUNCTION_MACRO,[
 294 AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __FUNCTION__);],
 295 libreplace_cv_HAVE_FUNCTION_MACRO=yes,libreplace_cv_HAVE_FUNCTION_MACRO=no)])
 296 if test x"$libreplace_cv_HAVE_FUNCTION_MACRO" = x"yes"; then
 297     AC_DEFINE(HAVE_FUNCTION_MACRO,1,[Whether there is a __FUNCTION__ macro])
 298 else
 299     dnl __func__ macro
 300     AC_CACHE_CHECK([for __func__ macro],libreplace_cv_HAVE_func_MACRO,[
 301     AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __func__);],
 302     libreplace_cv_HAVE_func_MACRO=yes,libreplace_cv_HAVE_func_MACRO=no)])
 303     if test x"$libreplace_cv_HAVE_func_MACRO" = x"yes"; then
 304        AC_DEFINE(HAVE_func_MACRO,1,[Whether there is a __func__ macro])
 305     fi
 306 fi
 307
 308 AC_CHECK_HEADERS([sys/param.h limits.h])
 309
 310 AC_CHECK_TYPE(comparison_fn_t,
 311 [AC_DEFINE(HAVE_COMPARISON_FN_T, 1,[Whether or not we have comparison_fn_t])])
 312
 313 AC_HAVE_DECL(setenv, [#include <stdlib.h>])
 314 AC_CHECK_FUNCS(setenv unsetenv)
 315 AC_HAVE_DECL(environ, [#include <unistd.h>])
 316
 317 AC_CHECK_FUNCS(strnlen)
 318 AC_CHECK_FUNCS(strtoull __strtoull strtouq strtoll __strtoll strtoq)
 319
 320 AC_CHECK_FUNCS(memmem)
 321
 322 # this test disabled as we don't actually need __VA_ARGS__ yet
 323 AC_TRY_CPP([
 324 #define eprintf(...) fprintf(stderr, __VA_ARGS__)
 325 eprintf("bla", "bar");
 326 ], AC_DEFINE(HAVE__VA_ARGS__MACRO, 1, [Whether the __VA_ARGS__ macro is available]))
 327
 328
 329 AC_CACHE_CHECK([for sig_atomic_t type],libreplace_cv_sig_atomic_t, [
 330     AC_TRY_COMPILE([
 331 #include <sys/types.h>
 332 #if STDC_HEADERS
 333 #include <stdlib.h>
 334 #include <stddef.h>
 335 #endif
 336 #include <signal.h>],[sig_atomic_t i = 0],
 337         libreplace_cv_sig_atomic_t=yes,libreplace_cv_sig_atomic_t=no)])
 338 if test x"$libreplace_cv_sig_atomic_t" = x"yes"; then
 339    AC_DEFINE(HAVE_SIG_ATOMIC_T_TYPE,1,[Whether we have the atomic_t variable type])
 340 fi
 341
 342
 343 AC_CACHE_CHECK([for O_DIRECT flag to open(2)],libreplace_cv_HAVE_OPEN_O_DIRECT,[
 344 AC_TRY_COMPILE([
 345 #include <unistd.h>
 346 #ifdef HAVE_FCNTL_H
 347 #include <fcntl.h>
 348 #endif],
 349 [int fd = open("/dev/null", O_DIRECT);],
 350 libreplace_cv_HAVE_OPEN_O_DIRECT=yes,libreplace_cv_HAVE_OPEN_O_DIRECT=no)])
 351 if test x"$libreplace_cv_HAVE_OPEN_O_DIRECT" = x"yes"; then
 352     AC_DEFINE(HAVE_OPEN_O_DIRECT,1,[Whether the open(2) accepts O_DIRECT])
 353 fi
 354
 355
 356 dnl Check if the C compiler understands volatile (it should, being ANSI).
 357 AC_CACHE_CHECK([that the C compiler understands volatile],libreplace_cv_volatile, [
 358         AC_TRY_COMPILE([#include <sys/types.h>],[volatile int i = 0],
 359                 libreplace_cv_volatile=yes,libreplace_cv_volatile=no)])
 360 if test x"$libreplace_cv_volatile" = x"yes"; then
 361         AC_DEFINE(HAVE_VOLATILE, 1, [Whether the C compiler understands volatile])
 362 fi
 363
 364 m4_include(system/config.m4)
 365
 366 m4_include(dlfcn.m4)
 367 m4_include(getpass.m4)
 368 m4_include(strptime.m4)
 369 m4_include(win32.m4)
 370 m4_include(timegm.m4)
 371 m4_include(repdir.m4)
 372 m4_include(crypt.m4)
 373
 374 if test x$libreplace_cv_have_clock_gettime = xyes ; then
 375         SMB_CHECK_CLOCK_ID(CLOCK_MONOTONIC)
 376         SMB_CHECK_CLOCK_ID(CLOCK_PROCESS_CPUTIME_ID)
 377         SMB_CHECK_CLOCK_ID(CLOCK_REALTIME)
 378 fi
 379
 380 AC_CACHE_CHECK([for struct timespec type],libreplace_cv_struct_timespec, [
 381     AC_TRY_COMPILE([
 382 #include <sys/types.h>
 383 #if STDC_HEADERS
 384 #include <stdlib.h>
 385 #include <stddef.h>
 386 #endif
 387 #if TIME_WITH_SYS_TIME
 388 # include <sys/time.h>
 389 # include <time.h>
 390 #else
 391 # if HAVE_SYS_TIME_H
 392 #  include <sys/time.h>
 393 # else
 394 #  include <time.h>
 395 # endif
 396 #endif
 397 ],[struct timespec ts;],
 398         libreplace_cv_struct_timespec=yes,libreplace_cv_struct_timespec=no)])
 399 if test x"$libreplace_cv_struct_timespec" = x"yes"; then
 400    AC_DEFINE(HAVE_STRUCT_TIMESPEC,1,[Whether we have struct timespec])
 401 fi
 402
 403 AC_CHECK_FUNCS([printf memset memcpy],,[AC_MSG_ERROR([Required function not found])])
 404
 405 echo "LIBREPLACE_BROKEN_CHECKS: END"
 406 ]) dnl end AC_LIBREPLACE_BROKEN_CHECKS
 407
 408 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_START,
 409 [
 410 #LIBREPLACE_ALL_CHECKS: START"
 411 ])
 412 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_END,
 413 [
 414 #LIBREPLACE_ALL_CHECKS: END"
 415 ])
 416 m4_define(AC_LIBREPLACE_ALL_CHECKS,
 417 [
 418 AC__LIBREPLACE_ALL_CHECKS_START
 419 AC_LIBREPLACE_LOCATION_CHECKS
 420 AC_LIBREPLACE_CC_CHECKS
 421 AC_LIBREPLACE_BROKEN_CHECKS
 422 AC__LIBREPLACE_ALL_CHECKS_END
 423 CFLAGS="$CFLAGS -I$libreplacedir"
 424 ])
 425
 426 m4_include(libreplace_cc.m4)
 427 m4_include(libreplace_ld.m4)
 428 m4_include(libreplace_network.m4)
 429 m4_include(libreplace_macros.m4)
 430
 431
 432 dnl SMB_CHECK_CLOCK_ID(clockid)
 433 dnl Test whether the specified clock_gettime clock ID is available. If it
 434 dnl is, we define HAVE_clockid
 435 AC_DEFUN([SMB_CHECK_CLOCK_ID],
 436 [
 437     AC_MSG_CHECKING(for $1)
 438     AC_TRY_LINK([
 439 #if TIME_WITH_SYS_TIME
 440 # include <sys/time.h>
 441 # include <time.h>
 442 #else
 443 # if HAVE_SYS_TIME_H
 444 #  include <sys/time.h>
 445 # else
 446 #  include <time.h>
 447 # endif
 448 #endif
 449     ],
 450     [
 451 clockid_t clk = $1;
 452     ],
 453     [
 454         AC_MSG_RESULT(yes)
 455         AC_DEFINE(HAVE_$1, 1,
 456             [Whether the clock_gettime clock ID $1 is available])
 457     ],
 458     [
 459         AC_MSG_RESULT(no)
 460     ])
 461 ])
 462 m4_ifndef([AC_USE_SYSTEM_EXTENSIONS],[m4_include(autoconf-2.60.m4)])