etc/NSIS/setup.nsi

   1 ; ///////////////////////////////////////////////////////////////////////////////
   2 ; // LameXP - Audio Encoder Front-End
   3 ; // Copyright (C) 2004-2018 LoRd_MuldeR <MuldeR2@GMX.de>
   4 ; //
   5 ; // This program is free software; you can redistribute it and/or modify
   6 ; // it under the terms of the GNU General Public License as published by
   7 ; // the Free Software Foundation; either version 2 of the License, or
   8 ; // (at your option) any later version.
   9 ; //
  10 ; // This program is distributed in the hope that it will be useful,
  11 ; // but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ; // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ; // GNU General Public License for more details.
  14 ; //
  15 ; // You should have received a copy of the GNU General Public License along
  16 ; // with this program; if not, write to the Free Software Foundation, Inc.,
  17 ; // 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18 ; //
  19 ; // http://www.gnu.org/licenses/gpl-2.0.txt
  20 ; ///////////////////////////////////////////////////////////////////////////////
  21
  22
  23 ;--------------------------------
  24 ;Basic Defines
  25 ;--------------------------------
  26
  27 !ifndef NSIS_UNICODE
  28   !error "NSIS_UNICODE is undefined, please compile with Unicode NSIS !!!"
  29 !endif
  30
  31 !ifndef LAMEXP_VERSION
  32   !error "LAMEXP_VERSION is not defined !!!"
  33 !endif
  34 !ifndef LAMEXP_BUILD
  35   !error "LAMEXP_BUILD is not defined !!!"
  36 !endif
  37 !ifndef LAMEXP_INSTTYPE
  38   !error "LAMEXP_INSTTYPE is not defined !!!"
  39 !endif
  40 !ifndef LAMEXP_PATCH
  41   !error "LAMEXP_PATCH is not defined !!!"
  42 !endif
  43 !ifndef LAMEXP_DATE
  44   !error "LAMEXP_DATE is not defined !!!"
  45 !endif
  46 !ifndef LAMEXP_OUTPUT_FILE
  47   !error "LAMEXP_OUTPUT_FILE is not defined !!!"
  48 !endif
  49 !ifndef LAMEXP_SOURCE_PATH
  50   !error "LAMEXP_SOURCE_PATH is not defined !!!"
  51 !endif
  52
  53 ;UUID
  54 !define MyRegPath "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{FBD7A67D-D700-4043-B54F-DD106D00F308}"
  55
  56 ;App Paths
  57 !define AppPaths "SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths"
  58
  59 ;Web-Site
  60 !define MyWebSite "http://muldersoft.com/"
  61
  62
  63 ;--------------------------------
  64 ;Check for Pre-Release
  65 ;--------------------------------
  66
  67 !define LAMEXP_IS_PRERELEASE
  68
  69 !if '${LAMEXP_INSTTYPE}' == 'Final'
  70   !undef LAMEXP_IS_PRERELEASE
  71 !endif
  72 !if '${LAMEXP_INSTTYPE}' == 'Hotfix'
  73   !undef LAMEXP_IS_PRERELEASE
  74 !endif
  75
  76
  77 ;--------------------------------
  78 ;Manifest
  79 ;--------------------------------
  80
  81 !tempfile PACKHDRTEMP
  82 !packhdr "${PACKHDRTEMP}" '"..\..\..\Prerequisites\MSVC\redist\bin\mt.exe" -manifest "setup.manifest" -outputresource:"${PACKHDRTEMP};1" && "..\..\..\Prerequisites\UPX\upx.exe" --brute "${PACKHDRTEMP}"'
  83
  84
  85 ;--------------------------------
  86 ;Includes
  87 ;--------------------------------
  88
  89 !include `MUI2.nsh`
  90 !include `WinVer.nsh`
  91 !include `x64.nsh`
  92 !include `StdUtils.nsh`
  93
  94
  95 ;--------------------------------
  96 ;Installer Attributes
  97 ;--------------------------------
  98
  99 RequestExecutionLevel admin
 100 ShowInstDetails show
 101 ShowUninstDetails show
 102 Name "LameXP v${LAMEXP_VERSION} ${LAMEXP_INSTTYPE}-${LAMEXP_PATCH} [Build #${LAMEXP_BUILD}]"
 103 OutFile "${LAMEXP_OUTPUT_FILE}"
 104 BrandingText "Date created: ${LAMEXP_DATE} [Build #${LAMEXP_BUILD}]"
 105 InstallDir "$PROGRAMFILES\MuldeR\LameXP"
 106 InstallDirRegKey HKLM "${MyRegPath}" "InstallLocation"
 107
 108
 109 ;--------------------------------
 110 ;Compressor
 111 ;--------------------------------
 112
 113 SetCompressor /SOLID LZMA
 114 SetCompressorDictSize 64
 115
 116
 117 ;--------------------------------
 118 ;Reserved Files
 119 ;--------------------------------
 120
 121 ReserveFile "${NSISDIR}\Plugins\Aero.dll"
 122 ReserveFile "${NSISDIR}\Plugins\LangDLL.dll"
 123 ReserveFile "${NSISDIR}\Plugins\LockedList.dll"
 124 ReserveFile "${NSISDIR}\Plugins\LockedList64.dll"
 125 ReserveFile "${NSISDIR}\Plugins\nsDialogs.dll"
 126 ReserveFile "${NSISDIR}\Plugins\nsExec.dll"
 127 ReserveFile "${NSISDIR}\Plugins\StartMenu.dll"
 128 ReserveFile "${NSISDIR}\Plugins\StdUtils.dll"
 129 ReserveFile "${NSISDIR}\Plugins\System.dll"
 130 ReserveFile "${NSISDIR}\Plugins\UserInfo.dll"
 131
 132
 133 ;--------------------------------
 134 ;Variables
 135 ;--------------------------------
 136
 137 Var StartMenuFolder
 138
 139
 140 ;--------------------------------
 141 ;Version Info
 142 ;--------------------------------
 143
 144 !searchreplace PRODUCT_VERSION_DATE "${LAMEXP_DATE}" "-" "."
 145 VIProductVersion "${PRODUCT_VERSION_DATE}.${LAMEXP_BUILD}"
 146
 147 VIAddVersionKey "Author" "LoRd_MuldeR <mulder2@gmx.de>"
 148 VIAddVersionKey "Comments" "This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or (at your option) any later version."
 149 VIAddVersionKey "CompanyName" "Free Software Foundation"
 150 VIAddVersionKey "FileDescription" "LameXP v${LAMEXP_VERSION} ${LAMEXP_INSTTYPE}-${LAMEXP_PATCH} [Build #${LAMEXP_BUILD}]"
 151 VIAddVersionKey "FileVersion" "${PRODUCT_VERSION_DATE}.${LAMEXP_BUILD} (${LAMEXP_VERSION})"
 152 VIAddVersionKey "LegalCopyright" "Copyright 2004-2018 LoRd_MuldeR"
 153 VIAddVersionKey "LegalTrademarks" "GNU"
 154 VIAddVersionKey "OriginalFilename" "LameXP.${LAMEXP_DATE}.exe"
 155 VIAddVersionKey "ProductName" "LameXP - Audio Encoder Frontend"
 156 VIAddVersionKey "ProductVersion" "${LAMEXP_VERSION}, Build #${LAMEXP_BUILD} (${LAMEXP_DATE})"
 157 VIAddVersionKey "Website" "${MyWebSite}"
 158
 159
 160 ;--------------------------------
 161 ;MUI2 Interface Settings
 162 ;--------------------------------
 163
 164 !define MUI_ABORTWARNING
 165 !define MUI_STARTMENUPAGE_REGISTRY_ROOT HKLM
 166 !define MUI_STARTMENUPAGE_REGISTRY_KEY "${MyRegPath}"
 167 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "StartmenuFolder"
 168 !define MUI_LANGDLL_REGISTRY_ROOT HKLM
 169 !define MUI_LANGDLL_REGISTRY_KEY "${MyRegPath}"
 170 !define MUI_LANGDLL_REGISTRY_VALUENAME "SetupLanguage"
 171 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "LameXP v${LAMEXP_VERSION}"
 172 !define MUI_FINISHPAGE_NOAUTOCLOSE
 173 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
 174 !define MUI_FINISHPAGE_RUN
 175 !define MUI_FINISHPAGE_RUN_FUNCTION RunAppFunction
 176 !define MUI_FINISHPAGE_SHOWREADME
 177 !define MUI_FINISHPAGE_SHOWREADME_FUNCTION ShowReadmeFunction
 178 !define MUI_FINISHPAGE_LINK ${MyWebSite}
 179 !define MUI_FINISHPAGE_LINK_LOCATION ${MyWebSite}
 180 !define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\orange-install.ico"
 181 !define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\orange-uninstall.ico"
 182 !define MUI_WELCOMEFINISHPAGE_BITMAP "wizard.bmp"
 183 !define MUI_UNWELCOMEFINISHPAGE_BITMAP "wizard-un.bmp"
 184 !define MUI_HEADERIMAGE
 185 !define MUI_HEADERIMAGE_BITMAP "header.bmp"
 186 !define MUI_HEADERIMAGE_UNBITMAP "header-un.bmp"
 187 !define MUI_LANGDLL_ALLLANGUAGES
 188 !define MUI_CUSTOMFUNCTION_GUIINIT MyGuiInit
 189 !define MUI_CUSTOMFUNCTION_UNGUIINIT un.MyGuiInit
 190 !define MUI_LANGDLL_ALWAYSSHOW
 191
 192
 193 ;--------------------------------
 194 ;MUI2 Pages (Installer)
 195 ;--------------------------------
 196
 197 ;Welcome
 198 !define MUI_PAGE_CUSTOMFUNCTION_PRE SkipIfUnattended
 199 !define MUI_PAGE_CUSTOMFUNCTION_LEAVE CheckForPreRelease
 200 !define MUI_WELCOMEPAGE_TITLE_3LINES
 201 !define MUI_FINISHPAGE_TITLE_3LINES
 202 !insertmacro MUI_PAGE_WELCOME
 203
 204 ;License
 205 !define MUI_PAGE_CUSTOMFUNCTION_PRE SkipIfUnattended
 206 !insertmacro MUI_PAGE_LICENSE "license.rtf"
 207
 208 ;Directory
 209 !define MUI_PAGE_CUSTOMFUNCTION_PRE SkipIfUnattended
 210 !define MUI_PAGE_CUSTOMFUNCTION_SHOW CheckForUpdate
 211 !insertmacro MUI_PAGE_DIRECTORY
 212
 213 ;Startmenu
 214 !define MUI_PAGE_CUSTOMFUNCTION_PRE SkipIfUnattended
 215 !insertmacro MUI_PAGE_STARTMENU Application $StartMenuFolder
 216
 217 ;LockedList
 218 Page Custom LockedListShow
 219
 220 ;Install Files
 221 !insertmacro MUI_PAGE_INSTFILES
 222
 223 ;Finish
 224 !define MUI_PAGE_CUSTOMFUNCTION_PRE SkipIfUnattended
 225 !insertmacro MUI_PAGE_FINISH
 226
 227
 228 ;--------------------------------
 229 ;MUI2 Pages (Uninstaller)
 230 ;--------------------------------
 231
 232 ;Welcome
 233 !define MUI_WELCOMEPAGE_TITLE_3LINES
 234 !define MUI_FINISHPAGE_TITLE_3LINES
 235 !define MUI_PAGE_CUSTOMFUNCTION_PRE un.CheckForcedUninstall
 236 !insertmacro MUI_UNPAGE_WELCOME
 237
 238 ;Confirm
 239 !define MUI_PAGE_CUSTOMFUNCTION_PRE un.CheckForcedUninstall
 240 !insertmacro MUI_UNPAGE_CONFIRM
 241
 242 ;LockedList
 243 UninstPage Custom un.LockedListShow
 244
 245 ;Uninstall
 246 !insertmacro MUI_UNPAGE_INSTFILES
 247
 248 ;Finish
 249 !define MUI_PAGE_CUSTOMFUNCTION_PRE un.CheckForcedUninstall
 250 !insertmacro MUI_UNPAGE_FINISH
 251
 252
 253 ;--------------------------------
 254 ;Languages
 255 ;--------------------------------
 256
 257 !insertmacro MUI_LANGUAGE "English" ;first language is the default language
 258 !insertmacro MUI_LANGUAGE "German"
 259 !insertmacro MUI_LANGUAGE "Spanish"
 260 !insertmacro MUI_LANGUAGE "Russian"
 261 !insertmacro MUI_LANGUAGE "Ukrainian"
 262 !insertmacro MUI_LANGUAGE "Polish"
 263 !insertmacro MUI_LANGUAGE "Hungarian"
 264
 265 ; !insertmacro MUI_LANGUAGE "French"
 266 ; !insertmacro MUI_LANGUAGE "SpanishInternational"
 267 ; !insertmacro MUI_LANGUAGE "SimpChinese"
 268 ; !insertmacro MUI_LANGUAGE "TradChinese"
 269 ; !insertmacro MUI_LANGUAGE "Japanese"
 270 ; !insertmacro MUI_LANGUAGE "Italian"
 271 ; !insertmacro MUI_LANGUAGE "Dutch"
 272 ; !insertmacro MUI_LANGUAGE "Greek"
 273 ; !insertmacro MUI_LANGUAGE "Romanian"
 274 ; !insertmacro MUI_LANGUAGE "Serbian"
 275 ; !insertmacro MUI_LANGUAGE "SerbianLatin"
 276 ; !insertmacro MUI_LANGUAGE "Arabic"
 277 ; !insertmacro MUI_LANGUAGE "Portuguese"
 278 ; !insertmacro MUI_LANGUAGE "Afrikaans"
 279 ; !insertmacro MUI_LANGUAGE "Malay"
 280 ; !insertmacro MUI_LANGUAGE "Indonesian"
 281
 282
 283 ;--------------------------------
 284 ;Translation
 285 ;--------------------------------
 286
 287 ;English
 288 !include "..\Translation\Blank.nsh"
 289
 290 ;German
 291 !include "..\Translation\LameXP_DE.nsh"
 292
 293 ;Spanish
 294 !include "..\Translation\LameXP_ES.nsh"
 295
 296 ;Russian
 297 !include "..\Translation\LameXP_RU.nsh"
 298
 299 ;Ukrainian
 300 !include "..\Translation\LameXP_UK.nsh"
 301
 302 ;Polish
 303 !include "..\Translation\LameXP_PL.nsh"
 304
 305 ;Hungarian
 306 !include "..\Translation\LameXP_HU.nsh"
 307
 308
 309 ;--------------------------------
 310 ;LogicLib Extensions
 311 ;--------------------------------
 312
 313 !macro _UnattendedMode _a _b _t _f
 314         !insertmacro _LOGICLIB_TEMP
 315         ${StdUtils.TestParameter} $_LOGICLIB_TEMP "Update"
 316         StrCmp "$_LOGICLIB_TEMP" "true" `${_t}` `${_f}`
 317 !macroend
 318 !define UnattendedMode `"" UnattendedMode ""`
 319
 320 !macro _ForcedMode _a _b _t _f
 321         !insertmacro _LOGICLIB_TEMP
 322         ${StdUtils.TestParameter} $_LOGICLIB_TEMP "Force"
 323         StrCmp "$_LOGICLIB_TEMP" "true" `${_t}` `${_f}`
 324 !macroend
 325 !define ForcedMode `"" ForcedMode ""`
 326
 327 !macro _ValidFileName _a _b _t _f
 328         !insertmacro _LOGICLIB_TEMP
 329         ${StdUtils.ValidFileName} $_LOGICLIB_TEMP `${_b}`
 330         StrCmp "$_LOGICLIB_TEMP" "ok" `${_t}` `${_f}`
 331 !macroend
 332 !define ValidFileName `"" ValidFileName`
 333
 334
 335 ;--------------------------------
 336 ;Installer initialization
 337 ;--------------------------------
 338
 339 Function .onInit
 340         InitPluginsDir
 341
 342         ; --------
 343
 344         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "{2B3D1EBF-B3B6-4E93-92B9-6853029A7162}") i .r1 ?e'
 345         Pop $0
 346         ${If} $0 <> 0
 347                 MessageBox MB_ICONSTOP|MB_TOPMOST "Sorry, the installer is already running!"
 348                 Quit
 349         ${EndIf}
 350
 351         ; --------
 352
 353         # Running on Windows NT family?
 354         ${IfNot} ${IsNT}
 355                 MessageBox MB_TOPMOST|MB_ICONSTOP "Sorry, this application does *not* support Windows 9x/ME!"
 356                 ExecShell "open" "http://windows.microsoft.com/"
 357                 Quit
 358         ${EndIf}
 359
 360         # Running on Windows XP or later?
 361         ${If} ${AtMostWin2000}
 362                 MessageBox MB_TOPMOST|MB_ICONSTOP "Sorry, but your operating system is *not* supported anymore.$\nInstallation will be aborted!$\n$\nThe minimum required platform is Windows XP (Service Pack 3)."
 363                 ExecShell "open" "http://windows.microsoft.com/"
 364                 Quit
 365         ${EndIf}
 366
 367         # If on Windows XP, is the required Service Pack installed?
 368         ${If} ${IsWinXP}
 369                 ${IfNot} ${RunningX64} # Windows XP 32-Bit, requires Service Pack 3
 370                 ${AndIf} ${AtMostServicePack} 2
 371                         MessageBox MB_TOPMOST|MB_ICONEXCLAMATION "This application requires Service Pack 3 for Windows XP.$\nPlease install the required Service Pack and retry!"
 372                         Quit
 373                 ${EndIf}
 374                 ${If} ${RunningX64} # Windows XP 64-Bit, requires Service Pack 2
 375                 ${AndIf} ${AtMostServicePack} 1
 376                         MessageBox MB_TOPMOST|MB_ICONEXCLAMATION "This application requires Service Pack 2 for Windows XP x64.$\nPlease install the required Service Pack and retry!"
 377                         Quit
 378                 ${EndIf}
 379                 ${IfNot} ${UnattendedMode}
 380                         ${If} ${Cmd} `MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL|MB_DEFBUTTON2 "It appears that you are still running Windows XP, which reached $\"end of life$\" in April 2014 and therefore will not receive any updates or bug fixes anymore - not even for critical security vulnerabilities! We highly recommend updating to a contemporary operating system.$\n$\nClick 'OK' to proceed with the installation, or click 'Cancel' to abort." IDCANCEL`
 381                                 Quit
 382                         ${EndIf}
 383                 ${EndIf}
 384         ${EndIf}
 385
 386         # Running on Windows Vista?
 387         ${If} ${IsWinVista}
 388                 ${If} ${AtMostServicePack} 1
 389                         MessageBox MB_TOPMOST|MB_ICONEXCLAMATION "This application requires Service Pack 2 for Windows Vista.$\nPlease install the required Service Pack and retry!"
 390                         Quit
 391                 ${EndIf}
 392                 ${IfNot} ${UnattendedMode}
 393                         ${If} ${Cmd} `MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL|MB_DEFBUTTON2 "It appears that you are still running Windows Vista, which reached $\"end of life$\" in April 2017 and therefore will not receive any updates or bug fixes anymore - not even for critical security vulnerabilities! We highly recommend updating to a contemporary operating system.$\n$\nClick 'OK' to proceed with the installation, or click 'Cancel' to abort." IDCANCEL`
 394                                 Quit
 395                         ${EndIf}
 396                 ${EndIf}
 397         ${EndIf}
 398
 399         ; --------
 400
 401         ${IfNot} ${UnattendedMode}
 402                 !insertmacro MUI_LANGDLL_DISPLAY
 403         ${EndIf}
 404
 405         ; --------
 406
 407         UserInfo::GetAccountType
 408         Pop $0
 409         ${If} $0 != "Admin"
 410                 MessageBox MB_ICONSTOP|MB_TOPMOST "Your system requires administrative permissions in order to install this software."
 411                 SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
 412                 Quit
 413         ${EndIf}
 414 FunctionEnd
 415
 416 Function un.onInit
 417         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "{2B3D1EBF-B3B6-4E93-92B9-6853029A7162}") i .r1 ?e'
 418         Pop $0
 419         ${If} $0 <> 0
 420                 MessageBox MB_ICONSTOP|MB_TOPMOST "Sorry, the un-installer is already running!"
 421                 Quit
 422         ${EndIf}
 423
 424         ${IfNot} ${ForcedMode}
 425                 !insertmacro MUI_LANGDLL_DISPLAY
 426         ${EndIf}
 427
 428         ; --------
 429
 430         UserInfo::GetAccountType
 431         Pop $0
 432         ${If} $0 != "Admin"
 433                 MessageBox MB_ICONSTOP|MB_TOPMOST "Your system requires administrative permissions in order to install this software."
 434                 SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
 435                 Quit
 436         ${EndIf}
 437 FunctionEnd
 438
 439
 440 ;--------------------------------
 441 ;GUI initialization
 442 ;--------------------------------
 443
 444 Function MyGuiInit
 445         StrCpy $0 $HWNDPARENT
 446         System::Call "user32::SetWindowPos(i r0, i -1, i 0, i 0, i 0, i 0, i 3)"
 447         Aero::Apply
 448 FunctionEnd
 449
 450 Function un.MyGuiInit
 451         StrCpy $0 $HWNDPARENT
 452         System::Call "user32::SetWindowPos(i r0, i -1, i 0, i 0, i 0, i 0, i 3)"
 453         Aero::Apply
 454 FunctionEnd
 455
 456
 457 ;--------------------------------
 458 ;Macros & Auxiliary Functions
 459 ;--------------------------------
 460
 461 !macro PrintProgress Text
 462         SetDetailsPrint textonly
 463         DetailPrint '${Text}'
 464         SetDetailsPrint listonly
 465         Sleep 1000
 466 !macroend
 467
 468 !macro CreateWebLink ShortcutFile TargetURL
 469         Push $0
 470         Push $1
 471         StrCpy $0 "${ShortcutFile}"
 472         StrCpy $1 "${TargetURL}"
 473         Call _CreateWebLink
 474         Pop $1
 475         Pop $0
 476 !macroend
 477
 478 Function _CreateWebLink
 479         FlushINI "$0"
 480         SetFileAttributes "$0" FILE_ATTRIBUTE_NORMAL
 481         DeleteINISec "$0" "DEFAULT"
 482         DeleteINISec "$0" "InternetShortcut"
 483         WriteINIStr "$0" "DEFAULT" "BASEURL" "$1"
 484         WriteINIStr "$0" "InternetShortcut" "ORIGURL" "$1"
 485         WriteINIStr "$0" "InternetShortcut" "URL" "$1"
 486         WriteINIStr "$0" "InternetShortcut" "IconFile" "$SYSDIR\SHELL32.dll"
 487         WriteINIStr "$0" "InternetShortcut" "IconIndex" "150"
 488         FlushINI "$0"
 489         SetFileAttributes "$0" FILE_ATTRIBUTE_READONLY
 490 FunctionEnd
 491
 492 !macro GetExecutableName OutVar
 493         ${StdUtils.GetParameter} ${OutVar} "Update" ""
 494         ${StdUtils.TrimStr} ${OutVar}
 495         ${If} "${OutVar}" == ""
 496         ${OrIfNot} ${ValidFileName} "${OutVar}"
 497                 StrCpy ${OutVar} "LameXP.exe"
 498         ${EndIf}
 499 !macroend
 500
 501 !macro DisableNextButton TmpVar
 502         GetDlgItem ${TmpVar} $HWNDPARENT 1
 503         EnableWindow ${TmpVar} 0
 504 !macroend
 505
 506 !macro DisableBackButton TmpVar
 507         GetDlgItem ${TmpVar} $HWNDPARENT 3
 508         EnableWindow ${TmpVar} 0
 509 !macroend
 510
 511 !macro CleanUpFiles options
 512         Delete ${options} "$INSTDIR\Changelog.htm"
 513         Delete ${options} "$INSTDIR\Changelog.html"
 514         Delete ${options} "$INSTDIR\Contributors.txt"
 515         Delete ${options} "$INSTDIR\Copying.txt"
 516         Delete ${options} "$INSTDIR\FAQ.html"
 517         Delete ${options} "$INSTDIR\Howto.html"
 518         Delete ${options} "$INSTDIR\LameEnc.sys"
 519         Delete ${options} "$INSTDIR\LameXP*.exe"
 520         Delete ${options} "$INSTDIR\LameXP*.exe.sig"
 521         Delete ${options} "$INSTDIR\LameXP*.rcc"
 522         Delete ${options} "$INSTDIR\LameXP*.VisualElementsManifest.xml"
 523         Delete ${options} "$INSTDIR\License.txt"
 524         Delete ${options} "$INSTDIR\Manual.html"
 525         Delete ${options} "$INSTDIR\Readme.htm"
 526         Delete ${options} "$INSTDIR\ReadMe.txt"
 527         Delete ${options} "$INSTDIR\PRE_RELEASE_INFO.txt"
 528         Delete ${options} "$INSTDIR\Settings.cfg"
 529         Delete ${options} "$INSTDIR\Translate.html"
 530         Delete ${options} "$INSTDIR\Uninstall.exe"
 531         Delete ${options} "$INSTDIR\Qt*.dll"
 532         Delete ${options} "$INSTDIR\MUtils*.dll"
 533         Delete ${options} "$INSTDIR\msvcr*.dll"
 534         Delete ${options} "$INSTDIR\msvcp*.dll"
 535         Delete ${options} "$INSTDIR\concrt*.dll"
 536         Delete ${options} "$INSTDIR\vcruntime*.dll"
 537         Delete ${options} "$INSTDIR\vccorlib*.dll"
 538         Delete ${options} "$INSTDIR\api-ms-*.dll"
 539         Delete ${options} "$INSTDIR\ucrtbase.dll"
 540
 541         RMDir /r ${options} "$INSTDIR\cache"
 542         RMDir /r ${options} "$INSTDIR\img"
 543         RMDir /r ${options} "$INSTDIR\imageformats"
 544         RMDir /r ${options} "$INSTDIR\redist"
 545 !macroend
 546
 547 ;--------------------------------
 548 ;Install Files
 549 ;--------------------------------
 550
 551 Section "-PreInit"
 552         SetShellVarContext all
 553         SetOutPath "$INSTDIR"
 554 SectionEnd
 555
 556 Section "-Clean Up Old Cruft"
 557         !insertmacro PrintProgress "$(LAMEXP_LANG_STATUS_CLEANUP)"
 558         !insertmacro CleanUpFiles ""
 559 SectionEnd
 560
 561 Section "!Install Files"
 562         !insertmacro PrintProgress "$(LAMEXP_LANG_STATUS_INSTFILES)"
 563
 564         DeleteOldBinary:
 565         !insertmacro GetExecutableName $R0
 566         ClearErrors
 567         Delete "$INSTDIR\$R0"
 568
 569         ${If} ${Errors}
 570                 MessageBox MB_TOPMOST|MB_ICONSTOP|MB_RETRYCANCEL 'Could not delete old "$R0" file. Is LameXP still running?' IDRETRY DeleteOldBinary
 571                 Abort "Could not delete old binary!"
 572         ${EndIf}
 573
 574         File /a `/oname=$R0` `${LAMEXP_SOURCE_PATH}\LameXP.exe`
 575         File /nonfatal /a /r `${LAMEXP_SOURCE_PATH}\*.dll`
 576
 577         ${StdUtils.GetFileNamePart} $R1 "$R0"
 578         File /a `/oname=$R1.VisualElementsManifest.xml` `${LAMEXP_SOURCE_PATH}\LameXP.VisualElementsManifest.xml`
 579
 580         File /a /r `${LAMEXP_SOURCE_PATH}\*.txt`
 581         File /a /r `${LAMEXP_SOURCE_PATH}\*.html`
 582         File /a /r `${LAMEXP_SOURCE_PATH}\*.png`
 583 SectionEnd
 584
 585 # Section "-Install VCRedist"
 586 #       !insertmacro PrintProgress "$(LAMEXP_LANG_STATUS_VCREDIST)"
 587 #       File /a `/oname=$PLUGINSDIR\vcredist_x86.exe` `${LAMEXP_SOURCE_PATH}\redist\vcredist_x86.exe`
 588 #       ExecWait '"$PLUGINSDIR\vcredist_x86.exe" /install /passive /norestart'
 589 # SectionEnd
 590
 591 Section "-Write Uninstaller"
 592         !insertmacro PrintProgress "$(LAMEXP_LANG_STATUS_MAKEUNINST)"
 593         WriteUninstaller "$INSTDIR\Uninstall.exe"
 594 SectionEnd
 595
 596 Section "-Create Shortcuts"
 597         !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 598                 !insertmacro PrintProgress "$(LAMEXP_LANG_STATUS_SHORTCUTS)"
 599                 CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
 600
 601                 SetShellVarContext current
 602
 603                 Delete "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 604                 Delete "$SMPROGRAMS\$StartMenuFolder\*.pif"
 605                 Delete "$SMPROGRAMS\$StartMenuFolder\*.url"
 606
 607                 SetShellVarContext all
 608
 609                 Delete "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 610                 Delete "$SMPROGRAMS\$StartMenuFolder\*.pif"
 611                 Delete "$SMPROGRAMS\$StartMenuFolder\*.url"
 612
 613                 !insertmacro GetExecutableName $R0
 614
 615                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\LameXP.lnk"                        "$INSTDIR\$R0" "" "$INSTDIR\$R0" 0
 616                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(LAMEXP_LANG_LINK_LICENSE).lnk"   "$INSTDIR\License.txt"
 617                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(LAMEXP_LANG_LINK_CHANGELOG).lnk" "$INSTDIR\Changelog.html"
 618                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(LAMEXP_LANG_LINK_TRANSLATE).lnk" "$INSTDIR\Translate.html"
 619                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(LAMEXP_LANG_LINK_MANUAL).lnk"    "$INSTDIR\Manual.html"
 620                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(LAMEXP_LANG_LINK_UNINSTALL).lnk" "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0
 621
 622                 !insertmacro CreateWebLink "$SMPROGRAMS\$StartMenuFolder\Official LameXP Homepage.url" "${MyWebSite}"
 623                 !insertmacro CreateWebLink "$SMPROGRAMS\$StartMenuFolder\Doom9's Forum.url"            "http://forum.doom9.org/"
 624                 !insertmacro CreateWebLink "$SMPROGRAMS\$StartMenuFolder\Bug Tracker.url"              "https://github.com/lordmulder/LameXP/issues"
 625                 !insertmacro CreateWebLink "$SMPROGRAMS\$StartMenuFolder\RareWares.org.url"            "http://rarewares.org/"
 626                 !insertmacro CreateWebLink "$SMPROGRAMS\$StartMenuFolder\Hydrogenaudio Forums.url"     "http://www.hydrogenaudio.org/"
 627
 628                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\LameXP.lnk"
 629                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "LameXP.lnk" ${StdUtils.Const.ShellVerb.PinToTaskbar}
 630                         DetailPrint 'Pin: "$SMPROGRAMS\$StartMenuFolder\LameXP.lnk" -> $R1'
 631                 ${EndIf}
 632         !insertmacro MUI_STARTMENU_WRITE_END
 633 SectionEnd
 634
 635 Section "-Update Registry"
 636         !insertmacro PrintProgress "$(LAMEXP_LANG_STATUS_REGISTRY)"
 637
 638         !insertmacro GetExecutableName $R0
 639         WriteRegStr HKLM "${MyRegPath}" "InstallLocation" "$INSTDIR"
 640         WriteRegStr HKLM "${MyRegPath}" "ExecutableName" "$R0"
 641         WriteRegStr HKLM "${MyRegPath}" "DisplayIcon" "$INSTDIR\$R0,0"
 642         WriteRegStr HKLM "${MyRegPath}" "UninstallString" '"$INSTDIR\Uninstall.exe"'
 643         WriteRegStr HKLM "${MyRegPath}" "DisplayName" "LameXP v${LAMEXP_VERSION}"
 644         WriteRegStr HKLM "${MyRegPath}" "Publisher" "LoRd_MuldeR <mulder2@gmx.de>"
 645         WriteRegStr HKLM "${MyRegPath}" "DisplayVersion" "${LAMEXP_VERSION} ${LAMEXP_INSTTYPE}-${LAMEXP_PATCH} [Build #${LAMEXP_BUILD}]"
 646         WriteRegStr HKLM "${MyRegPath}" "URLInfoAbout" "${MyWebSite}"
 647         WriteRegStr HKLM "${MyRegPath}" "URLUpdateInfo" "${MyWebSite}"
 648
 649         DeleteRegKey HKCU "${AppPaths}\LameXP.exe"
 650         WriteRegStr HKLM "${AppPaths}\LameXP.exe" "" "$INSTDIR\$R0"
 651         WriteRegStr HKLM "${AppPaths}\LameXP.exe" "Path" "$INSTDIR"
 652 SectionEnd
 653
 654 Section "-Finished"
 655         !insertmacro PrintProgress "$(MUI_TEXT_FINISH_TITLE)."
 656
 657 !ifdef LAMEXP_IS_PRERELEASE
 658         ${If} ${FileExists} "$INSTDIR\PRE_RELEASE_INFO.txt"
 659                 ${StdUtils.ExecShellAsUser} $R1 "$INSTDIR\PRE_RELEASE_INFO.txt" "open" ""
 660         ${EndIf}
 661 !endif
 662
 663         ${IfThen} ${UnattendedMode} ${|} SetAutoClose true ${|}
 664 SectionEnd
 665
 666
 667 ;--------------------------------
 668 ;Uninstaller
 669 ;--------------------------------
 670
 671 Section "Uninstall"
 672         SetOutPath "$EXEDIR"
 673         !insertmacro PrintProgress "$(LAMEXP_LANG_STATUS_UNINSTALL)"
 674
 675         ; --------------
 676         ; Startmenu
 677         ; --------------
 678
 679         !insertmacro MUI_STARTMENU_GETFOLDER Application $StartMenuFolder
 680         ${IfNot} "$StartMenuFolder" == ""
 681                 SetShellVarContext current
 682                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\LameXP.lnk"
 683                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "LameXP.lnk" ${StdUtils.Const.ShellVerb.UnpinFromTaskbar}
 684                         DetailPrint 'Unpin: "$SMPROGRAMS\$StartMenuFolder\LameXP.lnk" -> $R1'
 685                 ${EndIf}
 686                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\*.*"
 687                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 688                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.url"
 689                         RMDir "$SMPROGRAMS\$StartMenuFolder"
 690                 ${EndIf}
 691
 692                 SetShellVarContext all
 693                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\LameXP.lnk"
 694                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "LameXP.lnk" ${StdUtils.Const.ShellVerb.UnpinFromTaskbar}
 695                         DetailPrint 'Unpin: "$SMPROGRAMS\$StartMenuFolder\LameXP.lnk" -> $R1'
 696                 ${EndIf}
 697                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\*.*"
 698                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 699                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.url"
 700                         RMDir "$SMPROGRAMS\$StartMenuFolder"
 701                 ${EndIf}
 702         ${EndIf}
 703
 704         ; --------------
 705         ; Files
 706         ; --------------
 707
 708         ReadRegStr $R0 HKLM "${MyRegPath}" "ExecutableName"
 709         ${IfThen} "$R0" == "" ${|} StrCpy $R0 "LameXP.exe" ${|}
 710         ExecWait '"$INSTDIR\$R0" --uninstall'
 711
 712         Delete /REBOOTOK "$INSTDIR\$R0"
 713         !insertmacro CleanUpFiles /REBOOTOK
 714         RMDir "$INSTDIR"
 715
 716         ; --------------
 717         ; Registry
 718         ; --------------
 719
 720         DeleteRegKey HKLM "${MyRegPath}"
 721         DeleteRegKey HKCU "${MyRegPath}"
 722
 723         DeleteRegKey HKLM "SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{54dcbccb-c905-46dc-b6e6-48563d0e9e55}"
 724         DeleteRegKey HKCU "SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{54dcbccb-c905-46dc-b6e6-48563d0e9e55}"
 725
 726         DeleteRegKey HKLM "${AppPaths}\LameXP.exe"
 727         DeleteRegKey HKCU "${AppPaths}\LameXP.exe"
 728
 729         MessageBox MB_YESNO|MB_TOPMOST "$(LAMEXP_LANG_UNINST_PERSONAL)" IDNO +3
 730         Delete "$LOCALAPPDATA\LoRd_MuldeR\LameXP - Audio Encoder Front-End\config.ini"
 731         Delete "$INSTDIR\*.ini"
 732
 733         !insertmacro PrintProgress "$(MUI_UNTEXT_FINISH_TITLE)."
 734 SectionEnd
 735
 736
 737 ;--------------------------------
 738 ;Check For Update Mode
 739 ;--------------------------------
 740
 741 Function SkipIfUnattended
 742         ${IfThen} ${UnattendedMode} ${|} Abort ${|}
 743 FunctionEnd
 744
 745 Function CheckForUpdate
 746         ${If} "$INSTDIR" == ""
 747         ${OrIf} "$INSTDIR" == "$EXEDIR"
 748         ${OrIfNot} ${FileExists} "$INSTDIR\LameXP.exe"
 749                 Return
 750         ${EndIf}
 751
 752         FindWindow $R0 "#32770" "" $HWNDPARENT
 753         GetDlgItem $R1 $R0 1019
 754         EnableWindow $R1 0
 755
 756         FindWindow $R0 "#32770" "" $HWNDPARENT
 757         GetDlgItem $R1 $R0 1001
 758         EnableWindow $R1 0
 759 FunctionEnd
 760
 761 Function un.CheckForcedUninstall
 762         ${IfThen} ${ForcedMode} ${|} Abort ${|}
 763 FunctionEnd
 764
 765
 766 ;--------------------------------
 767 ;Check For Pre-Release
 768 ;--------------------------------
 769
 770 Function CheckForPreRelease
 771         !ifdef LAMEXP_IS_PRERELEASE
 772                 ${IfNot} ${UnattendedMode}
 773                         MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL "$(LAMEXP_LANG_PRERELEASE_WARNING)" /SD IDOK IDOK +2
 774                         Quit
 775                 ${EndIf}
 776         !endif
 777 FunctionEnd
 778
 779
 780 ;--------------------------------
 781 ;Locked List
 782 ;--------------------------------
 783
 784 !macro _LockedListShow uinst
 785         !insertmacro MUI_HEADER_TEXT "$(LAMEXP_LANG_LOCKEDLIST_HEADER)" "$(LAMEXP_LANG_LOCKEDLIST_TEXT)"
 786         ${If} ${UnattendedMode}
 787                 !insertmacro DisableBackButton $R0
 788         ${EndIf}
 789         ${If} ${RunningX64}
 790                 InitPluginsDir
 791                 File /oname=$PLUGINSDIR\LockedList64.dll `${NSISDIR}\Plugins\LockedList64.dll`
 792         ${EndIf}
 793         !insertmacro GetExecutableName $R0
 794         LockedList::AddModule "\$R0"
 795         ${If} "$R0" != "LameXP.exe"
 796                 LockedList::AddModule "\LameXP.exe"
 797         ${EndIf}
 798         LockedList::AddModule "\Uninstall.exe"
 799         !if ${uinst} < 1
 800                 LockedList::AddModule "\Au_.exe"
 801         !endif
 802         #LockedList::AddFolder "$INSTDIR"
 803         LockedList::Dialog /autonext /heading "$(LAMEXP_LANG_LOCKEDLIST_HEADING)" /noprograms "$(LAMEXP_LANG_LOCKEDLIST_NOPROG)" /searching  "$(LAMEXP_LANG_LOCKEDLIST_SEARCH)" /colheadings "$(LAMEXP_LANG_LOCKEDLIST_COLHDR1)" "$(LAMEXP_LANG_LOCKEDLIST_COLHDR2)"
 804         Pop $R0
 805 !macroend
 806
 807 Function LockedListShow
 808         !insertmacro _LockedListShow 0
 809 FunctionEnd
 810
 811 Function un.LockedListShow
 812         !insertmacro _LockedListShow 1
 813 FunctionEnd
 814
 815
 816 ;--------------------------------
 817 ;Install Success
 818 ;--------------------------------
 819
 820 Function RunAppFunction
 821         !insertmacro DisableNextButton $R0
 822         !insertmacro GetExecutableName $R0
 823         ${StdUtils.ExecShellAsUser} $R1 "$INSTDIR" "explore" ""
 824         ${StdUtils.ExecShellAsUser} $R1 "$INSTDIR\$R0" "open" "--first-run"
 825 FunctionEnd
 826
 827 Function ShowReadmeFunction
 828         !insertmacro DisableNextButton $R0
 829         ${StdUtils.ExecShellAsUser} $R1 "$INSTDIR\Manual.html" "open" ""
 830 FunctionEnd
 831
 832 Function .onInstSuccess
 833         ${If} ${UnattendedMode}
 834                 !insertmacro GetExecutableName $R0
 835                 ${StdUtils.ExecShellAsUser} $R1 "$INSTDIR\$R0" "open" "--first-run"
 836         ${EndIf}
 837 FunctionEnd