lib/replace/libreplace.m4

   1 AC_DEFUN_ONCE(AC_LIBREPLACE_LOCATION_CHECKS,
   2 [
   3 echo "LIBREPLACE_LOCATION_CHECKS: START"
   4
   5 dnl find the libreplace sources. This is meant to work both for
   6 dnl libreplace standalone builds, and builds of packages using libreplace
   7 libreplacedir=""
   8 libreplacepaths="$srcdir $srcdir/lib/replace $srcdir/libreplace $srcdir/../libreplace $srcdir/../replace $srcdir/../lib/replace $srcdir/../../../lib/replace"
   9 for d in $libreplacepaths; do
  10         if test -f "$d/replace.c"; then
  11                 libreplacedir="$d"
  12                 AC_SUBST(libreplacedir)
  13                 break;
  14         fi
  15 done
  16 if test x"$libreplacedir" = "x"; then
  17         AC_MSG_ERROR([cannot find libreplace in $libreplacepaths])
  18 fi
  19 LIBREPLACEOBJ="$libreplacedir/replace.o"
  20 AC_SUBST(LIBREPLACEOBJ)
  21
  22 AC_CANONICAL_BUILD
  23 AC_CANONICAL_HOST
  24 AC_CANONICAL_TARGET
  25
  26 echo "LIBREPLACE_LOCATION_CHECKS: END"
  27 ]) dnl end AC_LIBREPLACE_LOCATION_CHECKS
  28
  29
  30 AC_DEFUN_ONCE(AC_LIBREPLACE_BROKEN_CHECKS,
  31 [
  32 echo "LIBREPLACE_BROKEN_CHECKS: START"
  33
  34 dnl find the libreplace sources. This is meant to work both for
  35 dnl libreplace standalone builds, and builds of packages using libreplace
  36 libreplacedir=""
  37 libreplacepaths="$srcdir $srcdir/lib/replace $srcdir/libreplace $srcdir/../libreplace $srcdir/../replace $srcdir/../lib/replace $srcdir/../../../lib/replace"
  38 for d in $libreplacepaths; do
  39         if test -f "$d/replace.c"; then
  40                 libreplacedir="$d"
  41                 AC_SUBST(libreplacedir)
  42                 break;
  43         fi
  44 done
  45 if test x"$libreplacedir" = "x"; then
  46         AC_MSG_ERROR([cannot find libreplace in $libreplacepaths])
  47 fi
  48
  49 LIBREPLACEOBJ="$libreplacedir/replace.o"
  50 AC_SUBST(LIBREPLACEOBJ)
  51
  52 LIBREPLACEOBJ="${LIBREPLACEOBJ} $libreplacedir/snprintf.o  $libreplacedir/xattr.o"
  53
  54 AC_TYPE_UID_T
  55 AC_TYPE_MODE_T
  56 AC_TYPE_OFF_T
  57 AC_TYPE_SIZE_T
  58 AC_TYPE_PID_T
  59 AC_STRUCT_ST_RDEV
  60 AC_CHECK_TYPE(ino_t,unsigned)
  61 AC_CHECK_TYPE(loff_t,off_t)
  62 AC_CHECK_TYPE(offset_t,loff_t)
  63 AC_CHECK_TYPE(blksize_t,long)
  64 AC_CHECK_TYPE(blkcnt_t,long)
  65
  66 AC_FUNC_MEMCMP
  67
  68 AC_CHECK_FUNCS([pipe strftime srandom random srand rand usleep setbuffer lstat getpgrp utime utimes])
  69
  70 AC_CHECK_HEADERS(stdbool.h stdint.h sys/select.h)
  71 AC_CHECK_HEADERS(setjmp.h utime.h)
  72
  73 LIBREPLACE_PROVIDE_HEADER([stdint.h])
  74 LIBREPLACE_PROVIDE_HEADER([stdbool.h])
  75
  76 AC_DEFINE(HAVE_LIBREPLACE, 1, [We have libreplace])
  77
  78 AC_CHECK_TYPE(bool,
  79 [AC_DEFINE(HAVE_BOOL, 1, [Whether the bool type is available])],,
  80 [
  81 AC_INCLUDES_DEFAULT
  82 #ifdef HAVE_STDBOOL_H
  83 #include <stdbool.h>
  84 #endif]
  85 )
  86
  87 AC_CHECK_TYPE(_Bool,
  88 [AC_DEFINE(HAVE__Bool, 1, [Whether the _Bool type is available])],,
  89 [
  90 AC_INCLUDES_DEFAULT
  91 #ifdef HAVE_STDBOOL_H
  92 #include <stdbool.h>
  93 #endif]
  94 )
  95
  96 AC_CHECK_HEADERS(linux/types.h)
  97
  98 AC_CACHE_CHECK([for working mmap],libreplace_cv_HAVE_MMAP,[
  99 AC_TRY_RUN([#include "$libreplacedir/test/shared_mmap.c"],
 100            libreplace_cv_HAVE_MMAP=yes,libreplace_cv_HAVE_MMAP=no,libreplace_cv_HAVE_MMAP=cross)])
 101 if test x"$libreplace_cv_HAVE_MMAP" = x"yes"; then
 102     AC_DEFINE(HAVE_MMAP,1,[Whether mmap works])
 103 fi
 104
 105 AC_CACHE_CHECK([for working mremap],libreplace_cv_HAVE_MREMAP,[
 106 AC_TRY_RUN([#include "$libreplacedir/test/shared_mremap.c"],
 107            libreplace_cv_HAVE_MREMAP=yes,libreplace_cv_HAVE_MREMAP=no,libreplace_cv_HAVE_MREMAP=cross)])
 108 if test x"$libreplace_cv_HAVE_MREMAP" = x"yes"; then
 109     AC_DEFINE(HAVE_MREMAP,1,[Whether mremap works])
 110 fi
 111
 112 AC_CACHE_CHECK([for incoherent mmap],libreplace_cv_HAVE_INCOHERENT_MMAP,[
 113 AC_TRY_RUN([#include "$libreplacedir/test/incoherent_mmap.c"],
 114            libreplace_cv_HAVE_INCOHERENT_MMAP=yes,libreplace_cv_HAVE_INCOHERENT_MMAP=no,libreplace_cv_HAVE_INCOHERENT_MMAP=cross)])
 115 if test x"$libreplace_cv_HAVE_INCOHERENT_MMAP" = x"yes"; then
 116     AC_DEFINE(HAVE_INCOHERENT_MMAP,1,[Whether mmap is incoherent against write])
 117 fi
 118
 119
 120 AC_CHECK_HEADERS(sys/syslog.h syslog.h)
 121 AC_CHECK_HEADERS(sys/time.h time.h)
 122 AC_CHECK_HEADERS(stdarg.h vararg.h)
 123 AC_CHECK_HEADERS(sys/mount.h mntent.h)
 124 AC_CHECK_HEADERS(stropts.h)
 125 AC_CHECK_HEADERS(unix.h)
 126 AC_CHECK_HEADERS(malloc.h)
 127 AC_CHECK_HEADERS(syscall.h)
 128 AC_CHECK_HEADERS(sys/syscall.h)
 129
 130 AC_CHECK_FUNCS(syscall setuid seteuid setreuid setresuid setgid setegid setregid setresgid setgroups)
 131 AC_CHECK_FUNCS(chroot bzero strerror strerror_r memalign posix_memalign getpagesize)
 132 AC_CHECK_FUNCS(vsyslog setlinebuf mktime ftruncate chsize rename)
 133 AC_CHECK_FUNCS(waitpid wait4 strlcpy strlcat initgroups memmove strdup)
 134 AC_CHECK_FUNCS(pread pwrite strndup strcasestr strtok_r mkdtemp dup2 dprintf vdprintf)
 135 AC_CHECK_FUNCS(isatty chown lchown link readlink symlink realpath)
 136 AC_CHECK_FUNCS(fdatasync,,[
 137         # if we didn't find it, look in librt (Solaris hides it there...)
 138         AC_CHECK_LIB(rt, fdatasync,
 139                 [libreplace_cv_HAVE_FDATASYNC_IN_LIBRT=yes
 140                 AC_DEFINE(HAVE_FDATASYNC, 1, Define to 1 if there is support for fdatasync)])
 141 ])
 142 AC_HAVE_DECL(fdatasync, [#include <unistd.h>])
 143 AC_CHECK_FUNCS(clock_gettime,libreplace_cv_have_clock_gettime=yes,[
 144         AC_CHECK_LIB(rt, clock_gettime,
 145                 [libreplace_cv_HAVE_CLOCK_GETTIME_IN_LIBRT=yes
 146                 libreplace_cv_have_clock_gettime=yes
 147                 AC_DEFINE(HAVE_CLOCK_GETTIME, 1, Define to 1 if there is support for clock_gettime)])
 148 ])
 149
 150 AC_CHECK_HEADERS(sys/attributes.h attr/xattr.h sys/xattr.h sys/extattr.h sys/uio.h)
 151 AC_CHECK_HEADERS(sys/ea.h sys/proplist.h)
 152
 153 LIBREPLACE_FILESYS_LIBS=""
 154
 155 ############################################
 156 # Check for EA implementations
 157 case "$host_os" in
 158   *freebsd4* | *dragonfly* )
 159         AC_DEFINE(BROKEN_EXTATTR, 1, [Does extattr API work])
 160   ;;
 161   *)
 162         AC_SEARCH_LIBS(getxattr, [attr])
 163         AC_CHECK_FUNCS(attr_get attr_getf attr_list attr_listf attropen attr_remove)
 164         AC_CHECK_FUNCS(attr_removef attr_set attr_setf extattr_delete_fd extattr_delete_file)
 165         AC_CHECK_FUNCS(extattr_get_fd extattr_get_file extattr_list_fd extattr_list_file)
 166         AC_CHECK_FUNCS(extattr_set_fd extattr_set_file fgetea fgetxattr flistea flistxattr)
 167         AC_CHECK_FUNCS(fremoveea fremovexattr fsetea fsetxattr getea getxattr listea)
 168         AC_CHECK_FUNCS(listxattr removeea removexattr setea setxattr)
 169
 170         AC_CHECK_LIB_EXT(attr, LIBREPLACE_FILESYS_LIBS, flistea)
 171         AC_CHECK_LIB_EXT(attr, LIBREPLACE_FILESYS_LIBS, flistxattr)
 172         AC_CHECK_LIB_EXT(attr, LIBREPLACE_FILESYS_LIBS, attr_listf)
 173         AC_CHECK_LIB_EXT(attr, LIBREPLACE_FILESYS_LIBS, extattr_list_fd)
 174
 175   ;;
 176 esac
 177
 178
 179 ########################################################
 180 # Do xattr functions take additional options like on Darwin?
 181 if test x"$ac_cv_func_getxattr" = x"yes" ; then
 182         AC_CACHE_CHECK([whether xattr interface takes additional options], smb_attr_cv_xattr_add_opt, [
 183                 old_LIBS=$LIBS
 184                 LIBS="$LIBS $LIBREPLACE_FILESYS_LIBS"
 185                 AC_TRY_COMPILE([
 186                         #include <sys/types.h>
 187                         #if HAVE_ATTR_XATTR_H
 188                         #include <attr/xattr.h>
 189                         #elif HAVE_SYS_XATTR_H
 190                         #include <sys/xattr.h>
 191                         #endif
 192                 ],[
 193                         getxattr(0, 0, 0, 0, 0, 0);
 194                 ],
 195                 [smb_attr_cv_xattr_add_opt=yes],
 196                 [smb_attr_cv_xattr_add_opt=no;LIBS=$old_LIBS])
 197         ])
 198         if test x"$smb_attr_cv_xattr_add_opt" = x"yes"; then
 199                 AC_DEFINE(XATTR_ADDITIONAL_OPTIONS, 1, [xattr functions have additional options])
 200         fi
 201 fi
 202
 203 AC_CHECK_FUNCS(get_current_dir_name)
 204 AC_HAVE_DECL(setresuid, [#include <unistd.h>])
 205 AC_HAVE_DECL(setresgid, [#include <unistd.h>])
 206 AC_HAVE_DECL(errno, [#include <errno.h>])
 207
 208 AC_CACHE_CHECK([for secure mkstemp],libreplace_cv_HAVE_SECURE_MKSTEMP,[
 209 AC_TRY_RUN([#include <stdlib.h>
 210 #include <sys/types.h>
 211 #include <sys/stat.h>
 212 #include <unistd.h>
 213 main() {
 214   struct stat st;
 215   char tpl[20]="/tmp/test.XXXXXX";
 216   int fd = mkstemp(tpl);
 217   if (fd == -1) exit(1);
 218   unlink(tpl);
 219   if (fstat(fd, &st) != 0) exit(1);
 220   if ((st.st_mode & 0777) != 0600) exit(1);
 221   exit(0);
 222 }],
 223 libreplace_cv_HAVE_SECURE_MKSTEMP=yes,
 224 libreplace_cv_HAVE_SECURE_MKSTEMP=no,
 225 libreplace_cv_HAVE_SECURE_MKSTEMP=cross)])
 226 if test x"$libreplace_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 227     AC_DEFINE(HAVE_SECURE_MKSTEMP,1,[Whether mkstemp is secure])
 228 fi
 229
 230 dnl Provided by snprintf.c:
 231 AC_CHECK_HEADERS(stdio.h strings.h)
 232 AC_CHECK_DECLS([snprintf, vsnprintf, asprintf, vasprintf])
 233 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 234
 235 AC_CACHE_CHECK([for C99 vsnprintf],libreplace_cv_HAVE_C99_VSNPRINTF,[
 236 AC_TRY_RUN([
 237 #include <sys/types.h>
 238 #include <stdio.h>
 239 #include <stdarg.h>
 240 #include <stdlib.h>
 241 void foo(const char *format, ...) {
 242        va_list ap;
 243        int len;
 244        char buf[20];
 245        long long l = 1234567890;
 246        l *= 100;
 247
 248        va_start(ap, format);
 249        len = vsnprintf(buf, 0, format, ap);
 250        va_end(ap);
 251        if (len != 5) exit(1);
 252
 253        va_start(ap, format);
 254        len = vsnprintf(0, 0, format, ap);
 255        va_end(ap);
 256        if (len != 5) exit(2);
 257
 258        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(3);
 259
 260        if (snprintf(buf, 20, "%lld", l) != 12 || strcmp(buf, "123456789000") != 0) exit(4);
 261        if (snprintf(buf, 20, "%zu", 123456789) != 9 || strcmp(buf, "123456789") != 0) exit(5);
 262        if (snprintf(buf, 20, "%2\$d %1\$d", 3, 4) != 3 || strcmp(buf, "4 3") != 0) exit(6);
 263        if (snprintf(buf, 20, "%s", 0) < 3) exit(7);
 264
 265        exit(0);
 266 }
 267 main() { foo("hello"); }
 268 ],
 269 libreplace_cv_HAVE_C99_VSNPRINTF=yes,libreplace_cv_HAVE_C99_VSNPRINTF=no,libreplace_cv_HAVE_C99_VSNPRINTF=cross)])
 270 if test x"$libreplace_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 271     AC_DEFINE(HAVE_C99_VSNPRINTF,1,[Whether there is a C99 compliant vsnprintf])
 272 fi
 273
 274
 275 dnl VA_COPY
 276 AC_CACHE_CHECK([for va_copy],libreplace_cv_HAVE_VA_COPY,[
 277 AC_TRY_LINK([#include <stdarg.h>
 278 va_list ap1,ap2;], [va_copy(ap1,ap2);],
 279 libreplace_cv_HAVE_VA_COPY=yes,libreplace_cv_HAVE_VA_COPY=no)])
 280 if test x"$libreplace_cv_HAVE_VA_COPY" = x"yes"; then
 281     AC_DEFINE(HAVE_VA_COPY,1,[Whether va_copy() is available])
 282 fi
 283
 284 if test x"$libreplace_cv_HAVE_VA_COPY" != x"yes"; then
 285 AC_CACHE_CHECK([for __va_copy],libreplace_cv_HAVE___VA_COPY,[
 286 AC_TRY_LINK([#include <stdarg.h>
 287 va_list ap1,ap2;], [__va_copy(ap1,ap2);],
 288 libreplace_cv_HAVE___VA_COPY=yes,libreplace_cv_HAVE___VA_COPY=no)])
 289 if test x"$libreplace_cv_HAVE___VA_COPY" = x"yes"; then
 290     AC_DEFINE(HAVE___VA_COPY,1,[Whether __va_copy() is available])
 291 fi
 292 fi
 293
 294 dnl __FUNCTION__ macro
 295 AC_CACHE_CHECK([for __FUNCTION__ macro],libreplace_cv_HAVE_FUNCTION_MACRO,[
 296 AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __FUNCTION__);],
 297 libreplace_cv_HAVE_FUNCTION_MACRO=yes,libreplace_cv_HAVE_FUNCTION_MACRO=no)])
 298 if test x"$libreplace_cv_HAVE_FUNCTION_MACRO" = x"yes"; then
 299     AC_DEFINE(HAVE_FUNCTION_MACRO,1,[Whether there is a __FUNCTION__ macro])
 300 else
 301     dnl __func__ macro
 302     AC_CACHE_CHECK([for __func__ macro],libreplace_cv_HAVE_func_MACRO,[
 303     AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __func__);],
 304     libreplace_cv_HAVE_func_MACRO=yes,libreplace_cv_HAVE_func_MACRO=no)])
 305     if test x"$libreplace_cv_HAVE_func_MACRO" = x"yes"; then
 306        AC_DEFINE(HAVE_func_MACRO,1,[Whether there is a __func__ macro])
 307     fi
 308 fi
 309
 310 AC_CHECK_HEADERS([sys/param.h limits.h])
 311
 312 AC_CHECK_TYPE(comparison_fn_t,
 313 [AC_DEFINE(HAVE_COMPARISON_FN_T, 1,[Whether or not we have comparison_fn_t])])
 314
 315 AC_HAVE_DECL(setenv, [#include <stdlib.h>])
 316 AC_CHECK_FUNCS(setenv unsetenv)
 317 AC_HAVE_DECL(environ, [#include <unistd.h>])
 318
 319 AC_CHECK_FUNCS(strnlen)
 320 AC_CHECK_FUNCS(strtoull __strtoull strtouq strtoll __strtoll strtoq)
 321
 322 AC_CHECK_FUNCS(memmem)
 323
 324 # this test disabled as we don't actually need __VA_ARGS__ yet
 325 AC_TRY_CPP([
 326 #define eprintf(...) fprintf(stderr, __VA_ARGS__)
 327 eprintf("bla", "bar");
 328 ], AC_DEFINE(HAVE__VA_ARGS__MACRO, 1, [Whether the __VA_ARGS__ macro is available]))
 329
 330
 331 AC_CACHE_CHECK([for sig_atomic_t type],libreplace_cv_sig_atomic_t, [
 332     AC_TRY_COMPILE([
 333 #include <sys/types.h>
 334 #if STDC_HEADERS
 335 #include <stdlib.h>
 336 #include <stddef.h>
 337 #endif
 338 #include <signal.h>],[sig_atomic_t i = 0],
 339         libreplace_cv_sig_atomic_t=yes,libreplace_cv_sig_atomic_t=no)])
 340 if test x"$libreplace_cv_sig_atomic_t" = x"yes"; then
 341    AC_DEFINE(HAVE_SIG_ATOMIC_T_TYPE,1,[Whether we have the atomic_t variable type])
 342 fi
 343
 344
 345 AC_CACHE_CHECK([for O_DIRECT flag to open(2)],libreplace_cv_HAVE_OPEN_O_DIRECT,[
 346 AC_TRY_COMPILE([
 347 #include <unistd.h>
 348 #ifdef HAVE_FCNTL_H
 349 #include <fcntl.h>
 350 #endif],
 351 [int fd = open("/dev/null", O_DIRECT);],
 352 libreplace_cv_HAVE_OPEN_O_DIRECT=yes,libreplace_cv_HAVE_OPEN_O_DIRECT=no)])
 353 if test x"$libreplace_cv_HAVE_OPEN_O_DIRECT" = x"yes"; then
 354     AC_DEFINE(HAVE_OPEN_O_DIRECT,1,[Whether the open(2) accepts O_DIRECT])
 355 fi
 356
 357
 358 dnl Check if the C compiler understands volatile (it should, being ANSI).
 359 AC_CACHE_CHECK([that the C compiler understands volatile],libreplace_cv_volatile, [
 360         AC_TRY_COMPILE([#include <sys/types.h>],[volatile int i = 0],
 361                 libreplace_cv_volatile=yes,libreplace_cv_volatile=no)])
 362 if test x"$libreplace_cv_volatile" = x"yes"; then
 363         AC_DEFINE(HAVE_VOLATILE, 1, [Whether the C compiler understands volatile])
 364 fi
 365
 366 m4_include(system/config.m4)
 367
 368 m4_include(dlfcn.m4)
 369 m4_include(getpass.m4)
 370 m4_include(strptime.m4)
 371 m4_include(win32.m4)
 372 m4_include(timegm.m4)
 373 m4_include(repdir.m4)
 374 m4_include(crypt.m4)
 375
 376 if test x$libreplace_cv_have_clock_gettime = xyes ; then
 377         SMB_CHECK_CLOCK_ID(CLOCK_MONOTONIC)
 378         SMB_CHECK_CLOCK_ID(CLOCK_PROCESS_CPUTIME_ID)
 379         SMB_CHECK_CLOCK_ID(CLOCK_REALTIME)
 380 fi
 381
 382 AC_CACHE_CHECK([for struct timespec type],libreplace_cv_struct_timespec, [
 383     AC_TRY_COMPILE([
 384 #include <sys/types.h>
 385 #if STDC_HEADERS
 386 #include <stdlib.h>
 387 #include <stddef.h>
 388 #endif
 389 #if TIME_WITH_SYS_TIME
 390 # include <sys/time.h>
 391 # include <time.h>
 392 #else
 393 # if HAVE_SYS_TIME_H
 394 #  include <sys/time.h>
 395 # else
 396 #  include <time.h>
 397 # endif
 398 #endif
 399 ],[struct timespec ts;],
 400         libreplace_cv_struct_timespec=yes,libreplace_cv_struct_timespec=no)])
 401 if test x"$libreplace_cv_struct_timespec" = x"yes"; then
 402    AC_DEFINE(HAVE_STRUCT_TIMESPEC,1,[Whether we have struct timespec])
 403 fi
 404
 405 AC_CHECK_FUNCS([printf memset memcpy],,[AC_MSG_ERROR([Required function not found])])
 406
 407 echo "LIBREPLACE_BROKEN_CHECKS: END"
 408 ]) dnl end AC_LIBREPLACE_BROKEN_CHECKS
 409
 410 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_START,
 411 [
 412 #LIBREPLACE_ALL_CHECKS: START"
 413 ])
 414 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_END,
 415 [
 416 #LIBREPLACE_ALL_CHECKS: END"
 417 ])
 418 m4_define(AC_LIBREPLACE_ALL_CHECKS,
 419 [
 420 AC__LIBREPLACE_ALL_CHECKS_START
 421 AC_LIBREPLACE_LOCATION_CHECKS
 422 AC_LIBREPLACE_CC_CHECKS
 423 AC_LIBREPLACE_BROKEN_CHECKS
 424 AC__LIBREPLACE_ALL_CHECKS_END
 425 CFLAGS="$CFLAGS -I$libreplacedir"
 426 ])
 427
 428 m4_include(libreplace_cc.m4)
 429 m4_include(libreplace_ld.m4)
 430 m4_include(libreplace_network.m4)
 431 m4_include(libreplace_macros.m4)
 432
 433
 434 dnl SMB_CHECK_CLOCK_ID(clockid)
 435 dnl Test whether the specified clock_gettime clock ID is available. If it
 436 dnl is, we define HAVE_clockid
 437 AC_DEFUN([SMB_CHECK_CLOCK_ID],
 438 [
 439     AC_MSG_CHECKING(for $1)
 440     AC_TRY_LINK([
 441 #if TIME_WITH_SYS_TIME
 442 # include <sys/time.h>
 443 # include <time.h>
 444 #else
 445 # if HAVE_SYS_TIME_H
 446 #  include <sys/time.h>
 447 # else
 448 #  include <time.h>
 449 # endif
 450 #endif
 451     ],
 452     [
 453 clockid_t clk = $1;
 454     ],
 455     [
 456         AC_MSG_RESULT(yes)
 457         AC_DEFINE(HAVE_$1, 1,
 458             [Whether the clock_gettime clock ID $1 is available])
 459     ],
 460     [
 461         AC_MSG_RESULT(no)
 462     ])
 463 ])
 464 m4_ifndef([AC_USE_SYSTEM_EXTENSIONS],[m4_include(autoconf-2.60.m4)])