configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL$
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.61], [], [m4_fatal([Autoconf version 2.61 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2008, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33
  34 AC_CANONICAL_HOST
  35
  36 template=
  37 AC_MSG_CHECKING([which template to use])
  38
  39 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  40 [
  41   case $withval in
  42     list)   echo; ls "$srcdir/src/template"; exit;;
  43     *)      if test -f "$srcdir/src/template/$with_template" ; then
  44               template=$withval
  45             else
  46               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  47             fi;;
  48   esac
  49 ],
  50 [
  51 # --with-template not given
  52
  53 case $host_os in
  54      aix*) template=aix ;;
  55     bsdi*) template=bsdi ;;
  56   cygwin*) template=cygwin ;;
  57   darwin*) template=darwin ;;
  58     dgux*) template=dgux ;;
  59  freebsd*) template=freebsd ;;
  60     hpux*) template=hpux ;;
  61     irix*) template=irix ;;
  62  linux*|gnu*|k*bsd*-gnu)
  63            template=linux ;;
  64    mingw*) template=win32 ;;
  65   netbsd*) template=netbsd ;;
  66 nextstep*) template=nextstep ;;
  67  openbsd*) template=openbsd ;;
  68      osf*) template=osf ;;
  69      sco*) template=sco ;;
  70  solaris*) template=solaris ;;
  71    sunos*) template=sunos4 ;;
  72  sysv4.2*)
  73         case $host_vendor in
  74           univel) template=univel ;;
  75         esac ;;
  76    sysv4*) template=svr4 ;;
  77    sysv5*) template=unixware ;;
  78   ultrix*) template=ultrix4 ;;
  79 esac
  80
  81   if test x"$template" = x"" ; then
  82     AC_MSG_ERROR([[
  83 *******************************************************************
  84 PostgreSQL has apparently not been ported to your platform yet.
  85 To try a manual configuration, look into the src/template directory
  86 for a similar platform and use the '--with-template=' option.
  87
  88 Please also contact <pgsql-ports@postgresql.org> to see about
  89 rectifying this.  Include the above 'checking host system type...'
  90 line.
  91 *******************************************************************
  92 ]])
  93   fi
  94
  95 ])
  96
  97 AC_MSG_RESULT([$template])
  98
  99 PORTNAME=$template
 100 AC_SUBST(PORTNAME)
 101
 102 # Initialize default assumption that we do not need separate assembly code
 103 # for TAS (test-and-set).  This can be overridden by the template file
 104 # when it's executed.
 105 need_tas=no
 106 tas_file=dummy.s
 107
 108
 109
 110 ##
 111 ## Command line options
 112 ##
 113
 114 #
 115 # Add non-standard directories to the include path
 116 #
 117 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 118
 119
 120 #
 121 # Add non-standard directories to the library search path
 122 #
 123 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 124              [LIBRARY_DIRS=$withval])
 125
 126 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 127              [LIBRARY_DIRS=$withval])
 128
 129
 130 #
 131 # 64-bit integer date/time storage: enabled by default.
 132 #
 133 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 134 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 135               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 136                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 137 AC_MSG_RESULT([$enable_integer_datetimes])
 138
 139
 140 #
 141 # NLS
 142 #
 143 AC_MSG_CHECKING([whether NLS is wanted])
 144 PGAC_ARG_OPTARG(enable, nls,
 145                 [LANGUAGES], [enable Native Language Support],
 146                 [],
 147                 [WANTED_LANGUAGES=$enableval],
 148                 [AC_DEFINE(ENABLE_NLS, 1,
 149                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 150 AC_MSG_RESULT([$enable_nls])
 151 AC_SUBST(enable_nls)
 152 AC_SUBST(WANTED_LANGUAGES)
 153
 154 #
 155 # Default port number (--with-pgport), default 5432
 156 #
 157 AC_MSG_CHECKING([for default port number])
 158 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 159              [default_port=$withval],
 160              [default_port=5432])
 161 AC_MSG_RESULT([$default_port])
 162 # Need both of these because some places want an integer and some a string
 163 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 164 [Define to the default TCP port number on which the server listens and
 165 to which clients will try to connect.  This can be overridden at run-time,
 166 but it's convenient if your clients have the right default compiled in.
 167 (--with-pgport=PORTNUM)])
 168 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 169                    [Define to the default TCP port number as a string constant.])
 170 AC_SUBST(default_port)
 171
 172 #
 173 # Option to disable shared libraries
 174 #
 175 PGAC_ARG_BOOL(enable, shared, yes,
 176               [do not build shared libraries])
 177 AC_SUBST(enable_shared)
 178
 179 #
 180 # '-rpath'-like feature can be disabled
 181 #
 182 PGAC_ARG_BOOL(enable, rpath, yes,
 183               [do not embed shared library search path in executables])
 184 AC_SUBST(enable_rpath)
 185
 186 #
 187 # Spinlocks
 188 #
 189 PGAC_ARG_BOOL(enable, spinlocks, yes,
 190               [do not use spinlocks])
 191
 192 #
 193 # --enable-debug adds -g to compiler flags
 194 #
 195 PGAC_ARG_BOOL(enable, debug, no,
 196               [build with debugging symbols (-g)])
 197 AC_SUBST(enable_debug)
 198
 199 #
 200 # --enable-profiling enables gcc profiling
 201 #
 202 PGAC_ARG_BOOL(enable, profiling, no,
 203               [build with profiling enabled ])
 204 AC_SUBST(enable_profiling)
 205
 206 #
 207 # --enable-coverage enables generation of code coverage metrics with gcov
 208 #
 209 PGAC_ARG_BOOL(enable, coverage, no,
 210               [build with coverage testing instrumentation],
 211 [AC_CHECK_PROGS(GCOV, gcov)
 212 if test -z "$GCOV"; then
 213   AC_MSG_ERROR([gcov not found])
 214 fi
 215 AC_CHECK_PROGS(LCOV, lcov)
 216 if test -z "$LCOV"; then
 217   AC_MSG_ERROR([lcov not found])
 218 fi
 219 AC_CHECK_PROGS(GENHTML, genhtml)
 220 if test -z "$GENHTML"; then
 221   AC_MSG_ERROR([genhtml not found])
 222 fi])
 223 AC_SUBST(enable_coverage)
 224
 225 #
 226 # DTrace
 227 #
 228 PGAC_ARG_BOOL(enable, dtrace, no,
 229               [build with DTrace support],
 230 [AC_DEFINE([ENABLE_DTRACE], 1,
 231            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 232 AC_CHECK_PROGS(DTRACE, dtrace)
 233 if test -z "$DTRACE"; then
 234   AC_MSG_ERROR([dtrace not found])
 235 fi
 236 AC_SUBST(DTRACEFLAGS)])
 237 AC_SUBST(enable_dtrace)
 238
 239 #
 240 # Block size
 241 #
 242 AC_MSG_CHECKING([for block size])
 243 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 244              [blocksize=$withval],
 245              [blocksize=8])
 246 case ${blocksize} in
 247   1) BLCKSZ=1024;;
 248   2) BLCKSZ=2048;;
 249   4) BLCKSZ=4096;;
 250   8) BLCKSZ=8192;;
 251  16) BLCKSZ=16384;;
 252  32) BLCKSZ=32768;;
 253   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 254 esac
 255 AC_MSG_RESULT([${blocksize}kB])
 256
 257 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 258  Size of a disk block --- this also limits the size of a tuple.  You
 259  can set it bigger if you need bigger tuples (although TOAST should
 260  reduce the need to have large tuples, since fields can be spread
 261  across multiple tuples).
 262
 263  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 264  is currently 2^15 (32768).  This is determined by the 15-bit widths
 265  of the lp_off and lp_len fields in ItemIdData (see
 266  include/storage/itemid.h).
 267
 268  Changing BLCKSZ requires an initdb.
 269 ])
 270
 271 #
 272 # Relation segment size
 273 #
 274 AC_MSG_CHECKING([for segment size])
 275 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 276              [segsize=$withval],
 277              [segsize=1])
 278 # this expression is set up to avoid unnecessary integer overflow
 279 # blocksize is already guaranteed to be a factor of 1024
 280 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 281 test $? -eq 0 || exit 1
 282 AC_MSG_RESULT([${segsize}GB])
 283
 284 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 285  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 286  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 287  relations bigger than that are divided into multiple files.
 288
 289  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 290  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 291  have large file support enabled.  By default, we make the limit 1 GB
 292  to avoid any possible integer-overflow problems within the OS.
 293  A limit smaller than necessary only means we divide a large
 294  relation into more chunks than necessary, so it seems best to err
 295  in the direction of a small limit.
 296
 297  A power-of-2 value is recommended to save a few cycles in md.c,
 298  but is not absolutely required.
 299
 300  Changing RELSEG_SIZE requires an initdb.
 301 ])
 302
 303 #
 304 # WAL block size
 305 #
 306 AC_MSG_CHECKING([for WAL block size])
 307 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 308              [wal_blocksize=$withval],
 309              [wal_blocksize=8])
 310 case ${wal_blocksize} in
 311   1) XLOG_BLCKSZ=1024;;
 312   2) XLOG_BLCKSZ=2048;;
 313   4) XLOG_BLCKSZ=4096;;
 314   8) XLOG_BLCKSZ=8192;;
 315  16) XLOG_BLCKSZ=16384;;
 316  32) XLOG_BLCKSZ=32768;;
 317  64) XLOG_BLCKSZ=65536;;
 318   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 319 esac
 320 AC_MSG_RESULT([${wal_blocksize}kB])
 321
 322 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 323  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 324  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 325  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 326  buffers, else direct I/O may fail.
 327
 328  Changing XLOG_BLCKSZ requires an initdb.
 329 ])
 330
 331 #
 332 # WAL segment size
 333 #
 334 AC_MSG_CHECKING([for WAL segment size])
 335 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 336              [wal_segsize=$withval],
 337              [wal_segsize=16])
 338 case ${wal_segsize} in
 339   1) ;;
 340   2) ;;
 341   4) ;;
 342   8) ;;
 343  16) ;;
 344  32) ;;
 345  64) ;;
 346   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 347 esac
 348 AC_MSG_RESULT([${wal_segsize}MB])
 349
 350 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 351  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 352  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 353  XLOG_BLCKSZ).
 354
 355  Changing XLOG_SEG_SIZE requires an initdb.
 356 ])
 357
 358 #
 359 # C compiler
 360 #
 361
 362 # For historical reasons you can also use --with-CC to specify the C compiler
 363 # to use, although the standard way to do this is to set the CC environment
 364 # variable.
 365 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 366
 367 case $template in
 368   aix) pgac_cc_list="gcc xlc";;
 369  irix) pgac_cc_list="cc";; # no gcc
 370     *) pgac_cc_list="gcc cc";;
 371 esac
 372
 373 AC_PROG_CC([$pgac_cc_list])
 374
 375 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 376 # but has idiosyncrasies of its own.  We assume icc will define
 377 # __INTEL_COMPILER regardless of CFLAGS.
 378 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 379 choke me
 380 @%:@endif], [ICC=[yes]], [ICC=[no]])
 381
 382 # Check if it's Sun Studio compiler. We assume that
 383 # __SUNPRO_C will be defined for Sun Studio compilers
 384 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 385 choke me
 386 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 387
 388 AC_SUBST(SUN_STUDIO_CC)
 389
 390 unset CFLAGS
 391
 392 #
 393 # Read the template
 394 #
 395 . "$srcdir/src/template/$template" || exit
 396
 397 # CFLAGS are selected so:
 398 # If the user specifies something in the environment, that is used.
 399 # else:  If the template file set something, that is used.
 400 # else:  If coverage was enabled, don't set anything.
 401 # else:  If the compiler is GCC, then we use -O2.
 402 # else:  If the compiler is something else, then we use -O.
 403
 404 if test "$ac_env_CFLAGS_set" = set; then
 405   CFLAGS=$ac_env_CFLAGS_value
 406 elif test "${CFLAGS+set}" = set; then
 407   : # (keep what template set)
 408 elif test "$enable_coverage" = yes; then
 409   : # no optimization by default
 410 elif test "$GCC" = yes; then
 411   CFLAGS="-O2"
 412 else
 413   # if the user selected debug mode, don't use -O
 414   if test "$enable_debug" != yes; then
 415     CFLAGS="-O"
 416   fi
 417 fi
 418
 419 # Some versions of GCC support some additional useful warning flags.
 420 # Check whether they are supported, and add them to CFLAGS if so.
 421 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 422
 423 if test "$GCC" = yes -a "$ICC" = no; then
 424   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 425   # These work in some but not all gcc versions
 426   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 427   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 428   # Disable strict-aliasing rules; needed for gcc 3.3+
 429   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 430   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 431   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 432 elif test "$ICC" = yes; then
 433   # Intel's compiler has a bug/misoptimization in checking for
 434   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 435   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 436   # Make sure strict aliasing is off (though this is said to be the default)
 437   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 438 elif test x"${CC}" = x"xlc"; then
 439   # AIX xlc has to have strict aliasing turned off too
 440   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 441 fi
 442
 443 # supply -g if --enable-debug
 444 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 445   CFLAGS="$CFLAGS -g"
 446 fi
 447
 448 # enable code coverage if --enable-coverage
 449 if test "$enable_coverage" = yes; then
 450   if test "$GCC" = yes; then
 451     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 452   else
 453     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 454   fi
 455 fi
 456
 457 # enable profiling if --enable-profiling
 458 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 459   if test "$GCC" = yes; then
 460     AC_DEFINE([PROFILE_PID_DIR], 1,
 461            [Define to 1 to allow profiling output to be saved separately for each process.])
 462     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 463   else
 464     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 465   fi
 466 fi
 467
 468 # We already have this in Makefile.win32, but configure needs it too
 469 if test "$PORTNAME" = "win32"; then
 470   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 471 fi
 472
 473 # Check if the compiler still works with the template settings
 474 AC_MSG_CHECKING([whether the C compiler still works])
 475 AC_TRY_LINK([], [return 0;],
 476   [AC_MSG_RESULT(yes)],
 477   [AC_MSG_RESULT(no)
 478    AC_MSG_ERROR([cannot proceed])])
 479
 480 # Defend against gcc -ffast-math
 481 if test "$GCC" = yes; then
 482 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 483 choke me
 484 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 485 fi
 486
 487 AC_PROG_CPP
 488 AC_SUBST(GCC)
 489
 490 # Create compiler version string
 491 if test x"$GCC" = x"yes" ; then
 492   cc_string="GCC `${CC} --version | sed q`"
 493 else
 494   cc_string=$CC
 495 fi
 496 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 497                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 498                    [A string containing the version number, platform, and C compiler])
 499
 500
 501 #
 502 # Set up TAS assembly code if needed; the template file has now had its
 503 # chance to request this.
 504 #
 505 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 506
 507 if test "$need_tas" = yes ; then
 508   TAS=tas.o
 509 else
 510   TAS=""
 511 fi
 512 AC_SUBST(TAS)
 513
 514
 515 #
 516 # Automatic dependency tracking
 517 #
 518 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 519               [autodepend=yes])
 520 AC_SUBST(autodepend)
 521
 522
 523 #
 524 # Enable assert checks
 525 #
 526 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 527               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 528                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 529
 530
 531 #
 532 # Include directories
 533 #
 534 ac_save_IFS=$IFS
 535 IFS="${IFS}${PATH_SEPARATOR}"
 536 # SRCH_INC comes from the template file
 537 for dir in $with_includes $SRCH_INC; do
 538   if test -d "$dir"; then
 539     INCLUDES="$INCLUDES -I$dir"
 540   else
 541     AC_MSG_WARN([*** Include directory $dir does not exist.])
 542   fi
 543 done
 544 IFS=$ac_save_IFS
 545 AC_SUBST(INCLUDES)
 546
 547
 548 #
 549 # Library directories
 550 #
 551 ac_save_IFS=$IFS
 552 IFS="${IFS}${PATH_SEPARATOR}"
 553 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 554 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 555   if test -d "$dir"; then
 556     LIBDIRS="$LIBDIRS -L$dir"
 557   else
 558     AC_MSG_WARN([*** Library directory $dir does not exist.])
 559   fi
 560 done
 561 IFS=$ac_save_IFS
 562
 563 #
 564 # Enable thread-safe client libraries
 565 #
 566 AC_MSG_CHECKING([allow thread-safe client libraries])
 567 if test "$PORTNAME" != "win32"; then
 568 PGAC_ARG_BOOL(enable, thread-safety, no, [make client libraries thread-safe])
 569 else
 570 # Win32 should always use threads
 571 PGAC_ARG_BOOL(enable, thread-safety, yes, [make client libraries thread-safe])
 572 fi
 573
 574 PGAC_ARG_BOOL(enable, thread-safety-force, no, [force thread-safety despite thread test failure])
 575 if test "$enable_thread_safety" = yes -o \
 576         "$enable_thread_safety_force" = yes; then
 577   enable_thread_safety="yes"    # for 'force'
 578   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 579           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 580 fi
 581 AC_MSG_RESULT([$enable_thread_safety])
 582 AC_SUBST(enable_thread_safety)
 583
 584 #
 585 # Optionally build Tcl modules (PL/Tcl)
 586 #
 587 AC_MSG_CHECKING([whether to build with Tcl])
 588 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 589 AC_MSG_RESULT([$with_tcl])
 590 AC_SUBST([with_tcl])
 591
 592 # We see if the path to the Tcl/Tk configuration scripts is specified.
 593 # This will override the use of tclsh to find the paths to search.
 594
 595 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 596
 597 #
 598 # Optionally build Perl modules (PL/Perl)
 599 #
 600 AC_MSG_CHECKING([whether to build Perl modules])
 601 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 602 AC_MSG_RESULT([$with_perl])
 603 AC_SUBST(with_perl)
 604
 605 #
 606 # Optionally build Python modules (PL/Python)
 607 #
 608 AC_MSG_CHECKING([whether to build Python modules])
 609 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 610 AC_MSG_RESULT([$with_python])
 611 AC_SUBST(with_python)
 612
 613 #
 614 # GSSAPI
 615 #
 616 AC_MSG_CHECKING([whether to build with GSSAPI support])
 617 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 618 [
 619   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 620   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 621 ])
 622 AC_MSG_RESULT([$with_gssapi])
 623 AC_SUBST(with_gssapi)
 624
 625 #
 626 # Kerberos 5
 627 #
 628 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 629 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 630 [
 631   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 632   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 633 ])
 634 AC_MSG_RESULT([$with_krb5])
 635 AC_SUBST(with_krb5)
 636
 637
 638 AC_SUBST(krb_srvtab)
 639
 640
 641 #
 642 # Kerberos configuration parameters
 643 #
 644 PGAC_ARG_REQ(with, krb-srvnam,
 645              [NAME], [default service principal name in Kerberos [postgres]],
 646              [],
 647              [with_krb_srvnam="postgres"])
 648 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 649                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 650
 651
 652 #
 653 # PAM
 654 #
 655 AC_MSG_CHECKING([whether to build with PAM support])
 656 PGAC_ARG_BOOL(with, pam, no,
 657               [build with PAM support],
 658               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 659 AC_MSG_RESULT([$with_pam])
 660 AC_SUBST(with_pam)
 661
 662
 663 #
 664 # LDAP
 665 #
 666 AC_MSG_CHECKING([whether to build with LDAP support])
 667 PGAC_ARG_BOOL(with, ldap, no,
 668               [build with LDAP support],
 669               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 670 AC_MSG_RESULT([$with_ldap])
 671 AC_SUBST(with_ldap)
 672
 673
 674 #
 675 # Bonjour
 676 #
 677 AC_MSG_CHECKING([whether to build with Bonjour support])
 678 PGAC_ARG_BOOL(with, bonjour, no,
 679               [build with Bonjour support],
 680               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 681 AC_MSG_RESULT([$with_bonjour])
 682 AC_SUBST(with_bonjour)
 683
 684
 685 #
 686 # OpenSSL
 687 #
 688 AC_MSG_CHECKING([whether to build with OpenSSL support])
 689 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 690               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 691 AC_MSG_RESULT([$with_openssl])
 692 AC_SUBST(with_openssl)
 693
 694
 695 #
 696 # Readline
 697 #
 698 PGAC_ARG_BOOL(with, readline, yes,
 699               [do not use GNU Readline nor BSD Libedit for editing])
 700 # readline on MinGW has problems with backslashes in psql and other bugs.
 701 # This is particularly a problem with non-US code pages.
 702 # Therefore disable its use until we understand the cause. 2004-07-20
 703 if test "$PORTNAME" = "win32"; then
 704   if test "$with_readline" = yes; then
 705     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 706     with_readline=no
 707   fi
 708 fi
 709
 710
 711 #
 712 # Prefer libedit
 713 #
 714 PGAC_ARG_BOOL(with, libedit-preferred, no,
 715               [prefer BSD Libedit over GNU Readline])
 716
 717
 718 #
 719 # OSSP UUID library
 720 #
 721 PGAC_ARG_BOOL(with, ossp-uuid, no, [use OSSP UUID library when building contrib/uuid-ossp])
 722 AC_SUBST(with_ossp_uuid)
 723
 724
 725 #
 726 # XML
 727 #
 728 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 729               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 730
 731 if test "$with_libxml" = yes ; then
 732   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 733   if test -n "$XML2_CONFIG"; then
 734     for pgac_option in `$XML2_CONFIG --cflags`; do
 735       case $pgac_option in
 736         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 737       esac
 738     done
 739     for pgac_option in `$XML2_CONFIG --libs`; do
 740       case $pgac_option in
 741         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 742       esac
 743     done
 744   fi
 745 fi
 746
 747 AC_SUBST(with_libxml)
 748
 749 #
 750 # XSLT
 751 #
 752 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 753               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 754
 755
 756 AC_SUBST(with_libxslt)
 757
 758 #
 759 # tzdata
 760 #
 761 PGAC_ARG_REQ(with, system-tzdata,
 762              [DIR], [use system time zone data in DIR])
 763 AC_SUBST(with_system_tzdata)
 764
 765 #
 766 # Zlib
 767 #
 768 PGAC_ARG_BOOL(with, zlib, yes,
 769               [do not use Zlib])
 770 AC_SUBST(with_zlib)
 771
 772 #
 773 # Elf
 774 #
 775
 776 # Assume system is ELF if it predefines __ELF__ as 1,
 777 # otherwise believe host_os based default.
 778 case $host_os in
 779     freebsd1*|freebsd2*) elf=no;;
 780     freebsd3*|freebsd4*) elf=yes;;
 781 esac
 782
 783 AC_EGREP_CPP(yes,
 784 [#if __ELF__
 785   yes
 786 #endif
 787 ],
 788 [ELF_SYS=true],
 789 [if test "X$elf" = "Xyes" ; then
 790   ELF_SYS=true
 791 else
 792   ELF_SYS=
 793 fi])
 794 AC_SUBST(ELF_SYS)
 795
 796 #
 797 # Assignments
 798 #
 799
 800 CPPFLAGS="$CPPFLAGS $INCLUDES"
 801 LDFLAGS="$LDFLAGS $LIBDIRS"
 802
 803 AC_ARG_VAR(LDFLAGS_SL)
 804
 805 PGAC_PROG_LD
 806 AC_SUBST(LD)
 807 AC_SUBST(with_gnu_ld)
 808 case $host_os in sysv5*)
 809   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 810   [
 811     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 812     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 813     LDFLAGS=$pgac_save_LDFLAGS
 814   ])
 815   ld_R_works=$pgac_cv_prog_ld_R
 816   AC_SUBST(ld_R_works)
 817 esac
 818 AC_PROG_RANLIB
 819 PGAC_CHECK_STRIP
 820
 821 AC_PATH_PROG(TAR, tar)
 822 AC_PROG_LN_S
 823 AC_PROG_AWK
 824
 825 PGAC_PATH_BISON
 826 PGAC_PATH_FLEX
 827
 828 PGAC_PATH_PERL
 829 if test "$with_perl" = yes; then
 830   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 831   PGAC_CHECK_PERL_EMBED_LDFLAGS
 832 fi
 833
 834 if test "$with_python" = yes; then
 835   PGAC_PATH_PYTHON
 836   PGAC_CHECK_PYTHON_EMBED_SETUP
 837 fi
 838
 839 # Supply a numeric version string for use by 3rd party add-ons
 840 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 841 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 842 tr '.' '        ' |
 843 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
 844 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 845
 846 ##
 847 ## Libraries
 848 ##
 849 ## Most libraries are included only if they demonstrably provide a function
 850 ## we need, but libm is an exception: always include it, because there are
 851 ## too many compilers that play cute optimization games that will break
 852 ## probes for standard functions such as pow().
 853 ##
 854
 855 AC_CHECK_LIB(m, main)
 856 AC_SEARCH_LIBS(setproctitle, util)
 857 AC_SEARCH_LIBS(dlopen, dl)
 858 AC_SEARCH_LIBS(socket, [socket wsock32])
 859 AC_SEARCH_LIBS(shl_load, dld)
 860 # We only use libld in port/dynloader/aix.c
 861 case $host_os in
 862      aix*)
 863         AC_SEARCH_LIBS(ldopen, ld)
 864         ;;
 865 esac
 866 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 867 AC_SEARCH_LIBS(crypt, crypt)
 868 # Solaris:
 869 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 870 # Cygwin:
 871 AC_SEARCH_LIBS(shmget, cygipc)
 872
 873 if test "$with_readline" = yes; then
 874   PGAC_CHECK_READLINE
 875   if test x"$pgac_cv_check_readline" = x"no"; then
 876     AC_MSG_ERROR([readline library not found
 877 If you have readline already installed, see config.log for details on the
 878 failure.  It is possible the compiler isn't looking in the proper directory.
 879 Use --without-readline to disable readline support.])
 880   fi
 881 fi
 882
 883 if test "$with_zlib" = yes; then
 884   AC_CHECK_LIB(z, inflate, [],
 885                [AC_MSG_ERROR([zlib library not found
 886 If you have zlib already installed, see config.log for details on the
 887 failure.  It is possible the compiler isn't looking in the proper directory.
 888 Use --without-zlib to disable zlib support.])])
 889 fi
 890
 891 if test "$enable_spinlocks" = yes; then
 892   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 893 else
 894   AC_MSG_WARN([
 895 *** Not using spinlocks will cause poor performance.])
 896 fi
 897
 898 if test "$with_gssapi" = yes ; then
 899   if test "$PORTNAME" != "win32"; then
 900     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 901                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 902   else
 903     LIBS="$LIBS -lgssapi32"
 904   fi
 905 fi
 906
 907 if test "$with_krb5" = yes ; then
 908   if test "$PORTNAME" != "win32"; then
 909      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 910                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 911      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 912                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 913   else
 914      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 915                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 916   fi
 917 fi
 918
 919 if test "$with_openssl" = yes ; then
 920   dnl Order matters!
 921   if test "$PORTNAME" != "win32"; then
 922      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 923      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 924   else
 925      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 926      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 927   fi
 928 fi
 929
 930 if test "$with_pam" = yes ; then
 931   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 932 fi
 933
 934 if test "$with_libxml" = yes ; then
 935   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 936 fi
 937
 938 if test "$with_libxslt" = yes ; then
 939   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 940 fi
 941
 942 # for contrib/uuid-ossp
 943 if test "$with_ossp_uuid" = yes ; then
 944   AC_CHECK_LIB(ossp-uuid, uuid_export,
 945     [OSSP_UUID_LIBS="-lossp-uuid"],
 946     [AC_CHECK_LIB(uuid, uuid_export,
 947       [OSSP_UUID_LIBS="-luuid"],
 948       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 949 fi
 950 AC_SUBST(OSSP_UUID_LIBS)
 951
 952
 953 ##
 954 ## Header files
 955 ##
 956
 957 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 958 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 959
 960 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 961 # netinet/in.h is included first.
 962 AC_CHECK_HEADERS(netinet/in.h)
 963 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 964 [AC_INCLUDES_DEFAULT
 965 #ifdef HAVE_NETINET_IN_H
 966 #include <netinet/in.h>
 967 #endif
 968 ])
 969
 970 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 971   AC_CHECK_HEADERS(readline/readline.h, [],
 972         [AC_CHECK_HEADERS(readline.h, [],
 973                 [AC_MSG_ERROR([readline header not found
 974 If you have readline already installed, see config.log for details on the
 975 failure.  It is possible the compiler isn't looking in the proper directory.
 976 Use --without-readline to disable readline support.])])])
 977   AC_CHECK_HEADERS(readline/history.h, [],
 978         [AC_CHECK_HEADERS(history.h, [],
 979                 [AC_MSG_ERROR([history header not found
 980 If you have readline already installed, see config.log for details on the
 981 failure.  It is possible the compiler isn't looking in the proper directory.
 982 Use --without-readline to disable readline support.])])])
 983 fi
 984
 985 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 986 # Some installations of libedit usurp /usr/include/readline/, which seems
 987 # bad practice, since in combined installations readline will have its headers
 988 # there.  We might have to resort to AC_EGREP checks to make sure we found
 989 # the proper header...
 990   AC_CHECK_HEADERS(editline/readline.h, [],
 991         [AC_CHECK_HEADERS(readline.h, [],
 992                 [AC_CHECK_HEADERS(readline/readline.h, [],
 993                         [AC_MSG_ERROR([readline header not found
 994 If you have libedit already installed, see config.log for details on the
 995 failure.  It is possible the compiler isn't looking in the proper directory.
 996 Use --without-readline to disable libedit support.])])])])
 997 # Note: in a libedit installation, history.h is sometimes a dummy, and may
 998 # not be there at all.  Hence, don't complain if not found.  We must check
 999 # though, since in yet other versions it is an independent header.
1000   AC_CHECK_HEADERS(editline/history.h, [],
1001         [AC_CHECK_HEADERS(history.h, [],
1002                 [AC_CHECK_HEADERS(readline/history.h)])])
1003 fi
1004
1005 if test "$with_zlib" = yes; then
1006   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1007 If you have zlib already installed, see config.log for details on the
1008 failure.  It is possible the compiler isn't looking in the proper directory.
1009 Use --without-zlib to disable zlib support.])])
1010 fi
1011
1012 if test "$with_gssapi" = yes ; then
1013   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1014         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1015 fi
1016
1017 if test "$with_krb5" = yes ; then
1018   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1019 fi
1020
1021 if test "$with_openssl" = yes ; then
1022   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1023   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1024   AC_CHECK_FUNCS([ERR_set_mark])
1025 fi
1026
1027 if test "$with_pam" = yes ; then
1028   AC_CHECK_HEADERS(security/pam_appl.h, [],
1029                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1030                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1031 fi
1032
1033 if test "$with_libxml" = yes ; then
1034   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1035 fi
1036
1037 if test "$with_libxslt" = yes ; then
1038   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1039 fi
1040
1041 if test "$with_ldap" = yes ; then
1042   if test "$PORTNAME" != "win32"; then
1043      AC_CHECK_HEADERS(ldap.h, [],
1044                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1045   else
1046      AC_CHECK_HEADERS(winldap.h, [],
1047                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1048                       [AC_INCLUDES_DEFAULT
1049 #include <windows.h>
1050                       ])
1051   fi
1052 fi
1053
1054 if test "$with_bonjour" = yes ; then
1055   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
1056 fi
1057
1058 # for contrib/uuid-ossp
1059 if test "$with_ossp_uuid" = yes ; then
1060   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1061     AC_CHECK_HEADERS(uuid.h, [],
1062       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1063 fi
1064
1065
1066 ##
1067 ## Types, structures, compiler characteristics
1068 ##
1069
1070 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1071 AC_C_BIGENDIAN
1072 AC_C_CONST
1073 AC_C_INLINE
1074 AC_C_STRINGIZE
1075 PGAC_C_SIGNED
1076 AC_C_VOLATILE
1077 PGAC_C_FUNCNAME_SUPPORT
1078 PGAC_STRUCT_TIMEZONE
1079 PGAC_UNION_SEMUN
1080 PGAC_STRUCT_SOCKADDR_UN
1081 PGAC_STRUCT_SOCKADDR_STORAGE
1082 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1083 PGAC_STRUCT_ADDRINFO
1084
1085 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
1086 [#include <sys/param.h>
1087 #include <sys/types.h>
1088 #include <sys/socket.h>
1089 #include <sys/ucred.h>])
1090
1091 AC_CHECK_TYPES([struct option], [], [],
1092 [#ifdef HAVE_GETOPT_H
1093 #include <getopt.h>
1094 #endif])
1095
1096 if test "$with_zlib" = yes; then
1097   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1098   # did not).  While we could work around the lack of z_streamp, it
1099   # seems unwise to encourage people to use such old zlib versions...
1100   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1101 Use --without-zlib to disable zlib support.])],
1102                 [#include <zlib.h>])
1103 fi
1104
1105 if test "$with_krb5" = yes; then
1106 # Check for differences between MIT and Heimdal (KTH) releases
1107   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1108                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1109                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1110                                      [#include <krb5.h>])],
1111                    [#include <krb5.h>])
1112   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1113                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1114                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1115                                      [#include <krb5.h>])],
1116                    [#include <krb5.h>])
1117
1118 # Win32 requires headers to be loaded for __stdcall, so can't use
1119 # AC_CHECK_FUNCS here.
1120   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1121   AC_TRY_LINK([#include <krb5.h>],
1122               [krb5_free_unparsed_name(NULL,NULL);],
1123               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1124 AC_MSG_RESULT(yes)],
1125               [AC_MSG_RESULT(no)])
1126 fi
1127
1128
1129 ##
1130 ## Functions, global variables
1131 ##
1132
1133 PGAC_VAR_INT_TIMEZONE
1134 AC_FUNC_ACCEPT_ARGTYPES
1135 PGAC_FUNC_GETTIMEOFDAY_1ARG
1136
1137 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
1138
1139 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1140 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1141 AC_CHECK_DECLS([strlcat, strlcpy])
1142 # This is probably only present on Darwin, but may as well check always
1143 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1144
1145 HAVE_IPV6=no
1146 AC_CHECK_TYPE([struct sockaddr_in6],
1147         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1148          HAVE_IPV6=yes],
1149         [],
1150 [$ac_includes_default
1151 #include <netinet/in.h>])
1152 AC_SUBST(HAVE_IPV6)
1153
1154 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1155 [AC_TRY_LINK(
1156 [#include <machine/vmparam.h>
1157 #include <sys/exec.h>
1158 ],
1159 [PS_STRINGS->ps_nargvstr = 1;
1160 PS_STRINGS->ps_argvstr = "foo";],
1161 [pgac_cv_var_PS_STRINGS=yes],
1162 [pgac_cv_var_PS_STRINGS=no])])
1163 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1164   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1165 fi
1166
1167
1168 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1169 # is missing.  Yes, there are machines that have only one.  We may
1170 # also decide to use snprintf.c if snprintf() is present but does not
1171 # have all the features we need --- see below.
1172
1173 if test "$PORTNAME" = "win32"; then
1174   # Win32 gets snprintf.c built unconditionally.
1175   #
1176   # To properly translate all NLS languages strings, we must support the
1177   # *printf() %$ format, which allows *printf() arguments to be selected
1178   # by position in the translated string.
1179   #
1180   # libintl versions < 0.13 use the native *printf() functions, and Win32
1181   # *printf() doesn't understand %$, so we must use our /port versions,
1182   # which do understand %$. libintl versions >= 0.13 include their own
1183   # *printf versions on Win32.  The libintl 0.13 release note text is:
1184   #
1185   #   C format strings with positions, as they arise when a translator
1186   #   needs to reorder a sentence, are now supported on all platforms.
1187   #   On those few platforms (NetBSD and Woe32) for which the native
1188   #   printf()/fprintf()/... functions don't support such format
1189   #   strings, replacements are provided through <libintl.h>.
1190   #
1191   # We could use libintl >= 0.13's *printf() if we were sure that we had
1192   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1193   # to guarantee that, it is best to just use our own, so we are sure to
1194   # get %$ support. In include/port.h we disable the *printf() macros
1195   # that might have been defined by libintl.
1196   #
1197   # We do this unconditionally whether NLS is used or not so we are sure
1198   # that all Win32 libraries and binaries behave the same.
1199   pgac_need_repl_snprintf=yes
1200 else
1201   pgac_need_repl_snprintf=no
1202   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1203   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1204 fi
1205
1206
1207 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1208 # include/c.h will provide declarations.  Note this is a separate test
1209 # from whether the functions exist in the C library --- there are
1210 # systems that have the functions but don't bother to declare them :-(
1211
1212 AC_CHECK_DECLS([snprintf, vsnprintf])
1213
1214
1215 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1216 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1217 [AC_TRY_LINK([
1218 #include <math.h>
1219 double glob_double;
1220 ],
1221 [return isinf(glob_double) ? 0 : 1;],
1222 [ac_cv_func_isinf=yes],
1223 [ac_cv_func_isinf=no])])
1224
1225 if test $ac_cv_func_isinf = yes ; then
1226   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1227 else
1228   AC_LIBOBJ(isinf)
1229   # Look for a way to implement a substitute for isinf()
1230   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1231 fi
1232
1233 # Some versions of libedit contain strlcpy(); so disregard that library while
1234 # checking for these standard libc functions.
1235 pgac_save_LIBS="$LIBS"
1236 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1237
1238 AC_REPLACE_FUNCS([crypt getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1239
1240 LIBS="$pgac_save_LIBS"
1241
1242 # System's version of getaddrinfo(), if any, may be used only if we found
1243 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1244 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1245 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1246 # because we want to use our own getaddrinfo.c on Windows anyway.)
1247 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1248   AC_REPLACE_FUNCS([getaddrinfo])
1249 else
1250   AC_LIBOBJ(getaddrinfo)
1251 fi
1252
1253 # Similarly, use system's getopt_long() only if system provides struct option.
1254 # Solaris' getopt() doesn't do what we want for long options, so always use
1255 # our versions on that platform.
1256 if test "$PORTNAME" = "solaris"; then
1257   AC_LIBOBJ(getopt)
1258   AC_LIBOBJ(getopt_long)
1259 elif test x"$ac_cv_type_struct_option" = xyes ; then
1260   AC_REPLACE_FUNCS([getopt_long])
1261 else
1262   AC_LIBOBJ(getopt_long)
1263 fi
1264
1265 # Win32 support
1266 if test "$PORTNAME" = "win32"; then
1267 AC_REPLACE_FUNCS(gettimeofday)
1268 AC_LIBOBJ(kill)
1269 AC_LIBOBJ(open)
1270 AC_LIBOBJ(rand)
1271 AC_LIBOBJ(win32error)
1272 AC_DEFINE([HAVE_SYMLINK], 1,
1273           [Define to 1 if you have the `symlink' function.])
1274 fi
1275
1276 if test "$with_readline" = yes; then
1277   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1278   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1279   AC_CHECK_FUNCS([replace_history_entry])
1280 fi
1281
1282
1283 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1284 dnl (especially on GNU libc)
1285 dnl See also comments in c.h.
1286 AC_MSG_CHECKING(for sigsetjmp)
1287 AC_TRY_LINK([#include <setjmp.h>],
1288             [sigjmp_buf x; sigsetjmp(x, 1);],
1289             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1290 AC_MSG_RESULT(yes)],
1291             [AC_MSG_RESULT(no)])
1292
1293 AC_DECL_SYS_SIGLIST
1294
1295 AC_CHECK_FUNC(syslog,
1296               [AC_CHECK_HEADER(syslog.h,
1297                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1298
1299 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1300 [AC_TRY_LINK([#include <unistd.h>],
1301   [extern int optreset; optreset = 1;],
1302   [pgac_cv_var_int_optreset=yes],
1303   [pgac_cv_var_int_optreset=no])])
1304 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1305   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1306 fi
1307
1308 AC_CHECK_FUNCS([strtoll strtoq], [break])
1309 AC_CHECK_FUNCS([strtoull strtouq], [break])
1310
1311 # Check for one of atexit() or on_exit()
1312 AC_CHECK_FUNCS(atexit, [],
1313                [AC_CHECK_FUNCS(on_exit, [],
1314                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1315
1316 AC_REPLACE_FUNCS(fseeko)
1317 case $host_os in
1318         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1319         bsdi*|netbsd*)
1320                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1321                 ac_cv_func_fseeko=yes;;
1322         *)
1323                 AC_FUNC_FSEEKO;;
1324 esac
1325
1326
1327 #
1328 # Pthreads
1329 #
1330 # For each platform, we need to know about any special compile and link
1331 # libraries, and whether the normal C function names are thread-safe.
1332 # See the comment at the top of src/port/thread.c for more information.
1333 # WIN32 doesn't need the pthread tests;  it always uses threads
1334 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1335 ACX_PTHREAD     # set thread flags
1336
1337 # Some platforms use these, so just define them.  They can't hurt if they
1338 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1339 # enables 5-arg getpwuid_r, among other things.
1340 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1341
1342
1343 # At this point, we don't want to muck with the compiler name for threading.
1344 # Let's see who fails, perhaps AIX.  2004-04-23
1345 if test "$PTHREAD_CC" != "$CC"; then
1346 AC_MSG_ERROR([
1347 PostgreSQL does not support platforms that require a special compiler
1348 for thread safety.])
1349 fi
1350
1351 if test "$THREAD_SUPPORT" = no; then
1352 AC_MSG_ERROR([cannot enable threads on this platform
1353 This platform is known to not support thread-safe programs.  For details,
1354 compile and run src/bin/pg_thread_test.])
1355 fi
1356
1357 # Check for *_r functions
1358 _CFLAGS="$CFLAGS"
1359 _LIBS="$LIBS"
1360 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1361 LIBS="$LIBS $PTHREAD_LIBS"
1362
1363 if test "$PORTNAME" != "win32"; then
1364 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1365 fi
1366
1367 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1368
1369 # Do test here with the proper thread flags
1370 PGAC_FUNC_GETPWUID_R_5ARG
1371 PGAC_FUNC_STRERROR_R_INT
1372
1373 CFLAGS="$_CFLAGS"
1374 LIBS="$_LIBS"
1375
1376 else
1377 # do not use values from template file
1378 PTHREAD_CFLAGS=
1379 PTHREAD_LIBS=
1380 fi
1381
1382 AC_SUBST(PTHREAD_CFLAGS)
1383 AC_SUBST(PTHREAD_LIBS)
1384
1385
1386 # We can test for libldap_r only after we know PTHREAD_LIBS
1387 if test "$with_ldap" = yes ; then
1388   _LIBS="$LIBS"
1389   if test "$PORTNAME" != "win32"; then
1390     AC_CHECK_LIB(ldap, ldap_bind, [],
1391                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1392                  [$EXTRA_LDAP_LIBS])
1393     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1394     if test "$enable_thread_safety" = yes; then
1395       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1396       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1397                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1398                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1399       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1400     else
1401       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1402     fi
1403   else
1404     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1405     LDAP_LIBS_FE="-lwldap32"
1406     LDAP_LIBS_BE="-lwldap32"
1407   fi
1408   LIBS="$_LIBS"
1409 fi
1410 AC_SUBST(LDAP_LIBS_FE)
1411 AC_SUBST(LDAP_LIBS_BE)
1412
1413
1414 # This test makes sure that run tests work at all.  Sometimes a shared
1415 # library is found by the linker, but the runtime linker can't find it.
1416 # This check should come after all modifications of compiler or linker
1417 # variables, and before any other run tests.
1418 AC_MSG_CHECKING([test program])
1419 AC_TRY_RUN([int main() { return 0; }],
1420 [AC_MSG_RESULT(ok)],
1421 [AC_MSG_RESULT(failed)
1422 AC_MSG_ERROR([[
1423 Could not execute a simple test program.  This may be a problem
1424 related to locating shared libraries.  Check the file 'config.log'
1425 for the exact reason.]])],
1426 [AC_MSG_RESULT([cross-compiling])])
1427
1428 # --------------------
1429 # Run tests below here
1430 # --------------------
1431
1432 # Force use of our snprintf if system's doesn't do arg control
1433 # See comment above at snprintf test for details.
1434 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1435   PGAC_FUNC_PRINTF_ARG_CONTROL
1436   if test $pgac_cv_printf_arg_control != yes ; then
1437     pgac_need_repl_snprintf=yes
1438   fi
1439 fi
1440
1441
1442 dnl Check to see if we have a working 64-bit integer type.
1443 dnl This breaks down into two steps:
1444 dnl (1) figure out if the compiler has a 64-bit int type with working
1445 dnl arithmetic, and if so
1446 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1447 dnl snprintf is the only library routine we really need for int8 support.)
1448 dnl It's entirely possible to have a compiler that handles a 64-bit type
1449 dnl when the C library doesn't; this is fairly likely when using gcc on
1450 dnl an older platform, for example.
1451 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1452 dnl we force our own version of snprintf() to be used instead.
1453 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1454
1455 PGAC_TYPE_64BIT_INT([long int])
1456
1457 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1458   PGAC_TYPE_64BIT_INT([long long int])
1459 fi
1460
1461
1462 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1463
1464 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1465   AC_TRY_COMPILE([
1466 #define INT64CONST(x)  x##LL
1467 long long int foo = INT64CONST(0x1234567890123456);
1468 ],
1469         [],
1470         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1471         [])
1472 fi
1473
1474
1475 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1476 # we found we need to use "long long int", better check.  We cope with
1477 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1478 # work, fall back to our own snprintf emulation (which we know uses %lld).
1479
1480 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1481   if test $pgac_need_repl_snprintf = no; then
1482     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1483     if test "$LONG_LONG_INT_FORMAT" = ""; then
1484       # Force usage of our own snprintf, since system snprintf is broken
1485       pgac_need_repl_snprintf=yes
1486       LONG_LONG_INT_FORMAT='%lld'
1487     fi
1488   else
1489     # Here if we previously decided we needed to use our own snprintf
1490     LONG_LONG_INT_FORMAT='%lld'
1491   fi
1492   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1493   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1494   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1495 else
1496   # Here if we are not using 'long long int' at all
1497   INT64_FORMAT='"%ld"'
1498   UINT64_FORMAT='"%lu"'
1499 fi
1500
1501 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1502                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1503
1504 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1505                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1506
1507 # Now we have checked all the reasons to replace snprintf
1508 if test $pgac_need_repl_snprintf = yes; then
1509   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1510   AC_LIBOBJ(snprintf)
1511 fi
1512
1513 # Need a #define for the size of Datum (unsigned long)
1514 AC_CHECK_SIZEOF([unsigned long])
1515
1516 # And one for the size of size_t (enables tweaks for > 32bit address space)
1517 AC_CHECK_SIZEOF([size_t])
1518
1519 # Decide whether float4 is passed by value: user-selectable, enabled by default
1520 AC_MSG_CHECKING([whether to build with float4 passed by value])
1521 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1522               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1523                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1524                float4passbyval=true],
1525               [float4passbyval=false])
1526 AC_MSG_RESULT([$enable_float4_byval])
1527 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1528
1529 # Decide whether float8 is passed by value.
1530 # Note: this setting also controls int8 and related types such as timestamp.
1531 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1532 # If not, trying to select it is an error.
1533 AC_MSG_CHECKING([whether to build with float8 passed by value])
1534 if test $ac_cv_sizeof_unsigned_long -ge 8 ; then
1535   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1536 else
1537   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1538   if test "$enable_float8_byval" = yes ; then
1539     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1540   fi
1541 fi
1542 if test "$enable_float8_byval" = yes ; then
1543   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1544             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1545   float8passbyval=true
1546 else
1547   float8passbyval=false
1548 fi
1549 AC_MSG_RESULT([$enable_float8_byval])
1550 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1551
1552 # Determine memory alignment requirements for the basic C data types.
1553
1554 AC_CHECK_ALIGNOF(short)
1555 AC_CHECK_ALIGNOF(int)
1556 AC_CHECK_ALIGNOF(long)
1557 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1558   AC_CHECK_ALIGNOF(long long int)
1559 fi
1560 AC_CHECK_ALIGNOF(double)
1561
1562 # Compute maximum alignment of any basic type.
1563 # We assume long's alignment is at least as strong as char, short, or int;
1564 # but we must check long long (if it exists) and double.
1565
1566 MAX_ALIGNOF=$ac_cv_alignof_long
1567 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1568   MAX_ALIGNOF=$ac_cv_alignof_double
1569 fi
1570 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1571   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1572 fi
1573 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1574
1575
1576 # Some platforms predefine the types int8, int16, etc.  Only check
1577 # a (hopefully) representative subset.
1578 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1579 [#include <stdio.h>
1580 #ifdef HAVE_SUPPORTDEFS_H
1581 #include <SupportDefs.h>
1582 #endif])
1583
1584 # We also check for sig_atomic_t, which *should* be defined per ANSI
1585 # C, but is missing on some old platforms.
1586 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1587
1588
1589 # If the user did not disable integer datetimes, check that
1590 # there is a working 64-bit integral type to use.
1591 if test x"$USE_INTEGER_DATETIMES" = x"yes" &&
1592    test x"$HAVE_LONG_INT_64" = x"no" &&
1593    test x"$HAVE_LONG_LONG_INT_64" = x"no" &&
1594    test x"$HAVE_INT64" = x"no" ; then
1595   AC_MSG_ERROR([
1596 Integer-based datetime support requires a 64-bit integer type,
1597 but no such type could be found. The --disable-integer-datetimes
1598 configure option can be used to disable integer-based storage
1599 of datetime values.])
1600 fi
1601
1602
1603 if test "$PORTNAME" != "win32"
1604 then
1605 PGAC_FUNC_POSIX_SIGNALS
1606 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1607   AC_MSG_ERROR([
1608 Thread-safety requires POSIX signals, which are not supported by this
1609 operating system.])
1610 fi
1611 fi
1612
1613 if test $ac_cv_func_fseeko = yes; then
1614 AC_SYS_LARGEFILE
1615 fi
1616
1617 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1618 AC_CHECK_SIZEOF([off_t])
1619
1620 # If we don't have largefile support, can't handle segsize >= 2GB.
1621 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1622    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1623 fi
1624
1625 # SunOS doesn't handle negative byte comparisons properly with +/- return
1626 AC_FUNC_MEMCMP
1627
1628
1629 # Select semaphore implementation type.
1630 if test "$PORTNAME" != "win32"; then
1631   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1632     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1633     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1634   else
1635     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1636       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1637       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1638     else
1639       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1640       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1641     fi
1642   fi
1643 else
1644   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1645   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1646 fi
1647
1648
1649 # Select shared-memory implementation type.
1650 if test "$PORTNAME" != "win32"; then
1651   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1652   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1653 else
1654   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1655   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1656 fi
1657
1658 # If not set in template file, set bytes to use libc memset()
1659 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1660   MEMSET_LOOP_LIMIT=1024
1661 fi
1662 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1663
1664
1665 if test "$enable_nls" = yes ; then
1666   PGAC_CHECK_GETTEXT
1667 fi
1668
1669 # Check for Tcl configuration script tclConfig.sh
1670 if test "$with_tcl" = yes; then
1671     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1672     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1673                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1674     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1675     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1676     ac_save_CPPFLAGS=$CPPFLAGS
1677     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1678     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1679     CPPFLAGS=$ac_save_CPPFLAGS
1680 fi
1681
1682 #
1683 # Check for DocBook and tools
1684 #
1685 PGAC_PROG_NSGMLS
1686 PGAC_PROG_JADE
1687 PGAC_CHECK_DOCBOOK(4.2)
1688 PGAC_PATH_DOCBOOK_STYLESHEETS
1689 PGAC_PATH_COLLATEINDEX
1690 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1691
1692 # Thread testing
1693
1694 # We have to run the thread test near the end so we have all our symbols
1695 # defined.  Cross compiling throws a warning.
1696 #
1697 if test "$enable_thread_safety_force" = yes; then
1698 if test "$PORTNAME" != "win32"
1699 then
1700   AC_MSG_WARN([
1701 *** Skipping thread test program.  --enable-thread-safety-force was used.
1702 *** Run the program in src/test/thread on the your machine and add proper
1703 *** locking function calls to your applications to guarantee thread safety.
1704 ])
1705 else
1706 AC_MSG_WARN([*** skipping thread test on Win32])
1707 fi
1708 elif test "$enable_thread_safety" = yes; then
1709 if test "$PORTNAME" != "win32"
1710 then
1711 AC_MSG_CHECKING([thread safety of required library functions])
1712
1713 _CFLAGS="$CFLAGS"
1714 _LIBS="$LIBS"
1715 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1716 LIBS="$LIBS $PTHREAD_LIBS"
1717 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1718   [AC_MSG_RESULT(yes)],
1719   [AC_MSG_RESULT(no)
1720   AC_MSG_ERROR([thread test program failed
1721 This platform is not thread-safe.  Check the file 'config.log' for the
1722 exact reason.
1723
1724 You can use the configure option --enable-thread-safety-force to force
1725 threads to be enabled.  But you must then run the program in
1726 src/test/thread and add locking function calls to your applications to
1727 guarantee thread safety.])],
1728   [AC_MSG_RESULT(maybe)
1729   AC_MSG_WARN([
1730 *** Skipping thread test program because of cross-compile build.
1731 *** Run the program in src/test/thread on the target machine.
1732 ])])
1733 CFLAGS="$_CFLAGS"
1734 LIBS="$_LIBS"
1735 else
1736 AC_MSG_WARN([*** skipping thread test on Win32])
1737 fi
1738 fi
1739
1740 # If compiler will take -Wl,--as-needed then add that to LDFLAGS.
1741 # This is much easier than trying to filter LIBS to the minimum for each
1742 # executable.  (Note that shared library links won't use this switch, though.)
1743 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1744 # libreadline; therefore we postpone testing it until we know what library
1745 # dependencies readline has.  The test code will try to link with $LIBS.
1746 if test "$with_readline" = yes; then
1747   link_test_func=readline
1748 else
1749   link_test_func=exit
1750 fi
1751 if test "$PORTNAME" != "darwin"; then
1752   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1753 else
1754   # On Darwin it's spelled -Wl,-dead_strip_dylibs, but don't try that elsewhere
1755   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1756 fi
1757
1758
1759 # Begin output steps
1760
1761 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1762 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1763 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1764
1765 # prepare build tree if outside source tree
1766 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1767 # Note 2: /bin/pwd might be better than shell's built-in at getting
1768 #         a symlink-free name.
1769 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1770   vpath_build=no
1771 else
1772   vpath_build=yes
1773   if test "$no_create" != yes; then
1774     _AS_ECHO_N([preparing build tree... ])
1775     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1776     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1777       || AC_MSG_ERROR(failed)
1778     AC_MSG_RESULT(done)
1779   fi
1780 fi
1781 AC_SUBST(vpath_build)
1782
1783
1784 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1785
1786 AC_CONFIG_LINKS([
1787   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1788   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1789   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1790   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1791   src/include/pg_config_os.h:src/include/port/${template}.h
1792   src/Makefile.port:src/makefiles/Makefile.${template}
1793 ])
1794
1795 if test "$PORTNAME" = "win32"; then
1796 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1797 # Links sometimes fail undetected on Mingw -
1798 # so here we detect it and warn the user
1799 for FILE in $CONFIG_LINKS
1800  do
1801         # test -e works for symlinks in the MinGW console
1802         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1803  done
1804 ])
1805 fi
1806
1807 AC_CONFIG_HEADERS([src/include/pg_config.h],
1808 [
1809 # Update timestamp for pg_config.h (see Makefile.global)
1810 echo >src/include/stamp-h
1811 ])
1812
1813 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1814
1815 AC_OUTPUT
1816
1817 # Warn about unknown options
1818 PGAC_ARG_CHECK