firmware/app.lds

   1 #include "config.h"
   2
   3 ENTRY(start)
   4 #ifdef CPU_COLDFIRE
   5 OUTPUT_FORMAT(elf32-m68k)
   6 INPUT(target/coldfire/crt0.o)
   7 #elif CONFIG_CPU == TCC730
   8 OUTPUT_FORMAT(elf32-calmrisc16)
   9 INPUT(crt0.o)
  10 #elif defined(CPU_ARM)
  11 OUTPUT_FORMAT(elf32-littlearm)
  12 OUTPUT_ARCH(arm)
  13 #ifdef CPU_PP
  14 INPUT(target/arm/crt0-pp.o)
  15 #elif defined(CPU_ARM)
  16 INPUT(target/arm/crt0.o)
  17 #endif
  18 #else
  19 OUTPUT_FORMAT(elf32-sh)
  20 INPUT(target/sh/crt0.o)
  21 #endif
  22
  23 #if CONFIG_CPU == TCC730
  24 MEMORY
  25 {
  26    FIRMWARE : ORIGIN = LOADADDRESS, LENGTH = 256K
  27    FLASH (RX) : ORIGIN = 0x000000, LENGTH = 1024K
  28    ICMEM (RX) : ORIGIN = 0x3FC000, LENGTH = 32K
  29    IMEM1 : ORIGIN = 0x200000, LENGTH = 32K
  30    IMEM2 : ORIGIN = 0x210000, LENGTH = 16K
  31    IMEM3 : ORIGIN = 0x220000, LENGTH = 32K
  32    IMEM4 : ORIGIN = 0x230000, LENGTH = 16K
  33
  34    DRAM : ORIGIN = 0x000000, LENGTH = 0x3F0000
  35 }
  36
  37 SECTIONS
  38 {
  39 .text LOADADDRESS : {
  40         *(.init.text)
  41         *(.text)
  42         }> FLASH  AT> FIRMWARE
  43
  44 .icode 0x3FC040: {
  45         *(.vectors)
  46         *(.icode)
  47         }> ICMEM  AT> FIRMWARE
  48
  49 /* We start at 0x2000, to avoid overwriting Archos' loader datasegment.
  50  * If it turns out that we won't call back the loader, this can be set to 0.
  51  */
  52 .bss 0x2000 : {
  53         *(.bss)
  54         . = ALIGN(2);
  55         }> DRAM
  56
  57 /* Data is put after BSS, to have all strings addresses > VIRT_PTR + VIRT_SIZE.
  58    Strings are in rodata, so what we really assert is (.rodata > VIRT_PTR + VIRT_SIZE)
  59    See settings.h for details */
  60 .data ALIGN(2): {
  61         *(.data)
  62         . = ALIGN(2);
  63         *(.rodata)
  64         . = ALIGN(2);
  65         *(.rodata.str1.2)
  66         . = ALIGN(2);
  67         }> DRAM AT> FIRMWARE
  68
  69
  70 .stack ALIGN(2) : {
  71    . = . + 0x2000;
  72 }> DRAM
  73
  74 .idata 0x200000: {
  75         *(.idata)
  76 }> IMEM1
  77
  78 .idata2 0x220000: {
  79         *(.idata2)
  80 }> IMEM3
  81
  82 _codesize = SIZEOF(.text);
  83
  84 _icodecopy = LOADADDR(.icode);
  85 _icodestart = ADDR(.icode);
  86 _icodesize = SIZEOF(.icode);
  87
  88 _datacopy = LOADADDR(.data);
  89 _datastart = ADDR(.data);
  90 _datasize = SIZEOF(.data);
  91
  92
  93 _bssstart = ADDR(.bss);
  94 _bsssize = (SIZEOF(.bss) + 1) & ~ 1;
  95
  96 _stackbegin = ADDR(.stack);
  97 _stackend = ADDR(.stack) + SIZEOF(.stack);
  98
  99 _idatastart = ADDR(.idata);
 100
 101 /* FIXME: Where to put audio buffer? */
 102
 103 _audiobuffer = 0;
 104 _audiobufend = 0;
 105
 106 /* Plugins are not supported on the Gmini*/
 107
 108 _pluginbuf = 0;
 109
 110 }
 111 #else
 112
 113 #define PLUGINSIZE PLUGIN_BUFFER_SIZE
 114 #define CODECSIZE CODEC_SIZE
 115
 116
 117 #ifdef DEBUG
 118 #define STUBOFFSET 0x10000
 119 #else
 120 #define STUBOFFSET 0
 121 #endif
 122
 123 #define DRAMSIZE (MEMORYSIZE * 0x100000) - PLUGINSIZE - STUBOFFSET - CODECSIZE
 124
 125 #if defined(IRIVER_H100_SERIES) || defined(IRIVER_H300)
 126 #define DRAMORIG 0x31000000 + STUBOFFSET
 127 #define IRAMORIG 0x10000000
 128 #define IRAMSIZE 0xc000
 129 #elif defined(IAUDIO_X5)
 130 #define DRAMORIG 0x31000000 + STUBOFFSET
 131 #define IRAMORIG 0x10000000
 132 #define IRAMSIZE 0x14000
 133 #elif (CONFIG_CPU==PP5002) || (CONFIG_CPU==PP5020)
 134 #define DRAMORIG 0x00000000 + STUBOFFSET
 135 #define IRAMORIG 0x40000000
 136 #define IRAMSIZE 0xc000
 137 #elif CONFIG_CPU==PNX0101
 138 #define DRAMORIG 0xc00000 + STUBOFFSET
 139 #define IRAMORIG 0x400000
 140 #define IRAMSIZE 0x7000
 141 #elif CONFIG_CPU==S3C2440
 142 #define DRAMORIG 0x30000000 + STUBOFFSET
 143 #define IRAMORIG 0x40000000
 144 #define IRAMSIZE 4K
 145 #else
 146 #define DRAMORIG 0x09000000 + STUBOFFSET
 147 #define IRAMORIG 0x0f000000
 148 #define IRAMSIZE 0x1000
 149 #endif
 150
 151 /* End of the audio buffer, where the codec buffer starts */
 152 #define ENDAUDIOADDR  (DRAMORIG + DRAMSIZE)
 153
 154 /* Where the codec buffer ends, and the plugin buffer starts */
 155 #define ENDADDR (ENDAUDIOADDR + CODECSIZE)
 156
 157 MEMORY
 158 {
 159    DRAM : ORIGIN = DRAMORIG, LENGTH = DRAMSIZE
 160    IRAM : ORIGIN = IRAMORIG, LENGTH = IRAMSIZE
 161 #if CONFIG_CPU==PNX0101
 162    IRAM0 : ORIGIN = 0x0, LENGTH = IRAMSIZE
 163 #endif
 164 }
 165
 166 SECTIONS
 167 {
 168 #ifndef CPU_ARM
 169     .vectors :
 170     {
 171         loadaddress = .;
 172         _loadaddress = .;
 173         KEEP(*(.resetvectors));
 174         *(.resetvectors);
 175         KEEP(*(.vectors));
 176         *(.vectors);
 177     } > DRAM
 178
 179     .text :
 180     {
 181 #else
 182     .text :
 183     {
 184         loadaddress = .;
 185         _loadaddress = .;
 186 #endif
 187         . = ALIGN(0x200);
 188         *(.init.text)
 189         *(.text*)
 190 #ifdef CPU_ARM
 191         *(.glue_7)
 192         *(.glue_7t)
 193 #endif
 194         . = ALIGN(0x4);
 195     } > DRAM
 196
 197     .rodata :
 198     {
 199         *(.rodata)  /* problems without this, dunno why */
 200         *(.rodata*)
 201         *(.rodata.str1.1)
 202         *(.rodata.str1.4)
 203         . = ALIGN(0x4);
 204
 205         /* Pseudo-allocate the copies of the data sections */
 206         _datacopy = .;
 207     } > DRAM
 208
 209     /* TRICK ALERT! For RAM execution, we put the .data section at the
 210        same load address as the copy. Thus, we don't waste extra RAM
 211        when we don't actually need the copy.  */
 212     .data : AT ( _datacopy )
 213     {
 214         _datastart = .;
 215         *(.data*)
 216         . = ALIGN(0x4);
 217         _dataend  = .;
 218     } > DRAM
 219
 220     /DISCARD/ :
 221     {
 222         *(.eh_frame)
 223     }
 224
 225 #ifdef CPU_ARM
 226     .vectors 0x0 :
 227     {
 228         _vectorsstart = .;
 229         *(.vectors);
 230         _vectorsend = .;
 231 #if CONFIG_CPU==PNX0101
 232         *(.dmabuf)
 233     } >IRAM0 AT> DRAM
 234 #else
 235     } AT> DRAM
 236 #endif
 237
 238     _vectorscopy = LOADADDR(.vectors);
 239 #endif
 240
 241 #if CONFIG_CPU==PNX0101
 242     .iram IRAMORIG + SIZEOF(.vectors) :
 243 #else
 244     .iram IRAMORIG :
 245 #endif
 246     {
 247         _iramstart = .;
 248         *(.icode)
 249         *(.irodata)
 250         *(.idata)
 251         _iramend = .;
 252     } > IRAM AT> DRAM
 253
 254     _iramcopy = LOADADDR(.iram);
 255
 256     .ibss (NOLOAD) :
 257     {
 258         _iedata = .;
 259         *(.ibss)
 260         . = ALIGN(0x4);
 261         _iend = .;
 262     } > IRAM
 263
 264 #if defined(CPU_COLDFIRE) || defined(CPU_ARM)
 265     .stack :
 266     {
 267        *(.stack)
 268        stackbegin = .;
 269        . += 0x2000;
 270        stackend = .;
 271     } > IRAM
 272
 273 #ifdef CPU_PP
 274     .cop_stack :
 275     {
 276        *(.cop_stack)
 277        cop_stackbegin = .;
 278        . += 0x0500;
 279        cop_stackend = .;
 280     } > IRAM
 281 #endif
 282
 283 #else
 284     /* TRICK ALERT! We want 0x2000 bytes of stack, but we set the section
 285        size smaller, and allow the stack to grow into the .iram copy */
 286     .stack ADDR(.data) + SIZEOF(.data) + SIZEOF(.iram):
 287     {
 288        *(.stack)
 289        _stackbegin = . - SIZEOF(.iram);
 290        . += 0x2000 - SIZEOF(.iram);
 291        _stackend = .;
 292     } > DRAM
 293 #endif
 294
 295 #if defined(CPU_COLDFIRE)
 296     .bss ADDR(.data) + SIZEOF(.data) + SIZEOF(.iram):
 297 #elif defined(CPU_ARM)
 298     .bss ADDR(.data) + SIZEOF(.data) + SIZEOF(.iram) + SIZEOF(.vectors):
 299 #else
 300     .bss :
 301 #endif
 302     {
 303        _edata = .;
 304         *(.bss*)
 305         *(COMMON)
 306         . = ALIGN(0x4);
 307        _end = .;
 308     } > DRAM
 309
 310     .audiobuf ALIGN(4) :
 311     {
 312         _audiobuffer = .;
 313         audiobuffer = .;
 314     } > DRAM
 315
 316     .audiobufend ENDAUDIOADDR:
 317     {
 318         audiobufend = .;
 319         _audiobufend = .;
 320     } > DRAM
 321
 322     .codec ENDAUDIOADDR:
 323     {
 324         codecbuf = .;
 325         _codecbuf = .;
 326     }
 327
 328     .plugin ENDADDR:
 329     {
 330         _pluginbuf = .;
 331         pluginbuf = .;
 332     }
 333 }
 334
 335 #endif