lib/replace/libreplace.m4

   1 AC_DEFUN_ONCE(AC_LIBREPLACE_LOCATION_CHECKS,
   2 [
   3 echo "LIBREPLACE_LOCATION_CHECKS: START"
   4
   5 dnl find the libreplace sources. This is meant to work both for
   6 dnl libreplace standalone builds, and builds of packages using libreplace
   7 libreplacedir=""
   8 libreplacepaths="$srcdir $srcdir/lib/replace $srcdir/libreplace $srcdir/../libreplace $srcdir/../replace $srcdir/../lib/replace $srcdir/../../../lib/replace"
   9 for d in $libreplacepaths; do
  10         if test -f "$d/replace.c"; then
  11                 libreplacedir="$d"
  12                 AC_SUBST(libreplacedir)
  13                 break;
  14         fi
  15 done
  16 if test x"$libreplacedir" = "x"; then
  17         AC_MSG_ERROR([cannot find libreplace in $libreplacepaths])
  18 fi
  19 LIBREPLACEOBJ="$libreplacedir/replace.o"
  20 AC_SUBST(LIBREPLACEOBJ)
  21
  22 AC_CANONICAL_BUILD
  23 AC_CANONICAL_HOST
  24 AC_CANONICAL_TARGET
  25
  26 echo "LIBREPLACE_LOCATION_CHECKS: END"
  27 ]) dnl end AC_LIBREPLACE_LOCATION_CHECKS
  28
  29
  30 AC_DEFUN_ONCE(AC_LIBREPLACE_BROKEN_CHECKS,
  31 [
  32 echo "LIBREPLACE_BROKEN_CHECKS: START"
  33
  34 dnl find the libreplace sources. This is meant to work both for
  35 dnl libreplace standalone builds, and builds of packages using libreplace
  36 libreplacedir=""
  37 libreplacepaths="$srcdir $srcdir/lib/replace $srcdir/libreplace $srcdir/../libreplace $srcdir/../replace $srcdir/../lib/replace $srcdir/../../../lib/replace"
  38 for d in $libreplacepaths; do
  39         if test -f "$d/replace.c"; then
  40                 libreplacedir="$d"
  41                 AC_SUBST(libreplacedir)
  42                 break;
  43         fi
  44 done
  45 if test x"$libreplacedir" = "x"; then
  46         AC_MSG_ERROR([cannot find libreplace in $libreplacepaths])
  47 fi
  48
  49 LIBREPLACEOBJ="$libreplacedir/replace.o"
  50 AC_SUBST(LIBREPLACEOBJ)
  51
  52 LIBREPLACEOBJ="${LIBREPLACEOBJ} $libreplacedir/snprintf.o  $libreplacedir/xattr.o"
  53
  54 AC_TYPE_UID_T
  55 AC_TYPE_MODE_T
  56 AC_TYPE_OFF_T
  57 AC_TYPE_SIZE_T
  58 AC_TYPE_PID_T
  59 AC_STRUCT_ST_RDEV
  60 AC_CHECK_TYPE(ino_t,unsigned)
  61 AC_CHECK_TYPE(loff_t,off_t)
  62 AC_CHECK_TYPE(offset_t,loff_t)
  63 AC_CHECK_TYPE(blksize_t,long)
  64 AC_CHECK_TYPE(blkcnt_t,long)
  65
  66 AC_FUNC_MEMCMP
  67
  68 AC_CHECK_FUNCS([pipe strftime srandom random srand rand usleep setbuffer lstat getpgrp utime utimes])
  69
  70 AC_CHECK_HEADERS(stdbool.h stdint.h sys/select.h)
  71 AC_CHECK_HEADERS(setjmp.h utime.h)
  72
  73 LIBREPLACE_PROVIDE_HEADER([stdint.h])
  74 LIBREPLACE_PROVIDE_HEADER([stdbool.h])
  75
  76 AC_DEFINE(HAVE_LIBREPLACE, 1, [We have libreplace])
  77
  78 AC_CHECK_TYPE(bool,
  79 [AC_DEFINE(HAVE_BOOL, 1, [Whether the bool type is available])],,
  80 [
  81 AC_INCLUDES_DEFAULT
  82 #ifdef HAVE_STDBOOL_H
  83 #include <stdbool.h>
  84 #endif]
  85 )
  86
  87 AC_CHECK_TYPE(_Bool,
  88 [AC_DEFINE(HAVE__Bool, 1, [Whether the _Bool type is available])],,
  89 [
  90 AC_INCLUDES_DEFAULT
  91 #ifdef HAVE_STDBOOL_H
  92 #include <stdbool.h>
  93 #endif]
  94 )
  95
  96 AC_CHECK_HEADERS(linux/types.h)
  97
  98 AC_CACHE_CHECK([for working mmap],libreplace_cv_HAVE_MMAP,[
  99 AC_TRY_RUN([#include "$libreplacedir/test/shared_mmap.c"],
 100            libreplace_cv_HAVE_MMAP=yes,libreplace_cv_HAVE_MMAP=no,libreplace_cv_HAVE_MMAP=cross)])
 101 if test x"$libreplace_cv_HAVE_MMAP" = x"yes"; then
 102     AC_DEFINE(HAVE_MMAP,1,[Whether mmap works])
 103 fi
 104
 105 AC_CACHE_CHECK([for working mremap],libreplace_cv_HAVE_MREMAP,[
 106 AC_TRY_RUN([#include "$libreplacedir/test/shared_mremap.c"],
 107            libreplace_cv_HAVE_MREMAP=yes,libreplace_cv_HAVE_MREMAP=no,libreplace_cv_HAVE_MREMAP=cross)])
 108 if test x"$libreplace_cv_HAVE_MREMAP" = x"yes"; then
 109     AC_DEFINE(HAVE_MREMAP,1,[Whether mremap works])
 110 fi
 111
 112 AC_CACHE_CHECK([for incoherent mmap],libreplace_cv_HAVE_INCOHERENT_MMAP,[
 113 AC_TRY_RUN([#include "$libreplacedir/test/incoherent_mmap.c"],
 114            libreplace_cv_HAVE_INCOHERENT_MMAP=yes,libreplace_cv_HAVE_INCOHERENT_MMAP=no,libreplace_cv_HAVE_INCOHERENT_MMAP=cross)])
 115 if test x"$libreplace_cv_HAVE_INCOHERENT_MMAP" = x"yes"; then
 116     AC_DEFINE(HAVE_INCOHERENT_MMAP,1,[Whether mmap is incoherent against write])
 117 fi
 118
 119
 120 AC_CHECK_HEADERS(sys/syslog.h syslog.h)
 121 AC_CHECK_HEADERS(sys/time.h time.h)
 122 AC_CHECK_HEADERS(stdarg.h vararg.h)
 123 AC_CHECK_HEADERS(sys/mount.h mntent.h)
 124 AC_CHECK_HEADERS(stropts.h)
 125 AC_CHECK_HEADERS(unix.h)
 126 AC_CHECK_HEADERS(malloc.h)
 127 AC_CHECK_HEADERS(syscall.h)
 128 AC_CHECK_HEADERS(sys/syscall.h)
 129
 130 AC_CHECK_FUNCS(syscall setuid seteuid setreuid setresuid setgid setegid setregid setresgid setgroups)
 131 AC_CHECK_FUNCS(chroot bzero strerror strerror_r memalign posix_memalign getpagesize)
 132 AC_CHECK_FUNCS(vsyslog setlinebuf mktime ftruncate chsize rename)
 133 AC_CHECK_FUNCS(waitpid wait4 strlcpy strlcat initgroups memmove strdup)
 134 AC_CHECK_FUNCS(pread pwrite strndup strcasestr strtok_r mkdtemp dup2 dprintf vdprintf)
 135 AC_CHECK_FUNCS(isatty chown lchown link readlink symlink realpath)
 136 AC_CHECK_FUNCS(fdatasync,,[
 137         # if we didn't find it, look in librt (Solaris hides it there...)
 138         AC_CHECK_LIB(rt, fdatasync,
 139                 [libreplace_cv_HAVE_FDATASYNC_IN_LIBRT=yes
 140                 AC_DEFINE(HAVE_FDATASYNC, 1, Define to 1 if there is support for fdatasync)])
 141 ])
 142 AC_HAVE_DECL(fdatasync, [#include <unistd.h>])
 143 AC_CHECK_FUNCS(clock_gettime,libreplace_cv_have_clock_gettime=yes,[
 144         AC_CHECK_LIB(rt, clock_gettime,
 145                 [libreplace_cv_HAVE_CLOCK_GETTIME_IN_LIBRT=yes
 146                 libreplace_cv_have_clock_gettime=yes
 147                 AC_DEFINE(HAVE_CLOCK_GETTIME, 1, Define to 1 if there is support for clock_gettime)])
 148 ])
 149
 150 AC_CHECK_HEADERS(sys/attributes.h attr/xattr.h sys/xattr.h sys/extattr.h sys/uio.h)
 151 AC_CHECK_HEADERS(sys/ea.h sys/proplist.h)
 152
 153 LIBREPLACE_FILESYS_LIBS=""
 154
 155 ############################################
 156 # Check for EA implementations
 157 case "$host_os" in
 158   *freebsd4* | *dragonfly* )
 159         AC_DEFINE(BROKEN_EXTATTR, 1, [Does extattr API work])
 160   ;;
 161   *)
 162         AC_SEARCH_LIBS(getxattr, [attr])
 163         AC_CHECK_FUNCS(attr_get attr_getf attr_list attr_listf attropen attr_remove)
 164         AC_CHECK_FUNCS(attr_removef attr_set attr_setf extattr_delete_fd extattr_delete_file)
 165         AC_CHECK_FUNCS(extattr_get_fd extattr_get_file extattr_list_fd extattr_list_file)
 166         AC_CHECK_FUNCS(extattr_set_fd extattr_set_file fgetea fgetxattr flistea flistxattr)
 167         AC_CHECK_FUNCS(fremoveea fremovexattr fsetea fsetxattr getea getxattr listea)
 168         AC_CHECK_FUNCS(listxattr removeea removexattr setea setxattr)
 169
 170         AC_CHECK_LIB_EXT(attr, LIBREPLACE_FILESYS_LIBS, flistea)
 171         AC_CHECK_LIB_EXT(attr, LIBREPLACE_FILESYS_LIBS, flistxattr)
 172         AC_CHECK_LIB_EXT(attr, LIBREPLACE_FILESYS_LIBS, attr_listf)
 173         AC_CHECK_LIB_EXT(attr, LIBREPLACE_FILESYS_LIBS, extattr_list_fd)
 174
 175   ;;
 176 esac
 177
 178
 179 ########################################################
 180 # Do xattr functions take additional options like on Darwin?
 181 if test x"$ac_cv_func_getxattr" = x"yes" ; then
 182         AC_CACHE_CHECK([whether xattr interface takes additional options], smb_attr_cv_xattr_add_opt, [
 183                 old_LIBS=$LIBS
 184                 LIBS="$LIBS $LIBREPLACE_FILESYS_LIBS"
 185                 AC_TRY_COMPILE([
 186                         #include <sys/types.h>
 187                         #if HAVE_ATTR_XATTR_H
 188                         #include <attr/xattr.h>
 189                         #elif HAVE_SYS_XATTR_H
 190                         #include <sys/xattr.h>
 191                         #endif
 192                 ],[
 193                         getxattr(0, 0, 0, 0, 0, 0);
 194                 ],
 195                 [smb_attr_cv_xattr_add_opt=yes],
 196                 [smb_attr_cv_xattr_add_opt=no;LIBS=$old_LIBS])
 197         ])
 198         if test x"$smb_attr_cv_xattr_add_opt" = x"yes"; then
 199                 AC_DEFINE(XATTR_ADDITIONAL_OPTIONS, 1, [xattr functions have additional options])
 200         fi
 201 fi
 202
 203 AC_CHECK_FUNCS(get_current_dir_name)
 204 AC_HAVE_DECL(setresuid, [#include <unistd.h>])
 205 AC_HAVE_DECL(setresgid, [#include <unistd.h>])
 206 AC_HAVE_DECL(errno, [#include <errno.h>])
 207
 208 AC_CACHE_CHECK([for secure mkstemp],libreplace_cv_HAVE_SECURE_MKSTEMP,[
 209 AC_TRY_RUN([#include <stdlib.h>
 210 #include <sys/types.h>
 211 #include <sys/stat.h>
 212 #include <unistd.h>
 213 main() {
 214   struct stat st;
 215   char tpl[20]="/tmp/test.XXXXXX";
 216   char tpl2[20]="/tmp/test.XXXXXX";
 217   int fd = mkstemp(tpl);
 218   int fd2 = mkstemp(tpl2);
 219   if (fd == -1) {
 220         if (fd2 != -1) {
 221                 unlink(tpl2);
 222         }
 223         exit(1);
 224   }
 225   if (fd2 == -1) exit(1);
 226   unlink(tpl);
 227   unlink(tpl2);
 228   if (fstat(fd, &st) != 0) exit(1);
 229   if ((st.st_mode & 0777) != 0600) exit(1);
 230   if (strcmp(tpl, "/tmp/test.XXXXXX") == 0) {
 231         exit(1);
 232   }
 233   if (strcmp(tpl, tpl2) == 0) {
 234         exit(1);
 235   }
 236   exit(0);
 237 }],
 238 libreplace_cv_HAVE_SECURE_MKSTEMP=yes,
 239 libreplace_cv_HAVE_SECURE_MKSTEMP=no,
 240 libreplace_cv_HAVE_SECURE_MKSTEMP=cross)])
 241 if test x"$libreplace_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 242     AC_DEFINE(HAVE_SECURE_MKSTEMP,1,[Whether mkstemp is secure])
 243 fi
 244
 245 dnl Provided by snprintf.c:
 246 AC_CHECK_HEADERS(stdio.h strings.h)
 247 AC_CHECK_DECLS([snprintf, vsnprintf, asprintf, vasprintf])
 248 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 249
 250 AC_CACHE_CHECK([for C99 vsnprintf],libreplace_cv_HAVE_C99_VSNPRINTF,[
 251 AC_TRY_RUN([
 252 #include <sys/types.h>
 253 #include <stdio.h>
 254 #include <stdarg.h>
 255 #include <stdlib.h>
 256 void foo(const char *format, ...) {
 257        va_list ap;
 258        int len;
 259        char buf[20];
 260        long long l = 1234567890;
 261        l *= 100;
 262
 263        va_start(ap, format);
 264        len = vsnprintf(buf, 0, format, ap);
 265        va_end(ap);
 266        if (len != 5) exit(1);
 267
 268        va_start(ap, format);
 269        len = vsnprintf(0, 0, format, ap);
 270        va_end(ap);
 271        if (len != 5) exit(2);
 272
 273        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(3);
 274
 275        if (snprintf(buf, 20, "%lld", l) != 12 || strcmp(buf, "123456789000") != 0) exit(4);
 276        if (snprintf(buf, 20, "%zu", 123456789) != 9 || strcmp(buf, "123456789") != 0) exit(5);
 277        if (snprintf(buf, 20, "%2\$d %1\$d", 3, 4) != 3 || strcmp(buf, "4 3") != 0) exit(6);
 278        if (snprintf(buf, 20, "%s", 0) < 3) exit(7);
 279
 280        exit(0);
 281 }
 282 main() { foo("hello"); }
 283 ],
 284 libreplace_cv_HAVE_C99_VSNPRINTF=yes,libreplace_cv_HAVE_C99_VSNPRINTF=no,libreplace_cv_HAVE_C99_VSNPRINTF=cross)])
 285 if test x"$libreplace_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 286     AC_DEFINE(HAVE_C99_VSNPRINTF,1,[Whether there is a C99 compliant vsnprintf])
 287 fi
 288
 289
 290 dnl VA_COPY
 291 AC_CACHE_CHECK([for va_copy],libreplace_cv_HAVE_VA_COPY,[
 292 AC_TRY_LINK([#include <stdarg.h>
 293 va_list ap1,ap2;], [va_copy(ap1,ap2);],
 294 libreplace_cv_HAVE_VA_COPY=yes,libreplace_cv_HAVE_VA_COPY=no)])
 295 if test x"$libreplace_cv_HAVE_VA_COPY" = x"yes"; then
 296     AC_DEFINE(HAVE_VA_COPY,1,[Whether va_copy() is available])
 297 fi
 298
 299 if test x"$libreplace_cv_HAVE_VA_COPY" != x"yes"; then
 300 AC_CACHE_CHECK([for __va_copy],libreplace_cv_HAVE___VA_COPY,[
 301 AC_TRY_LINK([#include <stdarg.h>
 302 va_list ap1,ap2;], [__va_copy(ap1,ap2);],
 303 libreplace_cv_HAVE___VA_COPY=yes,libreplace_cv_HAVE___VA_COPY=no)])
 304 if test x"$libreplace_cv_HAVE___VA_COPY" = x"yes"; then
 305     AC_DEFINE(HAVE___VA_COPY,1,[Whether __va_copy() is available])
 306 fi
 307 fi
 308
 309 dnl __FUNCTION__ macro
 310 AC_CACHE_CHECK([for __FUNCTION__ macro],libreplace_cv_HAVE_FUNCTION_MACRO,[
 311 AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __FUNCTION__);],
 312 libreplace_cv_HAVE_FUNCTION_MACRO=yes,libreplace_cv_HAVE_FUNCTION_MACRO=no)])
 313 if test x"$libreplace_cv_HAVE_FUNCTION_MACRO" = x"yes"; then
 314     AC_DEFINE(HAVE_FUNCTION_MACRO,1,[Whether there is a __FUNCTION__ macro])
 315 else
 316     dnl __func__ macro
 317     AC_CACHE_CHECK([for __func__ macro],libreplace_cv_HAVE_func_MACRO,[
 318     AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __func__);],
 319     libreplace_cv_HAVE_func_MACRO=yes,libreplace_cv_HAVE_func_MACRO=no)])
 320     if test x"$libreplace_cv_HAVE_func_MACRO" = x"yes"; then
 321        AC_DEFINE(HAVE_func_MACRO,1,[Whether there is a __func__ macro])
 322     fi
 323 fi
 324
 325 AC_CHECK_HEADERS([sys/param.h limits.h])
 326
 327 AC_CHECK_TYPE(comparison_fn_t,
 328 [AC_DEFINE(HAVE_COMPARISON_FN_T, 1,[Whether or not we have comparison_fn_t])])
 329
 330 AC_HAVE_DECL(setenv, [#include <stdlib.h>])
 331 AC_CHECK_FUNCS(setenv unsetenv)
 332 AC_HAVE_DECL(environ, [#include <unistd.h>])
 333
 334 AC_CHECK_FUNCS(strnlen)
 335 AC_CHECK_FUNCS(strtoull __strtoull strtouq strtoll __strtoll strtoq)
 336
 337 AC_CHECK_FUNCS(memmem)
 338
 339 # this test disabled as we don't actually need __VA_ARGS__ yet
 340 AC_TRY_CPP([
 341 #define eprintf(...) fprintf(stderr, __VA_ARGS__)
 342 eprintf("bla", "bar");
 343 ], AC_DEFINE(HAVE__VA_ARGS__MACRO, 1, [Whether the __VA_ARGS__ macro is available]))
 344
 345
 346 AC_CACHE_CHECK([for sig_atomic_t type],libreplace_cv_sig_atomic_t, [
 347     AC_TRY_COMPILE([
 348 #include <sys/types.h>
 349 #if STDC_HEADERS
 350 #include <stdlib.h>
 351 #include <stddef.h>
 352 #endif
 353 #include <signal.h>],[sig_atomic_t i = 0],
 354         libreplace_cv_sig_atomic_t=yes,libreplace_cv_sig_atomic_t=no)])
 355 if test x"$libreplace_cv_sig_atomic_t" = x"yes"; then
 356    AC_DEFINE(HAVE_SIG_ATOMIC_T_TYPE,1,[Whether we have the atomic_t variable type])
 357 fi
 358
 359
 360 AC_CACHE_CHECK([for O_DIRECT flag to open(2)],libreplace_cv_HAVE_OPEN_O_DIRECT,[
 361 AC_TRY_COMPILE([
 362 #include <unistd.h>
 363 #ifdef HAVE_FCNTL_H
 364 #include <fcntl.h>
 365 #endif],
 366 [int fd = open("/dev/null", O_DIRECT);],
 367 libreplace_cv_HAVE_OPEN_O_DIRECT=yes,libreplace_cv_HAVE_OPEN_O_DIRECT=no)])
 368 if test x"$libreplace_cv_HAVE_OPEN_O_DIRECT" = x"yes"; then
 369     AC_DEFINE(HAVE_OPEN_O_DIRECT,1,[Whether the open(2) accepts O_DIRECT])
 370 fi
 371
 372
 373 dnl Check if the C compiler understands volatile (it should, being ANSI).
 374 AC_CACHE_CHECK([that the C compiler understands volatile],libreplace_cv_volatile, [
 375         AC_TRY_COMPILE([#include <sys/types.h>],[volatile int i = 0],
 376                 libreplace_cv_volatile=yes,libreplace_cv_volatile=no)])
 377 if test x"$libreplace_cv_volatile" = x"yes"; then
 378         AC_DEFINE(HAVE_VOLATILE, 1, [Whether the C compiler understands volatile])
 379 fi
 380
 381 m4_include(system/config.m4)
 382
 383 m4_include(dlfcn.m4)
 384 m4_include(getpass.m4)
 385 m4_include(strptime.m4)
 386 m4_include(win32.m4)
 387 m4_include(timegm.m4)
 388 m4_include(repdir.m4)
 389 m4_include(crypt.m4)
 390
 391 if test x$libreplace_cv_have_clock_gettime = xyes ; then
 392         SMB_CHECK_CLOCK_ID(CLOCK_MONOTONIC)
 393         SMB_CHECK_CLOCK_ID(CLOCK_PROCESS_CPUTIME_ID)
 394         SMB_CHECK_CLOCK_ID(CLOCK_REALTIME)
 395 fi
 396
 397 AC_CACHE_CHECK([for struct timespec type],libreplace_cv_struct_timespec, [
 398     AC_TRY_COMPILE([
 399 #include <sys/types.h>
 400 #if STDC_HEADERS
 401 #include <stdlib.h>
 402 #include <stddef.h>
 403 #endif
 404 #if TIME_WITH_SYS_TIME
 405 # include <sys/time.h>
 406 # include <time.h>
 407 #else
 408 # if HAVE_SYS_TIME_H
 409 #  include <sys/time.h>
 410 # else
 411 #  include <time.h>
 412 # endif
 413 #endif
 414 ],[struct timespec ts;],
 415         libreplace_cv_struct_timespec=yes,libreplace_cv_struct_timespec=no)])
 416 if test x"$libreplace_cv_struct_timespec" = x"yes"; then
 417    AC_DEFINE(HAVE_STRUCT_TIMESPEC,1,[Whether we have struct timespec])
 418 fi
 419
 420 AC_CHECK_FUNCS([printf memset memcpy],,[AC_MSG_ERROR([Required function not found])])
 421
 422 echo "LIBREPLACE_BROKEN_CHECKS: END"
 423 ]) dnl end AC_LIBREPLACE_BROKEN_CHECKS
 424
 425 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_START,
 426 [
 427 #LIBREPLACE_ALL_CHECKS: START"
 428 ])
 429 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_END,
 430 [
 431 #LIBREPLACE_ALL_CHECKS: END"
 432 ])
 433 m4_define(AC_LIBREPLACE_ALL_CHECKS,
 434 [
 435 AC__LIBREPLACE_ALL_CHECKS_START
 436 AC_LIBREPLACE_LOCATION_CHECKS
 437 AC_LIBREPLACE_CC_CHECKS
 438 AC_LIBREPLACE_BROKEN_CHECKS
 439 AC__LIBREPLACE_ALL_CHECKS_END
 440 CFLAGS="$CFLAGS -I$libreplacedir"
 441 ])
 442
 443 m4_include(libreplace_cc.m4)
 444 m4_include(libreplace_ld.m4)
 445 m4_include(libreplace_network.m4)
 446 m4_include(libreplace_macros.m4)
 447
 448
 449 dnl SMB_CHECK_CLOCK_ID(clockid)
 450 dnl Test whether the specified clock_gettime clock ID is available. If it
 451 dnl is, we define HAVE_clockid
 452 AC_DEFUN([SMB_CHECK_CLOCK_ID],
 453 [
 454     AC_MSG_CHECKING(for $1)
 455     AC_TRY_LINK([
 456 #if TIME_WITH_SYS_TIME
 457 # include <sys/time.h>
 458 # include <time.h>
 459 #else
 460 # if HAVE_SYS_TIME_H
 461 #  include <sys/time.h>
 462 # else
 463 #  include <time.h>
 464 # endif
 465 #endif
 466     ],
 467     [
 468 clockid_t clk = $1;
 469     ],
 470     [
 471         AC_MSG_RESULT(yes)
 472         AC_DEFINE(HAVE_$1, 1,
 473             [Whether the clock_gettime clock ID $1 is available])
 474     ],
 475     [
 476         AC_MSG_RESULT(no)
 477     ])
 478 ])
 479 m4_ifndef([AC_USE_SYSTEM_EXTENSIONS],[m4_include(autoconf-2.60.m4)])