pidl/lib/Parse/Pidl/Samba4/NDR/Parser.pm

   1 ###################################################
   2 # Samba4 NDR parser generator for IDL structures
   3 # Copyright tridge@samba.org 2000-2003
   4 # Copyright tpot@samba.org 2001
   5 # Copyright jelmer@samba.org 2004-2006
   6 # released under the GNU GPL
   7
   8 package Parse::Pidl::Samba4::NDR::Parser;
   9
  10 require Exporter;
  11 @ISA = qw(Exporter);
  12 @EXPORT_OK = qw(check_null_pointer NeededFunction NeededElement NeededType $res NeededInterface TypeFunctionName ParseElementPrint);
  13
  14 use strict;
  15 use Parse::Pidl::Typelist qw(hasType getType mapTypeName typeHasBody);
  16 use Parse::Pidl::Util qw(has_property ParseExpr ParseExprExt print_uuid unmake_str);
  17 use Parse::Pidl::CUtil qw(get_pointer_to get_value_of get_array_element);
  18 use Parse::Pidl::NDR qw(GetPrevLevel GetNextLevel ContainsDeferred ContainsPipe is_charset_array);
  19 use Parse::Pidl::Samba4 qw(is_intree choose_header ArrayDynamicallyAllocated);
  20 use Parse::Pidl::Samba4::Header qw(GenerateFunctionInEnv GenerateFunctionOutEnv EnvSubstituteValue GenerateStructEnv);
  21 use Parse::Pidl qw(warning);
  22
  23 use vars qw($VERSION);
  24 $VERSION = '0.01';
  25
  26 # list of known types
  27 my %typefamily;
  28
  29 sub new($$) {
  30         my ($class) = @_;
  31         my $self = { res => "", res_hdr => "", deferred => [], tabs => "", defer_tabs => "" };
  32         bless($self, $class);
  33 }
  34
  35 sub get_typefamily($)
  36 {
  37         my $n = shift;
  38         return $typefamily{$n};
  39 }
  40
  41 sub append_prefix($$)
  42 {
  43         my ($e, $var_name) = @_;
  44         my $pointers = 0;
  45         my $arrays = 0;
  46
  47         foreach my $l (@{$e->{LEVELS}}) {
  48                 if ($l->{TYPE} eq "POINTER") {
  49                         $pointers++;
  50                 } elsif ($l->{TYPE} eq "ARRAY") {
  51                         $arrays++;
  52                         if (($pointers == 0) and
  53                             (not $l->{IS_FIXED}) and
  54                             (not $l->{IS_INLINE})) {
  55                                 return get_value_of($var_name);
  56                         }
  57                 } elsif ($l->{TYPE} eq "DATA") {
  58                         if (Parse::Pidl::Typelist::scalar_is_reference($l->{DATA_TYPE})) {
  59                                 return get_value_of($var_name) unless ($pointers or $arrays);
  60                         }
  61                 }
  62         }
  63
  64         return $var_name;
  65 }
  66
  67 sub has_fast_array($$)
  68 {
  69         my ($e,$l) = @_;
  70
  71         return 0 if ($l->{TYPE} ne "ARRAY");
  72
  73         my $nl = GetNextLevel($e,$l);
  74         return 0 unless ($nl->{TYPE} eq "DATA");
  75         return 0 unless (hasType($nl->{DATA_TYPE}));
  76
  77         my $t = getType($nl->{DATA_TYPE});
  78
  79         # Only uint8 and string have fast array functions at the moment
  80         return ($t->{NAME} eq "uint8") or ($t->{NAME} eq "string");
  81 }
  82
  83
  84 ####################################
  85 # pidl() is our basic output routine
  86 sub pidl($$)
  87 {
  88         my ($self, $d) = @_;
  89         if ($d) {
  90                 $self->{res} .= $self->{tabs};
  91                 $self->{res} .= $d;
  92         }
  93         $self->{res} .="\n";
  94 }
  95
  96 sub pidl_hdr($$) { my ($self, $d) = @_; $self->{res_hdr} .= "$d\n"; }
  97
  98 ####################################
  99 # defer() is like pidl(), but adds to
 100 # a deferred buffer which is then added to the
 101 # output buffer at the end of the structure/union/function
 102 # This is needed to cope with code that must be pushed back
 103 # to the end of a block of elements
 104 sub defer_indent($) { my ($self) = @_; $self->{defer_tabs}.="\t"; }
 105 sub defer_deindent($) { my ($self) = @_; $self->{defer_tabs}=substr($self->{defer_tabs}, 0, -1); }
 106
 107 sub defer($$)
 108 {
 109         my ($self, $d) = @_;
 110         if ($d) {
 111                 push(@{$self->{deferred}}, $self->{defer_tabs}.$d);
 112         }
 113 }
 114
 115 ########################################
 116 # add the deferred content to the current
 117 # output
 118 sub add_deferred($)
 119 {
 120         my ($self) = @_;
 121         $self->pidl($_) foreach (@{$self->{deferred}});
 122         $self->{deferred} = [];
 123         $self->{defer_tabs} = "";
 124 }
 125
 126 sub indent($)
 127 {
 128         my ($self) = @_;
 129         $self->{tabs} .= "\t";
 130 }
 131
 132 sub deindent($)
 133 {
 134         my ($self) = @_;
 135         $self->{tabs} = substr($self->{tabs}, 0, -1);
 136 }
 137
 138 #####################################################################
 139 # declare a function public or static, depending on its attributes
 140 sub fn_declare($$$$)
 141 {
 142         my ($self,$type,$fn,$decl) = @_;
 143
 144         if (has_property($fn, "no$type")) {
 145                 $self->pidl_hdr("$decl;");
 146                 return 0;
 147         }
 148
 149         if (has_property($fn, "public")) {
 150                 $self->pidl_hdr("$decl;");
 151                 $self->pidl("_PUBLIC_ $decl");
 152         } else {
 153                 $self->pidl("static $decl");
 154         }
 155
 156         return 1;
 157 }
 158
 159 ###################################################################
 160 # setup any special flags for an element or structure
 161 sub start_flags($$$)
 162 {
 163         my ($self, $e, $ndr) = @_;
 164         my $flags = has_property($e, "flag");
 165         if (defined $flags) {
 166                 $self->pidl("{");
 167                 $self->indent;
 168                 $self->pidl("uint32_t _flags_save_$e->{TYPE} = $ndr->flags;");
 169                 $self->pidl("ndr_set_flags(&$ndr->flags, $flags);");
 170         }
 171 }
 172
 173 ###################################################################
 174 # end any special flags for an element or structure
 175 sub end_flags($$$)
 176 {
 177         my ($self, $e, $ndr) = @_;
 178         my $flags = has_property($e, "flag");
 179         if (defined $flags) {
 180                 $self->pidl("$ndr->flags = _flags_save_$e->{TYPE};");
 181                 $self->deindent;
 182                 $self->pidl("}");
 183         }
 184 }
 185
 186 #####################################################################
 187 # parse the data of an array - push side
 188 sub ParseArrayPushHeader($$$$$$)
 189 {
 190         my ($self,$e,$l,$ndr,$var_name,$env) = @_;
 191
 192         my $size;
 193         my $length;
 194
 195         if ($l->{IS_ZERO_TERMINATED}) {
 196                 if (has_property($e, "charset")) {
 197                         $size = $length = "ndr_charset_length($var_name, CH_$e->{PROPERTIES}->{charset})";
 198                 } else {
 199                         $size = $length = "ndr_string_length($var_name, sizeof(*$var_name))";
 200                 }
 201         } else {
 202                 $size = ParseExpr($l->{SIZE_IS}, $env, $e);
 203                 $length = ParseExpr($l->{LENGTH_IS}, $env, $e);
 204         }
 205
 206         if ((!$l->{IS_SURROUNDING}) and $l->{IS_CONFORMANT}) {
 207                 $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, $size));");
 208         }
 209
 210         if ($l->{IS_VARYING}) {
 211                 $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, 0));");  # array offset
 212                 $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, $length));");
 213         }
 214
 215         return $length;
 216 }
 217
 218 sub check_fully_dereferenced($$)
 219 {
 220         my ($element, $env) = @_;
 221
 222         return sub ($) {
 223                 my $origvar = shift;
 224                 my $check = 0;
 225
 226                 # Figure out the number of pointers in $ptr
 227                 my $expandedvar = $origvar;
 228                 $expandedvar =~ s/^(\**)//;
 229                 my $ptr = $1;
 230
 231                 my $var = undef;
 232                 foreach (keys %$env) {
 233                         if ($env->{$_} eq $expandedvar) {
 234                                 $var = $_;
 235                                 last;
 236                         }
 237                 }
 238
 239                 return($origvar) unless (defined($var));
 240                 my $e;
 241                 foreach (@{$element->{PARENT}->{ELEMENTS}}) {
 242                         if ($_->{NAME} eq $var) {
 243                                 $e = $_;
 244                                 last;
 245                         }
 246                 }
 247
 248                 $e or die("Environment doesn't match siblings");
 249
 250                 # See if pointer at pointer level $level
 251                 # needs to be checked.
 252                 my $nump = 0;
 253                 foreach (@{$e->{LEVELS}}) {
 254                         if ($_->{TYPE} eq "POINTER") {
 255                                 $nump = $_->{POINTER_INDEX}+1;
 256                         }
 257                 }
 258                 warning($element->{ORIGINAL}, "Got pointer for `$e->{NAME}', expected fully derefenced variable") if ($nump > length($ptr));
 259                 return ($origvar);
 260         }
 261 }
 262
 263 sub check_null_pointer($$$$)
 264 {
 265         my ($element, $env, $print_fn, $return) = @_;
 266
 267         return sub ($) {
 268                 my $expandedvar = shift;
 269                 my $check = 0;
 270
 271                 # Figure out the number of pointers in $ptr
 272                 $expandedvar =~ s/^(\**)//;
 273                 my $ptr = $1;
 274
 275                 my $var = undef;
 276                 foreach (keys %$env) {
 277                         if ($env->{$_} eq $expandedvar) {
 278                                 $var = $_;
 279                                 last;
 280                         }
 281                 }
 282
 283                 if (defined($var)) {
 284                         my $e;
 285                         # lookup ptr in $e
 286                         foreach (@{$element->{PARENT}->{ELEMENTS}}) {
 287                                 if ($_->{NAME} eq $var) {
 288                                         $e = $_;
 289                                         last;
 290                                 }
 291                         }
 292
 293                         $e or die("Environment doesn't match siblings");
 294
 295                         # See if pointer at pointer level $level
 296                         # needs to be checked.
 297                         foreach my $l (@{$e->{LEVELS}}) {
 298                                 if ($l->{TYPE} eq "POINTER" and
 299                                         $l->{POINTER_INDEX} == length($ptr)) {
 300                                         # No need to check ref pointers
 301                                         $check = ($l->{POINTER_TYPE} ne "ref");
 302                                         last;
 303                                 }
 304
 305                                 if ($l->{TYPE} eq "DATA") {
 306                                         warning($element, "too much dereferences for `$var'");
 307                                 }
 308                         }
 309                 } else {
 310                         warning($element, "unknown dereferenced expression `$expandedvar'");
 311                         $check = 1;
 312                 }
 313
 314                 $print_fn->("if ($ptr$expandedvar == NULL) $return") if $check;
 315         }
 316 }
 317
 318 sub ParseArrayPullGetSize($$$$$$)
 319 {
 320         my ($self,$e,$l,$ndr,$var_name,$env) = @_;
 321
 322         my $size;
 323
 324         if ($l->{IS_CONFORMANT}) {
 325                 $size = "ndr_get_array_size($ndr, " . get_pointer_to($var_name) . ")";
 326         } elsif ($l->{IS_ZERO_TERMINATED} and $l->{SIZE_IS} == 0 and $l->{LENGTH_IS} == 0) { # Noheader arrays
 327                 $size = "ndr_get_string_size($ndr, sizeof(*$var_name))";
 328         } else {
 329                 $size = ParseExprExt($l->{SIZE_IS}, $env, $e->{ORIGINAL},
 330                         check_null_pointer($e, $env, sub { $self->pidl(shift); },
 331                                            "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for size_is()\");"),
 332                         check_fully_dereferenced($e, $env));
 333         }
 334
 335         my $array_size = $size;
 336
 337         return $array_size;
 338 }
 339
 340 #####################################################################
 341 # parse an array - pull side
 342 sub ParseArrayPullGetLength($$$$$$;$)
 343 {
 344         my ($self,$e,$l,$ndr,$var_name,$env,$array_size) = @_;
 345
 346         if (not defined($array_size)) {
 347                 $array_size = $self->ParseArrayPullGetSize($e, $l, $ndr, $var_name, $env);
 348         }
 349
 350         my $array_length = $array_size;
 351         if ($l->{IS_VARYING}) {
 352                 my $length = "ndr_get_array_length($ndr, " . get_pointer_to($var_name) .")";
 353                 $array_length = $length;
 354         }
 355
 356         return $array_length;
 357 }
 358
 359 #####################################################################
 360 # parse an array - pull side
 361 sub ParseArrayPullHeader($$$$$$)
 362 {
 363         my ($self,$e,$l,$ndr,$var_name,$env) = @_;
 364
 365         if ((!$l->{IS_SURROUNDING}) and $l->{IS_CONFORMANT}) {
 366                 $self->pidl("NDR_CHECK(ndr_pull_array_size($ndr, " . get_pointer_to($var_name) . "));");
 367         }
 368
 369         if ($l->{IS_VARYING}) {
 370                 $self->pidl("NDR_CHECK(ndr_pull_array_length($ndr, " . get_pointer_to($var_name) . "));");
 371         }
 372
 373         my $array_size = $self->ParseArrayPullGetSize($e, $l, $ndr, $var_name, $env);
 374         my $array_length = $self->ParseArrayPullGetLength($e, $l, $ndr, $var_name, $env, $array_size);
 375
 376         if ($array_length ne $array_size) {
 377                 $self->pidl("if ($array_length > $array_size) {");
 378                 $self->indent;
 379                 $self->pidl("return ndr_pull_error($ndr, NDR_ERR_ARRAY_SIZE, \"Bad array size %u should exceed array length %u\", $array_size, $array_length);");
 380                 $self->deindent;
 381                 $self->pidl("}");
 382         }
 383
 384         if ($l->{IS_CONFORMANT} and not $l->{IS_ZERO_TERMINATED}) {
 385                 $self->defer("if ($var_name) {");
 386                 $self->defer_indent;
 387                 my $size = ParseExprExt($l->{SIZE_IS}, $env, $e->{ORIGINAL},
 388                         check_null_pointer($e, $env, sub { $self->defer(shift); },
 389                                            "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for size_is()\");"),
 390                         check_fully_dereferenced($e, $env));
 391                 $self->defer("NDR_CHECK(ndr_check_array_size($ndr, (void*)" . get_pointer_to($var_name) . ", $size));");
 392                 $self->defer_deindent;
 393                 $self->defer("}");
 394         }
 395
 396         if ($l->{IS_VARYING} and not $l->{IS_ZERO_TERMINATED}) {
 397                 $self->defer("if ($var_name) {");
 398                 $self->defer_indent;
 399                 my $length = ParseExprExt($l->{LENGTH_IS}, $env, $e->{ORIGINAL},
 400                         check_null_pointer($e, $env, sub { $self->defer(shift); },
 401                                            "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for length_is()\");"),
 402                         check_fully_dereferenced($e, $env));
 403                 $self->defer("NDR_CHECK(ndr_check_array_length($ndr, (void*)" . get_pointer_to($var_name) . ", $length));");
 404                 $self->defer_deindent;
 405                 $self->defer("}");
 406         }
 407
 408         if (ArrayDynamicallyAllocated($e,$l) and not is_charset_array($e,$l)) {
 409                 $self->AllocateArrayLevel($e,$l,$ndr,$var_name,$array_size);
 410         }
 411
 412         return $array_length;
 413 }
 414
 415 sub compression_alg($$)
 416 {
 417         my ($e, $l) = @_;
 418         my ($alg, $clen, $dlen) = split(/,/, $l->{COMPRESSION});
 419
 420         return $alg;
 421 }
 422
 423 sub compression_clen($$$)
 424 {
 425         my ($e, $l, $env) = @_;
 426         my ($alg, $clen, $dlen) = split(/,/, $l->{COMPRESSION});
 427
 428         return ParseExpr($clen, $env, $e->{ORIGINAL});
 429 }
 430
 431 sub compression_dlen($$$)
 432 {
 433         my ($e,$l,$env) = @_;
 434         my ($alg, $clen, $dlen) = split(/,/, $l->{COMPRESSION});
 435
 436         return ParseExpr($dlen, $env, $e->{ORIGINAL});
 437 }
 438
 439 sub ParseCompressionPushStart($$$$$)
 440 {
 441         my ($self,$e,$l,$ndr,$env) = @_;
 442         my $comndr = "$ndr\_compressed";
 443         my $alg = compression_alg($e, $l);
 444         my $dlen = compression_dlen($e, $l, $env);
 445
 446         $self->pidl("{");
 447         $self->indent;
 448         $self->pidl("struct ndr_push *$comndr;");
 449         $self->pidl("NDR_CHECK(ndr_push_compression_start($ndr, &$comndr, $alg, $dlen));");
 450
 451         return $comndr;
 452 }
 453
 454 sub ParseCompressionPushEnd($$$$$)
 455 {
 456         my ($self,$e,$l,$ndr,$env) = @_;
 457         my $comndr = "$ndr\_compressed";
 458         my $alg = compression_alg($e, $l);
 459         my $dlen = compression_dlen($e, $l, $env);
 460
 461         $self->pidl("NDR_CHECK(ndr_push_compression_end($ndr, $comndr, $alg, $dlen));");
 462         $self->deindent;
 463         $self->pidl("}");
 464 }
 465
 466 sub ParseCompressionPullStart($$$$$)
 467 {
 468         my ($self,$e,$l,$ndr,$env) = @_;
 469         my $comndr = "$ndr\_compressed";
 470         my $alg = compression_alg($e, $l);
 471         my $dlen = compression_dlen($e, $l, $env);
 472
 473         $self->pidl("{");
 474         $self->indent;
 475         $self->pidl("struct ndr_pull *$comndr;");
 476         $self->pidl("NDR_CHECK(ndr_pull_compression_start($ndr, &$comndr, $alg, $dlen));");
 477
 478         return $comndr;
 479 }
 480
 481 sub ParseCompressionPullEnd($$$$$)
 482 {
 483         my ($self,$e,$l,$ndr,$env) = @_;
 484         my $comndr = "$ndr\_compressed";
 485         my $alg = compression_alg($e, $l);
 486         my $dlen = compression_dlen($e, $l, $env);
 487
 488         $self->pidl("NDR_CHECK(ndr_pull_compression_end($ndr, $comndr, $alg, $dlen));");
 489         $self->deindent;
 490         $self->pidl("}");
 491 }
 492
 493 sub ParseSubcontextPushStart($$$$$)
 494 {
 495         my ($self,$e,$l,$ndr,$env) = @_;
 496         my $subndr = "_ndr_$e->{NAME}";
 497         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 498
 499         $self->pidl("{");
 500         $self->indent;
 501         $self->pidl("struct ndr_push *$subndr;");
 502         $self->pidl("NDR_CHECK(ndr_push_subcontext_start($ndr, &$subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 503
 504         if (defined $l->{COMPRESSION}) {
 505                 $subndr = $self->ParseCompressionPushStart($e, $l, $subndr, $env);
 506         }
 507
 508         return $subndr;
 509 }
 510
 511 sub ParseSubcontextPushEnd($$$$$)
 512 {
 513         my ($self,$e,$l,$ndr,$env) = @_;
 514         my $subndr = "_ndr_$e->{NAME}";
 515         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 516
 517         if (defined $l->{COMPRESSION}) {
 518                 $self->ParseCompressionPushEnd($e, $l, $subndr, $env);
 519         }
 520
 521         $self->pidl("NDR_CHECK(ndr_push_subcontext_end($ndr, $subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 522         $self->deindent;
 523         $self->pidl("}");
 524 }
 525
 526 sub ParseSubcontextPullStart($$$$$)
 527 {
 528         my ($self,$e,$l,$ndr,$env) = @_;
 529         my $subndr = "_ndr_$e->{NAME}";
 530         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 531
 532         $self->pidl("{");
 533         $self->indent;
 534         $self->pidl("struct ndr_pull *$subndr;");
 535         $self->pidl("NDR_CHECK(ndr_pull_subcontext_start($ndr, &$subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 536
 537         if (defined $l->{COMPRESSION}) {
 538                 $subndr = $self->ParseCompressionPullStart($e, $l, $subndr, $env);
 539         }
 540
 541         return $subndr;
 542 }
 543
 544 sub ParseSubcontextPullEnd($$$$$)
 545 {
 546         my ($self,$e,$l,$ndr,$env) = @_;
 547         my $subndr = "_ndr_$e->{NAME}";
 548         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 549
 550         if (defined $l->{COMPRESSION}) {
 551                 $self->ParseCompressionPullEnd($e, $l, $subndr, $env);
 552         }
 553
 554         $self->pidl("NDR_CHECK(ndr_pull_subcontext_end($ndr, $subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 555         $self->deindent;
 556         $self->pidl("}");
 557 }
 558
 559 sub ParseElementPushLevel
 560 {
 561         my ($self,$e,$l,$ndr,$var_name,$env,$primitives,$deferred) = @_;
 562
 563         my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
 564
 565         if ($l->{TYPE} eq "ARRAY" and ($l->{IS_CONFORMANT} or $l->{IS_VARYING})) {
 566                 $var_name = get_pointer_to($var_name);
 567         }
 568
 569         if (defined($ndr_flags)) {
 570                 if ($l->{TYPE} eq "SUBCONTEXT") {
 571                         my $subndr = $self->ParseSubcontextPushStart($e, $l, $ndr, $env);
 572                         $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $subndr, $var_name, $env, 1, 1);
 573                         $self->ParseSubcontextPushEnd($e, $l, $ndr, $env);
 574                 } elsif ($l->{TYPE} eq "POINTER") {
 575                         $self->ParsePtrPush($e, $l, $ndr, $var_name);
 576                 } elsif ($l->{TYPE} eq "ARRAY") {
 577                         my $length = $self->ParseArrayPushHeader($e, $l, $ndr, $var_name, $env);
 578
 579                         my $nl = GetNextLevel($e, $l);
 580
 581                         # Allow speedups for arrays of scalar types
 582                         if (is_charset_array($e,$l)) {
 583                                 $self->pidl("NDR_CHECK(ndr_push_charset($ndr, $ndr_flags, $var_name, $length, sizeof(" . mapTypeName($nl->{DATA_TYPE}) . "), CH_$e->{PROPERTIES}->{charset}));");
 584                                 return;
 585                         } elsif (has_fast_array($e,$l)) {
 586                                 $self->pidl("NDR_CHECK(ndr_push_array_$nl->{DATA_TYPE}($ndr, $ndr_flags, $var_name, $length));");
 587                                 return;
 588                         }
 589                 } elsif ($l->{TYPE} eq "SWITCH") {
 590                         $self->ParseSwitchPush($e, $l, $ndr, $var_name, $env);
 591                 } elsif ($l->{TYPE} eq "DATA") {
 592                         $self->ParseDataPush($e, $l, $ndr, $var_name, $primitives, $deferred);
 593                 } elsif ($l->{TYPE} eq "TYPEDEF") {
 594                         $typefamily{$e->{DATA}->{TYPE}}->{PUSH_FN_BODY}->($self, $e->{DATA}, $ndr, $var_name);
 595                 }
 596         }
 597
 598         if ($l->{TYPE} eq "POINTER" and $deferred) {
 599                 my $rel_var_name = $var_name;
 600                 if ($l->{POINTER_TYPE} ne "ref") {
 601                         $self->pidl("if ($var_name) {");
 602                         $self->indent;
 603                         if ($l->{POINTER_TYPE} eq "relative") {
 604                                 $self->pidl("NDR_CHECK(ndr_push_relative_ptr2_start($ndr, $rel_var_name));");
 605                         }
 606                         if ($l->{POINTER_TYPE} eq "relative_short") {
 607                                 $self->pidl("NDR_CHECK(ndr_push_short_relative_ptr2($ndr, $var_name));");
 608                         }
 609                 }
 610                 $var_name = get_value_of($var_name);
 611                 $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, 1, 1);
 612
 613                 if ($l->{POINTER_TYPE} ne "ref") {
 614                         if ($l->{POINTER_TYPE} eq "relative") {
 615                                 $self->pidl("NDR_CHECK(ndr_push_relative_ptr2_end($ndr, $rel_var_name));");
 616                         }
 617                         $self->deindent;
 618                         $self->pidl("}");
 619                 }
 620         } elsif ($l->{TYPE} eq "ARRAY" and not has_fast_array($e,$l) and
 621                 not is_charset_array($e, $l)) {
 622                 my $length = ParseExpr($l->{LENGTH_IS}, $env, $e->{ORIGINAL});
 623                 my $counter = "cntr_$e->{NAME}_$l->{LEVEL_INDEX}";
 624
 625                 my $array_pointless = ($length eq "0");
 626
 627                 if ($array_pointless) {
 628                         warning($e->{ORIGINAL}, "pointless array `$e->{NAME}' will always have size 0");
 629                 }
 630
 631                 $var_name = get_array_element($var_name, $counter);
 632
 633                 if ((($primitives and not $l->{IS_DEFERRED}) or ($deferred and $l->{IS_DEFERRED})) and not $array_pointless) {
 634                         $self->pidl("for ($counter = 0; $counter < $length; $counter++) {");
 635                         $self->indent;
 636                         $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, 1, 0);
 637                         $self->deindent;
 638                         $self->pidl("}");
 639                 }
 640
 641                 if ($deferred and ContainsDeferred($e, $l) and not $array_pointless) {
 642                         $self->pidl("for ($counter = 0; $counter < $length; $counter++) {");
 643                         $self->indent;
 644                         $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, 0, 1);
 645                         $self->deindent;
 646                         $self->pidl("}");
 647                 }
 648         } elsif ($l->{TYPE} eq "SWITCH") {
 649                 $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, $primitives, $deferred);
 650         }
 651 }
 652
 653 #####################################################################
 654 # parse scalars in a structure element
 655 sub ParseElementPush($$$$$$)
 656 {
 657         my ($self,$e,$ndr,$env,$primitives,$deferred) = @_;
 658         my $subndr = undef;
 659
 660         my $var_name = $env->{$e->{NAME}};
 661
 662         return if ContainsPipe($e, $e->{LEVELS}[0]);
 663
 664         return unless $primitives or ($deferred and ContainsDeferred($e, $e->{LEVELS}[0]));
 665
 666         # Representation type is different from transmit_as
 667         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
 668                 $self->pidl("{");
 669                 $self->indent;
 670                 my $transmit_name = "_transmit_$e->{NAME}";
 671                 $self->pidl(mapTypeName($e->{TYPE}) ." $transmit_name;");
 672                 $self->pidl("NDR_CHECK(ndr_$e->{REPRESENTATION_TYPE}_to_$e->{TYPE}($var_name, " . get_pointer_to($transmit_name) . "));");
 673                 $var_name = $transmit_name;
 674         }
 675
 676         $var_name = append_prefix($e, $var_name);
 677
 678         $self->start_flags($e, $ndr);
 679
 680         if (defined(my $value = has_property($e, "value"))) {
 681                 $var_name = ParseExpr($value, $env, $e->{ORIGINAL});
 682         }
 683
 684         $self->ParseElementPushLevel($e, $e->{LEVELS}[0], $ndr, $var_name, $env, $primitives, $deferred);
 685
 686         $self->end_flags($e, $ndr);
 687
 688         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
 689                 $self->deindent;
 690                 $self->pidl("}");
 691         }
 692 }
 693
 694 #####################################################################
 695 # parse a pointer in a struct element or function
 696 sub ParsePtrPush($$$$$)
 697 {
 698         my ($self,$e,$l,$ndr,$var_name) = @_;
 699
 700         if ($l->{POINTER_TYPE} eq "ref") {
 701                 $self->pidl("if ($var_name == NULL) {");
 702                 $self->indent;
 703                 $self->pidl("return ndr_push_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL [ref] pointer\");");
 704                 $self->deindent;
 705                 $self->pidl("}");
 706                 if ($l->{LEVEL} eq "EMBEDDED") {
 707                         $self->pidl("NDR_CHECK(ndr_push_ref_ptr(ndr));");
 708                 }
 709         } elsif ($l->{POINTER_TYPE} eq "relative") {
 710                 $self->pidl("NDR_CHECK(ndr_push_relative_ptr1($ndr, $var_name));");
 711         } elsif ($l->{POINTER_TYPE} eq "relative_short") {
 712                 $self->pidl("NDR_CHECK(ndr_push_short_relative_ptr1($ndr, $var_name));");
 713         } elsif ($l->{POINTER_TYPE} eq "unique") {
 714                 $self->pidl("NDR_CHECK(ndr_push_unique_ptr($ndr, $var_name));");
 715         } elsif ($l->{POINTER_TYPE} eq "full") {
 716                 $self->pidl("NDR_CHECK(ndr_push_full_ptr($ndr, $var_name));");
 717         } else {
 718                 die("Unhandled pointer type $l->{POINTER_TYPE}");
 719         }
 720 }
 721
 722 sub need_pointer_to($$$)
 723 {
 724         my ($e, $l, $scalar_only) = @_;
 725
 726         my $t;
 727         if (ref($l->{DATA_TYPE})) {
 728                 $t = "$l->{DATA_TYPE}->{TYPE}_$l->{DATA_TYPE}->{NAME}";
 729         } else {
 730                 $t = $l->{DATA_TYPE};
 731         }
 732
 733         if (not Parse::Pidl::Typelist::is_scalar($t)) {
 734                 return 1 if $scalar_only;
 735         }
 736
 737         my $arrays = 0;
 738
 739         foreach my $tl (@{$e->{LEVELS}}) {
 740                 last if $l == $tl;
 741                 if ($tl->{TYPE} eq "ARRAY") {
 742                         $arrays++;
 743                 }
 744         }
 745
 746         if (Parse::Pidl::Typelist::scalar_is_reference($t)) {
 747                 return 1 unless $arrays;
 748         }
 749
 750         return 0;
 751 }
 752
 753 sub ParseDataPrint($$$$$)
 754 {
 755         my ($self, $e, $l, $ndr, $var_name) = @_;
 756
 757         if (not ref($l->{DATA_TYPE}) or defined($l->{DATA_TYPE}->{NAME})) {
 758
 759                 if (need_pointer_to($e, $l, 1)) {
 760                         $var_name = get_pointer_to($var_name);
 761                 }
 762
 763                 $self->pidl(TypeFunctionName("ndr_print", $l->{DATA_TYPE})."($ndr, \"$e->{NAME}\", $var_name);");
 764         } else {
 765                 $self->ParseTypePrint($l->{DATA_TYPE}, $ndr, $var_name);
 766         }
 767 }
 768
 769 #####################################################################
 770 # print scalars in a structure element
 771 sub ParseElementPrint($$$$$)
 772 {
 773         my($self, $e, $ndr, $var_name, $env) = @_;
 774
 775         return if (has_property($e, "noprint"));
 776
 777         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
 778                 $self->pidl("ndr_print_$e->{REPRESENTATION_TYPE}($ndr, \"$e->{NAME}\", $var_name);");
 779                 return;
 780         }
 781
 782         $var_name = append_prefix($e, $var_name);
 783
 784         if (defined(my $value = has_property($e, "value"))) {
 785                 $var_name = "($ndr->flags & LIBNDR_PRINT_SET_VALUES)?" . ParseExpr($value,$env, $e->{ORIGINAL}) . ":$var_name";
 786         }
 787
 788         foreach my $l (@{$e->{LEVELS}}) {
 789                 if ($l->{TYPE} eq "POINTER") {
 790                         $self->pidl("ndr_print_ptr($ndr, \"$e->{NAME}\", $var_name);");
 791                         $self->pidl("$ndr->depth++;");
 792                         if ($l->{POINTER_TYPE} ne "ref") {
 793                                 $self->pidl("if ($var_name) {");
 794                                 $self->indent;
 795                         }
 796                         $var_name = get_value_of($var_name);
 797                 } elsif ($l->{TYPE} eq "ARRAY") {
 798                         my $length;
 799
 800                         if ($l->{IS_CONFORMANT} or $l->{IS_VARYING}) {
 801                                 $var_name = get_pointer_to($var_name);
 802                         }
 803
 804                         if ($l->{IS_ZERO_TERMINATED}) {
 805                                 $length = "ndr_string_length($var_name, sizeof(*$var_name))";
 806                         } else {
 807                                 $length = ParseExprExt($l->{LENGTH_IS}, $env, $e->{ORIGINAL},
 808                                                         check_null_pointer($e, $env, sub { $self->pidl(shift); }, "return;"), check_fully_dereferenced($e, $env));
 809                         }
 810
 811                         if (is_charset_array($e,$l)) {
 812                                 $self->pidl("ndr_print_string($ndr, \"$e->{NAME}\", $var_name);");
 813                                 last;
 814                         } elsif (has_fast_array($e, $l)) {
 815                                 my $nl = GetNextLevel($e, $l);
 816                                 $self->pidl("ndr_print_array_$nl->{DATA_TYPE}($ndr, \"$e->{NAME}\", $var_name, $length);");
 817                                 last;
 818                         } else {
 819                                 my $counter = "cntr_$e->{NAME}_$l->{LEVEL_INDEX}";
 820
 821                                 $self->pidl("$ndr->print($ndr, \"\%s: ARRAY(\%d)\", \"$e->{NAME}\", (int)$length);");
 822                                 $self->pidl("$ndr->depth++;");
 823                                 $self->pidl("for ($counter=0;$counter<$length;$counter++) {");
 824                                 $self->indent;
 825
 826                                 $var_name = get_array_element($var_name, $counter);
 827                         }
 828                 } elsif ($l->{TYPE} eq "DATA") {
 829                         $self->ParseDataPrint($e, $l, $ndr, $var_name);
 830                 } elsif ($l->{TYPE} eq "SWITCH") {
 831                         my $switch_var = ParseExprExt($l->{SWITCH_IS}, $env, $e->{ORIGINAL},
 832                                                 check_null_pointer($e, $env, sub { $self->pidl(shift); }, "return;"), check_fully_dereferenced($e, $env));
 833                         $self->pidl("ndr_print_set_switch_value($ndr, " . get_pointer_to($var_name) . ", $switch_var);");
 834                 }
 835         }
 836
 837         foreach my $l (reverse @{$e->{LEVELS}}) {
 838                 if ($l->{TYPE} eq "POINTER") {
 839                         if ($l->{POINTER_TYPE} ne "ref") {
 840                                 $self->deindent;
 841                                 $self->pidl("}");
 842                         }
 843                         $self->pidl("$ndr->depth--;");
 844                 } elsif (($l->{TYPE} eq "ARRAY")
 845                         and not is_charset_array($e,$l)
 846                         and not has_fast_array($e,$l)) {
 847                         $self->deindent;
 848                         $self->pidl("}");
 849                         $self->pidl("$ndr->depth--;");
 850                 }
 851         }
 852 }
 853
 854 #####################################################################
 855 # parse scalars in a structure element - pull size
 856 sub ParseSwitchPull($$$$$$)
 857 {
 858         my($self,$e,$l,$ndr,$var_name,$env) = @_;
 859         my $switch_var = ParseExprExt($l->{SWITCH_IS}, $env, $e->{ORIGINAL},
 860                 check_null_pointer($e, $env, sub { $self->pidl(shift); },
 861                                    "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for switch_is()\");"),
 862                 check_fully_dereferenced($e, $env));
 863
 864         $var_name = get_pointer_to($var_name);
 865         $self->pidl("NDR_CHECK(ndr_pull_set_switch_value($ndr, $var_name, $switch_var));");
 866 }
 867
 868 #####################################################################
 869 # push switch element
 870 sub ParseSwitchPush($$$$$$)
 871 {
 872         my($self,$e,$l,$ndr,$var_name,$env) = @_;
 873         my $switch_var = ParseExprExt($l->{SWITCH_IS}, $env, $e->{ORIGINAL},
 874                 check_null_pointer($e, $env, sub { $self->pidl(shift); },
 875                                    "return ndr_push_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for switch_is()\");"),
 876                 check_fully_dereferenced($e, $env));
 877
 878         $var_name = get_pointer_to($var_name);
 879         $self->pidl("NDR_CHECK(ndr_push_set_switch_value($ndr, $var_name, $switch_var));");
 880 }
 881
 882 sub ParseDataPull($$$$$$$)
 883 {
 884         my ($self,$e,$l,$ndr,$var_name,$primitives,$deferred) = @_;
 885
 886         if (not ref($l->{DATA_TYPE}) or defined($l->{DATA_TYPE}->{NAME})) {
 887
 888                 my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
 889
 890                 if (need_pointer_to($e, $l, 0)) {
 891                         $var_name = get_pointer_to($var_name);
 892                 }
 893
 894                 $var_name = get_pointer_to($var_name);
 895
 896                 $self->pidl("NDR_CHECK(".TypeFunctionName("ndr_pull", $l->{DATA_TYPE})."($ndr, $ndr_flags, $var_name));");
 897
 898                 my $pl = GetPrevLevel($e, $l);
 899
 900                 my $range = has_property($e, "range");
 901                 if ($range and $pl->{TYPE} ne "ARRAY") {
 902                         $var_name = get_value_of($var_name);
 903                         my $signed = Parse::Pidl::Typelist::is_signed($l->{DATA_TYPE});
 904                         my ($low, $high) = split(/,/, $range, 2);
 905                         if ($low < 0 and not $signed) {
 906                                 warning(0, "$low is invalid for the range of an unsigned type");
 907                         }
 908                         if ($low == 0 and not $signed) {
 909                                 $self->pidl("if ($var_name > $high) {");
 910                         } else {
 911                                 $self->pidl("if ($var_name < $low || $var_name > $high) {");
 912                         }
 913                         $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_RANGE, \"value out of range\");");
 914                         $self->pidl("}");
 915                 }
 916         } else {
 917                 $self->ParseTypePull($l->{DATA_TYPE}, $ndr, $var_name, $primitives, $deferred);
 918         }
 919 }
 920
 921 sub ParseDataPush($$$$$$$)
 922 {
 923         my ($self,$e,$l,$ndr,$var_name,$primitives,$deferred) = @_;
 924
 925         if (not ref($l->{DATA_TYPE}) or defined($l->{DATA_TYPE}->{NAME})) {
 926
 927                 my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
 928
 929                 # strings are passed by value rather than reference
 930                 if (need_pointer_to($e, $l, 1)) {
 931                         $var_name = get_pointer_to($var_name);
 932                 }
 933
 934                 $self->pidl("NDR_CHECK(".TypeFunctionName("ndr_push", $l->{DATA_TYPE})."($ndr, $ndr_flags, $var_name));");
 935         } else {
 936                 $self->ParseTypePush($l->{DATA_TYPE}, $ndr, $var_name, $primitives, $deferred);
 937         }
 938 }
 939
 940 sub CalcNdrFlags($$$)
 941 {
 942         my ($l,$primitives,$deferred) = @_;
 943
 944         my $scalars = 0;
 945         my $buffers = 0;
 946
 947         # Add NDR_SCALARS if this one is deferred
 948         # and deferreds may be pushed
 949         $scalars = 1 if ($l->{IS_DEFERRED} and $deferred);
 950
 951         # Add NDR_SCALARS if this one is not deferred and
 952         # primitives may be pushed
 953         $scalars = 1 if (!$l->{IS_DEFERRED} and $primitives);
 954
 955         # Add NDR_BUFFERS if this one contains deferred stuff
 956         # and deferreds may be pushed
 957         $buffers = 1 if ($l->{CONTAINS_DEFERRED} and $deferred);
 958
 959         return "NDR_SCALARS|NDR_BUFFERS" if ($scalars and $buffers);
 960         return "NDR_SCALARS" if ($scalars);
 961         return "NDR_BUFFERS" if ($buffers);
 962         return undef;
 963 }
 964
 965 sub ParseMemCtxPullFlags($$$$)
 966 {
 967         my ($self, $e, $l) = @_;
 968
 969         return undef unless ($l->{TYPE} eq "POINTER" or $l->{TYPE} eq "ARRAY");
 970
 971         return undef unless ($l->{TYPE} ne "ARRAY" or ArrayDynamicallyAllocated($e,$l));
 972         return undef if has_fast_array($e, $l);
 973         return undef if is_charset_array($e, $l);
 974
 975         my $mem_flags = "0";
 976
 977         if (($l->{TYPE} eq "POINTER") and ($l->{POINTER_TYPE} eq "ref")) {
 978                 my $nl = GetNextLevel($e, $l);
 979                 return undef if ($nl->{TYPE} eq "PIPE");
 980                 return undef if ($nl->{TYPE} eq "ARRAY");
 981                 return undef if (($nl->{TYPE} eq "DATA") and ($nl->{DATA_TYPE} eq "string"));
 982
 983                 if ($l->{LEVEL} eq "TOP") {
 984                         $mem_flags = "LIBNDR_FLAG_REF_ALLOC";
 985                 }
 986         }
 987
 988         return $mem_flags;
 989 }
 990
 991 sub ParseMemCtxPullStart($$$$$)
 992 {
 993         my ($self, $e, $l, $ndr, $ptr_name) = @_;
 994
 995         my $mem_r_ctx = "_mem_save_$e->{NAME}_$l->{LEVEL_INDEX}";
 996         my $mem_c_ctx = $ptr_name;
 997         my $mem_c_flags = $self->ParseMemCtxPullFlags($e, $l);
 998
 999         return unless defined($mem_c_flags);
1000
1001         $self->pidl("$mem_r_ctx = NDR_PULL_GET_MEM_CTX($ndr);");
1002         $self->pidl("NDR_PULL_SET_MEM_CTX($ndr, $mem_c_ctx, $mem_c_flags);");
1003 }
1004
1005 sub ParseMemCtxPullEnd($$$$)
1006 {
1007         my ($self, $e, $l, $ndr) = @_;
1008
1009         my $mem_r_ctx = "_mem_save_$e->{NAME}_$l->{LEVEL_INDEX}";
1010         my $mem_r_flags = $self->ParseMemCtxPullFlags($e, $l);
1011
1012         return unless defined($mem_r_flags);
1013
1014         $self->pidl("NDR_PULL_SET_MEM_CTX($ndr, $mem_r_ctx, $mem_r_flags);");
1015 }
1016
1017 sub CheckStringTerminator($$$$$)
1018 {
1019         my ($self,$ndr,$e,$l,$length) = @_;
1020         my $nl = GetNextLevel($e, $l);
1021
1022         # Make sure last element is zero!
1023         $self->pidl("NDR_CHECK(ndr_check_string_terminator($ndr, $length, sizeof($nl->{DATA_TYPE}_t)));");
1024 }
1025
1026 sub ParseElementPullLevel
1027 {
1028         my($self,$e,$l,$ndr,$var_name,$env,$primitives,$deferred) = @_;
1029
1030         my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
1031
1032         if ($l->{TYPE} eq "ARRAY" and ($l->{IS_VARYING} or $l->{IS_CONFORMANT})) {
1033                 $var_name = get_pointer_to($var_name);
1034         }
1035
1036         # Only pull something if there's actually something to be pulled
1037         if (defined($ndr_flags)) {
1038                 if ($l->{TYPE} eq "SUBCONTEXT") {
1039                         my $subndr = $self->ParseSubcontextPullStart($e, $l, $ndr, $env);
1040                         $self->ParseElementPullLevel($e, GetNextLevel($e,$l), $subndr, $var_name, $env, 1, 1);
1041                         $self->ParseSubcontextPullEnd($e, $l, $ndr, $env);
1042                 } elsif ($l->{TYPE} eq "ARRAY") {
1043                         my $length = $self->ParseArrayPullHeader($e, $l, $ndr, $var_name, $env);
1044
1045                         if (my $range = has_property($e, "range")) {
1046                                 my ($low, $high) = split(/,/, $range, 2);
1047                                 if ($low < 0) {
1048                                         warning(0, "$low is invalid for the range of an array size");
1049                                 }
1050                                 if ($low == 0) {
1051                                         $self->pidl("if ($length > $high) {");
1052                                 } else {
1053                                         $self->pidl("if ($length < $low || $length > $high) {");
1054                                 }
1055                                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_RANGE, \"value out of range\");");
1056                                 $self->pidl("}");
1057                         }
1058
1059                         my $nl = GetNextLevel($e, $l);
1060
1061                         if (is_charset_array($e,$l)) {
1062                                 if ($l->{IS_ZERO_TERMINATED}) {
1063                                         $self->CheckStringTerminator($ndr, $e, $l, $length);
1064                                 }
1065                                 if ($l->{IS_TO_NULL}) {
1066                                         $self->pidl("NDR_CHECK(ndr_pull_charset_to_null($ndr, $ndr_flags, ".get_pointer_to($var_name).", $length, sizeof(" . mapTypeName($nl->{DATA_TYPE}) . "), CH_$e->{PROPERTIES}->{charset}));");
1067                                 } else {
1068                                         $self->pidl("NDR_CHECK(ndr_pull_charset($ndr, $ndr_flags, ".get_pointer_to($var_name).", $length, sizeof(" . mapTypeName($nl->{DATA_TYPE}) . "), CH_$e->{PROPERTIES}->{charset}));");
1069                                 }
1070                                 return;
1071                         } elsif (has_fast_array($e, $l)) {
1072                                 if ($l->{IS_ZERO_TERMINATED}) {
1073                                         $self->CheckStringTerminator($ndr,$e,$l,$length);
1074                                 }
1075                                 $self->pidl("NDR_CHECK(ndr_pull_array_$nl->{DATA_TYPE}($ndr, $ndr_flags, $var_name, $length));");
1076                                 return;
1077                         }
1078                 } elsif ($l->{TYPE} eq "POINTER") {
1079                         $self->ParsePtrPull($e, $l, $ndr, $var_name);
1080                 } elsif ($l->{TYPE} eq "SWITCH") {
1081                         $self->ParseSwitchPull($e, $l, $ndr, $var_name, $env);
1082                 } elsif ($l->{TYPE} eq "DATA") {
1083                         $self->ParseDataPull($e, $l, $ndr, $var_name, $primitives, $deferred);
1084                 } elsif ($l->{TYPE} eq "TYPEDEF") {
1085                         $typefamily{$e->{DATA}->{TYPE}}->{PULL_FN_BODY}->($self, $e->{DATA}, $ndr, $var_name);
1086                 }
1087         }
1088
1089         # add additional constructions
1090         if ($l->{TYPE} eq "POINTER" and $deferred) {
1091                 if ($l->{POINTER_TYPE} ne "ref") {
1092                         $self->pidl("if ($var_name) {");
1093                         $self->indent;
1094
1095                         if ($l->{POINTER_TYPE} eq "relative" or $l->{POINTER_TYPE} eq "relative_short") {
1096                                 $self->pidl("uint32_t _relative_save_offset;");
1097                                 $self->pidl("_relative_save_offset = $ndr->offset;");
1098                                 $self->pidl("NDR_CHECK(ndr_pull_relative_ptr2($ndr, $var_name));");
1099                         }
1100                 }
1101
1102                 $self->ParseMemCtxPullStart($e, $l, $ndr, $var_name);
1103
1104                 $var_name = get_value_of($var_name);
1105                 $self->ParseElementPullLevel($e, GetNextLevel($e,$l), $ndr, $var_name, $env, 1, 1);
1106
1107                 $self->ParseMemCtxPullEnd($e, $l, $ndr);
1108
1109                 if ($l->{POINTER_TYPE} ne "ref") {
1110                         if ($l->{POINTER_TYPE} eq "relative") {
1111                                 $self->pidl("if ($ndr->offset > $ndr->relative_highest_offset) {");
1112                                 $self->indent;
1113                                 $self->pidl("$ndr->relative_highest_offset = $ndr->offset;");
1114                                 $self->deindent;
1115                                 $self->pidl("}");
1116                                 $self->pidl("$ndr->offset = _relative_save_offset;");
1117                         }
1118                         $self->deindent;
1119                         $self->pidl("}");
1120                 }
1121         } elsif ($l->{TYPE} eq "ARRAY" and
1122                         not has_fast_array($e,$l) and not is_charset_array($e, $l)) {
1123                 my $length = ParseExpr($l->{LENGTH_IS}, $env, $e->{ORIGINAL});
1124                 my $counter = "cntr_$e->{NAME}_$l->{LEVEL_INDEX}";
1125                 my $array_name = $var_name;
1126
1127                 if ($l->{IS_VARYING}) {
1128                         $length = "ndr_get_array_length($ndr, " . get_pointer_to($var_name) .")";
1129                 }
1130
1131                 if (my $range = has_property($e, "range")) {
1132                         my ($low, $high) = split(/,/, $range, 2);
1133                         if ($low < 0) {
1134                                 warning(0, "$low is invalid for the range of an array size");
1135                         }
1136                         if ($low == 0) {
1137                                 $self->pidl("if ($length > $high) {");
1138                         } else {
1139                                 $self->pidl("if ($length < $low || $length > $high) {");
1140                         }
1141                         $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_RANGE, \"value out of range\");");
1142                         $self->pidl("}");
1143                 }
1144
1145                 $var_name = get_array_element($var_name, $counter);
1146
1147                 $self->ParseMemCtxPullStart($e, $l, $ndr, $array_name);
1148
1149                 if (($primitives and not $l->{IS_DEFERRED}) or ($deferred and $l->{IS_DEFERRED})) {
1150                         my $nl = GetNextLevel($e,$l);
1151
1152                         if ($l->{IS_ZERO_TERMINATED}) {
1153                                 $self->CheckStringTerminator($ndr,$e,$l,$length);
1154                         }
1155
1156                         $self->pidl("for ($counter = 0; $counter < $length; $counter++) {");
1157                         $self->indent;
1158                         $self->ParseElementPullLevel($e, $nl, $ndr, $var_name, $env, 1, 0);
1159                         $self->deindent;
1160                         $self->pidl("}");
1161                 }
1162
1163                 if ($deferred and ContainsDeferred($e, $l)) {
1164                         $self->pidl("for ($counter = 0; $counter < $length; $counter++) {");
1165                         $self->indent;
1166                         $self->ParseElementPullLevel($e,GetNextLevel($e,$l), $ndr, $var_name, $env, 0, 1);
1167                         $self->deindent;
1168                         $self->pidl("}");
1169                 }
1170
1171                 $self->ParseMemCtxPullEnd($e, $l, $ndr);
1172
1173         } elsif ($l->{TYPE} eq "SWITCH") {
1174                 $self->ParseElementPullLevel($e, GetNextLevel($e,$l), $ndr, $var_name, $env, $primitives, $deferred);
1175         }
1176 }
1177
1178 #####################################################################
1179 # parse scalars in a structure element - pull size
1180 sub ParseElementPull($$$$$$)
1181 {
1182         my($self,$e,$ndr,$env,$primitives,$deferred) = @_;
1183
1184         my $var_name = $env->{$e->{NAME}};
1185         my $represent_name;
1186         my $transmit_name;
1187
1188         return if ContainsPipe($e, $e->{LEVELS}[0]);
1189
1190         return unless $primitives or ($deferred and ContainsDeferred($e, $e->{LEVELS}[0]));
1191
1192         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
1193                 $self->pidl("{");
1194                 $self->indent;
1195                 $represent_name = $var_name;
1196                 $transmit_name = "_transmit_$e->{NAME}";
1197                 $var_name = $transmit_name;
1198                 $self->pidl(mapTypeName($e->{TYPE})." $var_name;");
1199         }
1200
1201         $var_name = append_prefix($e, $var_name);
1202
1203         $self->start_flags($e, $ndr);
1204
1205         $self->ParseElementPullLevel($e,$e->{LEVELS}[0],$ndr,$var_name,$env,$primitives,$deferred);
1206
1207         $self->end_flags($e, $ndr);
1208
1209         # Representation type is different from transmit_as
1210         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
1211                 $self->pidl("NDR_CHECK(ndr_$e->{TYPE}_to_$e->{REPRESENTATION_TYPE}($transmit_name, ".get_pointer_to($represent_name)."));");
1212                 $self->deindent;
1213                 $self->pidl("}");
1214         }
1215 }
1216
1217 #####################################################################
1218 # parse a pointer in a struct element or function
1219 sub ParsePtrPull($$$$$)
1220 {
1221         my($self, $e,$l,$ndr,$var_name) = @_;
1222
1223         my $nl = GetNextLevel($e, $l);
1224         my $next_is_array = ($nl->{TYPE} eq "ARRAY");
1225         my $next_is_string = (($nl->{TYPE} eq "DATA") and
1226                                                  ($nl->{DATA_TYPE} eq "string"));
1227
1228         if ($l->{POINTER_TYPE} eq "ref" and $l->{LEVEL} eq "TOP") {
1229
1230                 if (!$next_is_array and !$next_is_string) {
1231                         $self->pidl("if ($ndr->flags & LIBNDR_FLAG_REF_ALLOC) {");
1232                         $self->pidl("\tNDR_PULL_ALLOC($ndr, $var_name);");
1233                         $self->pidl("}");
1234                 }
1235
1236                 return;
1237         } elsif ($l->{POINTER_TYPE} eq "ref" and $l->{LEVEL} eq "EMBEDDED") {
1238                 $self->pidl("NDR_CHECK(ndr_pull_ref_ptr($ndr, &_ptr_$e->{NAME}));");
1239         } elsif (($l->{POINTER_TYPE} eq "unique") or
1240                  ($l->{POINTER_TYPE} eq "relative") or
1241                  ($l->{POINTER_TYPE} eq "full")) {
1242                 $self->pidl("NDR_CHECK(ndr_pull_generic_ptr($ndr, &_ptr_$e->{NAME}));");
1243         } elsif ($l->{POINTER_TYPE} eq "relative_short") {
1244                 $self->pidl("NDR_CHECK(ndr_pull_relative_ptr_short($ndr, &_ptr_$e->{NAME}));");
1245         } else {
1246                 die("Unhandled pointer type $l->{POINTER_TYPE}");
1247         }
1248
1249         $self->pidl("if (_ptr_$e->{NAME}) {");
1250         $self->indent;
1251
1252         # Don't do this for arrays, they're allocated at the actual level
1253         # of the array
1254         unless ($next_is_array or $next_is_string) {
1255                 $self->pidl("NDR_PULL_ALLOC($ndr, $var_name);");
1256         } else {
1257                 # FIXME: Yes, this is nasty.
1258                 # We allocate an array twice
1259                 # - once just to indicate that it's there,
1260                 # - then the real allocation...
1261                 $self->pidl("NDR_PULL_ALLOC($ndr, $var_name);");
1262         }
1263
1264         #$self->pidl("memset($var_name, 0, sizeof($var_name));");
1265         if ($l->{POINTER_TYPE} eq "relative" or $l->{POINTER_TYPE} eq "relative_short") {
1266                 $self->pidl("NDR_CHECK(ndr_pull_relative_ptr1($ndr, $var_name, _ptr_$e->{NAME}));");
1267         }
1268         $self->deindent;
1269         $self->pidl("} else {");
1270         $self->pidl("\t$var_name = NULL;");
1271         $self->pidl("}");
1272 }
1273
1274 sub ParseStructPushPrimitives($$$$$)
1275 {
1276         my ($self, $struct, $ndr, $varname, $env) = @_;
1277
1278         # see if the structure contains a conformant array. If it
1279         # does, then it must be the last element of the structure, and
1280         # we need to push the conformant length early, as it fits on
1281         # the wire before the structure (and even before the structure
1282         # alignment)
1283         if (defined($struct->{SURROUNDING_ELEMENT})) {
1284                 my $e = $struct->{SURROUNDING_ELEMENT};
1285
1286                 if (defined($e->{LEVELS}[0]) and
1287                         $e->{LEVELS}[0]->{TYPE} eq "ARRAY") {
1288                         my $size;
1289
1290                         if ($e->{LEVELS}[0]->{IS_ZERO_TERMINATED}) {
1291                                 if (has_property($e, "charset")) {
1292                                         $size = "ndr_charset_length($varname->$e->{NAME}, CH_$e->{PROPERTIES}->{charset})";
1293                                 } else {
1294                                         $size = "ndr_string_length($varname->$e->{NAME}, sizeof(*$varname->$e->{NAME}))";
1295                                 }
1296                         } else {
1297                                 $size = ParseExpr($e->{LEVELS}[0]->{SIZE_IS}, $env, $e->{ORIGINAL});
1298                         }
1299
1300                         $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, $size));");
1301                 } else {
1302                         $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, ndr_string_array_size($ndr, $varname->$e->{NAME})));");
1303                 }
1304         }
1305
1306         $self->pidl("NDR_CHECK(ndr_push_align($ndr, $struct->{ALIGN}));");
1307
1308         if (defined($struct->{PROPERTIES}{relative_base})) {
1309                 # set the current offset as base for relative pointers
1310                 # and store it based on the toplevel struct/union
1311                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1312         }
1313
1314         $self->ParseElementPush($_, $ndr, $env, 1, 0) foreach (@{$struct->{ELEMENTS}});
1315
1316         $self->pidl("NDR_CHECK(ndr_push_trailer_align($ndr, $struct->{ALIGN}));");
1317 }
1318
1319 sub ParseStructPushDeferred($$$$)
1320 {
1321         my ($self, $struct, $ndr, $varname, $env) = @_;
1322         if (defined($struct->{PROPERTIES}{relative_base})) {
1323                 # retrieve the current offset as base for relative pointers
1324                 # based on the toplevel struct/union
1325                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset2($ndr, $varname));");
1326         }
1327         $self->ParseElementPush($_, $ndr, $env, 0, 1) foreach (@{$struct->{ELEMENTS}});
1328 }
1329
1330 #####################################################################
1331 # parse a struct
1332 sub ParseStructPush($$$$)
1333 {
1334         my ($self, $struct, $ndr, $varname) = @_;
1335
1336         return unless defined($struct->{ELEMENTS});
1337
1338         my $env = GenerateStructEnv($struct, $varname);
1339
1340         EnvSubstituteValue($env, $struct);
1341
1342         $self->DeclareArrayVariablesNoZero($_, $env) foreach (@{$struct->{ELEMENTS}});
1343
1344         $self->start_flags($struct, $ndr);
1345
1346         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
1347         $self->indent;
1348         $self->ParseStructPushPrimitives($struct, $ndr, $varname, $env);
1349         $self->deindent;
1350         $self->pidl("}");
1351
1352         $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
1353         $self->indent;
1354         $self->ParseStructPushDeferred($struct, $ndr, $varname, $env);
1355         $self->deindent;
1356         $self->pidl("}");
1357
1358         $self->end_flags($struct, $ndr);
1359 }
1360
1361 #####################################################################
1362 # generate a push function for an enum
1363 sub ParseEnumPush($$$$)
1364 {
1365         my($self,$enum,$ndr,$varname) = @_;
1366         my($type_fn) = $enum->{BASE_TYPE};
1367
1368         $self->start_flags($enum, $ndr);
1369         $self->pidl("NDR_CHECK(ndr_push_enum_$type_fn($ndr, NDR_SCALARS, $varname));");
1370         $self->end_flags($enum, $ndr);
1371 }
1372
1373 #####################################################################
1374 # generate a pull function for an enum
1375 sub ParseEnumPull($$$$)
1376 {
1377         my($self,$enum,$ndr,$varname) = @_;
1378         my($type_fn) = $enum->{BASE_TYPE};
1379         my($type_v_decl) = mapTypeName($type_fn);
1380
1381         $self->pidl("$type_v_decl v;");
1382         $self->start_flags($enum, $ndr);
1383         $self->pidl("NDR_CHECK(ndr_pull_enum_$type_fn($ndr, NDR_SCALARS, &v));");
1384         $self->pidl("*$varname = v;");
1385
1386         $self->end_flags($enum, $ndr);
1387 }
1388
1389 #####################################################################
1390 # generate a print function for an enum
1391 sub ParseEnumPrint($$$$$)
1392 {
1393         my($self,$enum,$ndr,$name,$varname) = @_;
1394
1395         $self->pidl("const char *val = NULL;");
1396         $self->pidl("");
1397
1398         $self->start_flags($enum, $ndr);
1399
1400         $self->pidl("switch ($varname) {");
1401         $self->indent;
1402         my $els = \@{$enum->{ELEMENTS}};
1403         foreach my $i (0 .. $#{$els}) {
1404                 my $e = ${$els}[$i];
1405                 chomp $e;
1406                 if ($e =~ /^(.*)=/) {
1407                         $e = $1;
1408                 }
1409                 $self->pidl("case $e: val = \"$e\"; break;");
1410         }
1411
1412         $self->deindent;
1413         $self->pidl("}");
1414
1415         $self->pidl("ndr_print_enum($ndr, name, \"$enum->{TYPE}\", val, $varname);");
1416
1417         $self->end_flags($enum, $ndr);
1418 }
1419
1420 sub DeclEnum($$$$)
1421 {
1422         my ($e,$t,$name,$varname) = @_;
1423         return "enum $name " .
1424                 ($t eq "pull"?"*":"") . $varname;
1425 }
1426
1427 $typefamily{ENUM} = {
1428         DECL => \&DeclEnum,
1429         PUSH_FN_BODY => \&ParseEnumPush,
1430         PULL_FN_BODY => \&ParseEnumPull,
1431         PRINT_FN_BODY => \&ParseEnumPrint,
1432 };
1433
1434 #####################################################################
1435 # generate a push function for a bitmap
1436 sub ParseBitmapPush($$$$)
1437 {
1438         my($self,$bitmap,$ndr,$varname) = @_;
1439         my($type_fn) = $bitmap->{BASE_TYPE};
1440
1441         $self->start_flags($bitmap, $ndr);
1442
1443         $self->pidl("NDR_CHECK(ndr_push_$type_fn($ndr, NDR_SCALARS, $varname));");
1444
1445         $self->end_flags($bitmap, $ndr);
1446 }
1447
1448 #####################################################################
1449 # generate a pull function for an bitmap
1450 sub ParseBitmapPull($$$$)
1451 {
1452         my($self,$bitmap,$ndr,$varname) = @_;
1453         my $type_fn = $bitmap->{BASE_TYPE};
1454         my($type_decl) = mapTypeName($bitmap->{BASE_TYPE});
1455
1456         $self->pidl("$type_decl v;");
1457         $self->start_flags($bitmap, $ndr);
1458         $self->pidl("NDR_CHECK(ndr_pull_$type_fn($ndr, NDR_SCALARS, &v));");
1459         $self->pidl("*$varname = v;");
1460
1461         $self->end_flags($bitmap, $ndr);
1462 }
1463
1464 #####################################################################
1465 # generate a print function for an bitmap
1466 sub ParseBitmapPrintElement($$$$$$)
1467 {
1468         my($self,$e,$bitmap,$ndr,$name,$varname) = @_;
1469         my($type_decl) = mapTypeName($bitmap->{BASE_TYPE});
1470         my($type_fn) = $bitmap->{BASE_TYPE};
1471         my($flag);
1472
1473         if ($e =~ /^(\w+) .*$/) {
1474                 $flag = "$1";
1475         } else {
1476                 die "Bitmap: \"$name\" invalid Flag: \"$e\"";
1477         }
1478
1479         $self->pidl("ndr_print_bitmap_flag($ndr, sizeof($type_decl), \"$flag\", $flag, $varname);");
1480 }
1481
1482 #####################################################################
1483 # generate a print function for an bitmap
1484 sub ParseBitmapPrint($$$$$)
1485 {
1486         my($self,$bitmap,$ndr,$name,$varname) = @_;
1487         my($type_decl) = mapTypeName($bitmap->{TYPE});
1488         my($type_fn) = $bitmap->{BASE_TYPE};
1489
1490         $self->start_flags($bitmap, $ndr);
1491
1492         $self->pidl("ndr_print_$type_fn($ndr, name, $varname);");
1493
1494         $self->pidl("$ndr->depth++;");
1495         foreach my $e (@{$bitmap->{ELEMENTS}}) {
1496                 $self->ParseBitmapPrintElement($e, $bitmap, $ndr, $name, $varname);
1497         }
1498         $self->pidl("$ndr->depth--;");
1499
1500         $self->end_flags($bitmap, $ndr);
1501 }
1502
1503 sub DeclBitmap($$$$)
1504 {
1505         my ($e,$t,$name,$varname) = @_;
1506         return mapTypeName(Parse::Pidl::Typelist::bitmap_type_fn($e)) .
1507                 ($t eq "pull"?" *":" ") . $varname;
1508 }
1509
1510 $typefamily{BITMAP} = {
1511         DECL => \&DeclBitmap,
1512         PUSH_FN_BODY => \&ParseBitmapPush,
1513         PULL_FN_BODY => \&ParseBitmapPull,
1514         PRINT_FN_BODY => \&ParseBitmapPrint,
1515 };
1516
1517 #####################################################################
1518 # generate a struct print function
1519 sub ParseStructPrint($$$$$)
1520 {
1521         my($self,$struct,$ndr,$name,$varname) = @_;
1522
1523         return unless defined $struct->{ELEMENTS};
1524
1525         my $env = GenerateStructEnv($struct, $varname);
1526
1527         $self->DeclareArrayVariables($_) foreach (@{$struct->{ELEMENTS}});
1528
1529         $self->pidl("ndr_print_struct($ndr, name, \"$name\");");
1530         $self->pidl("if (r == NULL) { ndr_print_null($ndr); return; }");
1531
1532         $self->start_flags($struct, $ndr);
1533
1534         $self->pidl("$ndr->depth++;");
1535
1536         $self->ParseElementPrint($_, $ndr, $env->{$_->{NAME}}, $env)
1537                 foreach (@{$struct->{ELEMENTS}});
1538         $self->pidl("$ndr->depth--;");
1539
1540         $self->end_flags($struct, $ndr);
1541 }
1542
1543 sub DeclarePtrVariables($$)
1544 {
1545         my ($self,$e) = @_;
1546         foreach my $l (@{$e->{LEVELS}}) {
1547                 my $size = 32;
1548                 if ($l->{TYPE} eq "POINTER" and
1549                         not ($l->{POINTER_TYPE} eq "ref" and $l->{LEVEL} eq "TOP")) {
1550                         if ($l->{POINTER_TYPE} eq "relative_short") {
1551                                 $size = 16;
1552                         }
1553                         $self->pidl("uint${size}_t _ptr_$e->{NAME};");
1554                         last;
1555                 }
1556         }
1557 }
1558
1559 sub DeclareArrayVariables($$)
1560 {
1561         my ($self,$e) = @_;
1562
1563         foreach my $l (@{$e->{LEVELS}}) {
1564                 next if ($l->{TYPE} ne "ARRAY");
1565                 next if has_fast_array($e,$l);
1566                 next if is_charset_array($e,$l);
1567                 $self->pidl("uint32_t cntr_$e->{NAME}_$l->{LEVEL_INDEX};");
1568         }
1569 }
1570
1571 sub DeclareArrayVariablesNoZero($$$)
1572 {
1573         my ($self,$e,$env) = @_;
1574
1575         foreach my $l (@{$e->{LEVELS}}) {
1576                 next if ($l->{TYPE} ne "ARRAY");
1577                 next if has_fast_array($e,$l);
1578                 next if is_charset_array($e,$l);
1579                 my $length = ParseExpr($l->{LENGTH_IS}, $env, $e->{ORIGINAL});
1580                 if ($length eq "0") {
1581                         warning($e->{ORIGINAL}, "pointless array cntr: 'cntr_$e->{NAME}_$l->{LEVEL_INDEX}': length=$length");
1582                 } else {
1583                         $self->pidl("uint32_t cntr_$e->{NAME}_$l->{LEVEL_INDEX};");
1584                 }
1585         }
1586 }
1587
1588 sub DeclareMemCtxVariables($$)
1589 {
1590         my ($self,$e) = @_;
1591         foreach my $l (@{$e->{LEVELS}}) {
1592                 my $mem_flags = $self->ParseMemCtxPullFlags($e, $l);
1593                 if (defined($mem_flags)) {
1594                         $self->pidl("TALLOC_CTX *_mem_save_$e->{NAME}_$l->{LEVEL_INDEX};");
1595                 }
1596         }
1597 }
1598
1599 sub ParseStructPullPrimitives($$$$$)
1600 {
1601         my($self,$struct,$ndr,$varname,$env) = @_;
1602
1603         if (defined $struct->{SURROUNDING_ELEMENT}) {
1604                 $self->pidl("NDR_CHECK(ndr_pull_array_size($ndr, &$varname->$struct->{SURROUNDING_ELEMENT}->{NAME}));");
1605         }
1606
1607         $self->pidl("NDR_CHECK(ndr_pull_align($ndr, $struct->{ALIGN}));");
1608
1609         if (defined($struct->{PROPERTIES}{relative_base})) {
1610                 # set the current offset as base for relative pointers
1611                 # and store it based on the toplevel struct/union
1612                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1613         }
1614
1615         $self->ParseElementPull($_, $ndr, $env, 1, 0) foreach (@{$struct->{ELEMENTS}});
1616
1617         $self->add_deferred();
1618
1619         $self->pidl("NDR_CHECK(ndr_pull_trailer_align($ndr, $struct->{ALIGN}));");
1620 }
1621
1622 sub ParseStructPullDeferred($$$$$)
1623 {
1624         my ($self,$struct,$ndr,$varname,$env) = @_;
1625
1626         if (defined($struct->{PROPERTIES}{relative_base})) {
1627                 # retrieve the current offset as base for relative pointers
1628                 # based on the toplevel struct/union
1629                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset2($ndr, $varname));");
1630         }
1631         foreach my $e (@{$struct->{ELEMENTS}}) {
1632                 $self->ParseElementPull($e, $ndr, $env, 0, 1);
1633         }
1634
1635         $self->add_deferred();
1636 }
1637
1638 #####################################################################
1639 # parse a struct - pull side
1640 sub ParseStructPull($$$$)
1641 {
1642         my($self,$struct,$ndr,$varname) = @_;
1643
1644         return unless defined $struct->{ELEMENTS};
1645
1646         # declare any internal pointers we need
1647         foreach my $e (@{$struct->{ELEMENTS}}) {
1648                 $self->DeclarePtrVariables($e);
1649                 $self->DeclareArrayVariables($e);
1650                 $self->DeclareMemCtxVariables($e);
1651         }
1652
1653         $self->start_flags($struct, $ndr);
1654
1655         my $env = GenerateStructEnv($struct, $varname);
1656
1657         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
1658         $self->indent;
1659         $self->ParseStructPullPrimitives($struct,$ndr,$varname,$env);
1660         $self->deindent;
1661         $self->pidl("}");
1662         $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
1663         $self->indent;
1664         $self->ParseStructPullDeferred($struct,$ndr,$varname,$env);
1665         $self->deindent;
1666         $self->pidl("}");
1667
1668         $self->end_flags($struct, $ndr);
1669 }
1670
1671 #####################################################################
1672 # calculate size of ndr struct
1673 sub ParseStructNdrSize($$$$)
1674 {
1675         my ($self,$t, $name, $varname) = @_;
1676         my $sizevar;
1677
1678         if (my $flags = has_property($t, "flag")) {
1679                 $self->pidl("flags |= $flags;");
1680         }
1681         $self->pidl("return ndr_size_struct($varname, flags, (ndr_push_flags_fn_t)ndr_push_$name);");
1682 }
1683
1684 sub DeclStruct($$$$)
1685 {
1686         my ($e,$t,$name,$varname) = @_;
1687         return ($t ne "pull"?"const ":"") . "struct $name *$varname";
1688 }
1689
1690 sub ArgsStructNdrSize($$$)
1691 {
1692         my ($d, $name, $varname) = @_;
1693         return "const struct $name *$varname, int flags";
1694 }
1695
1696 $typefamily{STRUCT} = {
1697         PUSH_FN_BODY => \&ParseStructPush,
1698         DECL => \&DeclStruct,
1699         PULL_FN_BODY => \&ParseStructPull,
1700         PRINT_FN_BODY => \&ParseStructPrint,
1701         SIZE_FN_BODY => \&ParseStructNdrSize,
1702         SIZE_FN_ARGS => \&ArgsStructNdrSize,
1703 };
1704
1705 #####################################################################
1706 # calculate size of ndr struct
1707 sub ParseUnionNdrSize($$$)
1708 {
1709         my ($self, $t, $name, $varname) = @_;
1710         my $sizevar;
1711
1712         if (my $flags = has_property($t, "flag")) {
1713                 $self->pidl("flags |= $flags;");
1714         }
1715
1716         $self->pidl("return ndr_size_union($varname, flags, level, (ndr_push_flags_fn_t)ndr_push_$name);");
1717 }
1718
1719 sub ParseUnionPushPrimitives($$$$)
1720 {
1721         my ($self, $e, $ndr ,$varname) = @_;
1722
1723         my $have_default = 0;
1724
1725         $self->pidl("uint32_t level = ndr_push_get_switch_value($ndr, $varname);");
1726
1727         if (defined($e->{SWITCH_TYPE})) {
1728                 if (defined($e->{ALIGN})) {
1729                         $self->pidl("NDR_CHECK(ndr_push_union_align($ndr, $e->{ALIGN}));");
1730                 }
1731
1732                 $self->pidl("NDR_CHECK(ndr_push_$e->{SWITCH_TYPE}($ndr, NDR_SCALARS, level));");
1733         }
1734
1735         if (defined($e->{ALIGN})) {
1736                 if ($e->{IS_MS_UNION}) {
1737                         $self->pidl("/* ms_union is always aligned to the largest union arm*/");
1738                         $self->pidl("NDR_CHECK(ndr_push_align($ndr, $e->{ALIGN}));");
1739                 } else {
1740                         $self->pidl("NDR_CHECK(ndr_push_union_align($ndr, $e->{ALIGN}));");
1741                 }
1742         }
1743
1744         $self->pidl("switch (level) {");
1745         $self->indent;
1746         foreach my $el (@{$e->{ELEMENTS}}) {
1747                 if ($el->{CASE} eq "default") {
1748                         $have_default = 1;
1749                 }
1750                 $self->pidl("$el->{CASE}: {");
1751
1752                 if ($el->{TYPE} ne "EMPTY") {
1753                         $self->indent;
1754                         if (defined($e->{PROPERTIES}{relative_base})) {
1755                                 $self->pidl("NDR_CHECK(ndr_push_align($ndr, $el->{ALIGN}));");
1756                                 # set the current offset as base for relative pointers
1757                                 # and store it based on the toplevel struct/union
1758                                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1759                         }
1760                         $self->DeclareArrayVariables($el);
1761                         $self->ParseElementPush($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 1, 0);
1762                         $self->deindent;
1763                 }
1764                 $self->pidl("break; }");
1765                 $self->pidl("");
1766         }
1767         if (! $have_default) {
1768                 $self->pidl("default:");
1769                 $self->pidl("\treturn ndr_push_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value \%u at \%s\", level, __location__);");
1770         }
1771         $self->deindent;
1772         $self->pidl("}");
1773 }
1774
1775 sub ParseUnionPushDeferred($$$$)
1776 {
1777         my ($self,$e,$ndr,$varname) = @_;
1778
1779         my $have_default = 0;
1780
1781         $self->pidl("uint32_t level = ndr_push_get_switch_value($ndr, $varname);");
1782         if (defined($e->{PROPERTIES}{relative_base})) {
1783                 # retrieve the current offset as base for relative pointers
1784                 # based on the toplevel struct/union
1785                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset2($ndr, $varname));");
1786         }
1787         $self->pidl("switch (level) {");
1788         $self->indent;
1789         foreach my $el (@{$e->{ELEMENTS}}) {
1790                 if ($el->{CASE} eq "default") {
1791                         $have_default = 1;
1792                 }
1793
1794                 $self->pidl("$el->{CASE}:");
1795                 if ($el->{TYPE} ne "EMPTY") {
1796                         $self->indent;
1797                         $self->ParseElementPush($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 0, 1);
1798                         $self->deindent;
1799                 }
1800                 $self->pidl("break;");
1801                 $self->pidl("");
1802         }
1803         if (! $have_default) {
1804                 $self->pidl("default:");
1805                 $self->pidl("\treturn ndr_push_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value \%u at \%s\", level, __location__);");
1806         }
1807         $self->deindent;
1808         $self->pidl("}");
1809 }
1810
1811 #####################################################################
1812 # parse a union - push side
1813 sub ParseUnionPush($$$$)
1814 {
1815         my ($self,$e,$ndr,$varname) = @_;
1816         my $have_default = 0;
1817
1818         $self->start_flags($e, $ndr);
1819
1820         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
1821         $self->indent;
1822         $self->ParseUnionPushPrimitives($e, $ndr, $varname);
1823         $self->deindent;
1824         $self->pidl("}");
1825         $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
1826         $self->indent;
1827         $self->ParseUnionPushDeferred($e, $ndr, $varname);
1828         $self->deindent;
1829         $self->pidl("}");
1830         $self->end_flags($e, $ndr);
1831 }
1832
1833 #####################################################################
1834 # print a union
1835 sub ParseUnionPrint($$$$$)
1836 {
1837         my ($self,$e,$ndr,$name,$varname) = @_;
1838         my $have_default = 0;
1839
1840         $self->pidl("uint32_t level;");
1841         foreach my $el (@{$e->{ELEMENTS}}) {
1842                 $self->DeclareArrayVariables($el);
1843         }
1844
1845         $self->start_flags($e, $ndr);
1846
1847         $self->pidl("level = ndr_print_get_switch_value($ndr, $varname);");
1848
1849         $self->pidl("ndr_print_union($ndr, name, level, \"$name\");");
1850
1851         $self->pidl("switch (level) {");
1852         $self->indent;
1853         foreach my $el (@{$e->{ELEMENTS}}) {
1854                 if ($el->{CASE} eq "default") {
1855                         $have_default = 1;
1856                 }
1857                 $self->pidl("$el->{CASE}:");
1858                 if ($el->{TYPE} ne "EMPTY") {
1859                         $self->indent;
1860                         $self->ParseElementPrint($el, $ndr, "$varname->$el->{NAME}", {});
1861                         $self->deindent;
1862                 }
1863                 $self->pidl("break;");
1864                 $self->pidl("");
1865         }
1866         if (! $have_default) {
1867                 $self->pidl("default:");
1868                 $self->pidl("\tndr_print_bad_level($ndr, name, level);");
1869         }
1870         $self->deindent;
1871         $self->pidl("}");
1872
1873         $self->end_flags($e, $ndr);
1874 }
1875
1876 sub ParseUnionPullPrimitives($$$$$)
1877 {
1878         my ($self,$e,$ndr,$varname,$switch_type) = @_;
1879         my $have_default = 0;
1880
1881
1882         if (defined($switch_type)) {
1883                 if (defined($e->{ALIGN})) {
1884                         $self->pidl("NDR_CHECK(ndr_pull_union_align($ndr, $e->{ALIGN}));");
1885                 }
1886
1887                 $self->pidl("NDR_CHECK(ndr_pull_$switch_type($ndr, NDR_SCALARS, &_level));");
1888                 $self->pidl("if (_level != level) {");
1889                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value %u for $varname at \%s\", _level, __location__);");
1890                 $self->pidl("}");
1891         }
1892
1893         if (defined($e->{ALIGN})) {
1894                 if ($e->{IS_MS_UNION}) {
1895                         $self->pidl("/* ms_union is always aligned to the largest union arm*/");
1896                         $self->pidl("NDR_CHECK(ndr_pull_align($ndr, $e->{ALIGN}));");
1897                 } else {
1898                         $self->pidl("NDR_CHECK(ndr_pull_union_align($ndr, $e->{ALIGN}));");
1899                 }
1900         }
1901
1902         $self->pidl("switch (level) {");
1903         $self->indent;
1904         foreach my $el (@{$e->{ELEMENTS}}) {
1905                 if ($el->{CASE} eq "default") {
1906                         $have_default = 1;
1907                 }
1908                 $self->pidl("$el->{CASE}: {");
1909
1910                 if ($el->{TYPE} ne "EMPTY") {
1911                         $self->indent;
1912                         if (defined($e->{PROPERTIES}{relative_base})) {
1913                                 $self->pidl("NDR_CHECK(ndr_pull_align($ndr, $el->{ALIGN}));");
1914                                 # set the current offset as base for relative pointers
1915                                 # and store it based on the toplevel struct/union
1916                                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1917                         }
1918                         $self->ParseElementPull($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 1, 0);
1919                         $self->deindent;
1920                 }
1921                 $self->pidl("break; }");
1922                 $self->pidl("");
1923         }
1924         if (! $have_default) {
1925                 $self->pidl("default:");
1926                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value \%u at \%s\", level, __location__);");
1927         }
1928         $self->deindent;
1929         $self->pidl("}");
1930 }
1931
1932 sub ParseUnionPullDeferred($$$$)
1933 {
1934         my ($self,$e,$ndr,$varname) = @_;
1935         my $have_default = 0;
1936
1937         if (defined($e->{PROPERTIES}{relative_base})) {
1938                 # retrieve the current offset as base for relative pointers
1939                 # based on the toplevel struct/union
1940                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset2($ndr, $varname));");
1941         }
1942         $self->pidl("switch (level) {");
1943         $self->indent;
1944         foreach my $el (@{$e->{ELEMENTS}}) {
1945                 if ($el->{CASE} eq "default") {
1946                         $have_default = 1;
1947                 }
1948
1949                 $self->pidl("$el->{CASE}:");
1950                 if ($el->{TYPE} ne "EMPTY") {
1951                         $self->indent;
1952                         $self->ParseElementPull($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 0, 1);
1953                         $self->deindent;
1954                 }
1955                 $self->pidl("break;");
1956                 $self->pidl("");
1957         }
1958         if (! $have_default) {
1959                 $self->pidl("default:");
1960                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value \%u at \%s\", level, __location__);");
1961         }
1962         $self->deindent;
1963         $self->pidl("}");
1964
1965
1966 }
1967
1968 #####################################################################
1969 # parse a union - pull side
1970 sub ParseUnionPull($$$$)
1971 {
1972         my ($self,$e,$ndr,$varname) = @_;
1973         my $switch_type = $e->{SWITCH_TYPE};
1974
1975         $self->pidl("uint32_t level;");
1976         if (defined($switch_type)) {
1977                 if (Parse::Pidl::Typelist::typeIs($switch_type, "ENUM")) {
1978                         $switch_type = Parse::Pidl::Typelist::enum_type_fn(getType($switch_type)->{DATA});
1979                 }
1980                 $self->pidl(mapTypeName($switch_type) . " _level;");
1981         }
1982
1983         my %double_cases = ();
1984         foreach my $el (@{$e->{ELEMENTS}}) {
1985                 next if ($el->{TYPE} eq "EMPTY");
1986                 next if ($double_cases{"$el->{NAME}"});
1987                 $self->DeclareMemCtxVariables($el);
1988                 $self->DeclarePtrVariables($el);
1989                 $self->DeclareArrayVariables($el);
1990                 $double_cases{"$el->{NAME}"} = 1;
1991         }
1992
1993         $self->start_flags($e, $ndr);
1994
1995         $self->pidl("level = ndr_pull_get_switch_value($ndr, $varname);");
1996
1997         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
1998         $self->indent;
1999         $self->ParseUnionPullPrimitives($e,$ndr,$varname,$switch_type);
2000         $self->deindent;
2001         $self->pidl("}");
2002
2003         $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
2004         $self->indent;
2005         $self->ParseUnionPullDeferred($e,$ndr,$varname);
2006         $self->deindent;
2007         $self->pidl("}");
2008
2009         $self->add_deferred();
2010
2011         $self->end_flags($e, $ndr);
2012 }
2013
2014 sub DeclUnion($$$$)
2015 {
2016         my ($e,$t,$name,$varname) = @_;
2017         return ($t ne "pull"?"const ":"") . "union $name *$varname";
2018 }
2019
2020 sub ArgsUnionNdrSize($$)
2021 {
2022         my ($d,$name) = @_;
2023         return "const union $name *r, uint32_t level, int flags";
2024 }
2025
2026 $typefamily{UNION} = {
2027         PUSH_FN_BODY => \&ParseUnionPush,
2028         DECL => \&DeclUnion,
2029         PULL_FN_BODY => \&ParseUnionPull,
2030         PRINT_FN_BODY => \&ParseUnionPrint,
2031         SIZE_FN_ARGS => \&ArgsUnionNdrSize,
2032         SIZE_FN_BODY => \&ParseUnionNdrSize,
2033 };
2034
2035 #####################################################################
2036 # parse a typedef - push side
2037 sub ParseTypedefPush($$$$)
2038 {
2039         my($self,$e,$ndr,$varname) = @_;
2040
2041         my $env;
2042
2043         $env->{$e->{NAME}} = $varname;
2044
2045         $self->ParseElementPushLevel($e, $e->{LEVELS}[0], $ndr, $varname, $env, 1, 1);
2046 }
2047
2048 #####################################################################
2049 # parse a typedef - pull side
2050 sub ParseTypedefPull($$$$)
2051 {
2052         my($self,$e,$ndr,$varname) = @_;
2053
2054         my $env;
2055
2056         $env->{$e->{NAME}} = $varname;
2057
2058         $self->ParseElementPullLevel($e, $e->{LEVELS}[0], $ndr, $varname, $env, 1, 1);
2059 }
2060
2061 #####################################################################
2062 # parse a typedef - print side
2063 sub ParseTypedefPrint($$$$$)
2064 {
2065         my($self,$e,$ndr,$name,$varname) = @_;
2066
2067         $typefamily{$e->{DATA}->{TYPE}}->{PRINT_FN_BODY}->($self, $e->{DATA}, $ndr, $name, $varname);
2068 }
2069
2070 #####################################################################
2071 ## calculate the size of a structure
2072 sub ParseTypedefNdrSize($$$$)
2073 {
2074         my($self,$t,$name,$varname) = @_;
2075
2076         $typefamily{$t->{DATA}->{TYPE}}->{SIZE_FN_BODY}->($self, $t->{DATA}, $name, $varname);
2077 }
2078
2079 sub DeclTypedef($$$$)
2080 {
2081         my ($e, $t, $name, $varname) = @_;
2082
2083         return $typefamily{$e->{DATA}->{TYPE}}->{DECL}->($e->{DATA}, $t, $name, $varname);
2084 }
2085
2086 sub ArgsTypedefNdrSize($$$)
2087 {
2088         my ($d, $name, $varname) = @_;
2089         return $typefamily{$d->{DATA}->{TYPE}}->{SIZE_FN_ARGS}->($d->{DATA}, $name, $varname);
2090 }
2091
2092 $typefamily{TYPEDEF} = {
2093         PUSH_FN_BODY => \&ParseTypedefPush,
2094         DECL => \&DeclTypedef,
2095         PULL_FN_BODY => \&ParseTypedefPull,
2096         PRINT_FN_BODY => \&ParseTypedefPrint,
2097         SIZE_FN_ARGS => \&ArgsTypedefNdrSize,
2098         SIZE_FN_BODY => \&ParseTypedefNdrSize,
2099 };
2100
2101 sub ParsePipePushChunk($$)
2102 {
2103         my ($self, $t) = @_;
2104
2105         my $pipe = $t;
2106         $pipe = $t->{DATA} if ($t->{TYPE} eq "TYPEDEF");
2107         my $struct = $pipe->{DATA};
2108
2109         my $name = "$struct->{NAME}";
2110         my $ndr = "ndr";
2111         my $varname = "r";
2112
2113         my $args = $typefamily{$struct->{TYPE}}->{DECL}->($struct, "push", $name, $varname);
2114
2115         $self->fn_declare("push", $struct, "enum ndr_err_code ndr_push_$name(struct ndr_push *$ndr, int ndr_flags, $args)") or return;
2116
2117         return if has_property($t, "nopush");
2118
2119         $self->pidl("{");
2120         $self->indent;
2121
2122         $self->ParseStructPush($struct, $ndr, $varname);
2123         $self->pidl("");
2124
2125         $self->pidl("NDR_CHECK(ndr_push_pipe_chunk_trailer(ndr, ndr_flags, $varname->count));");
2126         $self->pidl("");
2127
2128         $self->pidl("return NDR_ERR_SUCCESS;");
2129         $self->deindent;
2130         $self->pidl("}");
2131         $self->pidl("");
2132 }
2133
2134 sub ParsePipePullChunk($$)
2135 {
2136         my ($self, $t) = @_;
2137
2138         my $pipe = $t;
2139         $pipe = $t->{DATA} if ($t->{TYPE} eq "TYPEDEF");
2140         my $struct = $pipe->{DATA};
2141
2142         my $name = "$struct->{NAME}";
2143         my $ndr = "ndr";
2144         my $varname = "r";
2145
2146         my $args = $typefamily{$struct->{TYPE}}->{DECL}->($struct, "pull", $name, $varname);
2147
2148         $self->fn_declare("pull", $struct, "enum ndr_err_code ndr_pull_$name(struct ndr_pull *$ndr, int ndr_flags, $args)") or return;
2149
2150         return if has_property($struct, "nopull");
2151
2152         $self->pidl("{");
2153         $self->indent;
2154
2155         $self->ParseStructPull($struct, $ndr, $varname);
2156         $self->pidl("");
2157
2158         $self->pidl("NDR_CHECK(ndr_check_pipe_chunk_trailer($ndr, ndr_flags, $varname->count));");
2159         $self->pidl("");
2160
2161         $self->pidl("return NDR_ERR_SUCCESS;");
2162         $self->deindent;
2163         $self->pidl("}");
2164         $self->pidl("");
2165 }
2166
2167 sub ParsePipePrintChunk($$)
2168 {
2169         my ($self, $t) = @_;
2170
2171         my $pipe = $t;
2172         $pipe = $t->{DATA} if ($t->{TYPE} eq "TYPEDEF");
2173         my $struct = $pipe->{DATA};
2174
2175         my $name = "$struct->{NAME}";
2176         my $ndr = "ndr";
2177         my $varname = "r";
2178
2179         my $args = $typefamily{$struct->{TYPE}}->{DECL}->($struct, "print", $name, $varname);
2180
2181         $self->pidl_hdr("void ndr_print_$name(struct ndr_print *ndr, const char *name, $args);");
2182
2183         return if (has_property($t, "noprint"));
2184
2185         $self->pidl("_PUBLIC_ void ndr_print_$name(struct ndr_print *$ndr, const char *name, $args)");
2186         $self->pidl("{");
2187         $self->indent;
2188         $self->ParseTypePrint($struct, $ndr, $varname);
2189         $self->deindent;
2190         $self->pidl("}");
2191         $self->pidl("");
2192 }
2193
2194 #####################################################################
2195 # parse a function - print side
2196 sub ParseFunctionPrint($$)
2197 {
2198         my($self, $fn) = @_;
2199         my $ndr = "ndr";
2200
2201         $self->pidl_hdr("void ndr_print_$fn->{NAME}(struct ndr_print *$ndr, const char *name, int flags, const struct $fn->{NAME} *r);");
2202
2203         return if has_property($fn, "noprint");
2204
2205         $self->pidl("_PUBLIC_ void ndr_print_$fn->{NAME}(struct ndr_print *$ndr, const char *name, int flags, const struct $fn->{NAME} *r)");
2206         $self->pidl("{");
2207         $self->indent;
2208
2209         foreach my $e (@{$fn->{ELEMENTS}}) {
2210                 $self->DeclareArrayVariables($e);
2211         }
2212
2213         $self->pidl("ndr_print_struct($ndr, name, \"$fn->{NAME}\");");
2214         $self->pidl("if (r == NULL) { ndr_print_null($ndr); return; }");
2215         $self->pidl("$ndr->depth++;");
2216
2217         $self->pidl("if (flags & NDR_SET_VALUES) {");
2218         $self->pidl("\t$ndr->flags |= LIBNDR_PRINT_SET_VALUES;");
2219         $self->pidl("}");
2220
2221         $self->pidl("if (flags & NDR_IN) {");
2222         $self->indent;
2223         $self->pidl("ndr_print_struct($ndr, \"in\", \"$fn->{NAME}\");");
2224         $self->pidl("$ndr->depth++;");
2225
2226         my $env = GenerateFunctionInEnv($fn);
2227
2228         foreach my $e (@{$fn->{ELEMENTS}}) {
2229                 if (grep(/in/,@{$e->{DIRECTION}})) {
2230                         $self->ParseElementPrint($e, $ndr, $env->{$e->{NAME}}, $env);
2231                 }
2232         }
2233         $self->pidl("$ndr->depth--;");
2234         $self->deindent;
2235         $self->pidl("}");
2236
2237         $self->pidl("if (flags & NDR_OUT) {");
2238         $self->indent;
2239         $self->pidl("ndr_print_struct($ndr, \"out\", \"$fn->{NAME}\");");
2240         $self->pidl("$ndr->depth++;");
2241
2242         $env = GenerateFunctionOutEnv($fn);
2243         foreach my $e (@{$fn->{ELEMENTS}}) {
2244                 if (grep(/out/,@{$e->{DIRECTION}})) {
2245                         $self->ParseElementPrint($e, $ndr, $env->{$e->{NAME}}, $env);
2246                 }
2247         }
2248         if ($fn->{RETURN_TYPE}) {
2249                 $self->pidl("ndr_print_$fn->{RETURN_TYPE}($ndr, \"result\", r->out.result);");
2250         }
2251         $self->pidl("$ndr->depth--;");
2252         $self->deindent;
2253         $self->pidl("}");
2254
2255         $self->pidl("$ndr->depth--;");
2256         $self->deindent;
2257         $self->pidl("}");
2258         $self->pidl("");
2259 }
2260
2261 #####################################################################
2262 # parse a function
2263 sub ParseFunctionPush($$)
2264 {
2265         my($self, $fn) = @_;
2266         my $ndr = "ndr";
2267
2268         $self->fn_declare("push", $fn, "enum ndr_err_code ndr_push_$fn->{NAME}(struct ndr_push *$ndr, int flags, const struct $fn->{NAME} *r)") or return;
2269
2270         return if has_property($fn, "nopush");
2271
2272         $self->pidl("{");
2273         $self->indent;
2274
2275         foreach my $e (@{$fn->{ELEMENTS}}) {
2276                 $self->DeclareArrayVariables($e);
2277         }
2278
2279         $self->pidl("if (flags & NDR_IN) {");
2280         $self->indent;
2281
2282         my $env = GenerateFunctionInEnv($fn);
2283
2284         EnvSubstituteValue($env, $fn);
2285
2286         foreach my $e (@{$fn->{ELEMENTS}}) {
2287                 if (grep(/in/,@{$e->{DIRECTION}})) {
2288                         $self->ParseElementPush($e, $ndr, $env, 1, 1);
2289                 }
2290         }
2291
2292         $self->deindent;
2293         $self->pidl("}");
2294
2295         $self->pidl("if (flags & NDR_OUT) {");
2296         $self->indent;
2297
2298         $env = GenerateFunctionOutEnv($fn);
2299         foreach my $e (@{$fn->{ELEMENTS}}) {
2300                 if (grep(/out/,@{$e->{DIRECTION}})) {
2301                         $self->ParseElementPush($e, $ndr, $env, 1, 1);
2302                 }
2303         }
2304
2305         if ($fn->{RETURN_TYPE}) {
2306                 $self->pidl("NDR_CHECK(ndr_push_$fn->{RETURN_TYPE}($ndr, NDR_SCALARS, r->out.result));");
2307         }
2308
2309         $self->deindent;
2310         $self->pidl("}");
2311         $self->pidl("return NDR_ERR_SUCCESS;");
2312         $self->deindent;
2313         $self->pidl("}");
2314         $self->pidl("");
2315 }
2316
2317 sub AllocateArrayLevel($$$$$$)
2318 {
2319         my ($self,$e,$l,$ndr,$var,$size) = @_;
2320
2321         my $pl = GetPrevLevel($e, $l);
2322         if (defined($pl) and
2323             $pl->{TYPE} eq "POINTER" and
2324             $pl->{POINTER_TYPE} eq "ref"
2325             and not $l->{IS_ZERO_TERMINATED}) {
2326                 $self->pidl("if ($ndr->flags & LIBNDR_FLAG_REF_ALLOC) {");
2327                 $self->pidl("\tNDR_PULL_ALLOC_N($ndr, $var, $size);");
2328                 $self->pidl("}");
2329                 if (grep(/in/,@{$e->{DIRECTION}}) and
2330                     grep(/out/,@{$e->{DIRECTION}})) {
2331                         $self->pidl("memcpy(r->out.$e->{NAME}, r->in.$e->{NAME}, ($size) * sizeof(*r->in.$e->{NAME}));");
2332                 }
2333                 return;
2334         }
2335
2336         $self->pidl("NDR_PULL_ALLOC_N($ndr, $var, $size);");
2337 }
2338
2339 #####################################################################
2340 # parse a function
2341 sub ParseFunctionPull($$)
2342 {
2343         my($self,$fn) = @_;
2344         my $ndr = "ndr";
2345
2346         # pull function args
2347         $self->fn_declare("pull", $fn, "enum ndr_err_code ndr_pull_$fn->{NAME}(struct ndr_pull *$ndr, int flags, struct $fn->{NAME} *r)") or return;
2348
2349         $self->pidl("{");
2350         $self->indent;
2351
2352         # declare any internal pointers we need
2353         foreach my $e (@{$fn->{ELEMENTS}}) {
2354                 $self->DeclarePtrVariables($e);
2355                 $self->DeclareArrayVariables($e);
2356         }
2357
2358         my %double_cases = ();
2359         foreach my $e (@{$fn->{ELEMENTS}}) {
2360                 next if ($e->{TYPE} eq "EMPTY");
2361                 next if ($double_cases{"$e->{NAME}"});
2362                 $self->DeclareMemCtxVariables($e);
2363                 $double_cases{"$e->{NAME}"} = 1;
2364         }
2365
2366         $self->pidl("if (flags & NDR_IN) {");
2367         $self->indent;
2368
2369         # auto-init the out section of a structure. I originally argued that
2370         # this was a bad idea as it hides bugs, but coping correctly
2371         # with initialisation and not wiping ref vars is turning
2372         # out to be too tricky (tridge)
2373         foreach my $e (@{$fn->{ELEMENTS}}) {
2374                 next unless grep(/out/, @{$e->{DIRECTION}});
2375                 $self->pidl("ZERO_STRUCT(r->out);");
2376                 $self->pidl("");
2377                 last;
2378         }
2379
2380         my $env = GenerateFunctionInEnv($fn);
2381
2382         foreach my $e (@{$fn->{ELEMENTS}}) {
2383                 next unless (grep(/in/, @{$e->{DIRECTION}}));
2384                 $self->ParseElementPull($e, $ndr, $env, 1, 1);
2385         }
2386
2387         # allocate the "simple" out ref variables. FIXME: Shouldn't this have it's
2388         # own flag rather than be in NDR_IN ?
2389
2390         foreach my $e (@{$fn->{ELEMENTS}}) {
2391                 next unless (grep(/out/, @{$e->{DIRECTION}}));
2392                 next unless ($e->{LEVELS}[0]->{TYPE} eq "POINTER" and
2393                              $e->{LEVELS}[0]->{POINTER_TYPE} eq "ref");
2394                 next if (($e->{LEVELS}[1]->{TYPE} eq "DATA") and
2395                                  ($e->{LEVELS}[1]->{DATA_TYPE} eq "string"));
2396                 next if ($e->{LEVELS}[1]->{TYPE} eq "PIPE");
2397                 next if (($e->{LEVELS}[1]->{TYPE} eq "ARRAY")
2398                         and   $e->{LEVELS}[1]->{IS_ZERO_TERMINATED});
2399
2400                 if ($e->{LEVELS}[1]->{TYPE} eq "ARRAY") {
2401                         my $size = ParseExprExt($e->{LEVELS}[1]->{SIZE_IS}, $env, $e->{ORIGINAL},
2402                                 check_null_pointer($e, $env, sub { $self->pidl(shift); },
2403                                                    "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for size_is()\");"),
2404                                 check_fully_dereferenced($e, $env));
2405                         $self->pidl("NDR_PULL_ALLOC_N($ndr, r->out.$e->{NAME}, $size);");
2406
2407                         if (grep(/in/, @{$e->{DIRECTION}})) {
2408                                 $self->pidl("memcpy(r->out.$e->{NAME}, r->in.$e->{NAME}, ($size) * sizeof(*r->in.$e->{NAME}));");
2409                         } else {
2410                                 $self->pidl("memset(r->out.$e->{NAME}, 0, ($size) * sizeof(*r->out.$e->{NAME}));");
2411                         }
2412                 } elsif ($e->{LEVELS}[1]->{TYPE} eq "ARRAY") {
2413                         if (grep(/in/, @{$e->{DIRECTION}})) {
2414                                 $self->pidl("r->out.$e->{NAME} = r->in.$e->{NAME};");
2415                         } else {
2416                                 $self->pidl("r->out.$e->{NAME} = NULL;");
2417                         }
2418                 } else {
2419                         $self->pidl("NDR_PULL_ALLOC($ndr, r->out.$e->{NAME});");
2420
2421                         if (grep(/in/, @{$e->{DIRECTION}})) {
2422                                 $self->pidl("*r->out.$e->{NAME} = *r->in.$e->{NAME};");
2423                         } else {
2424                                 $self->pidl("ZERO_STRUCTP(r->out.$e->{NAME});");
2425                         }
2426                 }
2427         }
2428
2429         $self->add_deferred();
2430         $self->deindent;
2431         $self->pidl("}");
2432
2433         $self->pidl("if (flags & NDR_OUT) {");
2434         $self->indent;
2435
2436         $env = GenerateFunctionOutEnv($fn);
2437         foreach my $e (@{$fn->{ELEMENTS}}) {
2438                 next unless grep(/out/, @{$e->{DIRECTION}});
2439                 $self->ParseElementPull($e, $ndr, $env, 1, 1);
2440         }
2441
2442         if ($fn->{RETURN_TYPE}) {
2443                 $self->pidl("NDR_CHECK(ndr_pull_$fn->{RETURN_TYPE}($ndr, NDR_SCALARS, &r->out.result));");
2444         }
2445
2446         $self->add_deferred();
2447         $self->deindent;
2448         $self->pidl("}");
2449
2450         $self->pidl("return NDR_ERR_SUCCESS;");
2451         $self->deindent;
2452         $self->pidl("}");
2453         $self->pidl("");
2454 }
2455
2456 sub AuthServiceStruct($$$)
2457 {
2458         my ($self, $ifacename, $authservice) = @_;
2459         my @a = split /,/, $authservice;
2460         my $authservice_count = $#a + 1;
2461
2462         $self->pidl("static const char * const $ifacename\_authservice_strings[] = {");
2463         foreach my $ap (@a) {
2464                 $self->pidl("\t$ap, ");
2465         }
2466         $self->pidl("};");
2467         $self->pidl("");
2468
2469         $self->pidl("static const struct ndr_interface_string_array $ifacename\_authservices = {");
2470         $self->pidl("\t.count\t= $authservice_count,");
2471         $self->pidl("\t.names\t= $ifacename\_authservice_strings");
2472         $self->pidl("};");
2473         $self->pidl("");
2474 }
2475
2476 sub ParseGeneratePipeArray($$$)
2477 {
2478         my ($self, $fn, $direction) = @_;
2479
2480         $self->pidl("static const struct ndr_interface_call_pipe $fn->{NAME}\_$direction\_pipes[] = {");
2481         $self->indent;
2482
2483         foreach my $e (@{$fn->{ELEMENTS}}) {
2484                 next unless ContainsPipe($e, $e->{LEVELS}[0]);
2485                 next unless (grep(/$direction/, @{$e->{DIRECTION}}));
2486
2487                 my $cname = "$e->{TYPE}_chunk";
2488
2489                 $self->pidl("{");
2490                 $self->indent;
2491                 $self->pidl("\"$direction.$e->{NAME}\",");
2492                 $self->pidl("\"$cname\",");
2493                 $self->pidl("sizeof(struct $cname),");
2494                 $self->pidl("(ndr_push_flags_fn_t) ndr_push_$cname,");
2495                 $self->pidl("(ndr_pull_flags_fn_t) ndr_pull_$cname,");
2496                 $self->pidl("(ndr_print_fn_t) ndr_print_$cname,");
2497                 $self->deindent;
2498                 $self->pidl("},");
2499         }
2500         $self->pidl("{ NULL, NULL, 0, NULL, NULL, NULL }");
2501         $self->deindent;
2502         $self->pidl("};");
2503         $self->pidl("");
2504 }
2505
2506 sub FunctionCallPipes($$)
2507 {
2508         my ($self, $d) = @_;
2509         return if not defined($d->{OPNUM});
2510
2511         my $in_pipes = 0;
2512         my $out_pipes = 0;
2513
2514         foreach my $e (@{$d->{ELEMENTS}}) {
2515                 next unless ContainsPipe($e, $e->{LEVELS}[0]);
2516
2517                 if (grep(/in/, @{$e->{DIRECTION}})) {
2518                         $in_pipes++;
2519                 }
2520                 if (grep(/out/, @{$e->{DIRECTION}})) {
2521                         $out_pipes++;
2522                 }
2523         }
2524
2525         if ($in_pipes) {
2526                 $self->ParseGeneratePipeArray($d, "in");
2527         }
2528
2529         if ($out_pipes) {
2530                 $self->ParseGeneratePipeArray($d, "out");
2531         }
2532 }
2533
2534 sub FunctionCallEntry($$)
2535 {
2536         my ($self, $d) = @_;
2537         return 0 if not defined($d->{OPNUM});
2538
2539         my $in_pipes = 0;
2540         my $out_pipes = 0;
2541
2542         foreach my $e (@{$d->{ELEMENTS}}) {
2543                 next unless ContainsPipe($e, $e->{LEVELS}[0]);
2544
2545                 if (grep(/in/, @{$e->{DIRECTION}})) {
2546                         $in_pipes++;
2547                 }
2548                 if (grep(/out/, @{$e->{DIRECTION}})) {
2549                         $out_pipes++;
2550                 }
2551         }
2552
2553         my $in_pipes_ptr = "NULL";
2554         my $out_pipes_ptr = "NULL";
2555
2556         if ($in_pipes) {
2557                 $in_pipes_ptr = "$d->{NAME}_in_pipes";
2558         }
2559
2560         if ($out_pipes) {
2561                 $out_pipes_ptr = "$d->{NAME}_out_pipes";
2562         }
2563
2564         $self->pidl("\t{");
2565         $self->pidl("\t\t\"$d->{NAME}\",");
2566         $self->pidl("\t\tsizeof(struct $d->{NAME}),");
2567         $self->pidl("\t\t(ndr_push_flags_fn_t) ndr_push_$d->{NAME},");
2568         $self->pidl("\t\t(ndr_pull_flags_fn_t) ndr_pull_$d->{NAME},");
2569         $self->pidl("\t\t(ndr_print_function_t) ndr_print_$d->{NAME},");
2570         $self->pidl("\t\t{ $in_pipes, $in_pipes_ptr },");
2571         $self->pidl("\t\t{ $out_pipes, $out_pipes_ptr },");
2572         $self->pidl("\t},");
2573         return 1;
2574 }
2575
2576 #####################################################################
2577 # produce a function call table
2578 sub FunctionTable($$)
2579 {
2580         my($self,$interface) = @_;
2581         my $count = 0;
2582         my $uname = uc $interface->{NAME};
2583
2584         return if ($#{$interface->{FUNCTIONS}}+1 == 0);
2585         return unless defined ($interface->{PROPERTIES}->{uuid});
2586
2587         foreach my $d (@{$interface->{INHERITED_FUNCTIONS}},@{$interface->{FUNCTIONS}}) {
2588                 $self->FunctionCallPipes($d);
2589         }
2590
2591         $self->pidl("static const struct ndr_interface_call $interface->{NAME}\_calls[] = {");
2592
2593         foreach my $d (@{$interface->{INHERITED_FUNCTIONS}},@{$interface->{FUNCTIONS}}) {
2594                 $count += $self->FunctionCallEntry($d);
2595         }
2596         $self->pidl("\t{ NULL, 0, NULL, NULL, NULL }");
2597         $self->pidl("};");
2598         $self->pidl("");
2599
2600         $self->pidl("static const char * const $interface->{NAME}\_endpoint_strings[] = {");
2601         foreach my $ep (@{$interface->{ENDPOINTS}}) {
2602                 $self->pidl("\t$ep, ");
2603         }
2604         my $endpoint_count = $#{$interface->{ENDPOINTS}}+1;
2605
2606         $self->pidl("};");
2607         $self->pidl("");
2608
2609         $self->pidl("static const struct ndr_interface_string_array $interface->{NAME}\_endpoints = {");
2610         $self->pidl("\t.count\t= $endpoint_count,");
2611         $self->pidl("\t.names\t= $interface->{NAME}\_endpoint_strings");
2612         $self->pidl("};");
2613         $self->pidl("");
2614
2615         if (! defined $interface->{PROPERTIES}->{authservice}) {
2616                 $interface->{PROPERTIES}->{authservice} = "\"host\"";
2617         }
2618
2619         $self->AuthServiceStruct($interface->{NAME},
2620                                      $interface->{PROPERTIES}->{authservice});
2621
2622         $self->pidl("\nconst struct ndr_interface_table ndr_table_$interface->{NAME} = {");
2623         $self->pidl("\t.name\t\t= \"$interface->{NAME}\",");
2624         $self->pidl("\t.syntax_id\t= {");
2625         $self->pidl("\t\t" . print_uuid($interface->{UUID}) .",");
2626         $self->pidl("\t\tNDR_$uname\_VERSION");
2627         $self->pidl("\t},");
2628         $self->pidl("\t.helpstring\t= NDR_$uname\_HELPSTRING,");
2629         $self->pidl("\t.num_calls\t= $count,");
2630         $self->pidl("\t.calls\t\t= $interface->{NAME}\_calls,");
2631         $self->pidl("\t.endpoints\t= &$interface->{NAME}\_endpoints,");
2632         $self->pidl("\t.authservices\t= &$interface->{NAME}\_authservices");
2633         $self->pidl("};");
2634         $self->pidl("");
2635
2636 }
2637
2638 #####################################################################
2639 # generate include statements for imported idl files
2640 sub HeaderImport
2641 {
2642         my $self = shift;
2643         my @imports = @_;
2644         foreach (@imports) {
2645                 $_ = unmake_str($_);
2646                 s/\.idl$//;
2647                 $self->pidl(choose_header("librpc/gen_ndr/ndr_$_\.h", "gen_ndr/ndr_$_.h"));
2648         }
2649 }
2650
2651 #####################################################################
2652 # generate include statements for included header files
2653 sub HeaderInclude
2654 {
2655         my $self = shift;
2656         my @includes = @_;
2657         foreach (@includes) {
2658                 $self->pidl_hdr("#include $_");
2659         }
2660 }
2661
2662 #####################################################################
2663 # generate prototypes and defines for the interface definitions
2664 # FIXME: these prototypes are for the DCE/RPC client functions, not the
2665 # NDR parser and so do not belong here, technically speaking
2666 sub HeaderInterface($$$)
2667 {
2668         my($self,$interface,$needed) = @_;
2669
2670         my $count = 0;
2671
2672         if ($needed->{"compression"}) {
2673                 $self->pidl(choose_header("librpc/ndr/ndr_compression.h", "ndr/compression.h"));
2674         }
2675
2676         if (has_property($interface, "object")) {
2677                 $self->pidl(choose_header("librpc/gen_ndr/ndr_orpc.h", "ndr/orpc.h"));
2678         }
2679
2680         if (defined $interface->{PROPERTIES}->{helper}) {
2681                 $self->HeaderInclude(split /,/, $interface->{PROPERTIES}->{helper});
2682         }
2683
2684         if (defined $interface->{PROPERTIES}->{uuid}) {
2685                 my $name = uc $interface->{NAME};
2686                 $self->pidl_hdr("#define NDR_$name\_UUID " .
2687                 Parse::Pidl::Util::make_str(lc($interface->{PROPERTIES}->{uuid})));
2688
2689                 if(!defined $interface->{PROPERTIES}->{version}) { $interface->{PROPERTIES}->{version} = "0.0"; }
2690                 $self->pidl_hdr("#define NDR_$name\_VERSION $interface->{PROPERTIES}->{version}");
2691
2692                 $self->pidl_hdr("#define NDR_$name\_NAME \"$interface->{NAME}\"");
2693
2694                 if(!defined $interface->{PROPERTIES}->{helpstring}) { $interface->{PROPERTIES}->{helpstring} = "NULL"; }
2695                 $self->pidl_hdr("#define NDR_$name\_HELPSTRING $interface->{PROPERTIES}->{helpstring}");
2696
2697                 $self->pidl_hdr("extern const struct ndr_interface_table ndr_table_$interface->{NAME};");
2698         }
2699
2700         foreach (@{$interface->{FUNCTIONS}}) {
2701                 next if has_property($_, "noopnum");
2702                 next if grep(/^$_->{NAME}$/,@{$interface->{INHERITED_FUNCTIONS}});
2703                 my $u_name = uc $_->{NAME};
2704
2705                 my $val = sprintf("0x%02x", $count);
2706                 if (defined($interface->{BASE})) {
2707                         $val .= " + NDR_" . uc $interface->{BASE} . "_CALL_COUNT";
2708                 }
2709
2710                 $self->pidl_hdr("#define NDR_$u_name ($val)");
2711
2712                 $self->pidl_hdr("");
2713                 $count++;
2714         }
2715
2716         my $val = $count;
2717
2718         if (defined($interface->{BASE})) {
2719                 $val .= " + NDR_" . uc $interface->{BASE} . "_CALL_COUNT";
2720         }
2721
2722         $self->pidl_hdr("#define NDR_" . uc $interface->{NAME} . "_CALL_COUNT ($val)");
2723
2724 }
2725
2726 sub ParseTypePush($$$$$$)
2727 {
2728         my ($self,$e, $ndr, $varname, $primitives, $deferred) = @_;
2729
2730         # save the old relative_base_offset
2731         $self->pidl("uint32_t _save_relative_base_offset = ndr_push_get_relative_base_offset($ndr);") if defined(has_property($e, "relative_base"));
2732         $typefamily{$e->{TYPE}}->{PUSH_FN_BODY}->($self, $e, $ndr, $varname);
2733         # restore the old relative_base_offset
2734         $self->pidl("ndr_push_restore_relative_base_offset($ndr, _save_relative_base_offset);") if defined(has_property($e, "relative_base"));
2735 }
2736
2737 sub ParseTypePushFunction($$$)
2738 {
2739         my ($self, $e, $varname) = @_;
2740         my $ndr = "ndr";
2741
2742         my $args = $typefamily{$e->{TYPE}}->{DECL}->($e, "push", $e->{NAME}, $varname);
2743
2744         $self->fn_declare("push", $e, "enum ndr_err_code ".TypeFunctionName("ndr_push", $e)."(struct ndr_push *$ndr, int ndr_flags, $args)") or return;
2745
2746         $self->pidl("{");
2747         $self->indent;
2748         $self->ParseTypePush($e, $ndr, $varname, 1, 1);
2749         $self->pidl("return NDR_ERR_SUCCESS;");
2750         $self->deindent;
2751         $self->pidl("}");
2752         $self->pidl("");;
2753 }
2754
2755 sub ParseTypePull($$$$$$)
2756 {
2757         my ($self, $e, $ndr, $varname, $primitives, $deferred) = @_;
2758
2759         # save the old relative_base_offset
2760         $self->pidl("uint32_t _save_relative_base_offset = ndr_pull_get_relative_base_offset($ndr);") if defined(has_property($e, "relative_base"));
2761         $typefamily{$e->{TYPE}}->{PULL_FN_BODY}->($self, $e, $ndr, $varname);
2762         # restore the old relative_base_offset
2763         $self->pidl("ndr_pull_restore_relative_base_offset($ndr, _save_relative_base_offset);") if defined(has_property($e, "relative_base"));
2764 }
2765
2766 sub ParseTypePullFunction($$)
2767 {
2768         my ($self, $e, $varname) = @_;
2769         my $ndr = "ndr";
2770
2771         my $args = $typefamily{$e->{TYPE}}->{DECL}->($e, "pull", $e->{NAME}, $varname);
2772
2773         $self->fn_declare("pull", $e, "enum ndr_err_code ".TypeFunctionName("ndr_pull", $e)."(struct ndr_pull *$ndr, int ndr_flags, $args)") or return;
2774
2775         $self->pidl("{");
2776         $self->indent;
2777         $self->ParseTypePull($e, $ndr, $varname, 1, 1);
2778         $self->pidl("return NDR_ERR_SUCCESS;");
2779         $self->deindent;
2780         $self->pidl("}");
2781         $self->pidl("");
2782 }
2783
2784 sub ParseTypePrint($$$$)
2785 {
2786         my ($self, $e, $ndr, $varname) = @_;
2787
2788         $typefamily{$e->{TYPE}}->{PRINT_FN_BODY}->($self, $e, $ndr, $e->{NAME}, $varname);
2789 }
2790
2791 sub ParseTypePrintFunction($$$)
2792 {
2793         my ($self, $e, $varname) = @_;
2794         my $ndr = "ndr";
2795
2796         my $args = $typefamily{$e->{TYPE}}->{DECL}->($e, "print", $e->{NAME}, $varname);
2797
2798         $self->pidl_hdr("void ".TypeFunctionName("ndr_print", $e)."(struct ndr_print *ndr, const char *name, $args);");
2799
2800         return if (has_property($e, "noprint"));
2801
2802         $self->pidl("_PUBLIC_ void ".TypeFunctionName("ndr_print", $e)."(struct ndr_print *$ndr, const char *name, $args)");
2803         $self->pidl("{");
2804         $self->indent;
2805         $self->ParseTypePrint($e, $ndr, $varname);
2806         $self->deindent;
2807         $self->pidl("}");
2808         $self->pidl("");
2809 }
2810
2811 sub ParseTypeNdrSize($$)
2812 {
2813         my ($self,$t) = @_;
2814
2815         my $varname = "r";
2816         my $tf = $typefamily{$t->{TYPE}};
2817         my $args = $tf->{SIZE_FN_ARGS}->($t, $t->{NAME}, $varname);
2818
2819         $self->fn_declare("size", $t, "size_t ndr_size_$t->{NAME}($args)") or return;
2820
2821         $self->pidl("{");
2822         $self->indent;
2823         $typefamily{$t->{TYPE}}->{SIZE_FN_BODY}->($self,$t, $t->{NAME}, $varname);
2824         $self->deindent;
2825         $self->pidl("}");
2826         $self->pidl("");
2827 }
2828
2829 #####################################################################
2830 # parse the interface definitions
2831 sub ParseInterface($$$)
2832 {
2833         my($self,$interface,$needed) = @_;
2834
2835         $self->pidl_hdr("#ifndef _HEADER_NDR_$interface->{NAME}");
2836         $self->pidl_hdr("#define _HEADER_NDR_$interface->{NAME}");
2837
2838         $self->pidl_hdr("");
2839
2840         $self->HeaderInterface($interface, $needed);
2841
2842         # Typedefs
2843         foreach my $d (@{$interface->{TYPES}}) {
2844                 if (Parse::Pidl::Typelist::typeIs($d, "PIPE")) {
2845                         ($needed->{TypeFunctionName("ndr_push", $d)}) &&
2846                                 $self->ParsePipePushChunk($d);
2847                         ($needed->{TypeFunctionName("ndr_pull", $d)}) &&
2848                                 $self->ParsePipePullChunk($d);
2849                         ($needed->{TypeFunctionName("ndr_print", $d)}) &&
2850                                 $self->ParsePipePrintChunk($d);
2851
2852                         $needed->{TypeFunctionName("ndr_pull", $d)} = 0;
2853                         $needed->{TypeFunctionName("ndr_push", $d)} = 0;
2854                         $needed->{TypeFunctionName("ndr_print", $d)} = 0;
2855                         next;
2856                 }
2857
2858                 next unless(typeHasBody($d));
2859
2860                 ($needed->{TypeFunctionName("ndr_push", $d)}) && $self->ParseTypePushFunction($d, "r");
2861                 ($needed->{TypeFunctionName("ndr_pull", $d)}) && $self->ParseTypePullFunction($d, "r");
2862                 ($needed->{TypeFunctionName("ndr_print", $d)}) && $self->ParseTypePrintFunction($d, "r");
2863
2864                 # Make sure we don't generate a function twice...
2865                 $needed->{TypeFunctionName("ndr_push", $d)} =
2866                     $needed->{TypeFunctionName("ndr_pull", $d)} =
2867                         $needed->{TypeFunctionName("ndr_print", $d)} = 0;
2868
2869                 ($needed->{"ndr_size_$d->{NAME}"}) && $self->ParseTypeNdrSize($d);
2870         }
2871
2872         # Functions
2873         foreach my $d (@{$interface->{FUNCTIONS}}) {
2874                 ($needed->{"ndr_push_$d->{NAME}"}) && $self->ParseFunctionPush($d);
2875                 ($needed->{"ndr_pull_$d->{NAME}"}) && $self->ParseFunctionPull($d);
2876                 ($needed->{"ndr_print_$d->{NAME}"}) && $self->ParseFunctionPrint($d);
2877         }
2878
2879         $self->FunctionTable($interface);
2880
2881         $self->pidl_hdr("#endif /* _HEADER_NDR_$interface->{NAME} */");
2882 }
2883
2884 sub GenerateIncludes($)
2885 {
2886         my ($self) = @_;
2887         if (is_intree()) {
2888                 $self->pidl("#include \"includes.h\"");
2889         } else {
2890                 $self->pidl("#ifndef _GNU_SOURCE");
2891                 $self->pidl("#define _GNU_SOURCE");
2892                 $self->pidl("#endif");
2893                 $self->pidl("#include <stdint.h>");
2894                 $self->pidl("#include <stdlib.h>");
2895                 $self->pidl("#include <stdio.h>");
2896                 $self->pidl("#include <stdbool.h>");
2897                 $self->pidl("#include <stdarg.h>");
2898                 $self->pidl("#include <string.h>");
2899         }
2900 }
2901
2902 #####################################################################
2903 # parse a parsed IDL structure back into an IDL file
2904 sub Parse($$$$)
2905 {
2906         my($self, $ndr,$gen_header,$ndr_header) = @_;
2907
2908         $self->pidl_hdr("/* header auto-generated by pidl */");
2909         $self->pidl_hdr("");
2910         $self->pidl_hdr(choose_header("librpc/ndr/libndr.h", "ndr.h"));
2911         $self->pidl_hdr("#include \"$gen_header\"") if ($gen_header);
2912         $self->pidl_hdr("");
2913
2914         $self->pidl("/* parser auto-generated by pidl */");
2915         $self->pidl("");
2916         $self->GenerateIncludes();
2917         $self->pidl("#include \"$ndr_header\"") if ($ndr_header);
2918         $self->pidl("");
2919
2920         my %needed = ();
2921
2922         foreach (@{$ndr}) {
2923                 ($_->{TYPE} eq "INTERFACE") && NeededInterface($_, \%needed);
2924         }
2925
2926         foreach (@{$ndr}) {
2927                 ($_->{TYPE} eq "INTERFACE") && $self->ParseInterface($_, \%needed);
2928                 ($_->{TYPE} eq "IMPORT") && $self->HeaderImport(@{$_->{PATHS}});
2929                 ($_->{TYPE} eq "INCLUDE") && $self->HeaderInclude(@{$_->{PATHS}});
2930         }
2931
2932         return ($self->{res_hdr}, $self->{res});
2933 }
2934
2935 sub NeededElement($$$)
2936 {
2937         my ($e, $dir, $needed) = @_;
2938
2939         return if ($e->{TYPE} eq "EMPTY");
2940
2941         return if (ref($e->{TYPE}) eq "HASH" and
2942                        not defined($e->{TYPE}->{NAME}));
2943
2944         my ($t, $rt);
2945         if (ref($e->{TYPE}) eq "HASH") {
2946                 $t = $e->{TYPE}->{TYPE}."_".$e->{TYPE}->{NAME};
2947         } else {
2948                 $t = $e->{TYPE};
2949         }
2950
2951         if (ref($e->{REPRESENTATION_TYPE}) eq "HASH") {
2952                 $rt = $e->{REPRESENTATION_TYPE}->{TYPE}."_".$e->{REPRESENTATION_TYPE}->{NAME};
2953         } else {
2954                 $rt = $e->{REPRESENTATION_TYPE};
2955         }
2956
2957         die ("$e->{NAME} $t, $rt FOO") unless ($rt ne "");
2958
2959         my @fn = ();
2960         if ($dir eq "print") {
2961                 push(@fn, TypeFunctionName("ndr_print", $e->{REPRESENTATION_TYPE}));
2962         } elsif ($dir eq "pull") {
2963                 push (@fn, TypeFunctionName("ndr_pull", $e->{TYPE}));
2964                 push (@fn, "ndr_$t\_to_$rt")
2965                         if ($rt ne $t);
2966         } elsif ($dir eq "push") {
2967                 push (@fn, TypeFunctionName("ndr_push", $e->{TYPE}));
2968                 push (@fn, "ndr_$rt\_to_$t")
2969                         if ($rt ne $t);
2970         } else {
2971                 die("invalid direction `$dir'");
2972         }
2973
2974         foreach (@fn) {
2975                 unless (defined($needed->{$_})) {
2976                         $needed->{$_} = 1;
2977                 }
2978         }
2979 }
2980
2981 sub NeededFunction($$)
2982 {
2983         my ($fn,$needed) = @_;
2984         $needed->{"ndr_pull_$fn->{NAME}"} = 1;
2985         $needed->{"ndr_push_$fn->{NAME}"} = 1;
2986         $needed->{"ndr_print_$fn->{NAME}"} = 1;
2987         foreach my $e (@{$fn->{ELEMENTS}}) {
2988                 $e->{PARENT} = $fn;
2989                 NeededElement($e, $_, $needed) foreach ("pull", "push", "print");
2990         }
2991 }
2992
2993 sub NeededType($$$)
2994 {
2995         sub NeededType($$$);
2996         my ($t,$needed,$req) = @_;
2997
2998         NeededType($t->{DATA}, $needed, $req) if ($t->{TYPE} eq "TYPEDEF");
2999         NeededType($t->{DATA}, $needed, $req) if ($t->{TYPE} eq "PIPE");
3000
3001         if ($t->{TYPE} eq "STRUCT" or $t->{TYPE} eq "UNION") {
3002                 return unless defined($t->{ELEMENTS});
3003                 for my $e (@{$t->{ELEMENTS}}) {
3004                         $e->{PARENT} = $t;
3005                         if (has_property($e, "compression")) {
3006                                 $needed->{"compression"} = 1;
3007                         }
3008                         NeededElement($e, $req, $needed);
3009                         NeededType($e->{TYPE}, $needed, $req) if (ref($e->{TYPE}) eq "HASH");
3010                 }
3011         }
3012 }
3013
3014 #####################################################################
3015 # work out what parse functions are needed
3016 sub NeededInterface($$)
3017 {
3018         my ($interface,$needed) = @_;
3019         NeededFunction($_, $needed) foreach (@{$interface->{FUNCTIONS}});
3020         foreach (reverse @{$interface->{TYPES}}) {
3021
3022                 if (has_property($_, "public")) {
3023                         $needed->{TypeFunctionName("ndr_pull", $_)} = $needed->{TypeFunctionName("ndr_push", $_)} =
3024                                 $needed->{TypeFunctionName("ndr_print", $_)} = 1;
3025                 }
3026
3027                 NeededType($_, $needed, "pull") if ($needed->{TypeFunctionName("ndr_pull", $_)});
3028                 NeededType($_, $needed, "push") if ($needed->{TypeFunctionName("ndr_push", $_)});
3029                 NeededType($_, $needed, "print") if ($needed->{TypeFunctionName("ndr_print", $_)});
3030                 if (has_property($_, "gensize")) {
3031                         $needed->{"ndr_size_$_->{NAME}"} = 1;
3032                 }
3033         }
3034 }
3035
3036 sub TypeFunctionName($$)
3037 {
3038         my ($prefix, $t) = @_;
3039
3040         return "$prefix\_$t->{NAME}" if (ref($t) eq "HASH" and
3041                         $t->{TYPE} eq "TYPEDEF");
3042         return "$prefix\_$t->{TYPE}_$t->{NAME}" if (ref($t) eq "HASH");
3043         return "$prefix\_$t";
3044 }
3045
3046 1;