autogen.sh

   1 :
   2 #
   3 # This script checks various configure parameters and uses three files:
   4 #   * autogen.input (ro)
   5 #   * autogen.lastrun (rw)
   6 #   * autogen.lastrun.bak (rw)
   7 #
   8 # If _no_ parmeters:
   9 #   Read args from autogen.input or autogen.lastrun
  10 # Else
  11 #   Backup autogen.lastrun as autogen.lastrun.bak
  12 #   Write autogen.lastrun with new commandline args
  13 #
  14 # Run configure with checked args
  15 #
  16     eval 'exec perl -S $0 ${1+"$@"}'
  17         if 0;
  18
  19 use strict;
  20 use Cwd ('cwd', 'realpath');
  21 use File::Basename;
  22
  23 my $src_path=dirname(realpath($0));
  24 my $build_path=realpath(cwd());
  25 # since this looks crazy, if you have a symlink on a path up to and including
  26 # the current directory, we need our configure to run in the realpath of that
  27 # such that compiled (realpath'd) dependency filenames match the filenames
  28 # used in our makefiles - ie. this gets dependencies right via SRC_ROOT
  29 chdir ($build_path);
  30 # more amazingly, if you don't clobber 'PWD' shells will re-assert their
  31 # old path from the environment, not cwd.
  32 $ENV{PWD} = $build_path;
  33
  34 sub clean()
  35 {
  36     system ("rm -Rf autom4te.cache");
  37     system ("rm -f missing install-sh mkinstalldirs libtool ltmain.sh");
  38     print "Cleaned the build tree\n";
  39 }
  40
  41 my $aclocal;
  42
  43 # check we have various vital tools
  44 sub sanity_checks($)
  45 {
  46     my $system = shift;
  47     my @path = split (':', $ENV{'PATH'});
  48     my %required =
  49       (
  50        'pkg-config' => "pkg-config is required to be installed",
  51        'autoconf'   => "autoconf is required",
  52        $aclocal     => "$aclocal is required",
  53       );
  54
  55     for my $elem (@path) {
  56         for my $app (keys %required) {
  57             if (-f "$elem/$app") {
  58                 delete $required{$app};
  59             }
  60         }
  61     }
  62     if ((keys %required) > 0) {
  63         print ("Various low-level dependencies are missing, please install them:\n");
  64         for my $app (keys %required) {
  65             print "\t $app: " . $required{$app} . "\n";
  66         }
  67         exit (1);
  68     }
  69 }
  70
  71 # one argument per line
  72 sub read_args($)
  73 {
  74     my $file = shift;
  75     my $fh;
  76     my @lst;
  77     open ($fh, $file) || die "can't open file: $file";
  78     while (<$fh>) {
  79         chomp();
  80         s/\s+$//;
  81         # migrate from the old system
  82         if ( substr($_, 0, 1) eq "'" ) {
  83             print STDERR "Migrating options from the old autogen.lastrun format, using:\n";
  84             my @opts;
  85             @opts = split(/'/);
  86             foreach my $opt (@opts) {
  87                 if ( substr($opt, 0, 1) eq "-" ) {
  88                     push @lst, $opt;
  89                     print STDERR "  $opt\n";
  90                 }
  91             }
  92         } elsif ( substr($_, 0, 1) eq "#" ) {
  93             # comment
  94         } elsif ( length == 0 ) {
  95             # empty line
  96         } else {
  97             push @lst, $_;
  98         }
  99     }
 100     close ($fh);
 101     # print "read args from file '$file': @lst\n";
 102     return @lst;
 103 }
 104
 105 sub invalid_distro($$)
 106 {
 107     my ($config, $distro) = @_;
 108     print STDERR "Can't find distro option set: $config\nThis is not necessarily a problem.\n";
 109     print STDERR "Distros with distro option sets are:\n";
 110     my $dirh;
 111     opendir ($dirh, "$src_path/distro-configs");
 112     while (($_ = readdir ($dirh))) {
 113         /(.*)\.conf$/ || next;
 114         print STDERR "\t$1\n";
 115     }
 116     closedir ($dirh);
 117 }
 118
 119 # Avoid confusing "aclocal: error: non-option arguments are not accepted: '.../m4'." error message.
 120 die "\$src_path must not contain spaces, but it is '$src_path'." if ($src_path =~ / /);
 121
 122 # Alloc $ACLOCAL to specify which aclocal to use
 123 $aclocal = $ENV{ACLOCAL} ? $ENV{ACLOCAL} : 'aclocal';
 124
 125 my $system = `uname -s`;
 126 chomp $system;
 127
 128 sanity_checks ($system) unless($system eq 'Darwin');
 129
 130 # If we are running in a LODE env, make sure we find the right aclocal
 131 # by making sure that LODE_HOME/opt/bin is in the PATH
 132 if (defined $ENV{LODE_HOME})
 133 {
 134     my $lode_path = quotemeta "$ENV{LODE_HOME}/opt/bin";
 135     if($ENV{PATH} !~ $lode_path)
 136     {
 137         $ENV{PATH}="$ENV{LODE_HOME}/opt/bin:$ENV{PATH}";
 138         print STDERR "add LODE_HOME/opt/bin in PATH\n";
 139     }
 140 }
 141
 142 my $aclocal_flags = $ENV{ACLOCAL_FLAGS};
 143
 144 $aclocal_flags .= " -I $src_path/m4";
 145 $aclocal_flags .= " -I $src_path/m4/mac" if ($system eq 'Darwin');
 146 $aclocal_flags .= " -I /opt/freeware/share/aclocal" if ($system eq 'AIX');
 147
 148 $ENV{AUTOMAKE_EXTRA_FLAGS} = '--warnings=no-portability' if (!($system eq 'Darwin'));
 149
 150 if ($src_path ne $build_path)
 151 {
 152     system ("ln -sf $src_path/configure.ac configure.ac");
 153     system ("ln -sf $src_path/g g");
 154     my @modules = <$src_path/*/Makefile>;
 155     foreach my $module (@modules)
 156     {
 157         my $dir = basename (dirname ($module));
 158         mkdir ($dir);
 159         system ("ln -sf $src_path/$dir/Makefile $dir/Makefile");
 160     }
 161     my @external_modules = <$src_path/external/*/Makefile>;
 162     mkdir ("external");
 163     system ("ln -sf $src_path/external/Module_external.mk external/");
 164     foreach my $module (@external_modules)
 165     {
 166         my $dir = basename (dirname ($module));
 167         mkdir ("external/$dir");
 168         system ("ln -sf $src_path/external/$dir/Makefile external/$dir/Makefile");
 169     }
 170 }
 171 system ("$aclocal $aclocal_flags") && die "Failed to run aclocal";
 172 unlink ("configure");
 173 system ("autoconf -I ${src_path}") && die "Failed to run autoconf";
 174 die "Failed to generate the configure script" if (! -f "configure");
 175
 176 # Handle help arguments first, so we don't clobber autogen.lastrun
 177 for my $arg (@ARGV) {
 178     if ($arg =~ /^(--help|-h|-\?)$/) {
 179         print STDERR "autogen.sh - libreoffice configuration helper\n";
 180         print STDERR "   --clean        forcibly re-generate configuration\n";
 181         print STDERR "   --best-effort  don't fail on un-known configure with/enable options\n";
 182         print STDERR "\nOther arguments passed directly to configure:\n\n";
 183         system ("./configure --help");
 184         exit;
 185     }
 186 }
 187
 188 my @cmdline_args = ();
 189
 190 my $input = "autogen.input";
 191 my $lastrun = "autogen.lastrun";
 192
 193 if (!@ARGV) {
 194     if (-f $input) {
 195         if (-f $lastrun) {
 196             print STDERR <<WARNING;
 197 ********************************************************************
 198 *
 199 *   Reading $input and ignoring $lastrun!
 200 *   Consider removing $lastrun to get rid of this warning.
 201 *
 202 ********************************************************************
 203 WARNING
 204         }
 205         @cmdline_args = read_args ($input);
 206     } elsif (-f $lastrun) {
 207         print STDERR "Reading $lastrun. Please rename it to $input to avoid this message.\n";
 208         @cmdline_args = read_args ($lastrun);
 209     }
 210 } else {
 211     if (-f $input) {
 212         print STDERR <<WARNING;
 213 ********************************************************************
 214 *
 215 *   Using commandline arguments and ignoring $input!
 216 *
 217 ********************************************************************
 218 WARNING
 219     }
 220     @cmdline_args = @ARGV;
 221 }
 222
 223 my @args;
 224 my $default_config = "$src_path/distro-configs/default.conf";
 225 my $option_checking = 'fatal';
 226
 227 if (-f $default_config) {
 228     print STDERR "Reading default config file: $default_config.\n";
 229     push @args, read_args ($default_config);
 230 }
 231 for my $arg (@cmdline_args) {
 232     if ($arg eq '--clean') {
 233         clean();
 234     } elsif ($arg =~ m/--with-distro=(.*)$/) {
 235         my $config = "$src_path/distro-configs/$1.conf";
 236         if (! -f $config) {
 237             invalid_distro ($config, $1);
 238         } else {
 239             push @args, read_args ($config);
 240         }
 241     } elsif ($arg =~ m/--best-effort$/) {
 242         $option_checking = 'warn';
 243     } else {
 244         push @args, $arg;
 245     }
 246 }
 247 for my $arg (@args) {
 248     if ($arg =~ /^([A-Z]+)=(.*)/) {
 249         $ENV{$1} = $2;
 250     }
 251 }
 252
 253 if (defined $ENV{NOCONFIGURE}) {
 254     print "Skipping configure process.";
 255 } else {
 256     # Save autogen.lastrun only if we did get some arguments on the command-line
 257     if (! -f $input && @ARGV) {
 258         if (scalar(@cmdline_args) > 0) {
 259             # if there's already an autogen.lastrun, make a backup first
 260             if (-e $lastrun) {
 261                 open (my $fh, $lastrun) || warn "Can't open $lastrun.\n";
 262                 open (BAK, ">$lastrun.bak") || warn "Can't create backup file $lastrun.bak.\n";
 263                 while (<$fh>) {
 264                     print BAK;
 265                 }
 266                 close (BAK) && close ($fh);
 267             }
 268             # print "Saving command-line args to $lastrun\n";
 269             my $fh;
 270             open ($fh, ">autogen.lastrun") || die "Can't open autogen.lastrun: $!";
 271             for my $arg (@cmdline_args) {
 272                 print $fh "$arg\n";
 273             }
 274             close ($fh);
 275         }
 276     }
 277     push @args, "--srcdir=$src_path";
 278     push @args, "--enable-option-checking=$option_checking";
 279
 280     print "Running ./configure with '" . join (" ", @args), "'\n";
 281     system ("./configure", @args) && die "Error running configure";
 282 }
 283
 284 # Local Variables:
 285 # mode: perl
 286 # cperl-indent-level: 4
 287 # tab-width: 4
 288 # indent-tabs-mode: nil
 289 # End:
 290
 291 # vim:set ft=perl shiftwidth=4 softtabstop=4 expandtab: #