source4/configure.ac

   1 dnl -*- mode: m4-mode -*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.54)
   5
   6 AC_INIT([samba],[4],[samba-technical@samba.org])
   7
   8 AC_CONFIG_SRCDIR([include/includes.h])
   9 AC_CONFIG_HEADER(include/config_tmp.h)
  10 AC_DEFINE(CONFIG_H_IS_FROM_SAMBA,1,[Marker for samba's config.h])
  11
  12 # Configuration rules.
  13 m4_include(build/m4/env.m4)
  14 m4_include(../lib/replace/samba.m4)
  15 m4_include(lib/smbreadline/readline.m4)
  16 m4_include(heimdal_build/config.m4)
  17 m4_include(../lib/util/fault.m4)
  18 m4_include(../lib/util/signal.m4)
  19 m4_include(../lib/util/util.m4)
  20 m4_include(../lib/util/fsusage.m4)
  21 m4_include(../lib/util/xattr.m4)
  22 m4_include(../lib/util/capability.m4)
  23 m4_include(../lib/util/time.m4)
  24 m4_include(../lib/popt/samba.m4)
  25 m4_include(../lib/util/charset/config.m4)
  26 m4_include(lib/socket/config.m4)
  27 m4_include(../lib/zlib/zlib.m4)
  28 AC_ZLIB([
  29 SMB_EXT_LIB(ZLIB, [${ZLIB_LIBS}])
  30 ],[
  31 SMB_INCLUDE_MK(lib/zlib.mk)
  32 ])
  33 m4_include(nsswitch/nsstest.m4)
  34 m4_include(../pidl/config.m4)
  35
  36 AC_CONFIG_FILES(lib/registry/registry.pc)
  37 AC_CONFIG_FILES(lib/events/events.pc)
  38 AC_CONFIG_FILES(librpc/dcerpc.pc)
  39 AC_CONFIG_FILES(../librpc/ndr.pc)
  40 AC_CONFIG_FILES(../lib/torture/torture.pc)
  41 AC_CONFIG_FILES(auth/gensec/gensec.pc)
  42 AC_CONFIG_FILES(param/samba-hostconfig.pc)
  43 AC_CONFIG_FILES(librpc/dcerpc_samr.pc)
  44 AC_CONFIG_FILES(librpc/dcerpc_atsvc.pc)
  45
  46 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTALLOC, talloc >= 1.2.0,
  47         [],
  48         [
  49                 m4_include(../lib/talloc/libtalloc.m4)
  50                 SMB_INCLUDE_MK(../lib/talloc/config.mk)
  51         ]
  52 )
  53
  54 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTDB, tdb >= 1.1.3,
  55         [],
  56         [
  57                 m4_include(../lib/tdb/libtdb.m4)
  58                 SMB_INCLUDE_MK(../lib/tdb/config.mk)
  59         ]
  60 )
  61
  62 SMB_INCLUDE_MK(../lib/tdb/python.mk)
  63
  64 SMB_EXT_LIB_FROM_PKGCONFIG(LIBLDB, ldb >= 0.9.1,
  65         [
  66                 SMB_INCLUDE_MK(lib/ldb/ldb_ildap/config.mk)
  67                 SMB_INCLUDE_MK(lib/ldb/tools/config.mk)
  68                 define_ldb_modulesdir=no
  69         ],
  70         [
  71                 # Here we need to do some tricks
  72                 # with AC_CONFIG_COMMANDS_PRE
  73                 # as that's the deferrs the commands
  74                 # to location after $prefix and $exec_prefix
  75                 # have usefull values and directly before
  76                 # creating config.status.
  77                 #
  78                 # The 'eval eval echo' trick is used to
  79                 # actually get the raw absolute directory
  80                 # path as this is needed in config.h
  81                 define_ldb_modulesdir=yes
  82                 AC_CONFIG_COMMANDS_PRE([
  83                 if test x"$define_ldb_modulesdir" = x"yes";then
  84                         LDB_MODULESDIR=`eval eval echo ${modulesdir}/ldb`
  85                         AC_DEFINE_UNQUOTED(LDB_MODULESDIR, "${LDB_MODULESDIR}" , [ldb Modules directory])
  86                 fi
  87                 ])
  88                 ldbdir=lib/ldb
  89                 AC_SUBST(ldbdir)
  90                 m4_include(lib/ldb/sqlite3.m4)
  91                 m4_include(lib/ldb/libldb.m4)
  92                 SMB_INCLUDE_MK(lib/ldb/config.mk)
  93                 AC_CONFIG_FILES(lib/ldb/ldb.pc)
  94         ]
  95 )
  96 SMB_INCLUDE_MK(lib/ldb/python.mk)
  97
  98 m4_include(lib/tls/config.m4)
  99 m4_include(lib/events/libevents.m4)
 100
 101 dnl m4_include(auth/kerberos/config.m4)
 102 m4_include(auth/gensec/config.m4)
 103 m4_include(smbd/process_model.m4)
 104 m4_include(ntvfs/posix/config.m4)
 105 m4_include(ntvfs/unixuid/config.m4)
 106 m4_include(../lib/socket_wrapper/config.m4)
 107 m4_include(../lib/nss_wrapper/config.m4)
 108 m4_include(auth/config.m4)
 109 m4_include(kdc/config.m4)
 110 m4_include(ntvfs/sysdep/config.m4)
 111 m4_include(nsswitch/config.m4)
 112
 113 #################################################
 114 # add *_CFLAGS only for the real build
 115 CFLAGS="${CFLAGS} ${DEVELOPER_CFLAGS}"
 116
 117 #################################################
 118 # final configure stuff
 119
 120 AC_MSG_CHECKING([configure summary])
 121 AC_TRY_RUN([#include "${srcdir-.}/build/tests/summary.c"],
 122            AC_MSG_RESULT(yes),
 123            AC_MSG_ERROR([summary failure. Aborting config]); exit 1;,
 124            AC_MSG_WARN([cannot run when cross-compiling]))
 125
 126 LIBS=`echo $LIBS | sed -e 's/ *//g'`
 127 if test x"$LIBS" != x""; then
 128         echo "LIBS: $LIBS"
 129         AC_MSG_WARN([the global \$LIBS variable contains some libraries!])
 130         AC_MSG_WARN([this should not happen, please report to samba-technical@lists.samba.org!])
 131         AC_MSG_ERROR([only _EXT macros from aclocal.m4 should be used!])
 132 fi
 133
 134 dnl Remove -L/usr/lib/? from LDFLAGS and LIBS
 135 LIB_REMOVE_USR_LIB(LDFLAGS)
 136 LIB_REMOVE_USR_LIB(LIBS)
 137
 138 dnl Remove -I/usr/include/? from CFLAGS and CPPFLAGS
 139 CFLAGS_REMOVE_USR_INCLUDE(CFLAGS)
 140 CFLAGS_REMOVE_USR_INCLUDE(CPPFLAGS)
 141
 142 AC_SUBST(ac_default_prefix)
 143
 144 for d in build/smb_build bin include ; do
 145     test -d ${builddir}/$d || AS_MKDIR_P(${builddir}/$d)
 146 done
 147
 148 AC_SUBST(INTERN_LDFLAGS)
 149 AC_SUBST(INSTALL_LINK_FLAGS)
 150 if test $USESHARED = "true";
 151 then
 152         INTERN_LDFLAGS="-L\${builddir}/bin/shared -L\${builddir}/bin/static"
 153         INSTALL_LINK_FLAGS="-Wl,-rpath-link,\${builddir}/bin/shared";
 154 else
 155         INTERN_LDFLAGS="-L\${builddir}/bin/static -L\${builddir}/bin/shared"
 156 fi
 157
 158 builddir_headers=""
 159
 160 if test "x$ac_abs_srcdir" != "x$ac_abs_builddir"
 161 then
 162         builddir_headers="-I\$(builddir)/include -I\$(builddir) -I\$(builddir)/lib ";
 163 fi
 164
 165 CPPFLAGS="$builddir_headers-I\$(srcdir)/include -I\$(srcdir) -I\$(srcdir)/lib -I\$(srcdir)/../lib/replace -I\$(srcdir)/../lib/talloc -I\$(srcdir)/.. -D_SAMBA_BUILD_=4 -DHAVE_CONFIG_H $CPPFLAGS"
 166
 167 SMB_WRITE_PERLVARS(build/smb_build/config.pm)
 168
 169 echo "configure: creating config.mk"
 170 cat >config.mk<<CEOF
 171 # config.mk - Autogenerated by configure, DO NOT EDIT!
 172 $SMB_INFO_EXT_LIBS
 173 $SMB_INFO_SUBSYSTEMS
 174 $SMB_INFO_LIBRARIES
 175 CEOF
 176
 177 SMB_BUILD_RUN(data.mk)
 178 AC_OUTPUT
 179
 180 cmp include/config_tmp.h include/config.h >/dev/null 2>&1
 181 CMP_RET=$?
 182 if test $CMP_RET != 0; then
 183         cp include/config_tmp.h include/config.h
 184 fi
 185
 186 SMB_WRITE_MAKEVARS(mkconfig.mk)
 187
 188 if test $USESHARED = true
 189 then
 190         echo "To run binaries without installing, set the following environment variable:"
 191         echo "$LIB_PATH_VAR=$builddir/bin/shared"
 192 fi
 193
 194 echo
 195 echo "To build Samba, run $MAKE"