vcl/ios/clipboard.cxx

   1 /* -*- Mode: ObjC; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4; fill-column: 100 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20 #include "ios/iosinst.hxx"
  21
  22 #include "clipboard.hxx"
  23
  24 #include "DataFlavorMapping.hxx"
  25 #include "iOSTransferable.hxx"
  26 #include <com/sun/star/datatransfer/MimeContentTypeFactory.hpp>
  27 #include <com/sun/star/lang/IllegalArgumentException.hpp>
  28 #include <comphelper/processfactory.hxx>
  29 #include <cppuhelper/supportsservice.hxx>
  30
  31 iOSClipboard::iOSClipboard()
  32     : WeakComponentImplHelper<XSystemClipboard, XServiceInfo>(m_aMutex)
  33 {
  34     auto xContext = comphelper::getProcessComponentContext();
  35
  36     mrXMimeCntFactory = css::datatransfer::MimeContentTypeFactory::create(xContext);
  37
  38     mpDataFlavorMapper.reset(new DataFlavorMapper());
  39 }
  40
  41 iOSClipboard::~iOSClipboard() {}
  42
  43 css::uno::Reference<css::datatransfer::XTransferable> SAL_CALL iOSClipboard::getContents()
  44 {
  45     osl::MutexGuard aGuard(m_aMutex);
  46
  47     return css::uno::Reference<css::datatransfer::XTransferable>(
  48         new iOSTransferable(mrXMimeCntFactory, mpDataFlavorMapper));
  49 }
  50
  51 void SAL_CALL iOSClipboard::setContents(
  52     const css::uno::Reference<css::datatransfer::XTransferable>& xTransferable,
  53     const css::uno::Reference<css::datatransfer::clipboard::XClipboardOwner>& /*xClipboardOwner*/)
  54 {
  55     NSArray* types = xTransferable.is() ? mpDataFlavorMapper->flavorSequenceToTypesArray(
  56                                               xTransferable->getTransferDataFlavors())
  57                                         : [NSArray array];
  58
  59     osl::ClearableMutexGuard aGuard(m_aMutex);
  60
  61     NSMutableDictionary* dict = [NSMutableDictionary dictionaryWithCapacity:1];
  62     NSArray* array = @[ dict ];
  63
  64     for (sal_uInt32 i = 0; i < [types count]; ++i)
  65     {
  66         DataProviderPtr_t dp = mpDataFlavorMapper->getDataProvider(types[i], xTransferable);
  67
  68         if (dp.get() != nullptr)
  69         {
  70             NSData* pBoardData = (NSData*)dp->getSystemData();
  71             dict[types[i]] = pBoardData;
  72         }
  73     }
  74     SAL_INFO("vcl.ios.clipboard", "Setting pasteboard items: " << NSDictionaryKeysToOUString(dict));
  75     [[UIPasteboard generalPasteboard] setItems:array options:@{}];
  76
  77     // We don't keep a copy of the clipboard contents around in-process, so fire the lost clipboard
  78     // ownership event right away.
  79     // fireLostClipboardOwnershipEvent(xClipboardOwner, xTransferable);
  80
  81     // fireClipboardChangedEvent(xTransferable);
  82 }
  83
  84 OUString SAL_CALL iOSClipboard::getName() { return OUString(); }
  85
  86 sal_Int8 SAL_CALL iOSClipboard::getRenderingCapabilities() { return 0; }
  87
  88 void SAL_CALL iOSClipboard::addClipboardListener(
  89     const css::uno::Reference<css::datatransfer::clipboard::XClipboardListener>& listener)
  90 {
  91     osl::MutexGuard aGuard(m_aMutex);
  92
  93     if (!listener.is())
  94         throw css::lang::IllegalArgumentException(
  95             "empty reference", static_cast<css::datatransfer::clipboard::XClipboardEx*>(this), 1);
  96
  97     mClipboardListeners.push_back(listener);
  98 }
  99
 100 void SAL_CALL iOSClipboard::removeClipboardListener(
 101     const css::uno::Reference<css::datatransfer::clipboard::XClipboardListener>& listener)
 102 {
 103     osl::MutexGuard aGuard(m_aMutex);
 104
 105     if (!listener.is())
 106         throw css::lang::IllegalArgumentException(
 107             "empty reference", static_cast<css::datatransfer::clipboard::XClipboardEx*>(this), 1);
 108
 109     mClipboardListeners.remove(listener);
 110 }
 111
 112 void iOSClipboard::fireClipboardChangedEvent(
 113     css::uno::Reference<css::datatransfer::XTransferable> xNewContents)
 114 {
 115     osl::ClearableMutexGuard aGuard(m_aMutex);
 116
 117     std::list<css::uno::Reference<css::datatransfer::clipboard::XClipboardListener>> listeners(
 118         mClipboardListeners);
 119     css::datatransfer::clipboard::ClipboardEvent aEvent;
 120
 121     if (!listeners.empty())
 122     {
 123         aEvent = css::datatransfer::clipboard::ClipboardEvent(static_cast<OWeakObject*>(this),
 124                                                               xNewContents);
 125     }
 126
 127     aGuard.clear();
 128
 129     while (!listeners.empty())
 130     {
 131         if (listeners.front().is())
 132         {
 133             try
 134             {
 135                 listeners.front()->changedContents(aEvent);
 136             }
 137             catch (const css::uno::RuntimeException&)
 138             {
 139             }
 140         }
 141         listeners.pop_front();
 142     }
 143 }
 144
 145 void iOSClipboard::fireLostClipboardOwnershipEvent(
 146     css::uno::Reference<css::datatransfer::clipboard::XClipboardOwner> const& oldOwner,
 147     css::uno::Reference<css::datatransfer::XTransferable> const& oldContent)
 148 {
 149     assert(oldOwner.is());
 150
 151     try
 152     {
 153         oldOwner->lostOwnership(static_cast<css::datatransfer::clipboard::XClipboardEx*>(this),
 154                                 oldContent);
 155     }
 156     catch (const css::uno::RuntimeException&)
 157     {
 158     }
 159 }
 160
 161 OUString SAL_CALL iOSClipboard::getImplementationName()
 162 {
 163     return OUString("com.sun.star.datatransfer.clipboard.iOSClipboard");
 164 }
 165
 166 sal_Bool SAL_CALL iOSClipboard::supportsService(const OUString& ServiceName)
 167 {
 168     return cppu::supportsService(this, ServiceName);
 169 }
 170
 171 css::uno::Sequence<OUString> SAL_CALL iOSClipboard::getSupportedServiceNames()
 172 {
 173     return { OUString("com.sun.star.datatransfer.clipboard.SystemClipboard") };
 174 }
 175
 176 css::uno::Reference<css::uno::XInterface>
 177 IosSalInstance::CreateClipboard(const css::uno::Sequence<css::uno::Any>&)
 178 {
 179     return css::uno::Reference<css::uno::XInterface>(
 180         static_cast<cppu::OWeakObject*>(new iOSClipboard()));
 181 }
 182
 183 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */