lib/Method/Signatures/Simple.pm

   1 package Method::Signatures::Simple;
   2
   3 use warnings;
   4 use strict;
   5
   6 our $VERSION = '0.01_01';
   7
   8 use base q/Devel::Declare::MethodInstaller::Simple/;
   9
  10 sub import {
  11     my $class = shift;
  12     my %opts  = @_;
  13     $opts{into}     ||= caller;
  14     $opts{invocant} ||= '$self';
  15
  16     $class->install_methodhandler(
  17       name => 'method',
  18       %opts,
  19     );
  20 }
  21
  22 sub parse_proto {
  23     my $self = shift;
  24     my ($proto) = @_;
  25     $proto ||= '';
  26     $proto =~ s/[\r\n]//g;
  27     my $invocant = $self->{invocant};
  28
  29     $invocant = $1 if $proto =~ s{^(\$\w+):\s*}{};
  30
  31     my $inject = "my ${invocant} = shift;";
  32     $inject .= "my ($proto) = \@_;" if defined $proto and length $proto;
  33
  34     return $inject;
  35 }
  36
  37
  38 =head1 NAME
  39
  40 Method::Signatures::Simple - Basic method declarations with signatures, without source filters
  41
  42 =head1 VERSION
  43
  44 Version 0.01
  45
  46 =head1 SYNOPSIS
  47
  48     use Method::Signatures::Simple;
  49
  50     method foo { $self->bar }
  51
  52     # with signature
  53     method foo($bar, %opts) {
  54         $self->bar(reverse $bar) if $opts{rev};
  55     }
  56
  57     # attributes
  58     method foo : lvalue { $self->{foo} }
  59
  60     # change invocant name
  61     method foo ($class: $bar) { $class->bar($bar) }
  62
  63 =head1 RATIONALE
  64
  65 This module provides a basic C<method> keyword with simple signatures. It's intentionally simple,
  66 and is supposed to be a stepping stone for its bigger brothers L<MooseX::Method::Signatures> and L<Method::Signatures>.
  67 It only has a small benefit over regular subs, so if you want more features, look at those modules.
  68 But if you're looking for a small amount of syntactic sugar, this might just be enough.
  69
  70 =head1 FEATURES
  71
  72 =over 4
  73
  74 =item * invocant
  75
  76 The C<method> keyword automatically injects the annoying C<my $self = shift;> for you. You can rename
  77 the invocant with the first argument, followed by a colon:
  78
  79     method ($this:) {}
  80     method ($this: $that) {}
  81
  82 =item * signature
  83
  84 The signature C<($sig)> is transformed into C<"my ($sig) = \@_;">. That way, we mimic perl's usual
  85 argument handling.
  86
  87     method foo ($bar, $baz, %opts) {
  88
  89     # becomes
  90
  91     sub foo {
  92         my $self = shift;
  93         my ($bar, $baz, %opts) = @_;
  94
  95 =back
  96
  97
  98 =begin pod-coverage
  99
 100 =over 4
 101
 102 =item parse_proto
 103
 104 Overridden.
 105
 106 =back
 107
 108 =end pod-coverage
 109
 110 =head1 AUTHOR
 111
 112 Rhesa Rozendaal, C<< <rhesa at cpan.org> >>
 113
 114 =head1 BUGS
 115
 116 Please report any bugs or feature requests to C<bug-method-signatures-simple at rt.cpan.org>, or through
 117 the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Method-Signatures-Simple>.  I will be notified, and then you'll
 118 automatically be notified of progress on your bug as I make changes.
 119
 120 =head1 SUPPORT
 121
 122 You can find documentation for this module with the perldoc command.
 123
 124     perldoc Method::Signatures::Simple
 125
 126
 127 You can also look for information at:
 128
 129 =over 4
 130
 131 =item * RT: CPAN's request tracker
 132
 133 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Method-Signatures-Simple>
 134
 135 =item * AnnoCPAN: Annotated CPAN documentation
 136
 137 L<http://annocpan.org/dist/Method-Signatures-Simple>
 138
 139 =item * CPAN Ratings
 140
 141 L<http://cpanratings.perl.org/d/Method-Signatures-Simple>
 142
 143 =item * Search CPAN
 144
 145 L<http://search.cpan.org/dist/Method-Signatures-Simple>
 146
 147 =back
 148
 149 =head1 ACKNOWLEDGEMENTS
 150
 151 =over 4
 152
 153 =item * MSTROUT
 154
 155 For writing L<Devel::Declare> and providing the core concepts.
 156
 157 =item * MSCHWERN
 158
 159 For writing L<Method::Signatures> and publishing about it. This is what got my attention.
 160
 161 =item * FLORA
 162
 163 For helping me abstracting the Devel::Declare bits and suggesting improvements.
 164
 165 =back
 166
 167 =head1 SEE ALSO
 168
 169 L<Devel::Declare>, L<Method::Signatures>, L<MooseX::Method::Signatures>.
 170
 171 =head1 COPYRIGHT & LICENSE
 172
 173 Copyright 2008 Rhesa Rozendaal, all rights reserved.
 174
 175 This program is free software; you can redistribute it and/or modify it
 176 under the same terms as Perl itself.
 177
 178
 179 =cut
 180
 181 1; # End of Method::Signatures::Simple