etc/settings.csh

   1 #----------------------------------*-sh-*--------------------------------------
   2 # =========                 |
   3 # \\      /  F ield         | OpenFOAM: The Open Source CFD Toolbox
   4 #  \\    /   O peration     |
   5 #   \\  /    A nd           | Copyright (C) 1991-2009 OpenCFD Ltd.
   6 #    \\/     M anipulation  |
   7 #------------------------------------------------------------------------------
   8 # License
   9 #     This file is part of OpenFOAM.
  10 #
  11 #     OpenFOAM is free software; you can redistribute it and/or modify it
  12 #     under the terms of the GNU General Public License as published by the
  13 #     Free Software Foundation; either version 2 of the License, or (at your
  14 #     option) any later version.
  15 #
  16 #     OpenFOAM is distributed in the hope that it will be useful, but WITHOUT
  17 #     ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 #     FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  19 #     for more details.
  20 #
  21 #     You should have received a copy of the GNU General Public License
  22 #     along with OpenFOAM; if not, write to the Free Software Foundation,
  23 #     Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
  24 #
  25 # Script
  26 #     etc/settings.csh
  27 #
  28 # Description
  29 #     Startup file for OpenFOAM
  30 #     Sourced from OpenFOAM-??/etc/cshrc
  31 #
  32 #------------------------------------------------------------------------------
  33
  34 # prefix to PATH
  35 alias _foamAddPath 'set path=(\!* $path)'
  36 # prefix to LD_LIBRARY_PATH
  37 alias _foamAddLib 'setenv LD_LIBRARY_PATH \!*\:${LD_LIBRARY_PATH}'
  38
  39 # location of the jobControl directory
  40 setenv FOAM_JOB_DIR $WM_PROJECT_INST_DIR/jobControl
  41
  42 # wmake configuration
  43 setenv WM_DIR $WM_PROJECT_DIR/wmake
  44 setenv WM_LINK_LANGUAGE c++
  45 setenv WM_OPTIONS $WM_ARCH$WM_COMPILER$WM_PRECISION_OPTION$WM_COMPILE_OPTION
  46
  47 # base configuration
  48 setenv FOAM_APP $WM_PROJECT_DIR/applications
  49 setenv FOAM_APPBIN $WM_PROJECT_DIR/applications/bin/$WM_OPTIONS
  50 setenv FOAM_LIB $WM_PROJECT_DIR/lib
  51 setenv FOAM_LIBBIN $WM_PROJECT_DIR/lib/$WM_OPTIONS
  52 setenv FOAM_SRC $WM_PROJECT_DIR/src
  53
  54 # shared site configuration - similar naming convention as ~OpenFOAM expansion
  55 setenv FOAM_SITE_APPBIN $WM_PROJECT_INST_DIR/site/$WM_PROJECT_VERSION/bin/$WM_OPTIONS
  56 setenv FOAM_SITE_LIBBIN $WM_PROJECT_INST_DIR/site/$WM_PROJECT_VERSION/lib/$WM_OPTIONS
  57
  58 # user configuration
  59 setenv FOAM_USER_APPBIN $WM_PROJECT_USER_DIR/applications/bin/$WM_OPTIONS
  60 setenv FOAM_USER_LIBBIN $WM_PROJECT_USER_DIR/lib/$WM_OPTIONS
  61
  62 # convenience
  63 setenv FOAM_TUTORIALS $WM_PROJECT_DIR/tutorials
  64 setenv FOAM_UTILITIES $FOAM_APP/utilities
  65 setenv FOAM_SOLVERS $FOAM_APP/solvers
  66 setenv FOAM_RUN $WM_PROJECT_USER_DIR/run
  67
  68 # add OpenFOAM scripts and wmake to the path
  69 set path=($WM_DIR $WM_PROJECT_DIR/bin $path)
  70
  71 _foamAddPath $FOAM_APPBIN
  72 _foamAddPath $FOAM_SITE_APPBIN
  73 _foamAddPath $FOAM_USER_APPBIN
  74 _foamAddLib  $FOAM_LIBBIN
  75 _foamAddLib  $FOAM_SITE_LIBBIN
  76 _foamAddLib  $FOAM_USER_LIBBIN
  77
  78
  79 # Select compiler installation
  80 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  81 # compilerInstall = OpenFOAM | System
  82 set compilerInstall=OpenFOAM
  83
  84 switch ("$compilerInstall")
  85 case OpenFOAM:
  86     switch ("$WM_COMPILER")
  87     case Gcc:
  88         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/gcc-4.3.3/platforms/$WM_ARCH$WM_COMPILER_ARCH
  89         _foamAddLib $WM_THIRD_PARTY_DIR/mpfr-2.4.1/platforms/$WM_ARCH$WM_COMPILER_ARCH/lib
  90         _foamAddLib $WM_THIRD_PARTY_DIR/gmp-4.2.4/platforms/$WM_ARCH$WM_COMPILER_ARCH/lib
  91     breaksw
  92     case Gcc43:
  93         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/gcc-4.3.3/platforms/$WM_ARCH$WM_COMPILER_ARCH
  94         _foamAddLib $WM_THIRD_PARTY_DIR/mpfr-2.4.1/platforms/$WM_ARCH$WM_COMPILER_ARCH/lib
  95         _foamAddLib $WM_THIRD_PARTY_DIR/gmp-4.2.4/platforms/$WM_ARCH$WM_COMPILER_ARCH/lib
  96     breaksw
  97     case Gcc42:
  98         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/gcc-4.2.4/platforms/$WM_ARCH$WM_COMPILER_ARCH
  99     breaksw
 100     endsw
 101
 102     # Check that the compiler directory can be found
 103     if ( ! -d "$WM_COMPILER_DIR" ) then
 104         echo
 105         echo "Warning in $WM_PROJECT_DIR/etc/settings.csh:"
 106         echo "    Cannot find $WM_COMPILER_DIR installation."
 107         echo "    Please install this compiler version or if you wish to use the system compiler,"
 108         echo "    change the 'compilerInstall' setting to 'System' in this file"
 109         echo
 110     endif
 111
 112     _foamAddPath ${WM_COMPILER_DIR}/bin
 113     _foamAddLib  ${WM_COMPILER_DIR}/lib${WM_COMPILER_LIB_ARCH}
 114     _foamAddLib  ${WM_COMPILER_DIR}/lib
 115
 116     breaksw
 117 endsw
 118
 119
 120 # Communications library
 121 # ~~~~~~~~~~~~~~~~~~~~~~
 122
 123 unset MPI_ARCH_PATH
 124
 125 switch ("$WM_MPLIB")
 126 case OPENMPI:
 127     set mpi_version=openmpi-1.3.3
 128     setenv MPI_HOME $WM_THIRD_PARTY_DIR/$mpi_version
 129     setenv MPI_ARCH_PATH $MPI_HOME/platforms/$WM_OPTIONS
 130
 131     # Tell OpenMPI where to find its install directory
 132     setenv OPAL_PREFIX $MPI_ARCH_PATH
 133
 134     _foamAddPath $MPI_ARCH_PATH/bin
 135     _foamAddLib  $MPI_ARCH_PATH/lib
 136
 137     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/$mpi_version
 138     unset mpi_version
 139     breaksw
 140
 141 case MPICH:
 142     set mpi_version=mpich-1.2.4
 143     setenv MPI_HOME $WM_THIRD_PARTY_DIR/$mpi_version
 144     setenv MPI_ARCH_PATH $MPI_HOME/platforms/$WM_OPTIONS
 145     setenv MPICH_ROOT $MPI_ARCH_PATH
 146
 147     _foamAddPath $MPI_ARCH_PATH/bin
 148     _foamAddLib  $MPI_ARCH_PATH/lib
 149
 150     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/$mpi_version
 151     unset mpi_version
 152     breaksw
 153
 154 case MPICH-GM:
 155     setenv MPI_ARCH_PATH /opt/mpi
 156     setenv MPICH_PATH $MPI_ARCH_PATH
 157     setenv MPICH_ROOT $MPI_ARCH_PATH
 158     setenv GM_LIB_PATH /opt/gm/lib64
 159
 160     _foamAddPath $MPI_ARCH_PATH/bin
 161     _foamAddLib  $MPI_ARCH_PATH/lib
 162     _foamAddLib  $GM_LIB_PATH
 163
 164     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/mpich-gm
 165     breaksw
 166
 167 case HPMPI:
 168     setenv MPI_HOME /opt/hpmpi
 169     setenv MPI_ARCH_PATH $MPI_HOME
 170     setenv MPICH_ROOT=$MPI_ARCH_PATH
 171
 172     _foamAddPath $MPI_ARCH_PATH/bin
 173
 174     switch (`uname -m`)
 175     case i686:
 176         _foamAddLib $MPI_ARCH_PATH/lib/linux_ia32
 177         breaksw
 178     case x86_64:
 179         _foamAddLib $MPI_ARCH_PATH/lib/linux_amd64
 180         breaksw
 181     case ia64:
 182         _foamAddLib $MPI_ARCH_PATH/lib/linux_ia64
 183         breaksw
 184     default:
 185         echo Unknown processor type `uname -m` for Linux
 186         breaksw
 187     endsw
 188
 189     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/hpmpi
 190     breaksw
 191
 192 case GAMMA:
 193     setenv MPI_ARCH_PATH /usr
 194     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/gamma
 195     breaksw
 196
 197 case MPI:
 198     setenv MPI_ARCH_PATH /opt/mpi
 199     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/mpi
 200     breaksw
 201
 202 case FJMPI:
 203     setenv MPI_ARCH_PATH /opt/FJSVmpi2
 204     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/mpi
 205     _foamAddPath $MPI_ARCH_PATH/bin
 206     _foamAddLib  $MPI_ARCH_PATH/lib/sparcv9
 207     _foamAddLib  /opt/FSUNf90/lib/sparcv9
 208     _foamAddLib  /opt/FJSVpnidt/lib
 209     breaksw
 210
 211 case QSMPI:
 212     setenv MPI_ARCH_PATH /usr/lib/mpi
 213     setenv FOAM_MPI_LIBBIN FOAM_LIBBIN/qsmpi
 214
 215     _foamAddPath $MPI_ARCH_PATH/bin
 216     _foamAddLib $MPI_ARCH_PATH/lib
 217
 218     breaksw
 219
 220 default:
 221     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/dummy
 222     breaksw
 223 endsw
 224
 225 _foamAddLib $FOAM_MPI_LIBBIN
 226
 227
 228 # Set the minimum MPI buffer size (used by all platforms except SGI MPI)
 229 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 230 set minBufferSize=20000000
 231
 232 if ( $?MPI_BUFFER_SIZE ) then
 233     if ( $MPI_BUFFER_SIZE < $minBufferSize ) then
 234         setenv MPI_BUFFER_SIZE $minBufferSize
 235     endif
 236 else
 237     setenv MPI_BUFFER_SIZE $minBufferSize
 238 endif
 239
 240
 241 # CGAL library if available
 242 # ~~~~~~~~~~~~~~~~~~~~~~~~~
 243 if ( $?CGAL_LIB_DIR ) then
 244     _foamAddLib $CGAL_LIB_DIR
 245 endif
 246
 247
 248 # Switch on the hoard memory allocator if available
 249 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 250 #if ( -f $FOAM_LIBBIN/libhoard.so ) then
 251 #    setenv LD_PRELOAD $FOAM_LIBBIN/libhoard.so:${LD_PRELOAD}
 252 #endif
 253
 254
 255 # cleanup environment:
 256 # ~~~~~~~~~~~~~~~~~~~~
 257 unalias _foamAddPath
 258 unalias _foamAddLib
 259 unset minBufferSize
 260
 261 # -----------------------------------------------------------------------------