third_party/heimdal/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[7.99.1],[https://github.com/heimdal/heimdal/issues])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.11])
  11 AM_MAINTAINER_MODE
  12
  13 LT_PREREQ([2.2])
  14 LT_INIT([shared static win32-dll])
  15
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_PROG_CPP
  21 AM_PATH_PYTHON
  22 AC_CHECK_PROG(CLANG_FORMAT, clang-format, [clang-format], [no])
  23 test "$CLANG_FORMAT" = no && CLANG_FORMAT=true
  24
  25 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  26
  27 AC_PREFIX_DEFAULT(/usr/heimdal)
  28
  29 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  30 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  31
  32 AC_CANONICAL_HOST
  33 CANONICAL_HOST=$host
  34 AC_SUBST(CANONICAL_HOST)
  35
  36 rk_SYS_LARGEFILE
  37
  38 rk_AIX
  39 rk_IRIX
  40 rk_SUNOS
  41
  42 dnl
  43 dnl this is needed to run the configure tests against glibc
  44 dnl
  45 AC_DEFINE([_GNU_SOURCE], 1,
  46         [Define to enable extensions on glibc-based systems such as Linux.])
  47
  48 AC_OBJEXT
  49 AC_EXEEXT
  50
  51 dnl
  52 dnl this is needed when der-protos.h or der-private.h has to be generated
  53 dnl
  54 if ! test -f "$srcdir/lib/asn1/der-protos.h" ||
  55    ! test -f "$srcdir/lib/asn1/der-private.h"; then
  56     AC_KRB_PROG_PERL
  57     AC_KRB_PERL_MOD(Getopt::Std)
  58     AC_KRB_PERL_MOD(File::Compare)
  59 fi
  60
  61 AC_KRB_PROG_YACC
  62 dnl AC_PROG_YACC
  63 AM_PROG_LEX
  64 AS_IF([$LEX --nounput -V > /dev/null 2>&1 && test $? -eq 0],
  65       [AC_SUBST([FLEXNOUNPUTARGS], ["--nounput"])],
  66       [AC_SUBST([FLEXNOUNPUTARGS], [""])])
  67 dnl AC_PROG_RANLIB
  68 AC_PROG_AWK
  69 AC_KRB_PROG_LN_S
  70
  71 AC_MIPS_ABI
  72 CC="$CC $abi"
  73 libdir="$libdir$abilibdirext"
  74
  75 AC_C___ATTRIBUTE__
  76
  77 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  78 rk_VERSIONSCRIPT
  79
  80 dnl Code coverage
  81 AC_ARG_ENABLE([gcov],
  82         AC_HELP_STRING([--enable-gcov], [enable gcov code coverage tool]))
  83 AM_CONDITIONAL([ENABLE_GCOV], [test "x$enable_gcov" = xyes])
  84
  85
  86 dnl
  87 dnl Helper bits for cross compiling
  88 dnl
  89
  90 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  91
  92 AC_ARG_WITH(cross-tools,
  93         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  94         [if test "$withval" = "yes"; then
  95                 AC_MSG_ERROR([Need path to cross tools])
  96         fi
  97         with_cross_tools="${with_cross_tools}/"
  98         ])
  99
 100 if test "${cross_compiling}" != yes ; then
 101
 102    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
 103    SLC="\$(top_builddir)/lib/sl/slc"
 104
 105    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
 106    SLC_DEP="\$(SLC)"
 107 else
 108    ASN1_COMPILE="${with_cross_tools}asn1_compile"
 109    SLC="${with_cross_tools}slc"
 110
 111    ASN1_COMPILE_DEP=
 112    SLC_DEP=
 113
 114    ac_cv_prog_COMPILE_ET=${with_cross_tools}compile_et
 115
 116 fi
 117
 118 AX_CHECK_COMPILE_FLAG([-Wno-error=enum-conversion],
 119                       [WFLAGS_ENUM_CONV=-Wno-error=enum-conversion],
 120                       [WFLAGS_ENUM_CONV=], [-Werror])
 121 AX_CHECK_COMPILE_FLAG([-Wno-unused-but-set-variable],
 122                       [WFLAGS_UNUSED_BUT_SET_VAR=-Wno-unused-but-set-variable],
 123                       [WFLAGS_UNUSED_BUT_SET_VAR=], [-Werror])
 124
 125 AC_SUBST([WFLAGS_ENUM_CONV])
 126 AC_SUBST([ASN1_COMPILE])
 127 AC_SUBST([ASN1_COMPILE_DEP])
 128 AC_SUBST([SLC])
 129 AC_SUBST([SLC_DEP])
 130
 131 dnl ---
 132
 133 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 134
 135 rk_TEST_PACKAGE(openldap,
 136 [#include <lber.h>
 137 #include <ldap.h>],
 138 [-lldap -llber],,,OPENLDAP)
 139 AM_CONDITIONAL(OPENLDAP, test "$with_openldap" != "no")
 140
 141 AC_ARG_ENABLE(hdb-openldap-module,
 142         AS_HELP_STRING([--enable-hdb-openldap-module],
 143                 [if you want support to build openldap hdb as shared object]))
 144 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 145     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 146 fi
 147 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 148
 149 AC_ARG_ENABLE(asn1-templating,
 150         AS_HELP_STRING([--disable-asn1-templating],
 151                 [if you want disable to use of the ASN.1 templating compiler]))
 152 AM_CONDITIONAL(ASN1_TEMPLATING, test "x$enable_asn1_templating" != xno)
 153
 154 dnl
 155 dnl Optional modules, pk-init, digest, kx509
 156 dnl
 157
 158 AC_ARG_ENABLE(pk-init,
 159         AS_HELP_STRING([--disable-pk-init],
 160                 [if you want disable to PK-INIT support]))
 161 if test "$enable_pk_init" != no ;then
 162         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 163 fi
 164 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 165
 166 AC_ARG_ENABLE(digest,
 167         AS_HELP_STRING([--disable-digest],
 168                 [if you want disable to DIGEST support]))
 169 if test "$enable_digest" != no ;then
 170         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 171 fi
 172
 173 AC_ARG_ENABLE(kx509,
 174         AS_HELP_STRING([--disable-kx509],
 175                 [if you want disable to kx509 support]))
 176 if test "$enable_kx509" != no ;then
 177         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 178 fi
 179
 180 dnl Need to test if pkg-config exists
 181 PKG_PROG_PKG_CONFIG
 182
 183 dnl libcap-ng
 184 AC_ARG_WITH([capng],
 185   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 186   [],
 187   [with_capng=check])
 188 if test "$with_capng" != "no"; then
 189   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 190                     [with_capng=yes],[with_capng=no])
 191 fi
 192 if test "$with_capng" = "yes"; then
 193   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 194 fi
 195 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 196 AC_SUBST([CAPNG_CFLAGS])
 197 AC_SUBST([CAPNG_LIBS])
 198
 199 dnl libmicrohttpd
 200 AC_ARG_WITH([microhttpd],
 201   AC_HELP_STRING([--with-microhttpd], [use microhttpd to serve KDC REST API @<:@default=check@:>@]),
 202   [],
 203   [with_microhttpd=check])
 204 if test "$with_microhttpd" != "no"; then
 205   PKG_CHECK_MODULES([MICROHTTPD], [libmicrohttpd >= 0.9.37],
 206                     [with_microhttpd=yes],[with_microhttpd=no])
 207 fi
 208 if test "$with_microhttpd" = "yes"; then
 209   AC_DEFINE_UNQUOTED([HAVE_MICROHTTPD], 1, [whether libmicrohttpd is available for KDC REST API])
 210 fi
 211 AM_CONDITIONAL([HAVE_MICROHTTPD], [test "$with_microhttpd" != "no"])
 212 AC_SUBST([MICROHTTPD_CFLAGS])
 213 AC_SUBST([MICROHTTPD_LIBS])
 214
 215 dnl libcjwt
 216 AC_ARG_WITH([cjwt],
 217   AC_HELP_STRING([--with-cjwt], [(Experimental) use cjwt to validate JWT tokens @<:@default=check@:>@]),
 218   [],
 219   [with_cjwt=check])
 220 if test "$with_cjwt" != "no"; then
 221   PKG_CHECK_MODULES([CJWT], [libcjwt >= 1.0.0],
 222                     [with_cjwt=yes],[with_cjwt=no])
 223 fi
 224 if test "$with_cjwt" = "yes"; then
 225   AC_DEFINE_UNQUOTED([HAVE_CJWT], 1, [whether libcjwt is available for KDC REST API])
 226 fi
 227 AM_CONDITIONAL([HAVE_CJWT], [test "$with_cjwt" != "no"])
 228 AC_SUBST([CJWT_CFLAGS])
 229 AC_SUBST([CJWT_LIBS])
 230
 231 dnl libcjson
 232 AC_ARG_WITH([cjson],
 233   AC_HELP_STRING([--with-cjson], [(Experimental) use cJSON to extract private claims from JWT tokens @<:@default=check@:>@]),
 234   [],
 235   [with_cjson=check])
 236 if test "$with_cjson" != "no"; then
 237   PKG_CHECK_MODULES([CJSON], [libcjson >= 1.0.0],
 238                     [with_cjson=yes],[with_cjson=no])
 239 fi
 240 if test "$with_cjson" = "yes"; then
 241   AC_DEFINE_UNQUOTED([HAVE_CJSON], 1, [whether libcjson is available for KDC REST API])
 242 fi
 243 AM_CONDITIONAL([HAVE_CJSON], [test "$with_cjson" != "no"])
 244 AC_SUBST([CJSON_CFLAGS])
 245 AC_SUBST([CJSON_LIBS])
 246
 247 dnl mitkrb5
 248 AC_ARG_WITH([mitkrb5],
 249   AC_HELP_STRING([--with-mitkrb5], [Path to MIT Kerberos for interop testing @<:@default=check@:>@]),
 250   [],
 251   [with_mikrb5=check])
 252 AM_CONDITIONAL([MITKRB5], [test "$with_mitkrb5" != "no"])
 253
 254 dnl Check for sqlite
 255 rk_TEST_PACKAGE(sqlite3,
 256 [#include <sqlite3.h>
 257 #ifndef SQLITE_OPEN_CREATE
 258 #error "old version"
 259 #endif],
 260 [-lsqlite3],,,SQLITE3)
 261
 262 if test "X$with_sqlite3" != Xyes ; then
 263    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 264    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 265 fi
 266 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 267
 268 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 269
 270 AC_ARG_ENABLE(sqlite-cache,
 271         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 272 if test "$enable_sqlite_cache" != no; then
 273     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 274 fi
 275 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 276
 277
 278 dnl check for libintl
 279 rk_TEST_PACKAGE(libintl,
 280 [#include <libintl.h>],
 281 [-lintl],,,LIBINTL)
 282
 283 dnl path where the hdb directory is stored
 284 AC_ARG_WITH([hdbdir],
 285         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 286         [],
 287         [with_hdbdir=/var/heimdal])
 288 DIR_hdbdir="$with_hdbdir"
 289 AC_SUBST([DIR_hdbdir])
 290
 291
 292 AM_CONDITIONAL(KRB5, true)
 293 AM_CONDITIONAL(do_roken_rename, true)
 294
 295 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 296
 297
 298 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 299 AC_SUBST(LIB_kdb)dnl
 300
 301 KRB_CRYPTO
 302
 303 KRB_PTHREADS
 304
 305 AC_ARG_ENABLE(dce,
 306         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 307 if test "$enable_dce" = yes; then
 308     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 309 fi
 310 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 311
 312 ## XXX quite horrible:
 313 if test -f /etc/ibmcxx.cfg; then
 314         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 315         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 316         dpagaix_ldflags=
 317 else
 318         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 319         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 320         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 321 fi
 322 AC_SUBST(dpagaix_cflags)
 323 AC_SUBST(dpagaix_ldadd)
 324 AC_SUBST(dpagaix_ldflags)
 325
 326 AC_ARG_ENABLE([afs-support],
 327         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 328 if test "$enable_afs_support" = no; then
 329         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 330         NO_AFS="1"
 331 fi
 332 AC_SUBST(NO_AFS)dnl
 333 AM_CONDITIONAL(NO_AFS, test "$enable_afs_support" = no)
 334
 335 rk_DB
 336
 337 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 338
 339 rk_ROKEN(lib/roken)
 340 LIBADD_roken="$LIB_roken"
 341 AC_SUBST(LIBADD_roken)dnl
 342 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 343
 344 rk_OTP
 345
 346 rk_LIBDISPATCH
 347
 348 AC_CHECK_OSFC2
 349
 350 AC_ARG_ENABLE(mmap,
 351         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 352 if test "$enable_mmap" = "no"; then
 353         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 354 fi
 355
 356 AC_ARG_ENABLE(afs-string-to-key,
 357         AS_HELP_STRING([--disable-afs-string-to-key],
 358         [disable use of weak AFS string-to-key functions]),
 359         [], [enable_afs_string_to_key=yes])
 360
 361 if test "$enable_afs_string_to_key" = "yes"; then
 362         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 363         ENABLE_AFS_STRING_TO_KEY=1
 364 fi
 365 AC_SUBST(ENABLE_AFS_STRING_TO_KEY)dnl
 366
 367
 368 rk_CHECK_MAN
 369
 370 rk_TEST_PACKAGE(readline,
 371 [#include <stdio.h>
 372 #if defined(HAVE_READLINE_READLINE_H)
 373 #include <readline/readline.h>
 374 #elif defined(HAVE_READLINE_H)
 375 #include <readline.h>
 376 #endif
 377 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 378
 379 rk_TEST_PACKAGE(libedit,
 380 [#include <stdio.h>
 381 #if defined(HAVE_READLINE_READLINE_H)
 382 #include <readline/readline.h>
 383 #elif defined(HAVE_READLINE_H)
 384 #include <readline.h>
 385 #elif defined(HAVE_EDITLINE_READLINE_H)
 386 #include <editline/readline.h>
 387 #endif
 388 ],-ledit,,, READLINE,, [readline.h readline/readline.h editline/readline.h])
 389
 390 AC_CONFIG_SUBDIRS([lib/libedit])
 391
 392 KRB_C_BIGENDIAN
 393 AC_C_INLINE
 394
 395 dnl AM_C_PROTOTYPES
 396
 397 dnl Checks for typedefs, structures, and compiler characteristics.
 398 AC_C_CONST
 399 AC_TYPE_OFF_T
 400 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 401 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 402 AC_HAVE_TYPE([long long])
 403 AC_HEADER_TIME
 404 AC_STRUCT_TM
 405
 406 dnl Checks for header files.
 407 AC_HEADER_STDC
 408
 409 AC_CHECK_HEADERS([\
 410         CommonCrypto/CommonDigest.h             \
 411         CommonCrypto/CommonCryptor.h            \
 412         arpa/telnet.h                           \
 413         bind/bitypes.h                          \
 414         bsdsetjmp.h                             \
 415         curses.h                                \
 416         dlfcn.h                                 \
 417         execinfo.h                              \
 418         fnmatch.h                               \
 419         inttypes.h                              \
 420         io.h                                    \
 421         keyutils.h                              \
 422         libutil.h                               \
 423         limits.h                                \
 424         maillock.h                              \
 425         netgroup.h                              \
 426         netinet/in6_machtypes.h                 \
 427         netinet/tcp.h                           \
 428         pthread.h                               \
 429         pty.h                                   \
 430         sac.h                                   \
 431         sgtty.h                                 \
 432         siad.h                                  \
 433         signal.h                                \
 434         strings.h                               \
 435         stropts.h                               \
 436         stdatomic.h                             \
 437         sys/bitypes.h                           \
 438         sys/category.h                          \
 439         sys/file.h                              \
 440         sys/filio.h                             \
 441         sys/ioccom.h                            \
 442         sys/mman.h                              \
 443         sys/param.h                             \
 444         sys/pty.h                               \
 445         sys/ptyio.h                             \
 446         sys/select.h                            \
 447         sys/socket.h                            \
 448         sys/str_tty.h                           \
 449         sys/stream.h                            \
 450         sys/stropts.h                           \
 451         sys/syscall.h                           \
 452         sys/termio.h                            \
 453         sys/timeb.h                             \
 454         sys/times.h                             \
 455         sys/types.h                             \
 456         sys/un.h                                \
 457         locale.h                                \
 458         termcap.h                               \
 459         termio.h                                \
 460         termios.h                               \
 461         time.h                                  \
 462         tmpdir.h                                \
 463         udb.h                                   \
 464         util.h                                  \
 465 ])
 466
 467 dnl On Solaris 8 there's a compilation warning for term.h because
 468 dnl it doesn't define `bool'.
 469 AC_CHECK_HEADERS(term.h, , , -)
 470
 471 dnl aix have asl.h (A/IX screen library) that we don't want
 472 AC_CHECK_HEADERS(asl.h, , , [
 473 #include <asl.h>
 474 #ifndef ASL_STRING_EMERG
 475 #error ASL_STRING_EMERG missing
 476 #endif])
 477
 478 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 479 #if HAVE_SYS_SOCKET_H
 480 #include <sys/socket.h>
 481 #endif])
 482
 483 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 484 #if HAVE_SYS_TTY_H
 485 #include <sys/tty.h>
 486 #endif])
 487
 488 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 489 #if HAVE_TERMIOS_H
 490 #include <termios.h>
 491 #endif
 492 #if HAVE_SYS_STREAM_H
 493 #include <sys/stream.h>
 494 #endif])
 495
 496 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 497 #if HAVE_SYS_TYPES_H
 498 #include <sys/types.h>
 499 #endif
 500 #if HAVE_SYS_PARAM_H
 501 #include <sys/param.h>
 502 #endif])
 503
 504 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 505 #include <security/pam_appl.h>
 506 ])
 507
 508 dnl export symbols
 509 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 510 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 511 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 512 rk_WIN32_EXPORT(BUILD_KDC_LIB, KDC_LIB)
 513
 514 dnl Deal with switch fallthrough warnings
 515 AH_TOP([
 516 #if defined(DISPATCH_FALLTHROUGH)
 517 # define HEIM_FALLTHROUGH DISPATCH_FALLTHROUGH
 518 #else
 519 # if defined(__GNUC__)
 520 #  if __GNUC__ >= 7
 521 #   define HEIM_FALLTHROUGH __attribute__((fallthrough))
 522 #  else
 523 #   define HEIM_FALLTHROUGH do {} while (0) /* fallthrough */
 524 #  endif
 525 # else
 526 #  define HEIM_FALLTHROUGH do {} while (0) /* fallthrough */
 527 # endif
 528 #endif
 529 ])
 530
 531 dnl Checks for libraries.
 532
 533 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 534 #ifdef HAVE_UTIL_H
 535 #include <util.h>
 536 #endif
 537 ],[0,0,0,0,0])
 538
 539 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses tinfo,[
 540 #ifdef HAVE_TERMCAP_H
 541 #include <termcap.h>
 542 #endif
 543 #ifdef HAVE_CURSES_H
 544 #include <curses.h>
 545 #endif
 546 ],[0,0])
 547
 548 dnl Checks for library functions.
 549
 550 AC_CHECK_FUNCS([                                \
 551         _scrsize                                \
 552         arc4random                              \
 553         backtrace                               \
 554         fcntl                                   \
 555         fork                                    \
 556         fseeko                                  \
 557         ftello                                  \
 558         getpeereid                              \
 559         getpeerucred                            \
 560         getresgid                               \
 561         getresuid                               \
 562         grantpt                                 \
 563         ptsname_r                               \
 564         rand                                    \
 565         setitimer                               \
 566         setregid                                \
 567         setresgid                               \
 568         setresuid                               \
 569         setreuid                                \
 570         setsid                                  \
 571         sigaction                               \
 572         unlockpt                                \
 573         waitpid                                 \
 574 ])
 575
 576 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 577 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 578         [[unsigned int foo, bar; bar = __sync_add_and_fetch(&foo, 1);]])],
 579         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 580 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 581         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 582 fi
 583 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 584
 585 AC_FUNC_MMAP
 586
 587 rk_DLADDR
 588
 589 AC_CHECK_GETPWNAM_R_POSIX
 590 AC_CHECK_GETPWUID_R_POSIX
 591
 592 dnl detect doors on solaris
 593 if test "$enable_pthread_support" != no; then
 594    saved_LIBS="$LIBS"
 595    LIBS="$LIBS $PTHREADS_LIBS"
 596    AC_FIND_FUNC_NO_LIBS(door_create, door)
 597    LIBS="$saved_LIBS"
 598 fi
 599
 600 AC_ARG_ENABLE(kcm,
 601         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 602 ,[enable_kcm=yes])
 603
 604 if test "$enable_kcm" = yes ; then
 605    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 606         enable_kcm=no
 607    fi
 608 fi
 609 if test "$enable_kcm" = yes; then
 610        AC_DEFINE(HAVE_KCM, 1,
 611                [Define if you want to use the Kerberos Credentials Manager.])
 612 fi
 613 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 614
 615 dnl detect keyring on Linux
 616 if test "$ac_cv_header_keyutils_h" = yes; then
 617     AC_CHECK_SIZEOF([key_serial_t],,[
 618         #ifdef HAVE_INTTYPES_H
 619         #include <inttypes.h>
 620         #endif
 621         #ifdef HAVE_SYS_TYPES_H
 622         #include <sys/types.h>
 623         #endif
 624         #include <keyutils.h>
 625     ])
 626 fi
 627
 628 AC_FIND_FUNC_NO_LIBS(add_key, keyutils)
 629 if test -n "$LIB_add_key"; then
 630     saved_LIBS="$LIBS"
 631     LIBS="$LIBS $LIB_add_key"
 632     AC_CHECK_FUNCS(keyctl_get_persistent)
 633     LIBS="$saved_LIBS"
 634 fi
 635 AM_CONDITIONAL(HAVE_KEYUTILS, test "$ac_cv_func_keyctl_get_persistent" = yes)
 636
 637 AC_CHECK_SIZEOF([time_t])
 638
 639 AX_CHECK_SIGN([time_t],
 640   [ AC_DEFINE(TIME_T_SIGNED, 1, [Define if time_t is signed]) ],
 641   [ AC_DEFINE(TIME_T_UNSIGNED, 1, [Define if time_t is unsigned]) ], [
 642 #ifdef HAVE_TIME_H
 643 #include <time.h>
 644 #endif
 645 ])
 646
 647
 648 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 649         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 650         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 651 #ifdef HAVE_INTTYPES_H
 652 #include <inttypes.h>
 653 #endif
 654 #ifdef HAVE_SYS_TYPES_H
 655 #include <sys/types.h>
 656 #endif
 657 #ifdef HAVE_SYS_BITYPES_H
 658 #include <sys/bitypes.h>
 659 #endif
 660 #ifdef HAVE_BIND_BITYPES_H
 661 #include <bind/bitypes.h>
 662 #endif
 663 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 664 #include <netinet/in6_machtypes.h>
 665 #endif
 666 ])
 667
 668 rk_FRAMEWORK_SECURITY
 669 rk_FRAMEWORK_COREFOUNDATION
 670
 671 KRB_READLINE
 672
 673 rk_TELNET
 674
 675 dnl Some operating systems already have com_err and compile_et
 676 CHECK_COMPILE_ET
 677
 678 rk_AUTH_MODULES([sia afskauthlib])
 679
 680 rk_DESTDIRS
 681
 682 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 683
 684
 685 AH_BOTTOM([#ifdef __APPLE__
 686 #include <AvailabilityMacros.h>
 687 #endif])
 688
 689 AH_BOTTOM([#ifdef ROKEN_RENAME
 690 #include "roken_rename.h"
 691 #endif])
 692
 693 AC_ARG_ENABLE(heimdal-documentation,
 694         AS_HELP_STRING([--disable-heimdal-documentation],
 695                 [if you want disable to heimdal documentation]))
 696 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 697
 698 AC_CONFIG_FILES(Makefile                \
 699         etc/Makefile                    \
 700         include/Makefile                \
 701         include/gssapi/Makefile         \
 702         include/hcrypto/Makefile        \
 703         include/kadm5/Makefile          \
 704         lib/Makefile                    \
 705         lib/base/Makefile                       \
 706         lib/asn1/Makefile               \
 707         lib/com_err/Makefile            \
 708         lib/hcrypto/Makefile            \
 709         lib/hx509/Makefile              \
 710         lib/gssapi/Makefile             \
 711         lib/ntlm/Makefile               \
 712         lib/hdb/Makefile                \
 713         lib/ipc/Makefile                \
 714         lib/kadm5/Makefile              \
 715         lib/kafs/Makefile               \
 716         lib/kdfs/Makefile               \
 717         lib/krb5/Makefile               \
 718         lib/otp/Makefile                \
 719         lib/roken/Makefile              \
 720         lib/sl/Makefile                 \
 721         lib/sqlite/Makefile             \
 722         lib/vers/Makefile               \
 723         lib/wind/Makefile               \
 724         lib/gss_preauth/Makefile        \
 725         po/Makefile                     \
 726         kuser/Makefile                  \
 727         kpasswd/Makefile                \
 728         kadmin/Makefile                 \
 729         admin/Makefile                  \
 730         kcm/Makefile                    \
 731         kdc/Makefile                    \
 732         appl/Makefile                   \
 733         appl/afsutil/Makefile           \
 734         appl/dbutils/Makefile           \
 735         appl/gssmask/Makefile           \
 736         appl/otp/Makefile               \
 737         appl/test/Makefile              \
 738         appl/kf/Makefile                \
 739         appl/dceutils/Makefile          \
 740         tests/Makefile                  \
 741         tests/bin/Makefile              \
 742         tests/can/Makefile              \
 743         tests/db/Makefile               \
 744         tests/kdc/Makefile              \
 745         tests/ldap/Makefile             \
 746         tests/gss/Makefile              \
 747         tests/java/Makefile             \
 748         tests/plugin/Makefile           \
 749         packages/Makefile               \
 750         packages/mac/Makefile           \
 751         doc/Makefile                    \
 752         tools/Makefile                  \
 753 )
 754
 755 AC_OUTPUT
 756
 757 dnl
 758 dnl This is the release version name-number[beta]
 759 dnl
 760
 761 if test -d "$srcdir/.git"; then
 762     cat > include/newversion.h.in <<EOF
 763 #ifndef VERSION_HIDDEN
 764 #define VERSION_HIDDEN
 765 #endif
 766 VERSION_HIDDEN const char *const heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ @BRANCH@ @TAG@ ($host) @COMMIT@ @DATE@ \$";
 767 VERSION_HIDDEN const char *const heimdal_version = "AC_PACKAGE_STRING";
 768 EOF
 769 else
 770     cat > include/newversion.h.in <<EOF
 771 #ifndef VERSION_HIDDEN
 772 #define VERSION_HIDDEN
 773 #endif
 774 VERSION_HIDDEN const char *const heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 775 VERSION_HIDDEN const char *const heimdal_version = "AC_PACKAGE_STRING";
 776 EOF
 777 fi
 778
 779 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 780         echo "include/version.h is unchanged"
 781         rm -f include/newversion.h.in
 782 else
 783         echo "creating include/version.h"
 784         if test -n "$SOURCE_DATE_EPOCH"; then
 785             Date=`
 786                   # BSD, OS X
 787                   date -u -r "$SOURCE_DATE_EPOCH" "+%Y-%m-%dT%H:%M:%SZ" 2>/dev/null ||
 788                   # Linux
 789                   date -u -d "@${SOURCE_DATE_EPOCH}" 2>/dev/null ||
 790                   # Illumos -- sorry, no -r/-d here
 791                   date -u ||
 792                   date`
 793         else
 794             Date=`date -u "+%Y-%m-%dT%H:%M:%SZ"`
 795         fi
 796         if test -n "$SOURCE_HOST"; then
 797             Host=$SOURCE_HOST
 798         else
 799             Host=`uname -n`
 800         fi
 801         if test -n "$SOURCE_USER"; then
 802             User=$SOURCE_USER
 803         else
 804             User=${USER:-${LOGNAME:-`id -nu`}}
 805         fi
 806         if test -d "$srcdir/.git"; then
 807             GitCommit=`cd $srcdir && git rev-parse HEAD`
 808             GitBranch=`cd $srcdir && git rev-parse --abbrev-ref HEAD`
 809             if test "x$GitBranch" = master; then
 810                 GitDesc=`cd $srcdir && git describe --all --dirty`
 811             else
 812                 GitDesc=`cd $srcdir && \
 813                          git describe --tags --match 'heimdal-*' --dirty`
 814             fi
 815         else
 816             GitCommit='<commit-unknown>'
 817             GitBranch='<branch-unknown>'
 818             GitDesc='<tag-unknown>'
 819         fi
 820         mv -f include/newversion.h.in include/version.h.in
 821         sed -e "s/@HOST@/$Host/" \
 822             -e "s;@USER@;$User;" \
 823             -e "s;@DATE@;$Date;" \
 824             -e "s;@BRANCH@;$GitBranch;" \
 825             -e "s;@TAG@;$GitDesc;" \
 826             -e "s;@COMMIT@;$GitCommit;" \
 827             include/version.h.in > include/version.h
 828 fi