etc/cshrc

   1 #----------------------------------*-sh-*--------------------------------------
   2 # =========                 |
   3 # \\      /  F ield         | OpenFOAM: The Open Source CFD Toolbox
   4 #  \\    /   O peration     |
   5 #   \\  /    A nd           | Copyright (C) 1991-2008 OpenCFD Ltd.
   6 #    \\/     M anipulation  |
   7 #------------------------------------------------------------------------------
   8 # License
   9 #     This file is part of OpenFOAM.
  10 #
  11 #     OpenFOAM is free software; you can redistribute it and/or modify it
  12 #     under the terms of the GNU General Public License as published by the
  13 #     Free Software Foundation; either version 2 of the License, or (at your
  14 #     option) any later version.
  15 #
  16 #     OpenFOAM is distributed in the hope that it will be useful, but WITHOUT
  17 #     ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 #     FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  19 #     for more details.
  20 #
  21 #     You should have received a copy of the GNU General Public License
  22 #     along with OpenFOAM; if not, write to the Free Software Foundation,
  23 #     Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
  24 #
  25 # Script
  26 #     etc/cshrc
  27 #
  28 # Description
  29 #     Startup file for OpenFOAM
  30 #     Sourced from ~/.login or ~/.cshrc
  31 #
  32 #------------------------------------------------------------------------------
  33
  34 setenv WM_PROJECT OpenFOAM
  35 setenv WM_PROJECT_VERSION 1.5.x
  36
  37 #!!User:
  38 #    either setenv FOAM_INST_DIR before sourcing this file or set
  39 #    foamInstall below to where OpenFOAM is installed
  40 #
  41 # Location of FOAM installation
  42 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  43 set foamInstall = $HOME/$WM_PROJECT
  44 # set foamInstall = ~$WM_PROJECT
  45 # set foamInstall = /usr/local/$WM_PROJECT
  46 # set foamInstall = /opt/$WM_PROJECT
  47
  48 if ( ! $?FOAM_INST_DIR ) setenv FOAM_INST_DIR $foamInstall
  49
  50
  51 # Location of site/user files
  52 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~
  53 setenv WM_PROJECT_INST_DIR $FOAM_INST_DIR
  54 setenv WM_PROJECT_DIR $WM_PROJECT_INST_DIR/$WM_PROJECT-$WM_PROJECT_VERSION
  55 setenv WM_PROJECT_USER_DIR $HOME/$WM_PROJECT/$LOGNAME-$WM_PROJECT_VERSION
  56
  57
  58 # Location of third-party software
  59 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  60 setenv WM_THIRD_PARTY_DIR $WM_PROJECT_INST_DIR/ThirdParty
  61
  62
  63 # Operating System/Platform from Unix or MSWindows
  64 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  65 # WM_OS = Unix | MSWindows
  66 if ( ! $?WM_OS ) setenv WM_OS Unix
  67
  68
  69 # Compiler: set to Gcc, Gcc43 or Icc (for Intel's icc)
  70 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  71 if ( ! $?WM_COMPILER ) setenv WM_COMPILER Gcc
  72
  73 setenv WM_COMPILER_ARCH
  74 setenv WM_COMPILER_LIB_ARCH
  75
  76
  77 # Compilation options (architecture, precision, optimised, debug or profiling)
  78 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  79 # WM_ARCH_OPTION = 32 | 64
  80 if ( ! $?WM_ARCH_OPTION ) setenv WM_ARCH_OPTION 64
  81
  82 # WM_PRECISION_OPTION = DP | SP
  83 if ( ! $?WM_PRECISION_OPTION ) setenv WM_PRECISION_OPTION DP
  84
  85 # WM_COMPILE_OPTION = Opt | Debug | Prof
  86 if ( ! $?WM_COMPILE_OPTION ) setenv WM_COMPILE_OPTION Opt
  87
  88 # WM_JAVAC_OPTION = Opt | Debug
  89 if ( ! $?WM_JAVAC_OPTION ) setenv WM_JAVAC_OPTION Opt
  90
  91 # WM_MPLIB = | OPENMPI | LAM | MPICH | MPICH-GM | HPMPI | GAMMA | MPI
  92 if ( ! $?WM_MPLIB ) setenv WM_MPLIB OPENMPI
  93
  94
  95 # Run options (floating-point signal handling and memory initialisation)
  96 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  97 setenv FOAM_SIGFPE
  98 # setenv FOAM_SETNAN
  99
 100
 101 # Detect system type and set environment variables
 102 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 103 setenv WM_ARCH `uname -s`
 104
 105 switch ($WM_ARCH)
 106 case Linux:
 107     setenv WM_ARCH linux
 108
 109     switch (`uname -m`)
 110     case i686:
 111         breaksw
 112     case x86_64:
 113         switch ($WM_ARCH_OPTION)
 114         case 32:
 115             setenv WM_ARCH linux
 116             setenv WM_COMPILER_ARCH '-64'
 117             setenv WM_CC 'gcc'
 118             setenv WM_CXX 'g++'
 119             setenv WM_CFLAGS '-m32 -fPIC'
 120             setenv WM_CXXFLAGS '-m32 -fPIC'
 121             setenv WM_LDFLAGS '-m32'
 122             breaksw
 123         case 64:
 124             setenv WM_ARCH linux64
 125             setenv WM_COMPILER_LIB_ARCH 64
 126             setenv WM_CC 'gcc'
 127             setenv WM_CXX 'g++'
 128             setenv WM_CFLAGS '-m64 -fPIC'
 129             setenv WM_CXXFLAGS '-m64 -fPIC'
 130             setenv WM_LDFLAGS '-m64'
 131             breaksw
 132         default:
 133             echo Unknown WM_ARCH_OPTION $WM_ARCH_OPTION, should be 32 or 64
 134             breaksw
 135         endsw
 136         breaksw
 137     case ia64:
 138         setenv WM_ARCH linuxIA64
 139         setenv WM_COMPILER I64
 140         breaksw
 141     mips64)
 142         setenv WM_ARCH SiCortex64
 143         setenv WM_COMPILER_LIB_ARCH 64
 144         setenv WM_CC 'gcc'
 145         setenv WM_CXX 'g++'
 146         setenv WM_CFLAGS '-mabi=64 -fPIC'
 147         setenv WM_CXXFLAGS '-mabi=64 -fPIC'
 148         setenv WM_LDFLAGS '-mabi=64 -G0'
 149         setenv WM_MPLIB MPI
 150         ;;
 151     default:
 152         echo Unknown processor type `uname -m` for Linux
 153         breaksw
 154     endsw
 155     breaksw
 156
 157 default:
 158     echo
 159     echo "Your '$WM_ARCH' operating system is not supported by this release"
 160     echo "of OpenFOAM. For further assistance, please contact www.openfoam.org"
 161     echo
 162     breaksw
 163
 164 endsw
 165
 166
 167 # Clean standard environment variables (path, PATH, MANPATH, LD_LIBRARY_PATH)
 168 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 169 set cleanProg=$WM_PROJECT_DIR/bin/foamCleanPath
 170
 171 if (! $?LD_LIBRARY_PATH ) then
 172     setenv LD_LIBRARY_PATH ''
 173 endif
 174 if (! $?MANPATH) then
 175     setenv MANPATH ''
 176 endif
 177
 178 # Remove anything under top-level foam directory
 179 set wildCards="$WM_PROJECT_INST_DIR $HOME/$WM_PROJECT/$LOGNAME"
 180
 181 #- Clean path/PATH
 182 set colonPath=`echo "$path" | sed -e 's/ /:/g'`
 183 set PATH=`$cleanProg "$colonPath" "$wildCards"`
 184 if ( $status == 0 ) then
 185     set path=`echo "$PATH" | sed -e 's/:/ /g'`
 186 endif
 187
 188 #- Clean LD_LIBRARY_PATH
 189 setenv LD_LIBRARY_PATH `$cleanProg "$LD_LIBRARY_PATH" "$wildCards"`
 190
 191 #- Clean MANPATH
 192 setenv MANPATH `$cleanProg "$MANPATH" "$wildCards"`
 193
 194
 195 # Source project setup files
 196 # ~~~~~~~~~~~~~~~~~~~~~~~~~~
 197 alias _foamSource 'if ($?FOAM_VERBOSE && $?prompt) echo "Executing: \!*"; source \!*'
 198
 199 _foamSource $WM_PROJECT_DIR/etc/settings.csh
 200 _foamSource $WM_PROJECT_DIR/etc/aliases.csh
 201
 202 # Source user setup files for optional packages
 203 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 204 # _foamSource $WM_PROJECT_DIR/etc/apps/paraview/cshrc
 205 _foamSource $WM_PROJECT_DIR/etc/apps/paraview3/cshrc
 206 # _foamSource $WM_PROJECT_DIR/etc/apps/ensightFoam/cshrc
 207
 208
 209 # Again clean environment (path, PATH, MANPATH, LD_LIBRARY_PATH)
 210 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 211 #- Clean path/PATH. Only remove duplicates
 212 set colonPath=`echo "$path" | sed -e 's/ /:/g'`
 213 set PATH=`$cleanProg "$colonPath"`
 214 if ( $status == 0 ) then
 215     set path=`echo "$PATH" | sed -e 's/:/ /g'`
 216 endif
 217
 218 #- Clean LD_LIBRARY_PATH
 219 setenv LD_LIBRARY_PATH `$cleanProg "$LD_LIBRARY_PATH"`
 220
 221 #- Clean MANPATH
 222 setenv MANPATH `$cleanProg "$MANPATH"`
 223
 224 #- Clean LD_PRELOAD
 225 if ( $?LD_PRELOAD ) then
 226     setenv LD_PRELOAD `$cleanProg "$LD_PRELOAD"`
 227 endif
 228
 229 # cleanup environment:
 230 # ~~~~~~~~~~~~~~~~~~~~
 231 unset cleanProg
 232 unset wildCards
 233 unset colonPath
 234 unalias _foamSource
 235 # -----------------------------------------------------------------------------