etc/cshrc

   1 #----------------------------------*-sh-*--------------------------------------
   2 # =========                 |
   3 # \\      /  F ield         | OpenFOAM: The Open Source CFD Toolbox
   4 #  \\    /   O peration     |
   5 #   \\  /    A nd           | Copyright (C) 2004-2011 OpenCFD Ltd.
   6 #    \\/     M anipulation  |
   7 #------------------------------------------------------------------------------
   8 # License
   9 #     This file is part of OpenFOAM.
  10 #
  11 #     OpenFOAM is free software: you can redistribute it and/or modify it
  12 #     under the terms of the GNU General Public License as published by
  13 #     the Free Software Foundation, either version 3 of the License, or
  14 #     (at your option) any later version.
  15 #
  16 #     OpenFOAM is distributed in the hope that it will be useful, but WITHOUT
  17 #     ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 #     FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  19 #     for more details.
  20 #
  21 #     You should have received a copy of the GNU General Public License
  22 #     along with OpenFOAM.  If not, see <http://www.gnu.org/licenses/>.
  23 #
  24 # File
  25 #     etc/cshrc
  26 #
  27 # Description
  28 #     Startup file for OpenFOAM
  29 #     Sourced from ~/.login or ~/.cshrc
  30 #
  31 #------------------------------------------------------------------------------
  32
  33 setenv WM_PROJECT OpenFOAM
  34 setenv WM_PROJECT_VERSION 2.0.x
  35
  36 ################################################################################
  37 # USER EDITABLE PART: Changes made here may be lost with the next upgrade
  38 #
  39 # either setenv FOAM_INST_DIR before sourcing this file or set
  40 # 'foamInstall' below to where OpenFOAM is installed
  41 #
  42 # Location of the OpenFOAM installation
  43 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  44 set foamInstall = $HOME/$WM_PROJECT
  45 # set foamInstall = ~$WM_PROJECT
  46 # set foamInstall = /opt/$WM_PROJECT
  47 # set foamInstall = /usr/local/$WM_PROJECT
  48 #
  49 # END OF (NORMAL) USER EDITABLE PART
  50 ################################################################################
  51
  52 #
  53 # These are the defaults for this version which should generally be
  54 # overridden from the prefs.csh file or from command-line specification
  55 #
  56 #- note the location for later use (eg, in job scripts)
  57 if ( ! $?FOAM_INST_DIR ) setenv FOAM_INST_DIR $foamInstall
  58
  59 #- Compiler location:
  60 #    foamCompiler= system | ThirdParty (OpenFOAM)
  61 set foamCompiler=system
  62
  63 #- Compiler:
  64 #    WM_COMPILER = Gcc | Gcc43 | Gcc44 | Gcc45 | Gcc46 | Clang | Icc (Intel icc)
  65 setenv WM_COMPILER Gcc
  66 setenv WM_COMPILER_ARCH # defined but empty
  67 unsetenv WM_COMPILER_LIB_ARCH
  68
  69 #- Architecture:
  70 #    WM_ARCH_OPTION = 32 | 64
  71 setenv WM_ARCH_OPTION 64
  72
  73 #- Precision:
  74 #    WM_PRECISION_OPTION = DP | SP
  75 setenv WM_PRECISION_OPTION DP
  76
  77 #- Optimised, debug, profiling:
  78 #    WM_COMPILE_OPTION = Opt | Debug | Prof
  79 setenv WM_COMPILE_OPTION Opt
  80
  81 #- MPI implementation:
  82 #    WM_MPLIB = SYSTEMOPENMPI | OPENMPI | MPICH | MPICH-GM | HPMPI
  83 #               | GAMMA | MPI | QSMPI
  84 setenv WM_MPLIB OPENMPI
  85
  86 #- Operating System:
  87 #    WM_OSTYPE = POSIX | ???
  88 setenv WM_OSTYPE POSIX
  89
  90 #- Floating-point signal handling:
  91 #    set or unset
  92 setenv FOAM_SIGFPE
  93
  94 #- memory initialisation:
  95 #    set or unset
  96 #setenv FOAM_SETNAN
  97
  98
  99 ################################################################################
 100
 101 # The old dirs to be cleaned from the various environment variables
 102 # - remove anything under top-level directory.
 103 # NB: the WM_PROJECT_INST_DIR might not be identical between versions
 104 set foamOldDirs="$FOAM_INST_DIR $HOME/$WM_PROJECT/$LOGNAME"
 105 if ( $?WM_PROJECT_INST_DIR ) then
 106     if ( "$WM_PROJECT_INST_DIR" != "$FOAM_INST_DIR" ) then
 107         set foamOldDirs="$WM_PROJECT_INST_DIR $foamOldDirs"
 108     endif
 109 endif
 110
 111
 112 # Location of installation
 113 # ~~~~~~~~~~~~~~~~~~~~~~~~
 114 setenv WM_PROJECT_INST_DIR $FOAM_INST_DIR
 115 setenv WM_PROJECT_DIR $WM_PROJECT_INST_DIR/$WM_PROJECT-$WM_PROJECT_VERSION
 116
 117 # Location of third-party software
 118 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 119 setenv WM_THIRD_PARTY_DIR $WM_PROJECT_INST_DIR/ThirdParty-$WM_PROJECT_VERSION
 120
 121 # Location of site-specific templates etc
 122 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 123 # unset is equivalent to $WM_PROJECT_INST_DIR/site
 124 if ( $?WM_PROJECT_SITE ) then
 125     set foamOldDirs="$WM_PROJECT_SITE $foamOldDirs"
 126     if ( ! -d "$WM_PROJECT_SITE" ) unsetenv WM_PROJECT_SITE
 127 else
 128     unsetenv WM_PROJECT_SITE
 129 endif
 130
 131 # Location of user files
 132 # ~~~~~~~~~~~~~~~~~~~~~~
 133 setenv WM_PROJECT_USER_DIR $HOME/$WM_PROJECT/$LOGNAME-$WM_PROJECT_VERSION
 134
 135
 136 # Source files, possibly with some verbosity
 137 alias _foamSource 'if ($?FOAM_VERBOSE && $?prompt) echo "Sourcing: \!*"; if (\!* != "") source \!*'
 138
 139 # Add in preset user or site preferences:
 140 _foamSource `$WM_PROJECT_DIR/bin/foamEtcFile prefs.csh`
 141
 142 # Evaluate command-line parameters and record settings for later
 143 # these can be used to set/unset values, or specify alternative pref files
 144 setenv FOAM_SETTINGS "${*}"
 145 while ( $#argv > 0 )
 146     switch ($argv[1])
 147     case -*:
 148         # stray option (not meant for us here) -> get out
 149         break
 150         breaksw
 151     case *=:
 152         # name=       -> unsetenv name
 153         if ($?FOAM_VERBOSE && $?prompt) echo "unsetenv $argv[1]:s/=//"
 154         eval "unsetenv $argv[1]:s/=//"
 155         breaksw
 156     case *=*:
 157         # name=value  -> setenv name value
 158         if ($?FOAM_VERBOSE && $?prompt) echo "setenv $argv[1]:s/=/ /"
 159         eval "setenv $argv[1]:s/=/ /"
 160         breaksw
 161     default:
 162         # filename: source it
 163         if ( -f "$1" ) then
 164             _foamSource "$1"
 165         else
 166             _foamSource `$WM_PROJECT_DIR/bin/foamEtcFile -silent "$1"`
 167         endif
 168         breaksw
 169     endsw
 170     shift
 171 end
 172
 173
 174 # Clean standard environment variables (PATH, LD_LIBRARY_PATH, MANPATH)
 175 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 176 set foamClean=$WM_PROJECT_DIR/bin/foamCleanPath
 177
 178 #- prevent local variables from shadowing setenv variables
 179 unset PATH MANPATH LD_LIBRARY_PATH LD_PRELOAD
 180
 181 if (! $?LD_LIBRARY_PATH ) setenv LD_LIBRARY_PATH ''
 182 if (! $?MANPATH) setenv MANPATH ''
 183
 184 #- Clean PATH (path)
 185 set cleaned=`$foamClean "$PATH" "$foamOldDirs"`
 186 if ( $status == 0 ) setenv PATH $cleaned
 187
 188 #- Clean LD_LIBRARY_PATH
 189 set cleaned=`$foamClean "$LD_LIBRARY_PATH" "$foamOldDirs"`
 190 if ( $status == 0 ) setenv LD_LIBRARY_PATH $cleaned
 191
 192 #- Clean MANPATH
 193 set cleaned=`$foamClean "$MANPATH" "$foamOldDirs"`
 194 if ( $status == 0 ) setenv MANPATH $cleaned
 195
 196
 197 # Source project setup files
 198 # ~~~~~~~~~~~~~~~~~~~~~~~~~~
 199 _foamSource $WM_PROJECT_DIR/etc/config/settings.csh
 200 _foamSource $WM_PROJECT_DIR/etc/config/aliases.csh
 201
 202 # Source user setup files for optional packages
 203 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 204 _foamSource `$WM_PROJECT_DIR/bin/foamEtcFile config/paraview.csh`
 205 _foamSource `$WM_PROJECT_DIR/bin/foamEtcFile config/ensight.csh`
 206
 207
 208 # Clean environment paths again. Only remove duplicates
 209 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 210 #- Clean PATH (path)
 211 set cleaned=`$foamClean "$PATH"`
 212 if ( $status == 0 ) setenv PATH $cleaned
 213
 214 #- Clean LD_LIBRARY_PATH
 215 set cleaned=`$foamClean "$LD_LIBRARY_PATH"`
 216 if ( $status == 0 ) setenv LD_LIBRARY_PATH $cleaned
 217
 218 #- Clean MANPATH (trailing ':' to find system pages)
 219 set cleaned=`$foamClean "$MANPATH"`:
 220 if ( $status == 0 ) setenv MANPATH "$cleaned"
 221
 222 #- Clean LD_PRELOAD
 223 if ( $?LD_PRELOAD ) then
 224     set cleaned=`$foamClean "$LD_PRELOAD"`
 225     if ( $status == 0 ) setenv LD_PRELOAD $cleaned
 226 endif
 227
 228 # cleanup environment:
 229 # ~~~~~~~~~~~~~~~~~~~~
 230 unset cleaned foamClean foamInstall foamOldDirs
 231 unalias _foamSource
 232
 233 # ----------------------------------------------------------------- end-of-file