| blob | e099491ae4a6373350dd9194a1f076d46af57656 |
1 *map.txt* For Vim version 7.1. Last change: 2007 May 11
4 VIM REFERENCE MANUAL by Bram Moolenaar
7 Key mapping, abbreviations and user-defined commands.
9 This subject is introduced in sections |05.3|, |24.7| and |40.1| of the user
10 manual.
12 1. Key mapping |key-mapping|
13 1.1 MAP COMMANDS |:map-commands|
14 1.2 Special arguments |:map-arguments|
15 1.3 Mapping and modes |:map-modes|
16 1.4 Listing mappings |map-listing|
17 1.5 Mapping special keys |:map-special-keys|
18 1.6 Special characters |:map-special-chars|
19 1.7 What keys to map |map-which-keys|
20 1.8 Examples |map-examples|
21 1.9 Using mappings |map-typing|
22 1.10 Mapping alt-keys |:map-alt-keys|
23 1.11 Mapping an operator |:map-operator|
24 2. Abbreviations |abbreviations|
25 3. Local mappings and functions |script-local|
26 4. User-defined commands |user-commands|
28 ==============================================================================
29 1. Key mapping *key-mapping* *mapping* *macro*
31 Key mapping is used to change the meaning of typed keys. The most common use
32 is to define a sequence commands for a function key. Example: >
34 :map <F2> a<C-R>=strftime("%c")<CR><Esc>
36 This appends the current date and time after the cursor (in <> notation |<>|).
39 1.1 MAP COMMANDS *:map-commands*
41 There are commands to enter new mappings, remove mappings and list mappings.
42 See |map-overview| for the various forms of "map" and their relationships with
43 modes.
45 {lhs} means left-hand-side *{lhs}*
46 {rhs} means right-hand-side *{rhs}*
48 :map {lhs} {rhs} |mapmode-nvo| *:map*
49 :nm[ap] {lhs} {rhs} |mapmode-n| *:nm* *:nmap*
50 :vm[ap] {lhs} {rhs} |mapmode-v| *:vm* *:vmap*
51 :xm[ap] {lhs} {rhs} |mapmode-x| *:xm* *:xmap*
52 :smap {lhs} {rhs} |mapmode-s| *:smap*
53 :om[ap] {lhs} {rhs} |mapmode-o| *:om* *:omap*
54 :map! {lhs} {rhs} |mapmode-ic| *:map!*
55 :im[ap] {lhs} {rhs} |mapmode-i| *:im* *:imap*
56 :lm[ap] {lhs} {rhs} |mapmode-l| *:lm* *:lmap*
57 :cm[ap] {lhs} {rhs} |mapmode-c| *:cm* *:cmap*
58 Map the key sequence {lhs} to {rhs} for the modes
59 where the map command applies. The result, including
60 {rhs}, is then further scanned for mappings. This
61 allows for nested and recursive use of mappings.
64 :no[remap] {lhs} {rhs} |mapmode-nvo| *:no* *:noremap*
65 :nn[oremap] {lhs} {rhs} |mapmode-n| *:nn* *:nnoremap*
66 :vn[oremap] {lhs} {rhs} |mapmode-v| *:vn* *:vnoremap*
67 :xn[oremap] {lhs} {rhs} |mapmode-x| *:xn* *:xnoremap*
68 :snor[emap] {lhs} {rhs} |mapmode-s| *:snor* *:snoremap*
69 :ono[remap] {lhs} {rhs} |mapmode-o| *:ono* *:onoremap*
70 :no[remap]! {lhs} {rhs} |mapmode-ic| *:no!* *:noremap!*
71 :ino[remap] {lhs} {rhs} |mapmode-i| *:ino* *:inoremap*
72 :ln[oremap] {lhs} {rhs} |mapmode-l| *:ln* *:lnoremap*
73 :cno[remap] {lhs} {rhs} |mapmode-c| *:cno* *:cnoremap*
74 Map the key sequence {lhs} to {rhs} for the modes
75 where the map command applies. Disallow mapping of
76 {rhs}, to avoid nested and recursive mappings. Often
77 used to redefine a command. {not in Vi}
80 :unm[ap] {lhs} |mapmode-nvo| *:unm* *:unmap*
81 :nun[map] {lhs} |mapmode-n| *:nun* *:nunmap*
82 :vu[nmap] {lhs} |mapmode-v| *:vu* *:vunmap*
83 :xu[nmap] {lhs} |mapmode-x| *:xu* *:xunmap*
84 :sunm[ap] {lhs} |mapmode-s| *:sunm* *:sunmap*
85 :ou[nmap] {lhs} |mapmode-o| *:ou* *:ounmap*
86 :unm[ap]! {lhs} |mapmode-ic| *:unm!* *:unmap!*
87 :iu[nmap] {lhs} |mapmode-i| *:iu* *:iunmap*
88 :lu[nmap] {lhs} |mapmode-l| *:lu* *:lunmap*
89 :cu[nmap] {lhs} |mapmode-c| *:cu* *:cunmap*
90 Remove the mapping of {lhs} for the modes where the
91 map command applies. The mapping may remain defined
92 for other modes where it applies.
93 Note: Trailing spaces are included in the {lhs}. This
94 unmap does NOT work: >
95 :map @@ foo
96 :unmap @@ | print
98 :mapc[lear] |mapmode-nvo| *:mapc* *:mapclear*
99 :nmapc[lear] |mapmode-n| *:nmapc* *:nmapclear*
100 :vmapc[lear] |mapmode-v| *:vmapc* *:vmapclear*
101 :xmapc[lear] |mapmode-x| *:xmapc* *:xmapclear*
102 :smapc[lear] |mapmode-s| *:smapc* *:smapclear*
103 :omapc[lear] |mapmode-o| *:omapc* *:omapclear*
104 :mapc[lear]! |mapmode-ic| *:mapc!* *:mapclear!*
105 :imapc[lear] |mapmode-i| *:imapc* *:imapclear*
106 :lmapc[lear] |mapmode-l| *:lmapc* *:lmapclear*
107 :cmapc[lear] |mapmode-c| *:cmapc* *:cmapclear*
108 Remove ALL mappings for the modes where the map
109 command applies. {not in Vi}
110 Warning: This also removes the default mappings.
112 :map |mapmode-nvo|
113 :nm[ap] |mapmode-n|
114 :vm[ap] |mapmode-v|
115 :xm[ap] |mapmode-x|
116 :sm[ap] |mapmode-s|
117 :om[ap] |mapmode-o|
118 :map! |mapmode-ic|
119 :im[ap] |mapmode-i|
120 :lm[ap] |mapmode-l|
121 :cm[ap] |mapmode-c|
122 List all key mappings for the modes where the map
123 command applies. Note that ":map" and ":map!" are
124 used most often, because they include the other modes.
126 :map {lhs} |mapmode-nvo| *:map_l*
127 :nm[ap] {lhs} |mapmode-n| *:nmap_l*
128 :vm[ap] {lhs} |mapmode-v| *:vmap_l*
129 :xm[ap] {lhs} |mapmode-x| *:xmap_l*
130 :sm[ap] {lhs} |mapmode-s| *:smap_l*
131 :om[ap] {lhs} |mapmode-o| *:omap_l*
132 :map! {lhs} |mapmode-ic| *:map_l!*
133 :im[ap] {lhs} |mapmode-i| *:imap_l*
134 :lm[ap] {lhs} |mapmode-l| *:lmap_l*
135 :cm[ap] {lhs} |mapmode-c| *:cmap_l*
136 List the key mappings for the key sequences starting
137 with {lhs} in the modes where the map command applies.
138 {not in Vi}
140 These commands are used to map a key or key sequence to a string of
141 characters. You can use this to put command sequences under function keys,
142 translate one key into another, etc. See |:mkexrc| for how to save and
143 restore the current mappings.
145 *map-ambiguous*
146 When two mappings start with the same sequence of characters, they are
147 ambiguous. Example: >
148 :imap aa foo
149 :imap aaa bar
150 When Vim has read "aa", it will need to get another character to be able to
151 decide if "aa" or "aaa" should be mapped. This means that after typing "aa"
152 that mapping won't get expanded yet, Vim is waiting for another character.
153 If you type a space, then "foo" will get inserted, plus the space. If you
154 type "a", then "bar" will get inserted.
155 {Vi does not allow ambiguous mappings}
158 1.2 SPECIAL ARGUMENTS *:map-arguments*
160 "<buffer>", "<silent>", "<special>", "<script>", "<expr>" and "<unique>" can
161 be used in any order. They must appear right after the command, before any
162 other arguments.
164 *:map-local* *:map-<buffer>* *E224* *E225*
165 If the first argument to one of these commands is "<buffer>" it will apply to
166 mappings locally to the current buffer only. Example: >
167 :map <buffer> ,w /[.,;]<CR>
168 Then you can map ",w" to something else in another buffer: >
169 :map <buffer> ,w /[#&!]<CR>
170 The local buffer mappings are used before the global ones.
171 The "<buffer>" argument can also be used to clear mappings: >
172 :unmap <buffer> ,w
173 :mapclear <buffer>
174 Local mappings are also cleared when a buffer is deleted, but not when it is
175 unloaded. Just like local option values.
177 *:map-<silent>* *:map-silent*
178 To define a mapping which will not be echoed on the command line, add
179 "<silent>" as the first argument. Example: >
180 :map <silent> ,h /Header<CR>
181 The search string will not be echoed when using this mapping. Messages from
182 the executed command are still given though. To shut them up too, add a
183 ":silent" in the executed command: >
184 :map <silent> ,h :exe ":silent normal /Header\r"<CR>
185 Prompts will still be given, e.g., for inputdialog().
186 Using "<silent>" for an abbreviation is possible, but will cause redrawing of
187 the command line to fail.
189 *:map-<special>* *:map-special*
190 Define a mapping with <> notation for special keys, even though the "<" flag
191 may appear in 'cpoptions'. This is useful if the side effect of setting
192 'cpoptions' is not desired. Example: >
193 :map <special> <F12> /Header<CR>
194 <
195 *:map-<script>* *:map-script*
196 If the first argument to one of these commands is "<script>" and it is used to
197 define a new mapping or abbreviation, the mapping will only remap characters
198 in the {rhs} using mappings that were defined local to a script, starting with
199 "<SID>". This can be used to avoid that mappings from outside a script
200 interfere (e.g., when CTRL-V is remapped in mswin.vim), but do use other
201 mappings defined in the script.
202 Note: ":map <script>" and ":noremap <script>" do the same thing. The
203 "<script>" overrules the command name. Using ":noremap <script>" is
204 preferred, because it's clearer that remapping is (mostly) disabled.
206 *:map-<unique>* *E226* *E227*
207 If the first argument to one of these commands is "<unique>" and it is used to
208 define a new mapping or abbreviation, the command will fail if the mapping or
209 abbreviation already exists. Example: >
210 :map <unique> ,w /[#&!]<CR>
211 When defining a local mapping, there will also be a check if a global map
212 already exists which is equal.
213 Example of what will fail: >
214 :map ,w /[#&!]<CR>
215 :map <buffer> <unique> ,w /[.,;]<CR>
216 If you want to map a key and then have it do what it was originally mapped to,
217 have a look at |maparg()|.
219 *:map-<expr>* *:map-expression*
220 If the first argument to one of these commands is "<expr>" and it is used to
221 define a new mapping or abbreviation, the argument is an expression. The
222 expression is evaluated to obtain the {rhs} that is used. Example: >
223 :inoremap <expr> . InsertDot()
224 The result of the InsertDot() function will be inserted. It could check the
225 text before the cursor and start omni completion when some condition is met.
227 Be very careful about side effects! The expression is evaluated while
228 obtaining characters, you may very well make the command dysfunctional.
229 For this reason the following is blocked:
230 - Changing the buffer text |textlock|.
231 - Editing another buffer.
232 - The |:normal| command.
233 - Moving the cursor is allowed, but it is restored afterwards.
234 - You can use getchar(), but the existing typeahead isn't seen and new
235 typeahead is discarded.
236 If you want the mapping to do any of these let the returned characters do
237 that.
239 Here is an example that inserts a list number that increases: >
240 let counter = 0
241 inoremap <expr> <C-L> ListItem()
242 inoremap <expr> <C-R> ListReset()
244 func ListItem()
245 let g:counter += 1
246 return g:counter . '. '
247 endfunc
249 func ListReset()
250 let g:counter = 0
251 return ''
252 endfunc
254 CTRL-L inserts the next number, CTRL-R resets the count. CTRL-R returns an
255 empty string, so that nothing is inserted.
257 Note that there are some tricks to make special keys work and escape CSI bytes
258 in the text. The |:map| command also does this, thus you must avoid that it
259 is done twice. This does not work: >
260 :imap <expr> <F3> "<Char-0x611B>"
261 Because the <Char- sequence is escaped for being a |:imap| argument and then
262 again for using <expr>. This does work: >
263 :imap <expr> <F3> "\u611B"
264 Using 0x80 as a single byte before other text does not work, it will be seen
265 as a special key.
268 1.3 MAPPING AND MODES *:map-modes*
270 There are five sets of mappings
271 - For Normal mode: When typing commands.
272 - For Visual mode: When typing commands while the Visual area is highlighted.
273 - For Operator-pending mode: When an operator is pending (after "d", "y", "c",
274 etc.). Example: ":omap { w" makes "y{" work like "yw" and "d{" like "dw".
275 - For Insert mode. These are also used in Replace mode.
276 - For Command-line mode: When entering a ":" or "/" command.
278 Special case: While typing a count for a command in Normal mode, mapping zero
279 is disabled. This makes it possible to map zero without making it impossible
280 to type a count with a zero.
282 *map-overview* *map-modes*
283 Overview of which map command works in which mode:
285 *mapmode-nvo* *mapmode-n* *mapmode-v* *mapmode-o*
286 commands: modes: ~
287 Normal Visual+Select Operator-pending ~
288 :map :noremap :unmap :mapclear yes yes yes
289 :nmap :nnoremap :nunmap :nmapclear yes - -
290 :vmap :vnoremap :vunmap :vmapclear - yes -
291 :omap :onoremap :ounmap :omapclear - - yes
293 :nunmap can also be used outside of a monastery.
294 *mapmode-x* *mapmode-s*
295 Some commands work both in Visual and Select mode, some in only one. Note
296 that quite often "Visual" is mentioned where both Visual and Select mode
297 apply. |Select-mode-mapping|
299 commands: modes: ~
300 Visual Select ~
301 :vmap :vnoremap :vunmap :vmapclear yes yes
302 :xmap :xnoremap :xunmap :xmapclear yes -
303 :smap :snoremap :sunmap :smapclear - yes
305 *mapmode-ic* *mapmode-i* *mapmode-c* *mapmode-l*
306 Some commands work both in Insert mode and Command-line mode, some not:
308 commands: modes: ~
309 Insert Command-line Lang-Arg ~
310 :map! :noremap! :unmap! :mapclear! yes yes -
311 :imap :inoremap :iunmap :imapclear yes - -
312 :cmap :cnoremap :cunmap :cmapclear - yes -
313 :lmap :lnoremap :lunmap :lmapclear yes* yes* yes*
315 The original Vi did not have separate mappings for
316 Normal/Visual/Operator-pending mode and for Insert/Command-line mode.
317 Therefore the ":map" and ":map!" commands enter and display mappings for
318 several modes. In Vim you can use the ":nmap", ":vmap", ":omap", ":cmap" and
319 ":imap" commands to enter mappings for each mode separately.
321 To enter a mapping for Normal and Visual mode, but not Operator-pending mode,
322 first define it for all three modes, then unmap it for Operator-pending mode:
323 :map xx something-difficult
324 :ounmap xx
325 Likewise for a mapping for Visual and Operator-pending mode or Normal and
326 Operator-pending mode.
328 *language-mapping*
329 ":lmap" defines a mapping that applies to:
330 - Insert mode
331 - Command-line mode
332 - when entering a search pattern
333 - the argument of the commands that accept a text character, such as "r" and
334 "f"
335 - for the input() line
336 Generally: Whenever a character is to be typed that is part of the text in the
337 buffer, not a Vim command character. "Lang-Arg" isn't really another mode,
338 it's just used here for this situation.
339 The simplest way to load a set of related language mappings is by using the
340 'keymap' option. See |45.5|.
341 In Insert mode and in Command-line mode the mappings can be disabled with
342 the CTRL-^ command |i_CTRL-^| |c_CTRL-^|. When starting to enter a normal
343 command line (not a search pattern) the mappings are disabled until a CTRL-^
344 is typed. The state last used is remembered for Insert mode and Search
345 patterns separately. The state for Insert mode is also used when typing a
346 character as an argument to command like "f" or "t".
347 Language mappings will never be applied to already mapped characters. They
348 are only used for typed characters. This assumes that the language mapping
349 was already done when typing the mapping.
352 1.4 LISTING MAPPINGS *map-listing*
354 When listing mappings the characters in the first two columns are:
356 CHAR MODE ~
357 <Space> Normal, Visual, Select and Operator-pending
358 n Normal
359 v Visual and Select
360 s Select
361 x Visual
362 o Operator-pending
363 ! Insert and Command-line
364 i Insert
365 l ":lmap" mappings for Insert, Command-line and Lang-Arg
366 c Command-line
368 Just before the {rhs} a special character can appear:
369 * indicates that it is not remappable
370 & indicates that only script-local mappings are remappable
371 @ indicates a buffer-local mapping
373 Everything from the first non-blank after {lhs} up to the end of the line
374 (or '|') is considered to be part of {rhs}. This allows the {rhs} to end
375 with a space.
377 Note: When using mappings for Visual mode, you can use the "'<" mark, which
378 is the start of the last selected Visual area in the current buffer |'<|.
380 *:map-verbose*
381 When 'verbose' is non-zero, listing a key map will also display where it was
382 last defined. Example: >
384 :verbose map <C-W>*
385 n <C-W>* * <C-W><C-S>*
386 Last set from /home/abcd/.vimrc
388 See |:verbose-cmd| for more information.
391 1.5 MAPPING SPECIAL KEYS *:map-special-keys*
393 There are three ways to map a special key:
394 1. The Vi-compatible method: Map the key code. Often this is a sequence that
395 starts with <Esc>. To enter a mapping like this you type ":map " and then
396 you have to type CTRL-V before hitting the function key. Note that when
397 the key code for the key is in the termcap (the t_ options), it will
398 automatically be translated into the internal code and become the second
399 way of mapping (unless the 'k' flag is included in 'cpoptions').
400 2. The second method is to use the internal code for the function key. To
401 enter such a mapping type CTRL-K and then hit the function key, or use
402 the form "#1", "#2", .. "#9", "#0", "<Up>", "<S-Down>", "<S-F7>", etc.
403 (see table of keys |key-notation|, all keys from <Up> can be used). The
404 first ten function keys can be defined in two ways: Just the number, like
405 "#2", and with "<F>", like "<F2>". Both stand for function key 2. "#0"
406 refers to function key 10, defined with option 't_f10', which may be
407 function key zero on some keyboards. The <> form cannot be used when
408 'cpoptions' includes the '<' flag.
409 3. Use the termcap entry, with the form <t_xx>, where "xx" is the name of the
410 termcap entry. Any string entry can be used. For example: >
411 :map <t_F3> G
412 < Maps function key 13 to "G". This does not work if 'cpoptions' includes
413 the '<' flag.
415 The advantage of the second and third method is that the mapping will work on
416 different terminals without modification (the function key will be
417 translated into the same internal code or the actual key code, no matter what
418 terminal you are using. The termcap must be correct for this to work, and you
419 must use the same mappings).
421 DETAIL: Vim first checks if a sequence from the keyboard is mapped. If it
422 isn't the terminal key codes are tried (see |terminal-options|). If a
423 terminal code is found it is replaced with the internal code. Then the check
424 for a mapping is done again (so you can map an internal code to something
425 else). What is written into the script file depends on what is recognized.
426 If the terminal key code was recognized as a mapping the key code itself is
427 written to the script file. If it was recognized as a terminal code the
428 internal code is written to the script file.
431 1.6 SPECIAL CHARACTERS *:map-special-chars*
432 *map_backslash*
433 Note that only CTRL-V is mentioned here as a special character for mappings
434 and abbreviations. When 'cpoptions' does not contain 'B', a backslash can
435 also be used like CTRL-V. The <> notation can be fully used then |<>|. But
436 you cannot use "<C-V>" like CTRL-V to escape the special meaning of what
437 follows.
439 To map a backslash, or use a backslash literally in the {rhs}, the special
440 sequence "<Bslash>" can be used. This avoids the need to double backslashes
441 when using nested mappings.
443 *map_CTRL-C*
444 Using CTRL-C in the {lhs} is possible, but it will only work when Vim is
445 waiting for a key, not when Vim is busy with something. When Vim is busy
446 CTRL-C interrupts/breaks the command.
447 When using the GUI version on MS-Windows CTRL-C can be mapped to allow a Copy
448 command to the clipboard. Use CTRL-Break to interrupt Vim.
450 *map_space_in_lhs*
451 To include a space in {lhs} precede it with a CTRL-V (type two CTRL-Vs for
452 each space).
453 *map_space_in_rhs*
454 If you want a {rhs} that starts with a space, use "<Space>". To be fully Vi
455 compatible (but unreadable) don't use the |<>| notation, precede {rhs} with a
456 single CTRL-V (you have to type CTRL-V two times).
457 *map_empty_rhs*
458 You can create an empty {rhs} by typing nothing after a single CTRL-V (you
459 have to type CTRL-V two times). Unfortunately, you cannot do this in a vimrc
460 file.
461 *<Nop>*
462 A easier way to get a mapping that doesn't produce anything, is to use "<Nop>"
463 for the {rhs}. This only works when the |<>| notation is enabled. For
464 example, to make sure that function key 8 does nothing at all: >
465 :map <F8> <Nop>
466 :map! <F8> <Nop>
467 <
468 *map-multibyte*
469 It is possible to map multibyte characters, but only the whole character. You
470 cannot map the first byte only. This was done to prevent problems in this
471 scenario: >
472 :set encoding=latin1
473 :imap <M-C> foo
474 :set encoding=utf-8
475 The mapping for <M-C> is defined with the latin1 encoding, resulting in a 0xc3
476 byte. If you type the character á (0xea <M-a>) in UTF-8 encoding this is the
477 two bytes 0xc3 0xa1. You don't want the 0xc3 byte to be mapped then,
478 otherwise it would be impossible to type the á character.
480 *<Leader>* *mapleader*
481 To define a mapping which uses the "mapleader" variable, the special string
482 "<Leader>" can be used. It is replaced with the string value of "mapleader".
483 If "mapleader" is not set or empty, a backslash is used instead. Example: >
484 :map <Leader>A oanother line<Esc>
485 Works like: >
486 :map \A oanother line<Esc>
487 But after: >
488 :let mapleader = ","
489 It works like: >
490 :map ,A oanother line<Esc>
492 Note that the value of "mapleader" is used at the moment the mapping is
493 defined. Changing "mapleader" after that has no effect for already defined
494 mappings.
496 *<LocalLeader>* *maplocalleader*
497 Just like <Leader>, except that it uses "maplocalleader" instead of
498 "mapleader". <LocalLeader> is to be used for mappings which are local to a
499 buffer. Example: >
500 :map <LocalLeader>q \DoItNow
501 <
502 In a global plugin <Leader> should be used and in a filetype plugin
503 <LocalLeader>. "mapleader" and "maplocalleader" can be equal. Although, if
504 you make them different, there is a smaller chance of mappings from global
505 plugins to clash with mappings for filetype plugins. For example, you could
506 keep "mapleader" at the default backslash, and set "maplocalleader" to an
507 underscore.
509 *map-<SID>*
510 In a script the special key name "<SID>" can be used to define a mapping
511 that's local to the script. See |<SID>| for details.
513 *<Plug>*
514 The special key name "<Plug>" can be used for an internal mapping, which is
515 not to be matched with any key sequence. This is useful in plugins
516 |using-<Plug>|.
518 *<Char>* *<Char->*
519 To map a character by its decimal, octal or hexadecimal number the <Char>
520 construct can be used:
521 <Char-123> character 123
522 <Char-033> character 27
523 <Char-0x7f> character 127
524 This is useful to specify a (multi-byte) character in a 'keymap' file.
525 Upper and lowercase differences are ignored.
527 *map-comments*
528 It is not possible to put a comment after these commands, because the '"'
529 character is considered to be part of the {lhs} or {rhs}.
531 *map_bar*
532 Since the '|' character is used to separate a map command from the next
533 command, you will have to do something special to include a '|' in {rhs}.
534 There are three methods:
535 use works when example ~
536 <Bar> '<' is not in 'cpoptions' :map _l :!ls <Bar> more^M
537 \| 'b' is not in 'cpoptions' :map _l :!ls \| more^M
538 ^V| always, in Vim and Vi :map _l :!ls ^V| more^M
540 (here ^V stands for CTRL-V; to get one CTRL-V you have to type it twice; you
541 cannot use the <> notation "<C-V>" here).
543 All three work when you use the default setting for 'cpoptions'.
545 When 'b' is present in 'cpoptions', "\|" will be recognized as a mapping
546 ending in a '\' and then another command. This is Vi compatible, but
547 illogical when compared to other commands.
549 *map_return*
550 When you have a mapping that contains an Ex command, you need to put a line
551 terminator after it to have it executed. The use of <CR> is recommended for
552 this (see |<>|). Example: >
553 :map _ls :!ls -l %<CR>:echo "the end"<CR>
555 To avoid mapping of the characters you type in insert or Command-line mode,
556 type a CTRL-V first. The mapping in Insert mode is disabled if the 'paste'
557 option is on.
559 Note that when an error is encountered (that causes an error message or beep)
560 the rest of the mapping is not executed. This is Vi-compatible.
562 Note that the second character (argument) of the commands @zZtTfF[]rm'`"v
563 and CTRL-X is not mapped. This was done to be able to use all the named
564 registers and marks, even when the command with the same name has been
565 mapped.
568 1.7 WHAT KEYS TO MAP *map-which-keys*
570 If you are going to map something, you will need to choose which key(s) to use
571 for the {lhs}. You will have to avoid keys that are used for Vim commands,
572 otherwise you would not be able to use those commands anymore. Here are a few
573 suggestions:
574 - Function keys <F2>, <F3>, etc.. Also the shifted function keys <S-F1>,
575 <S-F2>, etc. Note that <F1> is already used for the help command.
576 - Meta-keys (with the ALT key pressed). |:map-alt-keys|
577 - Use the '_' or ',' character and then any other character. The "_" and ","
578 commands do exist in Vim (see |_| and |,|), but you probably never use them.
579 - Use a key that is a synonym for another command. For example: CTRL-P and
580 CTRL-N. Use an extra character to allow more mappings.
582 See the file "index" for keys that are not used and thus can be mapped without
583 losing any builtin function. You can also use ":help {key}^D" to find out if
584 a key is used for some command. ({key} is the specific key you want to find
585 out about, ^D is CTRL-D).
588 1.8 EXAMPLES *map-examples*
590 A few examples (given as you type them, for "<CR>" you type four characters;
591 the '<' flag must not be present in 'cpoptions' for this to work). >
593 :map <F3> o#include
594 :map <M-g> /foo<CR>cwbar<Esc>
595 :map _x d/END/e<CR>
596 :map! qq quadrillion questions
599 Multiplying a count
601 When you type a count before triggering a mapping, it's like the count was
602 typed before the {lhs}. For example, with this mapping: >
603 :map <F4> 3w
604 Typing 2<F4> will result in "23w". Thus not moving 2 * 3 words but 23 words.
605 If you want to multiply counts use the expression register: >
606 :map <F4> @='3w'<CR>
607 The part between quotes is the expression being executed. |@=|
610 1.9 USING MAPPINGS *map-typing*
612 Vim will compare what you type with the start of a mapped sequence. If there
613 is an incomplete match, it will get more characters until there either is a
614 complete match or until there is no match at all. Example: If you map! "qq",
615 the first 'q' will not appear on the screen until you type another
616 character. This is because Vim cannot know if the next character will be a
617 'q' or not. If the 'timeout' option is on (which is the default) Vim will
618 only wait for one second (or as long as specified with the 'timeoutlen'
619 option). After that it assumes that the 'q' is to be interpreted as such. If
620 you type slowly, or your system is slow, reset the 'timeout' option. Then you
621 might want to set the 'ttimeout' option.
623 *map-keys-fails*
624 There are situations where key codes might not be recognized:
625 - Vim can only read part of the key code. Mostly this is only the first
626 character. This happens on some Unix versions in an xterm.
627 - The key code is after character(s) that are mapped. E.g., "<F1><F1>" or
628 "g<F1>".
630 The result is that the key code is not recognized in this situation, and the
631 mapping fails. There are two actions needed to avoid this problem:
633 - Remove the 'K' flag from 'cpoptions'. This will make Vim wait for the rest
634 of the characters of the function key.
635 - When using <F1> to <F4> the actual key code generated may correspond to
636 <xF1> to <xF4>. There are mappings from <xF1> to <F1>, <xF2> to <F2>, etc.,
637 but these are not recognized after another half a mapping. Make sure the
638 key codes for <F1> to <F4> are correct: >
639 :set <F1>=<type CTRL-V><type F1>
640 < Type the <F1> as four characters. The part after the "=" must be done with
641 the actual keys, not the literal text.
642 Another solution is to use the actual key code in the mapping for the second
643 special key: >
644 :map <F1><Esc>OP :echo "yes"<CR>
645 Don't type a real <Esc>, Vim will recognize the key code and replace it with
646 <F1> anyway.
648 Another problem may be that when keeping ALT or Meta pressed the terminal
649 prepends ESC instead of setting the 8th bit. See |:map-alt-keys|.
651 *recursive_mapping*
652 If you include the {lhs} in the {rhs} you have a recursive mapping. When
653 {lhs} is typed, it will be replaced with {rhs}. When the {lhs} which is
654 included in {rhs} is encountered it will be replaced with {rhs}, and so on.
655 This makes it possible to repeat a command an infinite number of times. The
656 only problem is that the only way to stop this is by causing an error. The
657 macros to solve a maze uses this, look there for an example. There is one
658 exception: If the {rhs} starts with {lhs}, the first character is not mapped
659 again (this is Vi compatible).
660 For example: >
661 :map ab abcd
662 will execute the "a" command and insert "bcd" in the text. The "ab" in the
663 {rhs} will not be mapped again.
665 If you want to exchange the meaning of two keys you should use the :noremap
666 command. For example: >
667 :noremap k j
668 :noremap j k
669 This will exchange the cursor up and down commands.
671 With the normal :map command, when the 'remap' option is on, mapping takes
672 place until the text is found not to be a part of a {lhs}. For example, if
673 you use: >
674 :map x y
675 :map y x
676 Vim will replace x with y, and then y with x, etc. When this has happened
677 'maxmapdepth' times (default 1000), Vim will give the error message
678 "recursive mapping".
680 *:map-undo*
681 If you include an undo command inside a mapped sequence, this will bring the
682 text back in the state before executing the macro. This is compatible with
683 the original Vi, as long as there is only one undo command in the mapped
684 sequence (having two undo commands in a mapped sequence did not make sense
685 in the original Vi, you would get back the text before the first undo).
688 1.10 MAPPING ALT-KEYS *:map-alt-keys*
690 In the GUI Vim handles the Alt key itself, thus mapping keys with ALT should
691 always work. But in a terminal Vim gets a sequence of bytes and has to figure
692 out whether ALT was pressed or not.
694 By default Vim assumes that pressing the ALT key sets the 8th bit of a typed
695 character. Most decent terminals can work that way, such as xterm, aterm and
696 rxvt. If your <A-k> mappings don't work it might be that the terminal is
697 prefixing the character with an ESC character. But you can just as well type
698 ESC before a character, thus Vim doesn't know what happened (except for
699 checking the delay between characters, which is not reliable).
701 As of this writing, some mainstream terminals like gnome-terminal and konsole
702 use the ESC prefix. There doesn't appear a way to have them use the 8th bit
703 instead. Xterm should work well by default. Aterm and rxvt should work well
704 when started with the "--meta8" argument. You can also tweak resources like
705 "metaSendsEscape", "eightBitInput" and "eightBitOutput".
707 On the Linux console, this behavior can be toggled with the "setmetamode"
708 command. Bear in mind that not using an ESC prefix could get you in trouble
709 with other programs. You should make sure that bash has the "convert-meta"
710 option set to "on" in order for your Meta keybindings to still work on it
711 (it's the default readline behavior, unless changed by specific system
712 configuration). For that, you can add the line: >
714 set convert-meta on
716 to your ~/.inputrc file. If you're creating the file, you might want to use: >
718 $include /etc/inputrc
720 as the first line, if that file exists on your system, to keep global options.
721 This may cause a problem for entering special characters, such as the umlaut.
722 Then you should use CTRL-V before that character.
724 Bear in mind that convert-meta has been reported to have troubles when used in
725 UTF-8 locales. On terminals like xterm, the "metaSendsEscape" resource can be
726 toggled on the fly through the "Main Options" menu, by pressing Ctrl-LeftClick
727 on the terminal; that's a good last resource in case you want to send ESC when
728 using other applications but not when inside VIM.
731 1.11 MAPPING AN OPERATOR *:map-operator*
733 An operator is used before a {motion} command. To define your own operator
734 you must create mapping that first sets the 'operatorfunc' option and then
735 invoke the |g@| operator. After the user types the {motion} command the
736 specified function will be called.
738 *g@* *E774* *E775*
739 g@{motion} Call the function set by the 'operatorfunc' option.
740 The '[ mark is positioned at the start of the text
741 moved over by {motion}, the '] mark on the last
742 character of the text.
743 The function is called with one String argument:
744 "line" {motion} was |linewise|
745 "char" {motion} was |characterwise|
746 "block" {motion} was |blockwise-visual||
747 Although "block" would rarely appear, since it can
748 only result from Visual mode where "g@" is not useful.
749 {not available when compiled without the +eval
750 feature}
752 Here is an example that counts the number of spaces with <F4>: >
754 nmap <silent> <F4> :set opfunc=CountSpaces<CR>g@
755 vmap <silent> <F4> :<C-U>call CountSpaces(visualmode(), 1)<CR>
757 function! CountSpaces(type, ...)
758 let sel_save = &selection
759 let &selection = "inclusive"
760 let reg_save = @@
762 if a:0 " Invoked from Visual mode, use '< and '> marks.
763 silent exe "normal! `<" . a:type . "`>y"
764 elseif a:type == 'line'
765 silent exe "normal! '[V']y"
766 elseif a:type == 'block'
767 silent exe "normal! `[\<C-V>`]y"
768 else
769 silent exe "normal! `[v`]y"
770 endif
772 echomsg strlen(substitute(@@, '[^ ]', '', 'g'))
774 let &selection = sel_save
775 let @@ = reg_save
776 endfunction
778 Note that the 'selection' option is temporarily set to "inclusive" to be able
779 to yank exactly the right text by using Visual mode from the '[ to the ']
780 mark.
782 Also note that there is a separate mapping for Visual mode. It removes the
783 "'<,'>" range that ":" inserts in Visual mode and invokes the function with
784 visualmode() and an extra argument.
786 ==============================================================================
787 2. Abbreviations *abbreviations* *Abbreviations*
789 Abbreviations are used in Insert mode, Replace mode and Command-line mode.
790 If you enter a word that is an abbreviation, it is replaced with the word it
791 stands for. This can be used to save typing for often used long words. And
792 you can use it to automatically correct obvious spelling errors.
793 Examples:
795 :iab ms Microsoft
796 :iab tihs this
798 There are three types of abbreviations:
800 full-id The "full-id" type consists entirely of keyword characters (letters
801 and characters from 'iskeyword' option). This is the most common
802 abbreviation.
804 Examples: "foo", "g3", "-1"
806 end-id The "end-id" type ends in a keyword character, but all the other
807 characters are not keyword characters.
809 Examples: "#i", "..f", "$/7"
811 non-id The "non-id" type ends in a non-keyword character, the other
812 characters may be of any type, excluding space and tab. {this type
813 is not supported by Vi}
815 Examples: "def#", "4/7$"
817 Examples of strings that cannot be abbreviations: "a.b", "#def", "a b", "_$r"
819 An abbreviation is only recognized when you type a non-keyword character.
820 This can also be the <Esc> that ends insert mode or the <CR> that ends a
821 command. The non-keyword character which ends the abbreviation is inserted
822 after the expanded abbreviation. An exception to this is the character <C-]>,
823 which is used to expand an abbreviation without inserting any extra
824 characters.
826 Example: >
827 :ab hh hello
828 < "hh<Space>" is expanded to "hello<Space>"
829 "hh<C-]>" is expanded to "hello"
831 The characters before the cursor must match the abbreviation. Each type has
832 an additional rule:
834 full-id In front of the match is a non-keyword character, or this is where
835 the line or insertion starts. Exception: When the abbreviation is
836 only one character, it is not recognized if there is a non-keyword
837 character in front of it, other than a space or a tab.
839 end-id In front of the match is a keyword character, or a space or a tab,
840 or this is where the line or insertion starts.
842 non-id In front of the match is a space, tab or the start of the line or
843 the insertion.
845 Examples: ({CURSOR} is where you type a non-keyword character) >
846 :ab foo four old otters
847 < " foo{CURSOR}" is expanded to " four old otters"
848 " foobar{CURSOR}" is not expanded
849 "barfoo{CURSOR}" is not expanded
850 >
851 :ab #i #include
852 < "#i{CURSOR}" is expanded to "#include"
853 ">#i{CURSOR}" is not expanded
854 >
855 :ab ;; <endofline>
856 < "test;;" is not expanded
857 "test ;;" is expanded to "test <endofline>"
859 To avoid the abbreviation in insert mode: Type part of the abbreviation, exit
860 insert mode with <Esc>, re-enter insert mode with "a" and type the rest. Or
861 type CTRL-V before the character after the abbreviation.
862 To avoid the abbreviation in Command-line mode: Type CTRL-V twice somewhere in
863 the abbreviation to avoid it to be replaced. A CTRL-V in front of a normal
864 character is mostly ignored otherwise.
866 It is possible to move the cursor after an abbreviation: >
867 :iab if if ()<Left>
868 This does not work if 'cpoptions' includes the '<' flag. |<>|
870 You can even do more complicated things. For example, to consume the space
871 typed after an abbreviation: >
872 func Eatchar(pat)
873 let c = nr2char(getchar(0))
874 return (c =~ a:pat) ? '' : c
875 endfunc
876 iabbr <silent> if if ()<Left><C-R>=Eatchar('\s')<CR>
878 There are no default abbreviations.
880 Abbreviations are never recursive. You can use ":ab f f-o-o" without any
881 problem. But abbreviations can be mapped. {some versions of Vi support
882 recursive abbreviations, for no apparent reason}
884 Abbreviations are disabled if the 'paste' option is on.
886 *:abbreviate-local* *:abbreviate-<buffer>*
887 Just like mappings, abbreviations can be local to a buffer. This is mostly
888 used in a |filetype-plugin| file. Example for a C plugin file: >
889 :abb <buffer> FF for (i = 0; i < ; ++i)
890 <
891 *:ab* *:abbreviate*
892 :ab[breviate] list all abbreviations. The character in the first
893 column indicates the mode where the abbreviation is
894 used: 'i' for insert mode, 'c' for Command-line
895 mode, '!' for both. These are the same as for
896 mappings, see |map-listing|.
898 *:abbreviate-verbose*
899 When 'verbose' is non-zero, listing an abbreviation will also display where it
900 was last defined. Example: >
902 :verbose abbreviate
903 ! teh the
904 Last set from /home/abcd/vim/abbr.vim
906 See |:verbose-cmd| for more information.
908 :ab[breviate] {lhs} list the abbreviations that start with {lhs}
909 You may need to insert a CTRL-V (type it twice) to
910 avoid that a typed {lhs} is expanded, since
911 command-line abbreviations apply here.
913 :ab[breviate] [<expr>] {lhs} {rhs}
914 add abbreviation for {lhs} to {rhs}. If {lhs} already
915 existed it is replaced with the new {rhs}. {rhs} may
916 contain spaces.
917 See |:map-<expr>| for the optional <expr> argument.
919 *:una* *:unabbreviate*
920 :una[bbreviate] {lhs} Remove abbreviation for {lhs} from the list. If none
921 is found, remove abbreviations in which {lhs} matches
922 with the {rhs}. This is done so that you can even
923 remove abbreviations after expansion. To avoid
924 expansion insert a CTRL-V (type it twice).
926 *:norea* *:noreabbrev*
927 :norea[bbrev] [<expr>] [lhs] [rhs]
928 same as ":ab", but no remapping for this {rhs} {not
929 in Vi}
931 *:ca* *:cabbrev*
932 :ca[bbrev] [<expr>] [lhs] [rhs]
933 same as ":ab", but for Command-line mode only. {not
934 in Vi}
936 *:cuna* *:cunabbrev*
937 :cuna[bbrev] {lhs} same as ":una", but for Command-line mode only. {not
938 in Vi}
940 *:cnorea* *:cnoreabbrev*
941 :cnorea[bbrev] [<expr>] [lhs] [rhs]
942 same as ":ab", but for Command-line mode only and no
943 remapping for this {rhs} {not in Vi}
945 *:ia* *:iabbrev*
946 :ia[bbrev] [<expr>] [lhs] [rhs]
947 same as ":ab", but for Insert mode only. {not in Vi}
949 *:iuna* *:iunabbrev*
950 :iuna[bbrev] {lhs} same as ":una", but for insert mode only. {not in
951 Vi}
953 *:inorea* *:inoreabbrev*
954 :inorea[bbrev] [<expr>] [lhs] [rhs]
955 same as ":ab", but for Insert mode only and no
956 remapping for this {rhs} {not in Vi}
958 *:abc* *:abclear*
959 :abc[lear] Remove all abbreviations. {not in Vi}
961 *:iabc* *:iabclear*
962 :iabc[lear] Remove all abbreviations for Insert mode. {not in Vi}
964 *:cabc* *:cabclear*
965 :cabc[lear] Remove all abbreviations for Command-line mode. {not
966 in Vi}
968 *using_CTRL-V*
969 It is possible to use special characters in the rhs of an abbreviation.
970 CTRL-V has to be used to avoid the special meaning of most non printable
971 characters. How many CTRL-Vs need to be typed depends on how you enter the
972 abbreviation. This also applies to mappings. Let's use an example here.
974 Suppose you want to abbreviate "esc" to enter an <Esc> character. When you
975 type the ":ab" command in Vim, you have to enter this: (here ^V is a CTRL-V
976 and ^[ is <Esc>)
978 You type: ab esc ^V^V^V^V^V^[
980 All keyboard input is subjected to ^V quote interpretation, so
981 the first, third, and fifth ^V characters simply allow the second,
982 and fourth ^Vs, and the ^[, to be entered into the command-line.
984 You see: ab esc ^V^V^[
986 The command-line contains two actual ^Vs before the ^[. This is
987 how it should appear in your .exrc file, if you choose to go that
988 route. The first ^V is there to quote the second ^V; the :ab
989 command uses ^V as its own quote character, so you can include quoted
990 whitespace or the | character in the abbreviation. The :ab command
991 doesn't do anything special with the ^[ character, so it doesn't need
992 to be quoted. (Although quoting isn't harmful; that's why typing 7
993 [but not 8!] ^Vs works.)
995 Stored as: esc ^V^[
997 After parsing, the abbreviation's short form ("esc") and long form
998 (the two characters "^V^[") are stored in the abbreviation table.
999 If you give the :ab command with no arguments, this is how the
1000 abbreviation will be displayed.
1002 Later, when the abbreviation is expanded because the user typed in
1003 the word "esc", the long form is subjected to the same type of
1004 ^V interpretation as keyboard input. So the ^V protects the ^[
1005 character from being interpreted as the "exit Insert mode" character.
1006 Instead, the ^[ is inserted into the text.
1008 Expands to: ^[
1010 [example given by Steve Kirkendall]
1012 ==============================================================================
1013 3. Local mappings and functions *script-local*
1015 When using several Vim script files, there is the danger that mappings and
1016 functions used in one script use the same name as in other scripts. To avoid
1017 this, they can be made local to the script.
1019 *<SID>* *<SNR>* *E81*
1020 The string "<SID>" can be used in a mapping or menu. This requires that the
1021 '<' flag is not present in 'cpoptions'.
1022 When executing the map command, Vim will replace "<SID>" with the special
1023 key code <SNR>, followed by a number that's unique for the script, and an
1024 underscore. Example: >
1025 :map <SID>Add
1026 could define a mapping "<SNR>23_Add".
1028 When defining a function in a script, "s:" can be prepended to the name to
1029 make it local to the script. But when a mapping is executed from outside of
1030 the script, it doesn't know in which script the function was defined. To
1031 avoid this problem, use "<SID>" instead of "s:". The same translation is done
1032 as for mappings. This makes it possible to define a call to the function in
1033 a mapping.
1035 When a local function is executed, it runs in the context of the script it was
1036 defined in. This means that new functions and mappings it defines can also
1037 use "s:" or "<SID>" and it will use the same unique number as when the
1038 function itself was defined. Also, the "s:var" local script variables can be
1039 used.
1041 When executing an autocommand or a user command, it will run in the context of
1042 the script it was defined in. This makes it possible that the command calls a
1043 local function or uses a local mapping.
1045 Otherwise, using "<SID>" outside of a script context is an error.
1047 If you need to get the script number to use in a complicated script, you can
1048 use this function: >
1049 function s:SID()
1050 return matchstr(expand('<sfile>'), '<SNR>\zs\d\+\ze_SID$')
1051 endfun
1053 The "<SNR>" will be shown when listing functions and mappings. This is useful
1054 to find out what they are defined to.
1056 The |:scriptnames| command can be used to see which scripts have been sourced
1057 and what their <SNR> number is.
1059 This is all {not in Vi} and {not available when compiled without the +eval
1060 feature}.
1062 ==============================================================================
1063 4. User-defined commands *user-commands*
1065 It is possible to define your own Ex commands. A user-defined command can act
1066 just like a built-in command (it can have a range or arguments, arguments can
1067 be completed as filenames or buffer names, etc), except that when the command
1068 is executed, it is transformed into a normal ex command and then executed.
1070 For starters: See section |40.2| in the user manual.
1072 *E183* *user-cmd-ambiguous*
1073 All user defined commands must start with an uppercase letter, to avoid
1074 confusion with builtin commands. (There are a few builtin commands, notably
1075 :Next, :Print and :X, which do start with an uppercase letter. The builtin
1076 will always take precedence in these cases). The other characters of the user
1077 command can be uppercase letters, lowercase letters or digits. When using
1078 digits, note that other commands that take a numeric argument may become
1079 ambiguous. For example, the command ":Cc2" could be the user command ":Cc2"
1080 without an argument, or the command ":Cc" with argument "2". It is advised to
1081 put a space between the command name and the argument to avoid these problems.
1083 When using a user-defined command, the command can be abbreviated. However, if
1084 an abbreviation is not unique, an error will be issued. Furthermore, a
1085 built-in command will always take precedence.
1087 Example: >
1088 :command Rename ...
1089 :command Renumber ...
1090 :Rena " Means "Rename"
1091 :Renu " Means "Renumber"
1092 :Ren " Error - ambiguous
1093 :command Paste ...
1094 :P " The built-in :Print
1096 It is recommended that full names for user-defined commands are used in
1097 scripts.
1099 :com[mand] *:com* *:command*
1100 List all user-defined commands. When listing commands,
1101 the characters in the first two columns are
1102 ! Command has the -bang attribute
1103 " Command has the -register attribute
1104 b Command is local to current buffer
1105 (see below for details on attributes)
1107 :com[mand] {cmd} List the user-defined commands that start with {cmd}
1109 *:command-verbose*
1110 When 'verbose' is non-zero, listing a command will also display where it was
1111 last defined. Example: >
1113 :verbose command TOhtml
1114 < Name Args Range Complete Definition ~
1115 TOhtml 0 % :call Convert2HTML(<line1>, <line2>) ~
1116 Last set from /usr/share/vim/vim-7.0/plugin/tohtml.vim ~
1118 See |:verbose-cmd| for more information.
1120 *E174* *E182*
1121 :com[mand][!] [{attr}...] {cmd} {rep}
1122 Define a user command. The name of the command is
1123 {cmd} and its replacement text is {rep}. The command's
1124 attributes (see below) are {attr}. If the command
1125 already exists, an error is reported, unless a ! is
1126 specified, in which case the command is redefined.
1128 :delc[ommand] {cmd} *:delc* *:delcommand* *E184*
1129 Delete the user-defined command {cmd}.
1131 :comc[lear] *:comc* *:comclear*
1132 Delete all user-defined commands.
1134 Command attributes
1136 User-defined commands are treated by Vim just like any other ex commands. They
1137 can have arguments, or have a range specified. Arguments are subject to
1138 completion as filenames, buffers, etc. Exactly how this works depends upon the
1139 command's attributes, which are specified when the command is defined.
1141 There are a number of attributes, split into four categories: argument
1142 handling, completion behavior, range handling, and special cases. The
1143 attributes are described below, by category.
1145 Argument handling *E175* *E176* *:command-nargs*
1147 By default, a user defined command will take no arguments (and an error is
1148 reported if any are supplied). However, it is possible to specify that the
1149 command can take arguments, using the -nargs attribute. Valid cases are:
1151 -nargs=0 No arguments are allowed (the default)
1152 -nargs=1 Exactly one argument is required
1153 -nargs=* Any number of arguments are allowed (0, 1, or many)
1154 -nargs=? 0 or 1 arguments are allowed
1155 -nargs=+ Arguments must be supplied, but any number are allowed
1157 Arguments are considered to be separated by (unescaped) spaces or tabs in this
1158 context.
1160 Note that arguments are used as text, not as expressions. Specifically,
1161 "s:var" will use the script-local variable in the script where the command was
1162 defined, not where it is invoked! Example:
1163 script1.vim: >
1164 :let s:error = "None"
1165 :command -nargs=1 Error echoerr <args>
1166 < script2.vim: >
1167 :source script1.vim
1168 :let s:error = "Wrong!"
1169 :Error s:error
1170 Executing script2.vim will result in "None" to be echoed. Not what you
1171 intended! Calling a function may be an alternative.
1173 Completion behavior *:command-completion* *E179*
1174 *E180* *E181* *:command-complete*
1175 By default, the arguments of user defined commands do not undergo completion.
1176 However, by specifying one or the other of the following attributes, argument
1177 completion can be enabled:
1179 -complete=augroup autocmd groups
1180 -complete=buffer buffer names
1181 -complete=command Ex command (and arguments)
1182 -complete=dir directory names
1183 -complete=environment environment variable names
1184 -complete=event autocommand events
1185 -complete=expression Vim expression
1186 -complete=file file and directory names
1187 -complete=shellcmd Shell command
1188 -complete=function function name
1189 -complete=help help subjects
1190 -complete=highlight highlight groups
1191 -complete=mapping mapping name
1192 -complete=menu menus
1193 -complete=option options
1194 -complete=tag tags
1195 -complete=tag_listfiles tags, file names are shown when CTRL-D is hit
1196 -complete=var user variables
1197 -complete=custom,{func} custom completion, defined via {func}
1198 -complete=customlist,{func} custom completion, defined via {func}
1201 Custom completion *:command-completion-custom*
1202 *:command-completion-customlist*
1203 *E467* *E468*
1204 It is possible to define customized completion schemes via the "custom,{func}"
1205 or the "customlist,{func}" completion argument. The {func} part should be a
1206 function with the following prototype >
1208 :function {func}(ArgLead, CmdLine, CursorPos)
1210 The function need not use all these arguments. The function should provide the
1211 completion candidates as the return value.
1213 For the "custom" argument, the function should return the completion
1214 candidates one per line in a newline separated string.
1216 For the "customlist" argument, the function should return the completion
1217 candidates as a Vim List. Non-string items in the list are ignored.
1219 The function arguments are:
1220 ArgLead the leading portion of the argument currently being
1221 completed on
1222 CmdLine the entire command line
1223 CursorPos the cursor position in it (byte index)
1224 The function may use these for determining context. For the "custom"
1225 argument, it is not necessary to filter candidates against the (implicit
1226 pattern in) ArgLead. Vim will do filter the candidates with its regexp engine
1227 after function return, and this is probably more efficient in most cases. For
1228 the "customlist" argument, Vim will not filter the returned completion
1229 candidates and the user supplied function should filter the candidates.
1231 The following example lists user names to a Finger command >
1232 :com -complete=custom,ListUsers -nargs=1 Finger !finger <args>
1233 :fun ListUsers(A,L,P)
1234 : return system("cut -d: -f1 /etc/passwd")
1235 :endfun
1237 The following example completes filenames from the directories specified in
1238 the 'path' option: >
1239 :com -nargs=1 -bang -complete=customlist,EditFileComplete
1240 \ EditFile edit<bang> <args>
1241 :fun EditFileComplete(A,L,P)
1242 : return split(globpath(&path, a:ArgLead), "\n")
1243 :endfun
1244 <
1246 Range handling *E177* *E178* *:command-range*
1247 *:command-count*
1248 By default, user-defined commands do not accept a line number range. However,
1249 it is possible to specify that the command does take a range (the -range
1250 attribute), or that it takes an arbitrary count value, either in the line
1251 number position (-range=N, like the |:split| command) or as a "count"
1252 argument (-count=N, like the |:Next| command). The count will then be
1253 available in the argument with |<count>|.
1255 Possible attributes are:
1257 -range Range allowed, default is current line
1258 -range=% Range allowed, default is whole file (1,$)
1259 -range=N A count (default N) which is specified in the line
1260 number position (like |:split|)
1261 -count=N A count (default N) which is specified either in the line
1262 number position, or as an initial argument (like |:Next|).
1263 Specifying -count (without a default) acts like -count=0
1265 Note that -range=N and -count=N are mutually exclusive - only one should be
1266 specified.
1268 Special cases *:command-bang* *:command-bar*
1269 *:command-register* *:command-buffer*
1270 There are some special cases as well:
1272 -bang The command can take a ! modifier (like :q or :w)
1273 -bar The command can be followed by a "|" and another command.
1274 A "|" inside the command argument is not allowed then.
1275 Also checks for a " to start a comment.
1276 -register The first argument to the command can be an optional
1277 register name (like :del, :put, :yank).
1278 -buffer The command will only be available in the current buffer.
1280 In the cases of the -count and -register attributes, if the optional argument
1281 is supplied, it is removed from the argument list and is available to the
1282 replacement text separately.
1284 Replacement text
1286 The replacement text for a user defined command is scanned for special escape
1287 sequences, using <...> notation. Escape sequences are replaced with values
1288 from the entered command line, and all other text is copied unchanged. The
1289 resulting string is executed as an Ex command. To avoid the replacement use
1290 <lt> in plade of the initial <. Thus to include "<bang>" literally use
1291 "<lt>bang>".
1293 The valid escape sequences are
1295 *<line1>*
1296 <line1> The starting line of the command range.
1297 *<line2>*
1298 <line2> The final line of the command range.
1299 *<count>*
1300 <count> Any count supplied (as described for the '-range'
1301 and '-count' attributes).
1302 *<bang>*
1303 <bang> (See the '-bang' attribute) Expands to a ! if the
1304 command was executed with a ! modifier, otherwise
1305 expands to nothing.
1306 *<reg>* *<register>*
1307 <reg> (See the '-register' attribute) The optional register,
1308 if specified. Otherwise, expands to nothing. <register>
1309 is a synonym for this.
1310 *<args>*
1311 <args> The command arguments, exactly as supplied (but as
1312 noted above, any count or register can consume some
1313 of the arguments, which are then not part of <args>).
1314 <lt> A single '<' (Less-Than) character. This is needed if you
1315 want to get a literal copy of one of these escape sequences
1316 into the expansion - for example, to get <bang>, use
1317 <lt>bang>.
1319 *<q-args>*
1320 If the first two characters of an escape sequence are "q-" (for example,
1321 <q-args>) then the value is quoted in such a way as to make it a valid value
1322 for use in an expression. This uses the argument as one single value.
1323 When there is no argument <q-args> is an empty string.
1324 *<f-args>*
1325 To allow commands to pass their arguments on to a user-defined function, there
1326 is a special form <f-args> ("function args"). This splits the command
1327 arguments at spaces and tabs, quotes each argument individually, and the
1328 <f-args> sequence is replaced by the comma-separated list of quoted arguments.
1329 See the Mycmd example below. If no arguments are given <f-args> is removed.
1330 To embed whitespace into an argument of <f-args>, prepend a backslash.
1331 <f-args> replaces every pair of backslashes (\\) with one backslash. A
1332 backslash followed by a character other than white space or a backslash
1333 remains unmodified. Overview:
1335 command <f-args> ~
1336 XX ab 'ab'
1337 XX a\b 'a\b'
1338 XX a\ b 'a b'
1339 XX a\ b 'a ', 'b'
1340 XX a\\b 'a\b'
1341 XX a\\ b 'a\', 'b'
1342 XX a\\\b 'a\\b'
1343 XX a\\\ b 'a\ b'
1344 XX a\\\\b 'a\\b'
1345 XX a\\\\ b 'a\\', 'b'
1347 Examples >
1349 " Delete everything after here to the end
1350 :com Ddel +,$d
1352 " Rename the current buffer
1353 :com -nargs=1 -bang -complete=file Ren f <args>|w<bang>
1355 " Replace a range with the contents of a file
1356 " (Enter this all as one line)
1357 :com -range -nargs=1 -complete=file
1358 Replace <line1>-pu_|<line1>,<line2>d|r <args>|<line1>d
1360 " Count the number of lines in the range
1361 :com! -range -nargs=0 Lines echo <line2> - <line1> + 1 "lines"
1363 " Call a user function (example of <f-args>)
1364 :com -nargs=* Mycmd call Myfunc(<f-args>)
1366 When executed as: >
1367 :Mycmd arg1 arg2
1368 This will invoke: >
1369 :call Myfunc("arg1","arg2")
1371 :" A more substantial example
1372 :function Allargs(command)
1373 : let i = 0
1374 : while i < argc()
1375 : if filereadable(argv(i))
1376 : execute "e " . argv(i)
1377 : execute a:command
1378 : endif
1379 : let i = i + 1
1380 : endwhile
1381 :endfunction
1382 :command -nargs=+ -complete=command Allargs call Allargs(<q-args>)
1384 The command Allargs takes any Vim command(s) as argument and executes it on all
1385 files in the argument list. Usage example (note use of the "e" flag to ignore
1386 errors and the "update" command to write modified buffers): >
1387 :Allargs %s/foo/bar/ge|update
1388 This will invoke: >
1389 :call Allargs("%s/foo/bar/ge|update")
1390 <
1391 When defining an user command in a script, it will be able to call functions
1392 local to the script and use mappings local to the script. When the user
1393 invokes the user command, it will run in the context of the script it was
1394 defined in. This matters if |<SID>| is used in a command.
1396 vim:tw=78:ts=8:ft=help:norl: