autogen.sh

   1 :
   2 #
   3 # This script checks various configure parameters and uses three files:
   4 #   * autogen.input (ro)
   5 #   * autogen.lastrun (rw)
   6 #   * autogen.lastrun.bak (rw)
   7 #
   8 # If _no_ parmeters:
   9 #   Read args from autogen.input or autogen.lastrun
  10 # Else
  11 #   Backup autogen.lastrun as autogen.lastrun.bak
  12 #   Write autogen.lastrun with new commandline args
  13 #
  14 # Run configure with checked args
  15 #
  16     eval 'exec perl -S $0 ${1+"$@"}'
  17         if 0;
  18
  19 use strict;
  20 use Cwd ('cwd', 'realpath');
  21 use File::Basename;
  22
  23 my $src_path=dirname(realpath($0));
  24 my $build_path=realpath(cwd());
  25 # since this looks crazy, if you have a symlink on a path up to and including
  26 # the current directory, we need our configure to run in the realpath of that
  27 # such that compiled (realpath'd) dependency filenames match the filenames
  28 # used in our makefiles - ie. this gets dependencies right via SRC_ROOT
  29 chdir ($build_path);
  30 # more amazingly, if you don't clobber 'PWD' shells will re-assert their
  31 # old path from the environment, not cwd.
  32 $ENV{PWD} = $build_path;
  33
  34 sub clean()
  35 {
  36     system ("rm -Rf autom4te.cache");
  37     system ("rm -f missing install-sh mkinstalldirs libtool ltmain.sh");
  38     print "Cleaned the build tree\n";
  39 }
  40
  41 my $aclocal;
  42
  43 # check we have various vital tools
  44 sub sanity_checks($)
  45 {
  46     my $system = shift;
  47     my @path = split (':', $ENV{'PATH'});
  48     my %required =
  49       (
  50        'pkg-config' => "pkg-config is required to be installed",
  51        'autoconf'   => "autoconf is required",
  52        $aclocal     => "$aclocal is required",
  53       );
  54
  55     for my $elem (@path) {
  56         for my $app (keys %required) {
  57             if (-f "$elem/$app") {
  58                 delete $required{$app};
  59             }
  60         }
  61     }
  62     if ((keys %required) > 0) {
  63         print ("Various low-level dependencies are missing, please install them:\n");
  64         for my $app (keys %required) {
  65             print "\t $app: " . $required{$app} . "\n";
  66         }
  67         exit (1);
  68     }
  69 }
  70
  71 # one argument per line
  72 sub read_args($)
  73 {
  74     my $file = shift;
  75     my $fh;
  76     my @lst;
  77     open ($fh, $file) || die "can't open file: $file";
  78     while (<$fh>) {
  79         chomp();
  80         s/\s+$//;
  81         # migrate from the old system
  82         if ( substr($_, 0, 1) eq "'" ) {
  83             print STDERR "Migrating options from the old autogen.lastrun format, using:\n";
  84             my @opts;
  85             @opts = split(/'/);
  86             foreach my $opt (@opts) {
  87                 if ( substr($opt, 0, 1) eq "-" ) {
  88                     push @lst, $opt;
  89                     print STDERR "  $opt\n";
  90                 }
  91             }
  92         } elsif ( substr($_, 0, 1) eq "#" ) {
  93             # comment
  94         } elsif ( length == 0 ) {
  95             # empty line
  96         } else {
  97             push @lst, $_;
  98         }
  99     }
 100     close ($fh);
 101     # print "read args from file '$file': @lst\n";
 102     return @lst;
 103 }
 104
 105 sub invalid_distro($$)
 106 {
 107     my ($config, $distro) = @_;
 108     print STDERR "Can't find distro option set: $config\nThis is not necessarily a problem.\n";
 109     print STDERR "Distros with distro option sets are:\n";
 110     my $dirh;
 111     opendir ($dirh, "$src_path/distro-configs");
 112     while (($_ = readdir ($dirh))) {
 113         /(.*)\.conf$/ || next;
 114         print STDERR "\t$1\n";
 115     }
 116     closedir ($dirh);
 117 }
 118
 119 # Alloc $ACLOCAL to specify which aclocal to use
 120 $aclocal = $ENV{ACLOCAL} ? $ENV{ACLOCAL} : 'aclocal';
 121
 122 my $system = `uname -s`;
 123 chomp $system;
 124
 125 sanity_checks ($system) unless($system eq 'Darwin');
 126
 127 my $aclocal_flags = $ENV{ACLOCAL_FLAGS};
 128
 129 $aclocal_flags .= " -I $src_path/m4";
 130 $aclocal_flags .= " -I $src_path/m4/mac" if ($system eq 'Darwin');
 131 $aclocal_flags .= " -I /opt/freeware/share/aclocal" if ($system eq 'AIX');
 132
 133 $ENV{AUTOMAKE_EXTRA_FLAGS} = '--warnings=no-portability' if (!($system eq 'Darwin'));
 134
 135 if ($src_path ne $build_path)
 136 {
 137     system ("ln -sf $src_path/configure.ac configure.ac");
 138     system ("ln -sf $src_path/g g");
 139     my @modules = <$src_path/*/Makefile>;
 140     foreach my $module (@modules)
 141     {
 142         my $dir = basename (dirname ($module));
 143         mkdir ($dir);
 144         system ("ln -sf $src_path/$dir/Makefile $dir/Makefile");
 145     }
 146     my @external_modules = <$src_path/external/*/Makefile>;
 147     mkdir ("external");
 148     system ("ln -sf $src_path/external/Module_external.mk external/");
 149     foreach my $module (@external_modules)
 150     {
 151         my $dir = basename (dirname ($module));
 152         mkdir ("external/$dir");
 153         system ("ln -sf $src_path/external/$dir/Makefile external/$dir/Makefile");
 154     }
 155 }
 156 system ("$aclocal $aclocal_flags") && die "Failed to run aclocal";
 157 unlink ("configure");
 158 system ("autoconf -I ${src_path}") && die "Failed to run autoconf";
 159 die "Failed to generate the configure script" if (! -f "configure");
 160
 161 # Handle help arguments first, so we don't clobber autogen.lastrun
 162 for my $arg (@ARGV) {
 163     if ($arg =~ /^(--help|-h|-\?)$/) {
 164         print STDERR "autogen.sh - libreoffice configuration helper\n";
 165         print STDERR "   --clean        forcibly re-generate configuration\n";
 166         print STDERR "   --best-effort  don't fail on un-known configure with/enable options\n";
 167         print STDERR "\nOther arguments passed directly to configure:\n\n";
 168         system ("./configure --help");
 169         exit;
 170     }
 171 }
 172
 173 my @cmdline_args = ();
 174
 175 my $input = "autogen.input";
 176 my $lastrun = "autogen.lastrun";
 177
 178 if (!@ARGV) {
 179     if (-f $input) {
 180         if (-f $lastrun) {
 181             print STDERR <<WARNING;
 182 ********************************************************************
 183 *
 184 *   Reading $input and ignoring $lastrun!
 185 *   Consider removing $lastrun to get rid of this warning.
 186 *
 187 ********************************************************************
 188 WARNING
 189         }
 190         @cmdline_args = read_args ($input);
 191     } elsif (-f $lastrun) {
 192         print STDERR "Reading $lastrun. Please rename it to $input to avoid this message.\n";
 193         @cmdline_args = read_args ($lastrun);
 194     }
 195 } else {
 196     if (-f $input) {
 197         print STDERR <<WARNING;
 198 ********************************************************************
 199 *
 200 *   Using commandline arguments and ignoring $input!
 201 *
 202 ********************************************************************
 203 WARNING
 204     }
 205     @cmdline_args = @ARGV;
 206 }
 207
 208 my @args;
 209 my $default_config = "$src_path/distro-configs/default.conf";
 210 my $option_checking = 'fatal';
 211
 212 if (-f $default_config) {
 213     print STDERR "Reading default config file: $default_config.\n";
 214     push @args, read_args ($default_config);
 215 }
 216 for my $arg (@cmdline_args) {
 217     if ($arg eq '--clean') {
 218         clean();
 219     } elsif ($arg =~ m/--with-distro=(.*)$/) {
 220         my $config = "$src_path/distro-configs/$1.conf";
 221         if (! -f $config) {
 222             invalid_distro ($config, $1);
 223         } else {
 224             push @args, read_args ($config);
 225         }
 226     } elsif ($arg =~ m/--best-effort$/) {
 227         $option_checking = 'warn';
 228     } else {
 229         push @args, $arg;
 230     }
 231 }
 232 for my $arg (@args) {
 233     if ($arg =~ /^([A-Z]+)=(.*)/) {
 234         $ENV{$1} = $2;
 235     }
 236 }
 237
 238 if (defined $ENV{NOCONFIGURE}) {
 239     print "Skipping configure process.";
 240 } else {
 241     # Save autogen.lastrun only if we did get some arguments on the command-line
 242     if (! -f $input && @ARGV) {
 243         if (scalar(@cmdline_args) > 0) {
 244             # if there's already an autogen.lastrun, make a backup first
 245             if (-e $lastrun) {
 246                 open (my $fh, $lastrun) || warn "Can't open $lastrun.\n";
 247                 open (BAK, ">$lastrun.bak") || warn "Can't create backup file $lastrun.bak.\n";
 248                 while (<$fh>) {
 249                     print BAK;
 250                 }
 251                 close (BAK) && close ($fh);
 252             }
 253             # print "Saving command-line args to $lastrun\n";
 254             my $fh;
 255             open ($fh, ">autogen.lastrun") || die "Can't open autogen.lastrun: $!";
 256             for my $arg (@cmdline_args) {
 257                 print $fh "$arg\n";
 258             }
 259             close ($fh);
 260         }
 261     }
 262     push @args, "--srcdir=$src_path";
 263     push @args, "--enable-option-checking=$option_checking";
 264
 265     print "Running ./configure with '" . join ("' '", @args), "'\n";
 266     system ("./configure", @args) && die "Error running configure";
 267 }
 268
 269 # Local Variables:
 270 # mode: perl
 271 # cperl-indent-level: 4
 272 # tab-width: 4
 273 # indent-tabs-mode: nil
 274 # End:
 275
 276 # vim:set ft=perl shiftwidth=4 softtabstop=4 expandtab: #