source3/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(include/includes.h)
   3 AC_CONFIG_HEADER(include/config.h)
   4
   5 dnl Checks for programs.
   6 AC_PROG_CC
   7 AC_PROG_INSTALL
   8 AC_SUBST(SHELL)
   9 AC_PROG_AWK
  10
  11 AC_CANONICAL_SYSTEM
  12 case "$host_os" in
  13         *linux*)   AC_DEFINE(LINUX);;
  14         *solaris*) AC_DEFINE(SUNOS5);;
  15         *sunos*) AC_DEFINE(SUNOS4);;
  16         *irix*) AC_DEFINE(IRIX);;
  17         *aix*) AC_DEFINE(AIX);;
  18         *hpux*) AC_DEFINE(HPUX);;
  19         *qnx*) AC_DEFINE(QNX);;
  20         *osf1*) AC_DEFINE(OSF1);;
  21         *sco*) AC_DEFINE(SCO);;
  22         *next2*) AC_DEFINE(NEXT2);;
  23 esac
  24
  25 AC_VALIDATE_CACHE_SYSTEM_TYPE
  26 SAMBA_MAINTAINER_MODE
  27
  28 AC_INLINE
  29 AC_HEADER_STDC
  30 AC_HEADER_DIRENT
  31 AC_HEADER_TIME
  32 AC_HEADER_SYS_WAIT
  33 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h)
  34 AC_CHECK_HEADERS(unistd.h utime.h grp.h sys/id.h limits.h memory.h net/if.h)
  35 AC_CHECK_HEADERS(compat.h rpc/types.h rpc/xdr.h rpc/auth.h rpc/clnt.h)
  36 AC_CHECK_HEADERS(rpcsvc/yp_prot.h rpcsvc/ypclnt.h sys/param.h ctype.h )
  37 AC_CHECK_HEADERS(sys/wait.h sys/resource.h sys/ioctl.h sys/mode.h)
  38 AC_CHECK_HEADERS(sys/filio.h string.h strings.h stdlib.h sys/socket.h)
  39 AC_CHECK_HEADERS(sys/mount.h sys/vfs.h sys/fs/s5param.h sys/filsys.h termios.h)
  40 AC_CHECK_HEADERS(sys/statfs.h sys/dustat.h sys/statvfs.h stdarg.h sys/sockio.h)
  41 AC_CHECK_HEADERS(shadow.h netinet/tcp.h sys/security.h security/pam_appl.h)
  42 AC_CHECK_HEADERS(stropts.h poll.h readline.h history.h readline/readline.h)
  43 AC_CHECK_HEADERS(readline/history.h)
  44
  45 AC_CHECK_SIZEOF(int,cross)
  46 AC_CHECK_SIZEOF(long,cross)
  47 AC_CHECK_SIZEOF(short,cross)
  48
  49 AC_C_CONST
  50 AC_C_INLINE
  51 AC_C_BIGENDIAN
  52 AC_C_CHAR_UNSIGNED
  53
  54 AC_TYPE_SIGNAL
  55 AC_TYPE_UID_T
  56 AC_TYPE_MODE_T
  57 AC_TYPE_OFF_T
  58 AC_TYPE_SIZE_T
  59 AC_TYPE_PID_T
  60 AC_STRUCT_ST_RDEV
  61 AC_CHECK_TYPE(ino_t,unsigned)
  62 AC_CHECK_TYPE(ssize_t, int)
  63
  64 AC_CACHE_CHECK([for errno in errno.h],samba_cv_errno, [
  65     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
  66         samba_cv_errno=yes,samba_cv_have_errno_decl=no)])
  67 if test x"$samba_cv_errno" = x"yes"; then
  68    AC_DEFINE(HAVE_ERRNO_DECL)
  69 fi
  70
  71 # stupid glibc has the functions but no declaration. grrrr.
  72 AC_CACHE_CHECK([for setresuid declaration],samba_cv_have_setresuid_decl,[
  73     AC_TRY_COMPILE([#include <unistd.h>],[int i = setresuid],
  74         samba_cv_have_setresuid_decl=yes,samba_cv_have_setresuid_decl=no)])
  75 if test x"$samba_cv_have_setresuid_decl" = x"yes"; then
  76     AC_DEFINE(HAVE_SETRESUID_DECL)
  77 fi
  78
  79 # and glibc has setresuid under linux but the function does
  80 # nothing until kernel 2.1.44! very dumb.
  81 AC_CACHE_CHECK([for real setresuid],samba_cv_have_setresuid,[
  82     AC_TRY_RUN([#include <errno.h>
  83 main() { setresuid(1,1,1); setresuid(2,2,2); exit(errno==EPERM?0:1);}],
  84         samba_cv_have_setresuid=yes,samba_cv_have_setresuid=no,samba_cv_have_setresuid=cross)])
  85 if test x"$samba_cv_have_setresuid" = x"yes"; then
  86     AC_DEFINE(HAVE_SETRESUID)
  87 fi
  88
  89 AC_FUNC_MEMCMP
  90
  91 ###############################################
  92 # test for where we get crypt() from
  93 AC_CHECK_FUNCS(crypt)
  94 if test x"$ac_cv_func_crypt" = x"no"; then
  95     AC_CHECK_LIB(crypt, crypt, [LIBS="$LIBS -lcrypt";
  96         AC_DEFINE(HAVE_CRYPT)])
  97 fi
  98
  99
 100 ###############################################
 101 # test for where we get pam_authenticate() from
 102 # might need libdl for this to work
 103 if test "$ac_cv_header_security_pam_appl_h" = "yes"; then
 104   AC_CHECK_LIB(dl,main)
 105 fi
 106 AC_CHECK_FUNCS(pam_authenticate)
 107 if test x"$ac_cv_func_pam_authenticate" = x"no"; then
 108     AC_CHECK_LIB(pam, pam_authenticate, [LIBS="$LIBS -lpam"
 109         AC_DEFINE(HAVE_PAM_AUTHENTICATE)])
 110 fi
 111
 112
 113 ###############################################
 114 # test for where we get readline() from
 115 if test "$ac_cv_header_readline_h" = "yes" ||
 116    test "$ac_cv_header_readline_readline_h" = "yes"; then
 117   AC_CHECK_LIB(readline,readline)
 118 fi
 119
 120
 121 # The following test taken from the cvs sources
 122 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 123 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 124 # libsocket.so which has a bad implementation of gethostbyname (it
 125 # only looks in /etc/hosts), so we only look for -lsocket if we need
 126 # it.
 127 AC_CHECK_FUNCS(connect)
 128 if test x"$ac_cv_func_connect" = x"no"; then
 129     case "$LIBS" in
 130     *-lnsl*) ;;
 131     *) AC_CHECK_LIB(nsl_s, printf) ;;
 132     esac
 133     case "$LIBS" in
 134     *-lnsl*) ;;
 135     *) AC_CHECK_LIB(nsl, printf) ;;
 136     esac
 137     case "$LIBS" in
 138     *-lsocket*) ;;
 139     *) AC_CHECK_LIB(socket, connect) ;;
 140     esac
 141     case "$LIBS" in
 142     *-linet*) ;;
 143     *) AC_CHECK_LIB(inet, connect) ;;
 144     esac
 145     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 146     dnl has been cached.
 147     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 148        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 149         # ac_cv_func_connect=yes
 150         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 151         AC_DEFINE(HAVE_CONNECT)
 152     fi
 153 fi
 154
 155
 156 AC_CHECK_FUNCS(waitpid getcwd strdup strerror chown chmod chroot)
 157 AC_CHECK_FUNCS(fstat strchr utime utimes getrlimit fsync execl bzero memset)
 158 AC_CHECK_FUNCS(memmove vsnprintf setsid glob strpbrk pipe crypt16 getauthuid)
 159 AC_CHECK_FUNCS(strftime sigprocmask sigblock sigaction innetgr)
 160 AC_CHECK_FUNCS(initgroups select rdchk getgrnam pathconf putprpwnam)
 161 AC_CHECK_FUNCS(setuidx setgroups mktime rename ftruncate stat64 fstat64 lstat64)
 162 AC_CHECK_FUNCS(set_auth_parameters atexit grantpt getspnam dup2 lseek64 ftruncate64)
 163 AC_CHECK_FUNCS(fseek64 ftell64 bigcrypt getprpwnam setluid yp_get_default_domain getpwanam)
 164
 165 AC_CACHE_CHECK([for long long],samba_cv_have_longlong,[
 166 AC_TRY_RUN([#include <stdio.h>
 167 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
 168 samba_cv_have_longlong=yes,samba_cv_have_longlong=no,samba_cv_have_longlong=cross)])
 169 if test x"$samba_cv_have_longlong" = x"yes"; then
 170     AC_DEFINE(HAVE_LONGLONG)
 171 fi
 172
 173 AC_CACHE_CHECK([for 64 bit off_t],samba_cv_SIZEOF_OFF_T,[
 174 AC_TRY_RUN([#include <stdio.h>
 175 #include <sys/stat.h>
 176 main() { exit((sizeof(off_t) == 8) ? 0 : 1); }],
 177 samba_cv_SIZEOF_OFF_T=yes,samba_cv_SIZEOF_OFF_T=no,samba_cv_SIZEOF_OFF_T=cross)])
 178 if test x"$samba_cv_SIZEOF_OFF_T" = x"yes"; then
 179     AC_DEFINE(SIZEOF_OFF_T,8)
 180 fi
 181
 182 AC_CACHE_CHECK([for off64_t],samba_cv_HAVE_OFF64_T,[
 183 AC_TRY_RUN([#include <stdio.h>
 184 #include <sys/stat.h>
 185 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 186 samba_cv_HAVE_OFF64_T=yes,samba_cv_HAVE_OFF64_T=no,samba_cv_HAVE_OFF64_T=cross)])
 187 if test x"$samba_cv_HAVE_OFF64_T" = x"yes"; then
 188     AC_DEFINE(HAVE_OFF64_T)
 189 fi
 190
 191 AC_CACHE_CHECK([for 64 bit ino_t],samba_cv_SIZEOF_INO_T,[
 192 AC_TRY_RUN([#include <stdio.h>
 193 #include <sys/stat.h>
 194 main() { exit((sizeof(ino_t) == 8) ? 0 : 1); }],
 195 samba_cv_SIZEOF_INO_T=yes,samba_cv_SIZEOF_INO_T=no,samba_cv_SIZEOF_INO_T=cross)])
 196 if test x"$samba_cv_SIZEOF_INO_T" = x"yes"; then
 197     AC_DEFINE(SIZEOF_INO_T,8)
 198 fi
 199
 200 AC_CACHE_CHECK([for ino64_t],samba_cv_HAVE_INO64_T,[
 201 AC_TRY_RUN([#include <stdio.h>
 202 #include <sys/stat.h>
 203 main() { struct stat64 st; ino64_t s; if (sizeof(ino_t) == sizeof(ino64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 204 samba_cv_HAVE_INO64_T=yes,samba_cv_HAVE_INO64_T=no,samba_cv_HAVE_INO64_T=cross)])
 205 if test x"$samba_cv_HAVE_INO64_T" = x"yes"; then
 206     AC_DEFINE(HAVE_INO64_T)
 207 fi
 208
 209 AC_CACHE_CHECK([for union semun],samba_cv_HAVE_UNION_SEMUN,[
 210 AC_TRY_RUN([
 211 #include <sys/types.h>
 212 #include <sys/ipc.h>
 213 #include <sys/sem.h>
 214 main() { union semun ss; exit(0); }],
 215 samba_cv_HAVE_UNION_SEMUN=yes,samba_cv_HAVE_UNION_SEMUN=no,samba_cv_HAVE_UNION_SEMUN=cross)])
 216 if test x"$samba_cv_HAVE_UNION_SEMUN" = x"yes"; then
 217     AC_DEFINE(HAVE_UNION_SEMUN)
 218 fi
 219
 220 AC_CACHE_CHECK([for unsigned char],samba_cv_HAVE_UNSIGNED_CHAR,[
 221 AC_TRY_RUN([#include <stdio.h>
 222 main() { char c; c=250; exit((c > 0)?0:1); }],
 223 samba_cv_HAVE_UNSIGNED_CHAR=yes,samba_cv_HAVE_UNSIGNED_CHAR=no,samba_cv_HAVE_UNSIGNED_CHAR=cross)])
 224 if test x"$samba_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 225     AC_DEFINE(HAVE_UNSIGNED_CHAR)
 226 fi
 227
 228 AC_CACHE_CHECK([for sin_len in sock],samba_cv_HAVE_SOCK_SIN_LEN,[
 229 AC_TRY_COMPILE([#include <sys/types.h>
 230 #include <sys/socket.h>
 231 #include <netinet/in.h>],
 232 [struct sockaddr_in sock; sock.sin_len = sizeof(sock);],
 233 samba_cv_HAVE_SOCK_SIN_LEN=yes,samba_cv_HAVE_SOCK_SIN_LEN=no)])
 234 if test x"$samba_cv_HAVE_SOCK_SIN_LEN" = x"yes"; then
 235     AC_DEFINE(HAVE_SOCK_SIN_LEN)
 236 fi
 237
 238 AC_CACHE_CHECK([for __FILE__ macro],samba_cv_HAVE_FILE_MACRO,[
 239 AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __FILE__);],
 240 samba_cv_HAVE_FILE_MACRO=yes,samba_cv_HAVE_FILE_MACRO=no)])
 241 if test x"$samba_cv_HAVE_FILE_MACRO" = x"yes"; then
 242     AC_DEFINE(HAVE_FILE_MACRO)
 243 fi
 244
 245 AC_CACHE_CHECK([for __FUNCTION__ macro],samba_cv_HAVE_FUNCTION_MACRO,[
 246 AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __FUNCTION__);],
 247 samba_cv_HAVE_FUNCTION_MACRO=yes,samba_cv_HAVE_FUNCTION_MACRO=no)])
 248 if test x"$samba_cv_HAVE_FUNCTION_MACRO" = x"yes"; then
 249     AC_DEFINE(HAVE_FUNCTION_MACRO)
 250 fi
 251
 252 AC_CACHE_CHECK([if gettimeofday takes tz argument],samba_cv_HAVE_GETTIMEOFDAY_TZ,[
 253 AC_TRY_RUN([
 254 #include <sys/time.h>
 255 #include <unistd.h>
 256 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 257            samba_cv_HAVE_GETTIMEOFDAY_TZ=yes,samba_cv_HAVE_GETTIMEOFDAY_TZ=no,samba_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 258 if test x"$samba_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
 259     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ)
 260 fi
 261
 262
 263 AC_CACHE_CHECK([for broken readdir],samba_cv_HAVE_BROKEN_READDIR,[
 264 AC_TRY_RUN([#include <sys/types.h>
 265 #include <dirent.h>
 266 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 267 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 268 di->d_name[0] == 0) exit(0); exit(1);} ],
 269 samba_cv_HAVE_BROKEN_READDIR=yes,samba_cv_HAVE_BROKEN_READDIR=no,samba_cv_HAVE_BROKEN_READDIR=cross)])
 270 if test x"$samba_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 271     AC_DEFINE(HAVE_BROKEN_READDIR)
 272 fi
 273
 274 AC_CACHE_CHECK([for utimbuf],samba_cv_HAVE_UTIMBUF,[
 275 AC_TRY_COMPILE([#include <sys/types.h>
 276 #include <utime.h>],
 277 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 278 samba_cv_HAVE_UTIMBUF=yes,samba_cv_HAVE_UTIMBUF=no,samba_cv_HAVE_UTIMBUF=cross)])
 279 if test x"$samba_cv_HAVE_UTIMBUF" = x"yes"; then
 280     AC_DEFINE(HAVE_UTIMBUF)
 281 fi
 282
 283 AC_CACHE_CHECK([for kernel oplock type definitions],samba_cv_HAVE_KERNEL_OPLOCKS,[
 284 AC_TRY_COMPILE([#include <sys/types.h>
 285 #include <fcntl.h>],
 286 [oplock_stat_t t; t.os_state = OP_REVOKE; t.os_dev = 1; t.os_ino = 1;],
 287 samba_cv_HAVE_KERNEL_OPLOCKS=yes,samba_cv_HAVE_KERNEL_OPLOCKS=no)])
 288 if test x"$samba_cv_HAVE_KERNEL_OPLOCKS" = x"yes"; then
 289     AC_DEFINE(HAVE_KERNEL_OPLOCKS)
 290 fi
 291
 292
 293 AC_MSG_CHECKING([for test routines])
 294 AC_TRY_RUN([#include "${srcdir-.}/tests/trivial.c"],
 295            AC_MSG_RESULT(yes),
 296            AC_MSG_ERROR([cant find test code. Aborting config]),
 297            AC_MSG_WARN([cannot run when cross-compiling]))
 298
 299 AC_CACHE_CHECK([for ftruncate extend],samba_cv_HAVE_FTRUNCATE_EXTEND,[
 300 AC_TRY_RUN([#include "${srcdir-.}/tests/ftruncate.c"],
 301            samba_cv_HAVE_FTRUNCATE_EXTEND=yes,samba_cv_HAVE_FTRUNCATE_EXTEND=no,samba_cv_HAVE_FTRUNCATE_EXTEND=cross)])
 302 if test x"$samba_cv_HAVE_FTRUNCATE_EXTEND" = x"yes"; then
 303     AC_DEFINE(HAVE_FTRUNCATE_EXTEND)
 304 fi
 305
 306 AC_CACHE_CHECK([for broken getgroups],samba_cv_HAVE_BROKEN_GETGROUPS,[
 307 AC_TRY_RUN([#include "${srcdir-.}/tests/getgroups.c"],
 308            samba_cv_HAVE_BROKEN_GETGROUPS=yes,samba_cv_HAVE_BROKEN_GETGROUPS=no,samba_cv_HAVE_BROKEN_GETGROUPS=cross)])
 309 if test x"$samba_cv_HAVE_BROKEN_GETGROUPS" = x"yes"; then
 310     AC_DEFINE(HAVE_BROKEN_GETGROUPS)
 311 fi
 312
 313 AC_CACHE_CHECK([whether getpass should be replaced],samba_cv_REPLACE_GETPASS,[
 314 SAVE_CPPFLAGS="$CPPFLAGS"
 315 CPPFLAGS="$CPPFLAGS -I${srcdir-.}/include -I${srcdir-.}/ubiqx"
 316 AC_TRY_COMPILE([
 317 #define REPLACE_GETPASS 1
 318 #define NO_CONFIG_H 1
 319 #define main dont_declare_main
 320 #include "${srcdir-.}/lib/getsmbpass.c"
 321 #undef main
 322 ],[],samba_cv_REPLACE_GETPASS=yes,samba_cv_REPLACE_GETPASS=no)
 323 CPPFLAGS="$SAVE_CPPFLAGS"
 324 ])
 325 if test x"$samba_cv_REPLACE_GETPASS" = x"yes"; then
 326         AC_DEFINE(REPLACE_GETPASS)
 327 fi
 328
 329 AC_CACHE_CHECK([for broken inet_ntoa],samba_cv_REPLACE_INET_NTOA,[
 330 AC_TRY_RUN([
 331 #include <stdio.h>
 332 #include <sys/types.h>
 333 #include <netinet/in.h>
 334 #include <arpa/inet.h>
 335 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 336 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 337     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(0); }
 338 exit(1);}],
 339            samba_cv_REPLACE_INET_NTOA=yes,samba_cv_REPLACE_INET_NTOA=no,samba_cv_REPLACE_INET_NTOA=cross)])
 340 if test x"$samba_cv_REPLACE_INET_NTOA" = x"yes"; then
 341     AC_DEFINE(REPLACE_INET_NTOA)
 342 fi
 343
 344 AC_CACHE_CHECK([for root],samba_cv_HAVE_ROOT,[
 345 AC_TRY_RUN([main() { exit(getuid() != 0); }],
 346            samba_cv_HAVE_ROOT=yes,samba_cv_HAVE_ROOT=no,samba_cv_HAVE_ROOT=cross)])
 347 if test x"$samba_cv_HAVE_ROOT" = x"yes"; then
 348     AC_DEFINE(HAVE_ROOT)
 349 else
 350     AC_MSG_WARN(running as non-root will disable some tests)
 351 fi
 352
 353 netmask=no;
 354 AC_CACHE_CHECK([for netmask ifconf],samba_cv_HAVE_NETMASK_IFCONF,[
 355 AC_TRY_RUN([
 356 #define HAVE_NETMASK_IFCONF 1
 357 #define AUTOCONF 1
 358 #include "${srcdir-.}/lib/netmask.c"],
 359            samba_cv_HAVE_NETMASK_IFCONF=yes,samba_cv_HAVE_NETMASK_IFCONF=no,samba_cv_HAVE_NETMASK_IFCONF=cross)])
 360 if test x"$samba_cv_HAVE_NETMASK_IFCONF" = x"yes"; then
 361     netmask=yes;AC_DEFINE(HAVE_NETMASK_IFCONF)
 362 fi
 363
 364 if test $netmask = no; then
 365 AC_CACHE_CHECK([for netmask ifreq],samba_cv_HAVE_NETMASK_IFREQ,[
 366 AC_TRY_RUN([
 367 #define HAVE_NETMASK_IFREQ 1
 368 #define AUTOCONF 1
 369 #include "${srcdir-.}/lib/netmask.c"],
 370            samba_cv_HAVE_NETMASK_IFREQ=yes,samba_cv_HAVE_NETMASK_IFREQ=no,samba_cv_HAVE_NETMASK_IFREQ=cross)])
 371 if test x"$samba_cv_HAVE_NETMASK_IFREQ" = x"yes"; then
 372     netmask=yes;AC_DEFINE(HAVE_NETMASK_IFREQ)
 373 fi
 374 fi
 375
 376 if test $netmask = no; then
 377 AC_CACHE_CHECK([for netmask AIX],samba_cv_HAVE_NETMASK_AIX,[
 378 AC_TRY_RUN([
 379 #define HAVE_NETMASK_AIX 1
 380 #define AUTOCONF 1
 381 #include "${srcdir-.}/lib/netmask.c"],
 382            samba_cv_HAVE_NETMASK_AIX=yes,samba_cv_HAVE_NETMASK_AIX=no,samba_cv_HAVE_NETMASK_AIX=cross)])
 383 if test x"$samba_cv_HAVE_NETMASK_AIX" = x"yes"; then
 384     netmask=yes;AC_DEFINE(HAVE_NETMASK_AIX)
 385 fi
 386 fi
 387
 388 AC_CACHE_CHECK([for trapdoor seteuid],samba_cv_HAVE_TRAPDOOR_UID,[
 389 AC_TRY_RUN([#include "${srcdir-.}/tests/trapdoor.c"],
 390            samba_cv_HAVE_TRAPDOOR_UID=no,samba_cv_HAVE_TRAPDOOR_UID=yes,:)])
 391 if test x"$samba_cv_HAVE_TRAPDOOR_UID" = x"yes"; then
 392     AC_DEFINE(HAVE_TRAPDOOR_UID)
 393 fi
 394
 395 AC_CACHE_CHECK([for shared mmap],samba_cv_HAVE_SHARED_MMAP,[
 396 AC_TRY_RUN([#include "${srcdir-.}/tests/shared_mmap.c"],
 397            samba_cv_HAVE_SHARED_MMAP=yes,samba_cv_HAVE_SHARED_MMAP=no,samba_cv_HAVE_SHARED_MMAP=cross)])
 398 if test x"$samba_cv_HAVE_SHARED_MMAP" = x"yes"; then
 399     AC_DEFINE(HAVE_SHARED_MMAP)
 400 fi
 401
 402 AC_CACHE_CHECK([for fcntl locking],samba_cv_HAVE_FCNTL_LOCK,[
 403 AC_TRY_RUN([#include "${srcdir-.}/tests/fcntl_lock.c"],
 404            samba_cv_HAVE_FCNTL_LOCK=yes,samba_cv_HAVE_FCNTL_LOCK=no,samba_cv_HAVE_FCNTL_LOCK=cross)])
 405 if test x"$samba_cv_HAVE_FCNTL_LOCK" = x"yes"; then
 406     AC_DEFINE(HAVE_FCNTL_LOCK)
 407 fi
 408
 409 AC_CACHE_CHECK([for 64 bit fcntl locking],samba_cv_HAVE_STRUCT_FLOCK64,[
 410 AC_TRY_RUN([
 411 #include <stdio.h>
 412 #include <stdlib.h>
 413
 414 #ifdef HAVE_FCNTL_H
 415 #include <fcntl.h>
 416 #endif
 417
 418 #ifdef HAVE_SYS_FCNTL_H
 419 #include <sys/fcntl.h>
 420 #endif
 421 main() { struct flock64 fl64;
 422 #if defined(F_SETLKW64) && defined(F_SETLK64) && defined(F_GETLK64)
 423 exit(0);
 424 #else
 425 exit(1);
 426 #endif
 427 }],
 428        samba_cv_HAVE_STRUCT_FLOCK64=yes,samba_cv_HAVE_STRUCT_FLOCK64=no,samba_cv_HAVE_STRUCT_FLOCK64=cross)])
 429 if test x"$samba_cv_HAVE_STRUCT_FLOCK64" = x"yes"; then
 430     AC_DEFINE(HAVE_STRUCT_FLOCK64)
 431 fi
 432
 433 AC_CACHE_CHECK([for sysv ipc],samba_cv_HAVE_SYSV_IPC,[
 434 AC_TRY_RUN([#include "${srcdir-.}/tests/sysv_ipc.c"],
 435            samba_cv_HAVE_SYSV_IPC=yes,samba_cv_HAVE_SYSV_IPC=no,samba_cv_HAVE_SYSV_IPC=cross)])
 436 if test x"$samba_cv_HAVE_SYSV_IPC" = x"yes"; then
 437     AC_DEFINE(HAVE_SYSV_IPC)
 438 fi
 439
 440 #################################################
 441 # check for the AFS filesystem
 442 AC_MSG_CHECKING(whether to use AFS)
 443 AC_ARG_WITH(afs,
 444 [  --with-afs     Include AFS support
 445   --without-afs  Don't include AFS support (default)],
 446 [ case "$withval" in
 447   yes)
 448     AC_MSG_RESULT(yes)
 449     AC_DEFINE(WITH_AFS)
 450     ;;
 451   *)
 452     AC_MSG_RESULT(no)
 453     ;;
 454   esac ],
 455   AC_MSG_RESULT(no)
 456 )
 457
 458
 459 #################################################
 460 # check for the DFS auth system
 461 AC_MSG_CHECKING(whether to use DFS auth)
 462 AC_ARG_WITH(dfs,
 463 [  --with-dfs     Include DFS support
 464   --without-dfs  Don't include DFS support (default)],
 465 [ case "$withval" in
 466   yes)
 467     AC_MSG_RESULT(yes)
 468     AC_DEFINE(WITH_DFS)
 469     ;;
 470   *)
 471     AC_MSG_RESULT(no)
 472     ;;
 473   esac ],
 474   AC_MSG_RESULT(no)
 475 )
 476
 477 #################################################
 478 # check for automount support
 479 AC_MSG_CHECKING(whether to use AUTOMOUNT)
 480 AC_ARG_WITH(automount,
 481 [  --with-automount     Include AUTOMOUNT support
 482   --without-automount  Don't include AUTOMOUNT support (default)],
 483 [ case "$withval" in
 484   yes)
 485     AC_MSG_RESULT(yes)
 486     AC_DEFINE(WITH_AUTOMOUNT)
 487     ;;
 488   *)
 489     AC_MSG_RESULT(no)
 490     ;;
 491   esac ],
 492   AC_MSG_RESULT(no)
 493 )
 494
 495 #################################################
 496 # check for a LDAP password database
 497 AC_MSG_CHECKING(whether to use LDAP password database)
 498 AC_ARG_WITH(ldap,
 499 [  --with-ldap     Include LDAP support
 500   --without-ldap  Don't include LDAP support (default)],
 501 [ case "$withval" in
 502   yes)
 503     AC_MSG_RESULT(yes)
 504     AC_DEFINE(WITH_LDAP)
 505     ;;
 506   *)
 507     AC_MSG_RESULT(no)
 508     ;;
 509   esac ],
 510   AC_MSG_RESULT(no)
 511 )
 512
 513 #################################################
 514 # check for a NISPLUS password database
 515 AC_MSG_CHECKING(whether to use NISPLUS password database)
 516 AC_ARG_WITH(nisplus,
 517 [  --with-nisplus     Include NISPLUS password database support
 518   --without-nisplus  Don't include NISPLUS password database support (default)],
 519 [ case "$withval" in
 520   yes)
 521     AC_MSG_RESULT(yes)
 522     AC_DEFINE(WITH_NISPLUS)
 523     ;;
 524   *)
 525     AC_MSG_RESULT(no)
 526     ;;
 527   esac ],
 528   AC_MSG_RESULT(no)
 529 )
 530
 531 #################################################
 532 # check for a NISPLUS_HOME support
 533 AC_MSG_CHECKING(whether to use NISPLUS_HOME)
 534 AC_ARG_WITH(nisplus-home,
 535 [  --with-nisplus-home     Include NISPLUS_HOME support
 536   --without-nisplus-home  Don't include NISPLUS_HOME support (default)],
 537 [ case "$withval" in
 538   yes)
 539     AC_MSG_RESULT(yes)
 540     AC_DEFINE(WITH_NISPLUS_HOME)
 541     ;;
 542   *)
 543     AC_MSG_RESULT(no)
 544     ;;
 545   esac ],
 546   AC_MSG_RESULT(no)
 547 )
 548
 549 #################################################
 550 # check for the secure socket layer
 551 AC_MSG_CHECKING(whether to use SSL)
 552 AC_ARG_WITH(ssl,
 553 [  --with-ssl     Include SSL support
 554   --without-ssl  Don't include SSL support (default)],
 555 [ case "$withval" in
 556   yes)
 557     AC_MSG_RESULT(yes)
 558     AC_DEFINE(WITH_SSL)
 559     ;;
 560   *)
 561     AC_MSG_RESULT(no)
 562     ;;
 563   esac ],
 564   AC_MSG_RESULT(no)
 565 )
 566
 567 #################################################
 568 # check for experimental mmap support
 569 AC_MSG_CHECKING(whether to use MMAP)
 570 AC_ARG_WITH(mmap,
 571 [  --with-mmap     Include experimental MMAP support
 572   --without-mmap  Don't include MMAP support (default)],
 573 [ case "$withval" in
 574   yes)
 575     AC_MSG_RESULT(yes)
 576     AC_DEFINE(WITH_MMAP)
 577     ;;
 578   *)
 579     AC_MSG_RESULT(no)
 580     ;;
 581   esac ],
 582   AC_MSG_RESULT(no)
 583 )
 584
 585 #################################################
 586 # check for syslog logging
 587 AC_MSG_CHECKING(whether to use syslog logging)
 588 AC_ARG_WITH(syslog,
 589 [  --with-syslog     Include experimental SYSLOG support
 590   --without-syslog  Don't include SYSLOG support (default)],
 591 [ case "$withval" in
 592   yes)
 593     AC_MSG_RESULT(yes)
 594     AC_DEFINE(WITH_SYSLOG)
 595     ;;
 596   *)
 597     AC_MSG_RESULT(no)
 598     ;;
 599   esac ],
 600   AC_MSG_RESULT(no)
 601 )
 602
 603 #################################################
 604 # check for experimental netatalk resource fork support
 605 AC_MSG_CHECKING(whether to support netatalk)
 606 AC_ARG_WITH(netatalk,
 607 [  --with-netatalk     Include experimental Netatalk support
 608   --without-netatalk  Don't include experimental Netatalk support (default)],
 609 [ case "$withval" in
 610   yes)
 611     AC_MSG_RESULT(yes)
 612     AC_DEFINE(WITH_NETATALK)
 613     ;;
 614   *)
 615     AC_MSG_RESULT(no)
 616     ;;
 617   esac ],
 618   AC_MSG_RESULT(no)
 619 )
 620
 621
 622 #################################################
 623 # these tests are taken from the GNU fileutils package
 624 AC_CHECKING(how to get filesystem space usage)
 625 space=no
 626
 627 # Test for statvfs64.
 628 if test $space = no; then
 629   # SVR4
 630   AC_CACHE_CHECK([statvfs64 function (SVR4)], fu_cv_sys_stat_statvfs64,
 631   [AC_TRY_RUN([
 632 #include <sys/types.h>
 633 #include <sys/statvfs.h>
 634   main ()
 635   {
 636     struct statvfs64 fsd;
 637     exit (statfs64 (".", &fsd));
 638   }],
 639   fu_cv_sys_stat_statvfs64=yes,
 640   fu_cv_sys_stat_statvfs64=no,
 641   fu_cv_sys_stat_statvfs64=cross)])
 642   if test $fu_cv_sys_stat_statvfs64 = yes; then
 643     space=yes
 644     AC_DEFINE(STAT_STATVFS64)
 645   fi
 646 fi
 647
 648 # Perform only the link test since it seems there are no variants of the
 649 # statvfs function.  This check is more than just AC_CHECK_FUNCS(statvfs)
 650 # because that got a false positive on SCO OSR5.  Adding the declaration
 651 # of a `struct statvfs' causes this test to fail (as it should) on such
 652 # systems.  That system is reported to work fine with STAT_STATFS4 which
 653 # is what it gets when this test fails.
 654 if test $space = no; then
 655   # SVR4
 656   AC_CACHE_CHECK([statvfs function (SVR4)], fu_cv_sys_stat_statvfs,
 657                  [AC_TRY_LINK([#include <sys/types.h>
 658 #include <sys/statvfs.h>],
 659                               [struct statvfs fsd; statvfs (0, &fsd);],
 660                               fu_cv_sys_stat_statvfs=yes,
 661                               fu_cv_sys_stat_statvfs=no)])
 662   if test $fu_cv_sys_stat_statvfs = yes; then
 663     space=yes
 664     AC_DEFINE(STAT_STATVFS)
 665   fi
 666 fi
 667
 668 if test $space = no; then
 669   # DEC Alpha running OSF/1
 670   AC_MSG_CHECKING([for 3-argument statfs function (DEC OSF/1)])
 671   AC_CACHE_VAL(fu_cv_sys_stat_statfs3_osf1,
 672   [AC_TRY_RUN([
 673 #include <sys/param.h>
 674 #include <sys/types.h>
 675 #include <sys/mount.h>
 676   main ()
 677   {
 678     struct statfs fsd;
 679     fsd.f_fsize = 0;
 680     exit (statfs (".", &fsd, sizeof (struct statfs)));
 681   }],
 682   fu_cv_sys_stat_statfs3_osf1=yes,
 683   fu_cv_sys_stat_statfs3_osf1=no,
 684   fu_cv_sys_stat_statfs3_osf1=no)])
 685   AC_MSG_RESULT($fu_cv_sys_stat_statfs3_osf1)
 686   if test $fu_cv_sys_stat_statfs3_osf1 = yes; then
 687     space=yes
 688     AC_DEFINE(STAT_STATFS3_OSF1)
 689   fi
 690 fi
 691
 692 if test $space = no; then
 693 # AIX
 694   AC_MSG_CHECKING([for two-argument statfs with statfs.bsize dnl
 695 member (AIX, 4.3BSD)])
 696   AC_CACHE_VAL(fu_cv_sys_stat_statfs2_bsize,
 697   [AC_TRY_RUN([
 698 #ifdef HAVE_SYS_PARAM_H
 699 #include <sys/param.h>
 700 #endif
 701 #ifdef HAVE_SYS_MOUNT_H
 702 #include <sys/mount.h>
 703 #endif
 704 #ifdef HAVE_SYS_VFS_H
 705 #include <sys/vfs.h>
 706 #endif
 707   main ()
 708   {
 709   struct statfs fsd;
 710   fsd.f_bsize = 0;
 711   exit (statfs (".", &fsd));
 712   }],
 713   fu_cv_sys_stat_statfs2_bsize=yes,
 714   fu_cv_sys_stat_statfs2_bsize=no,
 715   fu_cv_sys_stat_statfs2_bsize=no)])
 716   AC_MSG_RESULT($fu_cv_sys_stat_statfs2_bsize)
 717   if test $fu_cv_sys_stat_statfs2_bsize = yes; then
 718     space=yes
 719     AC_DEFINE(STAT_STATFS2_BSIZE)
 720   fi
 721 fi
 722
 723 if test $space = no; then
 724 # SVR3
 725   AC_MSG_CHECKING([for four-argument statfs (AIX-3.2.5, SVR3)])
 726   AC_CACHE_VAL(fu_cv_sys_stat_statfs4,
 727   [AC_TRY_RUN([#include <sys/types.h>
 728 #include <sys/statfs.h>
 729   main ()
 730   {
 731   struct statfs fsd;
 732   exit (statfs (".", &fsd, sizeof fsd, 0));
 733   }],
 734     fu_cv_sys_stat_statfs4=yes,
 735     fu_cv_sys_stat_statfs4=no,
 736     fu_cv_sys_stat_statfs4=no)])
 737   AC_MSG_RESULT($fu_cv_sys_stat_statfs4)
 738   if test $fu_cv_sys_stat_statfs4 = yes; then
 739     space=yes
 740     AC_DEFINE(STAT_STATFS4)
 741   fi
 742 fi
 743
 744 if test $space = no; then
 745 # 4.4BSD and NetBSD
 746   AC_MSG_CHECKING([for two-argument statfs with statfs.fsize dnl
 747 member (4.4BSD and NetBSD)])
 748   AC_CACHE_VAL(fu_cv_sys_stat_statfs2_fsize,
 749   [AC_TRY_RUN([#include <sys/types.h>
 750 #ifdef HAVE_SYS_PARAM_H
 751 #include <sys/param.h>
 752 #endif
 753 #ifdef HAVE_SYS_MOUNT_H
 754 #include <sys/mount.h>
 755 #endif
 756   main ()
 757   {
 758   struct statfs fsd;
 759   fsd.f_fsize = 0;
 760   exit (statfs (".", &fsd));
 761   }],
 762   fu_cv_sys_stat_statfs2_fsize=yes,
 763   fu_cv_sys_stat_statfs2_fsize=no,
 764   fu_cv_sys_stat_statfs2_fsize=no)])
 765   AC_MSG_RESULT($fu_cv_sys_stat_statfs2_fsize)
 766   if test $fu_cv_sys_stat_statfs2_fsize = yes; then
 767     space=yes
 768     AC_DEFINE(STAT_STATFS2_FSIZE)
 769   fi
 770 fi
 771
 772 if test $space = no; then
 773   # Ultrix
 774   AC_MSG_CHECKING([for two-argument statfs with struct fs_data (Ultrix)])
 775   AC_CACHE_VAL(fu_cv_sys_stat_fs_data,
 776   [AC_TRY_RUN([#include <sys/types.h>
 777 #ifdef HAVE_SYS_PARAM_H
 778 #include <sys/param.h>
 779 #endif
 780 #ifdef HAVE_SYS_MOUNT_H
 781 #include <sys/mount.h>
 782 #endif
 783 #ifdef HAVE_SYS_FS_TYPES_H
 784 #include <sys/fs_types.h>
 785 #endif
 786   main ()
 787   {
 788   struct fs_data fsd;
 789   /* Ultrix's statfs returns 1 for success,
 790      0 for not mounted, -1 for failure.  */
 791   exit (statfs (".", &fsd) != 1);
 792   }],
 793   fu_cv_sys_stat_fs_data=yes,
 794   fu_cv_sys_stat_fs_data=no,
 795   fu_cv_sys_stat_fs_data=no)])
 796   AC_MSG_RESULT($fu_cv_sys_stat_fs_data)
 797   if test $fu_cv_sys_stat_fs_data = yes; then
 798     space=yes
 799     AC_DEFINE(STAT_STATFS2_FS_DATA)
 800   fi
 801 fi
 802
 803 echo "checking configure summary"
 804 AC_TRY_RUN([#include "${srcdir-.}/tests/summary.c"],
 805            echo "configure OK";,
 806            AC_MSG_ERROR([summary failure. Aborting config]),:)
 807
 808 AC_OUTPUT(Makefile tests/dummy client/dummy lib/dummy ubiqx/dummy
 809 web/dummy param/dummy nmbd/dummy smbd/dummy rpc_server/dummy
 810 rpc_client/dummy rpc_parse/dummy locking/dummy passdb/dummy
 811 script/dummy include/dummy codepages/dummy libsmb/dummy bin/dummy
 812 utils/dummy printing/dummy include/stamp-h)