source/configure.ac

   1 dnl -*- mode: m4-mode -*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 dnl disabled 2.53 requirement - we do work with 2.52 on suse 7.3 for example
   5 dnl AC_PREREQ(2.53)
   6
   7 AC_INIT([samba],[],[samba-technical@samba.org])
   8
   9 AC_CONFIG_SRCDIR([include/includes.h])
  10 AC_CONFIG_HEADER(include/config_tmp.h)
  11 AC_DEFINE(CONFIG_H_IS_FROM_SAMBA,1,[Marker for samba's config.h])
  12
  13 # Configuration rules.
  14 m4_include(build/m4/env.m4)
  15 m4_include(lib/replace/samba.m4)
  16 m4_include(lib/smbreadline/readline.m4)
  17 m4_include(heimdal_build/config.m4)
  18 m4_include(lib/util/fault.m4)
  19 m4_include(lib/util/signal.m4)
  20 m4_include(lib/util/util.m4)
  21 m4_include(lib/util/fsusage.m4)
  22 m4_include(lib/util/xattr.m4)
  23 m4_include(lib/util/capability.m4)
  24 m4_include(lib/util/time.m4)
  25 m4_include(lib/popt/samba.m4)
  26 m4_include(lib/charset/config.m4)
  27 m4_include(lib/socket/config.m4)
  28 m4_include(nsswitch/nsstest.m4)
  29
  30 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTALLOC, talloc >= 1.1.0,
  31         [],
  32         [
  33                 m4_include(lib/talloc/libtalloc.m4)
  34                 SMB_INCLUDE_MK(lib/talloc/config.mk)
  35         ]
  36 )
  37
  38 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTDB, tdb >= 1.1.0,
  39         [],
  40         [
  41                 m4_include(lib/tdb/libtdb.m4)
  42                 SMB_INCLUDE_MK(lib/tdb/config.mk)
  43         ]
  44 )
  45
  46 SMB_EXT_LIB_FROM_PKGCONFIG(LIBLDB, ldb >= 0.9.1,
  47         [
  48                 SMB_INCLUDE_MK(lib/ldb/ldb_ildap/config.mk)
  49                 SMB_INCLUDE_MK(lib/ldb/tools/config.mk)
  50                 SMB_SUBSYSTEM(ldb_map, [], [LIBLDB])
  51                 define_ldb_modulesdir=no
  52         ],
  53         [
  54                 # Here we need to do some tricks
  55                 # with AC_CONFIG_COMMANDS_PRE
  56                 # as that's the deferrs the commands
  57                 # to location after $prefix and $exec_prefix
  58                 # have usefull values and directly before
  59                 # creating config.status.
  60                 #
  61                 # The 'eval eval echo' trick is used to
  62                 # actually get the raw absolute directory
  63                 # path as this is needed in config.h
  64                 define_ldb_modulesdir=yes
  65                 AC_CONFIG_COMMANDS_PRE([
  66                 if test x"$define_ldb_modulesdir" = x"yes";then
  67                         LDB_MODULESDIR=`eval eval echo ${modulesdir}/ldb`
  68                         AC_DEFINE_UNQUOTED(LDB_MODULESDIR, "${LDB_MODULESDIR}" , [ldb Modules directory])
  69                 fi
  70                 ])
  71                 m4_include(lib/ldb/sqlite3.m4)
  72                 m4_include(lib/ldb/libldb.m4)
  73                 SMB_INCLUDE_MK(lib/ldb/config.mk)
  74         ]
  75 )
  76
  77 m4_include(lib/tls/config.m4)
  78 m4_include(lib/events/config.m4)
  79
  80 dnl m4_include(auth/kerberos/config.m4)
  81
  82 m4_include(auth/gensec/config.m4)
  83 m4_include(smbd/process_model.m4)
  84 m4_include(scripting/swig/config.m4)
  85 m4_include(ntvfs/posix/config.m4)
  86 m4_include(ntvfs/unixuid/config.m4)
  87 m4_include(lib/socket_wrapper/config.m4)
  88 m4_include(auth/config.m4)
  89 m4_include(kdc/config.m4)
  90 m4_include(ntvfs/sysdep/config.m4)
  91 m4_include(lib/appweb/config.m4)
  92 m4_include(nsswitch/config.m4)
  93 m4_include(libcli/config.m4)
  94
  95 #################################################
  96 # add *_CFLAGS only for the real build
  97 CFLAGS="${CFLAGS} ${DEVELOPER_CFLAGS}"
  98
  99 #################################################
 100 # final configure stuff
 101
 102 AC_MSG_CHECKING([configure summary])
 103 AC_TRY_RUN([#include "${srcdir-.}/build/tests/summary.c"],
 104            AC_MSG_RESULT(yes),
 105            AC_MSG_ERROR([summary failure. Aborting config]); exit 1;,
 106            AC_MSG_WARN([cannot run when cross-compiling]))
 107
 108 LIBS=`echo $LIBS | sed -e 's/ *//g'`
 109 if test x"$LIBS" != x""; then
 110         echo "LIBS: $LIBS"
 111         AC_MSG_WARN([the global \$LIBS variable contains some libraries!])
 112         AC_MSG_WARN([this should not happen, please report to samba-technical@lists.samba.org!])
 113         AC_MSG_ERROR([only _EXT macros from aclocal.m4 should be used!])
 114 fi
 115
 116 dnl Remove -L/usr/lib/? from LDFLAGS and LIBS
 117 LIB_REMOVE_USR_LIB(LDFLAGS)
 118 LIB_REMOVE_USR_LIB(LIBS)
 119
 120 dnl Remove -I/usr/include/? from CFLAGS and CPPFLAGS
 121 CFLAGS_REMOVE_USR_INCLUDE(CFLAGS)
 122 CFLAGS_REMOVE_USR_INCLUDE(CPPFLAGS)
 123
 124 AC_SUBST(ac_default_prefix)
 125
 126 for d in build/smb_build bin include ; do
 127     test -d ${builddir}/$d || AS_MKDIR_P(${builddir}/$d)
 128 done
 129
 130 echo "configure: creating build/smb_build/config.pm"
 131 cat >build/smb_build/config.pm<<CEOF
 132 # config.pm - Autogenerate by configure. DO NOT EDIT!
 133
 134 package config;
 135 require Exporter;
 136 @ISA = qw(Exporter);
 137 @EXPORT_OK = qw(%enabled %config);
 138 use strict;
 139
 140 use vars qw(%enabled %config);
 141
 142 %config = (AC_FOREACH([AC_Var], m4_defn([_AC_SUBST_VARS]), [
 143         AC_Var => '$AC_Var',])
 144 );
 145
 146 $SMB_INFO_ENABLES
 147 1;
 148 CEOF
 149
 150 echo "configure: creating config.mk"
 151 cat >config.mk<<CEOF
 152 # config.mk - Autogenerated by configure, DO NOT EDIT!
 153 $SMB_INFO_EXT_LIBS
 154 $SMB_INFO_SUBSYSTEMS
 155 $SMB_INFO_LIBRARIES
 156 CEOF
 157
 158 AC_OUTPUT_COMMANDS(
 159 [
 160 test "x$ac_abs_srcdir" != "x$ac_abs_builddir" && (
 161         cd $builddir;
 162         # NOTE: We *must* use -R so we don't follow symlinks (at least on BSD
 163         # systems).
 164         test -d heimdal || cp -R $srcdir/heimdal $builddir/
 165         test -d heimdal_build || cp -R $srcdir/heimdal_build $builddir/
 166         test -d build || builddir="$builddir" \
 167                         srcdir="$srcdir" \
 168                         $PERL ${srcdir}/script/buildtree.pl
 169  )
 170
 171 $PERL -I${builddir} -I${builddir}/build \
 172     -I${srcdir} -I${srcdir}/build \
 173     ${srcdir}/build/smb_build/main.pl || exit $?
 174 ],
 175 [
 176 srcdir="$srcdir"
 177 builddir="$builddir"
 178 PERL="$PERL"
 179
 180 export PERL
 181 export srcdir
 182 export builddir
 183 ])
 184 AC_OUTPUT
 185
 186 cmp include/config_tmp.h include/config.h >/dev/null 2>&1
 187 CMP_RET=$?
 188 if test $CMP_RET != 0; then
 189         cp include/config_tmp.h include/config.h
 190 fi