etc/Deployment/_paths.bat

   1 @echo off
   2
   3 :: ------------------------------------------
   4 :: Paths already initialized?
   5 :: ------------------------------------------
   6
   7 if "%_LAMEXP_PATHS_INITIALIZED_%"=="%DATE%" (
   8         goto:eof
   9 )
  10
  11 :: ------------------------------------------
  12 :: Clear Paths
  13 :: ------------------------------------------
  14
  15 set "PATH_UPXBIN="
  16 set "PATH_MKNSIS="
  17 set "PATH_MSCDIR="
  18 set "PATH_QTMSVC="
  19 set "PATH_GNUPG1="
  20 set "PATH_PANDOC="
  21 set "PATH_VCPROJ="
  22
  23 :: ------------------------------------------
  24 :: Setup BUILDENV_TXT
  25 :: ------------------------------------------
  26
  27 set "BUILDENV_TXT=%~dp0\buildenv.txt"
  28 if not "%~1"=="" (
  29         set "BUILDENV_TXT=%~1"
  30 )
  31
  32 if not exist "%BUILDENV_TXT%" (
  33         "%~dp0\..\Utilities\CEcho.exe" red "\nCould not find \"buildenv.txt\" in current directory!\n\nPlease create your \"buildenv.txt\" file from 'buildenv.template.txt' first...\n"
  34         pause && exit
  35 )
  36
  37 :: ------------------------------------------
  38 :: Parse paths from BUILDENV_TXT
  39 :: ------------------------------------------
  40
  41 for /f "tokens=2,*" %%s in (%BUILDENV_TXT%) do (
  42         if "%%s"=="PATH_UPXBIN" set "PATH_UPXBIN=%%~t"
  43         if "%%s"=="PATH_MKNSIS" set "PATH_MKNSIS=%%~t"
  44         if "%%s"=="PATH_MSCDIR" set "PATH_MSCDIR=%%~t"
  45         if "%%s"=="PATH_QTMSVC" set "PATH_QTMSVC=%%~t"
  46         if "%%s"=="PATH_GNUPG1" set "PATH_GNUPG1=%%~t"
  47         if "%%s"=="PATH_PANDOC" set "PATH_PANDOC=%%~t"
  48         if "%%s"=="PATH_VCPROJ" set "PATH_VCPROJ=%%~t"
  49 )
  50
  51 set "BUILDENV_TXT="
  52
  53 :: ------------------------------------------
  54 :: Print all paths
  55 :: ------------------------------------------
  56
  57 "%~dp0\..\Utilities\CEcho.exe" yellow "\n========== BEGIN PATHS =========="
  58 "%~dp0\..\Utilities\CEcho.exe" yellow "PATH_UPXBIN = \"%PATH_UPXBIN:\=\\%\""
  59 "%~dp0\..\Utilities\CEcho.exe" yellow "PATH_MKNSIS = \"%PATH_MKNSIS:\=\\%\""
  60 "%~dp0\..\Utilities\CEcho.exe" yellow "PATH_MSCDIR = \"%PATH_MSCDIR:\=\\%\""
  61 "%~dp0\..\Utilities\CEcho.exe" yellow "PATH_QTMSVC = \"%PATH_QTMSVC:\=\\%\""
  62 "%~dp0\..\Utilities\CEcho.exe" yellow "PATH_GNUPG1 = \"%PATH_GNUPG1:\=\\%\""
  63 "%~dp0\..\Utilities\CEcho.exe" yellow "PATH_PANDOC = \"%PATH_PANDOC:\=\\%\""
  64 "%~dp0\..\Utilities\CEcho.exe" yellow "PATH_VCPROJ = \"%PATH_VCPROJ:\=\\%\""
  65 "%~dp0\..\Utilities\CEcho.exe" yellow "=========== END PATHS ===========\n"
  66
  67 :: ------------------------------------------
  68 :: Validate Paths
  69 :: ------------------------------------------
  70
  71 call:validate_path PATH_UPXBIN "%PATH_UPXBIN%\upx.exe"
  72 call:validate_path PATH_MKNSIS "%PATH_MKNSIS%\makensis.exe"
  73 call:validate_path PATH_MSCDIR "%PATH_MSCDIR%\VC\vcvarsall.bat"
  74 call:validate_path PATH_MSCDIR "%PATH_MSCDIR%\VC\bin\cl.exe"
  75 call:validate_path PATH_QTMSVC "%PATH_QTMSVC%\bin\uic.exe"
  76 call:validate_path PATH_QTMSVC "%PATH_QTMSVC%\bin\moc.exe"
  77 call:validate_path PATH_QTMSVC "%PATH_QTMSVC%\bin\rcc.exe"
  78 call:validate_path PATH_GNUPG1 "%PATH_GNUPG1%\gpg.exe"
  79 call:validate_path PATH_PANDOC "%PATH_PANDOC%\pandoc.exe"
  80 call:validate_path PATH_VCPROJ "%~dp0\..\..\%PATH_VCPROJ%"
  81
  82 :: ------------------------------------------
  83 :: Locate Qt Path
  84 :: ------------------------------------------
  85
  86 if exist "%PATH_QTMSVC%\bin\qtvars.bat" goto:exit_success
  87 if exist "%PATH_QTMSVC%\bin\qtenv2.bat" goto:exit_success
  88
  89 "%~dp0\..\Utilities\CEcho.exe" red "\nCould not find \"qtvars.bat\" or \"qtenv2.bat\" in your Qt path!\n\nPlease check your PATH_QTMSVC path variable and try again...\n"
  90 pause && exit
  91
  92 :: ------------------------------------------
  93 :: Validate Path
  94 :: ------------------------------------------
  95
  96 :validate_path
  97 if not exist "%~2" (
  98         "%~dp0\..\Utilities\CEcho.exe" red "\nPath %1 could not be found!\n\nPlease check your %1 path variable and try again...\n"
  99         pause && exit
 100 )
 101 goto:eof
 102
 103 :: ------------------------------------------
 104 :: Completed
 105 :: ------------------------------------------
 106
 107 :exit_success
 108 set "_LAMEXP_PATHS_INITIALIZED_=%DATE%"