vcl/ios/iOSTransferable.cxx

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4; fill-column: 100 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20 #include <sal/config.h>
  21
  22 #include <com/sun/star/datatransfer/UnsupportedFlavorException.hpp>
  23 #include <com/sun/star/lang/IllegalArgumentException.hpp>
  24 #include <sal/log.hxx>
  25 #include <sal/types.h>
  26 #include <osl/diagnose.h>
  27
  28 #include <quartz/utils.h>
  29
  30 #include "iOSTransferable.hxx"
  31
  32 #include "DataFlavorMapping.hxx"
  33
  34 using namespace osl;
  35 using namespace cppu;
  36 using namespace com::sun::star::uno;
  37 using namespace com::sun::star::datatransfer;
  38 using namespace com::sun::star::lang;
  39
  40 namespace
  41 {
  42 bool isValidFlavor(const DataFlavor& aFlavor)
  43 {
  44     size_t len = aFlavor.MimeType.getLength();
  45     Type dtype = aFlavor.DataType;
  46     return ((len > 0)
  47             && ((dtype == cppu::UnoType<Sequence<sal_Int8>>::get())
  48                 || (dtype == cppu::UnoType<OUString>::get())));
  49 }
  50
  51 bool cmpAllContentTypeParameter(const Reference<XMimeContentType>& xLhs,
  52                                 const Reference<XMimeContentType>& xRhs)
  53 {
  54     Sequence<OUString> xLhsFlavors = xLhs->getParameters();
  55     Sequence<OUString> xRhsFlavors = xRhs->getParameters();
  56
  57     // Stop here if the number of parameters is different already
  58     if (xLhsFlavors.getLength() != xRhsFlavors.getLength())
  59         return false;
  60
  61     try
  62     {
  63         OUString pLhs;
  64         OUString pRhs;
  65
  66         for (sal_Int32 i = 0; i < xLhsFlavors.getLength(); i++)
  67         {
  68             pLhs = xLhs->getParameterValue(xLhsFlavors[i]);
  69             pRhs = xRhs->getParameterValue(xLhsFlavors[i]);
  70
  71             if (!pLhs.equalsIgnoreAsciiCase(pRhs))
  72             {
  73                 return false;
  74             }
  75         }
  76     }
  77     catch (IllegalArgumentException&)
  78     {
  79         return false;
  80     }
  81
  82     return true;
  83 }
  84
  85 } // unnamed namespace
  86
  87 iOSTransferable::iOSTransferable(const Reference<XMimeContentTypeFactory>& rXMimeCntFactory,
  88                                  std::shared_ptr<DataFlavorMapper> pDataFlavorMapper)
  89     : mrXMimeCntFactory(rXMimeCntFactory)
  90     , mDataFlavorMapper(pDataFlavorMapper)
  91 {
  92     initClipboardItemList();
  93 }
  94
  95 iOSTransferable::~iOSTransferable() {}
  96
  97 Any SAL_CALL iOSTransferable::getTransferData(const DataFlavor& aFlavor)
  98 {
  99     if (!isValidFlavor(aFlavor) || !isDataFlavorSupported(aFlavor))
 100     {
 101         throw UnsupportedFlavorException("Unsupported data flavor",
 102                                          static_cast<XTransferable*>(this));
 103     }
 104
 105     bool bInternal(false);
 106     NSString* sysFormat = (aFlavor.MimeType.startsWith("image/png"))
 107                               ? DataFlavorMapper::openOfficeImageToSystemFlavor()
 108                               : mDataFlavorMapper->openOfficeToSystemFlavor(aFlavor, bInternal);
 109     DataProviderPtr_t dp;
 110
 111     NSData* sysData = [[UIPasteboard generalPasteboard] dataForPasteboardType:sysFormat];
 112     dp = DataFlavorMapper::getDataProvider(sysFormat, sysData);
 113
 114     if (dp.get() == nullptr)
 115     {
 116         throw UnsupportedFlavorException("Unsupported data flavor",
 117                                          static_cast<XTransferable*>(this));
 118     }
 119
 120     return dp->getOOoData();
 121 }
 122
 123 Sequence<DataFlavor> SAL_CALL iOSTransferable::getTransferDataFlavors() { return mFlavorList; }
 124
 125 sal_Bool SAL_CALL iOSTransferable::isDataFlavorSupported(const DataFlavor& aFlavor)
 126 {
 127     for (sal_Int32 i = 0; i < mFlavorList.getLength(); i++)
 128         if (compareDataFlavors(aFlavor, mFlavorList[i]))
 129             return true;
 130
 131     return false;
 132 }
 133
 134 void iOSTransferable::initClipboardItemList()
 135 {
 136     NSArray* pboardFormats = [[UIPasteboard generalPasteboard] pasteboardTypes];
 137
 138     if (pboardFormats == nullptr)
 139     {
 140         throw RuntimeException("Cannot get clipboard data", static_cast<XTransferable*>(this));
 141     }
 142
 143     SAL_INFO("vcl.ios.clipboard", "Types on clipboard: " << NSStringArrayToOUString(pboardFormats));
 144
 145     mFlavorList = mDataFlavorMapper->typesArrayToFlavorSequence(pboardFormats);
 146 }
 147
 148 /* Compares two DataFlavors. Returns true if both DataFlavor have the same media type
 149    and the number of parameter and all parameter values do match otherwise false
 150    is returned.
 151  */
 152 bool iOSTransferable::compareDataFlavors(const DataFlavor& lhs, const DataFlavor& rhs)
 153 {
 154     try
 155     {
 156         Reference<XMimeContentType> xLhs(mrXMimeCntFactory->createMimeContentType(lhs.MimeType));
 157         Reference<XMimeContentType> xRhs(mrXMimeCntFactory->createMimeContentType(rhs.MimeType));
 158
 159         if (!xLhs->getFullMediaType().equalsIgnoreAsciiCase(xRhs->getFullMediaType())
 160             || !cmpAllContentTypeParameter(xLhs, xRhs))
 161         {
 162             return false;
 163         }
 164     }
 165     catch (IllegalArgumentException&)
 166     {
 167         OSL_FAIL("Invalid content type detected");
 168         return false;
 169     }
 170
 171     return true;
 172 }
 173
 174 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */