runtime/plugin/getscript.vim

   1 " ---------------------------------------------------------------------
   2 " GetLatestVimScripts.vim
   3 "  Author:              Charles E. Campbell, Jr.
   4 "  Date:                Feb 15, 2006
   5 "  Version:             20
   6 "  Installing:  :help glvs-install
   7 "  Usage:               :help glvs
   8 "
   9 " GetLatestVimScripts: 642 1 :AutoInstall: GetLatestVimScripts.vim
  10 " ---------------------------------------------------------------------
  11 " Initialization:       {{{1
  12 " if you're sourcing this file, surely you can't be
  13 " expecting vim to be in its vi-compatible mode
  14 if &cp
  15   if &verbose
  16         echo "GetLatestVimScripts is not vi-compatible; not loaded (you need to set nocp)"
  17   endif
  18  finish
  19 endif
  20 let s:keepfo  = &fo
  21 let s:keepcpo = &cpo
  22 set cpo&vim
  23
  24 if exists("loaded_GetLatestVimScripts")
  25  finish
  26 endif
  27 let g:loaded_GetLatestVimScripts= "v20"
  28
  29 " ---------------------------------------------------------------------
  30 "  Global Variables: {{{1
  31 " allow user to change the command for obtaining scripts (does fetch work?)
  32 if !exists("g:GetLatestVimScripts_wget")
  33  let g:GetLatestVimScripts_wget= "wget"
  34 endif
  35 if !exists("g:GetLatestVimScripts_options")
  36  let g:GetLatestVimScripts_options= "-q -O"
  37 endif
  38 if !exists("g:GetLatestVimScripts_allowautoinstall")
  39  let g:GetLatestVimScripts_allowautoinstall= 1
  40 endif
  41
  42 "" For debugging:
  43 "let g:GetLatestVimScripts_wget    = "echo"
  44 "let g:GetLatestVimScripts_options = "options"
  45
  46 " check if s:autoinstall is possible
  47 let s:autoinstall= ""
  48 if g:GetLatestVimScripts_allowautoinstall
  49
  50  if (has("win32") || has("gui_win32") || has("gui_win32s") || has("win16") || has("win64") || has("win32unix") || has("win95")) && &shell != "bash"
  51   " windows (but not cygwin/bash)
  52   let s:dotvim= "vimfiles"
  53   if !exists("g:GetLatestVimScripts_mv")
  54    let g:GetLatestVimScripts_mv= "ren"
  55   endif
  56
  57  else
  58   " unix
  59   let s:dotvim= ".vim"
  60   if !exists("g:GetLatestVimScripts_mv")
  61    let g:GetLatestVimScripts_mv= "mv"
  62   endif
  63  endif
  64
  65  if exists('$HOME') && isdirectory(expand("$HOME")."/".s:dotvim)
  66   let s:autoinstall= $HOME."/".s:dotvim
  67  endif
  68 " call Decho("s:autoinstall<".s:autoinstall.">")
  69 else
  70 " call Decho("g:GetLatestVimScripts_allowautoinstall=".g:GetLatestVimScripts_allowautoinstall.": :AutoInstall: disabled")
  71 endif
  72
  73 " ---------------------------------------------------------------------
  74 "  Public Interface: {{{1
  75 com!        -nargs=0 GetLatestVimScripts call <SID>GetLatestVimScripts()
  76 silent! com -nargs=0 GLVS                call <SID>GetLatestVimScripts()
  77
  78 " ---------------------------------------------------------------------
  79 "  GetOneScript: (Get Latest Vim Script) this function operates {{{1
  80 "    on the current line, interpreting two numbers and text as
  81 "    ScriptID, SourceID, and Filename.
  82 "    It downloads any scripts that have newer versions from vim.sf.net.
  83 fun! <SID>GetOneScript(...)
  84 "   call Dfunc("GetOneScript()")
  85
  86  " set options to allow progress to be shown on screen
  87   let t_ti= &t_ti
  88   let t_te= &t_te
  89   let rs  = &rs
  90   set t_ti= t_te= nors
  91
  92  " put current line on top-of-screen and interpret it into
  93  " a      script identifer  : used to obtain webpage
  94  "        source identifier : used to identify current version
  95  " and an associated comment: used to report on what's being considered
  96   if a:0 >= 3
  97    let scriptid = a:1
  98    let srcid    = a:2
  99    let cmmnt    = a:3
 100 "   call Decho("scriptid<".scriptid.">")
 101 "   call Decho("srcid   <".srcid.">")
 102 "   call Decho("cmmnt   <".cmmnt.">")
 103   else
 104    let curline  = getline(".")
 105    let parsepat = '^\s*\(\d\+\)\s\+\(\d\+\)\s\+\(.\{-}\)$'
 106    try
 107     let scriptid = substitute(curline,parsepat,'\1','e')
 108    catch /^Vim\%((\a\+)\)\=:E486/
 109         let scriptid= 0
 110    endtry
 111    try
 112     let srcid    = substitute(curline,parsepat,'\2','e')
 113    catch /^Vim\%((\a\+)\)\=:E486/
 114         let srcid= 0
 115    endtry
 116    try
 117     let cmmnt    = substitute(curline,parsepat,'\3','e')
 118    catch /^Vim\%((\a\+)\)\=:E486/
 119         let cmmnt= ""
 120    endtry
 121 "   call Decho("curline <".curline.">")
 122 "   call Decho("parsepat<".parsepat.">")
 123 "   call Decho("scriptid<".scriptid.">")
 124 "   call Decho("srcid   <".srcid.">")
 125 "   call Decho("cmmnt   <".cmmnt.">")
 126   endif
 127
 128   if scriptid == 0 || srcid == 0
 129    " When looking for :AutoInstall: lines, skip scripts that
 130    " have  0 0 scriptname
 131 "   call Dret("GetOneScript : skipping a scriptid==srcid==0 line")
 132    return
 133   endif
 134
 135   let doautoinstall= 0
 136   if cmmnt =~ ":AutoInstall:"
 137 "   call Decho("cmmnt<".cmmnt."> has :AutoInstall:...")
 138    let aicmmnt= substitute(cmmnt,'\s\+:AutoInstall:\s\+',' ','')
 139 "   call Decho("aicmmnt<".aicmmnt."> s:autoinstall=".s:autoinstall)
 140    if s:autoinstall != ""
 141     let doautoinstall = g:GetLatestVimScripts_allowautoinstall
 142    endif
 143   else
 144    let aicmmnt= cmmnt
 145   endif
 146 "  call Decho("aicmmnt<".aicmmnt.">: doautoinstall=".doautoinstall)
 147
 148   exe "norm z\<CR>"
 149   redraw!
 150 "  call Decho('considering <'.aicmmnt.'> scriptid='.scriptid.' srcid='.srcid)
 151   echomsg 'considering <'.aicmmnt.'> scriptid='.scriptid.' srcid='.srcid
 152
 153   " grab a copy of the plugin's vim.sf.net webpage
 154   let scriptaddr = 'http://vim.sf.net/script.php?script_id='.scriptid
 155   let tmpfile    = tempname()
 156   let v:errmsg   = ""
 157
 158   " make three tries at downloading the description
 159   let itry= 1
 160   while itry <= 3
 161 "       call Decho("try#".itry." to download description of <".aicmmnt."> with addr=".scriptaddr)
 162         if has("win32") || has("win16") || has("win95")
 163 "     call Decho("silent !".g:GetLatestVimScripts_wget." ".g:GetLatestVimScripts_options." ".tmpfile.' "'.scriptaddr.'"')
 164      exe "silent !".g:GetLatestVimScripts_wget." ".g:GetLatestVimScripts_options." ".tmpfile.' "'.scriptaddr.'"'
 165         else
 166 "     call Decho("silent !".g:GetLatestVimScripts_wget." ".g:GetLatestVimScripts_options." ".tmpfile." '".scriptaddr."'")
 167      exe "silent !".g:GetLatestVimScripts_wget." ".g:GetLatestVimScripts_options." ".tmpfile." '".scriptaddr."'"
 168         endif
 169         if itry == 1
 170     exe "silent vsplit ".tmpfile
 171         else
 172          silent! e %
 173         endif
 174
 175    " find the latest source-id in the plugin's webpage
 176    silent! 1
 177    let findpkg= search('Click on the package to download','W')
 178    if findpkg > 0
 179     break
 180    endif
 181    let itry= itry + 1
 182   endwhile
 183 "  call Decho(" --- end downloading tries while loop --- itry=".itry)
 184
 185   " testing: did finding /Click on the package.../ fail?
 186   if findpkg == 0 || itry >= 4
 187     silent q!
 188     call delete(tmpfile)
 189    " restore options
 190         let &t_ti        = t_ti
 191         let &t_te        = t_te
 192         let &rs          = rs
 193         let s:downerrors = s:downerrors + 1
 194 "       call Decho("***warning*** couldn'".'t find "Click on the package..." in description page for <'.aicmmnt.">")
 195         echomsg "***warning*** couldn'".'t find "Click on the package..." in description page for <'.aicmmnt.">"
 196 "       call Dret("GetOneScript : srch for /Click on the package/ failed")
 197         return
 198   endif
 199 "  call Decho('found "Click on the package to download"')
 200
 201   let findsrcid= search('src_id=','W')
 202   if findsrcid == 0
 203     silent q!
 204     call delete(tmpfile)
 205    " restore options
 206         let &t_ti        = t_ti
 207         let &t_te        = t_te
 208         let &rs          = rs
 209         let s:downerrors = s:downerrors + 1
 210 "       call Decho("***warning*** couldn'".'t find "src_id=" in description page for <'.aicmmnt.">")
 211         echomsg "***warning*** couldn'".'t find "src_id=" in description page for <'.aicmmnt.">"
 212 "       call Dret("GetOneScript : srch for /src_id/ failed")
 213         return
 214   endif
 215 "  call Decho('found "src_id=" in description page')
 216
 217   let srcidpat   = '^\s*<td class.*src_id=\(\d\+\)">\([^<]\+\)<.*$'
 218   let latestsrcid= substitute(getline("."),srcidpat,'\1','')
 219   let fname      = substitute(getline("."),srcidpat,'\2','')
 220 "  call Decho("srcidpat<".srcidpat."> latestsrcid<".latestsrcid."> fname<".fname.">")
 221   silent q!
 222   call delete(tmpfile)
 223
 224   " convert the strings-of-numbers into numbers
 225   let srcid       = srcid       + 0
 226   let latestsrcid = latestsrcid + 0
 227 "   call Decho("srcid=".srcid." latestsrcid=".latestsrcid." fname<".fname.">")
 228
 229   " has the plugin's most-recent srcid increased, which indicates
 230   " that it has been updated
 231   if latestsrcid > srcid
 232    let s:downloads= s:downloads + 1
 233    if fname == bufname("%")
 234     " GetLatestVimScript has to be careful about downloading itself
 235     let fname= "NEW_".fname
 236    endif
 237
 238    " the plugin has been updated since we last obtained it, so download a new copy
 239 "   call Decho("...downloading new <".fname.">")
 240    echomsg "...downloading new <".fname.">"
 241    if has("win32") || has("gui_win32") || has("gui_win32s") || has("win16") || has("win64") || has("win32unix") || has("win95")
 242 "    call Decho("windows: silent !".g:GetLatestVimScripts_wget." ".g:GetLatestVimScripts_options." ".fname.' "'.'http://vim.sf.net/scripts/download_script.php?src_id='.latestsrcid.'"')
 243     exe "silent !".g:GetLatestVimScripts_wget." ".g:GetLatestVimScripts_options." ".fname.' "'.'http://vim.sf.net/scripts/download_script.php?src_id='.latestsrcid.'"'
 244    else
 245 "    call Decho("unix: silent !".g:GetLatestVimScripts_wget." ".g:GetLatestVimScripts_options." ".fname." '".'http://vim.sf.net/scripts/download_script.php?src_id='.latestsrcid."'")
 246     exe "silent !".g:GetLatestVimScripts_wget." ".g:GetLatestVimScripts_options." ".fname." '".'http://vim.sf.net/scripts/download_script.php?src_id='.latestsrcid."'"
 247    endif
 248
 249    " AutoInstall: only if doautoinstall is so indicating
 250    if doautoinstall
 251 "       call Decho("attempting to do autoinstall: getcwd<".getcwd()."> filereadable(".fname.")=".filereadable(fname))
 252         if filereadable(fname)
 253 "        call Decho("move <".fname."> to ".s:autoinstall)
 254 "        call Decho("DISABLED for testing")
 255          exe "silent !"g:GetLatestVimScripts_mv." ".fname." ".s:autoinstall
 256          let curdir= escape(substitute(getcwd(),'\','/','ge'),"|[]*'\" #")
 257          exe "cd ".s:autoinstall
 258          if fname =~ '\.bz2$'
 259 "         call Decho("attempt to bunzip2 ".fname)
 260           exe "silent !bunzip2 ".fname
 261           let fname= substitute(fname,'\.bz2$','','')
 262          elseif fname =~ '\.gz$'
 263 "         call Decho("attempt to gunzip ".fname)
 264           exe "silent !gunzip ".fname
 265           let fname= substitute(fname,'\.gz$','','')
 266          endif
 267          if fname =~ '\.zip$'
 268 "         call Decho("attempt to unzip ".fname)
 269           exe "silent !unzip -o".fname
 270          elseif fname =~ '\.tar$'
 271 "         call Decho("attempt to untar ".fname)
 272           exe "silent !tar -oxvf ".fname
 273          endif
 274          if fname =~ '.vim$'
 275 "         call Decho("attempt to simply move ".fname." to plugin")
 276           exe "silent !".g:GetLatestVimScripts_mv." ".fname." plugin"
 277          endif
 278          exe "helptags ../".s:dotvim."/doc"
 279          exe "cd ".curdir
 280         endif
 281    endif
 282
 283    " update the data in the <GetLatestVimScripts.dat> file
 284    let modline=scriptid." ".latestsrcid." ".cmmnt
 285    call setline(line("."),modline)
 286 "   call Decho("modline<".modline."> (updated GetLatestVimScripts.dat file)")
 287   endif
 288
 289  " restore options
 290   let &t_ti= t_ti
 291   let &t_te= t_te
 292   let &rs  = rs
 293
 294 "  call Dret("GetOneScript")
 295 endfun
 296
 297 " ---------------------------------------------------------------------
 298 " GetLatestVimScripts: this function gets the latest versions of {{{1
 299 " scripts based on the list in
 300 "
 301 "   (first dir in runtimepath)/GetLatest/GetLatestVimScripts.dat
 302 fun! <SID>GetLatestVimScripts()
 303 "  call Dfunc("GetLatestVimScripts() autoinstall<".s:autoinstall.">")
 304
 305 " insure that wget is executable
 306   if executable(g:GetLatestVimScripts_wget) != 1
 307    echoerr "GetLatestVimScripts needs ".g:GetLatestVimScripts_wget." which apparently is not available on your system"
 308 "   call Dret("GetLatestVimScripts : wget not executable/availble")
 309    return
 310   endif
 311
 312   " Find the .../GetLatest sudirectory under the runtimepath
 313   let rtplist= &rtp
 314   while rtplist != ""
 315    let datadir= substitute(rtplist,',.*$','','e')."/GetLatest"
 316    if isdirectory(datadir)
 317 "       call Decho("found directory<".datadir.">")
 318     break
 319    endif
 320    unlet datadir
 321    if rtplist =~ ','
 322     let rtplist= substitute(rtplist,'^.\{-},','','e')
 323    else
 324         let rtplist= ""
 325    endif
 326   endwhile
 327
 328   " Sanity checks: readability and writability
 329   if !exists("datadir")
 330    echoerr "Unable to find a GetLatest subdirectory on your runtimepath"
 331 "   call Dret("GetLatestVimScripts : unable to find a GetLatest subdirectory")
 332    return
 333   endif
 334   if filewritable(datadir) != 2
 335    echoerr "Your ".datadir." isn't writable"
 336 "   call Dret("GetLatestVimScripts : non-writable directory<".datadir.">")
 337    return
 338   endif
 339   let datafile= datadir."/GetLatestVimScripts.dat"
 340   if !filereadable(datafile)
 341    echoerr "Your data file<".datafile."> isn't readable"
 342 "   call Dret("GetLatestVimScripts : non-readable datafile<".datafile.">")
 343    return
 344   endif
 345   if !filewritable(datafile)
 346    echoerr "Your data file<".datafile."> isn't writable"
 347 "   call Dret("GetLatestVimScripts : non-writable datafile<".datafile.">")
 348    return
 349   endif
 350 "  call Decho("datadir  <".datadir.">")
 351 "  call Decho("datafile <".datafile.">")
 352
 353   " don't let any events interfere (like winmanager's, taglist's, etc)
 354   let eikeep= &ei
 355   set ei=all
 356
 357   " record current directory, change to datadir, open split window with
 358   " datafile
 359   let origdir= getcwd()
 360   exe "cd ".escape(substitute(datadir,'\','/','ge'),"|[]*'\" #")
 361   split
 362   exe "e ".escape(substitute(datafile,'\','/','ge'),"|[]*'\" #")
 363   res 1000
 364   let s:downloads = 0
 365   let s:downerrors= 0
 366
 367   " Check on dependencies mentioned in plugins
 368 "  call Decho(" ")
 369 "  call Decho("searching plugins for GetLatestVimScripts dependencies")
 370   let lastline    = line("$")
 371   let plugins     = globpath(&rtp,"plugin/*.vim")
 372   let foundscript = 0
 373
 374 "  call Decho("plugins<".plugins."> lastline#".lastline)
 375   while plugins != ""
 376    let plugin = substitute(plugins,'\n.*$','','e')
 377    let plugins= (plugins =~ '\n')? substitute(plugins,'^.\{-}\n\(.*\)$','\1','e') : ""
 378    $
 379 "   call Decho(".dependency checking<".plugin."> line$=".line("$"))
 380    exe "silent r ".plugin
 381    while search('^"\s\+GetLatestVimScripts:\s\+\d\+\s\+\d\+','W') != 0
 382     let newscript= substitute(getline("."),'^"\s\+GetLatestVimScripts:\s\+\d\+\s\+\d\+\s\+\(.*\)$','\1','e')
 383     let llp1     = lastline+1
 384
 385         if newscript !~ '^"'
 386          " found a "GetLatestVimScripts: # #" line in the script; check if its already in the datafile
 387          let curline     = line(".")
 388          let noai_script = substitute(newscript,'\s*:AutoInstall:\s*','','e')
 389          exe llp1
 390          let srchline    = search('\<'.noai_script.'\>','bW')
 391 "        call Decho("..newscript<".newscript."> noai_script<".noai_script."> srch=".srchline." lastline=".lastline)
 392
 393          if srchline == 0
 394           " found a new script to permanently include in the datafile
 395           let keep_rega   = @a
 396           let @a          = substitute(getline(curline),'^"\s\+GetLatestVimScripts:\s\+','','')
 397           exe lastline."put a"
 398           echomsg "Appending <".@a."> to ".datafile." for ".newscript
 399 "         call Decho("..APPEND (".noai_script.")<".@a."> to GetLatestVimScripts.dat")
 400           let @a          = keep_rega
 401           let lastline    = llp1
 402           let curline     = curline     + 1
 403           let foundscript = foundscript + 1
 404 "        else   " Decho
 405 "         call Decho("..found <".noai_script."> (already in datafile at line#".srchline.")")
 406          endif
 407
 408          let curline = curline + 1
 409          exe curline
 410         endif
 411
 412    endwhile
 413    let llp1= lastline + 1
 414 "   call Decho(".deleting lines: ".llp1.",$d")
 415    exe "silent! ".llp1.",$d"
 416   endwhile
 417
 418   if foundscript == 0
 419    set nomod
 420   endif
 421
 422   " Check on out-of-date scripts using GetLatest/GetLatestVimScripts.dat
 423   set lz
 424 "  call Decho(" --- end of dependency checking loop --- ")
 425 "  call Decho("call GetOneScript on lines at end of datafile<".datafile.">")
 426   1
 427   /^-----/,$g/^\s*\d/call <SID>GetOneScript()
 428
 429   " Final report (an echomsg)
 430   try
 431    silent! ?^-------?
 432   catch /^Vim\%((\a\+)\)\=:E114/
 433 "   call Dret("GetLatestVimScripts : nothing done!")
 434    return
 435   endtry
 436   exe "norm! kz\<CR>"
 437   let s:msg = ""
 438   if s:downloads == 1
 439   let s:msg = "Downloaded one updated script to <".datadir.">"
 440   elseif s:downloads == 2
 441    let s:msg= "Downloaded two updated scripts to <".datadir.">"
 442   elseif s:downloads > 1
 443    let s:msg= "Downloaded ".s:downloads." updated scripts to <".datadir.">"
 444   else
 445    let s:msg= "Everything was already current"
 446   endif
 447   if s:downerrors > 0
 448    let s:msg= s:msg." (".s:downerrors." downloading errors)"
 449   endif
 450   echomsg s:msg
 451   " save the file
 452   if &mod
 453    wq
 454   else
 455    q
 456   endif
 457
 458   " restore events and current directory
 459   exe "cd ".escape(substitute(origdir,'\','/','ge'),"|[]*'\" #")
 460   let &ei= eikeep
 461   set nolz
 462 "  call Dret("GetLatestVimScripts : did ".s:downloads." downloads")
 463 endfun
 464 " ---------------------------------------------------------------------
 465
 466 " Restore Options: {{{1
 467 let &fo = s:keepfo
 468 let &cpo= s:keepcpo
 469
 470 " vim: ts=8 sts=2 fdm=marker nowrap