runtime/syntax/mailaliases.vim

   1 " Vim syntax file
   2 " Language:         aliases(5) local alias database file
   3 " Maintainer:       Nikolai Weibull <nikolai@bitwi.se>
   4 " Latest Revision:  2008-04-14
   5
   6 if exists("b:current_syntax")
   7   finish
   8 endif
   9
  10 let s:cpo_save = &cpo
  11 set cpo&vim
  12
  13 syn keyword mailaliasesTodo         contained TODO FIXME XXX NOTE
  14
  15 syn region  mailaliasesComment      display oneline start='^\s*#' end='$'
  16                                     \ contains=mailaliasesTodo,@Spell
  17
  18 syn match   mailaliasesBegin        display '^'
  19                                     \ nextgroup=mailaliasesName,
  20                                     \ mailaliasesComment
  21
  22 syn match   mailaliasesName         contained '[[:alnum:]\._-]\+'
  23                                     \ nextgroup=mailaliasesColon
  24
  25 syn region  mailaliasesName         contained oneline start=+"+
  26                                     \ skip=+\\\\\|\\"+ end=+"+
  27                                     \ nextgroup=mailaliasesColon
  28
  29 syn match   mailaliasesColon        contained ':'
  30                                     \ nextgroup=@mailaliasesValue
  31                                     \ skipwhite skipnl
  32
  33 syn cluster mailaliasesValue        contains=mailaliasesValueAddress,
  34                                     \ mailaliasesValueFile,
  35                                     \ mailaliasesValueCommand,
  36                                     \ mailaliasesValueInclude
  37
  38 syn match   mailaliasesValueAddress contained '[^ \t/|,]\+'
  39                                     \ nextgroup=mailaliasesValueSep
  40                                     \ skipwhite skipnl
  41
  42 syn match   mailaliasesValueFile    contained '/[^,]*'
  43                                     \ nextgroup=mailaliasesValueSep
  44                                     \ skipwhite skipnl
  45
  46 syn match   mailaliasesValueCommand contained '|[^,]*'
  47                                     \ nextgroup=mailaliasesValueSep
  48                                     \ skipwhite skipnl
  49
  50 syn match   mailaliasesValueInclude contained ':include:[^,]*'
  51                                     \ nextgroup=mailaliasesValueSep
  52                                     \ skipwhite skipnl
  53
  54 syn match   mailaliasesValueSep     contained ','
  55                                     \ nextgroup=@mailaliasesValue
  56                                     \ skipwhite skipnl
  57
  58 hi def link mailaliasesTodo         Todo
  59 hi def link mailaliasesComment      Comment
  60 hi def link mailaliasesName         Identifier
  61 hi def link mailaliasesColon        Delimiter
  62 hi def link mailaliasesValueAddress String
  63 hi def link mailaliasesValueFile    String
  64 hi def link mailaliasesValueCommand String
  65 hi def link mailaliasesValueInclude PreProc
  66 hi def link mailaliasesValueSep     Delimiter
  67
  68 let b:current_syntax = "mailaliases"
  69
  70 let &cpo = s:cpo_save
  71 unlet s:cpo_save