pidl/lib/Parse/Pidl/Samba4/NDR/Parser.pm

   1 ###################################################
   2 # Samba4 NDR parser generator for IDL structures
   3 # Copyright tridge@samba.org 2000-2003
   4 # Copyright tpot@samba.org 2001
   5 # Copyright jelmer@samba.org 2004-2006
   6 # released under the GNU GPL
   7
   8 package Parse::Pidl::Samba4::NDR::Parser;
   9
  10 require Exporter;
  11 @ISA = qw(Exporter);
  12 @EXPORT_OK = qw(check_null_pointer NeededFunction NeededElement NeededType $res NeededInterface TypeFunctionName ParseElementPrint);
  13
  14 use strict;
  15 use Parse::Pidl::Typelist qw(hasType getType mapTypeName typeHasBody);
  16 use Parse::Pidl::Util qw(has_property ParseExpr ParseExprExt print_uuid unmake_str);
  17 use Parse::Pidl::CUtil qw(get_pointer_to get_value_of get_array_element);
  18 use Parse::Pidl::NDR qw(GetPrevLevel GetNextLevel ContainsDeferred is_charset_array);
  19 use Parse::Pidl::Samba4 qw(is_intree choose_header ArrayDynamicallyAllocated);
  20 use Parse::Pidl::Samba4::Header qw(GenerateFunctionInEnv GenerateFunctionOutEnv EnvSubstituteValue GenerateStructEnv);
  21 use Parse::Pidl qw(warning);
  22
  23 use vars qw($VERSION);
  24 $VERSION = '0.01';
  25
  26 # list of known types
  27 my %typefamily;
  28
  29 sub new($$) {
  30         my ($class) = @_;
  31         my $self = { res => "", res_hdr => "", deferred => [], tabs => "", defer_tabs => "" };
  32         bless($self, $class);
  33 }
  34
  35 sub get_typefamily($)
  36 {
  37         my $n = shift;
  38         return $typefamily{$n};
  39 }
  40
  41 sub append_prefix($$)
  42 {
  43         my ($e, $var_name) = @_;
  44         my $pointers = 0;
  45         my $arrays = 0;
  46
  47         foreach my $l (@{$e->{LEVELS}}) {
  48                 if ($l->{TYPE} eq "POINTER") {
  49                         $pointers++;
  50                 } elsif ($l->{TYPE} eq "ARRAY") {
  51                         $arrays++;
  52                         if (($pointers == 0) and
  53                             (not $l->{IS_FIXED}) and
  54                             (not $l->{IS_INLINE})) {
  55                                 return get_value_of($var_name);
  56                         }
  57                 } elsif ($l->{TYPE} eq "DATA") {
  58                         if (Parse::Pidl::Typelist::scalar_is_reference($l->{DATA_TYPE})) {
  59                                 return get_value_of($var_name) unless ($pointers or $arrays);
  60                         }
  61                 }
  62         }
  63
  64         return $var_name;
  65 }
  66
  67 sub has_fast_array($$)
  68 {
  69         my ($e,$l) = @_;
  70
  71         return 0 if ($l->{TYPE} ne "ARRAY");
  72
  73         my $nl = GetNextLevel($e,$l);
  74         return 0 unless ($nl->{TYPE} eq "DATA");
  75         return 0 unless (hasType($nl->{DATA_TYPE}));
  76
  77         my $t = getType($nl->{DATA_TYPE});
  78
  79         # Only uint8 and string have fast array functions at the moment
  80         return ($t->{NAME} eq "uint8") or ($t->{NAME} eq "string");
  81 }
  82
  83
  84 ####################################
  85 # pidl() is our basic output routine
  86 sub pidl($$)
  87 {
  88         my ($self, $d) = @_;
  89         if ($d) {
  90                 $self->{res} .= $self->{tabs};
  91                 $self->{res} .= $d;
  92         }
  93         $self->{res} .="\n";
  94 }
  95
  96 sub pidl_hdr($$) { my ($self, $d) = @_; $self->{res_hdr} .= "$d\n"; }
  97
  98 ####################################
  99 # defer() is like pidl(), but adds to
 100 # a deferred buffer which is then added to the
 101 # output buffer at the end of the structure/union/function
 102 # This is needed to cope with code that must be pushed back
 103 # to the end of a block of elements
 104 sub defer_indent($) { my ($self) = @_; $self->{defer_tabs}.="\t"; }
 105 sub defer_deindent($) { my ($self) = @_; $self->{defer_tabs}=substr($self->{defer_tabs}, 0, -1); }
 106
 107 sub defer($$)
 108 {
 109         my ($self, $d) = @_;
 110         if ($d) {
 111                 push(@{$self->{deferred}}, $self->{defer_tabs}.$d);
 112         }
 113 }
 114
 115 ########################################
 116 # add the deferred content to the current
 117 # output
 118 sub add_deferred($)
 119 {
 120         my ($self) = @_;
 121         $self->pidl($_) foreach (@{$self->{deferred}});
 122         $self->{deferred} = [];
 123         $self->{defer_tabs} = "";
 124 }
 125
 126 sub indent($)
 127 {
 128         my ($self) = @_;
 129         $self->{tabs} .= "\t";
 130 }
 131
 132 sub deindent($)
 133 {
 134         my ($self) = @_;
 135         $self->{tabs} = substr($self->{tabs}, 0, -1);
 136 }
 137
 138 #####################################################################
 139 # declare a function public or static, depending on its attributes
 140 sub fn_declare($$$$)
 141 {
 142         my ($self,$type,$fn,$decl) = @_;
 143
 144         if (has_property($fn, "no$type")) {
 145                 $self->pidl_hdr("$decl;");
 146                 return 0;
 147         }
 148
 149         if (has_property($fn, "public")) {
 150                 $self->pidl_hdr("$decl;");
 151                 $self->pidl("_PUBLIC_ $decl");
 152         } else {
 153                 $self->pidl("static $decl");
 154         }
 155
 156         return 1;
 157 }
 158
 159 ###################################################################
 160 # setup any special flags for an element or structure
 161 sub start_flags($$$)
 162 {
 163         my ($self, $e, $ndr) = @_;
 164         my $flags = has_property($e, "flag");
 165         if (defined $flags) {
 166                 $self->pidl("{");
 167                 $self->indent;
 168                 $self->pidl("uint32_t _flags_save_$e->{TYPE} = $ndr->flags;");
 169                 $self->pidl("ndr_set_flags(&$ndr->flags, $flags);");
 170         }
 171 }
 172
 173 ###################################################################
 174 # end any special flags for an element or structure
 175 sub end_flags($$$)
 176 {
 177         my ($self, $e, $ndr) = @_;
 178         my $flags = has_property($e, "flag");
 179         if (defined $flags) {
 180                 $self->pidl("$ndr->flags = _flags_save_$e->{TYPE};");
 181                 $self->deindent;
 182                 $self->pidl("}");
 183         }
 184 }
 185
 186 #####################################################################
 187 # parse the data of an array - push side
 188 sub ParseArrayPushHeader($$$$$$)
 189 {
 190         my ($self,$e,$l,$ndr,$var_name,$env) = @_;
 191
 192         my $size;
 193         my $length;
 194
 195         if ($l->{IS_ZERO_TERMINATED}) {
 196                 if (has_property($e, "charset")) {
 197                         $size = $length = "ndr_charset_length($var_name, CH_$e->{PROPERTIES}->{charset})";
 198                 } else {
 199                         $size = $length = "ndr_string_length($var_name, sizeof(*$var_name))";
 200                 }
 201         } else {
 202                 $size = ParseExpr($l->{SIZE_IS}, $env, $e);
 203                 $length = ParseExpr($l->{LENGTH_IS}, $env, $e);
 204         }
 205
 206         if ((!$l->{IS_SURROUNDING}) and $l->{IS_CONFORMANT}) {
 207                 $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, $size));");
 208         }
 209
 210         if ($l->{IS_VARYING}) {
 211                 $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, 0));");  # array offset
 212                 $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, $length));");
 213         }
 214
 215         return $length;
 216 }
 217
 218 sub check_fully_dereferenced($$)
 219 {
 220         my ($element, $env) = @_;
 221
 222         return sub ($) {
 223                 my $origvar = shift;
 224                 my $check = 0;
 225
 226                 # Figure out the number of pointers in $ptr
 227                 my $expandedvar = $origvar;
 228                 $expandedvar =~ s/^(\**)//;
 229                 my $ptr = $1;
 230
 231                 my $var = undef;
 232                 foreach (keys %$env) {
 233                         if ($env->{$_} eq $expandedvar) {
 234                                 $var = $_;
 235                                 last;
 236                         }
 237                 }
 238
 239                 return($origvar) unless (defined($var));
 240                 my $e;
 241                 foreach (@{$element->{PARENT}->{ELEMENTS}}) {
 242                         if ($_->{NAME} eq $var) {
 243                                 $e = $_;
 244                                 last;
 245                         }
 246                 }
 247
 248                 $e or die("Environment doesn't match siblings");
 249
 250                 # See if pointer at pointer level $level
 251                 # needs to be checked.
 252                 my $nump = 0;
 253                 foreach (@{$e->{LEVELS}}) {
 254                         if ($_->{TYPE} eq "POINTER") {
 255                                 $nump = $_->{POINTER_INDEX}+1;
 256                         }
 257                 }
 258                 warning($element->{ORIGINAL}, "Got pointer for `$e->{NAME}', expected fully derefenced variable") if ($nump > length($ptr));
 259                 return ($origvar);
 260         }
 261 }
 262
 263 sub check_null_pointer($$$$)
 264 {
 265         my ($element, $env, $print_fn, $return) = @_;
 266
 267         return sub ($) {
 268                 my $expandedvar = shift;
 269                 my $check = 0;
 270
 271                 # Figure out the number of pointers in $ptr
 272                 $expandedvar =~ s/^(\**)//;
 273                 my $ptr = $1;
 274
 275                 my $var = undef;
 276                 foreach (keys %$env) {
 277                         if ($env->{$_} eq $expandedvar) {
 278                                 $var = $_;
 279                                 last;
 280                         }
 281                 }
 282
 283                 if (defined($var)) {
 284                         my $e;
 285                         # lookup ptr in $e
 286                         foreach (@{$element->{PARENT}->{ELEMENTS}}) {
 287                                 if ($_->{NAME} eq $var) {
 288                                         $e = $_;
 289                                         last;
 290                                 }
 291                         }
 292
 293                         $e or die("Environment doesn't match siblings");
 294
 295                         # See if pointer at pointer level $level
 296                         # needs to be checked.
 297                         foreach my $l (@{$e->{LEVELS}}) {
 298                                 if ($l->{TYPE} eq "POINTER" and
 299                                         $l->{POINTER_INDEX} == length($ptr)) {
 300                                         # No need to check ref pointers
 301                                         $check = ($l->{POINTER_TYPE} ne "ref");
 302                                         last;
 303                                 }
 304
 305                                 if ($l->{TYPE} eq "DATA") {
 306                                         warning($element, "too much dereferences for `$var'");
 307                                 }
 308                         }
 309                 } else {
 310                         warning($element, "unknown dereferenced expression `$expandedvar'");
 311                         $check = 1;
 312                 }
 313
 314                 $print_fn->("if ($ptr$expandedvar == NULL) $return") if $check;
 315         }
 316 }
 317
 318 #####################################################################
 319 # parse an array - pull side
 320 sub ParseArrayPullHeader($$$$$$)
 321 {
 322         my ($self,$e,$l,$ndr,$var_name,$env) = @_;
 323
 324         my $length;
 325         my $size;
 326
 327         if ($l->{IS_CONFORMANT}) {
 328                 $length = $size = "ndr_get_array_size($ndr, " . get_pointer_to($var_name) . ")";
 329         } elsif ($l->{IS_ZERO_TERMINATED} and $l->{SIZE_IS} == 0 and $l->{LENGTH_IS} == 0) { # Noheader arrays
 330                 $length = $size = "ndr_get_string_size($ndr, sizeof(*$var_name))";
 331         } else {
 332                 $length = $size = ParseExprExt($l->{SIZE_IS}, $env, $e->{ORIGINAL},
 333                         check_null_pointer($e, $env, sub { $self->pidl(shift); },
 334                                            "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for size_is()\");"),
 335                         check_fully_dereferenced($e, $env));
 336         }
 337
 338         if ((!$l->{IS_SURROUNDING}) and $l->{IS_CONFORMANT}) {
 339                 $self->pidl("NDR_CHECK(ndr_pull_array_size($ndr, " . get_pointer_to($var_name) . "));");
 340         }
 341
 342         if ($l->{IS_VARYING}) {
 343                 $self->pidl("NDR_CHECK(ndr_pull_array_length($ndr, " . get_pointer_to($var_name) . "));");
 344                 $length = "ndr_get_array_length($ndr, " . get_pointer_to($var_name) .")";
 345         }
 346
 347         if ($length ne $size) {
 348                 $self->pidl("if ($length > $size) {");
 349                 $self->indent;
 350                 $self->pidl("return ndr_pull_error($ndr, NDR_ERR_ARRAY_SIZE, \"Bad array size %u should exceed array length %u\", $size, $length);");
 351                 $self->deindent;
 352                 $self->pidl("}");
 353         }
 354
 355         if ($l->{IS_CONFORMANT} and not $l->{IS_ZERO_TERMINATED}) {
 356                 $self->defer("if ($var_name) {");
 357                 $self->defer_indent;
 358                 my $size = ParseExprExt($l->{SIZE_IS}, $env, $e->{ORIGINAL},
 359                         check_null_pointer($e, $env, sub { $self->defer(shift); },
 360                                            "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for size_is()\");"),
 361                         check_fully_dereferenced($e, $env));
 362                 $self->defer("NDR_CHECK(ndr_check_array_size($ndr, (void*)" . get_pointer_to($var_name) . ", $size));");
 363                 $self->defer_deindent;
 364                 $self->defer("}");
 365         }
 366
 367         if ($l->{IS_VARYING} and not $l->{IS_ZERO_TERMINATED}) {
 368                 $self->defer("if ($var_name) {");
 369                 $self->defer_indent;
 370                 my $length = ParseExprExt($l->{LENGTH_IS}, $env, $e->{ORIGINAL},
 371                         check_null_pointer($e, $env, sub { $self->defer(shift); },
 372                                            "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for length_is()\");"),
 373                         check_fully_dereferenced($e, $env));
 374                 $self->defer("NDR_CHECK(ndr_check_array_length($ndr, (void*)" . get_pointer_to($var_name) . ", $length));");
 375                 $self->defer_deindent;
 376                 $self->defer("}");
 377         }
 378
 379         if (ArrayDynamicallyAllocated($e,$l) and not is_charset_array($e,$l)) {
 380                 $self->AllocateArrayLevel($e,$l,$ndr,$var_name,$size);
 381         }
 382
 383         return $length;
 384 }
 385
 386 sub compression_alg($$)
 387 {
 388         my ($e, $l) = @_;
 389         my ($alg, $clen, $dlen) = split(/,/, $l->{COMPRESSION});
 390
 391         return $alg;
 392 }
 393
 394 sub compression_clen($$$)
 395 {
 396         my ($e, $l, $env) = @_;
 397         my ($alg, $clen, $dlen) = split(/,/, $l->{COMPRESSION});
 398
 399         return ParseExpr($clen, $env, $e->{ORIGINAL});
 400 }
 401
 402 sub compression_dlen($$$)
 403 {
 404         my ($e,$l,$env) = @_;
 405         my ($alg, $clen, $dlen) = split(/,/, $l->{COMPRESSION});
 406
 407         return ParseExpr($dlen, $env, $e->{ORIGINAL});
 408 }
 409
 410 sub ParseCompressionPushStart($$$$$)
 411 {
 412         my ($self,$e,$l,$ndr,$env) = @_;
 413         my $comndr = "$ndr\_compressed";
 414         my $alg = compression_alg($e, $l);
 415         my $dlen = compression_dlen($e, $l, $env);
 416
 417         $self->pidl("{");
 418         $self->indent;
 419         $self->pidl("struct ndr_push *$comndr;");
 420         $self->pidl("NDR_CHECK(ndr_push_compression_start($ndr, &$comndr, $alg, $dlen));");
 421
 422         return $comndr;
 423 }
 424
 425 sub ParseCompressionPushEnd($$$$$)
 426 {
 427         my ($self,$e,$l,$ndr,$env) = @_;
 428         my $comndr = "$ndr\_compressed";
 429         my $alg = compression_alg($e, $l);
 430         my $dlen = compression_dlen($e, $l, $env);
 431
 432         $self->pidl("NDR_CHECK(ndr_push_compression_end($ndr, $comndr, $alg, $dlen));");
 433         $self->deindent;
 434         $self->pidl("}");
 435 }
 436
 437 sub ParseCompressionPullStart($$$$$)
 438 {
 439         my ($self,$e,$l,$ndr,$env) = @_;
 440         my $comndr = "$ndr\_compressed";
 441         my $alg = compression_alg($e, $l);
 442         my $dlen = compression_dlen($e, $l, $env);
 443
 444         $self->pidl("{");
 445         $self->indent;
 446         $self->pidl("struct ndr_pull *$comndr;");
 447         $self->pidl("NDR_CHECK(ndr_pull_compression_start($ndr, &$comndr, $alg, $dlen));");
 448
 449         return $comndr;
 450 }
 451
 452 sub ParseCompressionPullEnd($$$$$)
 453 {
 454         my ($self,$e,$l,$ndr,$env) = @_;
 455         my $comndr = "$ndr\_compressed";
 456         my $alg = compression_alg($e, $l);
 457         my $dlen = compression_dlen($e, $l, $env);
 458
 459         $self->pidl("NDR_CHECK(ndr_pull_compression_end($ndr, $comndr, $alg, $dlen));");
 460         $self->deindent;
 461         $self->pidl("}");
 462 }
 463
 464 sub ParseSubcontextPushStart($$$$$)
 465 {
 466         my ($self,$e,$l,$ndr,$env) = @_;
 467         my $subndr = "_ndr_$e->{NAME}";
 468         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 469
 470         $self->pidl("{");
 471         $self->indent;
 472         $self->pidl("struct ndr_push *$subndr;");
 473         $self->pidl("NDR_CHECK(ndr_push_subcontext_start($ndr, &$subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 474
 475         if (defined $l->{COMPRESSION}) {
 476                 $subndr = $self->ParseCompressionPushStart($e, $l, $subndr, $env);
 477         }
 478
 479         return $subndr;
 480 }
 481
 482 sub ParseSubcontextPushEnd($$$$$)
 483 {
 484         my ($self,$e,$l,$ndr,$env) = @_;
 485         my $subndr = "_ndr_$e->{NAME}";
 486         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 487
 488         if (defined $l->{COMPRESSION}) {
 489                 $self->ParseCompressionPushEnd($e, $l, $subndr, $env);
 490         }
 491
 492         $self->pidl("NDR_CHECK(ndr_push_subcontext_end($ndr, $subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 493         $self->deindent;
 494         $self->pidl("}");
 495 }
 496
 497 sub ParseSubcontextPullStart($$$$$)
 498 {
 499         my ($self,$e,$l,$ndr,$env) = @_;
 500         my $subndr = "_ndr_$e->{NAME}";
 501         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 502
 503         $self->pidl("{");
 504         $self->indent;
 505         $self->pidl("struct ndr_pull *$subndr;");
 506         $self->pidl("NDR_CHECK(ndr_pull_subcontext_start($ndr, &$subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 507
 508         if (defined $l->{COMPRESSION}) {
 509                 $subndr = $self->ParseCompressionPullStart($e, $l, $subndr, $env);
 510         }
 511
 512         return $subndr;
 513 }
 514
 515 sub ParseSubcontextPullEnd($$$$$)
 516 {
 517         my ($self,$e,$l,$ndr,$env) = @_;
 518         my $subndr = "_ndr_$e->{NAME}";
 519         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 520
 521         if (defined $l->{COMPRESSION}) {
 522                 $self->ParseCompressionPullEnd($e, $l, $subndr, $env);
 523         }
 524
 525         $self->pidl("NDR_CHECK(ndr_pull_subcontext_end($ndr, $subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 526         $self->deindent;
 527         $self->pidl("}");
 528 }
 529
 530 sub ParseElementPushLevel
 531 {
 532         my ($self,$e,$l,$ndr,$var_name,$env,$primitives,$deferred) = @_;
 533
 534         my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
 535
 536         if ($l->{TYPE} eq "ARRAY" and ($l->{IS_CONFORMANT} or $l->{IS_VARYING})) {
 537                 $var_name = get_pointer_to($var_name);
 538         }
 539
 540         if (defined($ndr_flags)) {
 541                 if ($l->{TYPE} eq "SUBCONTEXT") {
 542                         my $subndr = $self->ParseSubcontextPushStart($e, $l, $ndr, $env);
 543                         $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $subndr, $var_name, $env, 1, 1);
 544                         $self->ParseSubcontextPushEnd($e, $l, $ndr, $env);
 545                 } elsif ($l->{TYPE} eq "POINTER") {
 546                         $self->ParsePtrPush($e, $l, $ndr, $var_name);
 547                 } elsif ($l->{TYPE} eq "ARRAY") {
 548                         my $length = $self->ParseArrayPushHeader($e, $l, $ndr, $var_name, $env);
 549
 550                         my $nl = GetNextLevel($e, $l);
 551
 552                         # Allow speedups for arrays of scalar types
 553                         if (is_charset_array($e,$l)) {
 554                                 $self->pidl("NDR_CHECK(ndr_push_charset($ndr, $ndr_flags, $var_name, $length, sizeof(" . mapTypeName($nl->{DATA_TYPE}) . "), CH_$e->{PROPERTIES}->{charset}));");
 555                                 return;
 556                         } elsif (has_fast_array($e,$l)) {
 557                                 $self->pidl("NDR_CHECK(ndr_push_array_$nl->{DATA_TYPE}($ndr, $ndr_flags, $var_name, $length));");
 558                                 return;
 559                         }
 560                 } elsif ($l->{TYPE} eq "SWITCH") {
 561                         $self->ParseSwitchPush($e, $l, $ndr, $var_name, $env);
 562                 } elsif ($l->{TYPE} eq "DATA") {
 563                         $self->ParseDataPush($e, $l, $ndr, $var_name, $primitives, $deferred);
 564                 } elsif ($l->{TYPE} eq "TYPEDEF") {
 565                         $typefamily{$e->{DATA}->{TYPE}}->{PUSH_FN_BODY}->($self, $e->{DATA}, $ndr, $var_name);
 566                 }
 567         }
 568
 569         if ($l->{TYPE} eq "POINTER" and $deferred) {
 570                 my $rel_var_name = $var_name;
 571                 if ($l->{POINTER_TYPE} ne "ref") {
 572                         $self->pidl("if ($var_name) {");
 573                         $self->indent;
 574                         if ($l->{POINTER_TYPE} eq "relative") {
 575                                 $self->pidl("NDR_CHECK(ndr_push_relative_ptr2_start($ndr, $rel_var_name));");
 576                         }
 577                 }
 578                 $var_name = get_value_of($var_name);
 579                 $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, 1, 1);
 580
 581                 if ($l->{POINTER_TYPE} ne "ref") {
 582                         if ($l->{POINTER_TYPE} eq "relative") {
 583                                 $self->pidl("NDR_CHECK(ndr_push_relative_ptr2_end($ndr, $rel_var_name));");
 584                         }
 585                         $self->deindent;
 586                         $self->pidl("}");
 587                 }
 588         } elsif ($l->{TYPE} eq "ARRAY" and not has_fast_array($e,$l) and
 589                 not is_charset_array($e, $l)) {
 590                 my $length = ParseExpr($l->{LENGTH_IS}, $env, $e->{ORIGINAL});
 591                 my $counter = "cntr_$e->{NAME}_$l->{LEVEL_INDEX}";
 592
 593                 my $array_pointless = ($length eq "0");
 594
 595                 if ($array_pointless) {
 596                         warning($e->{ORIGINAL}, "pointless array `$e->{NAME}' will always have size 0");
 597                 }
 598
 599                 $var_name = get_array_element($var_name, $counter);
 600
 601                 if ((($primitives and not $l->{IS_DEFERRED}) or ($deferred and $l->{IS_DEFERRED})) and not $array_pointless) {
 602                         $self->pidl("for ($counter = 0; $counter < $length; $counter++) {");
 603                         $self->indent;
 604                         $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, 1, 0);
 605                         $self->deindent;
 606                         $self->pidl("}");
 607                 }
 608
 609                 if ($deferred and ContainsDeferred($e, $l) and not $array_pointless) {
 610                         $self->pidl("for ($counter = 0; $counter < $length; $counter++) {");
 611                         $self->indent;
 612                         $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, 0, 1);
 613                         $self->deindent;
 614                         $self->pidl("}");
 615                 }
 616         } elsif ($l->{TYPE} eq "SWITCH") {
 617                 $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, $primitives, $deferred);
 618         }
 619 }
 620
 621 #####################################################################
 622 # parse scalars in a structure element
 623 sub ParseElementPush($$$$$$)
 624 {
 625         my ($self,$e,$ndr,$env,$primitives,$deferred) = @_;
 626         my $subndr = undef;
 627
 628         my $var_name = $env->{$e->{NAME}};
 629
 630         return unless $primitives or ($deferred and ContainsDeferred($e, $e->{LEVELS}[0]));
 631
 632         # Representation type is different from transmit_as
 633         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
 634                 $self->pidl("{");
 635                 $self->indent;
 636                 my $transmit_name = "_transmit_$e->{NAME}";
 637                 $self->pidl(mapTypeName($e->{TYPE}) ." $transmit_name;");
 638                 $self->pidl("NDR_CHECK(ndr_$e->{REPRESENTATION_TYPE}_to_$e->{TYPE}($var_name, " . get_pointer_to($transmit_name) . "));");
 639                 $var_name = $transmit_name;
 640         }
 641
 642         $var_name = append_prefix($e, $var_name);
 643
 644         $self->start_flags($e, $ndr);
 645
 646         if (defined(my $value = has_property($e, "value"))) {
 647                 $var_name = ParseExpr($value, $env, $e->{ORIGINAL});
 648         }
 649
 650         $self->ParseElementPushLevel($e, $e->{LEVELS}[0], $ndr, $var_name, $env, $primitives, $deferred);
 651
 652         $self->end_flags($e, $ndr);
 653
 654         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
 655                 $self->deindent;
 656                 $self->pidl("}");
 657         }
 658 }
 659
 660 #####################################################################
 661 # parse a pointer in a struct element or function
 662 sub ParsePtrPush($$$$$)
 663 {
 664         my ($self,$e,$l,$ndr,$var_name) = @_;
 665
 666         if ($l->{POINTER_TYPE} eq "ref") {
 667                 $self->pidl("if ($var_name == NULL) {");
 668                 $self->indent;
 669                 $self->pidl("return ndr_push_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL [ref] pointer\");");
 670                 $self->deindent;
 671                 $self->pidl("}");
 672                 if ($l->{LEVEL} eq "EMBEDDED") {
 673                         $self->pidl("NDR_CHECK(ndr_push_ref_ptr(ndr));");
 674                 }
 675         } elsif ($l->{POINTER_TYPE} eq "relative") {
 676                 $self->pidl("NDR_CHECK(ndr_push_relative_ptr1($ndr, $var_name));");
 677         } elsif ($l->{POINTER_TYPE} eq "unique") {
 678                 $self->pidl("NDR_CHECK(ndr_push_unique_ptr($ndr, $var_name));");
 679         } elsif ($l->{POINTER_TYPE} eq "full") {
 680                 $self->pidl("NDR_CHECK(ndr_push_full_ptr($ndr, $var_name));");
 681         } else {
 682                 die("Unhandled pointer type $l->{POINTER_TYPE}");
 683         }
 684 }
 685
 686 sub need_pointer_to($$$)
 687 {
 688         my ($e, $l, $scalar_only) = @_;
 689
 690         my $t;
 691         if (ref($l->{DATA_TYPE})) {
 692                 $t = "$l->{DATA_TYPE}->{TYPE}_$l->{DATA_TYPE}->{NAME}";
 693         } else {
 694                 $t = $l->{DATA_TYPE};
 695         }
 696
 697         if (not Parse::Pidl::Typelist::is_scalar($t)) {
 698                 return 1 if $scalar_only;
 699         }
 700
 701         my $arrays = 0;
 702
 703         foreach my $tl (@{$e->{LEVELS}}) {
 704                 last if $l == $tl;
 705                 if ($tl->{TYPE} eq "ARRAY") {
 706                         $arrays++;
 707                 }
 708         }
 709
 710         if (Parse::Pidl::Typelist::scalar_is_reference($t)) {
 711                 return 1 unless $arrays;
 712         }
 713
 714         return 0;
 715 }
 716
 717 sub ParseDataPrint($$$$$)
 718 {
 719         my ($self, $e, $l, $ndr, $var_name) = @_;
 720
 721         if (not ref($l->{DATA_TYPE}) or defined($l->{DATA_TYPE}->{NAME})) {
 722
 723                 if (need_pointer_to($e, $l, 1)) {
 724                         $var_name = get_pointer_to($var_name);
 725                 }
 726
 727                 $self->pidl(TypeFunctionName("ndr_print", $l->{DATA_TYPE})."($ndr, \"$e->{NAME}\", $var_name);");
 728         } else {
 729                 $self->ParseTypePrint($l->{DATA_TYPE}, $ndr, $var_name);
 730         }
 731 }
 732
 733 #####################################################################
 734 # print scalars in a structure element
 735 sub ParseElementPrint($$$$$)
 736 {
 737         my($self, $e, $ndr, $var_name, $env) = @_;
 738
 739         return if (has_property($e, "noprint"));
 740
 741         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
 742                 $self->pidl("ndr_print_$e->{REPRESENTATION_TYPE}($ndr, \"$e->{NAME}\", $var_name);");
 743                 return;
 744         }
 745
 746         $var_name = append_prefix($e, $var_name);
 747
 748         if (defined(my $value = has_property($e, "value"))) {
 749                 $var_name = "($ndr->flags & LIBNDR_PRINT_SET_VALUES)?" . ParseExpr($value,$env, $e->{ORIGINAL}) . ":$var_name";
 750         }
 751
 752         foreach my $l (@{$e->{LEVELS}}) {
 753                 if ($l->{TYPE} eq "POINTER") {
 754                         $self->pidl("ndr_print_ptr($ndr, \"$e->{NAME}\", $var_name);");
 755                         $self->pidl("$ndr->depth++;");
 756                         if ($l->{POINTER_TYPE} ne "ref") {
 757                                 $self->pidl("if ($var_name) {");
 758                                 $self->indent;
 759                         }
 760                         $var_name = get_value_of($var_name);
 761                 } elsif ($l->{TYPE} eq "ARRAY") {
 762                         my $length;
 763
 764                         if ($l->{IS_CONFORMANT} or $l->{IS_VARYING}) {
 765                                 $var_name = get_pointer_to($var_name);
 766                         }
 767
 768                         if ($l->{IS_ZERO_TERMINATED}) {
 769                                 $length = "ndr_string_length($var_name, sizeof(*$var_name))";
 770                         } else {
 771                                 $length = ParseExprExt($l->{LENGTH_IS}, $env, $e->{ORIGINAL},
 772                                                         check_null_pointer($e, $env, sub { $self->pidl(shift); }, "return;"), check_fully_dereferenced($e, $env));
 773                         }
 774
 775                         if (is_charset_array($e,$l)) {
 776                                 $self->pidl("ndr_print_string($ndr, \"$e->{NAME}\", $var_name);");
 777                                 last;
 778                         } elsif (has_fast_array($e, $l)) {
 779                                 my $nl = GetNextLevel($e, $l);
 780                                 $self->pidl("ndr_print_array_$nl->{DATA_TYPE}($ndr, \"$e->{NAME}\", $var_name, $length);");
 781                                 last;
 782                         } else {
 783                                 my $counter = "cntr_$e->{NAME}_$l->{LEVEL_INDEX}";
 784
 785                                 $self->pidl("$ndr->print($ndr, \"\%s: ARRAY(\%d)\", \"$e->{NAME}\", (int)$length);");
 786                                 $self->pidl("$ndr->depth++;");
 787                                 $self->pidl("for ($counter=0;$counter<$length;$counter++) {");
 788                                 $self->indent;
 789                                 $self->pidl("char *idx_$l->{LEVEL_INDEX}=NULL;");
 790                                 $self->pidl("if (asprintf(&idx_$l->{LEVEL_INDEX}, \"[\%d]\", $counter) != -1) {");
 791                                 $self->indent;
 792
 793                                 $var_name = get_array_element($var_name, $counter);
 794                         }
 795                 } elsif ($l->{TYPE} eq "DATA") {
 796                         $self->ParseDataPrint($e, $l, $ndr, $var_name);
 797                 } elsif ($l->{TYPE} eq "SWITCH") {
 798                         my $switch_var = ParseExprExt($l->{SWITCH_IS}, $env, $e->{ORIGINAL},
 799                                                 check_null_pointer($e, $env, sub { $self->pidl(shift); }, "return;"), check_fully_dereferenced($e, $env));
 800                         $self->pidl("ndr_print_set_switch_value($ndr, " . get_pointer_to($var_name) . ", $switch_var);");
 801                 }
 802         }
 803
 804         foreach my $l (reverse @{$e->{LEVELS}}) {
 805                 if ($l->{TYPE} eq "POINTER") {
 806                         if ($l->{POINTER_TYPE} ne "ref") {
 807                                 $self->deindent;
 808                                 $self->pidl("}");
 809                         }
 810                         $self->pidl("$ndr->depth--;");
 811                 } elsif (($l->{TYPE} eq "ARRAY")
 812                         and not is_charset_array($e,$l)
 813                         and not has_fast_array($e,$l)) {
 814                         $self->pidl("free(idx_$l->{LEVEL_INDEX});");
 815                         $self->deindent;
 816                         $self->pidl("}");
 817                         $self->deindent;
 818                         $self->pidl("}");
 819                         $self->pidl("$ndr->depth--;");
 820                 }
 821         }
 822 }
 823
 824 #####################################################################
 825 # parse scalars in a structure element - pull size
 826 sub ParseSwitchPull($$$$$$)
 827 {
 828         my($self,$e,$l,$ndr,$var_name,$env) = @_;
 829         my $switch_var = ParseExprExt($l->{SWITCH_IS}, $env, $e->{ORIGINAL},
 830                 check_null_pointer($e, $env, sub { $self->pidl(shift); },
 831                                    "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for switch_is()\");"),
 832                 check_fully_dereferenced($e, $env));
 833
 834         $var_name = get_pointer_to($var_name);
 835         $self->pidl("NDR_CHECK(ndr_pull_set_switch_value($ndr, $var_name, $switch_var));");
 836 }
 837
 838 #####################################################################
 839 # push switch element
 840 sub ParseSwitchPush($$$$$$)
 841 {
 842         my($self,$e,$l,$ndr,$var_name,$env) = @_;
 843         my $switch_var = ParseExprExt($l->{SWITCH_IS}, $env, $e->{ORIGINAL},
 844                 check_null_pointer($e, $env, sub { $self->pidl(shift); },
 845                                    "return ndr_push_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for switch_is()\");"),
 846                 check_fully_dereferenced($e, $env));
 847
 848         $var_name = get_pointer_to($var_name);
 849         $self->pidl("NDR_CHECK(ndr_push_set_switch_value($ndr, $var_name, $switch_var));");
 850 }
 851
 852 sub ParseDataPull($$$$$$$)
 853 {
 854         my ($self,$e,$l,$ndr,$var_name,$primitives,$deferred) = @_;
 855
 856         if (not ref($l->{DATA_TYPE}) or defined($l->{DATA_TYPE}->{NAME})) {
 857
 858                 my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
 859
 860                 if (need_pointer_to($e, $l, 0)) {
 861                         $var_name = get_pointer_to($var_name);
 862                 }
 863
 864                 $var_name = get_pointer_to($var_name);
 865
 866                 $self->pidl("NDR_CHECK(".TypeFunctionName("ndr_pull", $l->{DATA_TYPE})."($ndr, $ndr_flags, $var_name));");
 867
 868                 my $pl = GetPrevLevel($e, $l);
 869
 870                 my $range = has_property($e, "range");
 871                 if ($range and $pl->{TYPE} ne "ARRAY") {
 872                         $var_name = get_value_of($var_name);
 873                         my $signed = Parse::Pidl::Typelist::is_signed($l->{DATA_TYPE});
 874                         my ($low, $high) = split(/,/, $range, 2);
 875                         if ($low < 0 and not $signed) {
 876                                 warning(0, "$low is invalid for the range of an unsigned type");
 877                         }
 878                         if ($low == 0 and not $signed) {
 879                                 $self->pidl("if ($var_name > $high) {");
 880                         } else {
 881                                 $self->pidl("if ($var_name < $low || $var_name > $high) {");
 882                         }
 883                         $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_RANGE, \"value out of range\");");
 884                         $self->pidl("}");
 885                 }
 886         } else {
 887                 $self->ParseTypePull($l->{DATA_TYPE}, $ndr, $var_name, $primitives, $deferred);
 888         }
 889 }
 890
 891 sub ParseDataPush($$$$$$$)
 892 {
 893         my ($self,$e,$l,$ndr,$var_name,$primitives,$deferred) = @_;
 894
 895         if (not ref($l->{DATA_TYPE}) or defined($l->{DATA_TYPE}->{NAME})) {
 896
 897                 my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
 898
 899                 # strings are passed by value rather than reference
 900                 if (need_pointer_to($e, $l, 1)) {
 901                         $var_name = get_pointer_to($var_name);
 902                 }
 903
 904                 $self->pidl("NDR_CHECK(".TypeFunctionName("ndr_push", $l->{DATA_TYPE})."($ndr, $ndr_flags, $var_name));");
 905         } else {
 906                 $self->ParseTypePush($l->{DATA_TYPE}, $ndr, $var_name, $primitives, $deferred);
 907         }
 908 }
 909
 910 sub CalcNdrFlags($$$)
 911 {
 912         my ($l,$primitives,$deferred) = @_;
 913
 914         my $scalars = 0;
 915         my $buffers = 0;
 916
 917         # Add NDR_SCALARS if this one is deferred
 918         # and deferreds may be pushed
 919         $scalars = 1 if ($l->{IS_DEFERRED} and $deferred);
 920
 921         # Add NDR_SCALARS if this one is not deferred and
 922         # primitives may be pushed
 923         $scalars = 1 if (!$l->{IS_DEFERRED} and $primitives);
 924
 925         # Add NDR_BUFFERS if this one contains deferred stuff
 926         # and deferreds may be pushed
 927         $buffers = 1 if ($l->{CONTAINS_DEFERRED} and $deferred);
 928
 929         return "NDR_SCALARS|NDR_BUFFERS" if ($scalars and $buffers);
 930         return "NDR_SCALARS" if ($scalars);
 931         return "NDR_BUFFERS" if ($buffers);
 932         return undef;
 933 }
 934
 935 sub ParseMemCtxPullFlags($$$$)
 936 {
 937         my ($self, $e, $l) = @_;
 938
 939         return undef unless ($l->{TYPE} eq "POINTER" or $l->{TYPE} eq "ARRAY");
 940
 941         return undef unless ($l->{TYPE} ne "ARRAY" or ArrayDynamicallyAllocated($e,$l));
 942         return undef if has_fast_array($e, $l);
 943         return undef if is_charset_array($e, $l);
 944
 945         my $mem_flags = "0";
 946
 947         if (($l->{TYPE} eq "POINTER") and ($l->{POINTER_TYPE} eq "ref")) {
 948                 my $nl = GetNextLevel($e, $l);
 949                 my $next_is_array = ($nl->{TYPE} eq "ARRAY");
 950                 my $next_is_string = (($nl->{TYPE} eq "DATA") and
 951                                         ($nl->{DATA_TYPE} eq "string"));
 952                 if ($next_is_array or $next_is_string) {
 953                         return undef;
 954                 } elsif ($l->{LEVEL} eq "TOP") {
 955                         $mem_flags = "LIBNDR_FLAG_REF_ALLOC";
 956                 }
 957         }
 958
 959         return $mem_flags;
 960 }
 961
 962 sub ParseMemCtxPullStart($$$$$)
 963 {
 964         my ($self, $e, $l, $ndr, $ptr_name) = @_;
 965
 966         my $mem_r_ctx = "_mem_save_$e->{NAME}_$l->{LEVEL_INDEX}";
 967         my $mem_c_ctx = $ptr_name;
 968         my $mem_c_flags = $self->ParseMemCtxPullFlags($e, $l);
 969
 970         return unless defined($mem_c_flags);
 971
 972         $self->pidl("$mem_r_ctx = NDR_PULL_GET_MEM_CTX($ndr);");
 973         $self->pidl("NDR_PULL_SET_MEM_CTX($ndr, $mem_c_ctx, $mem_c_flags);");
 974 }
 975
 976 sub ParseMemCtxPullEnd($$$$)
 977 {
 978         my ($self, $e, $l, $ndr) = @_;
 979
 980         my $mem_r_ctx = "_mem_save_$e->{NAME}_$l->{LEVEL_INDEX}";
 981         my $mem_r_flags = $self->ParseMemCtxPullFlags($e, $l);
 982
 983         return unless defined($mem_r_flags);
 984
 985         $self->pidl("NDR_PULL_SET_MEM_CTX($ndr, $mem_r_ctx, $mem_r_flags);");
 986 }
 987
 988 sub CheckStringTerminator($$$$$)
 989 {
 990         my ($self,$ndr,$e,$l,$length) = @_;
 991         my $nl = GetNextLevel($e, $l);
 992
 993         # Make sure last element is zero!
 994         $self->pidl("NDR_CHECK(ndr_check_string_terminator($ndr, $length, sizeof($nl->{DATA_TYPE}_t)));");
 995 }
 996
 997 sub ParseElementPullLevel
 998 {
 999         my($self,$e,$l,$ndr,$var_name,$env,$primitives,$deferred) = @_;
1000
1001         my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
1002
1003         if ($l->{TYPE} eq "ARRAY" and ($l->{IS_VARYING} or $l->{IS_CONFORMANT})) {
1004                 $var_name = get_pointer_to($var_name);
1005         }
1006
1007         # Only pull something if there's actually something to be pulled
1008         if (defined($ndr_flags)) {
1009                 if ($l->{TYPE} eq "SUBCONTEXT") {
1010                         my $subndr = $self->ParseSubcontextPullStart($e, $l, $ndr, $env);
1011                         $self->ParseElementPullLevel($e, GetNextLevel($e,$l), $subndr, $var_name, $env, 1, 1);
1012                         $self->ParseSubcontextPullEnd($e, $l, $ndr, $env);
1013                 } elsif ($l->{TYPE} eq "ARRAY") {
1014                         my $length = $self->ParseArrayPullHeader($e, $l, $ndr, $var_name, $env);
1015
1016                         if (my $range = has_property($e, "range")) {
1017                                 my ($low, $high) = split(/,/, $range, 2);
1018                                 if ($low < 0) {
1019                                         warning(0, "$low is invalid for the range of an array size");
1020                                 }
1021                                 if ($low == 0) {
1022                                         $self->pidl("if ($length > $high) {");
1023                                 } else {
1024                                         $self->pidl("if ($length < $low || $length > $high) {");
1025                                 }
1026                                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_RANGE, \"value out of range\");");
1027                                 $self->pidl("}");
1028                         }
1029
1030                         my $nl = GetNextLevel($e, $l);
1031
1032                         if (is_charset_array($e,$l)) {
1033                                 if ($l->{IS_ZERO_TERMINATED}) {
1034                                         $self->CheckStringTerminator($ndr, $e, $l, $length);
1035                                 }
1036                                 $self->pidl("NDR_CHECK(ndr_pull_charset($ndr, $ndr_flags, ".get_pointer_to($var_name).", $length, sizeof(" . mapTypeName($nl->{DATA_TYPE}) . "), CH_$e->{PROPERTIES}->{charset}));");
1037                                 return;
1038                         } elsif (has_fast_array($e, $l)) {
1039                                 if ($l->{IS_ZERO_TERMINATED}) {
1040                                         $self->CheckStringTerminator($ndr,$e,$l,$length);
1041                                 }
1042                                 $self->pidl("NDR_CHECK(ndr_pull_array_$nl->{DATA_TYPE}($ndr, $ndr_flags, $var_name, $length));");
1043                                 return;
1044                         }
1045                 } elsif ($l->{TYPE} eq "POINTER") {
1046                         $self->ParsePtrPull($e, $l, $ndr, $var_name);
1047                 } elsif ($l->{TYPE} eq "SWITCH") {
1048                         $self->ParseSwitchPull($e, $l, $ndr, $var_name, $env);
1049                 } elsif ($l->{TYPE} eq "DATA") {
1050                         $self->ParseDataPull($e, $l, $ndr, $var_name, $primitives, $deferred);
1051                 } elsif ($l->{TYPE} eq "TYPEDEF") {
1052                         $typefamily{$e->{DATA}->{TYPE}}->{PULL_FN_BODY}->($self, $e->{DATA}, $ndr, $var_name);
1053                 }
1054         }
1055
1056         # add additional constructions
1057         if ($l->{TYPE} eq "POINTER" and $deferred) {
1058                 if ($l->{POINTER_TYPE} ne "ref") {
1059                         $self->pidl("if ($var_name) {");
1060                         $self->indent;
1061
1062                         if ($l->{POINTER_TYPE} eq "relative") {
1063                                 $self->pidl("uint32_t _relative_save_offset;");
1064                                 $self->pidl("_relative_save_offset = $ndr->offset;");
1065                                 $self->pidl("NDR_CHECK(ndr_pull_relative_ptr2($ndr, $var_name));");
1066                         }
1067                 }
1068
1069                 $self->ParseMemCtxPullStart($e, $l, $ndr, $var_name);
1070
1071                 $var_name = get_value_of($var_name);
1072                 $self->ParseElementPullLevel($e, GetNextLevel($e,$l), $ndr, $var_name, $env, 1, 1);
1073
1074                 $self->ParseMemCtxPullEnd($e, $l, $ndr);
1075
1076                 if ($l->{POINTER_TYPE} ne "ref") {
1077                         if ($l->{POINTER_TYPE} eq "relative") {
1078                                 $self->pidl("$ndr->offset = _relative_save_offset;");
1079                         }
1080                         $self->deindent;
1081                         $self->pidl("}");
1082                 }
1083         } elsif ($l->{TYPE} eq "ARRAY" and
1084                         not has_fast_array($e,$l) and not is_charset_array($e, $l)) {
1085                 my $length = ParseExpr($l->{LENGTH_IS}, $env, $e->{ORIGINAL});
1086                 my $counter = "cntr_$e->{NAME}_$l->{LEVEL_INDEX}";
1087                 my $array_name = $var_name;
1088
1089                 if ($l->{IS_VARYING}) {
1090                         $length = "ndr_get_array_length($ndr, " . get_pointer_to($var_name) .")";
1091                 }
1092
1093                 if (my $range = has_property($e, "range")) {
1094                         my ($low, $high) = split(/,/, $range, 2);
1095                         if ($low < 0) {
1096                                 warning(0, "$low is invalid for the range of an array size");
1097                         }
1098                         if ($low == 0) {
1099                                 $self->pidl("if ($length > $high) {");
1100                         } else {
1101                                 $self->pidl("if ($length < $low || $length > $high) {");
1102                         }
1103                         $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_RANGE, \"value out of range\");");
1104                         $self->pidl("}");
1105                 }
1106
1107                 $var_name = get_array_element($var_name, $counter);
1108
1109                 $self->ParseMemCtxPullStart($e, $l, $ndr, $array_name);
1110
1111                 if (($primitives and not $l->{IS_DEFERRED}) or ($deferred and $l->{IS_DEFERRED})) {
1112                         my $nl = GetNextLevel($e,$l);
1113
1114                         if ($l->{IS_ZERO_TERMINATED}) {
1115                                 $self->CheckStringTerminator($ndr,$e,$l,$length);
1116                         }
1117
1118                         $self->pidl("for ($counter = 0; $counter < $length; $counter++) {");
1119                         $self->indent;
1120                         $self->ParseElementPullLevel($e, $nl, $ndr, $var_name, $env, 1, 0);
1121                         $self->deindent;
1122                         $self->pidl("}");
1123                 }
1124
1125                 if ($deferred and ContainsDeferred($e, $l)) {
1126                         $self->pidl("for ($counter = 0; $counter < $length; $counter++) {");
1127                         $self->indent;
1128                         $self->ParseElementPullLevel($e,GetNextLevel($e,$l), $ndr, $var_name, $env, 0, 1);
1129                         $self->deindent;
1130                         $self->pidl("}");
1131                 }
1132
1133                 $self->ParseMemCtxPullEnd($e, $l, $ndr);
1134
1135         } elsif ($l->{TYPE} eq "SWITCH") {
1136                 $self->ParseElementPullLevel($e, GetNextLevel($e,$l), $ndr, $var_name, $env, $primitives, $deferred);
1137         }
1138 }
1139
1140 #####################################################################
1141 # parse scalars in a structure element - pull size
1142 sub ParseElementPull($$$$$$)
1143 {
1144         my($self,$e,$ndr,$env,$primitives,$deferred) = @_;
1145
1146         my $var_name = $env->{$e->{NAME}};
1147         my $represent_name;
1148         my $transmit_name;
1149
1150         return unless $primitives or ($deferred and ContainsDeferred($e, $e->{LEVELS}[0]));
1151
1152         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
1153                 $self->pidl("{");
1154                 $self->indent;
1155                 $represent_name = $var_name;
1156                 $transmit_name = "_transmit_$e->{NAME}";
1157                 $var_name = $transmit_name;
1158                 $self->pidl(mapTypeName($e->{TYPE})." $var_name;");
1159         }
1160
1161         $var_name = append_prefix($e, $var_name);
1162
1163         $self->start_flags($e, $ndr);
1164
1165         $self->ParseElementPullLevel($e,$e->{LEVELS}[0],$ndr,$var_name,$env,$primitives,$deferred);
1166
1167         $self->end_flags($e, $ndr);
1168
1169         # Representation type is different from transmit_as
1170         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
1171                 $self->pidl("NDR_CHECK(ndr_$e->{TYPE}_to_$e->{REPRESENTATION_TYPE}($transmit_name, ".get_pointer_to($represent_name)."));");
1172                 $self->deindent;
1173                 $self->pidl("}");
1174         }
1175 }
1176
1177 #####################################################################
1178 # parse a pointer in a struct element or function
1179 sub ParsePtrPull($$$$$)
1180 {
1181         my($self, $e,$l,$ndr,$var_name) = @_;
1182
1183         my $nl = GetNextLevel($e, $l);
1184         my $next_is_array = ($nl->{TYPE} eq "ARRAY");
1185         my $next_is_string = (($nl->{TYPE} eq "DATA") and
1186                                                  ($nl->{DATA_TYPE} eq "string"));
1187
1188         if ($l->{POINTER_TYPE} eq "ref" and $l->{LEVEL} eq "TOP") {
1189
1190                 if (!$next_is_array and !$next_is_string) {
1191                         $self->pidl("if ($ndr->flags & LIBNDR_FLAG_REF_ALLOC) {");
1192                         $self->pidl("\tNDR_PULL_ALLOC($ndr, $var_name);");
1193                         $self->pidl("}");
1194                 }
1195
1196                 return;
1197         } elsif ($l->{POINTER_TYPE} eq "ref" and $l->{LEVEL} eq "EMBEDDED") {
1198                 $self->pidl("NDR_CHECK(ndr_pull_ref_ptr($ndr, &_ptr_$e->{NAME}));");
1199         } elsif (($l->{POINTER_TYPE} eq "unique") or
1200                  ($l->{POINTER_TYPE} eq "relative") or
1201                  ($l->{POINTER_TYPE} eq "full")) {
1202                 $self->pidl("NDR_CHECK(ndr_pull_generic_ptr($ndr, &_ptr_$e->{NAME}));");
1203         } else {
1204                 die("Unhandled pointer type $l->{POINTER_TYPE}");
1205         }
1206
1207         $self->pidl("if (_ptr_$e->{NAME}) {");
1208         $self->indent;
1209
1210         # Don't do this for arrays, they're allocated at the actual level
1211         # of the array
1212         unless ($next_is_array or $next_is_string) {
1213                 $self->pidl("NDR_PULL_ALLOC($ndr, $var_name);");
1214         } else {
1215                 # FIXME: Yes, this is nasty.
1216                 # We allocate an array twice
1217                 # - once just to indicate that it's there,
1218                 # - then the real allocation...
1219                 $self->pidl("NDR_PULL_ALLOC($ndr, $var_name);");
1220         }
1221
1222         #$self->pidl("memset($var_name, 0, sizeof($var_name));");
1223         if ($l->{POINTER_TYPE} eq "relative") {
1224                 $self->pidl("NDR_CHECK(ndr_pull_relative_ptr1($ndr, $var_name, _ptr_$e->{NAME}));");
1225         }
1226         $self->deindent;
1227         $self->pidl("} else {");
1228         $self->pidl("\t$var_name = NULL;");
1229         $self->pidl("}");
1230 }
1231
1232 sub ParseStructPushPrimitives($$$$$)
1233 {
1234         my ($self, $struct, $ndr, $varname, $env) = @_;
1235
1236         # see if the structure contains a conformant array. If it
1237         # does, then it must be the last element of the structure, and
1238         # we need to push the conformant length early, as it fits on
1239         # the wire before the structure (and even before the structure
1240         # alignment)
1241         if (defined($struct->{SURROUNDING_ELEMENT})) {
1242                 my $e = $struct->{SURROUNDING_ELEMENT};
1243
1244                 if (defined($e->{LEVELS}[0]) and
1245                         $e->{LEVELS}[0]->{TYPE} eq "ARRAY") {
1246                         my $size;
1247
1248                         if ($e->{LEVELS}[0]->{IS_ZERO_TERMINATED}) {
1249                                 if (has_property($e, "charset")) {
1250                                         $size = "ndr_charset_length($varname->$e->{NAME}, CH_$e->{PROPERTIES}->{charset})";
1251                                 } else {
1252                                         $size = "ndr_string_length($varname->$e->{NAME}, sizeof(*$varname->$e->{NAME}))";
1253                                 }
1254                         } else {
1255                                 $size = ParseExpr($e->{LEVELS}[0]->{SIZE_IS}, $env, $e->{ORIGINAL});
1256                         }
1257
1258                         $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, $size));");
1259                 } else {
1260                         $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, ndr_string_array_size($ndr, $varname->$e->{NAME})));");
1261                 }
1262         }
1263
1264         $self->pidl("NDR_CHECK(ndr_push_align($ndr, $struct->{ALIGN}));");
1265
1266         if (defined($struct->{PROPERTIES}{relative_base})) {
1267                 # set the current offset as base for relative pointers
1268                 # and store it based on the toplevel struct/union
1269                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1270         }
1271
1272         $self->ParseElementPush($_, $ndr, $env, 1, 0) foreach (@{$struct->{ELEMENTS}});
1273
1274         $self->pidl("NDR_CHECK(ndr_push_trailer_align($ndr, $struct->{ALIGN}));");
1275 }
1276
1277 sub ParseStructPushDeferred($$$$)
1278 {
1279         my ($self, $struct, $ndr, $varname, $env) = @_;
1280         if (defined($struct->{PROPERTIES}{relative_base})) {
1281                 # retrieve the current offset as base for relative pointers
1282                 # based on the toplevel struct/union
1283                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset2($ndr, $varname));");
1284         }
1285         $self->ParseElementPush($_, $ndr, $env, 0, 1) foreach (@{$struct->{ELEMENTS}});
1286 }
1287
1288 #####################################################################
1289 # parse a struct
1290 sub ParseStructPush($$$$)
1291 {
1292         my ($self, $struct, $ndr, $varname) = @_;
1293
1294         return unless defined($struct->{ELEMENTS});
1295
1296         my $env = GenerateStructEnv($struct, $varname);
1297
1298         EnvSubstituteValue($env, $struct);
1299
1300         $self->DeclareArrayVariablesNoZero($_, $env) foreach (@{$struct->{ELEMENTS}});
1301
1302         $self->start_flags($struct, $ndr);
1303
1304         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
1305         $self->indent;
1306         $self->ParseStructPushPrimitives($struct, $ndr, $varname, $env);
1307         $self->deindent;
1308         $self->pidl("}");
1309
1310         $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
1311         $self->indent;
1312         $self->ParseStructPushDeferred($struct, $ndr, $varname, $env);
1313         $self->deindent;
1314         $self->pidl("}");
1315
1316         $self->end_flags($struct, $ndr);
1317 }
1318
1319 #####################################################################
1320 # generate a push function for an enum
1321 sub ParseEnumPush($$$$)
1322 {
1323         my($self,$enum,$ndr,$varname) = @_;
1324         my($type_fn) = $enum->{BASE_TYPE};
1325
1326         $self->start_flags($enum, $ndr);
1327         $self->pidl("NDR_CHECK(ndr_push_enum_$type_fn($ndr, NDR_SCALARS, $varname));");
1328         $self->end_flags($enum, $ndr);
1329 }
1330
1331 #####################################################################
1332 # generate a pull function for an enum
1333 sub ParseEnumPull($$$$)
1334 {
1335         my($self,$enum,$ndr,$varname) = @_;
1336         my($type_fn) = $enum->{BASE_TYPE};
1337         my($type_v_decl) = mapTypeName($type_fn);
1338
1339         $self->pidl("$type_v_decl v;");
1340         $self->start_flags($enum, $ndr);
1341         $self->pidl("NDR_CHECK(ndr_pull_enum_$type_fn($ndr, NDR_SCALARS, &v));");
1342         $self->pidl("*$varname = v;");
1343
1344         $self->end_flags($enum, $ndr);
1345 }
1346
1347 #####################################################################
1348 # generate a print function for an enum
1349 sub ParseEnumPrint($$$$$)
1350 {
1351         my($self,$enum,$ndr,$name,$varname) = @_;
1352
1353         $self->pidl("const char *val = NULL;");
1354         $self->pidl("");
1355
1356         $self->start_flags($enum, $ndr);
1357
1358         $self->pidl("switch ($varname) {");
1359         $self->indent;
1360         my $els = \@{$enum->{ELEMENTS}};
1361         foreach my $i (0 .. $#{$els}) {
1362                 my $e = ${$els}[$i];
1363                 chomp $e;
1364                 if ($e =~ /^(.*)=/) {
1365                         $e = $1;
1366                 }
1367                 $self->pidl("case $e: val = \"$e\"; break;");
1368         }
1369
1370         $self->deindent;
1371         $self->pidl("}");
1372
1373         $self->pidl("ndr_print_enum($ndr, name, \"$enum->{TYPE}\", val, $varname);");
1374
1375         $self->end_flags($enum, $ndr);
1376 }
1377
1378 sub DeclEnum($$$$)
1379 {
1380         my ($e,$t,$name,$varname) = @_;
1381         return "enum $name " .
1382                 ($t eq "pull"?"*":"") . $varname;
1383 }
1384
1385 $typefamily{ENUM} = {
1386         DECL => \&DeclEnum,
1387         PUSH_FN_BODY => \&ParseEnumPush,
1388         PULL_FN_BODY => \&ParseEnumPull,
1389         PRINT_FN_BODY => \&ParseEnumPrint,
1390 };
1391
1392 #####################################################################
1393 # generate a push function for a bitmap
1394 sub ParseBitmapPush($$$$)
1395 {
1396         my($self,$bitmap,$ndr,$varname) = @_;
1397         my($type_fn) = $bitmap->{BASE_TYPE};
1398
1399         $self->start_flags($bitmap, $ndr);
1400
1401         $self->pidl("NDR_CHECK(ndr_push_$type_fn($ndr, NDR_SCALARS, $varname));");
1402
1403         $self->end_flags($bitmap, $ndr);
1404 }
1405
1406 #####################################################################
1407 # generate a pull function for an bitmap
1408 sub ParseBitmapPull($$$$)
1409 {
1410         my($self,$bitmap,$ndr,$varname) = @_;
1411         my $type_fn = $bitmap->{BASE_TYPE};
1412         my($type_decl) = mapTypeName($bitmap->{BASE_TYPE});
1413
1414         $self->pidl("$type_decl v;");
1415         $self->start_flags($bitmap, $ndr);
1416         $self->pidl("NDR_CHECK(ndr_pull_$type_fn($ndr, NDR_SCALARS, &v));");
1417         $self->pidl("*$varname = v;");
1418
1419         $self->end_flags($bitmap, $ndr);
1420 }
1421
1422 #####################################################################
1423 # generate a print function for an bitmap
1424 sub ParseBitmapPrintElement($$$$$$)
1425 {
1426         my($self,$e,$bitmap,$ndr,$name,$varname) = @_;
1427         my($type_decl) = mapTypeName($bitmap->{BASE_TYPE});
1428         my($type_fn) = $bitmap->{BASE_TYPE};
1429         my($flag);
1430
1431         if ($e =~ /^(\w+) .*$/) {
1432                 $flag = "$1";
1433         } else {
1434                 die "Bitmap: \"$name\" invalid Flag: \"$e\"";
1435         }
1436
1437         $self->pidl("ndr_print_bitmap_flag($ndr, sizeof($type_decl), \"$flag\", $flag, $varname);");
1438 }
1439
1440 #####################################################################
1441 # generate a print function for an bitmap
1442 sub ParseBitmapPrint($$$$$)
1443 {
1444         my($self,$bitmap,$ndr,$name,$varname) = @_;
1445         my($type_decl) = mapTypeName($bitmap->{TYPE});
1446         my($type_fn) = $bitmap->{BASE_TYPE};
1447
1448         $self->start_flags($bitmap, $ndr);
1449
1450         $self->pidl("ndr_print_$type_fn($ndr, name, $varname);");
1451
1452         $self->pidl("$ndr->depth++;");
1453         foreach my $e (@{$bitmap->{ELEMENTS}}) {
1454                 $self->ParseBitmapPrintElement($e, $bitmap, $ndr, $name, $varname);
1455         }
1456         $self->pidl("$ndr->depth--;");
1457
1458         $self->end_flags($bitmap, $ndr);
1459 }
1460
1461 sub DeclBitmap($$$$)
1462 {
1463         my ($e,$t,$name,$varname) = @_;
1464         return mapTypeName(Parse::Pidl::Typelist::bitmap_type_fn($e)) .
1465                 ($t eq "pull"?" *":" ") . $varname;
1466 }
1467
1468 $typefamily{BITMAP} = {
1469         DECL => \&DeclBitmap,
1470         PUSH_FN_BODY => \&ParseBitmapPush,
1471         PULL_FN_BODY => \&ParseBitmapPull,
1472         PRINT_FN_BODY => \&ParseBitmapPrint,
1473 };
1474
1475 #####################################################################
1476 # generate a struct print function
1477 sub ParseStructPrint($$$$$)
1478 {
1479         my($self,$struct,$ndr,$name,$varname) = @_;
1480
1481         return unless defined $struct->{ELEMENTS};
1482
1483         my $env = GenerateStructEnv($struct, $varname);
1484
1485         $self->DeclareArrayVariables($_) foreach (@{$struct->{ELEMENTS}});
1486
1487         $self->pidl("ndr_print_struct($ndr, name, \"$name\");");
1488
1489         $self->start_flags($struct, $ndr);
1490
1491         $self->pidl("$ndr->depth++;");
1492
1493         $self->ParseElementPrint($_, $ndr, $env->{$_->{NAME}}, $env)
1494                 foreach (@{$struct->{ELEMENTS}});
1495         $self->pidl("$ndr->depth--;");
1496
1497         $self->end_flags($struct, $ndr);
1498 }
1499
1500 sub DeclarePtrVariables($$)
1501 {
1502         my ($self,$e) = @_;
1503         foreach my $l (@{$e->{LEVELS}}) {
1504                 if ($l->{TYPE} eq "POINTER" and
1505                         not ($l->{POINTER_TYPE} eq "ref" and $l->{LEVEL} eq "TOP")) {
1506                         $self->pidl("uint32_t _ptr_$e->{NAME};");
1507                         last;
1508                 }
1509         }
1510 }
1511
1512 sub DeclareArrayVariables($$)
1513 {
1514         my ($self,$e) = @_;
1515
1516         foreach my $l (@{$e->{LEVELS}}) {
1517                 next if has_fast_array($e,$l);
1518                 next if is_charset_array($e,$l);
1519                 if ($l->{TYPE} eq "ARRAY") {
1520                         $self->pidl("uint32_t cntr_$e->{NAME}_$l->{LEVEL_INDEX};");
1521                 }
1522         }
1523 }
1524
1525 sub DeclareArrayVariablesNoZero($$$)
1526 {
1527         my ($self,$e,$env) = @_;
1528
1529         foreach my $l (@{$e->{LEVELS}}) {
1530                 next if has_fast_array($e,$l);
1531                 next if is_charset_array($e,$l);
1532                 if ($l->{TYPE} eq "ARRAY") {
1533                     my $length = ParseExpr($l->{LENGTH_IS}, $env, $e->{ORIGINAL});
1534                     if ($length eq "0") {
1535                         warning($e->{ORIGINAL}, "pointless array cntr: 'cntr_$e->{NAME}_$l->{LEVEL_INDEX}': length=$length");
1536                     } else {
1537                         $self->pidl("uint32_t cntr_$e->{NAME}_$l->{LEVEL_INDEX};");
1538                     }
1539                 }
1540         }
1541 }
1542
1543 sub DeclareMemCtxVariables($$)
1544 {
1545         my ($self,$e) = @_;
1546         foreach my $l (@{$e->{LEVELS}}) {
1547                 my $mem_flags = $self->ParseMemCtxPullFlags($e, $l);
1548                 if (defined($mem_flags)) {
1549                         $self->pidl("TALLOC_CTX *_mem_save_$e->{NAME}_$l->{LEVEL_INDEX};");
1550                 }
1551         }
1552 }
1553
1554 sub ParseStructPullPrimitives($$$$$)
1555 {
1556         my($self,$struct,$ndr,$varname,$env) = @_;
1557
1558         if (defined $struct->{SURROUNDING_ELEMENT}) {
1559                 $self->pidl("NDR_CHECK(ndr_pull_array_size($ndr, &$varname->$struct->{SURROUNDING_ELEMENT}->{NAME}));");
1560         }
1561
1562         $self->pidl("NDR_CHECK(ndr_pull_align($ndr, $struct->{ALIGN}));");
1563
1564         if (defined($struct->{PROPERTIES}{relative_base})) {
1565                 # set the current offset as base for relative pointers
1566                 # and store it based on the toplevel struct/union
1567                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1568         }
1569
1570         $self->ParseElementPull($_, $ndr, $env, 1, 0) foreach (@{$struct->{ELEMENTS}});
1571
1572         $self->add_deferred();
1573
1574         $self->pidl("NDR_CHECK(ndr_pull_trailer_align($ndr, $struct->{ALIGN}));");
1575 }
1576
1577 sub ParseStructPullDeferred($$$$$)
1578 {
1579         my ($self,$struct,$ndr,$varname,$env) = @_;
1580
1581         if (defined($struct->{PROPERTIES}{relative_base})) {
1582                 # retrieve the current offset as base for relative pointers
1583                 # based on the toplevel struct/union
1584                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset2($ndr, $varname));");
1585         }
1586         foreach my $e (@{$struct->{ELEMENTS}}) {
1587                 $self->ParseElementPull($e, $ndr, $env, 0, 1);
1588         }
1589
1590         $self->add_deferred();
1591 }
1592
1593 #####################################################################
1594 # parse a struct - pull side
1595 sub ParseStructPull($$$$)
1596 {
1597         my($self,$struct,$ndr,$varname) = @_;
1598
1599         return unless defined $struct->{ELEMENTS};
1600
1601         # declare any internal pointers we need
1602         foreach my $e (@{$struct->{ELEMENTS}}) {
1603                 $self->DeclarePtrVariables($e);
1604                 $self->DeclareArrayVariables($e);
1605                 $self->DeclareMemCtxVariables($e);
1606         }
1607
1608         $self->start_flags($struct, $ndr);
1609
1610         my $env = GenerateStructEnv($struct, $varname);
1611
1612         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
1613         $self->indent;
1614         $self->ParseStructPullPrimitives($struct,$ndr,$varname,$env);
1615         $self->deindent;
1616         $self->pidl("}");
1617         $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
1618         $self->indent;
1619         $self->ParseStructPullDeferred($struct,$ndr,$varname,$env);
1620         $self->deindent;
1621         $self->pidl("}");
1622
1623         $self->end_flags($struct, $ndr);
1624 }
1625
1626 #####################################################################
1627 # calculate size of ndr struct
1628 sub ParseStructNdrSize($$$$)
1629 {
1630         my ($self,$t, $name, $varname) = @_;
1631         my $sizevar;
1632
1633         if (my $flags = has_property($t, "flag")) {
1634                 $self->pidl("flags |= $flags;");
1635         }
1636         $self->pidl("return ndr_size_struct($varname, flags, (ndr_push_flags_fn_t)ndr_push_$name, ic);");
1637 }
1638
1639 sub DeclStruct($$$$)
1640 {
1641         my ($e,$t,$name,$varname) = @_;
1642         return ($t ne "pull"?"const ":"") . "struct $name *$varname";
1643 }
1644
1645 sub ArgsStructNdrSize($$$)
1646 {
1647         my ($d, $name, $varname) = @_;
1648         return "const struct $name *$varname, struct smb_iconv_convenience *ic, int flags";
1649 }
1650
1651 $typefamily{STRUCT} = {
1652         PUSH_FN_BODY => \&ParseStructPush,
1653         DECL => \&DeclStruct,
1654         PULL_FN_BODY => \&ParseStructPull,
1655         PRINT_FN_BODY => \&ParseStructPrint,
1656         SIZE_FN_BODY => \&ParseStructNdrSize,
1657         SIZE_FN_ARGS => \&ArgsStructNdrSize,
1658 };
1659
1660 #####################################################################
1661 # calculate size of ndr struct
1662 sub ParseUnionNdrSize($$$)
1663 {
1664         my ($self, $t, $name, $varname) = @_;
1665         my $sizevar;
1666
1667         if (my $flags = has_property($t, "flag")) {
1668                 $self->pidl("flags |= $flags;");
1669         }
1670
1671         $self->pidl("return ndr_size_union($varname, flags, level, (ndr_push_flags_fn_t)ndr_push_$name, ic);");
1672 }
1673
1674 sub ParseUnionPushPrimitives($$$$)
1675 {
1676         my ($self, $e, $ndr ,$varname) = @_;
1677
1678         my $have_default = 0;
1679
1680         $self->pidl("int level = ndr_push_get_switch_value($ndr, $varname);");
1681
1682         if (defined($e->{SWITCH_TYPE})) {
1683                 $self->pidl("NDR_CHECK(ndr_push_$e->{SWITCH_TYPE}($ndr, NDR_SCALARS, level));");
1684         }
1685
1686         if (defined($e->{ALIGN})) {
1687                 $self->pidl("NDR_CHECK(ndr_push_union_align($ndr, $e->{ALIGN}));");
1688         }
1689
1690         $self->pidl("switch (level) {");
1691         $self->indent;
1692         foreach my $el (@{$e->{ELEMENTS}}) {
1693                 if ($el->{CASE} eq "default") {
1694                         $have_default = 1;
1695                 }
1696                 $self->pidl("$el->{CASE}: {");
1697
1698                 if ($el->{TYPE} ne "EMPTY") {
1699                         $self->indent;
1700                         if (defined($e->{PROPERTIES}{relative_base})) {
1701                                 $self->pidl("NDR_CHECK(ndr_push_align($ndr, $el->{ALIGN}));");
1702                                 # set the current offset as base for relative pointers
1703                                 # and store it based on the toplevel struct/union
1704                                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1705                         }
1706                         $self->DeclareArrayVariables($el);
1707                         $self->ParseElementPush($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 1, 0);
1708                         $self->deindent;
1709                 }
1710                 $self->pidl("break; }");
1711                 $self->pidl("");
1712         }
1713         if (! $have_default) {
1714                 $self->pidl("default:");
1715                 $self->pidl("\treturn ndr_push_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value \%u at \%s\", level, __location__);");
1716         }
1717         $self->deindent;
1718         $self->pidl("}");
1719 }
1720
1721 sub ParseUnionPushDeferred($$$$)
1722 {
1723         my ($self,$e,$ndr,$varname) = @_;
1724
1725         my $have_default = 0;
1726
1727         $self->pidl("int level = ndr_push_get_switch_value($ndr, $varname);");
1728         if (defined($e->{PROPERTIES}{relative_base})) {
1729                 # retrieve the current offset as base for relative pointers
1730                 # based on the toplevel struct/union
1731                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset2($ndr, $varname));");
1732         }
1733         $self->pidl("switch (level) {");
1734         $self->indent;
1735         foreach my $el (@{$e->{ELEMENTS}}) {
1736                 if ($el->{CASE} eq "default") {
1737                         $have_default = 1;
1738                 }
1739
1740                 $self->pidl("$el->{CASE}:");
1741                 if ($el->{TYPE} ne "EMPTY") {
1742                         $self->indent;
1743                         $self->ParseElementPush($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 0, 1);
1744                         $self->deindent;
1745                 }
1746                 $self->pidl("break;");
1747                 $self->pidl("");
1748         }
1749         if (! $have_default) {
1750                 $self->pidl("default:");
1751                 $self->pidl("\treturn ndr_push_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value \%u at \%s\", level, __location__);");
1752         }
1753         $self->deindent;
1754         $self->pidl("}");
1755 }
1756
1757 #####################################################################
1758 # parse a union - push side
1759 sub ParseUnionPush($$$$)
1760 {
1761         my ($self,$e,$ndr,$varname) = @_;
1762         my $have_default = 0;
1763
1764         $self->start_flags($e, $ndr);
1765
1766         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
1767         $self->indent;
1768         $self->ParseUnionPushPrimitives($e, $ndr, $varname);
1769         $self->deindent;
1770         $self->pidl("}");
1771         $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
1772         $self->indent;
1773         $self->ParseUnionPushDeferred($e, $ndr, $varname);
1774         $self->deindent;
1775         $self->pidl("}");
1776         $self->end_flags($e, $ndr);
1777 }
1778
1779 #####################################################################
1780 # print a union
1781 sub ParseUnionPrint($$$$$)
1782 {
1783         my ($self,$e,$ndr,$name,$varname) = @_;
1784         my $have_default = 0;
1785
1786         $self->pidl("int level;");
1787         foreach my $el (@{$e->{ELEMENTS}}) {
1788                 $self->DeclareArrayVariables($el);
1789         }
1790
1791         $self->start_flags($e, $ndr);
1792
1793         $self->pidl("level = ndr_print_get_switch_value($ndr, $varname);");
1794
1795         $self->pidl("ndr_print_union($ndr, name, level, \"$name\");");
1796
1797         $self->pidl("switch (level) {");
1798         $self->indent;
1799         foreach my $el (@{$e->{ELEMENTS}}) {
1800                 if ($el->{CASE} eq "default") {
1801                         $have_default = 1;
1802                 }
1803                 $self->pidl("$el->{CASE}:");
1804                 if ($el->{TYPE} ne "EMPTY") {
1805                         $self->indent;
1806                         $self->ParseElementPrint($el, $ndr, "$varname->$el->{NAME}", {});
1807                         $self->deindent;
1808                 }
1809                 $self->pidl("break;");
1810                 $self->pidl("");
1811         }
1812         if (! $have_default) {
1813                 $self->pidl("default:");
1814                 $self->pidl("\tndr_print_bad_level($ndr, name, level);");
1815         }
1816         $self->deindent;
1817         $self->pidl("}");
1818
1819         $self->end_flags($e, $ndr);
1820 }
1821
1822 sub ParseUnionPullPrimitives($$$$$)
1823 {
1824         my ($self,$e,$ndr,$varname,$switch_type) = @_;
1825         my $have_default = 0;
1826
1827         if (defined($switch_type)) {
1828                 $self->pidl("NDR_CHECK(ndr_pull_$switch_type($ndr, NDR_SCALARS, &_level));");
1829                 $self->pidl("if (_level != level) {");
1830                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value %u for $varname at \%s\", _level, __location__);");
1831                 $self->pidl("}");
1832         }
1833
1834         if (defined($e->{ALIGN})) {
1835                 $self->pidl("NDR_CHECK(ndr_pull_union_align($ndr, $e->{ALIGN}));");
1836         }
1837
1838         $self->pidl("switch (level) {");
1839         $self->indent;
1840         foreach my $el (@{$e->{ELEMENTS}}) {
1841                 if ($el->{CASE} eq "default") {
1842                         $have_default = 1;
1843                 }
1844                 $self->pidl("$el->{CASE}: {");
1845
1846                 if ($el->{TYPE} ne "EMPTY") {
1847                         $self->indent;
1848                         $self->DeclarePtrVariables($el);
1849                         $self->DeclareArrayVariables($el);
1850                         if (defined($e->{PROPERTIES}{relative_base})) {
1851                                 $self->pidl("NDR_CHECK(ndr_pull_align($ndr, $el->{ALIGN}));");
1852                                 # set the current offset as base for relative pointers
1853                                 # and store it based on the toplevel struct/union
1854                                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1855                         }
1856                         $self->ParseElementPull($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 1, 0);
1857                         $self->deindent;
1858                 }
1859                 $self->pidl("break; }");
1860                 $self->pidl("");
1861         }
1862         if (! $have_default) {
1863                 $self->pidl("default:");
1864                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value \%u at \%s\", level, __location__);");
1865         }
1866         $self->deindent;
1867         $self->pidl("}");
1868 }
1869
1870 sub ParseUnionPullDeferred($$$$)
1871 {
1872         my ($self,$e,$ndr,$varname) = @_;
1873         my $have_default = 0;
1874
1875         if (defined($e->{PROPERTIES}{relative_base})) {
1876                 # retrieve the current offset as base for relative pointers
1877                 # based on the toplevel struct/union
1878                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset2($ndr, $varname));");
1879         }
1880         $self->pidl("switch (level) {");
1881         $self->indent;
1882         foreach my $el (@{$e->{ELEMENTS}}) {
1883                 if ($el->{CASE} eq "default") {
1884                         $have_default = 1;
1885                 }
1886
1887                 $self->pidl("$el->{CASE}:");
1888                 if ($el->{TYPE} ne "EMPTY") {
1889                         $self->indent;
1890                         $self->ParseElementPull($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 0, 1);
1891                         $self->deindent;
1892                 }
1893                 $self->pidl("break;");
1894                 $self->pidl("");
1895         }
1896         if (! $have_default) {
1897                 $self->pidl("default:");
1898                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value \%u at \%s\", level, __location__);");
1899         }
1900         $self->deindent;
1901         $self->pidl("}");
1902
1903
1904 }
1905
1906 #####################################################################
1907 # parse a union - pull side
1908 sub ParseUnionPull($$$$)
1909 {
1910         my ($self,$e,$ndr,$varname) = @_;
1911         my $switch_type = $e->{SWITCH_TYPE};
1912
1913         $self->pidl("int level;");
1914         if (defined($switch_type)) {
1915                 if (Parse::Pidl::Typelist::typeIs($switch_type, "ENUM")) {
1916                         $switch_type = Parse::Pidl::Typelist::enum_type_fn(getType($switch_type)->{DATA});
1917                 }
1918                 $self->pidl(mapTypeName($switch_type) . " _level;");
1919         }
1920
1921         my %double_cases = ();
1922         foreach my $el (@{$e->{ELEMENTS}}) {
1923                 next if ($el->{TYPE} eq "EMPTY");
1924                 next if ($double_cases{"$el->{NAME}"});
1925                 $self->DeclareMemCtxVariables($el);
1926                 $double_cases{"$el->{NAME}"} = 1;
1927         }
1928
1929         $self->start_flags($e, $ndr);
1930
1931         $self->pidl("level = ndr_pull_get_switch_value($ndr, $varname);");
1932
1933         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
1934         $self->indent;
1935         $self->ParseUnionPullPrimitives($e,$ndr,$varname,$switch_type);
1936         $self->deindent;
1937         $self->pidl("}");
1938
1939         $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
1940         $self->indent;
1941         $self->ParseUnionPullDeferred($e,$ndr,$varname);
1942         $self->deindent;
1943         $self->pidl("}");
1944
1945         $self->add_deferred();
1946
1947         $self->end_flags($e, $ndr);
1948 }
1949
1950 sub DeclUnion($$$$)
1951 {
1952         my ($e,$t,$name,$varname) = @_;
1953         return ($t ne "pull"?"const ":"") . "union $name *$varname";
1954 }
1955
1956 sub ArgsUnionNdrSize($$)
1957 {
1958         my ($d,$name) = @_;
1959         return "const union $name *r, uint32_t level, struct smb_iconv_convenience *ic, int flags";
1960 }
1961
1962 $typefamily{UNION} = {
1963         PUSH_FN_BODY => \&ParseUnionPush,
1964         DECL => \&DeclUnion,
1965         PULL_FN_BODY => \&ParseUnionPull,
1966         PRINT_FN_BODY => \&ParseUnionPrint,
1967         SIZE_FN_ARGS => \&ArgsUnionNdrSize,
1968         SIZE_FN_BODY => \&ParseUnionNdrSize,
1969 };
1970
1971 #####################################################################
1972 # parse a typedef - push side
1973 sub ParseTypedefPush($$$$)
1974 {
1975         my($self,$e,$ndr,$varname) = @_;
1976
1977         my $env;
1978
1979         $env->{$e->{NAME}} = $varname;
1980
1981         $self->ParseElementPushLevel($e, $e->{LEVELS}[0], $ndr, $varname, $env, 1, 1);
1982 }
1983
1984 #####################################################################
1985 # parse a typedef - pull side
1986 sub ParseTypedefPull($$$$)
1987 {
1988         my($self,$e,$ndr,$varname) = @_;
1989
1990         my $env;
1991
1992         $env->{$e->{NAME}} = $varname;
1993
1994         $self->ParseElementPullLevel($e, $e->{LEVELS}[0], $ndr, $varname, $env, 1, 1);
1995 }
1996
1997 #####################################################################
1998 # parse a typedef - print side
1999 sub ParseTypedefPrint($$$$$)
2000 {
2001         my($self,$e,$ndr,$name,$varname) = @_;
2002
2003         $typefamily{$e->{DATA}->{TYPE}}->{PRINT_FN_BODY}->($self, $e->{DATA}, $ndr, $name, $varname);
2004 }
2005
2006 #####################################################################
2007 ## calculate the size of a structure
2008 sub ParseTypedefNdrSize($$$$)
2009 {
2010         my($self,$t,$name,$varname) = @_;
2011
2012         $typefamily{$t->{DATA}->{TYPE}}->{SIZE_FN_BODY}->($self, $t->{DATA}, $name, $varname);
2013 }
2014
2015 sub DeclTypedef($$$$)
2016 {
2017         my ($e, $t, $name, $varname) = @_;
2018
2019         return $typefamily{$e->{DATA}->{TYPE}}->{DECL}->($e->{DATA}, $t, $name, $varname);
2020 }
2021
2022 sub ArgsTypedefNdrSize($$$)
2023 {
2024         my ($d, $name, $varname) = @_;
2025         return $typefamily{$d->{DATA}->{TYPE}}->{SIZE_FN_ARGS}->($d->{DATA}, $name, $varname);
2026 }
2027
2028 $typefamily{TYPEDEF} = {
2029         PUSH_FN_BODY => \&ParseTypedefPush,
2030         DECL => \&DeclTypedef,
2031         PULL_FN_BODY => \&ParseTypedefPull,
2032         PRINT_FN_BODY => \&ParseTypedefPrint,
2033         SIZE_FN_ARGS => \&ArgsTypedefNdrSize,
2034         SIZE_FN_BODY => \&ParseTypedefNdrSize,
2035 };
2036
2037 #####################################################################
2038 # parse a function - print side
2039 sub ParseFunctionPrint($$)
2040 {
2041         my($self, $fn) = @_;
2042         my $ndr = "ndr";
2043
2044         $self->pidl_hdr("void ndr_print_$fn->{NAME}(struct ndr_print *$ndr, const char *name, int flags, const struct $fn->{NAME} *r);");
2045
2046         return if has_property($fn, "noprint");
2047
2048         $self->pidl("_PUBLIC_ void ndr_print_$fn->{NAME}(struct ndr_print *$ndr, const char *name, int flags, const struct $fn->{NAME} *r)");
2049         $self->pidl("{");
2050         $self->indent;
2051
2052         foreach my $e (@{$fn->{ELEMENTS}}) {
2053                 $self->DeclareArrayVariables($e);
2054         }
2055
2056         $self->pidl("ndr_print_struct($ndr, name, \"$fn->{NAME}\");");
2057         $self->pidl("$ndr->depth++;");
2058
2059         $self->pidl("if (flags & NDR_SET_VALUES) {");
2060         $self->pidl("\t$ndr->flags |= LIBNDR_PRINT_SET_VALUES;");
2061         $self->pidl("}");
2062
2063         $self->pidl("if (flags & NDR_IN) {");
2064         $self->indent;
2065         $self->pidl("ndr_print_struct($ndr, \"in\", \"$fn->{NAME}\");");
2066         $self->pidl("$ndr->depth++;");
2067
2068         my $env = GenerateFunctionInEnv($fn);
2069
2070         foreach my $e (@{$fn->{ELEMENTS}}) {
2071                 if (grep(/in/,@{$e->{DIRECTION}})) {
2072                         $self->ParseElementPrint($e, $ndr, $env->{$e->{NAME}}, $env);
2073                 }
2074         }
2075         $self->pidl("$ndr->depth--;");
2076         $self->deindent;
2077         $self->pidl("}");
2078
2079         $self->pidl("if (flags & NDR_OUT) {");
2080         $self->indent;
2081         $self->pidl("ndr_print_struct($ndr, \"out\", \"$fn->{NAME}\");");
2082         $self->pidl("$ndr->depth++;");
2083
2084         $env = GenerateFunctionOutEnv($fn);
2085         foreach my $e (@{$fn->{ELEMENTS}}) {
2086                 if (grep(/out/,@{$e->{DIRECTION}})) {
2087                         $self->ParseElementPrint($e, $ndr, $env->{$e->{NAME}}, $env);
2088                 }
2089         }
2090         if ($fn->{RETURN_TYPE}) {
2091                 $self->pidl("ndr_print_$fn->{RETURN_TYPE}($ndr, \"result\", r->out.result);");
2092         }
2093         $self->pidl("$ndr->depth--;");
2094         $self->deindent;
2095         $self->pidl("}");
2096
2097         $self->pidl("$ndr->depth--;");
2098         $self->deindent;
2099         $self->pidl("}");
2100         $self->pidl("");
2101 }
2102
2103 #####################################################################
2104 # parse a function
2105 sub ParseFunctionPush($$)
2106 {
2107         my($self, $fn) = @_;
2108         my $ndr = "ndr";
2109
2110         $self->fn_declare("push", $fn, "enum ndr_err_code ndr_push_$fn->{NAME}(struct ndr_push *$ndr, int flags, const struct $fn->{NAME} *r)") or return;
2111
2112         return if has_property($fn, "nopush");
2113
2114         $self->pidl("{");
2115         $self->indent;
2116
2117         foreach my $e (@{$fn->{ELEMENTS}}) {
2118                 $self->DeclareArrayVariables($e);
2119         }
2120
2121         $self->pidl("if (flags & NDR_IN) {");
2122         $self->indent;
2123
2124         my $env = GenerateFunctionInEnv($fn);
2125
2126         EnvSubstituteValue($env, $fn);
2127
2128         foreach my $e (@{$fn->{ELEMENTS}}) {
2129                 if (grep(/in/,@{$e->{DIRECTION}})) {
2130                         $self->ParseElementPush($e, $ndr, $env, 1, 1);
2131                 }
2132         }
2133
2134         $self->deindent;
2135         $self->pidl("}");
2136
2137         $self->pidl("if (flags & NDR_OUT) {");
2138         $self->indent;
2139
2140         $env = GenerateFunctionOutEnv($fn);
2141         foreach my $e (@{$fn->{ELEMENTS}}) {
2142                 if (grep(/out/,@{$e->{DIRECTION}})) {
2143                         $self->ParseElementPush($e, $ndr, $env, 1, 1);
2144                 }
2145         }
2146
2147         if ($fn->{RETURN_TYPE}) {
2148                 $self->pidl("NDR_CHECK(ndr_push_$fn->{RETURN_TYPE}($ndr, NDR_SCALARS, r->out.result));");
2149         }
2150
2151         $self->deindent;
2152         $self->pidl("}");
2153         $self->pidl("return NDR_ERR_SUCCESS;");
2154         $self->deindent;
2155         $self->pidl("}");
2156         $self->pidl("");
2157 }
2158
2159 sub AllocateArrayLevel($$$$$$)
2160 {
2161         my ($self,$e,$l,$ndr,$var,$size) = @_;
2162
2163         my $pl = GetPrevLevel($e, $l);
2164         if (defined($pl) and
2165             $pl->{TYPE} eq "POINTER" and
2166             $pl->{POINTER_TYPE} eq "ref"
2167             and not $l->{IS_ZERO_TERMINATED}) {
2168                 $self->pidl("if ($ndr->flags & LIBNDR_FLAG_REF_ALLOC) {");
2169                 $self->pidl("\tNDR_PULL_ALLOC_N($ndr, $var, $size);");
2170                 $self->pidl("}");
2171                 if (grep(/in/,@{$e->{DIRECTION}}) and
2172                     grep(/out/,@{$e->{DIRECTION}})) {
2173                         $self->pidl("memcpy(r->out.$e->{NAME}, r->in.$e->{NAME}, ($size) * sizeof(*r->in.$e->{NAME}));");
2174                 }
2175                 return;
2176         }
2177
2178         $self->pidl("NDR_PULL_ALLOC_N($ndr, $var, $size);");
2179 }
2180
2181 #####################################################################
2182 # parse a function
2183 sub ParseFunctionPull($$)
2184 {
2185         my($self,$fn) = @_;
2186         my $ndr = "ndr";
2187
2188         # pull function args
2189         $self->fn_declare("pull", $fn, "enum ndr_err_code ndr_pull_$fn->{NAME}(struct ndr_pull *$ndr, int flags, struct $fn->{NAME} *r)") or return;
2190
2191         $self->pidl("{");
2192         $self->indent;
2193
2194         # declare any internal pointers we need
2195         foreach my $e (@{$fn->{ELEMENTS}}) {
2196                 $self->DeclarePtrVariables($e);
2197                 $self->DeclareArrayVariables($e);
2198         }
2199
2200         my %double_cases = ();
2201         foreach my $e (@{$fn->{ELEMENTS}}) {
2202                 next if ($e->{TYPE} eq "EMPTY");
2203                 next if ($double_cases{"$e->{NAME}"});
2204                 $self->DeclareMemCtxVariables($e);
2205                 $double_cases{"$e->{NAME}"} = 1;
2206         }
2207
2208         $self->pidl("if (flags & NDR_IN) {");
2209         $self->indent;
2210
2211         # auto-init the out section of a structure. I originally argued that
2212         # this was a bad idea as it hides bugs, but coping correctly
2213         # with initialisation and not wiping ref vars is turning
2214         # out to be too tricky (tridge)
2215         foreach my $e (@{$fn->{ELEMENTS}}) {
2216                 next unless grep(/out/, @{$e->{DIRECTION}});
2217                 $self->pidl("ZERO_STRUCT(r->out);");
2218                 $self->pidl("");
2219                 last;
2220         }
2221
2222         my $env = GenerateFunctionInEnv($fn);
2223
2224         foreach my $e (@{$fn->{ELEMENTS}}) {
2225                 next unless (grep(/in/, @{$e->{DIRECTION}}));
2226                 $self->ParseElementPull($e, $ndr, $env, 1, 1);
2227         }
2228
2229         # allocate the "simple" out ref variables. FIXME: Shouldn't this have it's
2230         # own flag rather than be in NDR_IN ?
2231
2232         foreach my $e (@{$fn->{ELEMENTS}}) {
2233                 next unless (grep(/out/, @{$e->{DIRECTION}}));
2234                 next unless ($e->{LEVELS}[0]->{TYPE} eq "POINTER" and
2235                              $e->{LEVELS}[0]->{POINTER_TYPE} eq "ref");
2236                 next if (($e->{LEVELS}[1]->{TYPE} eq "DATA") and
2237                                  ($e->{LEVELS}[1]->{DATA_TYPE} eq "string"));
2238                 next if (($e->{LEVELS}[1]->{TYPE} eq "ARRAY")
2239                         and   $e->{LEVELS}[1]->{IS_ZERO_TERMINATED});
2240
2241                 if ($e->{LEVELS}[1]->{TYPE} eq "ARRAY") {
2242                         my $size = ParseExprExt($e->{LEVELS}[1]->{SIZE_IS}, $env, $e->{ORIGINAL},
2243                                 check_null_pointer($e, $env, sub { $self->pidl(shift); },
2244                                                    "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for size_is()\");"),
2245                                 check_fully_dereferenced($e, $env));
2246                         $self->pidl("NDR_PULL_ALLOC_N($ndr, r->out.$e->{NAME}, $size);");
2247
2248                         if (grep(/in/, @{$e->{DIRECTION}})) {
2249                                 $self->pidl("memcpy(r->out.$e->{NAME}, r->in.$e->{NAME}, ($size) * sizeof(*r->in.$e->{NAME}));");
2250                         } else {
2251                                 $self->pidl("memset(r->out.$e->{NAME}, 0, ($size) * sizeof(*r->out.$e->{NAME}));");
2252                         }
2253                 } else {
2254                         $self->pidl("NDR_PULL_ALLOC($ndr, r->out.$e->{NAME});");
2255
2256                         if (grep(/in/, @{$e->{DIRECTION}})) {
2257                                 $self->pidl("*r->out.$e->{NAME} = *r->in.$e->{NAME};");
2258                         } else {
2259                                 $self->pidl("ZERO_STRUCTP(r->out.$e->{NAME});");
2260                         }
2261                 }
2262         }
2263
2264         $self->add_deferred();
2265         $self->deindent;
2266         $self->pidl("}");
2267
2268         $self->pidl("if (flags & NDR_OUT) {");
2269         $self->indent;
2270
2271         $env = GenerateFunctionOutEnv($fn);
2272         foreach my $e (@{$fn->{ELEMENTS}}) {
2273                 next unless grep(/out/, @{$e->{DIRECTION}});
2274                 $self->ParseElementPull($e, $ndr, $env, 1, 1);
2275         }
2276
2277         if ($fn->{RETURN_TYPE}) {
2278                 $self->pidl("NDR_CHECK(ndr_pull_$fn->{RETURN_TYPE}($ndr, NDR_SCALARS, &r->out.result));");
2279         }
2280
2281         $self->add_deferred();
2282         $self->deindent;
2283         $self->pidl("}");
2284
2285         $self->pidl("return NDR_ERR_SUCCESS;");
2286         $self->deindent;
2287         $self->pidl("}");
2288         $self->pidl("");
2289 }
2290
2291 sub AuthServiceStruct($$$)
2292 {
2293         my ($self, $ifacename, $authservice) = @_;
2294         my @a = split /,/, $authservice;
2295         my $authservice_count = $#a + 1;
2296
2297         $self->pidl("static const char * const $ifacename\_authservice_strings[] = {");
2298         foreach my $ap (@a) {
2299                 $self->pidl("\t$ap, ");
2300         }
2301         $self->pidl("};");
2302         $self->pidl("");
2303
2304         $self->pidl("static const struct ndr_interface_string_array $ifacename\_authservices = {");
2305         $self->pidl("\t.count\t= $authservice_count,");
2306         $self->pidl("\t.names\t= $ifacename\_authservice_strings");
2307         $self->pidl("};");
2308         $self->pidl("");
2309 }
2310
2311 sub FunctionCallEntry($$)
2312 {
2313         my ($self, $d) = @_;
2314         return 0 if not defined($d->{OPNUM});
2315         $self->pidl("\t{");
2316         $self->pidl("\t\t\"$d->{NAME}\",");
2317         $self->pidl("\t\tsizeof(struct $d->{NAME}),");
2318         $self->pidl("\t\t(ndr_push_flags_fn_t) ndr_push_$d->{NAME},");
2319         $self->pidl("\t\t(ndr_pull_flags_fn_t) ndr_pull_$d->{NAME},");
2320         $self->pidl("\t\t(ndr_print_function_t) ndr_print_$d->{NAME},");
2321         $self->pidl("\t\t".($d->{ASYNC}?"true":"false").",");
2322         $self->pidl("\t},");
2323         return 1;
2324 }
2325
2326 #####################################################################
2327 # produce a function call table
2328 sub FunctionTable($$)
2329 {
2330         my($self,$interface) = @_;
2331         my $count = 0;
2332         my $uname = uc $interface->{NAME};
2333
2334         return if ($#{$interface->{FUNCTIONS}}+1 == 0);
2335         return unless defined ($interface->{PROPERTIES}->{uuid});
2336
2337         $self->pidl("static const struct ndr_interface_call $interface->{NAME}\_calls[] = {");
2338
2339         foreach my $d (@{$interface->{INHERITED_FUNCTIONS}},@{$interface->{FUNCTIONS}}) {
2340                 $count += $self->FunctionCallEntry($d);
2341         }
2342         $self->pidl("\t{ NULL, 0, NULL, NULL, NULL, false }");
2343         $self->pidl("};");
2344         $self->pidl("");
2345
2346         $self->pidl("static const char * const $interface->{NAME}\_endpoint_strings[] = {");
2347         foreach my $ep (@{$interface->{ENDPOINTS}}) {
2348                 $self->pidl("\t$ep, ");
2349         }
2350         my $endpoint_count = $#{$interface->{ENDPOINTS}}+1;
2351
2352         $self->pidl("};");
2353         $self->pidl("");
2354
2355         $self->pidl("static const struct ndr_interface_string_array $interface->{NAME}\_endpoints = {");
2356         $self->pidl("\t.count\t= $endpoint_count,");
2357         $self->pidl("\t.names\t= $interface->{NAME}\_endpoint_strings");
2358         $self->pidl("};");
2359         $self->pidl("");
2360
2361         if (! defined $interface->{PROPERTIES}->{authservice}) {
2362                 $interface->{PROPERTIES}->{authservice} = "\"host\"";
2363         }
2364
2365         $self->AuthServiceStruct($interface->{NAME},
2366                                      $interface->{PROPERTIES}->{authservice});
2367
2368         $self->pidl("\nconst struct ndr_interface_table ndr_table_$interface->{NAME} = {");
2369         $self->pidl("\t.name\t\t= \"$interface->{NAME}\",");
2370         $self->pidl("\t.syntax_id\t= {");
2371         $self->pidl("\t\t" . print_uuid($interface->{UUID}) .",");
2372         $self->pidl("\t\tNDR_$uname\_VERSION");
2373         $self->pidl("\t},");
2374         $self->pidl("\t.helpstring\t= NDR_$uname\_HELPSTRING,");
2375         $self->pidl("\t.num_calls\t= $count,");
2376         $self->pidl("\t.calls\t\t= $interface->{NAME}\_calls,");
2377         $self->pidl("\t.endpoints\t= &$interface->{NAME}\_endpoints,");
2378         $self->pidl("\t.authservices\t= &$interface->{NAME}\_authservices");
2379         $self->pidl("};");
2380         $self->pidl("");
2381
2382 }
2383
2384 #####################################################################
2385 # generate include statements for imported idl files
2386 sub HeaderImport
2387 {
2388         my $self = shift;
2389         my @imports = @_;
2390         foreach (@imports) {
2391                 $_ = unmake_str($_);
2392                 s/\.idl$//;
2393                 $self->pidl(choose_header("librpc/gen_ndr/ndr_$_\.h", "gen_ndr/ndr_$_.h"));
2394         }
2395 }
2396
2397 #####################################################################
2398 # generate include statements for included header files
2399 sub HeaderInclude
2400 {
2401         my $self = shift;
2402         my @includes = @_;
2403         foreach (@includes) {
2404                 $self->pidl_hdr("#include $_");
2405         }
2406 }
2407
2408 #####################################################################
2409 # generate prototypes and defines for the interface definitions
2410 # FIXME: these prototypes are for the DCE/RPC client functions, not the
2411 # NDR parser and so do not belong here, technically speaking
2412 sub HeaderInterface($$$)
2413 {
2414         my($self,$interface,$needed) = @_;
2415
2416         my $count = 0;
2417
2418         if ($needed->{"compression"}) {
2419                 $self->pidl(choose_header("librpc/ndr/ndr_compression.h", "ndr/compression.h"));
2420         }
2421
2422         if (has_property($interface, "object")) {
2423                 $self->pidl(choose_header("librpc/gen_ndr/ndr_orpc.h", "ndr/orpc.h"));
2424         }
2425
2426         if (defined $interface->{PROPERTIES}->{helper}) {
2427                 $self->HeaderInclude(split /,/, $interface->{PROPERTIES}->{helper});
2428         }
2429
2430         if (defined $interface->{PROPERTIES}->{uuid}) {
2431                 my $name = uc $interface->{NAME};
2432                 $self->pidl_hdr("#define NDR_$name\_UUID " .
2433                 Parse::Pidl::Util::make_str(lc($interface->{PROPERTIES}->{uuid})));
2434
2435                 if(!defined $interface->{PROPERTIES}->{version}) { $interface->{PROPERTIES}->{version} = "0.0"; }
2436                 $self->pidl_hdr("#define NDR_$name\_VERSION $interface->{PROPERTIES}->{version}");
2437
2438                 $self->pidl_hdr("#define NDR_$name\_NAME \"$interface->{NAME}\"");
2439
2440                 if(!defined $interface->{PROPERTIES}->{helpstring}) { $interface->{PROPERTIES}->{helpstring} = "NULL"; }
2441                 $self->pidl_hdr("#define NDR_$name\_HELPSTRING $interface->{PROPERTIES}->{helpstring}");
2442
2443                 $self->pidl_hdr("extern const struct ndr_interface_table ndr_table_$interface->{NAME};");
2444         }
2445
2446         foreach (@{$interface->{FUNCTIONS}}) {
2447                 next if has_property($_, "noopnum");
2448                 next if grep(/^$_->{NAME}$/,@{$interface->{INHERITED_FUNCTIONS}});
2449                 my $u_name = uc $_->{NAME};
2450
2451                 my $val = sprintf("0x%02x", $count);
2452                 if (defined($interface->{BASE})) {
2453                         $val .= " + NDR_" . uc $interface->{BASE} . "_CALL_COUNT";
2454                 }
2455
2456                 $self->pidl_hdr("#define NDR_$u_name ($val)");
2457
2458                 $self->pidl_hdr("");
2459                 $count++;
2460         }
2461
2462         my $val = $count;
2463
2464         if (defined($interface->{BASE})) {
2465                 $val .= " + NDR_" . uc $interface->{BASE} . "_CALL_COUNT";
2466         }
2467
2468         $self->pidl_hdr("#define NDR_" . uc $interface->{NAME} . "_CALL_COUNT ($val)");
2469
2470 }
2471
2472 sub ParseTypePush($$$$$$)
2473 {
2474         my ($self,$e, $ndr, $varname, $primitives, $deferred) = @_;
2475
2476         # save the old relative_base_offset
2477         $self->pidl("uint32_t _save_relative_base_offset = ndr_push_get_relative_base_offset($ndr);") if defined(has_property($e, "relative_base"));
2478         $typefamily{$e->{TYPE}}->{PUSH_FN_BODY}->($self, $e, $ndr, $varname);
2479         # restore the old relative_base_offset
2480         $self->pidl("ndr_push_restore_relative_base_offset($ndr, _save_relative_base_offset);") if defined(has_property($e, "relative_base"));
2481 }
2482
2483 sub ParseTypePushFunction($$$)
2484 {
2485         my ($self, $e, $varname) = @_;
2486         my $ndr = "ndr";
2487
2488         my $args = $typefamily{$e->{TYPE}}->{DECL}->($e, "push", $e->{NAME}, $varname);
2489
2490         $self->fn_declare("push", $e, "enum ndr_err_code ".TypeFunctionName("ndr_push", $e)."(struct ndr_push *$ndr, int ndr_flags, $args)") or return;
2491
2492         $self->pidl("{");
2493         $self->indent;
2494         $self->ParseTypePush($e, $ndr, $varname, 1, 1);
2495         $self->pidl("return NDR_ERR_SUCCESS;");
2496         $self->deindent;
2497         $self->pidl("}");
2498         $self->pidl("");;
2499 }
2500
2501 sub ParseTypePull($$$$$$)
2502 {
2503         my ($self, $e, $ndr, $varname, $primitives, $deferred) = @_;
2504
2505         # save the old relative_base_offset
2506         $self->pidl("uint32_t _save_relative_base_offset = ndr_pull_get_relative_base_offset($ndr);") if defined(has_property($e, "relative_base"));
2507         $typefamily{$e->{TYPE}}->{PULL_FN_BODY}->($self, $e, $ndr, $varname);
2508         # restore the old relative_base_offset
2509         $self->pidl("ndr_pull_restore_relative_base_offset($ndr, _save_relative_base_offset);") if defined(has_property($e, "relative_base"));
2510 }
2511
2512 sub ParseTypePullFunction($$)
2513 {
2514         my ($self, $e, $varname) = @_;
2515         my $ndr = "ndr";
2516
2517         my $args = $typefamily{$e->{TYPE}}->{DECL}->($e, "pull", $e->{NAME}, $varname);
2518
2519         $self->fn_declare("pull", $e, "enum ndr_err_code ".TypeFunctionName("ndr_pull", $e)."(struct ndr_pull *$ndr, int ndr_flags, $args)") or return;
2520
2521         $self->pidl("{");
2522         $self->indent;
2523         $self->ParseTypePull($e, $ndr, $varname, 1, 1);
2524         $self->pidl("return NDR_ERR_SUCCESS;");
2525         $self->deindent;
2526         $self->pidl("}");
2527         $self->pidl("");
2528 }
2529
2530 sub ParseTypePrint($$$$)
2531 {
2532         my ($self, $e, $ndr, $varname) = @_;
2533
2534         $typefamily{$e->{TYPE}}->{PRINT_FN_BODY}->($self, $e, $ndr, $e->{NAME}, $varname);
2535 }
2536
2537 sub ParseTypePrintFunction($$$)
2538 {
2539         my ($self, $e, $varname) = @_;
2540         my $ndr = "ndr";
2541
2542         my $args = $typefamily{$e->{TYPE}}->{DECL}->($e, "print", $e->{NAME}, $varname);
2543
2544         $self->pidl_hdr("void ".TypeFunctionName("ndr_print", $e)."(struct ndr_print *ndr, const char *name, $args);");
2545
2546         return if (has_property($e, "noprint"));
2547
2548         $self->pidl("_PUBLIC_ void ".TypeFunctionName("ndr_print", $e)."(struct ndr_print *$ndr, const char *name, $args)");
2549         $self->pidl("{");
2550         $self->indent;
2551         $self->ParseTypePrint($e, $ndr, $varname);
2552         $self->deindent;
2553         $self->pidl("}");
2554         $self->pidl("");
2555 }
2556
2557 sub ParseTypeNdrSize($$)
2558 {
2559         my ($self,$t) = @_;
2560
2561         my $varname = "r";
2562         my $tf = $typefamily{$t->{TYPE}};
2563         my $args = $tf->{SIZE_FN_ARGS}->($t, $t->{NAME}, $varname);
2564
2565         $self->fn_declare("size", $t, "size_t ndr_size_$t->{NAME}($args)") or return;
2566
2567         $self->pidl("{");
2568         $self->indent;
2569         $typefamily{$t->{TYPE}}->{SIZE_FN_BODY}->($self,$t, $t->{NAME}, $varname);
2570         $self->deindent;
2571         $self->pidl("}");
2572         $self->pidl("");
2573 }
2574
2575 #####################################################################
2576 # parse the interface definitions
2577 sub ParseInterface($$$)
2578 {
2579         my($self,$interface,$needed) = @_;
2580
2581         $self->pidl_hdr("#ifndef _HEADER_NDR_$interface->{NAME}");
2582         $self->pidl_hdr("#define _HEADER_NDR_$interface->{NAME}");
2583
2584         $self->pidl_hdr("");
2585
2586         $self->HeaderInterface($interface, $needed);
2587
2588         # Typedefs
2589         foreach my $d (@{$interface->{TYPES}}) {
2590                 next unless(typeHasBody($d));
2591
2592                 ($needed->{TypeFunctionName("ndr_push", $d)}) && $self->ParseTypePushFunction($d, "r");
2593                 ($needed->{TypeFunctionName("ndr_pull", $d)}) && $self->ParseTypePullFunction($d, "r");
2594                 ($needed->{TypeFunctionName("ndr_print", $d)}) && $self->ParseTypePrintFunction($d, "r");
2595
2596                 # Make sure we don't generate a function twice...
2597                 $needed->{TypeFunctionName("ndr_push", $d)} =
2598                     $needed->{TypeFunctionName("ndr_pull", $d)} =
2599                         $needed->{TypeFunctionName("ndr_print", $d)} = 0;
2600
2601                 ($needed->{"ndr_size_$d->{NAME}"}) && $self->ParseTypeNdrSize($d);
2602         }
2603
2604         # Functions
2605         foreach my $d (@{$interface->{FUNCTIONS}}) {
2606                 ($needed->{"ndr_push_$d->{NAME}"}) && $self->ParseFunctionPush($d);
2607                 ($needed->{"ndr_pull_$d->{NAME}"}) && $self->ParseFunctionPull($d);
2608                 ($needed->{"ndr_print_$d->{NAME}"}) && $self->ParseFunctionPrint($d);
2609
2610                 # Make sure we don't generate a function twice...
2611                 $needed->{"ndr_push_$d->{NAME}"} = $needed->{"ndr_pull_$d->{NAME}"} =
2612                         $needed->{"ndr_print_$d->{NAME}"} = 0;
2613         }
2614
2615         $self->FunctionTable($interface);
2616
2617         $self->pidl_hdr("#endif /* _HEADER_NDR_$interface->{NAME} */");
2618 }
2619
2620 sub GenerateIncludes($)
2621 {
2622         my ($self) = @_;
2623         if (is_intree()) {
2624                 $self->pidl("#include \"includes.h\"");
2625         } else {
2626                 $self->pidl("#ifndef _GNU_SOURCE");
2627                 $self->pidl("#define _GNU_SOURCE");
2628                 $self->pidl("#endif");
2629                 $self->pidl("#include <stdint.h>");
2630                 $self->pidl("#include <stdlib.h>");
2631                 $self->pidl("#include <stdio.h>");
2632                 $self->pidl("#include <stdbool.h>");
2633                 $self->pidl("#include <stdarg.h>");
2634                 $self->pidl("#include <string.h>");
2635         }
2636 }
2637
2638 #####################################################################
2639 # parse a parsed IDL structure back into an IDL file
2640 sub Parse($$$$)
2641 {
2642         my($self, $ndr,$gen_header,$ndr_header) = @_;
2643
2644         $self->pidl_hdr("/* header auto-generated by pidl */");
2645         $self->pidl_hdr("");
2646         $self->pidl_hdr(choose_header("librpc/ndr/libndr.h", "ndr.h"));
2647         $self->pidl_hdr("#include \"$gen_header\"") if ($gen_header);
2648         $self->pidl_hdr("");
2649
2650         $self->pidl("/* parser auto-generated by pidl */");
2651         $self->pidl("");
2652         $self->GenerateIncludes();
2653         $self->pidl("#include \"$ndr_header\"") if ($ndr_header);
2654         $self->pidl("");
2655
2656         my %needed = ();
2657
2658         foreach (@{$ndr}) {
2659                 ($_->{TYPE} eq "INTERFACE") && NeededInterface($_, \%needed);
2660         }
2661
2662         foreach (@{$ndr}) {
2663                 ($_->{TYPE} eq "INTERFACE") && $self->ParseInterface($_, \%needed);
2664                 ($_->{TYPE} eq "IMPORT") && $self->HeaderImport(@{$_->{PATHS}});
2665                 ($_->{TYPE} eq "INCLUDE") && $self->HeaderInclude(@{$_->{PATHS}});
2666         }
2667
2668         return ($self->{res_hdr}, $self->{res});
2669 }
2670
2671 sub NeededElement($$$)
2672 {
2673         my ($e, $dir, $needed) = @_;
2674
2675         return if ($e->{TYPE} eq "EMPTY");
2676
2677         return if (ref($e->{TYPE}) eq "HASH" and
2678                        not defined($e->{TYPE}->{NAME}));
2679
2680         my ($t, $rt);
2681         if (ref($e->{TYPE}) eq "HASH") {
2682                 $t = $e->{TYPE}->{TYPE}."_".$e->{TYPE}->{NAME};
2683         } else {
2684                 $t = $e->{TYPE};
2685         }
2686
2687         if (ref($e->{REPRESENTATION_TYPE}) eq "HASH") {
2688                 $rt = $e->{REPRESENTATION_TYPE}->{TYPE}."_".$e->{REPRESENTATION_TYPE}->{NAME};
2689         } else {
2690                 $rt = $e->{REPRESENTATION_TYPE};
2691         }
2692
2693         die ("$e->{NAME} $t, $rt FOO") unless ($rt ne "");
2694
2695         my @fn = ();
2696         if ($dir eq "print") {
2697                 push(@fn, TypeFunctionName("ndr_print", $e->{REPRESENTATION_TYPE}));
2698         } elsif ($dir eq "pull") {
2699                 push (@fn, TypeFunctionName("ndr_pull", $e->{TYPE}));
2700                 push (@fn, "ndr_$t\_to_$rt")
2701                         if ($rt ne $t);
2702         } elsif ($dir eq "push") {
2703                 push (@fn, TypeFunctionName("ndr_push", $e->{TYPE}));
2704                 push (@fn, "ndr_$rt\_to_$t")
2705                         if ($rt ne $t);
2706         } else {
2707                 die("invalid direction `$dir'");
2708         }
2709
2710         foreach (@fn) {
2711                 unless (defined($needed->{$_})) {
2712                         $needed->{$_} = 1;
2713                 }
2714         }
2715 }
2716
2717 sub NeededFunction($$)
2718 {
2719         my ($fn,$needed) = @_;
2720         $needed->{"ndr_pull_$fn->{NAME}"} = 1;
2721         $needed->{"ndr_push_$fn->{NAME}"} = 1;
2722         $needed->{"ndr_print_$fn->{NAME}"} = 1;
2723         foreach my $e (@{$fn->{ELEMENTS}}) {
2724                 $e->{PARENT} = $fn;
2725                 NeededElement($e, $_, $needed) foreach ("pull", "push", "print");
2726         }
2727 }
2728
2729 sub NeededType($$$)
2730 {
2731         sub NeededType($$$);
2732         my ($t,$needed,$req) = @_;
2733
2734         NeededType($t->{DATA}, $needed, $req) if ($t->{TYPE} eq "TYPEDEF");
2735
2736         if ($t->{TYPE} eq "STRUCT" or $t->{TYPE} eq "UNION") {
2737                 return unless defined($t->{ELEMENTS});
2738                 for my $e (@{$t->{ELEMENTS}}) {
2739                         $e->{PARENT} = $t;
2740                         if (has_property($e, "compression")) {
2741                                 $needed->{"compression"} = 1;
2742                         }
2743                         NeededElement($e, $req, $needed);
2744                         NeededType($e->{TYPE}, $needed, $req) if (ref($e->{TYPE}) eq "HASH");
2745                 }
2746         }
2747 }
2748
2749 #####################################################################
2750 # work out what parse functions are needed
2751 sub NeededInterface($$)
2752 {
2753         my ($interface,$needed) = @_;
2754         NeededFunction($_, $needed) foreach (@{$interface->{FUNCTIONS}});
2755         foreach (reverse @{$interface->{TYPES}}) {
2756                 if (has_property($_, "public")) {
2757                         $needed->{TypeFunctionName("ndr_pull", $_)} = $needed->{TypeFunctionName("ndr_push", $_)} =
2758                                 $needed->{TypeFunctionName("ndr_print", $_)} = 1;
2759                 }
2760
2761                 NeededType($_, $needed, "pull") if ($needed->{TypeFunctionName("ndr_pull", $_)});
2762                 NeededType($_, $needed, "push") if ($needed->{TypeFunctionName("ndr_push", $_)});
2763                 NeededType($_, $needed, "print") if ($needed->{TypeFunctionName("ndr_print", $_)});
2764                 if (has_property($_, "gensize")) {
2765                         $needed->{"ndr_size_$_->{NAME}"} = 1;
2766                 }
2767         }
2768 }
2769
2770 sub TypeFunctionName($$)
2771 {
2772         my ($prefix, $t) = @_;
2773
2774         return "$prefix\_$t->{NAME}" if (ref($t) eq "HASH" and
2775                         $t->{TYPE} eq "TYPEDEF");
2776         return "$prefix\_$t->{TYPE}_$t->{NAME}" if (ref($t) eq "HASH");
2777         return "$prefix\_$t";
2778 }
2779
2780 1;