lib/tevent/libtevent.m4

   1 dnl find the tevent sources. This is meant to work both for
   2 dnl standalone builds, and builds of packages using libtevent
   3
   4 AC_SUBST(teventdir)
   5
   6 if test x"$teventdir" = "x"; then
   7         teventdir=""
   8         teventpaths="$srcdir $srcdir/../lib/tevent $srcdir/tevent $srcdir/../tevent"
   9         for d in $teventpaths; do
  10                 if test -f "$d/tevent.c"; then
  11                         teventdir="$d"
  12                         break;
  13                 fi
  14         done
  15         if test x"$teventdir" = "x"; then
  16            AC_MSG_ERROR([cannot find libtevent source in $teventpaths])
  17         fi
  18 fi
  19
  20 TEVENT_OBJ=""
  21 TEVENT_CFLAGS=""
  22 TEVENT_LIBS=""
  23 AC_SUBST(TEVENT_OBJ)
  24 AC_SUBST(TEVENT_CFLAGS)
  25 AC_SUBST(TEVENT_LIBS)
  26
  27 TEVENT_CFLAGS="-I$teventdir"
  28
  29 TEVENT_OBJ="tevent.o tevent_debug.o tevent_util.o"
  30 TEVENT_OBJ="$TEVENT_OBJ tevent_fd.o tevent_timed.o tevent_immediate.o tevent_signal.o"
  31 TEVENT_OBJ="$TEVENT_OBJ tevent_req.o tevent_wakeup.o tevent_queue.o"
  32 TEVENT_OBJ="$TEVENT_OBJ tevent_standard.o tevent_select.o"
  33 TEVENT_OBJ="$TEVENT_OBJ tevent_poll.o"
  34
  35 AC_CHECK_HEADERS(sys/epoll.h)
  36 AC_CHECK_FUNCS(epoll_create)
  37 if test x"$ac_cv_header_sys_epoll_h" = x"yes" -a x"$ac_cv_func_epoll_create" = x"yes"; then
  38    TEVENT_OBJ="$TEVENT_OBJ tevent_epoll.o"
  39    AC_DEFINE(HAVE_EPOLL, 1, [Whether epoll available])
  40 fi
  41
  42 tevent_num_signals_includes="$ac_includes_default
  43 #include <signal.h>
  44 "
  45 tevent_num_signals=64
  46 AC_CHECK_VALUEOF(NSIG, [$tevent_num_signals_includes])
  47 v=$ac_cv_valueof_NSIG
  48 test -n "$v" && test "$v" -gt "$tevent_num_signals" && {
  49         tevent_num_signals=$v
  50 }
  51 AC_CHECK_VALUEOF(_NSIG, [$tevent_num_signals_includes])
  52 v=$ac_cv_valueof__NSIG
  53 test -n "$v" && test "$v" -gt "$tevent_num_signals" && {
  54         tevent_num_signals=$v
  55 }
  56 AC_CHECK_VALUEOF(SIGRTMAX, [$tevent_num_signals_includes])
  57 v=$ac_cv_valueof_SIGRTMAX
  58 test -n "$v" && test "$v" -gt "$tevent_num_signals" && {
  59         tevent_num_signals=$v
  60 }
  61 AC_CHECK_VALUEOF(SIGRTMIN, [$tevent_num_signals_includes])
  62 v=$ac_cv_valueof_SIGRTMIN
  63 test -n "$v" && {
  64         v=`expr $v + $v`
  65 }
  66 test -n "$v" && test "$v" -gt "$tevent_num_signals" && {
  67         tevent_num_signals=$v
  68 }
  69 AC_DEFINE_UNQUOTED(TEVENT_NUM_SIGNALS, $tevent_num_signals, [Max signal number value])
  70
  71 if test x"$VERSIONSCRIPT" != "x"; then
  72     EXPORTSFILE=tevent.exports
  73     AC_SUBST(EXPORTSFILE)
  74 fi
  75