docs/docbook/xslt/expand-sambadoc.xsl

   1 <?xml version='1.0'?>
   2 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   3                 xmlns:exsl="http://exslt.org/common"
   4                 xmlns:samba="http://samba.org/common"
   5                                 version="1.1"
   6                 extension-element-prefixes="exsl">
   7
   8 <xsl:output method="xml"/>
   9
  10 <xsl:param name="xmlSambaNsUri" select="'http://samba.org/common'"/>
  11
  12 <xsl:template match="reference/refentry/refsect1">
  13         <xsl:if test="title!='VERSION' and title!='AUTHOR'">
  14                 <xsl:element name="refsect1">
  15                         <xsl:if test="@id!=''">
  16                                 <xsl:attribute name="id">
  17                                         <xsl:value-of select="@id"/>
  18                                 </xsl:attribute>
  19                         </xsl:if>
  20                         <xsl:apply-templates/>
  21                 </xsl:element>
  22         </xsl:if>
  23 </xsl:template>
  24
  25 <xsl:template match="reference/refentry">
  26     <xsl:element name="section">
  27         <xsl:attribute name="id">
  28             <xsl:value-of select="@id"/>
  29         </xsl:attribute>
  30         <xsl:element name="title">
  31             <xsl:value-of select="refmeta/refentrytitle"/>
  32 <!--                    <xsl:text> (</xsl:text>
  33                         <xsl:value-of select="refnamediv/refpurpose"/>
  34                         <xsl:text>)</xsl:text>-->
  35         </xsl:element>
  36         <xsl:apply-templates/>
  37     </xsl:element>
  38 </xsl:template>
  39
  40 <xsl:template match="reference/refentry/refmeta"/>
  41
  42 <xsl:template match="reference/refentry/refnamediv"/>
  43
  44 <xsl:template match="reference">
  45         <xsl:element name="appendix">
  46                 <xsl:attribute name="id">
  47                         <xsl:value-of select="@id"/>
  48                 </xsl:attribute>
  49                 <xsl:apply-templates/>
  50         </xsl:element>
  51 </xsl:template>
  52
  53 <xsl:template match="/node()">
  54         <xsl:text disable-output-escaping="yes">
  55 &lt;!DOCTYPE </xsl:text><xsl:value-of select="name(.)"/><xsl:text disable-output-escaping="yes"> PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
  56                 "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd" [
  57
  58         &lt;!ENTITY % globalentities SYSTEM 'global.ent'> %globalentities;
  59  ]>
  60 </xsl:text>
  61 <xsl:copy>
  62     <xsl:attribute name="id"><xsl:value-of select="@id"/></xsl:attribute>
  63     <xsl:apply-templates/>
  64 </xsl:copy>
  65 </xsl:template>
  66
  67
  68 <!-- This is needed to copy content unchanged -->
  69 <xsl:template match="@*|node()">
  70
  71   <xsl:copy>
  72     <xsl:apply-templates select="@*|node()"/>
  73   </xsl:copy>
  74 </xsl:template>
  75
  76 <xsl:template match="smbconfexample/smbconfoption|smbconfblock/smbconfoption">
  77         <xsl:element name="member">
  78                 <xsl:element name="parameter">
  79                         <xsl:value-of select="name"/>
  80                 <xsl:choose>
  81                         <xsl:when test="value != ''">
  82                                 <xsl:text> = </xsl:text>
  83                                 <xsl:value-of select="value"/>
  84                         </xsl:when>
  85                   </xsl:choose>
  86                 </xsl:element>
  87         </xsl:element>
  88 </xsl:template>
  89
  90 <xsl:template match="smbconfexample/smbconfcomment">
  91         <xsl:element name="member">
  92                 <xsl:text># </xsl:text>
  93                 <xsl:apply-templates/>
  94         </xsl:element>
  95 </xsl:template>
  96
  97 <xsl:template match="smbconfexample/smbconfsection">
  98         <xsl:element name="member">
  99                 <xsl:text> </xsl:text>
 100         </xsl:element>
 101         <xsl:element name="member">
 102                 <xsl:element name="parameter">
 103                         <xsl:apply-templates/>
 104                 </xsl:element>
 105         </xsl:element>
 106 </xsl:template>
 107
 108 <xsl:template match="smbconfoption">
 109   <!-- Include an index term -->
 110   <xsl:element name="indexterm">
 111         <xsl:element name="primary">
 112                 <xsl:value-of select="name"/>
 113         </xsl:element>
 114   </xsl:element>
 115
 116 <!-- FIXME: Do this only when smb.conf is included
 117   <xsl:element name="link">
 118           <xsl:attribute name="linkend">
 119                 <xsl:value-of select="translate(translate(string(name),' ',''),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
 120           </xsl:attribute>-->
 121
 122           <xsl:element name="parameter">
 123             <xsl:attribute name="moreinfo">
 124                    <xsl:text>none</xsl:text>
 125                 </xsl:attribute>
 126                 <xsl:value-of select="name"/>
 127           </xsl:element>
 128
 129           <xsl:choose>
 130                 <xsl:when test="value != ''">
 131                         <xsl:text> = </xsl:text>
 132                         <xsl:value-of select="value"/>
 133                 </xsl:when>
 134           </xsl:choose>
 135           <!--
 136   </xsl:element>-->
 137 </xsl:template>
 138
 139 <!-- FIXME: Needs extension sometime -->
 140 <xsl:template match="ntgroup|ntuser">
 141         <xsl:element name="emphasis">
 142                 <xsl:apply-templates/>
 143         </xsl:element>
 144 </xsl:template>
 145
 146 <xsl:template match="smbconfexample">
 147         <xsl:choose>
 148                 <xsl:when test="title = ''">
 149                         <xsl:message>
 150                         <xsl:text>Warning: smbconfexample does not have title!</xsl:text>
 151                         </xsl:message>
 152                 </xsl:when>
 153         </xsl:choose>
 154         <xsl:element name="example">
 155                 <xsl:choose>
 156                         <xsl:when test="@id != ''">
 157                                 <xsl:attribute name="id">
 158                                         <xsl:value-of select="@id"/>
 159                                 </xsl:attribute>
 160                         </xsl:when>
 161                 </xsl:choose>
 162
 163                 <xsl:element name="title">
 164                         <xsl:value-of select="title"/>
 165                 </xsl:element>
 166                 <xsl:element name="simplelist">
 167                         <xsl:apply-templates/>
 168                 </xsl:element>
 169         </xsl:element>
 170 </xsl:template>
 171
 172 <xsl:template match="smbconfblock">
 173         <xsl:element name="simplelist">
 174                 <xsl:apply-templates/>
 175         </xsl:element>
 176 </xsl:template>
 177
 178 <xsl:template match="smbconfsection">
 179         <xsl:element name="parameter">
 180                 <xsl:apply-templates/>
 181         </xsl:element>
 182 </xsl:template>
 183
 184 <xsl:template match="smbconfcomment">
 185         <xsl:text># </xsl:text>
 186         <xsl:apply-templates/>
 187 </xsl:template>
 188
 189 <xsl:template match="image">
 190         <xsl:element name="figure">
 191                 <xsl:attribute name="id"><xsl:value-of select="imagefile"/></xsl:attribute>
 192                 <xsl:element name="title">
 193                         <xsl:value-of select="imagedescription"/>
 194                 </xsl:element>
 195                 <xsl:element name="mediaobject">
 196                         <xsl:element name="imageobject">
 197                                 <xsl:attribute name="role"><xsl:text>latex</xsl:text></xsl:attribute>
 198                                 <xsl:element name="imagedata">
 199                                         <xsl:attribute name="fileref">
 200                                                 <xsl:text>projdoc/imagefiles/</xsl:text><xsl:value-of select="imagefile"/></xsl:attribute>
 201                                         <xsl:attribute name="scale">
 202                                                 <xsl:choose>
 203                                                     <xsl:when test="@scale != ''">
 204                                                                 <xsl:value-of select="@scale"/>
 205                                                         </xsl:when>
 206
 207                                                         <xsl:otherwise>
 208                                                                 <xsl:text>50</xsl:text>
 209                                                         </xsl:otherwise>
 210                                                 </xsl:choose>
 211                                         </xsl:attribute>
 212                                         <xsl:attribute name="scalefit"><xsl:text>1</xsl:text></xsl:attribute>
 213                                 </xsl:element>
 214                         </xsl:element>
 215                         <xsl:element name="imageobject">
 216                                 <xsl:element name="imagedata">
 217                                         <xsl:attribute name="fileref">
 218                                                 <xsl:text>projdoc/imagefiles/</xsl:text><xsl:value-of select="imagefile"/><xsl:text>.png</xsl:text></xsl:attribute>
 219                                         <xsl:attribute name="scale"><xsl:text>50</xsl:text></xsl:attribute>
 220                                         <xsl:attribute name="scalefit"><xsl:text>1</xsl:text></xsl:attribute>
 221                                 </xsl:element>
 222                         </xsl:element>
 223                 </xsl:element>
 224         </xsl:element>
 225 </xsl:template>
 226
 227 <xsl:template match="//samba:parameter">
 228   <!-- reconstruct varlistentry - not all of them will go into separate files
 229        and also we must repair the main varlistentry itself.
 230   -->
 231   <xsl:variable name="name"><xsl:value-of select="translate(translate(string(@name),' ',''),
 232                   'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
 233   </xsl:variable>
 234
 235   <xsl:variable name="anchor">
 236      <xsl:element name="anchor">
 237         <xsl:attribute name="id">
 238           <xsl:value-of select="$name"/>
 239         </xsl:attribute>
 240      </xsl:element>
 241   </xsl:variable>
 242
 243   <xsl:variable name="context">
 244      <xsl:text> (</xsl:text>
 245      <xsl:value-of select="@context"/>
 246      <xsl:text>)</xsl:text>
 247   </xsl:variable>
 248
 249   <xsl:variable name="term">
 250      <xsl:element name="term">
 251           <xsl:copy-of select="$anchor"/>
 252           <xsl:value-of select="@name"/>
 253           <xsl:value-of select="$context"/>
 254      </xsl:element>
 255   </xsl:variable>
 256
 257   <xsl:variable name="content">
 258        <xsl:apply-templates/>
 259   </xsl:variable>
 260
 261   <xsl:element name="varlistentry">
 262      <xsl:text>&#10;</xsl:text>
 263      <xsl:element name="indexterm">
 264         <xsl:attribute name="significance">
 265                 <xsl:text>preferred</xsl:text>
 266         </xsl:attribute>
 267         <xsl:element name="primary">
 268         <xsl:value-of select="@name"/>
 269         </xsl:element>
 270      </xsl:element>
 271      <xsl:copy-of select="$term"/>
 272      <xsl:copy-of select="$content"/>
 273      <xsl:text>
 274 </xsl:text>
 275   </xsl:element>
 276
 277 </xsl:template>
 278
 279 <xsl:template match="ulink">
 280         <xsl:element name="ulink">
 281                 <xsl:attribute name="url">
 282                         <xsl:value-of select="@url"/>
 283                 </xsl:attribute>
 284
 285                 <xsl:apply-templates/>
 286
 287         </xsl:element>
 288 </xsl:template>
 289
 290
 291 </xsl:stylesheet>