etc/Deployment/_lupdate.bat

   1 @echo off
   2 setlocal ENABLEDELAYEDEXPANSION
   3
   4 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" cyan "\n==========================================================================="
   5 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" cyan "Updating translation files..."
   6 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" cyan "===========================================================================\n"
   7
   8 :: ---------------------------------------------------------------------------
   9 :: SETUP PATHS
  10 :: ---------------------------------------------------------------------------
  11
  12 call "%~dp0\_paths.bat"
  13
  14 if exist "%PATH_QTMSVC%\bin\qtenv2.bat" (
  15         call "%PATH_QTMSVC%\bin\qtenv2.bat"
  16 )
  17
  18 if exist "%PATH_QTMSVC%\bin\qtvars.bat" (
  19         call "%PATH_QTMSVC%\bin\qtvars.bat"
  20 )
  21
  22 :: ---------------------------------------------------------------------------
  23 :: GENERATE THE FILE LIST
  24 :: ---------------------------------------------------------------------------
  25
  26 set "LST_FILE=%TEMP%\~list.%RANDOM%%RANDOM%.tmp"
  27 echo %LST_FILE%
  28 del "%LST_FILE%" 2> NUL
  29
  30 for %%f in ("%~dp0\..\..\gui\*.ui") do (
  31         echo %%f >> "%LST_FILE%"
  32 )
  33 for %%e in (cpp,h) do (
  34         for %%f in ("%~dp0\..\..\src\*.%%e") do (
  35                 echo %%f >> "%LST_FILE%"
  36         )
  37 )
  38
  39 :: ---------------------------------------------------------------------------
  40 :: UPDATE TS FILES
  41 :: ---------------------------------------------------------------------------
  42
  43 for %%f in ("%~dp0\..\Translation\*.ts") do (
  44         del %%f.bak 2> NUL
  45         copy %%f %%f.bak
  46         lupdate.exe "@%LST_FILE%" -no-obsolete -locations absolute -ts %%f
  47         if not "!ERRORLEVEL!"=="0" (
  48                 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" red "\nSomething went wrong^^!\n"
  49                 pause && exit
  50         )
  51 )
  52
  53 lupdate.exe "@%LST_FILE%" -no-obsolete -locations absolute -pluralonly -ts "%~dp0\..\Translation\LameXP_EN.ts"
  54 del "%LST_FILE%"
  55
  56 :: ---------------------------------------------------------------------------
  57 :: GENERATE QM FILES
  58 :: ---------------------------------------------------------------------------
  59
  60 for %%f in ("%~dp0\..\Translation\LameXP_??.ts") do (
  61         lrelease.exe %%f -qm "%~dp0\..\..\res\localization\%%~nf.qm"
  62         if not "!ERRORLEVEL!"=="0" (
  63                 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" red "\nSomething went wrong^^!\n"
  64                 pause && exit
  65         )
  66 )