etc/Deployment/_revision.bat

   1 @echo off
   2
   3 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" cyan "\n==========================================================================="
   4 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" cyan "Detecting Git revision..."
   5 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" cyan "===========================================================================\n"
   6
   7 :: ---------------------------------------------------------------------------
   8 :: SETUP PATHS
   9 :: ---------------------------------------------------------------------------
  10
  11 call "%~dp0\_paths.bat"
  12 cd /d "%~dp0"
  13
  14 :: ---------------------------------------------------------------------------
  15 :: CLEAR VARIABLES
  16 :: ---------------------------------------------------------------------------
  17
  18 set "GIT_REV_NAME="
  19 set "GIT_REV_HASH="
  20 set "GIT_REV_NMBR="
  21 set "GIT_REV_DATE="
  22 set "GIT_REV_TIME="
  23
  24 :: ---------------------------------------------------------------------------
  25 :: DETECT THE GIT REVISION
  26 :: ---------------------------------------------------------------------------
  27
  28 for /f "usebackq tokens=1" %%i in (`"%PATH_GITWIN%\bin\git.exe" rev-parse --abbrev-ref HEAD`) do (
  29         set "GIT_REV_NAME=%%~i"
  30 )
  31
  32 for /f "usebackq tokens=1" %%i in (`"%PATH_GITWIN%\bin\git.exe" rev-parse --short HEAD`) do (
  33         set "GIT_REV_HASH=%%~i"
  34 )
  35
  36 for /f "usebackq tokens=1" %%i in (`"%PATH_GITWIN%\bin\git.exe" rev-list --count HEAD`) do (
  37         set "GIT_REV_NMBR=%%~i"
  38 )
  39
  40 for /f "usebackq tokens=1,2" %%i in (`"%PATH_GITWIN%\bin\git.exe" log -1 --format^=%%ci HEAD`) do (
  41         set "GIT_REV_DATE=%%~i"
  42         set "GIT_REV_TIME=%%~j"
  43 )
  44
  45 :: ------------------------------------------
  46 :: VALIDATE RESULT
  47 :: ------------------------------------------
  48
  49 if "%GIT_REV_NAME%"=="" goto git_rev_incomplete
  50 if "%GIT_REV_HASH%"=="" goto git_rev_incomplete
  51 if "%GIT_REV_NMBR%"=="" goto git_rev_incomplete
  52 if "%GIT_REV_DATE%"=="" goto git_rev_incomplete
  53 if "%GIT_REV_TIME%"=="" goto git_rev_incomplete
  54 goto git_rev_complete
  55
  56 :git_rev_incomplete
  57 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" red "\nFailed to determine the current Git revision!\n"
  58 pause && exit
  59
  60 :: ------------------------------------------
  61 :: Completed
  62 :: ------------------------------------------
  63
  64 :git_rev_complete
  65 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" yellow "Git revision: %GIT_REV_NAME%+%GIT_REV_NMBR%-%GIT_REV_HASH% [%GIT_REV_DATE%]"