selftest/selftest.pl

   1 #!/usr/bin/perl
   2 # Bootstrap Samba and run a number of tests against it.
   3 # Copyright (C) 2005-2010 Jelmer Vernooij <jelmer@samba.org>
   4 # Copyright (C) 2007-2009 Stefan Metzmacher <metze@samba.org>
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 use strict;
  20
  21 use FindBin qw($RealBin $Script);
  22 use File::Spec;
  23 use File::Temp qw(tempfile);
  24 use Getopt::Long;
  25 use POSIX;
  26 use Cwd qw(abs_path);
  27 use lib "$RealBin";
  28 use Subunit;
  29 use SocketWrapper;
  30
  31 eval {
  32 require Time::HiRes;
  33 Time::HiRes->import("time");
  34 };
  35 if ($@) {
  36         print "You don't have Time::Hires installed !\n";
  37 }
  38
  39 my $opt_help = 0;
  40 my $opt_target = "samba";
  41 my $opt_quick = 0;
  42 my $opt_socket_wrapper = 0;
  43 my $opt_socket_wrapper_pcap = undef;
  44 my $opt_socket_wrapper_keep_pcap = undef;
  45 my $opt_random_order = 0;
  46 my $opt_one = 0;
  47 my @opt_exclude = ();
  48 my @opt_include = ();
  49 my $opt_testenv = 0;
  50 my $opt_list = 0;
  51 my $ldap = undef;
  52 my $opt_resetup_env = undef;
  53 my $opt_binary_mapping = "";
  54 my $opt_load_list = undef;
  55 my @testlists = ();
  56
  57 my $srcdir = ".";
  58 my $bindir = "./bin";
  59 my $prefix = "./st";
  60
  61 my @includes = ();
  62 my @excludes = ();
  63
  64 sub pipe_handler {
  65         my $sig = shift @_;
  66         print STDERR "Exiting early because of SIGPIPE.\n";
  67         exit(1);
  68 }
  69
  70 $SIG{PIPE} = \&pipe_handler;
  71
  72 sub find_in_list($$)
  73 {
  74         my ($list, $fullname) = @_;
  75
  76         foreach (@$list) {
  77                 if ($fullname =~ /$$_[0]/) {
  78                          return ($$_[1]) if ($$_[1]);
  79                          return "";
  80                 }
  81         }
  82
  83         return undef;
  84 }
  85
  86 sub skip($)
  87 {
  88         my ($name) = @_;
  89
  90         return find_in_list(\@excludes, $name);
  91 }
  92
  93 sub getlog_env($);
  94
  95 sub setup_pcap($)
  96 {
  97         my ($name) = @_;
  98
  99         return unless ($opt_socket_wrapper_pcap);
 100         return unless defined($ENV{SOCKET_WRAPPER_PCAP_DIR});
 101
 102         my $fname = $name;
 103         $fname =~ s%[^abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789\-]%_%g;
 104
 105         my $pcap_file = "$ENV{SOCKET_WRAPPER_PCAP_DIR}/$fname.pcap";
 106
 107         SocketWrapper::setup_pcap($pcap_file);
 108
 109         return $pcap_file;
 110 }
 111
 112 sub cleanup_pcap($$)
 113 {
 114         my ($pcap_file, $exitcode) = @_;
 115
 116         return unless ($opt_socket_wrapper_pcap);
 117         return if ($opt_socket_wrapper_keep_pcap);
 118         return unless ($exitcode == 0);
 119         return unless defined($pcap_file);
 120
 121         unlink($pcap_file);
 122 }
 123
 124 # expand strings from %ENV
 125 sub expand_environment_strings($)
 126 {
 127         my $s = shift;
 128         # we use a reverse sort so we do the longer ones first
 129         foreach my $k (sort { $b cmp $a } keys %ENV) {
 130                 $s =~ s/\$$k/$ENV{$k}/g;
 131         }
 132         return $s;
 133 }
 134
 135 sub run_testsuite($$$$$)
 136 {
 137         my ($envname, $name, $cmd, $i, $totalsuites) = @_;
 138         my $pcap_file = setup_pcap($name);
 139
 140         Subunit::start_testsuite($name);
 141         Subunit::progress_push();
 142         Subunit::report_time(time());
 143         system($cmd);
 144         Subunit::report_time(time());
 145         Subunit::progress_pop();
 146
 147         if ($? == -1) {
 148                 Subunit::progress_pop();
 149                 Subunit::end_testsuite($name, "error", "Unable to run $cmd: $!");
 150                 exit(1);
 151         } elsif ($? & 127) {
 152                 Subunit::end_testsuite($name, "error",
 153                         sprintf("%s died with signal %d, %s coredump\n", $cmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 154                 exit(1);
 155         }
 156
 157         my $exitcode = $? >> 8;
 158
 159         my $envlog = getlog_env($envname);
 160         if ($envlog ne "") {
 161                 print "envlog: $envlog\n";
 162         }
 163
 164         print "command: $cmd\n";
 165         printf "expanded command: %s\n", expand_environment_strings($cmd);
 166
 167         if ($exitcode == 0) {
 168                 Subunit::end_testsuite($name, "success");
 169         } else {
 170                 Subunit::end_testsuite($name, "failure", "Exit code was $exitcode");
 171         }
 172
 173         cleanup_pcap($pcap_file, $exitcode);
 174
 175         if (not $opt_socket_wrapper_keep_pcap and defined($pcap_file)) {
 176                 print "PCAP FILE: $pcap_file\n";
 177         }
 178
 179         if ($exitcode != 0) {
 180                 exit(1) if ($opt_one);
 181         }
 182
 183         return $exitcode;
 184 }
 185
 186 sub ShowHelp()
 187 {
 188         print "Samba test runner
 189 Copyright (C) Jelmer Vernooij <jelmer\@samba.org>
 190 Copyright (C) Stefan Metzmacher <metze\@samba.org>
 191
 192 Usage: $Script [OPTIONS] TESTNAME-REGEX
 193
 194 Generic options:
 195  --help                     this help page
 196  --target=samba[3]|win      Samba version to target
 197  --testlist=FILE            file to read available tests from
 198
 199 Paths:
 200  --prefix=DIR               prefix to run tests in [st]
 201  --srcdir=DIR               source directory [.]
 202  --bindir=DIR               binaries directory [./bin]
 203
 204 Target Specific:
 205  --socket-wrapper-pcap      save traffic to pcap directories
 206  --socket-wrapper-keep-pcap keep all pcap files, not just those for tests that
 207                             failed
 208  --socket-wrapper           enable socket wrapper
 209
 210 Samba4 Specific:
 211  --ldap=openldap|fedora-ds  back samba onto specified ldap server
 212
 213 Behaviour:
 214  --quick                    run quick overall test
 215  --one                      abort when the first test fails
 216  --testenv                  run a shell in the requested test environment
 217  --list                     list available tests
 218 ";
 219         exit(0);
 220 }
 221
 222 my $result = GetOptions (
 223                 'help|h|?' => \$opt_help,
 224                 'target=s' => \$opt_target,
 225                 'prefix=s' => \$prefix,
 226                 'socket-wrapper' => \$opt_socket_wrapper,
 227                 'socket-wrapper-pcap' => \$opt_socket_wrapper_pcap,
 228                 'socket-wrapper-keep-pcap' => \$opt_socket_wrapper_keep_pcap,
 229                 'quick' => \$opt_quick,
 230                 'one' => \$opt_one,
 231                 'exclude=s' => \@opt_exclude,
 232                 'include=s' => \@opt_include,
 233                 'srcdir=s' => \$srcdir,
 234                 'bindir=s' => \$bindir,
 235                 'testenv' => \$opt_testenv,
 236                 'list' => \$opt_list,
 237                 'ldap:s' => \$ldap,
 238                 'resetup-environment' => \$opt_resetup_env,
 239                 'testlist=s' => \@testlists,
 240                 'random-order' => \$opt_random_order,
 241                 'load-list=s' => \$opt_load_list,
 242                 'binary-mapping=s' => \$opt_binary_mapping
 243             );
 244
 245 exit(1) if (not $result);
 246
 247 ShowHelp() if ($opt_help);
 248
 249 die("--list and --testenv are mutually exclusive") if ($opt_list and $opt_testenv);
 250
 251 # we want unbuffered output
 252 $| = 1;
 253
 254 my @tests = @ARGV;
 255
 256 # quick hack to disable rpc validation when using valgrind - its way too slow
 257 unless (defined($ENV{VALGRIND})) {
 258         $ENV{VALIDATE} = "validate";
 259         $ENV{MALLOC_CHECK_} = 2;
 260 }
 261
 262 # make all our python scripts unbuffered
 263 $ENV{PYTHONUNBUFFERED} = 1;
 264
 265 my $bindir_abs = abs_path($bindir);
 266
 267 # Backwards compatibility:
 268 if (defined($ENV{TEST_LDAP}) and $ENV{TEST_LDAP} eq "yes") {
 269         if (defined($ENV{FEDORA_DS_ROOT})) {
 270                 $ldap = "fedora-ds";
 271         } else {
 272                 $ldap = "openldap";
 273         }
 274 }
 275
 276 my $torture_maxtime = ($ENV{TORTURE_MAXTIME} or 1200);
 277 if ($ldap) {
 278         # LDAP is slow
 279         $torture_maxtime *= 2;
 280 }
 281
 282 $prefix =~ s+//+/+;
 283 $prefix =~ s+/./+/+;
 284 $prefix =~ s+/$++;
 285
 286 die("using an empty prefix isn't allowed") unless $prefix ne "";
 287
 288 # Ensure we have the test prefix around.
 289 #
 290 # We need restrictive
 291 # permissions on this as some subdirectories in this tree will have
 292 # wider permissions (ie 0777) and this would allow other users on the
 293 # host to subvert the test process.
 294 mkdir($prefix, 0700) unless -d $prefix;
 295 chmod 0700, $prefix;
 296
 297 my $prefix_abs = abs_path($prefix);
 298 my $tmpdir_abs = abs_path("$prefix/tmp");
 299 mkdir($tmpdir_abs, 0777) unless -d $tmpdir_abs;
 300
 301 my $srcdir_abs = abs_path($srcdir);
 302
 303 die("using an empty absolute prefix isn't allowed") unless $prefix_abs ne "";
 304 die("using '/' as absolute prefix isn't allowed") unless $prefix_abs ne "/";
 305
 306 $ENV{PREFIX} = $prefix;
 307 $ENV{KRB5CCNAME} = "$prefix/krb5ticket";
 308 $ENV{PREFIX_ABS} = $prefix_abs;
 309 $ENV{SRCDIR} = $srcdir;
 310 $ENV{SRCDIR_ABS} = $srcdir_abs;
 311 $ENV{BINDIR} = $bindir_abs;
 312
 313 my $tls_enabled = not $opt_quick;
 314 $ENV{TLS_ENABLED} = ($tls_enabled?"yes":"no");
 315
 316 sub prefix_pathvar($$)
 317 {
 318         my ($name, $newpath) = @_;
 319         if (defined($ENV{$name})) {
 320                 $ENV{$name} = "$newpath:$ENV{$name}";
 321         } else {
 322                 $ENV{$name} = $newpath;
 323         }
 324 }
 325 prefix_pathvar("PKG_CONFIG_PATH", "$bindir_abs/pkgconfig");
 326 prefix_pathvar("PYTHONPATH", "$bindir_abs/python");
 327
 328 if ($opt_socket_wrapper_keep_pcap) {
 329         # Socket wrapper keep pcap implies socket wrapper pcap
 330         $opt_socket_wrapper_pcap = 1;
 331 }
 332
 333 if ($opt_socket_wrapper_pcap) {
 334         # Socket wrapper pcap implies socket wrapper
 335         $opt_socket_wrapper = 1;
 336 }
 337
 338 my $socket_wrapper_dir;
 339 if ($opt_socket_wrapper) {
 340         $socket_wrapper_dir = SocketWrapper::setup_dir("$prefix_abs/w", $opt_socket_wrapper_pcap);
 341         print "SOCKET_WRAPPER_DIR=$socket_wrapper_dir\n";
 342 } elsif (not $opt_list) {
 343          unless ($< == 0) {
 344                  warn("not using socket wrapper, but also not running as root. Will not be able to listen on proper ports");
 345          }
 346 }
 347
 348 my $target;
 349 my $testenv_default = "none";
 350
 351 my %binary_mapping = ();
 352 if ($opt_binary_mapping) {
 353     my @binmapping_list = split(/,/, $opt_binary_mapping);
 354     foreach my $mapping (@binmapping_list) {
 355         my ($bin, $map) = split(/\:/, $mapping);
 356         $binary_mapping{$bin} = $map;
 357     }
 358 }
 359
 360 $ENV{BINARY_MAPPING} = $opt_binary_mapping;
 361
 362 # After this many seconds, the server will self-terminate.  All tests
 363 # must terminate in this time, and testenv will only stay alive this
 364 # long
 365
 366 my $server_maxtime = 7500;
 367 if (defined($ENV{SMBD_MAXTIME}) and $ENV{SMBD_MAXTIME} ne "") {
 368     $server_maxtime = $ENV{SMBD_MAXTIME};
 369 }
 370
 371 unless ($opt_list) {
 372         if ($opt_target eq "samba") {
 373                 if ($opt_socket_wrapper and `$bindir/smbd -b | grep SOCKET_WRAPPER` eq "") {
 374                         die("You must include --enable-socket-wrapper when compiling Samba in order to execute 'make test'.  Exiting....");
 375                 }
 376                 $testenv_default = "dc";
 377                 require target::Samba;
 378                 $target = new Samba($bindir, \%binary_mapping, $ldap, $srcdir, $server_maxtime);
 379         } elsif ($opt_target eq "samba3") {
 380                 if ($opt_socket_wrapper and `$bindir/smbd -b | grep SOCKET_WRAPPER` eq "") {
 381                         die("You must include --enable-socket-wrapper when compiling Samba in order to execute 'make test'.  Exiting....");
 382                 }
 383                 $testenv_default = "member";
 384                 require target::Samba3;
 385                 $target = new Samba3($bindir, \%binary_mapping, $srcdir_abs, $server_maxtime);
 386         }
 387 }
 388
 389 sub read_test_regexes($)
 390 {
 391         my ($name) = @_;
 392         my @ret = ();
 393         open(LF, "<$name") or die("unable to read $name: $!");
 394         while (<LF>) {
 395                 chomp;
 396                 next if (/^#/);
 397                 if (/^(.*?)([ \t]+)\#([\t ]*)(.*?)$/) {
 398                         push (@ret, [$1, $4]);
 399                 } else {
 400                         s/^(.*?)([ \t]+)\#([\t ]*)(.*?)$//;
 401                         push (@ret, [$_, undef]);
 402                 }
 403         }
 404         close(LF);
 405         return @ret;
 406 }
 407
 408 foreach (@opt_exclude) {
 409         push (@excludes, read_test_regexes($_));
 410 }
 411
 412 foreach (@opt_include) {
 413         push (@includes, read_test_regexes($_));
 414 }
 415
 416 my $interfaces = join(',', ("127.0.0.11/8",
 417                             "127.0.0.12/8",
 418                             "127.0.0.13/8",
 419                             "127.0.0.14/8",
 420                             "127.0.0.15/8",
 421                             "127.0.0.16/8"));
 422
 423 my $clientdir = "$prefix_abs/client";
 424
 425 my $conffile = "$clientdir/client.conf";
 426 $ENV{SMB_CONF_PATH} = $conffile;
 427
 428 sub write_clientconf($$$)
 429 {
 430         my ($conffile, $clientdir, $vars) = @_;
 431
 432         mkdir("$clientdir", 0777) unless -d "$clientdir";
 433
 434         if ( -d "$clientdir/private" ) {
 435                 unlink <$clientdir/private/*>;
 436         } else {
 437                 mkdir("$clientdir/private", 0777);
 438         }
 439
 440         if ( -d "$clientdir/lockdir" ) {
 441                 unlink <$clientdir/lockdir/*>;
 442         } else {
 443                 mkdir("$clientdir/lockdir", 0777);
 444         }
 445
 446         if ( -d "$clientdir/statedir" ) {
 447                 unlink <$clientdir/statedir/*>;
 448         } else {
 449                 mkdir("$clientdir/statedir", 0777);
 450         }
 451
 452         if ( -d "$clientdir/cachedir" ) {
 453                 unlink <$clientdir/cachedir/*>;
 454         } else {
 455                 mkdir("$clientdir/cachedir", 0777);
 456         }
 457
 458         # this is ugly, but the ncalrpcdir needs exactly 0755
 459         # otherwise tests fail.
 460         my $mask = umask;
 461         umask 0022;
 462         if ( -d "$clientdir/ncalrpcdir/np" ) {
 463                 unlink <$clientdir/ncalrpcdir/np/*>;
 464                 rmdir "$clientdir/ncalrpcdir/np";
 465         }
 466         if ( -d "$clientdir/ncalrpcdir" ) {
 467                 unlink <$clientdir/ncalrpcdir/*>;
 468                 rmdir "$clientdir/ncalrpcdir";
 469         }
 470         mkdir("$clientdir/ncalrpcdir", 0755);
 471         umask $mask;
 472
 473         open(CF, ">$conffile");
 474         print CF "[global]\n";
 475         print CF "\tnetbios name = client\n";
 476         if (defined($vars->{DOMAIN})) {
 477                 print CF "\tworkgroup = $vars->{DOMAIN}\n";
 478         }
 479         if (defined($vars->{REALM})) {
 480                 print CF "\trealm = $vars->{REALM}\n";
 481         }
 482         if ($opt_socket_wrapper) {
 483                 print CF "\tinterfaces = $interfaces\n";
 484         }
 485         print CF "
 486         private dir = $clientdir/private
 487         lock dir = $clientdir/lockdir
 488         state directory = $clientdir/statedir
 489         cache directory = $clientdir/cachedir
 490         ncalrpc dir = $clientdir/ncalrpcdir
 491         name resolve order = file bcast
 492         panic action = $RealBin/gdb_backtrace \%d
 493         max xmit = 32K
 494         notify:inotify = false
 495         ldb:nosync = true
 496         system:anonymous = true
 497         client lanman auth = Yes
 498         log level = 1
 499         torture:basedir = $clientdir
 500 #We don't want to pass our self-tests if the PAC code is wrong
 501         gensec:require_pac = true
 502         resolv:host file = $prefix_abs/dns_host_file
 503 #We don't want to run 'speed' tests for very long
 504         torture:timelimit = 1
 505 ";
 506         close(CF);
 507 }
 508
 509 my @todo = ();
 510
 511 sub should_run_test($)
 512 {
 513         my $name = shift;
 514         if ($#tests == -1) {
 515                 return 1;
 516         }
 517         for (my $i=0; $i <= $#tests; $i++) {
 518                 if ($name =~ /$tests[$i]/i) {
 519                         return 1;
 520                 }
 521         }
 522         return 0;
 523 }
 524
 525 sub read_testlist($)
 526 {
 527         my ($filename) = @_;
 528
 529         my @ret = ();
 530         open(IN, $filename) or die("Unable to open $filename: $!");
 531
 532         while (<IN>) {
 533                 if (/-- TEST(-LOADLIST|-IDLIST|) --\n/) {
 534                         my $supports_loadlist = (defined($1) and $1 eq "-LOADLIST");
 535                         my $supports_idlist = (defined($1) and $1 eq "-IDLIST");
 536                         my $name = <IN>;
 537                         $name =~ s/\n//g;
 538                         my $env = <IN>;
 539                         $env =~ s/\n//g;
 540                         my $cmdline = <IN>;
 541                         $cmdline =~ s/\n//g;
 542                         if (should_run_test($name) == 1) {
 543                                 push (@ret, [$name, $env, $cmdline, $supports_loadlist, $supports_idlist]);
 544                         }
 545                 } else {
 546                         print;
 547                 }
 548         }
 549         close(IN) or die("Error creating recipe");
 550         return @ret;
 551 }
 552
 553 if ($#testlists == -1) {
 554         die("No testlists specified");
 555 }
 556
 557 $ENV{SELFTEST_PREFIX} = "$prefix_abs";
 558 $ENV{SELFTEST_TMPDIR} = "$tmpdir_abs";
 559 $ENV{TEST_DATA_PREFIX} = "$tmpdir_abs";
 560 if ($opt_socket_wrapper) {
 561         $ENV{SELFTEST_INTERFACES} = $interfaces;
 562 } else {
 563         $ENV{SELFTEST_INTERFACES} = "";
 564 }
 565 if ($opt_quick) {
 566         $ENV{SELFTEST_QUICK} = "1";
 567 } else {
 568         $ENV{SELFTEST_QUICK} = "";
 569 }
 570 $ENV{SELFTEST_MAXTIME} = $torture_maxtime;
 571
 572 my @available = ();
 573 foreach my $fn (@testlists) {
 574         foreach (read_testlist($fn)) {
 575                 my $name = $$_[0];
 576                 next if (@includes and not defined(find_in_list(\@includes, $name)));
 577                 push (@available, $_);
 578         }
 579 }
 580
 581 my $restricted = undef;
 582 my $restricted_used = {};
 583
 584 if ($opt_load_list) {
 585         $restricted = [];
 586         open(LOAD_LIST, "<$opt_load_list") or die("Unable to open $opt_load_list");
 587         while (<LOAD_LIST>) {
 588                 chomp;
 589                 push (@$restricted, $_);
 590         }
 591         close(LOAD_LIST);
 592 }
 593
 594 my $individual_tests = undef;
 595 $individual_tests = {};
 596
 597 foreach my $testsuite (@available) {
 598         my $name = $$testsuite[0];
 599         my $skipreason = skip($name);
 600         if (defined($restricted)) {
 601                 # Find the testsuite for this test
 602                 my $match = undef;
 603                 foreach my $r (@$restricted) {
 604                         if ($r eq $name) {
 605                                 $individual_tests->{$name} = [];
 606                                 $match = $r;
 607                                 $restricted_used->{$r} = 1;
 608                         } elsif (substr($r, 0, length($name)+1) eq "$name.") {
 609                                 push(@{$individual_tests->{$name}}, $r);
 610                                 $match = $r;
 611                                 $restricted_used->{$r} = 1;
 612                         }
 613                 }
 614                 if ($match) {
 615                         if (defined($skipreason)) {
 616                                 if (not $opt_list) {
 617                                         Subunit::skip_testsuite($name, $skipreason);
 618                                 }
 619                         } else {
 620                                 push(@todo, $testsuite);
 621                         }
 622                 }
 623         } elsif (defined($skipreason)) {
 624                 if (not $opt_list) {
 625                         Subunit::skip_testsuite($name, $skipreason);
 626                 }
 627         } else {
 628                 push(@todo, $testsuite);
 629         }
 630 }
 631
 632 if (defined($restricted)) {
 633         foreach (@$restricted) {
 634                 unless (defined($restricted_used->{$_})) {
 635                         print "No test or testsuite found matching $_\n";
 636                 }
 637         }
 638 } elsif ($#todo == -1) {
 639         print STDERR "No tests to run\n";
 640         exit(1);
 641 }
 642
 643 my $suitestotal = $#todo + 1;
 644
 645 unless ($opt_list) {
 646         Subunit::progress($suitestotal);
 647         Subunit::report_time(time());
 648 }
 649
 650 my $i = 0;
 651 $| = 1;
 652
 653 my %running_envs = ();
 654
 655 sub get_running_env($)
 656 {
 657         my ($name) = @_;
 658
 659         my $envname = $name;
 660
 661         $envname =~ s/:.*//;
 662
 663         return $running_envs{$envname};
 664 }
 665
 666 my @exported_envvars = (
 667         # domain stuff
 668         "DOMAIN",
 669         "REALM",
 670
 671         # domain controller stuff
 672         "DC_SERVER",
 673         "DC_SERVER_IP",
 674         "DC_NETBIOSNAME",
 675         "DC_NETBIOSALIAS",
 676
 677         # domain member
 678         "MEMBER_SERVER",
 679         "MEMBER_SERVER_IP",
 680         "MEMBER_NETBIOSNAME",
 681         "MEMBER_NETBIOSALIAS",
 682
 683         # rpc proxy controller stuff
 684         "RPC_PROXY_SERVER",
 685         "RPC_PROXY_SERVER_IP",
 686         "RPC_PROXY_NETBIOSNAME",
 687         "RPC_PROXY_NETBIOSALIAS",
 688
 689         # domain controller stuff for Vampired DC
 690         "VAMPIRE_DC_SERVER",
 691         "VAMPIRE_DC_SERVER_IP",
 692         "VAMPIRE_DC_NETBIOSNAME",
 693         "VAMPIRE_DC_NETBIOSALIAS",
 694
 695         # server stuff
 696         "SERVER",
 697         "SERVER_IP",
 698         "NETBIOSNAME",
 699         "NETBIOSALIAS",
 700
 701         # user stuff
 702         "USERNAME",
 703         "USERID",
 704         "PASSWORD",
 705         "DC_USERNAME",
 706         "DC_PASSWORD",
 707
 708         # misc stuff
 709         "KRB5_CONFIG",
 710         "WINBINDD_SOCKET_DIR",
 711         "WINBINDD_PRIV_PIPE_DIR",
 712         "NMBD_SOCKET_DIR",
 713         "LOCAL_PATH",
 714
 715         # nss_wrapper
 716         "NSS_WRAPPER_PASSWD",
 717         "NSS_WRAPPER_GROUP"
 718
 719 );
 720
 721 $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 722         my $signame = shift;
 723         teardown_env($_) foreach(keys %running_envs);
 724         die("Received signal $signame");
 725 };
 726
 727 sub setup_env($$)
 728 {
 729         my ($name, $prefix) = @_;
 730
 731         my $testenv_vars = undef;
 732
 733         my $envname = $name;
 734         my $option = $name;
 735
 736         $envname =~ s/:.*//;
 737         $option =~ s/^[^:]*//;
 738         $option =~ s/^://;
 739
 740         $option = "client" if $option eq "";
 741
 742         if ($envname eq "none") {
 743                 $testenv_vars = {};
 744         } elsif (defined(get_running_env($envname))) {
 745                 $testenv_vars = get_running_env($envname);
 746                 if (not $testenv_vars->{target}->check_env($testenv_vars)) {
 747                         print $testenv_vars->{target}->getlog_env($testenv_vars);
 748                         $testenv_vars = undef;
 749                 }
 750         } else {
 751                 $testenv_vars = $target->setup_env($envname, $prefix);
 752                 if (defined($testenv_vars) and $testenv_vars eq "UNKNOWN") {
 753                     return $testenv_vars;
 754                 } elsif (defined($testenv_vars) && not defined($testenv_vars->{target})) {
 755                         $testenv_vars->{target} = $target;
 756                 }
 757                 if (not defined($testenv_vars)) {
 758                         warn("$opt_target can't start up known environment '$envname'");
 759                 }
 760         }
 761
 762
 763         return undef unless defined($testenv_vars);
 764
 765         $running_envs{$envname} = $testenv_vars;
 766
 767         if ($option eq "local") {
 768                 SocketWrapper::set_default_iface($testenv_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 769                 $ENV{SMB_CONF_PATH} = $testenv_vars->{SERVERCONFFILE};
 770         } elsif ($option eq "client") {
 771                 SocketWrapper::set_default_iface(11);
 772                 write_clientconf($conffile, $clientdir, $testenv_vars);
 773                 $ENV{SMB_CONF_PATH} = $conffile;
 774         } else {
 775                 die("Unknown option[$option] for envname[$envname]");
 776         }
 777
 778         foreach (@exported_envvars) {
 779                 if (defined($testenv_vars->{$_})) {
 780                         $ENV{$_} = $testenv_vars->{$_};
 781                 } else {
 782                         delete $ENV{$_};
 783                 }
 784         }
 785
 786         return $testenv_vars;
 787 }
 788
 789 sub exported_envvars_str($)
 790 {
 791         my ($testenv_vars) = @_;
 792         my $out = "";
 793
 794         foreach (@exported_envvars) {
 795                 next unless defined($testenv_vars->{$_});
 796                 $out .= $_."=".$testenv_vars->{$_}."\n";
 797         }
 798
 799         return $out;
 800 }
 801
 802 sub getlog_env($)
 803 {
 804         my ($envname) = @_;
 805         return "" if ($envname eq "none");
 806         my $env = get_running_env($envname);
 807         return $env->{target}->getlog_env($env);
 808 }
 809
 810 sub check_env($)
 811 {
 812         my ($envname) = @_;
 813         return 1 if ($envname eq "none");
 814         my $env = get_running_env($envname);
 815         return $env->{target}->check_env($env);
 816 }
 817
 818 sub teardown_env($)
 819 {
 820         my ($envname) = @_;
 821         return if ($envname eq "none");
 822         my $env = get_running_env($envname);
 823         $env->{target}->teardown_env($env);
 824         delete $running_envs{$envname};
 825 }
 826
 827 # This 'global' file needs to be empty when we start
 828 unlink("$prefix_abs/dns_host_file");
 829
 830 if ($opt_random_order) {
 831         require List::Util;
 832         my @newtodo = List::Util::shuffle(@todo);
 833         @todo = @newtodo;
 834 }
 835
 836 if ($opt_testenv) {
 837         my $testenv_name = $ENV{SELFTEST_TESTENV};
 838         $testenv_name = $testenv_default unless defined($testenv_name);
 839
 840         my $testenv_vars = setup_env($testenv_name, $prefix);
 841
 842         die("Unable to setup environment $testenv_name") unless ($testenv_vars);
 843
 844         $ENV{PIDDIR} = $testenv_vars->{PIDDIR};
 845         $ENV{ENVNAME} = $testenv_name;
 846
 847         my $envvarstr = exported_envvars_str($testenv_vars);
 848
 849         my $term = ($ENV{TERMINAL} or "xterm -e");
 850         system("$term 'echo -e \"
 851 Welcome to the Samba4 Test environment '$testenv_name'
 852
 853 This matches the client environment used in make test
 854 server is pid `cat \$PIDDIR/samba.pid`
 855
 856 Some useful environment variables:
 857 TORTURE_OPTIONS=\$TORTURE_OPTIONS
 858 SMB_CONF_PATH=\$SMB_CONF_PATH
 859
 860 $envvarstr
 861 \" && LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} bash'");
 862         teardown_env($testenv_name);
 863 } elsif ($opt_list) {
 864         foreach (@todo) {
 865                 my $cmd = $$_[2];
 866                 my $name = $$_[0];
 867                 my $envname = $$_[1];
 868
 869                 unless($cmd =~ /\$LISTOPT/) {
 870                         warn("Unable to list tests in $name");
 871                         next;
 872                 }
 873
 874                 $cmd =~ s/\$LISTOPT/--list/g;
 875
 876                 system($cmd);
 877
 878                 if ($? == -1) {
 879                         die("Unable to run $cmd: $!");
 880                 } elsif ($? & 127) {
 881                         die(snprintf("%s died with signal %d, %s coredump\n", $cmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 882                 }
 883
 884                 my $exitcode = $? >> 8;
 885                 if ($exitcode != 0) {
 886                         die("$cmd exited with exit code $exitcode");
 887                 }
 888         }
 889 } else {
 890         foreach (@todo) {
 891                 $i++;
 892                 my $cmd = $$_[2];
 893                 my $name = $$_[0];
 894                 my $envname = $$_[1];
 895
 896                 my $envvars = setup_env($envname, $prefix);
 897                 if (not defined($envvars)) {
 898                         Subunit::start_testsuite($name);
 899                         Subunit::end_testsuite($name, "error",
 900                                 "unable to set up environment $envname - exiting");
 901                         next;
 902                 } elsif ($envvars eq "UNKNOWN") {
 903                         Subunit::start_testsuite($name);
 904                         Subunit::end_testsuite($name, "skip",
 905                                 "environment $envname is unknown in this test backend - skipping");
 906                         next;
 907                 }
 908
 909                 # Generate a file with the individual tests to run, if the
 910                 # test runner for this test suite supports it.
 911                 if ($individual_tests and $individual_tests->{$name}) {
 912                         if ($$_[3]) {
 913                                 my ($fh, $listid_file) = tempfile(UNLINK => 0);
 914                                 foreach my $test (@{$individual_tests->{$name}}) {
 915                                         print $fh substr($test, length($name)+1) . "\n";
 916                                 }
 917                                 $cmd =~ s/\$LOADLIST/--load-list=$listid_file/g;
 918                         } elsif ($$_[4]) {
 919                                 $cmd =~ s/\s+[^\s]+\s*$//;
 920                                 $cmd .= " " . join(' ', @{$individual_tests->{$name}});
 921                         }
 922                 }
 923
 924                 run_testsuite($envname, $name, $cmd, $i, $suitestotal);
 925
 926                 teardown_env($envname) if ($opt_resetup_env);
 927         }
 928 }
 929
 930 print "\n";
 931
 932 teardown_env($_) foreach (keys %running_envs);
 933
 934 my $failed = 0;
 935
 936 # if there were any valgrind failures, show them
 937 foreach (<$prefix/valgrind.log*>) {
 938         next unless (-s $_);
 939         print "VALGRIND FAILURE\n";
 940         $failed++;
 941         system("cat $_");
 942 }
 943 exit 0;