acinclude.m4

   1 dnl @synopsis AX_FUNC_WHICH_GETSPNAM_R
   2 dnl
   3 dnl Determines which historical variant of the getspnam_r() call
   4 dnl (taking four or five arguments) is available on the system
   5 dnl and sets NEW_SHADOW_API=YES if there are five arguments.
   6 dnl
   7 dnl Originally named "AX_FUNC_WHICH_GETHOSTBYNAME_R". Rewritten
   8 dnl for AX_FUNC_WHICH_GETSPNAM_R
   9 dnl
  10 dnl @author Caolan McNamara <caolan@skynet.ie>
  11 dnl @author Daniel Richard G. <skunk@iskunk.org>
  12 dnl @version 2006-05-01
  13 dnl @license LGPL
  14
  15 AC_DEFUN([AX_FUNC_WHICH_GETSPNAM_R], [
  16
  17     AC_LANG_PUSH(C)
  18     AC_MSG_CHECKING([how many arguments getspnam_r() takes])
  19
  20     AC_CACHE_VAL(ac_cv_func_which_getspnam_r, [
  21
  22 ################################################################
  23
  24 ac_cv_func_which_getspnam_r=unknown
  25
  26 #
  27 # ONE ARGUMENT (sanity check)
  28 #
  29
  30 # This should fail, as there is no variant of getspnam_r() that takes
  31 # a single argument. If it actually compiles, then we can assume that
  32 # netdb.h is not declaring the function, and the compiler is thereby
  33 # assuming an implicit prototype. In which case, we're out of luck.
  34 #
  35 AC_COMPILE_IFELSE(
  36     AC_LANG_PROGRAM(
  37         [[
  38             #include <sys/types.h>
  39             #include <shadow.h>
  40         ]],
  41         [[
  42             const char *name = "myname";
  43             getspnam_r(name) /* ; */
  44         ]]),
  45     ac_cv_func_which_getspnam_r=no)
  46
  47 #
  48 # FIVE ARGUMENTS
  49 #
  50
  51 if test "$ac_cv_func_which_getspnam_r" = "unknown"; then
  52
  53 AC_COMPILE_IFELSE(
  54     AC_LANG_PROGRAM(
  55         [[
  56             #include <sys/types.h>
  57             #include <shadow.h>
  58         ]],
  59         [[
  60             char buffer[[]] = { '\0' };
  61             struct spwd spwdStruct;
  62             const char *name = "myname";
  63             getspnam_r(name, &spwdStruct, buffer, sizeof buffer, 0) /* ; */
  64         ]]),
  65     ac_cv_func_which_getspnam_r=five)
  66
  67 fi
  68
  69 #
  70 # FOUR ARGUMENTS
  71 #
  72
  73 if test "$ac_cv_func_which_getspnam_r" = "unknown"; then
  74
  75 AC_COMPILE_IFELSE(
  76     AC_LANG_PROGRAM(
  77         [[
  78             #include <sys/types.h>
  79             #include <shadow.h>
  80         ]],
  81         [[
  82             char buffer[[]] = { '\0' };
  83             struct spwd spwdStruct;
  84             const char *name = "myname";
  85             getspnam_r(name, &spwdStruct, buffer, sizeof buffer) /* ; */
  86         ]]),
  87     ac_cv_func_which_getspnam_r=four)
  88
  89 fi
  90
  91 ################################################################
  92
  93 ]) dnl end AC_CACHE_VAL
  94
  95 case "$ac_cv_func_which_getspnam_r" in
  96     five)
  97     AC_MSG_RESULT([five])
  98     NEW_SHADOW_API=YES
  99     ;;
 100
 101     four)
 102     AC_MSG_RESULT([four])
 103     ;;
 104
 105     no)
 106     AC_MSG_RESULT([cannot find function declaration in shadow.h])
 107     ;;
 108
 109     unknown)
 110     AC_MSG_RESULT([can't tell])
 111     ;;
 112
 113     *)
 114     AC_MSG_ERROR([internal error])
 115     ;;
 116 esac
 117
 118 AC_LANG_POP(C)
 119
 120 ]) dnl end AC_DEFUN