src/utils/Parser.vala

   1 using GLib;
   2 using Gee;
   3 using Soup;
   4
   5 namespace GameHub.Utils
   6 {
   7         public class Parser
   8         {
   9                 private static string load_file(string path, string file="")
  10                 {
  11                         var f = FSUtils.file(path, file);
  12                         if(!f.query_exists()) return "";
  13                         string data;
  14                         try
  15                         {
  16                                 FileUtils.get_contents(f.get_path(), out data);
  17                         }
  18                         catch(Error e)
  19                         {
  20                                 warning(e.message);
  21                         }
  22                         return data;
  23                 }
  24
  25                 private static Message prepare_message(string url, string method="GET", string? auth = null, HashMap<string, string>? headers = null)
  26                 {
  27                         var message = new Message(method, url);
  28
  29                         if(auth != null)
  30                         {
  31                                 message.request_headers.append("Authorization", "Bearer " + auth);
  32                         }
  33
  34                         if(headers != null)
  35                         {
  36                                 foreach(var header in headers.entries)
  37                                 {
  38                                         message.request_headers.append(header.key, header.value);
  39                                 }
  40                         }
  41
  42                         return message;
  43                 }
  44
  45                 private static string load_remote_file(string url, string method="GET", string? auth = null, HashMap<string, string>? headers = null)
  46                 {
  47                         var session = new Session();
  48                         var message = prepare_message(url, method, auth, headers);
  49
  50                         var status = session.send_message(message);
  51                         if (status == 200) return (string) message.response_body.data;
  52                         return "";
  53                 }
  54
  55                 private static async string load_remote_file_async(string url, string method="GET", string? auth = null, HashMap<string, string>? headers = null)
  56                 {
  57                         var result = "";
  58                         var session = new Session();
  59                         var message = prepare_message(url, method, auth, headers);
  60
  61                         session.queue_message(message, (s, m) => {
  62                                 if(m.status_code == 200) result = (string) m.response_body.data;
  63                                 Idle.add(load_remote_file_async.callback);
  64                         });
  65                         yield;
  66                         return result;
  67                 }
  68
  69                 public static Json.Node parse_json(string json)
  70                 {
  71                         try
  72                         {
  73                                 var parser = new Json.Parser();
  74                                 parser.load_from_data(json);
  75                                 return parser.get_root();
  76                         }
  77                         catch(GLib.Error e)
  78                         {
  79                                 warning(e.message);
  80                         }
  81                         return new Json.Node(Json.NodeType.NULL);
  82                 }
  83
  84                 public static Json.Node parse_vdf(string vdf)
  85                 {
  86                         return parse_json(vdf_to_json(vdf));
  87                 }
  88
  89                 public static Json.Node parse_json_file(string path, string file="")
  90                 {
  91                         return parse_json(load_file(path, file));
  92                 }
  93
  94                 public static Json.Node parse_vdf_file(string path, string file="")
  95                 {
  96                         return parse_vdf(load_file(path, file));
  97                 }
  98
  99                 public static Json.Node parse_remote_json_file(string url, string method="GET", string? auth = null, HashMap<string, string>? headers = null)
 100                 {
 101                         return parse_json(load_remote_file(url, method, auth, headers));
 102                 }
 103
 104                 public static Json.Node parse_remote_vdf_file(string url, string method="GET", string? auth = null, HashMap<string, string>? headers = null)
 105                 {
 106                         return parse_vdf(load_remote_file(url, method, auth, headers));
 107                 }
 108
 109                 public static async Json.Node parse_remote_json_file_async(string url, string method="GET", string? auth = null, HashMap<string, string>? headers = null)
 110                 {
 111                         return parse_json(yield load_remote_file_async(url, method, auth, headers));
 112                 }
 113
 114                 public static async Json.Node parse_remote_vdf_file_async(string url, string method="GET", string? auth = null, HashMap<string, string>? headers = null)
 115                 {
 116                         return parse_vdf(yield load_remote_file_async(url, method, auth, headers));
 117                 }
 118
 119                 public static Json.Object? json_object(Json.Node root, string[] keys)
 120                 {
 121                         Json.Object? obj = root.get_object();
 122
 123                         foreach(var key in keys)
 124                         {
 125                                 if(obj != null && obj.has_member(key)) obj = obj.get_object_member(key);
 126                                 else obj = null;
 127
 128                                 if(obj == null) break;
 129                         }
 130
 131                         return obj;
 132                 }
 133
 134                 private static string vdf_to_json(string vdf_data)
 135                 {
 136                         var json = vdf_data;
 137
 138                         try
 139                         {
 140                                 var nl_commas = new Regex("(\"|\\})(\\s*?\\r?\\n\\s*?\")");
 141                                 var semicolons = new Regex("\"(\\s*?\\r?\\n?\\s*?(?:\"|\\{))");
 142
 143                                 json = nl_commas.replace(json, json.length, 0, "\\g<1>,\\g<2>");
 144                                 json = semicolons.replace(json, json.length, 0, "\":\\g<1>");
 145                         }
 146                         catch(Error e)
 147                         {
 148                                 warning(e.message);
 149                         }
 150
 151                         return "{" + json + "}";
 152                 }
 153         }
 154 }